1: # The LearningOnline Network
2: # Cookie Based Access Handler
3: #
4: # $Id: lonacc.pm,v 1.115 2008/05/14 18:27:30 raeburn Exp $
5: #
6: # Copyright Michigan State University Board of Trustees
7: #
8: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
9: #
10: # LON-CAPA is free software; you can redistribute it and/or modify
11: # it under the terms of the GNU General Public License as published by
12: # the Free Software Foundation; either version 2 of the License, or
13: # (at your option) any later version.
14: #
15: # LON-CAPA is distributed in the hope that it will be useful,
16: # but WITHOUT ANY WARRANTY; without even the implied warranty of
17: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18: # GNU General Public License for more details.
19: #
20: # You should have received a copy of the GNU General Public License
21: # along with LON-CAPA; if not, write to the Free Software
22: # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
23: #
24: # /home/httpd/html/adm/gpl.txt
25: #
26: # http://www.lon-capa.org/
27: #
28: ###
29:
30: package Apache::lonacc;
31:
32: use strict;
33: use Apache::Constants qw(:common :http :methods);
34: use Apache::File;
35: use Apache::lonnet;
36: use Apache::loncommon();
37: use Apache::lonlocal;
38: use Apache::restrictedaccess();
39: use Apache::blockedaccess();
40: use Fcntl qw(:flock);
41: use LONCAPA;
42:
43: sub cleanup {
44: my ($r)=@_;
45: if (! $r->is_initial_req()) { return DECLINED; }
46: &Apache::lonnet::save_cache();
47: &Apache::lontexconvert::jsMath_reset();
48: return OK;
49: }
50:
51: sub goodbye {
52: my ($r)=@_;
53: &Apache::lonnet::goodbye();
54: return DONE;
55: }
56:
57: ###############################################
58:
59: sub get_posted_cgi {
60: my ($r,$fields) = @_;
61:
62: my $buffer;
63: if ($r->header_in('Content-length')) {
64: $r->read($buffer,$r->header_in('Content-length'),0);
65: }
66: my $content_type = $r->header_in('Content-type');
67: if ($content_type !~ m{^multipart/form-data}) {
68: my @pairs=split(/&/,$buffer);
69: my $pair;
70: foreach $pair (@pairs) {
71: my ($name,$value) = split(/=/,$pair);
72: $value =~ tr/+/ /;
73: $value =~ s/%([a-fA-F0-9][a-fA-F0-9])/pack("C",hex($1))/eg;
74: $name =~ tr/+/ /;
75: $name =~ s/%([a-fA-F0-9][a-fA-F0-9])/pack("C",hex($1))/eg;
76: if (ref($fields) eq 'ARRAY') {
77: next if (!grep(/^\Q$name\E$/,@{$fields}));
78: }
79: &Apache::loncommon::add_to_env("form.$name",$value);
80: }
81: } else {
82: my ($contentsep) = ($content_type =~ /boundary=\"?([^\";,]+)\"?/);
83: my @lines = split (/\n/,$buffer);
84: my $name='';
85: my $value='';
86: my $fname='';
87: my $fmime='';
88: my $i;
89: for ($i=0;$i<=$#lines;$i++) {
90: if ($lines[$i]=~/^--\Q$contentsep\E/) {
91: if ($name) {
92: chomp($value);
93: if ($fname) {
94: $env{"form.$name.filename"}=$fname;
95: $env{"form.$name.mimetype"}=$fmime;
96: } else {
97: $value=~s/\s+$//s;
98: }
99: if (ref($fields) eq 'ARRAY') {
100: next if (!grep(/^\Q$name\E$/,@{$fields}));
101: }
102: &Apache::loncommon::add_to_env("form.$name",$value);
103: }
104: if ($i<$#lines) {
105: $i++;
106: $lines[$i]=~
107: /Content\-Disposition\:\s*form\-data\;\s*name\=\"([^\"]+)\"/i;
108: $name=$1;
109: $value='';
110: if ($lines[$i]=~/filename\=\"([^\"]+)\"/i) {
111: $fname=$1;
112: if
113: ($lines[$i+1]=~/Content\-Type\:\s*([\w\-\/]+)/i) {
114: $fmime=$1;
115: $i++;
116: } else {
117: $fmime='';
118: }
119: } else {
120: $fname='';
121: $fmime='';
122: }
123: $i++;
124: }
125: } else {
126: $value.=$lines[$i]."\n";
127: }
128: }
129: }
130: #
131: # Digested POSTed values
132: #
133: # Remember the way this was originally done (GET or POST)
134: #
135: $env{'request.method'}=$ENV{'REQUEST_METHOD'};
136: #
137: # There may also be stuff in the query string
138: # Tell subsequent handlers that this was GET, not POST, so they can access query string.
139: # Also, unset POSTed content length to cover all tracks.
140: #
141:
142: $r->method_number(M_GET);
143:
144: $r->method('GET');
145: $r->headers_in->unset('Content-length');
146: }
147:
148: # handle the case of the single sign on user, at this point $r->user
149: # will be set and valid now need to find the loncapa user info and possibly
150: # balance them
151: # returns OK if it was a SSO and user was handled
152: # undef if not SSO or no means to hanle the user
153: sub sso_login {
154: my ($r,$handle) = @_;
155:
156: my $lonidsdir=$r->dir_config('lonIDsDir');
157: if (!($r->user
158: && (!defined($env{'user.name'}) && !defined($env{'user.domain'}))
159: && ($handle eq ''))) {
160: # not an SSO case or already logged in
161: return undef;
162: }
163:
164: my ($user) = ($r->user =~ m/([a-zA-Z0-9_\-@.]*)/);
165:
166: my $domain = $r->dir_config('lonDefDomain');
167: my $home=&Apache::lonnet::homeserver($user,$domain);
168: if ($home !~ /(con_lost|no_host|no_such_host)/) {
169: &Apache::lonnet::logthis(" SSO authorized user $user ");
170: if ($r->dir_config("lonBalancer") eq 'yes') {
171: # login but immeaditly go to switch server to find us a new
172: # machine
173: &Apache::lonauth::success($r,$user,$domain,$home,'noredirect');
174: $env{'request.sso.login'} = 1;
175: if (defined($r->dir_config("lonSSOReloginServer"))) {
176: $env{'request.sso.reloginserver'} =
177: $r->dir_config('lonSSOReloginServer');
178: }
179: $r->internal_redirect('/adm/switchserver');
180: $r->set_handlers('PerlHandler'=> undef);
181: } else {
182: # need to login them in, so generate the need data that
183: # migrate expects to do login
184: my %info=('ip' => $r->connection->remote_ip(),
185: 'domain' => $domain,
186: 'username' => $user,
187: 'server' => $r->dir_config('lonHostID'),
188: 'sso.login' => 1
189: );
190: if (defined($r->dir_config("lonSSOReloginServer"))) {
191: $info{'sso.reloginserver'} =
192: $r->dir_config('lonSSOReloginServer');
193: }
194: my $token =
195: &Apache::lonnet::tmpput(\%info,
196: $r->dir_config('lonHostID'));
197: $env{'form.token'} = $token;
198: $r->internal_redirect('/adm/migrateuser');
199: $r->set_handlers('PerlHandler'=> undef);
200: }
201: return OK;
202: } elsif (defined($r->dir_config('lonSSOUserUnknownRedirect'))) {
203: &Apache::lonnet::logthis(" SSO authorized unknown user $user ");
204: $r->subprocess_env->set('SSOUserUnknown' => $user);
205: $r->subprocess_env->set('SSOUserDomain' => $domain);
206: my @cancreate;
207: my %domconfig =
208: &Apache::lonnet::get_dom('configuration',['usercreation'],$domain);
209: if (ref($domconfig{'usercreation'}) eq 'HASH') {
210: if (ref($domconfig{'usercreation'}{'cancreate'}) eq 'HASH') {
211: if (ref($domconfig{'usercreation'}{'cancreate'}{'selfcreate'}) eq 'ARRAY') {
212: @cancreate = @{$domconfig{'usercreation'}{'cancreate'}{'selfcreate'}};
213: } elsif (($domconfig{'usercreation'}{'cancreate'}{'selfcreate'} ne 'none') &&
214: ($domconfig{'usercreation'}{'cancreate'}{'selfcreate'} ne '')) {
215: @cancreate = ($domconfig{'usercreation'}{'cancreate'}{'selfcreate'});
216: }
217: }
218: }
219: if (grep(/^sso$/,@cancreate)) {
220: $r->internal_redirect('/adm/createaccount');
221: } else {
222: $r->internal_redirect($r->dir_config('lonSSOUserUnknownRedirect'));
223: }
224: $r->set_handlers('PerlHandler'=> undef);
225: return OK;
226: }
227: return undef;
228: }
229:
230: sub handler {
231: my $r = shift;
232: my $requrl=$r->uri;
233: if (&Apache::lonnet::is_domainimage($requrl)) {
234: return OK;
235: }
236:
237:
238: my $handle = &Apache::lonnet::check_for_valid_session($r);
239:
240: my $result = &sso_login($r,$handle);
241: if (defined($result)) {
242: return $result
243: }
244:
245:
246: if ($r->dir_config("lonBalancer") eq 'yes') {
247: $r->set_handlers('PerlResponseHandler'=>
248: [\&Apache::switchserver::handler]);
249: }
250:
251: if ($handle eq '') {
252: $r->log_reason("Cookie $handle not valid", $r->filename);
253: } elsif ($handle ne '') {
254:
255: # ------------------------------------------------------ Initialize Environment
256: my $lonidsdir=$r->dir_config('lonIDsDir');
257: &Apache::lonnet::transfer_profile_to_env($lonidsdir,$handle);
258:
259: # --------------------------------------------------------- Initialize Language
260:
261: &Apache::lonlocal::get_language_handle($r);
262:
263: }
264:
265: # -------------------------------------------------- Should be a valid user now
266: if ($env{'user.name'} ne '' && $env{'user.domain'} ne '') {
267: # -------------------------------------------------------------- Resource State
268:
269: if ($requrl=~/^\/+(res|uploaded)\//) {
270: $env{'request.state'} = "published";
271: } else {
272: $env{'request.state'} = 'unknown';
273: }
274: $env{'request.filename'} = $r->filename;
275: $env{'request.noversionuri'} = &Apache::lonnet::deversion($requrl);
276: # -------------------------------------------------------- Load POST parameters
277:
278: &Apache::lonacc::get_posted_cgi($r);
279:
280: # ---------------------------------------------------------------- Check access
281: my $now = time;
282: if ($requrl !~ m{^/(?:adm|public|prtspool)/}
283: || $requrl =~ /^\/adm\/.*\/(smppg|bulletinboard)(\?|$ )/x) {
284: my $access=&Apache::lonnet::allowed('bre',$requrl);
285: if ($access eq '1') {
286: $env{'user.error.msg'}="$requrl:bre:0:0:Choose Course";
287: return HTTP_NOT_ACCEPTABLE;
288: }
289: if ($access eq 'A') {
290: &Apache::restrictedaccess::setup_handler($r);
291: return OK;
292: }
293: if ($access eq 'B') {
294: &Apache::blockedaccess::setup_handler($r);
295: return OK;
296: }
297: if (($access ne '2') && ($access ne 'F')) {
298: $env{'user.error.msg'}="$requrl:bre:1:1:Access Denied";
299: return HTTP_NOT_ACCEPTABLE;
300: }
301: }
302: if ($requrl =~ m|^/prtspool/|) {
303: my $start='/prtspool/'.$env{'user.name'}.'_'.
304: $env{'user.domain'};
305: if ($requrl !~ /^\Q$start\E/) {
306: $env{'user.error.msg'}="$requrl:bre:1:1:Access Denied";
307: return HTTP_NOT_ACCEPTABLE;
308: }
309: }
310: if ($requrl =~ m|^/zipspool/|) {
311: my $start='/zipspool/zipout/'.$env{'user.name'}.":".
312: $env{'user.domain'};
313: if ($requrl !~ /^\Q$start\E/) {
314: $env{'user.error.msg'}="$requrl:bre:1:1:Access Denied";
315: return HTTP_NOT_ACCEPTABLE;
316: }
317: }
318: if ($env{'user.name'} eq 'public' &&
319: $env{'user.domain'} eq 'public' &&
320: $requrl !~ m{^/+(res|public|uploaded)/} &&
321: $requrl !~ m{^/adm/[^/]+/[^/]+/aboutme/portfolio$ }x &&
322: $requrl !~ m{^/+adm/(help|logout|restrictedaccess|randomlabel\.png)}) {
323: $env{'request.querystring'}=$r->args;
324: $env{'request.firsturl'}=$requrl;
325: return FORBIDDEN;
326: }
327: # ------------------------------------------------------------- This is allowed
328: if ($env{'request.course.id'}) {
329: &Apache::lonnet::countacc($requrl);
330: $requrl=~/\.(\w+)$/;
331: if ((&Apache::loncommon::fileembstyle($1) eq 'ssi') ||
332: ($requrl=~/^\/adm\/.*\/(aboutme|navmaps|smppg|bulletinboard)(\?|$ )/x) ||
333: ($requrl=~/^\/adm\/wrapper\//) ||
334: ($requrl=~m|^/adm/coursedocs/showdoc/|) ||
335: ($requrl=~m|\.problem/smpedit$|) ||
336: ($requrl=~/^\/public\/.*\/syllabus$/)) {
337: # ------------------------------------- This is serious stuff, get symb and log
338: my $query=$r->args;
339: my $symb;
340: if ($query) {
341: &Apache::loncommon::get_unprocessed_cgi($query,['symb']);
342: }
343: if ($env{'form.symb'}) {
344: $symb=&Apache::lonnet::symbclean($env{'form.symb'});
345: if ($requrl =~ m|^/adm/wrapper/|
346: || $requrl =~ m|^/adm/coursedocs/showdoc/|) {
347: my ($map,$mid,$murl)=&Apache::lonnet::decode_symb($symb);
348: &Apache::lonnet::symblist($map,$murl => [$murl,$mid],
349: 'last_known' =>[$murl,$mid]);
350: } elsif ((&Apache::lonnet::symbverify($symb,$requrl)) ||
351: (($requrl=~m|(.*)/smpedit$|) &&
352: &Apache::lonnet::symbverify($symb,$1))) {
353: my ($map,$mid,$murl)=&Apache::lonnet::decode_symb($symb);
354: &Apache::lonnet::symblist($map,$murl => [$murl,$mid],
355: 'last_known' =>[$murl,$mid]);
356: } else {
357: $r->log_reason('Invalid symb for '.$requrl.': '.
358: $symb);
359: $env{'user.error.msg'}=
360: "$requrl:bre:1:1:Invalid Access";
361: return HTTP_NOT_ACCEPTABLE;
362: }
363: } else {
364: $symb=&Apache::lonnet::symbread($requrl);
365: if (&Apache::lonnet::is_on_map($requrl) && $symb &&
366: !&Apache::lonnet::symbverify($symb,$requrl)) {
367: $r->log_reason('Invalid symb for '.$requrl.': '.$symb);
368: $env{'user.error.msg'}=
369: "$requrl:bre:1:1:Invalid Access";
370: return HTTP_NOT_ACCEPTABLE;
371: }
372: if ($symb) {
373: my ($map,$mid,$murl)=
374: &Apache::lonnet::decode_symb($symb);
375: &Apache::lonnet::symblist($map,$murl =>[$murl,$mid],
376: 'last_known' =>[$murl,$mid]);
377: }
378: }
379: $env{'request.symb'}=$symb;
380: &Apache::lonnet::courseacclog($symb);
381: } else {
382: # ------------------------------------------------------- This is other content
383: &Apache::lonnet::courseacclog($requrl);
384: }
385: }
386: return OK;
387: }
388: # -------------------------------------------- See if this is a public resource
389: if ($requrl=~m|^/+adm/+help/+|) {
390: return OK;
391: }
392: # ------------------------------------ See if this is a viewable portfolio file
393: if (&Apache::lonnet::is_portfolio_url($requrl)) {
394: my $access=&Apache::lonnet::allowed('bre',$requrl);
395: if ($access eq 'A') {
396: &Apache::restrictedaccess::setup_handler($r);
397: return OK;
398: }
399: if (($access ne '2') && ($access ne 'F')) {
400: $env{'user.error.msg'}="$requrl:bre:1:1:Access Denied";
401: return HTTP_NOT_ACCEPTABLE;
402: }
403: }
404:
405: # -------------------------------------------------------------- Not authorized
406: $requrl=~/\.(\w+)$/;
407: # if ((&Apache::loncommon::fileembstyle($1) eq 'ssi') ||
408: # ($requrl=~/^\/adm\/(roles|logout|email|menu|remote)/) ||
409: # ($requrl=~m|^/prtspool/|)) {
410: # -------------------------- Store where they wanted to go and get login screen
411: $env{'request.querystring'}=$r->args;
412: $env{'request.firsturl'}=$requrl;
413: return FORBIDDEN;
414: # } else {
415: # --------------------------------------------------------------------- Goodbye
416: # return HTTP_BAD_REQUEST;
417: # }
418: }
419:
420: 1;
421: __END__
422:
423: =head1 NAME
424:
425: Apache::lonacc - Cookie Based Access Handler
426:
427: =head1 SYNOPSIS
428:
429: Invoked (for various locations) by /etc/httpd/conf/srm.conf:
430:
431: PerlAccessHandler Apache::lonacc
432:
433: =head1 INTRODUCTION
434:
435: This module enables cookie based authentication and is used
436: to control access for many different LON-CAPA URIs.
437:
438: Whenever the client sends the cookie back to the server,
439: this cookie is handled by either lonacc.pm or loncacc.pm
440: (see srm.conf for what is invoked when). If
441: the cookie is missing or invalid, the user is re-challenged
442: for login information.
443:
444: This is part of the LearningOnline Network with CAPA project
445: described at http://www.lon-capa.org.
446:
447: =head1 HANDLER SUBROUTINE
448:
449: This routine is called by Apache and mod_perl.
450:
451: =over 4
452:
453: =item *
454:
455: transfer profile into environment
456:
457: =item *
458:
459: load POST parameters
460:
461: =item *
462:
463: check access
464:
465: =item *
466:
467: if allowed, get symb, log, generate course statistics if applicable
468:
469: =item *
470:
471: otherwise return error
472:
473: =item *
474:
475: see if public resource
476:
477: =item *
478:
479: store attempted access
480:
481: =back
482:
483: =cut
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>