1: # The LearningOnline Network
2: # Cookie Based Access Handler
3: #
4: # $Id: lonacc.pm,v 1.163 2016/02/20 00:12:49 raeburn Exp $
5: #
6: # Copyright Michigan State University Board of Trustees
7: #
8: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
9: #
10: # LON-CAPA is free software; you can redistribute it and/or modify
11: # it under the terms of the GNU General Public License as published by
12: # the Free Software Foundation; either version 2 of the License, or
13: # (at your option) any later version.
14: #
15: # LON-CAPA is distributed in the hope that it will be useful,
16: # but WITHOUT ANY WARRANTY; without even the implied warranty of
17: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18: # GNU General Public License for more details.
19: #
20: # You should have received a copy of the GNU General Public License
21: # along with LON-CAPA; if not, write to the Free Software
22: # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
23: #
24: # /home/httpd/html/adm/gpl.txt
25: #
26: # http://www.lon-capa.org/
27: #
28: ###
29:
30: =head1 NAME
31:
32: Apache::lonacc - Cookie Based Access Handler
33:
34: =head1 SYNOPSIS
35:
36: Invoked (for various locations) by /etc/httpd/conf/srm.conf:
37:
38: PerlAccessHandler Apache::lonacc
39:
40: =head1 INTRODUCTION
41:
42: This module enables cookie based authentication and is used
43: to control access for many different LON-CAPA URIs.
44:
45: Whenever the client sends the cookie back to the server,
46: this cookie is handled by either lonacc.pm or loncacc.pm
47: (see srm.conf for what is invoked when). If
48: the cookie is missing or invalid, the user is re-challenged
49: for login information.
50:
51: This is part of the LearningOnline Network with CAPA project
52: described at http://www.lon-capa.org.
53:
54: =head1 HANDLER SUBROUTINE
55:
56: This routine is called by Apache and mod_perl.
57:
58: =over 4
59:
60: =item *
61:
62: transfer profile into environment
63:
64: =item *
65:
66: load POST parameters
67:
68: =item *
69:
70: check access
71:
72: =item *
73:
74: if allowed, get symb, log, generate course statistics if applicable
75:
76: =item *
77:
78: otherwise return error
79:
80: =item *
81:
82: see if public resource
83:
84: =item *
85:
86: store attempted access
87:
88: =back
89:
90: =head1 NOTABLE SUBROUTINES
91:
92: =cut
93:
94:
95: package Apache::lonacc;
96:
97: use strict;
98: use Apache::Constants qw(:common :http :methods);
99: use Apache::File;
100: use Apache::lonnet;
101: use Apache::loncommon();
102: use Apache::lonlocal;
103: use Apache::restrictedaccess();
104: use Apache::blockedaccess();
105: use Fcntl qw(:flock);
106: use LONCAPA qw(:DEFAULT :match);
107:
108: sub cleanup {
109: my ($r)=@_;
110: if (! $r->is_initial_req()) { return DECLINED; }
111: &Apache::lonnet::save_cache();
112: return OK;
113: }
114:
115: sub goodbye {
116: my ($r)=@_;
117: &Apache::lonnet::goodbye();
118: return DONE;
119: }
120:
121: ###############################################
122:
123: sub get_posted_cgi {
124: my ($r,$fields) = @_;
125:
126: my $buffer;
127: if ($r->header_in('Content-length')) {
128: $r->read($buffer,$r->header_in('Content-length'),0);
129: }
130: my $content_type = $r->header_in('Content-type');
131: if ($content_type !~ m{^multipart/form-data}) {
132: my @pairs=split(/&/,$buffer);
133: my $pair;
134: foreach $pair (@pairs) {
135: my ($name,$value) = split(/=/,$pair);
136: $value =~ tr/+/ /;
137: $value =~ s/%([a-fA-F0-9][a-fA-F0-9])/pack("C",hex($1))/eg;
138: $name =~ tr/+/ /;
139: $name =~ s/%([a-fA-F0-9][a-fA-F0-9])/pack("C",hex($1))/eg;
140: if (ref($fields) eq 'ARRAY') {
141: next if (!grep(/^\Q$name\E$/,@{$fields}));
142: }
143: &Apache::loncommon::add_to_env("form.$name",$value);
144: }
145: } else {
146: my ($contentsep) = ($content_type =~ /boundary=\"?([^\";,]+)\"?/);
147: my @lines = split (/\n/,$buffer);
148: my $name='';
149: my $value='';
150: my $fname='';
151: my $fmime='';
152: my $i;
153: for ($i=0;$i<=$#lines;$i++) {
154: if ($lines[$i]=~/^--\Q$contentsep\E/) {
155: if ($name) {
156: chomp($value);
157: if (($r->uri eq '/adm/portfolio') &&
158: ($name eq 'uploaddoc')) {
159: if (length($value) == 1) {
160: $value=~s/[\r\n]$//;
161: }
162: } elsif ($fname =~ /\.(xls|doc|ppt)x$/i) {
163: $value=~s/[\r\n]$//;
164: }
165: if (ref($fields) eq 'ARRAY') {
166: next if (!grep(/^\Q$name\E$/,@{$fields}));
167: }
168: if ($fname) {
169: if ($env{'form.symb'} ne '') {
170: my $size = (length($value))/(1024.0 * 1024.0);
171: if (&upload_size_allowed($name,$size,$fname) eq 'ok') {
172: $env{"form.$name.filename"}=$fname;
173: $env{"form.$name.mimetype"}=$fmime;
174: &Apache::loncommon::add_to_env("form.$name",$value);
175: }
176: } else {
177: $env{"form.$name.filename"}=$fname;
178: $env{"form.$name.mimetype"}=$fmime;
179: &Apache::loncommon::add_to_env("form.$name",$value);
180: }
181: } else {
182: $value=~s/\s+$//s;
183: &Apache::loncommon::add_to_env("form.$name",$value);
184: }
185: }
186: if ($i<$#lines) {
187: $i++;
188: $lines[$i]=~
189: /Content\-Disposition\:\s*form\-data\;\s*name\=\"([^\"]+)\"/i;
190: $name=$1;
191: $value='';
192: if ($lines[$i]=~/filename\=\"([^\"]+)\"/i) {
193: $fname=$1;
194: if
195: ($lines[$i+1]=~/Content\-Type\:\s*([\w\-\/]+)/i) {
196: $fmime=$1;
197: $i++;
198: } else {
199: $fmime='';
200: }
201: } else {
202: $fname='';
203: $fmime='';
204: }
205: if ($i<$#lines && $lines[$i+1]=~/^Content\-Type\:\s*([\w\-\/]+)/i) {
206: # TODO: something with $1 !
207: $i++;
208: }
209: if ($i<$#lines && $lines[$i+1]=~/^Content\-transfer\-encoding\:\s*([\w\-\/]+)/i) {
210: # TODO: something with $1 !
211: $i++;
212: }
213: $i++;
214: }
215: } else {
216: $value.=$lines[$i]."\n";
217: }
218: }
219: }
220: #
221: # Digested POSTed values
222: #
223: # Remember the way this was originally done (GET or POST)
224: #
225: $env{'request.method'}=$ENV{'REQUEST_METHOD'};
226: #
227: # There may also be stuff in the query string
228: # Tell subsequent handlers that this was GET, not POST, so they can access query string.
229: # Also, unset POSTed content length to cover all tracks.
230: #
231:
232: $r->method_number(M_GET);
233:
234: $r->method('GET');
235: $r->headers_in->unset('Content-length');
236: }
237:
238: =pod
239:
240: =over
241:
242: =item upload_size_allowed()
243:
244: Perform size checks for file uploads to essayresponse items in course context.
245:
246: Add form.HWFILESIZE.$part_$id to %env with file size (MB)
247: If file exceeds maximum allowed size, add form.HWFILETOOBIG.$part_$id to %env.
248:
249: =cut
250:
251: sub upload_size_allowed {
252: my ($name,$size,$fname) = @_;
253: if ($name =~ /^HWFILE(\w+)$/) {
254: my $ident = $1;
255: my $item = 'HWFILESIZE'.$ident;
256: my $savesize = sprintf("%.6f",$size);
257: &Apache::loncommon::add_to_env("form.$item",$savesize);
258: my $maxsize= &Apache::lonnet::EXT("resource.$ident.maxfilesize");
259: if (!$maxsize) {
260: $maxsize = 10.0; # FIXME This should become a domain configuration.
261: }
262: if ($size > $maxsize) {
263: my $warn = 'HWFILETOOBIG'.$ident;
264: &Apache::loncommon::add_to_env("form.$warn",$fname);
265: return;
266: }
267: }
268: return 'ok';
269: }
270:
271: =pod
272:
273: =item sso_login()
274:
275: handle the case of the single sign on user, at this point $r->user
276: will be set and valid; now need to find the loncapa user info, and possibly
277: balance them. If $r->user() is set this means either it was either set by
278: SSO or by checkauthen.pm, if a valid cookie was found. The latter case can
279: be identified by the third arg ($usename), except when lonacc is called in
280: an internal redirect to /adm/switchserver (e.g., load-balancing following
281: successful authentication) -- no cookie set yet. For that particular case
282: simply skip the call to sso_login().
283:
284: returns OK if it was SSO and user was handled.
285: returns undef if not SSO or no means to handle the user.
286:
287: =cut
288:
289: sub sso_login {
290: my ($r,$handle,$username) = @_;
291:
292: my $lonidsdir=$r->dir_config('lonIDsDir');
293: if (($r->user eq '') || ($username ne '') || ($r->user eq 'public:public') ||
294: (defined($env{'user.name'}) && (defined($env{'user.domain'}))
295: && ($handle ne ''))) {
296: # not an SSO case or already logged in
297: return undef;
298: }
299:
300: my ($user) = ($r->user =~ m/^($match_username)$/);
301: if ($user eq '') {
302: return undef;
303: }
304:
305: my $query = $r->args;
306: my %form;
307: if ($query) {
308: my @items = ('role','symb','iptoken');
309: &Apache::loncommon::get_unprocessed_cgi($query,\@items);
310: foreach my $item (@items) {
311: if (defined($env{'form.'.$item})) {
312: $form{$item} = $env{'form.'.$item};
313: }
314: }
315: }
316:
317: my %sessiondata;
318: if ($form{'iptoken'}) {
319: %sessiondata = &Apache::lonnet::tmpget($form{'iptoken'});
320: my $delete = &Apache::lonnet::tmpdel($form{'iptoken'});
321: unless ($sessiondata{'sessionserver'}) {
322: delete($form{'iptoken'});
323: }
324: }
325:
326: my $domain = $r->dir_config('lonSSOUserDomain');
327: if ($domain eq '') {
328: $domain = $r->dir_config('lonDefDomain');
329: }
330: my $home=&Apache::lonnet::homeserver($user,$domain);
331: if ($home !~ /(con_lost|no_host|no_such_host)/) {
332: &Apache::lonnet::logthis(" SSO authorized user $user ");
333: my ($is_balancer,$otherserver,$hosthere);
334: if ($form{'iptoken'}) {
335: if (($sessiondata{'domain'} eq $domain) &&
336: ($sessiondata{'username'} eq $user)) {
337: $hosthere = 1;
338: }
339: }
340: unless ($hosthere) {
341: ($is_balancer,$otherserver) =
342: &Apache::lonnet::check_loadbalancing($user,$domain);
343: }
344:
345: if ($is_balancer) {
346: # login but immediately go to switch server to find us a new
347: # machine
348: &Apache::lonauth::success($r,$user,$domain,$home,'noredirect');
349: $env{'request.sso.login'} = 1;
350: if (defined($r->dir_config("lonSSOReloginServer"))) {
351: $env{'request.sso.reloginserver'} =
352: $r->dir_config('lonSSOReloginServer');
353: }
354: my $redirecturl = '/adm/switchserver';
355: if ($otherserver ne '') {
356: $redirecturl .= '?otherserver='.$otherserver;
357: }
358: $r->internal_redirect($redirecturl);
359: $r->set_handlers('PerlHandler'=> undef);
360: } else {
361: # need to login them in, so generate the need data that
362: # migrate expects to do login
363: my $ip;
364: my $c = $r->connection;
365: eval {
366: $ip = $c->remote_ip();
367: };
368: if ($@) {
369: $ip = $c->client_ip();
370: }
371: my %info=('ip' => $ip,
372: 'domain' => $domain,
373: 'username' => $user,
374: 'server' => $r->dir_config('lonHostID'),
375: 'sso.login' => 1
376: );
377: foreach my $item ('role','symb','iptoken') {
378: if (exists($form{$item})) {
379: $info{$item} = $form{$item};
380: }
381: }
382: unless ($info{'symb'}) {
383: unless (($r->uri eq '/adm/roles') || ($r->uri eq '/adm/sso')) {
384: $info{'origurl'} = $r->uri;
385: }
386: }
387: if ($r->dir_config("ssodirecturl") == 1) {
388: $info{'origurl'} = $r->uri;
389: }
390: if (defined($r->dir_config("lonSSOReloginServer"))) {
391: $info{'sso.reloginserver'} =
392: $r->dir_config('lonSSOReloginServer');
393: }
394: my $token =
395: &Apache::lonnet::tmpput(\%info,
396: $r->dir_config('lonHostID'));
397: $env{'form.token'} = $token;
398: $r->internal_redirect('/adm/migrateuser');
399: $r->set_handlers('PerlHandler'=> undef);
400: }
401: return OK;
402: } else {
403: &Apache::lonnet::logthis(" SSO authorized unknown user $user ");
404: my @cancreate;
405: my %domconfig =
406: &Apache::lonnet::get_dom('configuration',['usercreation'],$domain);
407: if (ref($domconfig{'usercreation'}) eq 'HASH') {
408: if (ref($domconfig{'usercreation'}{'cancreate'}) eq 'HASH') {
409: if (ref($domconfig{'usercreation'}{'cancreate'}{'selfcreate'}) eq 'ARRAY') {
410: @cancreate = @{$domconfig{'usercreation'}{'cancreate'}{'selfcreate'}};
411: } elsif (($domconfig{'usercreation'}{'cancreate'}{'selfcreate'} ne 'none') &&
412: ($domconfig{'usercreation'}{'cancreate'}{'selfcreate'} ne '')) {
413: @cancreate = ($domconfig{'usercreation'}{'cancreate'}{'selfcreate'});
414: }
415: }
416: }
417: if ((grep(/^sso$/,@cancreate)) || (defined($r->dir_config('lonSSOUserUnknownRedirect')))) {
418: $r->subprocess_env->set('SSOUserUnknown' => $user);
419: $r->subprocess_env->set('SSOUserDomain' => $domain);
420: if (grep(/^sso$/,@cancreate)) {
421: $r->set_handlers('PerlHandler'=> [\&Apache::createaccount::handler]);
422: $r->handler('perl-script');
423: } else {
424: $r->internal_redirect($r->dir_config('lonSSOUserUnknownRedirect'));
425: $r->set_handlers('PerlHandler'=> undef);
426: }
427: return OK;
428: }
429: }
430: return undef;
431: }
432:
433: sub handler {
434: my $r = shift;
435: my $requrl=$r->uri;
436:
437: if ($requrl =~ m{^/res/adm/pages/[^/]+\.(gif|png)$}) {
438: return OK;
439: }
440:
441: if (&Apache::lonnet::is_domainimage($requrl)) {
442: return OK;
443: }
444:
445: my %user;
446: my $handle = &Apache::lonnet::check_for_valid_session($r,undef,\%user);
447:
448: unless (($requrl eq '/adm/switchserver') && (!$r->is_initial_req())) {
449: my $result = &sso_login($r,$handle,$user{'name'});
450: if (defined($result)) {
451: return $result;
452: }
453: }
454:
455: my ($is_balancer,$otherserver);
456:
457: if ($handle eq '') {
458: unless ((($requrl eq '/adm/switchserver') && (!$r->is_initial_req())) ||
459: ($requrl =~ m{^/public/$match_domain/$match_courseid/syllabus}) ||
460: ($requrl =~ m{^/adm/help/}) ||
461: ($requrl =~ m{^/res/$match_domain/$match_username/})) {
462: $r->log_reason("Cookie not valid", $r->filename);
463: }
464: } elsif ($handle ne '') {
465:
466: # ------------------------------------------------------ Initialize Environment
467: my $lonidsdir=$r->dir_config('lonIDsDir');
468: &Apache::lonnet::transfer_profile_to_env($lonidsdir,$handle);
469:
470: # --------------------------------------------------------- Initialize Language
471:
472: &Apache::lonlocal::get_language_handle($r);
473:
474: }
475:
476: # -------------------------------------------------- Should be a valid user now
477: if ($env{'user.name'} ne '' && $env{'user.domain'} ne '') {
478: # -------------------------------------------------------------- Resource State
479:
480: my ($cdom,$cnum);
481: if ($env{'request.course.id'}) {
482: $cdom = $env{'course.'.$env{'request.course.id'}.'.domain'};
483: $cnum = $env{'course.'.$env{'request.course.id'}.'.num'};
484: }
485: if ($requrl=~/^\/+(res|uploaded)\//) {
486: $env{'request.state'} = "published";
487: } else {
488: $env{'request.state'} = 'unknown';
489: }
490: $env{'request.filename'} = $r->filename;
491: $env{'request.noversionuri'} = &Apache::lonnet::deversion($requrl);
492: my ($suppext,$checkabsolute);
493: if ($requrl =~ m{^/adm/wrapper/ext/}) {
494: my $query = $r->args;
495: if ($query) {
496: my $preserved;
497: foreach my $pair (split(/&/,$query)) {
498: my ($name, $value) = split(/=/,$pair);
499: unless ($name eq 'symb') {
500: $preserved .= $pair.'&';
501: }
502: if (($env{'request.course.id'}) && ($name eq 'folderpath')) {
503: if ($value =~ /^supplemental/) {
504: $suppext = 1;
505: }
506: }
507: }
508: $preserved =~ s/\&$//;
509: if ($preserved) {
510: $env{'request.external.querystring'} = $preserved;
511: }
512: }
513: if ($env{'request.course.id'}) {
514: $checkabsolute = 1;
515: }
516: } elsif ($env{'request.course.id'} &&
517: (($requrl =~ m{^/adm/$match_domain/$match_username/aboutme$}) ||
518: ($requrl =~ m{^/public/$cdom/$cnum/syllabus$}))) {
519: my $query = $r->args;
520: if ($query) {
521: foreach my $pair (split(/&/,$query)) {
522: my ($name, $value) = split(/=/,$pair);
523: if ($name eq 'folderpath') {
524: if ($value =~ /^supplemental/) {
525: $suppext = 1;
526: }
527: }
528: }
529: }
530: if ($requrl =~ m{^/public/$cdom/$cnum/syllabus$}) {
531: $checkabsolute = 1;
532: }
533: }
534: if ($checkabsolute) {
535: my $hostname = $r->hostname();
536: my $lonhost = &Apache::lonnet::host_from_dns($hostname);
537: if ($lonhost) {
538: my $actual = &Apache::lonnet::absolute_url($hostname);
539: my $expected = $Apache::lonnet::protocol{$lonhost}.'://'.$hostname;
540: unless ($actual eq $expected) {
541: $env{'request.use_absolute'} = $expected;
542: }
543: }
544: }
545: # -------------------------------------------------------- Load POST parameters
546:
547: &Apache::lonacc::get_posted_cgi($r);
548:
549: # ------------------------------------------------------ Check if load balancer
550:
551: my $checkexempt;
552: if ($env{'user.loadbalexempt'} eq $r->dir_config('lonHostID')) {
553: if ($env{'user.loadbalcheck.time'} + 600 > time) {
554: $checkexempt = 1;
555: }
556: }
557: if ($env{'user.noloadbalance'} eq $r->dir_config('lonHostID')) {
558: $checkexempt = 1;
559: }
560: unless ($checkexempt) {
561: ($is_balancer,$otherserver) =
562: &Apache::lonnet::check_loadbalancing($env{'user.name'},
563: $env{'user.domain'});
564: }
565: if ($is_balancer) {
566: $r->set_handlers('PerlResponseHandler'=>
567: [\&Apache::switchserver::handler]);
568: if ($otherserver ne '') {
569: $env{'form.otherserver'} = $otherserver;
570: }
571: unless (($env{'form.origurl'}) || ($r->uri eq '/adm/roles') ||
572: ($r->uri eq '/adm/switchserver') || ($r->uri eq '/adm/sso')) {
573: $env{'form.origurl'} = $r->uri;
574: }
575: }
576:
577: # ---------------------------------------------------------------- Check access
578: my $now = time;
579: if ($requrl !~ m{^/(?:adm|public|prtspool)/}
580: || $requrl =~ /^\/adm\/.*\/(smppg|bulletinboard)(\?|$ )/x) {
581: my $access=&Apache::lonnet::allowed('bre',$requrl);
582: if ($handle eq '') {
583: unless ($access eq 'F') {
584: if ($requrl =~ m{^/res/$match_domain/$match_username/}) {
585: $r->log_reason("Cookie not valid", $r->filename);
586: }
587: }
588: }
589: if ($access eq '1') {
590: $env{'user.error.msg'}="$requrl:bre:0:0:Choose Course";
591: return HTTP_NOT_ACCEPTABLE;
592: }
593: if ($access eq 'A') {
594: &Apache::restrictedaccess::setup_handler($r);
595: return OK;
596: }
597: if ($access eq 'B') {
598: &Apache::blockedaccess::setup_handler($r);
599: return OK;
600: }
601: if (($access ne '2') && ($access ne 'F')) {
602: if ($requrl =~ m{^/res/}) {
603: $access = &Apache::lonnet::allowed('bro',$requrl);
604: if ($access ne 'F') {
605: if ($requrl eq '/res/lib/templates/simpleproblem.problem/smpedit') {
606: $access = &Apache::lonnet::allowed('bre','/res/lib/templates/simpleproblem.problem');
607: if ($access ne 'F') {
608: $env{'user.error.msg'}="$requrl:bre:1:1:Access Denied";
609: return HTTP_NOT_ACCEPTABLE;
610: }
611: } else {
612: $env{'user.error.msg'}="$requrl:bre:1:1:Access Denied";
613: return HTTP_NOT_ACCEPTABLE;
614: }
615: }
616: } elsif (($handle =~ /^publicuser_\d+$/) && (&Apache::lonnet::is_portfolio_url($requrl))) {
617: my $clientip = $r->get_remote_host();
618: if (&Apache::lonnet::allowed('bre',$requrl,undef,undef,$clientip) ne 'F') {
619: $env{'user.error.msg'}="$requrl:bre:1:1:Access Denied";
620: return HTTP_NOT_ACCEPTABLE;
621: }
622: } else {
623: $env{'user.error.msg'}="$requrl:bre:1:1:Access Denied";
624: return HTTP_NOT_ACCEPTABLE;
625: }
626: }
627: }
628: if ($requrl =~ m|^/prtspool/|) {
629: my $start='/prtspool/'.$env{'user.name'}.'_'.
630: $env{'user.domain'};
631: if ($requrl !~ /^\Q$start\E/) {
632: $env{'user.error.msg'}="$requrl:bre:1:1:Access Denied";
633: return HTTP_NOT_ACCEPTABLE;
634: }
635: }
636: if ($requrl =~ m|^/zipspool/|) {
637: my $start='/zipspool/zipout/'.$env{'user.name'}.":".
638: $env{'user.domain'};
639: if ($requrl !~ /^\Q$start\E/) {
640: $env{'user.error.msg'}="$requrl:bre:1:1:Access Denied";
641: return HTTP_NOT_ACCEPTABLE;
642: }
643: }
644: if ($env{'user.name'} eq 'public' &&
645: $env{'user.domain'} eq 'public' &&
646: $requrl !~ m{^/+(res|public|uploaded)/} &&
647: $requrl !~ m{^/adm/[^/]+/[^/]+/aboutme/portfolio$ }x &&
648: $requrl !~ m{^/adm/blockingstatus/.*$} &&
649: $requrl !~ m{^/+adm/(help|logout|restrictedaccess|randomlabel\.png)}) {
650: $env{'request.querystring'}=$r->args;
651: $env{'request.firsturl'}=$requrl;
652: return FORBIDDEN;
653: }
654: # ------------------------------------------------------------- This is allowed
655: if ($env{'request.course.id'}) {
656: &Apache::lonnet::countacc($requrl);
657: $requrl=~/\.(\w+)$/;
658: my $query=$r->args;
659: if ((&Apache::loncommon::fileembstyle($1) eq 'ssi') ||
660: ($requrl=~/^\/adm\/.*\/(aboutme|smppg|bulletinboard)(\?|$ )/x) ||
661: ($requrl=~/^\/adm\/wrapper\//) ||
662: ($requrl=~m|^/adm/coursedocs/showdoc/|) ||
663: ($requrl=~m|\.problem/smpedit$|) ||
664: ($requrl=~/^\/public\/.*\/syllabus$/) ||
665: ($requrl=~/^\/adm\/(viewclasslist|navmaps)$/) ||
666: ($requrl=~/^\/adm\/.*\/aboutme\/portfolio(\?|$)/)) {
667: # ------------------------------------- This is serious stuff, get symb and log
668: my $symb;
669: if ($query) {
670: &Apache::loncommon::get_unprocessed_cgi($query,['symb','folderpath']);
671: }
672: if ($env{'form.symb'}) {
673: $symb=&Apache::lonnet::symbclean($env{'form.symb'});
674: if ($requrl =~ m|^/adm/wrapper/|
675: || $requrl =~ m|^/adm/coursedocs/showdoc/|) {
676: my ($map,$mid,$murl)=&Apache::lonnet::decode_symb($symb);
677: &Apache::lonnet::symblist($map,$murl => [$murl,$mid],
678: 'last_known' =>[$murl,$mid]);
679: } elsif ((&Apache::lonnet::symbverify($symb,$requrl)) ||
680: (($requrl=~m|(.*)/smpedit$|) &&
681: &Apache::lonnet::symbverify($symb,$1)) ||
682: (($requrl=~m|(.*/aboutme)/portfolio$|) &&
683: &Apache::lonnet::symbverify($symb,$1))) {
684: my ($map,$mid,$murl)=&Apache::lonnet::decode_symb($symb);
685: &Apache::lonnet::symblist($map,$murl => [$murl,$mid],
686: 'last_known' =>[$murl,$mid]);
687: } else {
688: $r->log_reason('Invalid symb for '.$requrl.': '.
689: $symb);
690: $env{'user.error.msg'}=
691: "$requrl:bre:1:1:Invalid Access";
692: return HTTP_NOT_ACCEPTABLE;
693: }
694: } else {
695: if ($requrl=~m{^(/adm/.*/aboutme)/portfolio$}) {
696: $requrl = $1;
697: }
698: unless ($suppext) {
699: $symb=&Apache::lonnet::symbread($requrl);
700: if (&Apache::lonnet::is_on_map($requrl) && $symb &&
701: !&Apache::lonnet::symbverify($symb,$requrl)) {
702: $r->log_reason('Invalid symb for '.$requrl.': '.$symb);
703: $env{'user.error.msg'}=
704: "$requrl:bre:1:1:Invalid Access";
705: return HTTP_NOT_ACCEPTABLE;
706: }
707: if ($symb) {
708: my ($map,$mid,$murl)=
709: &Apache::lonnet::decode_symb($symb);
710: &Apache::lonnet::symblist($map,$murl =>[$murl,$mid],
711: 'last_known' =>[$murl,$mid]);
712: }
713: }
714: }
715: $env{'request.symb'}=$symb;
716: &Apache::lonnet::courseacclog($symb);
717: } else {
718: # ------------------------------------------------------- This is other content
719: &Apache::lonnet::courseacclog($requrl);
720: }
721: if ($requrl =~ m{^/+uploaded/\Q$cdom\E/\Q$cnum\E/(docs|supplemental)/.+\.html?$}) {
722: if (&Apache::lonnet::allowed('mdc',$env{'request.course.id'})) {
723: if ($query) {
724: &Apache::loncommon::get_unprocessed_cgi($query,['forceedit']);
725: if ($env{'form.forceedit'}) {
726: $env{'request.state'} = 'edit';
727: }
728: }
729: }
730: } elsif ($requrl =~ m{^/+uploaded/\Q$cdom\E/\Q$cnum\E/portfolio/syllabus/.+\.html?$}) {
731: if (&Apache::lonnet::allowed('mdc',$env{'request.course.id'})) {
732: if ($query) {
733: &Apache::loncommon::get_unprocessed_cgi($query,['forceedit','editmode']);
734: if (($env{'form.forceedit'}) || ($env{'form.editmode'})) {
735: $env{'request.state'} = 'edit';
736: }
737: }
738: }
739: }
740: }
741: return OK;
742: } else {
743: my $defdom=$r->dir_config('lonDefDomain');
744: ($is_balancer,$otherserver) =
745: &Apache::lonnet::check_loadbalancing(undef,$defdom);
746: if ($is_balancer) {
747: $r->set_handlers('PerlResponseHandler'=>
748: [\&Apache::switchserver::handler]);
749: if ($otherserver ne '') {
750: $env{'form.otherserver'} = $otherserver;
751: }
752: }
753: }
754: # -------------------------------------------- See if this is a public resource
755: if ($requrl=~m|^/+adm/+help/+|) {
756: return OK;
757: }
758: # ------------------------------------ See if this is a viewable portfolio file
759: if (&Apache::lonnet::is_portfolio_url($requrl)) {
760: my $clientip = $r->get_remote_host();
761: my $access=&Apache::lonnet::allowed('bre',$requrl,undef,undef,$clientip);
762: if ($access eq 'A') {
763: &Apache::restrictedaccess::setup_handler($r);
764: return OK;
765: }
766: if (($access ne '2') && ($access ne 'F')) {
767: $env{'user.error.msg'}="$requrl:bre:1:1:Access Denied";
768: return HTTP_NOT_ACCEPTABLE;
769: }
770: }
771:
772: # -------------------------------------------------------------- Not authorized
773: $requrl=~/\.(\w+)$/;
774: # if ((&Apache::loncommon::fileembstyle($1) eq 'ssi') ||
775: # ($requrl=~/^\/adm\/(roles|logout|email|menu|remote)/) ||
776: # ($requrl=~m|^/prtspool/|)) {
777: # -------------------------- Store where they wanted to go and get login screen
778: $env{'request.querystring'}=$r->args;
779: $env{'request.firsturl'}=$requrl;
780: return FORBIDDEN;
781: # } else {
782: # --------------------------------------------------------------------- Goodbye
783: # return HTTP_BAD_REQUEST;
784: # }
785: }
786:
787: 1;
788: __END__
789:
790: =pod
791:
792: =back
793:
794: =cut
795:
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>
![[BACK]](/icons/back.gif){kind=icon}
Return to lonacc.pm CVS log ![[TXT]](/icons/text.gif){kind=icon}
![[DIR]](/icons/dir.gif){kind=icon}
Up to [LON-CAPA] / loncom / auth