1: # The LearningOnline Network
2: # Cookie Based Access Handler
3: #
4: # $Id: lonacc.pm,v 1.159.2.4 2016/08/16 20:36:45 raeburn Exp $
5: #
6: # Copyright Michigan State University Board of Trustees
7: #
8: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
9: #
10: # LON-CAPA is free software; you can redistribute it and/or modify
11: # it under the terms of the GNU General Public License as published by
12: # the Free Software Foundation; either version 2 of the License, or
13: # (at your option) any later version.
14: #
15: # LON-CAPA is distributed in the hope that it will be useful,
16: # but WITHOUT ANY WARRANTY; without even the implied warranty of
17: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18: # GNU General Public License for more details.
19: #
20: # You should have received a copy of the GNU General Public License
21: # along with LON-CAPA; if not, write to the Free Software
22: # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
23: #
24: # /home/httpd/html/adm/gpl.txt
25: #
26: # http://www.lon-capa.org/
27: #
28: ###
29:
30: =head1 NAME
31:
32: Apache::lonacc - Cookie Based Access Handler
33:
34: =head1 SYNOPSIS
35:
36: Invoked (for various locations) by /etc/httpd/conf/srm.conf:
37:
38: PerlAccessHandler Apache::lonacc
39:
40: =head1 INTRODUCTION
41:
42: This module enables cookie based authentication and is used
43: to control access for many different LON-CAPA URIs.
44:
45: Whenever the client sends the cookie back to the server,
46: this cookie is handled by either lonacc.pm or loncacc.pm
47: (see srm.conf for what is invoked when). If
48: the cookie is missing or invalid, the user is re-challenged
49: for login information.
50:
51: This is part of the LearningOnline Network with CAPA project
52: described at http://www.lon-capa.org.
53:
54: =head1 HANDLER SUBROUTINE
55:
56: This routine is called by Apache and mod_perl.
57:
58: =over 4
59:
60: =item *
61:
62: transfer profile into environment
63:
64: =item *
65:
66: load POST parameters
67:
68: =item *
69:
70: check access
71:
72: =item *
73:
74: if allowed, get symb, log, generate course statistics if applicable
75:
76: =item *
77:
78: otherwise return error
79:
80: =item *
81:
82: see if public resource
83:
84: =item *
85:
86: store attempted access
87:
88: =back
89:
90: =head1 NOTABLE SUBROUTINES
91:
92: =cut
93:
94:
95: package Apache::lonacc;
96:
97: use strict;
98: use Apache::Constants qw(:common :http :methods);
99: use Apache::File;
100: use Apache::lonnet;
101: use Apache::loncommon();
102: use Apache::lonlocal;
103: use Apache::restrictedaccess();
104: use Apache::blockedaccess();
105: use Fcntl qw(:flock);
106: use LONCAPA qw(:DEFAULT :match);
107:
108: sub cleanup {
109: my ($r)=@_;
110: if (! $r->is_initial_req()) { return DECLINED; }
111: &Apache::lonnet::save_cache();
112: return OK;
113: }
114:
115: sub goodbye {
116: my ($r)=@_;
117: &Apache::lonnet::goodbye();
118: return DONE;
119: }
120:
121: ###############################################
122:
123: sub get_posted_cgi {
124: my ($r,$fields) = @_;
125:
126: my $buffer;
127: if ($r->header_in('Content-length')) {
128: $r->read($buffer,$r->header_in('Content-length'),0);
129: }
130: my $content_type = $r->header_in('Content-type');
131: if ($content_type !~ m{^multipart/form-data}) {
132: my @pairs=split(/&/,$buffer);
133: my $pair;
134: foreach $pair (@pairs) {
135: my ($name,$value) = split(/=/,$pair);
136: $value =~ tr/+/ /;
137: $value =~ s/%([a-fA-F0-9][a-fA-F0-9])/pack("C",hex($1))/eg;
138: $name =~ tr/+/ /;
139: $name =~ s/%([a-fA-F0-9][a-fA-F0-9])/pack("C",hex($1))/eg;
140: if (ref($fields) eq 'ARRAY') {
141: next if (!grep(/^\Q$name\E$/,@{$fields}));
142: }
143: &Apache::loncommon::add_to_env("form.$name",$value);
144: }
145: } else {
146: my ($contentsep) = ($content_type =~ /boundary=\"?([^\";,]+)\"?/);
147: my @lines = split (/\n/,$buffer);
148: my $name='';
149: my $value='';
150: my $fname='';
151: my $fmime='';
152: my $i;
153: for ($i=0;$i<=$#lines;$i++) {
154: if ($lines[$i]=~/^--\Q$contentsep\E/) {
155: if ($name) {
156: chomp($value);
157: if (($r->uri eq '/adm/portfolio') &&
158: ($name eq 'uploaddoc')) {
159: if (length($value) == 1) {
160: $value=~s/[\r\n]$//;
161: }
162: } elsif ($fname =~ /\.(xls|doc|ppt)x$/i) {
163: $value=~s/[\r\n]$//;
164: }
165: if (ref($fields) eq 'ARRAY') {
166: next if (!grep(/^\Q$name\E$/,@{$fields}));
167: }
168: if ($fname) {
169: if ($env{'form.symb'} ne '') {
170: my $size = (length($value))/(1024.0 * 1024.0);
171: if (&upload_size_allowed($name,$size,$fname) eq 'ok') {
172: $env{"form.$name.filename"}=$fname;
173: $env{"form.$name.mimetype"}=$fmime;
174: &Apache::loncommon::add_to_env("form.$name",$value);
175: }
176: } else {
177: $env{"form.$name.filename"}=$fname;
178: $env{"form.$name.mimetype"}=$fmime;
179: &Apache::loncommon::add_to_env("form.$name",$value);
180: }
181: } else {
182: $value=~s/\s+$//s;
183: &Apache::loncommon::add_to_env("form.$name",$value);
184: }
185: }
186: if ($i<$#lines) {
187: $i++;
188: $lines[$i]=~
189: /Content\-Disposition\:\s*form\-data\;\s*name\=\"([^\"]+)\"/i;
190: $name=$1;
191: $value='';
192: if ($lines[$i]=~/filename\=\"([^\"]+)\"/i) {
193: $fname=$1;
194: if
195: ($lines[$i+1]=~/Content\-Type\:\s*([\w\-\/]+)/i) {
196: $fmime=$1;
197: $i++;
198: } else {
199: $fmime='';
200: }
201: } else {
202: $fname='';
203: $fmime='';
204: }
205: $i++;
206: }
207: } else {
208: $value.=$lines[$i]."\n";
209: }
210: }
211: }
212: #
213: # Digested POSTed values
214: #
215: # Remember the way this was originally done (GET or POST)
216: #
217: $env{'request.method'}=$ENV{'REQUEST_METHOD'};
218: #
219: # There may also be stuff in the query string
220: # Tell subsequent handlers that this was GET, not POST, so they can access query string.
221: # Also, unset POSTed content length to cover all tracks.
222: #
223:
224: $r->method_number(M_GET);
225:
226: $r->method('GET');
227: $r->headers_in->unset('Content-length');
228: }
229:
230: =pod
231:
232: =over
233:
234: =item upload_size_allowed()
235:
236: Perform size checks for file uploads to essayresponse items in course context.
237:
238: Add form.HWFILESIZE.$part_$id to %env with file size (MB)
239: If file exceeds maximum allowed size, add form.HWFILETOOBIG.$part_$id to %env.
240:
241: =cut
242:
243: sub upload_size_allowed {
244: my ($name,$size,$fname) = @_;
245: if ($name =~ /^HWFILE(\w+)$/) {
246: my $ident = $1;
247: my $item = 'HWFILESIZE'.$ident;
248: my $savesize = sprintf("%.6f",$size);
249: &Apache::loncommon::add_to_env("form.$item",$savesize);
250: my $maxsize= &Apache::lonnet::EXT("resource.$ident.maxfilesize");
251: if (!$maxsize) {
252: $maxsize = 10.0; # FIXME This should become a domain configuration.
253: }
254: if ($size > $maxsize) {
255: my $warn = 'HWFILETOOBIG'.$ident;
256: &Apache::loncommon::add_to_env("form.$warn",$fname);
257: return;
258: }
259: }
260: return 'ok';
261: }
262:
263: =pod
264:
265: =item sso_login()
266:
267: handle the case of the single sign on user, at this point $r->user
268: will be set and valid; now need to find the loncapa user info, and possibly
269: balance them. If $r->user() is set this means either it was either set by
270: SSO or by checkauthen.pm, if a valid cookie was found. The latter case can
271: be identified by the third arg ($usename), except when lonacc is called in
272: an internal redirect to /adm/switchserver (e.g., load-balancing following
273: successful authentication) -- no cookie set yet. For that particular case
274: simply skip the call to sso_login().
275:
276: returns OK if it was SSO and user was handled.
277: returns undef if not SSO or no means to handle the user.
278:
279: =cut
280:
281: sub sso_login {
282: my ($r,$handle,$username) = @_;
283:
284: my $lonidsdir=$r->dir_config('lonIDsDir');
285: if (($r->user eq '') || ($username ne '') || ($r->user eq 'public:public') ||
286: (defined($env{'user.name'}) && (defined($env{'user.domain'}))
287: && ($handle ne ''))) {
288: # not an SSO case or already logged in
289: return undef;
290: }
291:
292: my ($user) = ($r->user =~ m/^($match_username)$/);
293: if ($user eq '') {
294: return undef;
295: }
296:
297: my $query = $r->args;
298: my %form;
299: if ($query) {
300: my @items = ('role','symb','iptoken');
301: &Apache::loncommon::get_unprocessed_cgi($query,\@items);
302: foreach my $item (@items) {
303: if (defined($env{'form.'.$item})) {
304: $form{$item} = $env{'form.'.$item};
305: }
306: }
307: }
308:
309: my %sessiondata;
310: if ($form{'iptoken'}) {
311: %sessiondata = &Apache::lonnet::tmpget($form{'iptoken'});
312: my $delete = &Apache::lonnet::tmpdel($form{'iptoken'});
313: unless ($sessiondata{'sessionserver'}) {
314: delete($form{'iptoken'});
315: }
316: }
317:
318: my $domain = $r->dir_config('lonSSOUserDomain');
319: if ($domain eq '') {
320: $domain = $r->dir_config('lonDefDomain');
321: }
322: my $home=&Apache::lonnet::homeserver($user,$domain);
323: if ($home !~ /(con_lost|no_host|no_such_host)/) {
324: &Apache::lonnet::logthis(" SSO authorized user $user ");
325: my ($is_balancer,$otherserver,$hosthere);
326: if ($form{'iptoken'}) {
327: if (($sessiondata{'domain'} eq $domain) &&
328: ($sessiondata{'username'} eq $user)) {
329: $hosthere = 1;
330: }
331: }
332: unless ($hosthere) {
333: ($is_balancer,$otherserver) =
334: &Apache::lonnet::check_loadbalancing($user,$domain);
335: }
336:
337: if ($is_balancer) {
338: # login but immediately go to switch server to find us a new
339: # machine
340: &Apache::lonauth::success($r,$user,$domain,$home,'noredirect');
341: $env{'request.sso.login'} = 1;
342: if (defined($r->dir_config("lonSSOReloginServer"))) {
343: $env{'request.sso.reloginserver'} =
344: $r->dir_config('lonSSOReloginServer');
345: }
346: my $redirecturl = '/adm/switchserver';
347: if ($otherserver ne '') {
348: $redirecturl .= '?otherserver='.$otherserver;
349: }
350: $r->internal_redirect($redirecturl);
351: $r->set_handlers('PerlHandler'=> undef);
352: } else {
353: # need to login them in, so generate the need data that
354: # migrate expects to do login
355: my $ip = $r->get_remote_host();
356: my %info=('ip' => $ip,
357: 'domain' => $domain,
358: 'username' => $user,
359: 'server' => $r->dir_config('lonHostID'),
360: 'sso.login' => 1
361: );
362: foreach my $item ('role','symb','iptoken') {
363: if (exists($form{$item})) {
364: $info{$item} = $form{$item};
365: }
366: }
367: unless ($info{'symb'}) {
368: unless (($r->uri eq '/adm/roles') || ($r->uri eq '/adm/sso')) {
369: $info{'origurl'} = $r->uri;
370: }
371: }
372: if ($r->dir_config("ssodirecturl") == 1) {
373: $info{'origurl'} = $r->uri;
374: }
375: if (defined($r->dir_config("lonSSOReloginServer"))) {
376: $info{'sso.reloginserver'} =
377: $r->dir_config('lonSSOReloginServer');
378: }
379: my $token =
380: &Apache::lonnet::tmpput(\%info,
381: $r->dir_config('lonHostID'));
382: $env{'form.token'} = $token;
383: $r->internal_redirect('/adm/migrateuser');
384: $r->set_handlers('PerlHandler'=> undef);
385: }
386: return OK;
387: } else {
388: &Apache::lonnet::logthis(" SSO authorized unknown user $user ");
389: my @cancreate;
390: my %domconfig =
391: &Apache::lonnet::get_dom('configuration',['usercreation'],$domain);
392: if (ref($domconfig{'usercreation'}) eq 'HASH') {
393: if (ref($domconfig{'usercreation'}{'cancreate'}) eq 'HASH') {
394: if (ref($domconfig{'usercreation'}{'cancreate'}{'selfcreate'}) eq 'ARRAY') {
395: @cancreate = @{$domconfig{'usercreation'}{'cancreate'}{'selfcreate'}};
396: } elsif (($domconfig{'usercreation'}{'cancreate'}{'selfcreate'} ne 'none') &&
397: ($domconfig{'usercreation'}{'cancreate'}{'selfcreate'} ne '')) {
398: @cancreate = ($domconfig{'usercreation'}{'cancreate'}{'selfcreate'});
399: }
400: }
401: }
402: if ((grep(/^sso$/,@cancreate)) || (defined($r->dir_config('lonSSOUserUnknownRedirect')))) {
403: $r->subprocess_env->set('SSOUserUnknown' => $user);
404: $r->subprocess_env->set('SSOUserDomain' => $domain);
405: if (grep(/^sso$/,@cancreate)) {
406: $r->set_handlers('PerlHandler'=> [\&Apache::createaccount::handler]);
407: $r->handler('perl-script');
408: } else {
409: $r->internal_redirect($r->dir_config('lonSSOUserUnknownRedirect'));
410: $r->set_handlers('PerlHandler'=> undef);
411: }
412: return OK;
413: }
414: }
415: return undef;
416: }
417:
418: sub handler {
419: my $r = shift;
420: my $requrl=$r->uri;
421:
422: if ($requrl =~ m{^/res/adm/pages/[^/]+\.(gif|png)$}) {
423: return OK;
424: }
425:
426: if (&Apache::lonnet::is_domainimage($requrl)) {
427: return OK;
428: }
429:
430: my %user;
431: my $handle = &Apache::lonnet::check_for_valid_session($r,undef,\%user);
432:
433: unless (($requrl eq '/adm/switchserver') && (!$r->is_initial_req())) {
434: my $result = &sso_login($r,$handle,$user{'name'});
435: if (defined($result)) {
436: return $result;
437: }
438: }
439:
440: my ($is_balancer,$otherserver);
441:
442: if ($handle eq '') {
443: unless ((($requrl eq '/adm/switchserver') && (!$r->is_initial_req())) ||
444: ($requrl =~ m{^/public/$match_domain/$match_courseid/syllabus}) ||
445: ($requrl =~ m{^/adm/help/}) ||
446: ($requrl =~ m{^/res/$match_domain/$match_username/})) {
447: $r->log_reason("Cookie not valid", $r->filename);
448: }
449: } elsif ($handle ne '') {
450:
451: # ------------------------------------------------------ Initialize Environment
452: my $lonidsdir=$r->dir_config('lonIDsDir');
453: &Apache::lonnet::transfer_profile_to_env($lonidsdir,$handle);
454:
455: # --------------------------------------------------------- Initialize Language
456:
457: &Apache::lonlocal::get_language_handle($r);
458:
459: }
460:
461: # -------------------------------------------------- Should be a valid user now
462: if ($env{'user.name'} ne '' && $env{'user.domain'} ne '') {
463: # -------------------------------------------------------------- Resource State
464:
465: my ($cdom,$cnum);
466: if ($env{'request.course.id'}) {
467: $cdom = $env{'course.'.$env{'request.course.id'}.'.domain'};
468: $cnum = $env{'course.'.$env{'request.course.id'}.'.num'};
469: }
470: if ($requrl=~/^\/+(res|uploaded)\//) {
471: $env{'request.state'} = "published";
472: } else {
473: $env{'request.state'} = 'unknown';
474: }
475: $env{'request.filename'} = $r->filename;
476: $env{'request.noversionuri'} = &Apache::lonnet::deversion($requrl);
477: my ($suppext,$checkabsolute);
478: if ($requrl =~ m{^/adm/wrapper/ext/}) {
479: my $query = $r->args;
480: if ($query) {
481: my $preserved;
482: foreach my $pair (split(/&/,$query)) {
483: my ($name, $value) = split(/=/,$pair);
484: unless ($name eq 'symb') {
485: $preserved .= $pair.'&';
486: }
487: if (($env{'request.course.id'}) && ($name eq 'folderpath')) {
488: if ($value =~ /^supplemental/) {
489: $suppext = 1;
490: }
491: }
492: }
493: $preserved =~ s/\&$//;
494: if ($preserved) {
495: $env{'request.external.querystring'} = $preserved;
496: }
497: }
498: if ($env{'request.course.id'}) {
499: $checkabsolute = 1;
500: }
501: } elsif ($env{'request.course.id'} &&
502: (($requrl =~ m{^/adm/$match_domain/$match_username/aboutme$}) ||
503: ($requrl =~ m{^/public/$cdom/$cnum/syllabus$}))) {
504: my $query = $r->args;
505: if ($query) {
506: foreach my $pair (split(/&/,$query)) {
507: my ($name, $value) = split(/=/,$pair);
508: if ($name eq 'folderpath') {
509: if ($value =~ /^supplemental/) {
510: $suppext = 1;
511: }
512: }
513: }
514: }
515: if ($requrl =~ m{^/public/$cdom/$cnum/syllabus$}) {
516: $checkabsolute = 1;
517: }
518: }
519: if ($checkabsolute) {
520: my $hostname = $r->hostname();
521: my $lonhost = &Apache::lonnet::host_from_dns($hostname);
522: if ($lonhost) {
523: my $actual = &Apache::lonnet::absolute_url($hostname);
524: my $expected = $Apache::lonnet::protocol{$lonhost}.'://'.$hostname;
525: unless ($actual eq $expected) {
526: $env{'request.use_absolute'} = $expected;
527: }
528: }
529: }
530: # -------------------------------------------------------- Load POST parameters
531:
532: &Apache::lonacc::get_posted_cgi($r);
533:
534: # ------------------------------------------------------ Check if load balancer
535:
536: my $checkexempt;
537: if ($env{'user.loadbalexempt'} eq $r->dir_config('lonHostID')) {
538: if ($env{'user.loadbalcheck.time'} + 600 > time) {
539: $checkexempt = 1;
540: }
541: }
542: if ($env{'user.noloadbalance'} eq $r->dir_config('lonHostID')) {
543: $checkexempt = 1;
544: }
545: unless ($checkexempt) {
546: ($is_balancer,$otherserver) =
547: &Apache::lonnet::check_loadbalancing($env{'user.name'},
548: $env{'user.domain'});
549: }
550: if ($is_balancer) {
551: $r->set_handlers('PerlResponseHandler'=>
552: [\&Apache::switchserver::handler]);
553: if ($otherserver ne '') {
554: $env{'form.otherserver'} = $otherserver;
555: }
556: unless (($env{'form.origurl'}) || ($r->uri eq '/adm/roles') ||
557: ($r->uri eq '/adm/switchserver') || ($r->uri eq '/adm/sso')) {
558: $env{'form.origurl'} = $r->uri;
559: }
560: }
561:
562: # ---------------------------------------------------------------- Check access
563: my $now = time;
564: if ($requrl !~ m{^/(?:adm|public|prtspool)/}
565: || $requrl =~ /^\/adm\/.*\/(smppg|bulletinboard)(\?|$ )/x) {
566: my $access=&Apache::lonnet::allowed('bre',$requrl);
567: if ($handle eq '') {
568: unless ($access eq 'F') {
569: if ($requrl =~ m{^/res/$match_domain/$match_username/}) {
570: $r->log_reason("Cookie not valid", $r->filename);
571: }
572: }
573: }
574: if ($access eq '1') {
575: $env{'user.error.msg'}="$requrl:bre:0:0:Choose Course";
576: return HTTP_NOT_ACCEPTABLE;
577: }
578: if ($access eq 'A') {
579: &Apache::restrictedaccess::setup_handler($r);
580: return OK;
581: }
582: if ($access eq 'B') {
583: &Apache::blockedaccess::setup_handler($r);
584: return OK;
585: }
586: if (($access ne '2') && ($access ne 'F')) {
587: if ($requrl =~ m{^/res/}) {
588: $access = &Apache::lonnet::allowed('bro',$requrl);
589: if ($access ne 'F') {
590: if ($requrl eq '/res/lib/templates/simpleproblem.problem/smpedit') {
591: $access = &Apache::lonnet::allowed('bre','/res/lib/templates/simpleproblem.problem');
592: if ($access ne 'F') {
593: $env{'user.error.msg'}="$requrl:bre:1:1:Access Denied";
594: return HTTP_NOT_ACCEPTABLE;
595: }
596: } else {
597: $env{'user.error.msg'}="$requrl:bre:1:1:Access Denied";
598: return HTTP_NOT_ACCEPTABLE;
599: }
600: }
601: } elsif (($handle =~ /^publicuser_\d+$/) && (&Apache::lonnet::is_portfolio_url($requrl))) {
602: my $clientip = $r->get_remote_host();
603: if (&Apache::lonnet::allowed('bre',$requrl,undef,undef,$clientip) ne 'F') {
604: $env{'user.error.msg'}="$requrl:bre:1:1:Access Denied";
605: return HTTP_NOT_ACCEPTABLE;
606: }
607: } else {
608: $env{'user.error.msg'}="$requrl:bre:1:1:Access Denied";
609: return HTTP_NOT_ACCEPTABLE;
610: }
611: }
612: }
613: if ($requrl =~ m|^/prtspool/|) {
614: my $start='/prtspool/'.$env{'user.name'}.'_'.
615: $env{'user.domain'};
616: if ($requrl !~ /^\Q$start\E/) {
617: $env{'user.error.msg'}="$requrl:bre:1:1:Access Denied";
618: return HTTP_NOT_ACCEPTABLE;
619: }
620: }
621: if ($requrl =~ m|^/zipspool/|) {
622: my $start='/zipspool/zipout/'.$env{'user.name'}.":".
623: $env{'user.domain'};
624: if ($requrl !~ /^\Q$start\E/) {
625: $env{'user.error.msg'}="$requrl:bre:1:1:Access Denied";
626: return HTTP_NOT_ACCEPTABLE;
627: }
628: }
629: if ($env{'user.name'} eq 'public' &&
630: $env{'user.domain'} eq 'public' &&
631: $requrl !~ m{^/+(res|public|uploaded)/} &&
632: $requrl !~ m{^/adm/[^/]+/[^/]+/aboutme/portfolio$ }x &&
633: $requrl !~ m{^/adm/blockingstatus/.*$} &&
634: $requrl !~ m{^/+adm/(help|logout|restrictedaccess|randomlabel\.png)}) {
635: $env{'request.querystring'}=$r->args;
636: $env{'request.firsturl'}=$requrl;
637: return FORBIDDEN;
638: }
639: # ------------------------------------------------------------- This is allowed
640: if ($env{'request.course.id'}) {
641: &Apache::lonnet::countacc($requrl);
642: $requrl=~/\.(\w+)$/;
643: my $query=$r->args;
644: if ((&Apache::loncommon::fileembstyle($1) eq 'ssi') ||
645: ($requrl=~/^\/adm\/.*\/(aboutme|smppg|bulletinboard)(\?|$ )/x) ||
646: ($requrl=~/^\/adm\/wrapper\//) ||
647: ($requrl=~m|^/adm/coursedocs/showdoc/|) ||
648: ($requrl=~m|\.problem/smpedit$|) ||
649: ($requrl=~/^\/public\/.*\/syllabus$/) ||
650: ($requrl=~/^\/adm\/(viewclasslist|navmaps)$/) ||
651: ($requrl=~/^\/adm\/.*\/aboutme\/portfolio(\?|$)/)) {
652: # ------------------------------------- This is serious stuff, get symb and log
653: my $symb;
654: if ($query) {
655: &Apache::loncommon::get_unprocessed_cgi($query,['symb','folderpath']);
656: }
657: if ($env{'form.symb'}) {
658: $symb=&Apache::lonnet::symbclean($env{'form.symb'});
659: if ($requrl =~ m|^/adm/wrapper/|
660: || $requrl =~ m|^/adm/coursedocs/showdoc/|) {
661: my ($map,$mid,$murl)=&Apache::lonnet::decode_symb($symb);
662: &Apache::lonnet::symblist($map,$murl => [$murl,$mid],
663: 'last_known' =>[$murl,$mid]);
664: } elsif ((&Apache::lonnet::symbverify($symb,$requrl)) ||
665: (($requrl=~m|(.*)/smpedit$|) &&
666: &Apache::lonnet::symbverify($symb,$1)) ||
667: (($requrl=~m|(.*/aboutme)/portfolio$|) &&
668: &Apache::lonnet::symbverify($symb,$1))) {
669: my ($map,$mid,$murl)=&Apache::lonnet::decode_symb($symb);
670: &Apache::lonnet::symblist($map,$murl => [$murl,$mid],
671: 'last_known' =>[$murl,$mid]);
672: } else {
673: $r->log_reason('Invalid symb for '.$requrl.': '.
674: $symb);
675: $env{'user.error.msg'}=
676: "$requrl:bre:1:1:Invalid Access";
677: return HTTP_NOT_ACCEPTABLE;
678: }
679: } else {
680: if ($requrl=~m{^(/adm/.*/aboutme)/portfolio$}) {
681: $requrl = $1;
682: }
683: unless ($suppext) {
684: $symb=&Apache::lonnet::symbread($requrl);
685: if (&Apache::lonnet::is_on_map($requrl) && $symb &&
686: !&Apache::lonnet::symbverify($symb,$requrl)) {
687: $r->log_reason('Invalid symb for '.$requrl.': '.$symb);
688: $env{'user.error.msg'}=
689: "$requrl:bre:1:1:Invalid Access";
690: return HTTP_NOT_ACCEPTABLE;
691: }
692: if ($symb) {
693: my ($map,$mid,$murl)=
694: &Apache::lonnet::decode_symb($symb);
695: &Apache::lonnet::symblist($map,$murl =>[$murl,$mid],
696: 'last_known' =>[$murl,$mid]);
697: }
698: }
699: }
700: $env{'request.symb'}=$symb;
701: &Apache::lonnet::courseacclog($symb);
702: } else {
703: # ------------------------------------------------------- This is other content
704: &Apache::lonnet::courseacclog($requrl);
705: }
706: if ($requrl =~ m{^/+uploaded/\Q$cdom\E/\Q$cnum\E/(docs|supplemental)/.+\.html?$}) {
707: if (&Apache::lonnet::allowed('mdc',$env{'request.course.id'})) {
708: if ($query) {
709: &Apache::loncommon::get_unprocessed_cgi($query,['forceedit']);
710: if ($env{'form.forceedit'}) {
711: $env{'request.state'} = 'edit';
712: }
713: }
714: }
715: } elsif ($requrl =~ m{^/+uploaded/\Q$cdom\E/\Q$cnum\E/portfolio/syllabus/.+\.html?$}) {
716: if (&Apache::lonnet::allowed('mdc',$env{'request.course.id'})) {
717: if ($query) {
718: &Apache::loncommon::get_unprocessed_cgi($query,['forceedit','editmode']);
719: if (($env{'form.forceedit'}) || ($env{'form.editmode'})) {
720: $env{'request.state'} = 'edit';
721: }
722: }
723: }
724: }
725: }
726: return OK;
727: } else {
728: my $defdom=$r->dir_config('lonDefDomain');
729: ($is_balancer,$otherserver) =
730: &Apache::lonnet::check_loadbalancing(undef,$defdom);
731: if ($is_balancer) {
732: $r->set_handlers('PerlResponseHandler'=>
733: [\&Apache::switchserver::handler]);
734: if ($otherserver ne '') {
735: $env{'form.otherserver'} = $otherserver;
736: }
737: }
738: }
739: # -------------------------------------------- See if this is a public resource
740: if ($requrl=~m|^/+adm/+help/+|) {
741: return OK;
742: }
743: # ------------------------------------ See if this is a viewable portfolio file
744: if (&Apache::lonnet::is_portfolio_url($requrl)) {
745: my $clientip = $r->get_remote_host();
746: my $access=&Apache::lonnet::allowed('bre',$requrl,undef,undef,$clientip);
747: if ($access eq 'A') {
748: &Apache::restrictedaccess::setup_handler($r);
749: return OK;
750: }
751: if (($access ne '2') && ($access ne 'F')) {
752: $env{'user.error.msg'}="$requrl:bre:1:1:Access Denied";
753: return HTTP_NOT_ACCEPTABLE;
754: }
755: }
756:
757: # -------------------------------------------------------------- Not authorized
758: $requrl=~/\.(\w+)$/;
759: # if ((&Apache::loncommon::fileembstyle($1) eq 'ssi') ||
760: # ($requrl=~/^\/adm\/(roles|logout|email|menu|remote)/) ||
761: # ($requrl=~m|^/prtspool/|)) {
762: # -------------------------- Store where they wanted to go and get login screen
763: $env{'request.querystring'}=$r->args;
764: $env{'request.firsturl'}=$requrl;
765: return FORBIDDEN;
766: # } else {
767: # --------------------------------------------------------------------- Goodbye
768: # return HTTP_BAD_REQUEST;
769: # }
770: }
771:
772: 1;
773: __END__
774:
775: =pod
776:
777: =back
778:
779: =cut
780:
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>