1: # The LearningOnline Network
2: # Cookie Based Access Handler
3: #
4: # $Id: lonacc.pm,v 1.126 2009/07/23 17:40:29 raeburn Exp $
5: #
6: # Copyright Michigan State University Board of Trustees
7: #
8: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
9: #
10: # LON-CAPA is free software; you can redistribute it and/or modify
11: # it under the terms of the GNU General Public License as published by
12: # the Free Software Foundation; either version 2 of the License, or
13: # (at your option) any later version.
14: #
15: # LON-CAPA is distributed in the hope that it will be useful,
16: # but WITHOUT ANY WARRANTY; without even the implied warranty of
17: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18: # GNU General Public License for more details.
19: #
20: # You should have received a copy of the GNU General Public License
21: # along with LON-CAPA; if not, write to the Free Software
22: # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
23: #
24: # /home/httpd/html/adm/gpl.txt
25: #
26: # http://www.lon-capa.org/
27: #
28: ###
29:
30: =head1 NAME
31:
32: Apache::lonacc - Cookie Based Access Handler
33:
34: =head1 SYNOPSIS
35:
36: Invoked (for various locations) by /etc/httpd/conf/srm.conf:
37:
38: PerlAccessHandler Apache::lonacc
39:
40: =head1 INTRODUCTION
41:
42: This module enables cookie based authentication and is used
43: to control access for many different LON-CAPA URIs.
44:
45: Whenever the client sends the cookie back to the server,
46: this cookie is handled by either lonacc.pm or loncacc.pm
47: (see srm.conf for what is invoked when). If
48: the cookie is missing or invalid, the user is re-challenged
49: for login information.
50:
51: This is part of the LearningOnline Network with CAPA project
52: described at http://www.lon-capa.org.
53:
54: =head1 HANDLER SUBROUTINE
55:
56: This routine is called by Apache and mod_perl.
57:
58: =over 4
59:
60: =item *
61:
62: transfer profile into environment
63:
64: =item *
65:
66: load POST parameters
67:
68: =item *
69:
70: check access
71:
72: =item *
73:
74: if allowed, get symb, log, generate course statistics if applicable
75:
76: =item *
77:
78: otherwise return error
79:
80: =item *
81:
82: see if public resource
83:
84: =item *
85:
86: store attempted access
87:
88: =back
89:
90: =head1 NOTABLE SUBROUTINES
91:
92: =over
93:
94: =cut
95:
96:
97: package Apache::lonacc;
98:
99: use strict;
100: use Apache::Constants qw(:common :http :methods);
101: use Apache::File;
102: use Apache::lonnet;
103: use Apache::loncommon();
104: use Apache::lonlocal;
105: use Apache::restrictedaccess();
106: use Apache::blockedaccess();
107: use Fcntl qw(:flock);
108: use LONCAPA;
109:
110: sub cleanup {
111: my ($r)=@_;
112: if (! $r->is_initial_req()) { return DECLINED; }
113: &Apache::lonnet::save_cache();
114: &Apache::lontexconvert::jsMath_reset();
115: return OK;
116: }
117:
118: sub goodbye {
119: my ($r)=@_;
120: &Apache::lonnet::goodbye();
121: return DONE;
122: }
123:
124: ###############################################
125:
126: sub get_posted_cgi {
127: my ($r,$fields) = @_;
128:
129: my $buffer;
130: if ($r->header_in('Content-length')) {
131: $r->read($buffer,$r->header_in('Content-length'),0);
132: }
133: my $content_type = $r->header_in('Content-type');
134: if ($content_type !~ m{^multipart/form-data}) {
135: my @pairs=split(/&/,$buffer);
136: my $pair;
137: foreach $pair (@pairs) {
138: my ($name,$value) = split(/=/,$pair);
139: $value =~ tr/+/ /;
140: $value =~ s/%([a-fA-F0-9][a-fA-F0-9])/pack("C",hex($1))/eg;
141: $name =~ tr/+/ /;
142: $name =~ s/%([a-fA-F0-9][a-fA-F0-9])/pack("C",hex($1))/eg;
143: if (ref($fields) eq 'ARRAY') {
144: next if (!grep(/^\Q$name\E$/,@{$fields}));
145: }
146: &Apache::loncommon::add_to_env("form.$name",$value);
147: }
148: } else {
149: my ($contentsep) = ($content_type =~ /boundary=\"?([^\";,]+)\"?/);
150: my @lines = split (/\n/,$buffer);
151: my $name='';
152: my $value='';
153: my $fname='';
154: my $fmime='';
155: my $i;
156: for ($i=0;$i<=$#lines;$i++) {
157: if ($lines[$i]=~/^--\Q$contentsep\E/) {
158: if ($name) {
159: chomp($value);
160: if (ref($fields) eq 'ARRAY') {
161: next if (!grep(/^\Q$name\E$/,@{$fields}));
162: }
163: if ($fname) {
164: if ($env{'form.symb'} ne '') {
165: my $size = (length($value))/(1024.0 * 1024.0);
166: if (&upload_size_allowed($name,$size,$fname) eq 'ok') {
167: $env{"form.$name.filename"}=$fname;
168: $env{"form.$name.mimetype"}=$fmime;
169: &Apache::loncommon::add_to_env("form.$name",$value);
170: }
171: } else {
172: $env{"form.$name.filename"}=$fname;
173: $env{"form.$name.mimetype"}=$fmime;
174: &Apache::loncommon::add_to_env("form.$name",$value);
175: }
176: } else {
177: $value=~s/\s+$//s;
178: &Apache::loncommon::add_to_env("form.$name",$value);
179: }
180: }
181: if ($i<$#lines) {
182: $i++;
183: $lines[$i]=~
184: /Content\-Disposition\:\s*form\-data\;\s*name\=\"([^\"]+)\"/i;
185: $name=$1;
186: $value='';
187: if ($lines[$i]=~/filename\=\"([^\"]+)\"/i) {
188: $fname=$1;
189: if
190: ($lines[$i+1]=~/Content\-Type\:\s*([\w\-\/]+)/i) {
191: $fmime=$1;
192: $i++;
193: } else {
194: $fmime='';
195: }
196: } else {
197: $fname='';
198: $fmime='';
199: }
200: $i++;
201: }
202: } else {
203: $value.=$lines[$i]."\n";
204: }
205: }
206: }
207: #
208: # Digested POSTed values
209: #
210: # Remember the way this was originally done (GET or POST)
211: #
212: $env{'request.method'}=$ENV{'REQUEST_METHOD'};
213: #
214: # There may also be stuff in the query string
215: # Tell subsequent handlers that this was GET, not POST, so they can access query string.
216: # Also, unset POSTed content length to cover all tracks.
217: #
218:
219: $r->method_number(M_GET);
220:
221: $r->method('GET');
222: $r->headers_in->unset('Content-length');
223: }
224:
225: =pod
226:
227: =item upload_size_allowed()
228:
229: Perform size checks for file uploads to essayresponse items in course context.
230:
231: Add form.HWFILESIZE.$part_$id to %env with file size (MB)
232: If file exceeds maximum allowed size, add form.HWFILETOOBIG.$part_$id to %env.
233:
234: =cut
235:
236: sub upload_size_allowed {
237: my ($name,$size,$fname) = @_;
238: if ($name =~ /^HWFILE(\w+)$/) {
239: my $ident = $1;
240: my $item = 'HWFILESIZE'.$ident;
241: my $savesize = sprintf("%.6f",$size);
242: &Apache::loncommon::add_to_env("form.$item",$savesize);
243: my $maxsize= &Apache::lonnet::EXT("resource.$ident.maxfilesize");
244: if (!$maxsize) {
245: $maxsize = 10.0; # FIXME This should become a domain configuration.
246: }
247: if ($size > $maxsize) {
248: my $warn = 'HWFILETOOBIG'.$ident;
249: &Apache::loncommon::add_to_env("form.$warn",$fname);
250: return;
251: }
252: }
253: return 'ok';
254: }
255:
256: =pod
257:
258: =item sso_login()
259:
260: handle the case of the single sign on user, at this point $r->user
261: will be set and valid now need to find the loncapa user info and possibly
262: balance them
263: returns OK if it was a SSO and user was handled
264: undef if not SSO or no means to hanle the user
265:
266: =cut
267:
268: sub sso_login {
269: my ($r,$handle) = @_;
270:
271: my $lonidsdir=$r->dir_config('lonIDsDir');
272: if (!($r->user
273: && (!defined($env{'user.name'}) && !defined($env{'user.domain'}))
274: && ($handle eq ''))) {
275: # not an SSO case or already logged in
276: return undef;
277: }
278:
279: my ($user) = ($r->user =~ m/([a-zA-Z0-9_\-@.]*)/);
280:
281: my $query = $r->args;
282: my %form;
283: if ($query) {
284: foreach my $pair (split(/&/,$query)) {
285: my ($name, $value) = split(/=/,$pair);
286: $name = &unescape($name);
287: if (($name eq 'role') || ($name eq 'symb')) {
288: $value =~ tr/+/ /;
289: $value =~ s/%([a-fA-F0-9][a-fA-F0-9])/pack("C",hex($1))/eg;
290: $form{$name} = $value;
291: }
292: }
293: }
294:
295: my $domain = $r->dir_config('lonDefDomain');
296: my $home=&Apache::lonnet::homeserver($user,$domain);
297: if ($home !~ /(con_lost|no_host|no_such_host)/) {
298: &Apache::lonnet::logthis(" SSO authorized user $user ");
299: if ($r->dir_config("lonBalancer") eq 'yes') {
300: # login but immeaditly go to switch server to find us a new
301: # machine
302: &Apache::lonauth::success($r,$user,$domain,$home,'noredirect','',\%form);
303: $env{'request.sso.login'} = 1;
304: if (defined($r->dir_config("lonSSOReloginServer"))) {
305: $env{'request.sso.reloginserver'} =
306: $r->dir_config('lonSSOReloginServer');
307: }
308: $r->internal_redirect('/adm/switchserver');
309: $r->set_handlers('PerlHandler'=> undef);
310: } else {
311: # need to login them in, so generate the need data that
312: # migrate expects to do login
313: my %info=('ip' => $r->connection->remote_ip(),
314: 'domain' => $domain,
315: 'username' => $user,
316: 'server' => $r->dir_config('lonHostID'),
317: 'sso.login' => 1
318: );
319: foreach my $item ('role','symb') {
320: if (exists($form{$item})) {
321: $info{$item} = $form{$item};
322: }
323: }
324: if ($r->dir_config("ssodirecturl") == 1) {
325: $info{'origurl'} = $r->uri;
326: }
327: if (defined($r->dir_config("lonSSOReloginServer"))) {
328: $info{'sso.reloginserver'} =
329: $r->dir_config('lonSSOReloginServer');
330: }
331: my $token =
332: &Apache::lonnet::tmpput(\%info,
333: $r->dir_config('lonHostID'));
334: $env{'form.token'} = $token;
335: $r->internal_redirect('/adm/migrateuser');
336: $r->set_handlers('PerlHandler'=> undef);
337: }
338: return OK;
339: } elsif (defined($r->dir_config('lonSSOUserUnknownRedirect'))) {
340: &Apache::lonnet::logthis(" SSO authorized unknown user $user ");
341: $r->subprocess_env->set('SSOUserUnknown' => $user);
342: $r->subprocess_env->set('SSOUserDomain' => $domain);
343: my @cancreate;
344: my %domconfig =
345: &Apache::lonnet::get_dom('configuration',['usercreation'],$domain);
346: if (ref($domconfig{'usercreation'}) eq 'HASH') {
347: if (ref($domconfig{'usercreation'}{'cancreate'}) eq 'HASH') {
348: if (ref($domconfig{'usercreation'}{'cancreate'}{'selfcreate'}) eq 'ARRAY') {
349: @cancreate = @{$domconfig{'usercreation'}{'cancreate'}{'selfcreate'}};
350: } elsif (($domconfig{'usercreation'}{'cancreate'}{'selfcreate'} ne 'none') &&
351: ($domconfig{'usercreation'}{'cancreate'}{'selfcreate'} ne '')) {
352: @cancreate = ($domconfig{'usercreation'}{'cancreate'}{'selfcreate'});
353: }
354: }
355: }
356: if (grep(/^sso$/,@cancreate)) {
357: $r->internal_redirect('/adm/createaccount');
358: } else {
359: $r->internal_redirect($r->dir_config('lonSSOUserUnknownRedirect'));
360: }
361: $r->set_handlers('PerlHandler'=> undef);
362: return OK;
363: }
364: return undef;
365: }
366:
367: sub handler {
368: my $r = shift;
369: my $requrl=$r->uri;
370: if (&Apache::lonnet::is_domainimage($requrl)) {
371: return OK;
372: }
373:
374: if ($requrl =~ m{^/res/adm/pages/[^/]+\.(gif|png)$}) {
375: return OK;
376: }
377:
378: my $handle = &Apache::lonnet::check_for_valid_session($r);
379:
380: my $result = &sso_login($r,$handle);
381: if (defined($result)) {
382: return $result;
383: }
384:
385:
386: if ($r->dir_config("lonBalancer") eq 'yes') {
387: $r->set_handlers('PerlResponseHandler'=>
388: [\&Apache::switchserver::handler]);
389: }
390:
391: if ($handle eq '') {
392: $r->log_reason("Cookie $handle not valid", $r->filename);
393: } elsif ($handle ne '') {
394:
395: # ------------------------------------------------------ Initialize Environment
396: my $lonidsdir=$r->dir_config('lonIDsDir');
397: &Apache::lonnet::transfer_profile_to_env($lonidsdir,$handle);
398:
399: # --------------------------------------------------------- Initialize Language
400:
401: &Apache::lonlocal::get_language_handle($r);
402:
403: }
404:
405: # -------------------------------------------------- Should be a valid user now
406: if ($env{'user.name'} ne '' && $env{'user.domain'} ne '') {
407: # -------------------------------------------------------------- Resource State
408:
409: if ($requrl=~/^\/+(res|uploaded)\//) {
410: $env{'request.state'} = "published";
411: } else {
412: $env{'request.state'} = 'unknown';
413: }
414: $env{'request.filename'} = $r->filename;
415: $env{'request.noversionuri'} = &Apache::lonnet::deversion($requrl);
416: # -------------------------------------------------------- Load POST parameters
417:
418: &Apache::lonacc::get_posted_cgi($r);
419:
420: # ---------------------------------------------------------------- Check access
421: my $now = time;
422: if ($requrl !~ m{^/(?:adm|public|prtspool)/}
423: || $requrl =~ /^\/adm\/.*\/(smppg|bulletinboard)(\?|$ )/x) {
424: my $access=&Apache::lonnet::allowed('bre',$requrl);
425: if ($access eq '1') {
426: $env{'user.error.msg'}="$requrl:bre:0:0:Choose Course";
427: return HTTP_NOT_ACCEPTABLE;
428: }
429: if ($access eq 'A') {
430: &Apache::restrictedaccess::setup_handler($r);
431: return OK;
432: }
433: if ($access eq 'B') {
434: &Apache::blockedaccess::setup_handler($r);
435: return OK;
436: }
437: if (($access ne '2') && ($access ne 'F')) {
438: $env{'user.error.msg'}="$requrl:bre:1:1:Access Denied";
439: return HTTP_NOT_ACCEPTABLE;
440: }
441: }
442: if ($requrl =~ m|^/prtspool/|) {
443: my $start='/prtspool/'.$env{'user.name'}.'_'.
444: $env{'user.domain'};
445: if ($requrl !~ /^\Q$start\E/) {
446: $env{'user.error.msg'}="$requrl:bre:1:1:Access Denied";
447: return HTTP_NOT_ACCEPTABLE;
448: }
449: }
450: if ($requrl =~ m|^/zipspool/|) {
451: my $start='/zipspool/zipout/'.$env{'user.name'}.":".
452: $env{'user.domain'};
453: if ($requrl !~ /^\Q$start\E/) {
454: $env{'user.error.msg'}="$requrl:bre:1:1:Access Denied";
455: return HTTP_NOT_ACCEPTABLE;
456: }
457: }
458: if ($env{'user.name'} eq 'public' &&
459: $env{'user.domain'} eq 'public' &&
460: $requrl !~ m{^/+(res|public|uploaded)/} &&
461: $requrl !~ m{^/adm/[^/]+/[^/]+/aboutme/portfolio$ }x &&
462: $requrl !~ m{^/+adm/(help|logout|restrictedaccess|randomlabel\.png)}) {
463: $env{'request.querystring'}=$r->args;
464: $env{'request.firsturl'}=$requrl;
465: return FORBIDDEN;
466: }
467: # ------------------------------------------------------------- This is allowed
468: if ($env{'request.course.id'}) {
469: &Apache::lonnet::countacc($requrl);
470: $requrl=~/\.(\w+)$/;
471: my $query=$r->args;
472: if ((&Apache::loncommon::fileembstyle($1) eq 'ssi') ||
473: ($requrl=~/^\/adm\/.*\/(aboutme|navmaps|smppg|bulletinboard)(\?|$ )/x) ||
474: ($requrl=~/^\/adm\/wrapper\//) ||
475: ($requrl=~m|^/adm/coursedocs/showdoc/|) ||
476: ($requrl=~m|\.problem/smpedit$|) ||
477: ($requrl=~/^\/public\/.*\/syllabus$/)) {
478: # ------------------------------------- This is serious stuff, get symb and log
479: my $symb;
480: if ($query) {
481: &Apache::loncommon::get_unprocessed_cgi($query,['symb']);
482: }
483: if ($env{'form.symb'}) {
484: $symb=&Apache::lonnet::symbclean($env{'form.symb'});
485: if ($requrl =~ m|^/adm/wrapper/|
486: || $requrl =~ m|^/adm/coursedocs/showdoc/|) {
487: my ($map,$mid,$murl)=&Apache::lonnet::decode_symb($symb);
488: &Apache::lonnet::symblist($map,$murl => [$murl,$mid],
489: 'last_known' =>[$murl,$mid]);
490: } elsif ((&Apache::lonnet::symbverify($symb,$requrl)) ||
491: (($requrl=~m|(.*)/smpedit$|) &&
492: &Apache::lonnet::symbverify($symb,$1))) {
493: my ($map,$mid,$murl)=&Apache::lonnet::decode_symb($symb);
494: &Apache::lonnet::symblist($map,$murl => [$murl,$mid],
495: 'last_known' =>[$murl,$mid]);
496: } else {
497: $r->log_reason('Invalid symb for '.$requrl.': '.
498: $symb);
499: $env{'user.error.msg'}=
500: "$requrl:bre:1:1:Invalid Access";
501: return HTTP_NOT_ACCEPTABLE;
502: }
503: } else {
504: $symb=&Apache::lonnet::symbread($requrl);
505: if (&Apache::lonnet::is_on_map($requrl) && $symb &&
506: !&Apache::lonnet::symbverify($symb,$requrl)) {
507: $r->log_reason('Invalid symb for '.$requrl.': '.$symb);
508: $env{'user.error.msg'}=
509: "$requrl:bre:1:1:Invalid Access";
510: return HTTP_NOT_ACCEPTABLE;
511: }
512: if ($symb) {
513: my ($map,$mid,$murl)=
514: &Apache::lonnet::decode_symb($symb);
515: &Apache::lonnet::symblist($map,$murl =>[$murl,$mid],
516: 'last_known' =>[$murl,$mid]);
517: }
518: }
519: $env{'request.symb'}=$symb;
520: &Apache::lonnet::courseacclog($symb);
521: } else {
522: # ------------------------------------------------------- This is other content
523: &Apache::lonnet::courseacclog($requrl);
524: }
525: my $cdom = $env{'course.'.$env{'request.course.id'}.'.domain'};;
526: my $cnum = $env{'course.'.$env{'request.course.id'}.'.num'};;
527: if ($requrl =~ m{^/+uploaded/\Q$cdom\E/\Q$cnum\E/docs/.+\.html?$}) {
528: if (&Apache::lonnet::allowed('mdc',$env{'request.course.id'})) {
529: if ($query) {
530: &Apache::loncommon::get_unprocessed_cgi($query,['forceedit']);
531: if ($env{'form.forceedit'}) {
532: $env{'request.state'} = 'edit';
533: }
534: }
535: }
536: }
537: }
538: return OK;
539: }
540: # -------------------------------------------- See if this is a public resource
541: if ($requrl=~m|^/+adm/+help/+|) {
542: return OK;
543: }
544: # ------------------------------------ See if this is a viewable portfolio file
545: if (&Apache::lonnet::is_portfolio_url($requrl)) {
546: my $access=&Apache::lonnet::allowed('bre',$requrl);
547: if ($access eq 'A') {
548: &Apache::restrictedaccess::setup_handler($r);
549: return OK;
550: }
551: if (($access ne '2') && ($access ne 'F')) {
552: $env{'user.error.msg'}="$requrl:bre:1:1:Access Denied";
553: return HTTP_NOT_ACCEPTABLE;
554: }
555: }
556:
557: # -------------------------------------------------------------- Not authorized
558: $requrl=~/\.(\w+)$/;
559: # if ((&Apache::loncommon::fileembstyle($1) eq 'ssi') ||
560: # ($requrl=~/^\/adm\/(roles|logout|email|menu|remote)/) ||
561: # ($requrl=~m|^/prtspool/|)) {
562: # -------------------------- Store where they wanted to go and get login screen
563: $env{'request.querystring'}=$r->args;
564: $env{'request.firsturl'}=$requrl;
565: return FORBIDDEN;
566: # } else {
567: # --------------------------------------------------------------------- Goodbye
568: # return HTTP_BAD_REQUEST;
569: # }
570: }
571:
572: 1;
573: __END__
574:
575: =pod
576:
577: =back
578:
579: =cut
580:
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>