1: # The LearningOnline Network
2: # Cookie Based Access Handler
3: #
4: # $Id: lonacc.pm,v 1.159.2.3 2016/08/07 20:49:37 raeburn Exp $
5: #
6: # Copyright Michigan State University Board of Trustees
7: #
8: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
9: #
10: # LON-CAPA is free software; you can redistribute it and/or modify
11: # it under the terms of the GNU General Public License as published by
12: # the Free Software Foundation; either version 2 of the License, or
13: # (at your option) any later version.
14: #
15: # LON-CAPA is distributed in the hope that it will be useful,
16: # but WITHOUT ANY WARRANTY; without even the implied warranty of
17: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18: # GNU General Public License for more details.
19: #
20: # You should have received a copy of the GNU General Public License
21: # along with LON-CAPA; if not, write to the Free Software
22: # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
23: #
24: # /home/httpd/html/adm/gpl.txt
25: #
26: # http://www.lon-capa.org/
27: #
28: ###
29:
30: =head1 NAME
31:
32: Apache::lonacc - Cookie Based Access Handler
33:
34: =head1 SYNOPSIS
35:
36: Invoked (for various locations) by /etc/httpd/conf/srm.conf:
37:
38: PerlAccessHandler Apache::lonacc
39:
40: =head1 INTRODUCTION
41:
42: This module enables cookie based authentication and is used
43: to control access for many different LON-CAPA URIs.
44:
45: Whenever the client sends the cookie back to the server,
46: this cookie is handled by either lonacc.pm or loncacc.pm
47: (see srm.conf for what is invoked when). If
48: the cookie is missing or invalid, the user is re-challenged
49: for login information.
50:
51: This is part of the LearningOnline Network with CAPA project
52: described at http://www.lon-capa.org.
53:
54: =head1 HANDLER SUBROUTINE
55:
56: This routine is called by Apache and mod_perl.
57:
58: =over 4
59:
60: =item *
61:
62: transfer profile into environment
63:
64: =item *
65:
66: load POST parameters
67:
68: =item *
69:
70: check access
71:
72: =item *
73:
74: if allowed, get symb, log, generate course statistics if applicable
75:
76: =item *
77:
78: otherwise return error
79:
80: =item *
81:
82: see if public resource
83:
84: =item *
85:
86: store attempted access
87:
88: =back
89:
90: =head1 NOTABLE SUBROUTINES
91:
92: =cut
93:
94:
95: package Apache::lonacc;
96:
97: use strict;
98: use Apache::Constants qw(:common :http :methods);
99: use Apache::File;
100: use Apache::lonnet;
101: use Apache::loncommon();
102: use Apache::lonlocal;
103: use Apache::restrictedaccess();
104: use Apache::blockedaccess();
105: use Fcntl qw(:flock);
106: use LONCAPA qw(:DEFAULT :match);
107:
108: sub cleanup {
109: my ($r)=@_;
110: if (! $r->is_initial_req()) { return DECLINED; }
111: &Apache::lonnet::save_cache();
112: return OK;
113: }
114:
115: sub goodbye {
116: my ($r)=@_;
117: &Apache::lonnet::goodbye();
118: return DONE;
119: }
120:
121: ###############################################
122:
123: sub get_posted_cgi {
124: my ($r,$fields) = @_;
125:
126: my $buffer;
127: if ($r->header_in('Content-length')) {
128: $r->read($buffer,$r->header_in('Content-length'),0);
129: }
130: my $content_type = $r->header_in('Content-type');
131: if ($content_type !~ m{^multipart/form-data}) {
132: my @pairs=split(/&/,$buffer);
133: my $pair;
134: foreach $pair (@pairs) {
135: my ($name,$value) = split(/=/,$pair);
136: $value =~ tr/+/ /;
137: $value =~ s/%([a-fA-F0-9][a-fA-F0-9])/pack("C",hex($1))/eg;
138: $name =~ tr/+/ /;
139: $name =~ s/%([a-fA-F0-9][a-fA-F0-9])/pack("C",hex($1))/eg;
140: if (ref($fields) eq 'ARRAY') {
141: next if (!grep(/^\Q$name\E$/,@{$fields}));
142: }
143: &Apache::loncommon::add_to_env("form.$name",$value);
144: }
145: } else {
146: my ($contentsep) = ($content_type =~ /boundary=\"?([^\";,]+)\"?/);
147: my @lines = split (/\n/,$buffer);
148: my $name='';
149: my $value='';
150: my $fname='';
151: my $fmime='';
152: my $i;
153: for ($i=0;$i<=$#lines;$i++) {
154: if ($lines[$i]=~/^--\Q$contentsep\E/) {
155: if ($name) {
156: chomp($value);
157: if (($r->uri eq '/adm/portfolio') &&
158: ($name eq 'uploaddoc')) {
159: if (length($value) == 1) {
160: $value=~s/[\r\n]$//;
161: }
162: } elsif ($fname =~ /\.(xls|doc|ppt)x$/i) {
163: $value=~s/[\r\n]$//;
164: }
165: if (ref($fields) eq 'ARRAY') {
166: next if (!grep(/^\Q$name\E$/,@{$fields}));
167: }
168: if ($fname) {
169: if ($env{'form.symb'} ne '') {
170: my $size = (length($value))/(1024.0 * 1024.0);
171: if (&upload_size_allowed($name,$size,$fname) eq 'ok') {
172: $env{"form.$name.filename"}=$fname;
173: $env{"form.$name.mimetype"}=$fmime;
174: &Apache::loncommon::add_to_env("form.$name",$value);
175: }
176: } else {
177: $env{"form.$name.filename"}=$fname;
178: $env{"form.$name.mimetype"}=$fmime;
179: &Apache::loncommon::add_to_env("form.$name",$value);
180: }
181: } else {
182: $value=~s/\s+$//s;
183: &Apache::loncommon::add_to_env("form.$name",$value);
184: }
185: }
186: if ($i<$#lines) {
187: $i++;
188: $lines[$i]=~
189: /Content\-Disposition\:\s*form\-data\;\s*name\=\"([^\"]+)\"/i;
190: $name=$1;
191: $value='';
192: if ($lines[$i]=~/filename\=\"([^\"]+)\"/i) {
193: $fname=$1;
194: if
195: ($lines[$i+1]=~/Content\-Type\:\s*([\w\-\/]+)/i) {
196: $fmime=$1;
197: $i++;
198: } else {
199: $fmime='';
200: }
201: } else {
202: $fname='';
203: $fmime='';
204: }
205: $i++;
206: }
207: } else {
208: $value.=$lines[$i]."\n";
209: }
210: }
211: }
212: #
213: # Digested POSTed values
214: #
215: # Remember the way this was originally done (GET or POST)
216: #
217: $env{'request.method'}=$ENV{'REQUEST_METHOD'};
218: #
219: # There may also be stuff in the query string
220: # Tell subsequent handlers that this was GET, not POST, so they can access query string.
221: # Also, unset POSTed content length to cover all tracks.
222: #
223:
224: $r->method_number(M_GET);
225:
226: $r->method('GET');
227: $r->headers_in->unset('Content-length');
228: }
229:
230: =pod
231:
232: =over
233:
234: =item upload_size_allowed()
235:
236: Perform size checks for file uploads to essayresponse items in course context.
237:
238: Add form.HWFILESIZE.$part_$id to %env with file size (MB)
239: If file exceeds maximum allowed size, add form.HWFILETOOBIG.$part_$id to %env.
240:
241: =cut
242:
243: sub upload_size_allowed {
244: my ($name,$size,$fname) = @_;
245: if ($name =~ /^HWFILE(\w+)$/) {
246: my $ident = $1;
247: my $item = 'HWFILESIZE'.$ident;
248: my $savesize = sprintf("%.6f",$size);
249: &Apache::loncommon::add_to_env("form.$item",$savesize);
250: my $maxsize= &Apache::lonnet::EXT("resource.$ident.maxfilesize");
251: if (!$maxsize) {
252: $maxsize = 10.0; # FIXME This should become a domain configuration.
253: }
254: if ($size > $maxsize) {
255: my $warn = 'HWFILETOOBIG'.$ident;
256: &Apache::loncommon::add_to_env("form.$warn",$fname);
257: return;
258: }
259: }
260: return 'ok';
261: }
262:
263: =pod
264:
265: =item sso_login()
266:
267: handle the case of the single sign on user, at this point $r->user
268: will be set and valid; now need to find the loncapa user info, and possibly
269: balance them. If $r->user() is set this means either it was either set by
270: SSO or by checkauthen.pm, if a valid cookie was found. The latter case can
271: be identified by the third arg ($usename), except when lonacc is called in
272: an internal redirect to /adm/switchserver (e.g., load-balancing following
273: successful authentication) -- no cookie set yet. For that particular case
274: simply skip the call to sso_login().
275:
276: returns OK if it was SSO and user was handled.
277: returns undef if not SSO or no means to handle the user.
278:
279: =cut
280:
281: sub sso_login {
282: my ($r,$handle,$username) = @_;
283:
284: my $lonidsdir=$r->dir_config('lonIDsDir');
285: if (($r->user eq '') || ($username ne '') || ($r->user eq 'public:public') ||
286: (defined($env{'user.name'}) && (defined($env{'user.domain'}))
287: && ($handle ne ''))) {
288: # not an SSO case or already logged in
289: return undef;
290: }
291:
292: my ($user) = ($r->user =~ m/^($match_username)$/);
293: if ($user eq '') {
294: return undef;
295: }
296:
297: my $query = $r->args;
298: my %form;
299: if ($query) {
300: my @items = ('role','symb','iptoken');
301: &Apache::loncommon::get_unprocessed_cgi($query,\@items);
302: foreach my $item (@items) {
303: if (defined($env{'form.'.$item})) {
304: $form{$item} = $env{'form.'.$item};
305: }
306: }
307: }
308:
309: my %sessiondata;
310: if ($form{'iptoken'}) {
311: %sessiondata = &Apache::lonnet::tmpget($form{'iptoken'});
312: my $delete = &Apache::lonnet::tmpdel($form{'iptoken'});
313: unless ($sessiondata{'sessionserver'}) {
314: delete($form{'iptoken'});
315: }
316: }
317:
318: my $domain = $r->dir_config('lonSSOUserDomain');
319: if ($domain eq '') {
320: $domain = $r->dir_config('lonDefDomain');
321: }
322: my $home=&Apache::lonnet::homeserver($user,$domain);
323: if ($home !~ /(con_lost|no_host|no_such_host)/) {
324: &Apache::lonnet::logthis(" SSO authorized user $user ");
325: my ($is_balancer,$otherserver,$hosthere);
326: if ($form{'iptoken'}) {
327: if (($sessiondata{'domain'} eq $domain) &&
328: ($sessiondata{'username'} eq $user)) {
329: $hosthere = 1;
330: }
331: }
332: unless ($hosthere) {
333: ($is_balancer,$otherserver) =
334: &Apache::lonnet::check_loadbalancing($user,$domain);
335: }
336:
337: if ($is_balancer) {
338: # login but immediately go to switch server to find us a new
339: # machine
340: &Apache::lonauth::success($r,$user,$domain,$home,'noredirect');
341: $env{'request.sso.login'} = 1;
342: if (defined($r->dir_config("lonSSOReloginServer"))) {
343: $env{'request.sso.reloginserver'} =
344: $r->dir_config('lonSSOReloginServer');
345: }
346: my $redirecturl = '/adm/switchserver';
347: if ($otherserver ne '') {
348: $redirecturl .= '?otherserver='.$otherserver;
349: }
350: $r->internal_redirect($redirecturl);
351: $r->set_handlers('PerlHandler'=> undef);
352: } else {
353: # need to login them in, so generate the need data that
354: # migrate expects to do login
355: my $ip;
356: my $c = $r->connection;
357: eval {
358: $ip = $c->remote_ip();
359: };
360: if ($@) {
361: $ip = $c->client_ip();
362: }
363: my %info=('ip' => $ip,
364: 'domain' => $domain,
365: 'username' => $user,
366: 'server' => $r->dir_config('lonHostID'),
367: 'sso.login' => 1
368: );
369: foreach my $item ('role','symb','iptoken') {
370: if (exists($form{$item})) {
371: $info{$item} = $form{$item};
372: }
373: }
374: unless ($info{'symb'}) {
375: unless (($r->uri eq '/adm/roles') || ($r->uri eq '/adm/sso')) {
376: $info{'origurl'} = $r->uri;
377: }
378: }
379: if ($r->dir_config("ssodirecturl") == 1) {
380: $info{'origurl'} = $r->uri;
381: }
382: if (defined($r->dir_config("lonSSOReloginServer"))) {
383: $info{'sso.reloginserver'} =
384: $r->dir_config('lonSSOReloginServer');
385: }
386: my $token =
387: &Apache::lonnet::tmpput(\%info,
388: $r->dir_config('lonHostID'));
389: $env{'form.token'} = $token;
390: $r->internal_redirect('/adm/migrateuser');
391: $r->set_handlers('PerlHandler'=> undef);
392: }
393: return OK;
394: } else {
395: &Apache::lonnet::logthis(" SSO authorized unknown user $user ");
396: my @cancreate;
397: my %domconfig =
398: &Apache::lonnet::get_dom('configuration',['usercreation'],$domain);
399: if (ref($domconfig{'usercreation'}) eq 'HASH') {
400: if (ref($domconfig{'usercreation'}{'cancreate'}) eq 'HASH') {
401: if (ref($domconfig{'usercreation'}{'cancreate'}{'selfcreate'}) eq 'ARRAY') {
402: @cancreate = @{$domconfig{'usercreation'}{'cancreate'}{'selfcreate'}};
403: } elsif (($domconfig{'usercreation'}{'cancreate'}{'selfcreate'} ne 'none') &&
404: ($domconfig{'usercreation'}{'cancreate'}{'selfcreate'} ne '')) {
405: @cancreate = ($domconfig{'usercreation'}{'cancreate'}{'selfcreate'});
406: }
407: }
408: }
409: if ((grep(/^sso$/,@cancreate)) || (defined($r->dir_config('lonSSOUserUnknownRedirect')))) {
410: $r->subprocess_env->set('SSOUserUnknown' => $user);
411: $r->subprocess_env->set('SSOUserDomain' => $domain);
412: if (grep(/^sso$/,@cancreate)) {
413: $r->set_handlers('PerlHandler'=> [\&Apache::createaccount::handler]);
414: $r->handler('perl-script');
415: } else {
416: $r->internal_redirect($r->dir_config('lonSSOUserUnknownRedirect'));
417: $r->set_handlers('PerlHandler'=> undef);
418: }
419: return OK;
420: }
421: }
422: return undef;
423: }
424:
425: sub handler {
426: my $r = shift;
427: my $requrl=$r->uri;
428:
429: if ($requrl =~ m{^/res/adm/pages/[^/]+\.(gif|png)$}) {
430: return OK;
431: }
432:
433: if (&Apache::lonnet::is_domainimage($requrl)) {
434: return OK;
435: }
436:
437: my %user;
438: my $handle = &Apache::lonnet::check_for_valid_session($r,undef,\%user);
439:
440: unless (($requrl eq '/adm/switchserver') && (!$r->is_initial_req())) {
441: my $result = &sso_login($r,$handle,$user{'name'});
442: if (defined($result)) {
443: return $result;
444: }
445: }
446:
447: my ($is_balancer,$otherserver);
448:
449: if ($handle eq '') {
450: unless ((($requrl eq '/adm/switchserver') && (!$r->is_initial_req())) ||
451: ($requrl =~ m{^/public/$match_domain/$match_courseid/syllabus}) ||
452: ($requrl =~ m{^/adm/help/}) ||
453: ($requrl =~ m{^/res/$match_domain/$match_username/})) {
454: $r->log_reason("Cookie not valid", $r->filename);
455: }
456: } elsif ($handle ne '') {
457:
458: # ------------------------------------------------------ Initialize Environment
459: my $lonidsdir=$r->dir_config('lonIDsDir');
460: &Apache::lonnet::transfer_profile_to_env($lonidsdir,$handle);
461:
462: # --------------------------------------------------------- Initialize Language
463:
464: &Apache::lonlocal::get_language_handle($r);
465:
466: }
467:
468: # -------------------------------------------------- Should be a valid user now
469: if ($env{'user.name'} ne '' && $env{'user.domain'} ne '') {
470: # -------------------------------------------------------------- Resource State
471:
472: my ($cdom,$cnum);
473: if ($env{'request.course.id'}) {
474: $cdom = $env{'course.'.$env{'request.course.id'}.'.domain'};
475: $cnum = $env{'course.'.$env{'request.course.id'}.'.num'};
476: }
477: if ($requrl=~/^\/+(res|uploaded)\//) {
478: $env{'request.state'} = "published";
479: } else {
480: $env{'request.state'} = 'unknown';
481: }
482: $env{'request.filename'} = $r->filename;
483: $env{'request.noversionuri'} = &Apache::lonnet::deversion($requrl);
484: my ($suppext,$checkabsolute);
485: if ($requrl =~ m{^/adm/wrapper/ext/}) {
486: my $query = $r->args;
487: if ($query) {
488: my $preserved;
489: foreach my $pair (split(/&/,$query)) {
490: my ($name, $value) = split(/=/,$pair);
491: unless ($name eq 'symb') {
492: $preserved .= $pair.'&';
493: }
494: if (($env{'request.course.id'}) && ($name eq 'folderpath')) {
495: if ($value =~ /^supplemental/) {
496: $suppext = 1;
497: }
498: }
499: }
500: $preserved =~ s/\&$//;
501: if ($preserved) {
502: $env{'request.external.querystring'} = $preserved;
503: }
504: }
505: if ($env{'request.course.id'}) {
506: $checkabsolute = 1;
507: }
508: } elsif ($env{'request.course.id'} &&
509: (($requrl =~ m{^/adm/$match_domain/$match_username/aboutme$}) ||
510: ($requrl =~ m{^/public/$cdom/$cnum/syllabus$}))) {
511: my $query = $r->args;
512: if ($query) {
513: foreach my $pair (split(/&/,$query)) {
514: my ($name, $value) = split(/=/,$pair);
515: if ($name eq 'folderpath') {
516: if ($value =~ /^supplemental/) {
517: $suppext = 1;
518: }
519: }
520: }
521: }
522: if ($requrl =~ m{^/public/$cdom/$cnum/syllabus$}) {
523: $checkabsolute = 1;
524: }
525: }
526: if ($checkabsolute) {
527: my $hostname = $r->hostname();
528: my $lonhost = &Apache::lonnet::host_from_dns($hostname);
529: if ($lonhost) {
530: my $actual = &Apache::lonnet::absolute_url($hostname);
531: my $expected = $Apache::lonnet::protocol{$lonhost}.'://'.$hostname;
532: unless ($actual eq $expected) {
533: $env{'request.use_absolute'} = $expected;
534: }
535: }
536: }
537: # -------------------------------------------------------- Load POST parameters
538:
539: &Apache::lonacc::get_posted_cgi($r);
540:
541: # ------------------------------------------------------ Check if load balancer
542:
543: my $checkexempt;
544: if ($env{'user.loadbalexempt'} eq $r->dir_config('lonHostID')) {
545: if ($env{'user.loadbalcheck.time'} + 600 > time) {
546: $checkexempt = 1;
547: }
548: }
549: if ($env{'user.noloadbalance'} eq $r->dir_config('lonHostID')) {
550: $checkexempt = 1;
551: }
552: unless ($checkexempt) {
553: ($is_balancer,$otherserver) =
554: &Apache::lonnet::check_loadbalancing($env{'user.name'},
555: $env{'user.domain'});
556: }
557: if ($is_balancer) {
558: $r->set_handlers('PerlResponseHandler'=>
559: [\&Apache::switchserver::handler]);
560: if ($otherserver ne '') {
561: $env{'form.otherserver'} = $otherserver;
562: }
563: unless (($env{'form.origurl'}) || ($r->uri eq '/adm/roles') ||
564: ($r->uri eq '/adm/switchserver') || ($r->uri eq '/adm/sso')) {
565: $env{'form.origurl'} = $r->uri;
566: }
567: }
568:
569: # ---------------------------------------------------------------- Check access
570: my $now = time;
571: if ($requrl !~ m{^/(?:adm|public|prtspool)/}
572: || $requrl =~ /^\/adm\/.*\/(smppg|bulletinboard)(\?|$ )/x) {
573: my $access=&Apache::lonnet::allowed('bre',$requrl);
574: if ($handle eq '') {
575: unless ($access eq 'F') {
576: if ($requrl =~ m{^/res/$match_domain/$match_username/}) {
577: $r->log_reason("Cookie not valid", $r->filename);
578: }
579: }
580: }
581: if ($access eq '1') {
582: $env{'user.error.msg'}="$requrl:bre:0:0:Choose Course";
583: return HTTP_NOT_ACCEPTABLE;
584: }
585: if ($access eq 'A') {
586: &Apache::restrictedaccess::setup_handler($r);
587: return OK;
588: }
589: if ($access eq 'B') {
590: &Apache::blockedaccess::setup_handler($r);
591: return OK;
592: }
593: if (($access ne '2') && ($access ne 'F')) {
594: if ($requrl =~ m{^/res/}) {
595: $access = &Apache::lonnet::allowed('bro',$requrl);
596: if ($access ne 'F') {
597: if ($requrl eq '/res/lib/templates/simpleproblem.problem/smpedit') {
598: $access = &Apache::lonnet::allowed('bre','/res/lib/templates/simpleproblem.problem');
599: if ($access ne 'F') {
600: $env{'user.error.msg'}="$requrl:bre:1:1:Access Denied";
601: return HTTP_NOT_ACCEPTABLE;
602: }
603: } else {
604: $env{'user.error.msg'}="$requrl:bre:1:1:Access Denied";
605: return HTTP_NOT_ACCEPTABLE;
606: }
607: }
608: } elsif (($handle =~ /^publicuser_\d+$/) && (&Apache::lonnet::is_portfolio_url($requrl))) {
609: my $clientip = $r->get_remote_host();
610: if (&Apache::lonnet::allowed('bre',$requrl,undef,undef,$clientip) ne 'F') {
611: $env{'user.error.msg'}="$requrl:bre:1:1:Access Denied";
612: return HTTP_NOT_ACCEPTABLE;
613: }
614: } else {
615: $env{'user.error.msg'}="$requrl:bre:1:1:Access Denied";
616: return HTTP_NOT_ACCEPTABLE;
617: }
618: }
619: }
620: if ($requrl =~ m|^/prtspool/|) {
621: my $start='/prtspool/'.$env{'user.name'}.'_'.
622: $env{'user.domain'};
623: if ($requrl !~ /^\Q$start\E/) {
624: $env{'user.error.msg'}="$requrl:bre:1:1:Access Denied";
625: return HTTP_NOT_ACCEPTABLE;
626: }
627: }
628: if ($requrl =~ m|^/zipspool/|) {
629: my $start='/zipspool/zipout/'.$env{'user.name'}.":".
630: $env{'user.domain'};
631: if ($requrl !~ /^\Q$start\E/) {
632: $env{'user.error.msg'}="$requrl:bre:1:1:Access Denied";
633: return HTTP_NOT_ACCEPTABLE;
634: }
635: }
636: if ($env{'user.name'} eq 'public' &&
637: $env{'user.domain'} eq 'public' &&
638: $requrl !~ m{^/+(res|public|uploaded)/} &&
639: $requrl !~ m{^/adm/[^/]+/[^/]+/aboutme/portfolio$ }x &&
640: $requrl !~ m{^/adm/blockingstatus/.*$} &&
641: $requrl !~ m{^/+adm/(help|logout|restrictedaccess|randomlabel\.png)}) {
642: $env{'request.querystring'}=$r->args;
643: $env{'request.firsturl'}=$requrl;
644: return FORBIDDEN;
645: }
646: # ------------------------------------------------------------- This is allowed
647: if ($env{'request.course.id'}) {
648: &Apache::lonnet::countacc($requrl);
649: $requrl=~/\.(\w+)$/;
650: my $query=$r->args;
651: if ((&Apache::loncommon::fileembstyle($1) eq 'ssi') ||
652: ($requrl=~/^\/adm\/.*\/(aboutme|smppg|bulletinboard)(\?|$ )/x) ||
653: ($requrl=~/^\/adm\/wrapper\//) ||
654: ($requrl=~m|^/adm/coursedocs/showdoc/|) ||
655: ($requrl=~m|\.problem/smpedit$|) ||
656: ($requrl=~/^\/public\/.*\/syllabus$/) ||
657: ($requrl=~/^\/adm\/(viewclasslist|navmaps)$/) ||
658: ($requrl=~/^\/adm\/.*\/aboutme\/portfolio(\?|$)/)) {
659: # ------------------------------------- This is serious stuff, get symb and log
660: my $symb;
661: if ($query) {
662: &Apache::loncommon::get_unprocessed_cgi($query,['symb','folderpath']);
663: }
664: if ($env{'form.symb'}) {
665: $symb=&Apache::lonnet::symbclean($env{'form.symb'});
666: if ($requrl =~ m|^/adm/wrapper/|
667: || $requrl =~ m|^/adm/coursedocs/showdoc/|) {
668: my ($map,$mid,$murl)=&Apache::lonnet::decode_symb($symb);
669: &Apache::lonnet::symblist($map,$murl => [$murl,$mid],
670: 'last_known' =>[$murl,$mid]);
671: } elsif ((&Apache::lonnet::symbverify($symb,$requrl)) ||
672: (($requrl=~m|(.*)/smpedit$|) &&
673: &Apache::lonnet::symbverify($symb,$1)) ||
674: (($requrl=~m|(.*/aboutme)/portfolio$|) &&
675: &Apache::lonnet::symbverify($symb,$1))) {
676: my ($map,$mid,$murl)=&Apache::lonnet::decode_symb($symb);
677: &Apache::lonnet::symblist($map,$murl => [$murl,$mid],
678: 'last_known' =>[$murl,$mid]);
679: } else {
680: $r->log_reason('Invalid symb for '.$requrl.': '.
681: $symb);
682: $env{'user.error.msg'}=
683: "$requrl:bre:1:1:Invalid Access";
684: return HTTP_NOT_ACCEPTABLE;
685: }
686: } else {
687: if ($requrl=~m{^(/adm/.*/aboutme)/portfolio$}) {
688: $requrl = $1;
689: }
690: unless ($suppext) {
691: $symb=&Apache::lonnet::symbread($requrl);
692: if (&Apache::lonnet::is_on_map($requrl) && $symb &&
693: !&Apache::lonnet::symbverify($symb,$requrl)) {
694: $r->log_reason('Invalid symb for '.$requrl.': '.$symb);
695: $env{'user.error.msg'}=
696: "$requrl:bre:1:1:Invalid Access";
697: return HTTP_NOT_ACCEPTABLE;
698: }
699: if ($symb) {
700: my ($map,$mid,$murl)=
701: &Apache::lonnet::decode_symb($symb);
702: &Apache::lonnet::symblist($map,$murl =>[$murl,$mid],
703: 'last_known' =>[$murl,$mid]);
704: }
705: }
706: }
707: $env{'request.symb'}=$symb;
708: &Apache::lonnet::courseacclog($symb);
709: } else {
710: # ------------------------------------------------------- This is other content
711: &Apache::lonnet::courseacclog($requrl);
712: }
713: if ($requrl =~ m{^/+uploaded/\Q$cdom\E/\Q$cnum\E/(docs|supplemental)/.+\.html?$}) {
714: if (&Apache::lonnet::allowed('mdc',$env{'request.course.id'})) {
715: if ($query) {
716: &Apache::loncommon::get_unprocessed_cgi($query,['forceedit']);
717: if ($env{'form.forceedit'}) {
718: $env{'request.state'} = 'edit';
719: }
720: }
721: }
722: } elsif ($requrl =~ m{^/+uploaded/\Q$cdom\E/\Q$cnum\E/portfolio/syllabus/.+\.html?$}) {
723: if (&Apache::lonnet::allowed('mdc',$env{'request.course.id'})) {
724: if ($query) {
725: &Apache::loncommon::get_unprocessed_cgi($query,['forceedit','editmode']);
726: if (($env{'form.forceedit'}) || ($env{'form.editmode'})) {
727: $env{'request.state'} = 'edit';
728: }
729: }
730: }
731: }
732: }
733: return OK;
734: } else {
735: my $defdom=$r->dir_config('lonDefDomain');
736: ($is_balancer,$otherserver) =
737: &Apache::lonnet::check_loadbalancing(undef,$defdom);
738: if ($is_balancer) {
739: $r->set_handlers('PerlResponseHandler'=>
740: [\&Apache::switchserver::handler]);
741: if ($otherserver ne '') {
742: $env{'form.otherserver'} = $otherserver;
743: }
744: }
745: }
746: # -------------------------------------------- See if this is a public resource
747: if ($requrl=~m|^/+adm/+help/+|) {
748: return OK;
749: }
750: # ------------------------------------ See if this is a viewable portfolio file
751: if (&Apache::lonnet::is_portfolio_url($requrl)) {
752: my $clientip = $r->get_remote_host();
753: my $access=&Apache::lonnet::allowed('bre',$requrl,undef,undef,$clientip);
754: if ($access eq 'A') {
755: &Apache::restrictedaccess::setup_handler($r);
756: return OK;
757: }
758: if (($access ne '2') && ($access ne 'F')) {
759: $env{'user.error.msg'}="$requrl:bre:1:1:Access Denied";
760: return HTTP_NOT_ACCEPTABLE;
761: }
762: }
763:
764: # -------------------------------------------------------------- Not authorized
765: $requrl=~/\.(\w+)$/;
766: # if ((&Apache::loncommon::fileembstyle($1) eq 'ssi') ||
767: # ($requrl=~/^\/adm\/(roles|logout|email|menu|remote)/) ||
768: # ($requrl=~m|^/prtspool/|)) {
769: # -------------------------- Store where they wanted to go and get login screen
770: $env{'request.querystring'}=$r->args;
771: $env{'request.firsturl'}=$requrl;
772: return FORBIDDEN;
773: # } else {
774: # --------------------------------------------------------------------- Goodbye
775: # return HTTP_BAD_REQUEST;
776: # }
777: }
778:
779: 1;
780: __END__
781:
782: =pod
783:
784: =back
785:
786: =cut
787:
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>