1: # The LearningOnline Network
2: # Cookie Based Access Handler
3: #
4: # $Id: lonacc.pm,v 1.159.2.12 2020/09/30 19:33:59 raeburn Exp $
5: #
6: # Copyright Michigan State University Board of Trustees
7: #
8: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
9: #
10: # LON-CAPA is free software; you can redistribute it and/or modify
11: # it under the terms of the GNU General Public License as published by
12: # the Free Software Foundation; either version 2 of the License, or
13: # (at your option) any later version.
14: #
15: # LON-CAPA is distributed in the hope that it will be useful,
16: # but WITHOUT ANY WARRANTY; without even the implied warranty of
17: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18: # GNU General Public License for more details.
19: #
20: # You should have received a copy of the GNU General Public License
21: # along with LON-CAPA; if not, write to the Free Software
22: # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
23: #
24: # /home/httpd/html/adm/gpl.txt
25: #
26: # http://www.lon-capa.org/
27: #
28: ###
29:
30: =head1 NAME
31:
32: Apache::lonacc - Cookie Based Access Handler
33:
34: =head1 SYNOPSIS
35:
36: Invoked (for various locations) by /etc/httpd/conf/srm.conf:
37:
38: PerlAccessHandler Apache::lonacc
39:
40: =head1 INTRODUCTION
41:
42: This module enables cookie based authentication and is used
43: to control access for many different LON-CAPA URIs.
44:
45: Whenever the client sends the cookie back to the server,
46: this cookie is handled by either lonacc.pm or loncacc.pm
47: (see srm.conf for what is invoked when). If
48: the cookie is missing or invalid, the user is re-challenged
49: for login information.
50:
51: This is part of the LearningOnline Network with CAPA project
52: described at http://www.lon-capa.org.
53:
54: =head1 HANDLER SUBROUTINE
55:
56: This routine is called by Apache and mod_perl.
57:
58: =over 4
59:
60: =item *
61:
62: transfer profile into environment
63:
64: =item *
65:
66: load POST parameters
67:
68: =item *
69:
70: check access
71:
72: =item *
73:
74: if allowed, get symb, log, generate course statistics if applicable
75:
76: =item *
77:
78: otherwise return error
79:
80: =item *
81:
82: see if public resource
83:
84: =item *
85:
86: store attempted access
87:
88: =back
89:
90: =head1 NOTABLE SUBROUTINES
91:
92: =cut
93:
94:
95: package Apache::lonacc;
96:
97: use strict;
98: use Apache::Constants qw(:common :http :methods);
99: use Apache::File;
100: use Apache::lonnet;
101: use Apache::loncommon();
102: use Apache::lonlocal;
103: use Apache::restrictedaccess();
104: use Apache::blockedaccess();
105: use Fcntl qw(:flock);
106: use LONCAPA qw(:DEFAULT :match);
107:
108: sub cleanup {
109: my ($r)=@_;
110: if (! $r->is_initial_req()) { return DECLINED; }
111: &Apache::lonnet::save_cache();
112: return OK;
113: }
114:
115: sub goodbye {
116: my ($r)=@_;
117: &Apache::lonnet::goodbye();
118: return DONE;
119: }
120:
121: ###############################################
122:
123: sub get_posted_cgi {
124: my ($r,$fields) = @_;
125:
126: my $buffer;
127: if ($r->header_in('Content-length')) {
128: $r->read($buffer,$r->header_in('Content-length'),0);
129: }
130: my $content_type = $r->header_in('Content-type');
131: if ($content_type !~ m{^multipart/form-data}) {
132: my @pairs=split(/&/,$buffer);
133: my $pair;
134: foreach $pair (@pairs) {
135: my ($name,$value) = split(/=/,$pair);
136: $value =~ tr/+/ /;
137: $value =~ s/%([a-fA-F0-9][a-fA-F0-9])/pack("C",hex($1))/eg;
138: $name =~ tr/+/ /;
139: $name =~ s/%([a-fA-F0-9][a-fA-F0-9])/pack("C",hex($1))/eg;
140: if (ref($fields) eq 'ARRAY') {
141: next if (!grep(/^\Q$name\E$/,@{$fields}));
142: }
143: &Apache::loncommon::add_to_env("form.$name",$value);
144: }
145: } else {
146: my ($contentsep) = ($content_type =~ /boundary=\"?([^\";,]+)\"?/);
147: my @lines = split (/\n/,$buffer);
148: my $name='';
149: my $value='';
150: my $fname='';
151: my $fmime='';
152: my $i;
153: for ($i=0;$i<=$#lines;$i++) {
154: if ($lines[$i]=~/^--\Q$contentsep\E/) {
155: if ($name) {
156: chomp($value);
157: if (($r->uri eq '/adm/portfolio') &&
158: ($name eq 'uploaddoc')) {
159: if (length($value) == 1) {
160: $value=~s/[\r\n]$//;
161: }
162: } elsif ($fname =~ /\.(xls|doc|ppt)(x|m)$/i) {
163: $value=~s/[\r\n]$//;
164: }
165: if (ref($fields) eq 'ARRAY') {
166: next if (!grep(/^\Q$name\E$/,@{$fields}));
167: }
168: if ($fname) {
169: if ($env{'form.symb'} ne '') {
170: my $size = (length($value))/(1024.0 * 1024.0);
171: if (&upload_size_allowed($name,$size,$fname) eq 'ok') {
172: $env{"form.$name.filename"}=$fname;
173: $env{"form.$name.mimetype"}=$fmime;
174: &Apache::loncommon::add_to_env("form.$name",$value);
175: }
176: } else {
177: $env{"form.$name.filename"}=$fname;
178: $env{"form.$name.mimetype"}=$fmime;
179: &Apache::loncommon::add_to_env("form.$name",$value);
180: }
181: } else {
182: $value=~s/\s+$//s;
183: &Apache::loncommon::add_to_env("form.$name",$value);
184: }
185: }
186: if ($i<$#lines) {
187: $i++;
188: $lines[$i]=~
189: /Content\-Disposition\:\s*form\-data\;\s*name\=\"([^\"]+)\"/i;
190: $name=$1;
191: $value='';
192: if ($lines[$i]=~/filename\=\"([^\"]+)\"/i) {
193: $fname=$1;
194: if
195: ($lines[$i+1]=~/Content\-Type\:\s*([\w\-\/]+)/i) {
196: $fmime=$1;
197: $i++;
198: } else {
199: $fmime='';
200: }
201: } else {
202: $fname='';
203: $fmime='';
204: }
205: $i++;
206: }
207: } else {
208: $value.=$lines[$i]."\n";
209: }
210: }
211: }
212: #
213: # Digested POSTed values
214: #
215: # Remember the way this was originally done (GET or POST)
216: #
217: $env{'request.method'}=$ENV{'REQUEST_METHOD'};
218: #
219: # There may also be stuff in the query string
220: # Tell subsequent handlers that this was GET, not POST, so they can access query string.
221: # Also, unset POSTed content length to cover all tracks.
222: #
223:
224: $r->method_number(M_GET);
225:
226: $r->method('GET');
227: $r->headers_in->unset('Content-length');
228: }
229:
230: =pod
231:
232: =over
233:
234: =item upload_size_allowed()
235:
236: Perform size checks for file uploads to essayresponse items in course context.
237:
238: Add form.HWFILESIZE.$part_$id to %env with file size (MB)
239: If file exceeds maximum allowed size, add form.HWFILETOOBIG.$part_$id to %env.
240:
241: =cut
242:
243: sub upload_size_allowed {
244: my ($name,$size,$fname) = @_;
245: if ($name =~ /^HWFILE(\w+)$/) {
246: my $ident = $1;
247: my $item = 'HWFILESIZE'.$ident;
248: my $savesize = sprintf("%.6f",$size);
249: &Apache::loncommon::add_to_env("form.$item",$savesize);
250: my $maxsize= &Apache::lonnet::EXT("resource.$ident.maxfilesize");
251: if (!$maxsize) {
252: $maxsize = 10.0; # FIXME This should become a domain configuration.
253: }
254: if ($size > $maxsize) {
255: my $warn = 'HWFILETOOBIG'.$ident;
256: &Apache::loncommon::add_to_env("form.$warn",$fname);
257: return;
258: }
259: }
260: return 'ok';
261: }
262:
263: =pod
264:
265: =item sso_login()
266:
267: handle the case of the single sign on user, at this point $r->user
268: will be set and valid; now need to find the loncapa user info, and possibly
269: balance them. If $r->user() is set this means either it was either set by
270: SSO or by checkauthen.pm, if a valid cookie was found. The latter case can
271: be identified by the third arg ($usename), except when lonacc is called in
272: an internal redirect to /adm/switchserver (e.g., load-balancing following
273: successful authentication) -- no cookie set yet. For that particular case
274: simply skip the call to sso_login().
275:
276: returns OK if it was SSO and user was handled.
277: returns undef if not SSO or no means to handle the user.
278:
279: =cut
280:
281: sub sso_login {
282: my ($r,$handle,$username) = @_;
283:
284: if (($r->user eq '') || ($username ne '') || ($r->user eq 'public:public') ||
285: (defined($env{'user.name'}) && (defined($env{'user.domain'}))
286: && ($handle ne ''))) {
287: # not an SSO case or already logged in
288: return undef;
289: }
290:
291: my ($user) = ($r->user =~ m/^($match_username)$/);
292: if ($user eq '') {
293: return undef;
294: }
295:
296: my $query = $r->args;
297: my %form;
298: if ($query) {
299: my @items = ('role','symb','iptoken');
300: &Apache::loncommon::get_unprocessed_cgi($query,\@items);
301: foreach my $item (@items) {
302: if (defined($env{'form.'.$item})) {
303: $form{$item} = $env{'form.'.$item};
304: }
305: }
306: }
307:
308: my %sessiondata;
309: if ($form{'iptoken'}) {
310: %sessiondata = &Apache::lonnet::tmpget($form{'iptoken'});
311: my $delete = &Apache::lonnet::tmpdel($form{'iptoken'});
312: unless ($sessiondata{'sessionserver'}) {
313: delete($form{'iptoken'});
314: }
315: }
316:
317: my $domain = $r->dir_config('lonSSOUserDomain');
318: if ($domain eq '') {
319: $domain = $r->dir_config('lonDefDomain');
320: }
321: my $home=&Apache::lonnet::homeserver($user,$domain);
322: if ($home !~ /(con_lost|no_host|no_such_host)/) {
323: &Apache::lonnet::logthis(" SSO authorized user $user ");
324: my ($is_balancer,$otherserver,$hosthere);
325: if ($form{'iptoken'}) {
326: if (($sessiondata{'domain'} eq $domain) &&
327: ($sessiondata{'username'} eq $user)) {
328: $hosthere = 1;
329: }
330: }
331: unless ($hosthere) {
332: ($is_balancer,$otherserver) =
333: &Apache::lonnet::check_loadbalancing($user,$domain,'login');
334: if ($is_balancer) {
335: # Check if browser sent a LON-CAPA load balancer cookie (and this is a balancer)
336: my ($found_server,$balancer_cookie) = &Apache::lonnet::check_for_balancer_cookie($r);
337: if (($found_server) && ($balancer_cookie =~ /^\Q$domain\E_\Q$user\E_/)) {
338: $otherserver = $found_server;
339: } elsif ($otherserver eq '') {
340: my $lowest_load;
341: ($otherserver,undef,undef,undef,$lowest_load) = &Apache::lonnet::choose_server($domain);
342: if ($lowest_load > 100) {
343: $otherserver = &Apache::lonnet::spareserver($lowest_load,$lowest_load,1,$domain);
344: }
345: if ($otherserver ne '') {
346: my @hosts = &Apache::lonnet::current_machine_ids();
347: if (grep(/^\Q$otherserver\E$/,@hosts)) {
348: $hosthere = $otherserver;
349: }
350: }
351: }
352: }
353: }
354: if (($is_balancer) && (!$hosthere)) {
355: # login but immediately go to switch server to find us a new
356: # machine
357: &Apache::lonauth::success($r,$user,$domain,$home,'noredirect');
358: $env{'request.sso.login'} = 1;
359: if (defined($r->dir_config("lonSSOReloginServer"))) {
360: $env{'request.sso.reloginserver'} =
361: $r->dir_config('lonSSOReloginServer');
362: }
363: my $redirecturl = '/adm/switchserver';
364: if ($otherserver ne '') {
365: $redirecturl .= '?otherserver='.$otherserver;
366: }
367: $r->internal_redirect($redirecturl);
368: $r->set_handlers('PerlHandler'=> undef);
369: } else {
370: # need to login them in, so generate the need data that
371: # migrate expects to do login
372: my $ip = $r->get_remote_host();
373: my %info=('ip' => $ip,
374: 'domain' => $domain,
375: 'username' => $user,
376: 'server' => $r->dir_config('lonHostID'),
377: 'sso.login' => 1
378: );
379: foreach my $item ('role','symb','iptoken') {
380: if (exists($form{$item})) {
381: $info{$item} = $form{$item};
382: }
383: }
384: unless ($info{'symb'}) {
385: unless (($r->uri eq '/adm/roles') || ($r->uri eq '/adm/sso')) {
386: $info{'origurl'} = $r->uri;
387: }
388: }
389: if ($r->dir_config("ssodirecturl") == 1) {
390: $info{'origurl'} = $r->uri;
391: }
392: if (defined($r->dir_config("lonSSOReloginServer"))) {
393: $info{'sso.reloginserver'} =
394: $r->dir_config('lonSSOReloginServer');
395: }
396: if (($is_balancer) && ($hosthere)) {
397: $info{'noloadbalance'} = $hosthere;
398: }
399: my $token =
400: &Apache::lonnet::tmpput(\%info,
401: $r->dir_config('lonHostID'));
402: $env{'form.token'} = $token;
403: $r->internal_redirect('/adm/migrateuser');
404: $r->set_handlers('PerlHandler'=> undef);
405: }
406: return OK;
407: } else {
408: &Apache::lonnet::logthis(" SSO authorized unknown user $user ");
409: my @cancreate;
410: my %domconfig =
411: &Apache::lonnet::get_dom('configuration',['usercreation'],$domain);
412: if (ref($domconfig{'usercreation'}) eq 'HASH') {
413: if (ref($domconfig{'usercreation'}{'cancreate'}) eq 'HASH') {
414: if (ref($domconfig{'usercreation'}{'cancreate'}{'selfcreate'}) eq 'ARRAY') {
415: @cancreate = @{$domconfig{'usercreation'}{'cancreate'}{'selfcreate'}};
416: } elsif (($domconfig{'usercreation'}{'cancreate'}{'selfcreate'} ne 'none') &&
417: ($domconfig{'usercreation'}{'cancreate'}{'selfcreate'} ne '')) {
418: @cancreate = ($domconfig{'usercreation'}{'cancreate'}{'selfcreate'});
419: }
420: }
421: }
422: if ((grep(/^sso$/,@cancreate)) || (defined($r->dir_config('lonSSOUserUnknownRedirect')))) {
423: $r->subprocess_env->set('SSOUserUnknown' => $user);
424: $r->subprocess_env->set('SSOUserDomain' => $domain);
425: if (grep(/^sso$/,@cancreate)) {
426: $r->set_handlers('PerlHandler'=> [\&Apache::createaccount::handler]);
427: $r->handler('perl-script');
428: } else {
429: $r->internal_redirect($r->dir_config('lonSSOUserUnknownRedirect'));
430: $r->set_handlers('PerlHandler'=> undef);
431: }
432: return OK;
433: }
434: }
435: return undef;
436: }
437:
438: sub handler {
439: my $r = shift;
440: my $requrl=$r->uri;
441:
442: if ($requrl =~ m{^/res/adm/pages/[^/]+\.(gif|png)$}) {
443: return OK;
444: }
445:
446: if (&Apache::lonnet::is_domainimage($requrl)) {
447: return OK;
448: }
449:
450: my %user;
451: my $handle = &Apache::lonnet::check_for_valid_session($r,undef,\%user);
452:
453: unless (($requrl eq '/adm/switchserver') && (!$r->is_initial_req())) {
454: my $result = &sso_login($r,$handle,$user{'name'});
455: if (defined($result)) {
456: return $result;
457: }
458: }
459:
460: my ($is_balancer,$otherserver);
461:
462: if ($handle eq '') {
463: unless ((($requrl eq '/adm/switchserver') && (!$r->is_initial_req())) ||
464: ($requrl =~ m{^/public/$match_domain/$match_courseid/syllabus}) ||
465: ($requrl =~ m{^/adm/help/}) ||
466: ($requrl =~ m{^/res/$match_domain/$match_username/})) {
467: $r->log_reason("Cookie not valid", $r->filename);
468: }
469: } elsif ($handle ne '') {
470:
471: # ------------------------------------------------------ Initialize Environment
472: my $lonidsdir=$r->dir_config('lonIDsDir');
473: &Apache::lonnet::transfer_profile_to_env($lonidsdir,$handle);
474:
475: # --------------------------------------------------------- Initialize Language
476:
477: &Apache::lonlocal::get_language_handle($r);
478:
479: }
480:
481: # -------------------------------------------------- Should be a valid user now
482: if ($env{'user.name'} ne '' && $env{'user.domain'} ne '') {
483: # -------------------------------------------------------------- Resource State
484:
485: my ($cdom,$cnum);
486: if ($env{'request.course.id'}) {
487: $cdom = $env{'course.'.$env{'request.course.id'}.'.domain'};
488: $cnum = $env{'course.'.$env{'request.course.id'}.'.num'};
489: }
490: if ($requrl=~/^\/+(res|uploaded)\//) {
491: $env{'request.state'} = "published";
492: } else {
493: $env{'request.state'} = 'unknown';
494: }
495: $env{'request.filename'} = $r->filename;
496: $env{'request.noversionuri'} = &Apache::lonnet::deversion($requrl);
497: my ($suppext,$checkabsolute);
498: if ($requrl =~ m{^/adm/wrapper/ext/}) {
499: my $query = $r->args;
500: if ($query) {
501: my $preserved;
502: foreach my $pair (split(/&/,$query)) {
503: my ($name, $value) = split(/=/,$pair);
504: unless (($name eq 'symb') || ($name eq 'usehttp')) {
505: $preserved .= $pair.'&';
506: }
507: if (($env{'request.course.id'}) && ($name eq 'folderpath')) {
508: if ($value =~ /^supplemental/) {
509: $suppext = 1;
510: }
511: }
512: }
513: $preserved =~ s/\&$//;
514: if ($preserved) {
515: $env{'request.external.querystring'} = $preserved;
516: }
517: }
518: if ($env{'request.course.id'}) {
519: $checkabsolute = 1;
520: }
521: } elsif ($env{'request.course.id'} &&
522: (($requrl =~ m{^/adm/$match_domain/$match_username/aboutme$}) ||
523: ($requrl =~ m{^/public/$cdom/$cnum/syllabus$}))) {
524: my $query = $r->args;
525: if ($query) {
526: foreach my $pair (split(/&/,$query)) {
527: my ($name, $value) = split(/=/,$pair);
528: if ($name eq 'folderpath') {
529: if ($value =~ /^supplemental/) {
530: $suppext = 1;
531: }
532: last;
533: }
534: }
535: }
536: if ($requrl =~ m{^/public/$cdom/$cnum/syllabus$}) {
537: $checkabsolute = 1;
538: }
539: }
540: if ($checkabsolute) {
541: my $hostname = $r->hostname();
542: my $lonhost = &Apache::lonnet::host_from_dns($hostname);
543: if ($lonhost) {
544: my $actual = &Apache::lonnet::absolute_url($hostname);
545: my $expected = $Apache::lonnet::protocol{$lonhost}.'://'.$hostname;
546: unless ($actual eq $expected) {
547: $env{'request.use_absolute'} = $expected;
548: }
549: }
550: }
551: # -------------------------------------------------------- Load POST parameters
552:
553: &Apache::lonacc::get_posted_cgi($r);
554:
555: # ------------------------------------------------------ Check if load balancer
556:
557: my $checkexempt;
558: if ($env{'user.loadbalexempt'} eq $r->dir_config('lonHostID')) {
559: if ($env{'user.loadbalcheck.time'} + 600 > time) {
560: $checkexempt = 1;
561: }
562: }
563: if ($env{'user.noloadbalance'} eq $r->dir_config('lonHostID')) {
564: $checkexempt = 1;
565: }
566: unless ($checkexempt) {
567: ($is_balancer,$otherserver) =
568: &Apache::lonnet::check_loadbalancing($env{'user.name'},
569: $env{'user.domain'});
570: if ($is_balancer) {
571: unless (($requrl eq '/adm/switchserver') && (!$r->is_initial_req())) {
572: # Check if browser sent a LON-CAPA load balancer cookie (and this is a balancer)
573: my ($found_server,$balancer_cookie) = &Apache::lonnet::check_for_balancer_cookie($r);
574: if (($found_server) && ($balancer_cookie =~ /^\Q$env{'user.domain'}\E_\Q$env{'user.name'}\E_/)) {
575: $otherserver = $found_server;
576: }
577: }
578: }
579: }
580: if ($is_balancer) {
581: unless (($requrl eq '/adm/switchserver') && (!$r->is_initial_req())) {
582: $r->set_handlers('PerlResponseHandler'=>
583: [\&Apache::switchserver::handler]);
584: if ($otherserver ne '') {
585: $env{'form.otherserver'} = $otherserver;
586: }
587: }
588: unless (($env{'form.origurl'}) || ($r->uri eq '/adm/roles') ||
589: ($r->uri eq '/adm/switchserver') || ($r->uri eq '/adm/sso')) {
590: $env{'form.origurl'} = $r->uri;
591: }
592: }
593:
594: # ---------------------------------------------------------------- Check access
595: my $now = time;
596: my $check_symb;
597: if ($requrl !~ m{^/(?:adm|public|(?:prt|zip)spool)/}
598: || $requrl =~ /^\/adm\/.*\/(smppg|bulletinboard)(\?|$ )/x) {
599: my ($access,$poss_symb);
600: if (($env{'request.course.id'}) && (!$suppext)) {
601: $requrl=~/\.(\w+)$/;
602: if ((&Apache::loncommon::fileembstyle($1) eq 'ssi') ||
603: ($requrl=~/^\/adm\/.*\/(aboutme|smppg|bulletinboard)(\?|$ )/x) ||
604: ($requrl=~/^\/adm\/wrapper\//) ||
605: ($requrl=~m|^/adm/coursedocs/showdoc/|) ||
606: ($requrl=~m|\.problem/smpedit$|) ||
607: ($requrl=~/^\/public\/.*\/syllabus$/) ||
608: ($requrl=~/^\/adm\/(viewclasslist|navmaps)$/) ||
609: ($requrl=~/^\/adm\/.*\/aboutme\/portfolio(\?|$)/)) {
610: $check_symb = 1;
611: }
612: }
613: if ($check_symb) {
614: if ($env{'form.symb'}) {
615: $poss_symb=&Apache::lonnet::symbclean($env{'form.symb'});
616: } elsif (($env{'request.course.id'}) && ($r->args ne '')) {
617: my $query = $r->args;
618: foreach my $pair (split(/&/,$query)) {
619: my ($name, $value) = split(/=/,$pair);
620: if ($name eq 'symb') {
621: $poss_symb = &Apache::lonnet::symbclean($value);
622: last;
623: }
624: }
625: }
626: if ($poss_symb) {
627: my ($possmap,$resid,$url)=&Apache::lonnet::decode_symb($poss_symb);
628: $url = &Apache::lonnet::clutter($url);
629: unless (($url eq $requrl) && (&Apache::lonnet::is_on_map($possmap))) {
630: undef($poss_symb);
631: }
632: if ($poss_symb) {
633: if ((!$env{'request.role.adv'}) && ($env{'acc.randomout'}) &&
634: ($env{'acc.randomout'}=~/\&\Q$poss_symb\E\&/)) {
635: undef($poss_symb);
636: }
637: }
638: }
639: if ($poss_symb) {
640: $access=&Apache::lonnet::allowed('bre',$requrl,$poss_symb);
641: } else {
642: $access=&Apache::lonnet::allowed('bre',$requrl,'','','','',1);
643: }
644: } else {
645: $access=&Apache::lonnet::allowed('bre',$requrl);
646: }
647: if ($handle eq '') {
648: unless ($access eq 'F') {
649: if ($requrl =~ m{^/res/$match_domain/$match_username/}) {
650: $r->log_reason("Cookie not valid", $r->filename);
651: }
652: }
653: }
654: if ($access eq '1') {
655: $env{'user.error.msg'}="$requrl:bre:0:0:Choose Course";
656: return HTTP_NOT_ACCEPTABLE;
657: }
658: if ($access eq 'A') {
659: &Apache::restrictedaccess::setup_handler($r);
660: return OK;
661: }
662: if ($access eq 'B') {
663: if ($poss_symb) {
664: if ($requrl=~m{^(/adm/.*/aboutme)/portfolio$}) {
665: $requrl = $1;
666: }
667: if (&Apache::lonnet::symbverify($poss_symb,$requrl)) {
668: $env{'request.symb'} = $poss_symb;
669: }
670: }
671: &Apache::blockedaccess::setup_handler($r);
672: return OK;
673: }
674: if (($access ne '2') && ($access ne 'F')) {
675: if ($requrl =~ m{^/res/}) {
676: $access = &Apache::lonnet::allowed('bro',$requrl);
677: if ($access ne 'F') {
678: if ($requrl eq '/res/lib/templates/simpleproblem.problem/smpedit') {
679: $access = &Apache::lonnet::allowed('bre','/res/lib/templates/simpleproblem.problem');
680: if ($access ne 'F') {
681: $env{'user.error.msg'}="$requrl:bre:1:1:Access Denied";
682: return HTTP_NOT_ACCEPTABLE;
683: }
684: } else {
685: $env{'user.error.msg'}="$requrl:bre:1:1:Access Denied";
686: return HTTP_NOT_ACCEPTABLE;
687: }
688: }
689: } elsif (($handle =~ /^publicuser_\d+$/) && (&Apache::lonnet::is_portfolio_url($requrl))) {
690: my $clientip = $r->get_remote_host();
691: if (&Apache::lonnet::allowed('bre',$requrl,undef,undef,$clientip) ne 'F') {
692: $env{'user.error.msg'}="$requrl:bre:1:1:Access Denied";
693: return HTTP_NOT_ACCEPTABLE;
694: }
695: } else {
696: $env{'user.error.msg'}="$requrl:bre:1:1:Access Denied";
697: return HTTP_NOT_ACCEPTABLE;
698: }
699: }
700: }
701: if ($requrl =~ m|^/prtspool/|) {
702: my $start='/prtspool/'.$env{'user.name'}.'_'.
703: $env{'user.domain'};
704: if ($requrl !~ /^\Q$start\E/) {
705: $env{'user.error.msg'}="$requrl:bre:1:1:Access Denied";
706: return HTTP_NOT_ACCEPTABLE;
707: }
708: }
709: if ($requrl =~ m|^/zipspool/|) {
710: my $start='/zipspool/zipout/'.$env{'user.name'}.":".
711: $env{'user.domain'};
712: if ($requrl !~ /^\Q$start\E/) {
713: $env{'user.error.msg'}="$requrl:bre:1:1:Access Denied";
714: return HTTP_NOT_ACCEPTABLE;
715: }
716: }
717: if ($env{'user.name'} eq 'public' &&
718: $env{'user.domain'} eq 'public' &&
719: $requrl !~ m{^/+(res|public|uploaded)/} &&
720: $requrl !~ m{^/adm/[^/]+/[^/]+/aboutme/portfolio$ }x &&
721: $requrl !~ m{^/adm/blockingstatus/.*$} &&
722: $requrl !~ m{^/+adm/(help|logout|restrictedaccess|randomlabel\.png)}) {
723: $env{'request.querystring'}=$r->args;
724: $env{'request.firsturl'}=$requrl;
725: return FORBIDDEN;
726: }
727: # ------------------------------------------------------------- This is allowed
728: if ($env{'request.course.id'}) {
729: &Apache::lonnet::countacc($requrl);
730: my $query=$r->args;
731: if ($check_symb) {
732: # ------------------------------------- This is serious stuff, get symb and log
733: my $symb;
734: if ($query) {
735: &Apache::loncommon::get_unprocessed_cgi($query,['symb','folderpath']);
736: }
737: if ($env{'form.symb'}) {
738: $symb=&Apache::lonnet::symbclean($env{'form.symb'});
739: if ($requrl eq '/adm/navmaps') {
740: my ($map,$mid,$murl)=&Apache::lonnet::decode_symb($symb);
741: &Apache::lonnet::symblist($map,$murl => [$murl,$mid]);
742: } elsif ($requrl =~ m|^/adm/wrapper/|
743: || $requrl =~ m|^/adm/coursedocs/showdoc/|) {
744: my ($map,$mid,$murl)=&Apache::lonnet::decode_symb($symb);
745: if ($map =~ /\.page$/) {
746: my $mapsymb = &Apache::lonnet::symbread($map);
747: ($map,$mid,$murl)=&Apache::lonnet::decode_symb($mapsymb);
748: }
749: &Apache::lonnet::symblist($map,$murl => [$murl,$mid],
750: 'last_known' =>[$murl,$mid]);
751: } elsif ((&Apache::lonnet::symbverify($symb,$requrl)) ||
752: (($requrl=~m|(.*)/smpedit$|) &&
753: &Apache::lonnet::symbverify($symb,$1)) ||
754: (($requrl=~m|(.*/aboutme)/portfolio$|) &&
755: &Apache::lonnet::symbverify($symb,$1))) {
756: my ($map,$mid,$murl)=&Apache::lonnet::decode_symb($symb);
757: if (($map =~ /\.page$/) && ($requrl !~ /\.page$/)) {
758: my $mapsymb = &Apache::lonnet::symbread($map);
759: ($map,$mid,$murl)=&Apache::lonnet::decode_symb($mapsymb);
760: }
761: &Apache::lonnet::symblist($map,$murl => [$murl,$mid],
762: 'last_known' =>[$murl,$mid]);
763: } else {
764: $r->log_reason('Invalid symb for '.$requrl.': '.
765: $symb);
766: $env{'user.error.msg'}=
767: "$requrl:bre:1:1:Invalid Access";
768: return HTTP_NOT_ACCEPTABLE;
769: }
770: } else {
771: if ($requrl=~m{^(/adm/.*/aboutme)/portfolio$}) {
772: $requrl = $1;
773: }
774: $symb=&Apache::lonnet::symbread($requrl);
775: if (&Apache::lonnet::is_on_map($requrl) && $symb) {
776: my ($encstate,$invalidsymb);
777: unless (&Apache::lonnet::symbverify($symb,$requrl,\$encstate)) {
778: $invalidsymb = 1;
779: #
780: # If $env{'request.enc'} is true, but no encryption for $symb retrieved
781: # by original lonnet::symbread() call, call again to check for an instance
782: # of $requrl in the course which has encryption, and set that as the symb.
783: # If there is no such symb, or symbverify() fails for the new symb proceed
784: # to report invalid symb.
785: #
786: if ($env{'request.enc'} && !$encstate) {
787: my %possibles;
788: my $nocache = 1;
789: $symb = &Apache::lonnet::symbread($requrl,'','','',\%possibles,$nocache);
790: if ($symb) {
791: if (&Apache::lonnet::symbverify($symb,$requrl)) {
792: $invalidsymb = '';
793: }
794: } elsif (keys(%possibles) > 1) {
795: $r->internal_redirect('/adm/ambiguous');
796: return OK;
797: }
798: }
799: if ($invalidsymb) {
800: $r->log_reason('Invalid symb for '.$requrl.': '.$symb);
801: $env{'user.error.msg'}=
802: "$requrl:bre:1:1:Invalid Access";
803: return HTTP_NOT_ACCEPTABLE;
804: }
805: }
806: }
807: if ($symb) {
808: my ($map,$mid,$murl)=
809: &Apache::lonnet::decode_symb($symb);
810: if ($requrl eq '/adm/navmaps') {
811: &Apache::lonnet::symblist($map,$murl =>[$murl,$mid]);
812: } else {
813: if (($map =~ /\.page$/) && ($requrl !~ /\.page$/)) {
814: my $mapsymb = &Apache::lonnet::symbread($map);
815: ($map,$mid,$murl)=&Apache::lonnet::decode_symb($mapsymb);
816: }
817: &Apache::lonnet::symblist($map,$murl =>[$murl,$mid],
818: 'last_known' =>[$murl,$mid]);
819: }
820: }
821: }
822: $env{'request.symb'}=$symb;
823: if (($env{'request.symbread.cached.'}) && ($env{'request.symbread.cached.'} ne $symb)) {
824: $env{'request.symbread.cached.'} = $symb;
825: }
826: &Apache::lonnet::courseacclog($symb);
827: } else {
828: # ------------------------------------------------------- This is other content
829: &Apache::lonnet::courseacclog($requrl);
830: }
831: if ($requrl =~ m{^/+uploaded/\Q$cdom\E/\Q$cnum\E/(docs|supplemental)/.+\.html?$}) {
832: if (&Apache::lonnet::allowed('mdc',$env{'request.course.id'})) {
833: if ($query) {
834: &Apache::loncommon::get_unprocessed_cgi($query,['forceedit']);
835: if ($env{'form.forceedit'}) {
836: $env{'request.state'} = 'edit';
837: }
838: }
839: }
840: } elsif ($requrl =~ m{^/+uploaded/\Q$cdom\E/\Q$cnum\E/portfolio/syllabus/.+\.html?$}) {
841: if (&Apache::lonnet::allowed('mdc',$env{'request.course.id'})) {
842: if ($query) {
843: &Apache::loncommon::get_unprocessed_cgi($query,['forceedit','editmode']);
844: if (($env{'form.forceedit'}) || ($env{'form.editmode'})) {
845: $env{'request.state'} = 'edit';
846: }
847: }
848: }
849: }
850: }
851: return OK;
852: } else {
853: my $defdom=$r->dir_config('lonDefDomain');
854: ($is_balancer,$otherserver) =
855: &Apache::lonnet::check_loadbalancing(undef,$defdom);
856: if ($is_balancer) {
857: $r->set_handlers('PerlResponseHandler'=>
858: [\&Apache::switchserver::handler]);
859: if ($otherserver ne '') {
860: $env{'form.otherserver'} = $otherserver;
861: }
862: }
863: }
864: # -------------------------------------------- See if this is a public resource
865: if ($requrl=~m|^/+adm/+help/+|) {
866: return OK;
867: }
868: # ------------------------------------ See if this is a viewable portfolio file
869: if (&Apache::lonnet::is_portfolio_url($requrl)) {
870: my $clientip = $r->get_remote_host();
871: my $access=&Apache::lonnet::allowed('bre',$requrl,undef,undef,$clientip);
872: if ($access eq 'A') {
873: &Apache::restrictedaccess::setup_handler($r);
874: return OK;
875: }
876: if (($access ne '2') && ($access ne 'F')) {
877: $env{'user.error.msg'}="$requrl:bre:1:1:Access Denied";
878: return HTTP_NOT_ACCEPTABLE;
879: }
880: }
881:
882: # -------------------------------------------------------------- Not authorized
883: $requrl=~/\.(\w+)$/;
884: # if ((&Apache::loncommon::fileembstyle($1) eq 'ssi') ||
885: # ($requrl=~/^\/adm\/(roles|logout|email|menu|remote)/) ||
886: # ($requrl=~m|^/prtspool/|)) {
887: # -------------------------- Store where they wanted to go and get login screen
888: $env{'request.querystring'}=$r->args;
889: $env{'request.firsturl'}=$requrl;
890: return FORBIDDEN;
891: # } else {
892: # --------------------------------------------------------------------- Goodbye
893: # return HTTP_BAD_REQUEST;
894: # }
895: }
896:
897: 1;
898: __END__
899:
900: =pod
901:
902: =back
903:
904: =cut
905:
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>