1: # The LearningOnline Network
2: # Cookie Based Access Handler
3: #
4: # $Id: lonacc.pm,v 1.159 2014/10/18 21:40:06 raeburn Exp $
5: #
6: # Copyright Michigan State University Board of Trustees
7: #
8: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
9: #
10: # LON-CAPA is free software; you can redistribute it and/or modify
11: # it under the terms of the GNU General Public License as published by
12: # the Free Software Foundation; either version 2 of the License, or
13: # (at your option) any later version.
14: #
15: # LON-CAPA is distributed in the hope that it will be useful,
16: # but WITHOUT ANY WARRANTY; without even the implied warranty of
17: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18: # GNU General Public License for more details.
19: #
20: # You should have received a copy of the GNU General Public License
21: # along with LON-CAPA; if not, write to the Free Software
22: # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
23: #
24: # /home/httpd/html/adm/gpl.txt
25: #
26: # http://www.lon-capa.org/
27: #
28: ###
29:
30: =head1 NAME
31:
32: Apache::lonacc - Cookie Based Access Handler
33:
34: =head1 SYNOPSIS
35:
36: Invoked (for various locations) by /etc/httpd/conf/srm.conf:
37:
38: PerlAccessHandler Apache::lonacc
39:
40: =head1 INTRODUCTION
41:
42: This module enables cookie based authentication and is used
43: to control access for many different LON-CAPA URIs.
44:
45: Whenever the client sends the cookie back to the server,
46: this cookie is handled by either lonacc.pm or loncacc.pm
47: (see srm.conf for what is invoked when). If
48: the cookie is missing or invalid, the user is re-challenged
49: for login information.
50:
51: This is part of the LearningOnline Network with CAPA project
52: described at http://www.lon-capa.org.
53:
54: =head1 HANDLER SUBROUTINE
55:
56: This routine is called by Apache and mod_perl.
57:
58: =over 4
59:
60: =item *
61:
62: transfer profile into environment
63:
64: =item *
65:
66: load POST parameters
67:
68: =item *
69:
70: check access
71:
72: =item *
73:
74: if allowed, get symb, log, generate course statistics if applicable
75:
76: =item *
77:
78: otherwise return error
79:
80: =item *
81:
82: see if public resource
83:
84: =item *
85:
86: store attempted access
87:
88: =back
89:
90: =head1 NOTABLE SUBROUTINES
91:
92: =cut
93:
94:
95: package Apache::lonacc;
96:
97: use strict;
98: use Apache::Constants qw(:common :http :methods);
99: use Apache::File;
100: use Apache::lonnet;
101: use Apache::loncommon();
102: use Apache::lonlocal;
103: use Apache::restrictedaccess();
104: use Apache::blockedaccess();
105: use Fcntl qw(:flock);
106: use LONCAPA qw(:DEFAULT :match);
107:
108: sub cleanup {
109: my ($r)=@_;
110: if (! $r->is_initial_req()) { return DECLINED; }
111: &Apache::lonnet::save_cache();
112: &Apache::lontexconvert::jsMath_reset();
113: return OK;
114: }
115:
116: sub goodbye {
117: my ($r)=@_;
118: &Apache::lonnet::goodbye();
119: return DONE;
120: }
121:
122: ###############################################
123:
124: sub get_posted_cgi {
125: my ($r,$fields) = @_;
126:
127: my $buffer;
128: if ($r->header_in('Content-length')) {
129: $r->read($buffer,$r->header_in('Content-length'),0);
130: }
131: my $content_type = $r->header_in('Content-type');
132: if ($content_type !~ m{^multipart/form-data}) {
133: my @pairs=split(/&/,$buffer);
134: my $pair;
135: foreach $pair (@pairs) {
136: my ($name,$value) = split(/=/,$pair);
137: $value =~ tr/+/ /;
138: $value =~ s/%([a-fA-F0-9][a-fA-F0-9])/pack("C",hex($1))/eg;
139: $name =~ tr/+/ /;
140: $name =~ s/%([a-fA-F0-9][a-fA-F0-9])/pack("C",hex($1))/eg;
141: if (ref($fields) eq 'ARRAY') {
142: next if (!grep(/^\Q$name\E$/,@{$fields}));
143: }
144: &Apache::loncommon::add_to_env("form.$name",$value);
145: }
146: } else {
147: my ($contentsep) = ($content_type =~ /boundary=\"?([^\";,]+)\"?/);
148: my @lines = split (/\n/,$buffer);
149: my $name='';
150: my $value='';
151: my $fname='';
152: my $fmime='';
153: my $i;
154: for ($i=0;$i<=$#lines;$i++) {
155: if ($lines[$i]=~/^--\Q$contentsep\E/) {
156: if ($name) {
157: chomp($value);
158: if (($r->uri eq '/adm/portfolio') &&
159: ($name eq 'uploaddoc')) {
160: if (length($value) == 1) {
161: $value=~s/[\r\n]$//;
162: }
163: } elsif ($fname =~ /\.(xls|doc|ppt)x$/i) {
164: $value=~s/[\r\n]$//;
165: }
166: if (ref($fields) eq 'ARRAY') {
167: next if (!grep(/^\Q$name\E$/,@{$fields}));
168: }
169: if ($fname) {
170: if ($env{'form.symb'} ne '') {
171: my $size = (length($value))/(1024.0 * 1024.0);
172: if (&upload_size_allowed($name,$size,$fname) eq 'ok') {
173: $env{"form.$name.filename"}=$fname;
174: $env{"form.$name.mimetype"}=$fmime;
175: &Apache::loncommon::add_to_env("form.$name",$value);
176: }
177: } else {
178: $env{"form.$name.filename"}=$fname;
179: $env{"form.$name.mimetype"}=$fmime;
180: &Apache::loncommon::add_to_env("form.$name",$value);
181: }
182: } else {
183: $value=~s/\s+$//s;
184: &Apache::loncommon::add_to_env("form.$name",$value);
185: }
186: }
187: if ($i<$#lines) {
188: $i++;
189: $lines[$i]=~
190: /Content\-Disposition\:\s*form\-data\;\s*name\=\"([^\"]+)\"/i;
191: $name=$1;
192: $value='';
193: if ($lines[$i]=~/filename\=\"([^\"]+)\"/i) {
194: $fname=$1;
195: if
196: ($lines[$i+1]=~/Content\-Type\:\s*([\w\-\/]+)/i) {
197: $fmime=$1;
198: $i++;
199: } else {
200: $fmime='';
201: }
202: } else {
203: $fname='';
204: $fmime='';
205: }
206: $i++;
207: }
208: } else {
209: $value.=$lines[$i]."\n";
210: }
211: }
212: }
213: #
214: # Digested POSTed values
215: #
216: # Remember the way this was originally done (GET or POST)
217: #
218: $env{'request.method'}=$ENV{'REQUEST_METHOD'};
219: #
220: # There may also be stuff in the query string
221: # Tell subsequent handlers that this was GET, not POST, so they can access query string.
222: # Also, unset POSTed content length to cover all tracks.
223: #
224:
225: $r->method_number(M_GET);
226:
227: $r->method('GET');
228: $r->headers_in->unset('Content-length');
229: }
230:
231: =pod
232:
233: =over
234:
235: =item upload_size_allowed()
236:
237: Perform size checks for file uploads to essayresponse items in course context.
238:
239: Add form.HWFILESIZE.$part_$id to %env with file size (MB)
240: If file exceeds maximum allowed size, add form.HWFILETOOBIG.$part_$id to %env.
241:
242: =cut
243:
244: sub upload_size_allowed {
245: my ($name,$size,$fname) = @_;
246: if ($name =~ /^HWFILE(\w+)$/) {
247: my $ident = $1;
248: my $item = 'HWFILESIZE'.$ident;
249: my $savesize = sprintf("%.6f",$size);
250: &Apache::loncommon::add_to_env("form.$item",$savesize);
251: my $maxsize= &Apache::lonnet::EXT("resource.$ident.maxfilesize");
252: if (!$maxsize) {
253: $maxsize = 10.0; # FIXME This should become a domain configuration.
254: }
255: if ($size > $maxsize) {
256: my $warn = 'HWFILETOOBIG'.$ident;
257: &Apache::loncommon::add_to_env("form.$warn",$fname);
258: return;
259: }
260: }
261: return 'ok';
262: }
263:
264: =pod
265:
266: =item sso_login()
267:
268: handle the case of the single sign on user, at this point $r->user
269: will be set and valid; now need to find the loncapa user info, and possibly
270: balance them. If $r->user() is set this means either it was either set by
271: SSO or by checkauthen.pm, if a valid cookie was found. The latter case can
272: be identified by the third arg ($usename), except when lonacc is called in
273: an internal redirect to /adm/switchserver (e.g., load-balancing following
274: successful authentication) -- no cookie set yet. For that particular case
275: simply skip the call to sso_login().
276:
277: returns OK if it was SSO and user was handled.
278: returns undef if not SSO or no means to handle the user.
279:
280: =cut
281:
282: sub sso_login {
283: my ($r,$handle,$username) = @_;
284:
285: my $lonidsdir=$r->dir_config('lonIDsDir');
286: if (($r->user eq '') || ($username ne '') || ($r->user eq 'public:public') ||
287: (defined($env{'user.name'}) && (defined($env{'user.domain'}))
288: && ($handle ne ''))) {
289: # not an SSO case or already logged in
290: return undef;
291: }
292:
293: my ($user) = ($r->user =~ m/([a-zA-Z0-9_\-@.]*)/);
294:
295: my $query = $r->args;
296: my %form;
297: if ($query) {
298: my @items = ('role','symb','iptoken');
299: &Apache::loncommon::get_unprocessed_cgi($query,\@items);
300: foreach my $item (@items) {
301: if (defined($env{'form.'.$item})) {
302: $form{$item} = $env{'form.'.$item};
303: }
304: }
305: }
306:
307: my %sessiondata;
308: if ($form{'iptoken'}) {
309: %sessiondata = &Apache::lonnet::tmpget($form{'iptoken'});
310: my $delete = &Apache::lonnet::tmpdel($form{'iptoken'});
311: unless ($sessiondata{'sessionserver'}) {
312: delete($form{'iptoken'});
313: }
314: }
315:
316: my $domain = $r->dir_config('lonSSOUserDomain');
317: if ($domain eq '') {
318: $domain = $r->dir_config('lonDefDomain');
319: }
320: my $home=&Apache::lonnet::homeserver($user,$domain);
321: if ($home !~ /(con_lost|no_host|no_such_host)/) {
322: &Apache::lonnet::logthis(" SSO authorized user $user ");
323: my ($is_balancer,$otherserver,$hosthere);
324: if ($form{'iptoken'}) {
325: if (($sessiondata{'domain'} eq $domain) &&
326: ($sessiondata{'username'} eq $user)) {
327: $hosthere = 1;
328: }
329: }
330: unless ($hosthere) {
331: ($is_balancer,$otherserver) =
332: &Apache::lonnet::check_loadbalancing($user,$domain);
333: }
334:
335: if ($is_balancer) {
336: # login but immediately go to switch server to find us a new
337: # machine
338: &Apache::lonauth::success($r,$user,$domain,$home,'noredirect');
339: $env{'request.sso.login'} = 1;
340: if (defined($r->dir_config("lonSSOReloginServer"))) {
341: $env{'request.sso.reloginserver'} =
342: $r->dir_config('lonSSOReloginServer');
343: }
344: my $redirecturl = '/adm/switchserver';
345: if ($otherserver ne '') {
346: $redirecturl .= '?otherserver='.$otherserver;
347: }
348: $r->internal_redirect($redirecturl);
349: $r->set_handlers('PerlHandler'=> undef);
350: } else {
351: # need to login them in, so generate the need data that
352: # migrate expects to do login
353: my $ip;
354: my $c = $r->connection;
355: eval {
356: $ip = $c->remote_ip();
357: };
358: if ($@) {
359: $ip = $c->client_ip();
360: }
361: my %info=('ip' => $ip,
362: 'domain' => $domain,
363: 'username' => $user,
364: 'server' => $r->dir_config('lonHostID'),
365: 'sso.login' => 1
366: );
367: foreach my $item ('role','symb','iptoken') {
368: if (exists($form{$item})) {
369: $info{$item} = $form{$item};
370: }
371: }
372: unless ($info{'symb'}) {
373: unless (($r->uri eq '/adm/roles') || ($r->uri eq '/adm/sso')) {
374: $info{'origurl'} = $r->uri;
375: }
376: }
377: if ($r->dir_config("ssodirecturl") == 1) {
378: $info{'origurl'} = $r->uri;
379: }
380: if (defined($r->dir_config("lonSSOReloginServer"))) {
381: $info{'sso.reloginserver'} =
382: $r->dir_config('lonSSOReloginServer');
383: }
384: my $token =
385: &Apache::lonnet::tmpput(\%info,
386: $r->dir_config('lonHostID'));
387: $env{'form.token'} = $token;
388: $r->internal_redirect('/adm/migrateuser');
389: $r->set_handlers('PerlHandler'=> undef);
390: }
391: return OK;
392: } else {
393: &Apache::lonnet::logthis(" SSO authorized unknown user $user ");
394: my @cancreate;
395: my %domconfig =
396: &Apache::lonnet::get_dom('configuration',['usercreation'],$domain);
397: if (ref($domconfig{'usercreation'}) eq 'HASH') {
398: if (ref($domconfig{'usercreation'}{'cancreate'}) eq 'HASH') {
399: if (ref($domconfig{'usercreation'}{'cancreate'}{'selfcreate'}) eq 'ARRAY') {
400: @cancreate = @{$domconfig{'usercreation'}{'cancreate'}{'selfcreate'}};
401: } elsif (($domconfig{'usercreation'}{'cancreate'}{'selfcreate'} ne 'none') &&
402: ($domconfig{'usercreation'}{'cancreate'}{'selfcreate'} ne '')) {
403: @cancreate = ($domconfig{'usercreation'}{'cancreate'}{'selfcreate'});
404: }
405: }
406: }
407: if ((grep(/^sso$/,@cancreate)) || (defined($r->dir_config('lonSSOUserUnknownRedirect')))) {
408: $r->subprocess_env->set('SSOUserUnknown' => $user);
409: $r->subprocess_env->set('SSOUserDomain' => $domain);
410: if (grep(/^sso$/,@cancreate)) {
411: $r->set_handlers('PerlHandler'=> [\&Apache::createaccount::handler]);
412: $r->handler('perl-script');
413: } else {
414: $r->internal_redirect($r->dir_config('lonSSOUserUnknownRedirect'));
415: $r->set_handlers('PerlHandler'=> undef);
416: }
417: return OK;
418: }
419: }
420: return undef;
421: }
422:
423: sub handler {
424: my $r = shift;
425: my $requrl=$r->uri;
426:
427: if ($requrl =~ m{^/res/adm/pages/[^/]+\.(gif|png)$}) {
428: return OK;
429: }
430:
431: if (&Apache::lonnet::is_domainimage($requrl)) {
432: return OK;
433: }
434:
435: my %user;
436: my $handle = &Apache::lonnet::check_for_valid_session($r,undef,\%user);
437:
438: unless (($requrl eq '/adm/switchserver') && (!$r->is_initial_req())) {
439: my $result = &sso_login($r,$handle,$user{'name'});
440: if (defined($result)) {
441: return $result;
442: }
443: }
444:
445: my ($is_balancer,$otherserver);
446:
447: if ($handle eq '') {
448: unless ((($requrl eq '/adm/switchserver') && (!$r->is_initial_req())) ||
449: ($requrl =~ m{^/public/$match_domain/$match_courseid/syllabus}) ||
450: ($requrl =~ m{^/adm/help/}) ||
451: ($requrl =~ m{^/res/$match_domain/$match_username/})) {
452: $r->log_reason("Cookie not valid", $r->filename);
453: }
454: } elsif ($handle ne '') {
455:
456: # ------------------------------------------------------ Initialize Environment
457: my $lonidsdir=$r->dir_config('lonIDsDir');
458: &Apache::lonnet::transfer_profile_to_env($lonidsdir,$handle);
459:
460: # --------------------------------------------------------- Initialize Language
461:
462: &Apache::lonlocal::get_language_handle($r);
463:
464: }
465:
466: # -------------------------------------------------- Should be a valid user now
467: if ($env{'user.name'} ne '' && $env{'user.domain'} ne '') {
468: # -------------------------------------------------------------- Resource State
469:
470: my ($cdom,$cnum);
471: if ($env{'request.course.id'}) {
472: $cdom = $env{'course.'.$env{'request.course.id'}.'.domain'};
473: $cnum = $env{'course.'.$env{'request.course.id'}.'.num'};
474: }
475: if ($requrl=~/^\/+(res|uploaded)\//) {
476: $env{'request.state'} = "published";
477: } else {
478: $env{'request.state'} = 'unknown';
479: }
480: $env{'request.filename'} = $r->filename;
481: $env{'request.noversionuri'} = &Apache::lonnet::deversion($requrl);
482: my ($suppext,$checkabsolute);
483: if ($requrl =~ m{^/adm/wrapper/ext/}) {
484: my $query = $r->args;
485: if ($query) {
486: my $preserved;
487: foreach my $pair (split(/&/,$query)) {
488: my ($name, $value) = split(/=/,$pair);
489: unless ($name eq 'symb') {
490: $preserved .= $pair.'&';
491: }
492: if (($env{'request.course.id'}) && ($name eq 'folderpath')) {
493: if ($value =~ /^supplemental/) {
494: $suppext = 1;
495: }
496: }
497: }
498: $preserved =~ s/\&$//;
499: if ($preserved) {
500: $env{'request.external.querystring'} = $preserved;
501: }
502: }
503: if ($env{'request.course.id'}) {
504: $checkabsolute = 1;
505: }
506: } elsif ($env{'request.course.id'} &&
507: (($requrl =~ m{^/adm/$match_domain/$match_username/aboutme$}) ||
508: ($requrl =~ m{^/public/$cdom/$cnum/syllabus$}))) {
509: my $query = $r->args;
510: if ($query) {
511: foreach my $pair (split(/&/,$query)) {
512: my ($name, $value) = split(/=/,$pair);
513: if ($name eq 'folderpath') {
514: if ($value =~ /^supplemental/) {
515: $suppext = 1;
516: }
517: }
518: }
519: }
520: if ($requrl =~ m{^/public/$cdom/$cnum/syllabus$}) {
521: $checkabsolute = 1;
522: }
523: }
524: if ($checkabsolute) {
525: my $hostname = $r->hostname();
526: my $lonhost = &Apache::lonnet::host_from_dns($hostname);
527: if ($lonhost) {
528: my $actual = &Apache::lonnet::absolute_url($hostname);
529: my $expected = $Apache::lonnet::protocol{$lonhost}.'://'.$hostname;
530: unless ($actual eq $expected) {
531: $env{'request.use_absolute'} = $expected;
532: }
533: }
534: }
535: # -------------------------------------------------------- Load POST parameters
536:
537: &Apache::lonacc::get_posted_cgi($r);
538:
539: # ------------------------------------------------------ Check if load balancer
540:
541: my $checkexempt;
542: if ($env{'user.loadbalexempt'} eq $r->dir_config('lonHostID')) {
543: if ($env{'user.loadbalcheck.time'} + 600 > time) {
544: $checkexempt = 1;
545: }
546: }
547: if ($env{'user.noloadbalance'} eq $r->dir_config('lonHostID')) {
548: $checkexempt = 1;
549: }
550: unless ($checkexempt) {
551: ($is_balancer,$otherserver) =
552: &Apache::lonnet::check_loadbalancing($env{'user.name'},
553: $env{'user.domain'});
554: }
555: if ($is_balancer) {
556: $r->set_handlers('PerlResponseHandler'=>
557: [\&Apache::switchserver::handler]);
558: if ($otherserver ne '') {
559: $env{'form.otherserver'} = $otherserver;
560: }
561: unless (($env{'form.origurl'}) || ($r->uri eq '/adm/roles') ||
562: ($r->uri eq '/adm/switchserver') || ($r->uri eq '/adm/sso')) {
563: $env{'form.origurl'} = $r->uri;
564: }
565: }
566:
567: # ---------------------------------------------------------------- Check access
568: my $now = time;
569: if ($requrl !~ m{^/(?:adm|public|prtspool)/}
570: || $requrl =~ /^\/adm\/.*\/(smppg|bulletinboard)(\?|$ )/x) {
571: my $access=&Apache::lonnet::allowed('bre',$requrl);
572: if ($handle eq '') {
573: unless ($access eq 'F') {
574: if ($requrl =~ m{^/res/$match_domain/$match_username/}) {
575: $r->log_reason("Cookie not valid", $r->filename);
576: }
577: }
578: }
579: if ($access eq '1') {
580: $env{'user.error.msg'}="$requrl:bre:0:0:Choose Course";
581: return HTTP_NOT_ACCEPTABLE;
582: }
583: if ($access eq 'A') {
584: &Apache::restrictedaccess::setup_handler($r);
585: return OK;
586: }
587: if ($access eq 'B') {
588: &Apache::blockedaccess::setup_handler($r);
589: return OK;
590: }
591: if (($access ne '2') && ($access ne 'F')) {
592: if ($requrl =~ m{^/res/}) {
593: $access = &Apache::lonnet::allowed('bro',$requrl);
594: if ($access ne 'F') {
595: if ($requrl eq '/res/lib/templates/simpleproblem.problem/smpedit') {
596: $access = &Apache::lonnet::allowed('bre','/res/lib/templates/simpleproblem.problem');
597: if ($access ne 'F') {
598: $env{'user.error.msg'}="$requrl:bre:1:1:Access Denied";
599: return HTTP_NOT_ACCEPTABLE;
600: }
601: } else {
602: $env{'user.error.msg'}="$requrl:bre:1:1:Access Denied";
603: return HTTP_NOT_ACCEPTABLE;
604: }
605: }
606: } else {
607: $env{'user.error.msg'}="$requrl:bre:1:1:Access Denied";
608: return HTTP_NOT_ACCEPTABLE;
609: }
610: }
611: }
612: if ($requrl =~ m|^/prtspool/|) {
613: my $start='/prtspool/'.$env{'user.name'}.'_'.
614: $env{'user.domain'};
615: if ($requrl !~ /^\Q$start\E/) {
616: $env{'user.error.msg'}="$requrl:bre:1:1:Access Denied";
617: return HTTP_NOT_ACCEPTABLE;
618: }
619: }
620: if ($requrl =~ m|^/zipspool/|) {
621: my $start='/zipspool/zipout/'.$env{'user.name'}.":".
622: $env{'user.domain'};
623: if ($requrl !~ /^\Q$start\E/) {
624: $env{'user.error.msg'}="$requrl:bre:1:1:Access Denied";
625: return HTTP_NOT_ACCEPTABLE;
626: }
627: }
628: if ($env{'user.name'} eq 'public' &&
629: $env{'user.domain'} eq 'public' &&
630: $requrl !~ m{^/+(res|public|uploaded)/} &&
631: $requrl !~ m{^/adm/[^/]+/[^/]+/aboutme/portfolio$ }x &&
632: $requrl !~ m{^/adm/blockingstatus/.*$} &&
633: $requrl !~ m{^/+adm/(help|logout|restrictedaccess|randomlabel\.png)}) {
634: $env{'request.querystring'}=$r->args;
635: $env{'request.firsturl'}=$requrl;
636: return FORBIDDEN;
637: }
638: # ------------------------------------------------------------- This is allowed
639: if ($env{'request.course.id'}) {
640: &Apache::lonnet::countacc($requrl);
641: $requrl=~/\.(\w+)$/;
642: my $query=$r->args;
643: if ((&Apache::loncommon::fileembstyle($1) eq 'ssi') ||
644: ($requrl=~/^\/adm\/.*\/(aboutme|smppg|bulletinboard)(\?|$ )/x) ||
645: ($requrl=~/^\/adm\/wrapper\//) ||
646: ($requrl=~m|^/adm/coursedocs/showdoc/|) ||
647: ($requrl=~m|\.problem/smpedit$|) ||
648: ($requrl=~/^\/public\/.*\/syllabus$/) ||
649: ($requrl=~/^\/adm\/(viewclasslist|navmaps)$/) ||
650: ($requrl=~/^\/adm\/.*\/aboutme\/portfolio(\?|$)/)) {
651: # ------------------------------------- This is serious stuff, get symb and log
652: my $symb;
653: if ($query) {
654: &Apache::loncommon::get_unprocessed_cgi($query,['symb','folderpath']);
655: }
656: if ($env{'form.symb'}) {
657: $symb=&Apache::lonnet::symbclean($env{'form.symb'});
658: if ($requrl =~ m|^/adm/wrapper/|
659: || $requrl =~ m|^/adm/coursedocs/showdoc/|) {
660: my ($map,$mid,$murl)=&Apache::lonnet::decode_symb($symb);
661: &Apache::lonnet::symblist($map,$murl => [$murl,$mid],
662: 'last_known' =>[$murl,$mid]);
663: } elsif ((&Apache::lonnet::symbverify($symb,$requrl)) ||
664: (($requrl=~m|(.*)/smpedit$|) &&
665: &Apache::lonnet::symbverify($symb,$1)) ||
666: (($requrl=~m|(.*/aboutme)/portfolio$|) &&
667: &Apache::lonnet::symbverify($symb,$1))) {
668: my ($map,$mid,$murl)=&Apache::lonnet::decode_symb($symb);
669: &Apache::lonnet::symblist($map,$murl => [$murl,$mid],
670: 'last_known' =>[$murl,$mid]);
671: } else {
672: $r->log_reason('Invalid symb for '.$requrl.': '.
673: $symb);
674: $env{'user.error.msg'}=
675: "$requrl:bre:1:1:Invalid Access";
676: return HTTP_NOT_ACCEPTABLE;
677: }
678: } else {
679: if ($requrl=~m{^(/adm/.*/aboutme)/portfolio$}) {
680: $requrl = $1;
681: }
682: unless ($suppext) {
683: $symb=&Apache::lonnet::symbread($requrl);
684: if (&Apache::lonnet::is_on_map($requrl) && $symb &&
685: !&Apache::lonnet::symbverify($symb,$requrl)) {
686: $r->log_reason('Invalid symb for '.$requrl.': '.$symb);
687: $env{'user.error.msg'}=
688: "$requrl:bre:1:1:Invalid Access";
689: return HTTP_NOT_ACCEPTABLE;
690: }
691: if ($symb) {
692: my ($map,$mid,$murl)=
693: &Apache::lonnet::decode_symb($symb);
694: &Apache::lonnet::symblist($map,$murl =>[$murl,$mid],
695: 'last_known' =>[$murl,$mid]);
696: }
697: }
698: }
699: $env{'request.symb'}=$symb;
700: &Apache::lonnet::courseacclog($symb);
701: } else {
702: # ------------------------------------------------------- This is other content
703: &Apache::lonnet::courseacclog($requrl);
704: }
705: if ($requrl =~ m{^/+uploaded/\Q$cdom\E/\Q$cnum\E/(docs|supplemental)/.+\.html?$}) {
706: if (&Apache::lonnet::allowed('mdc',$env{'request.course.id'})) {
707: if ($query) {
708: &Apache::loncommon::get_unprocessed_cgi($query,['forceedit']);
709: if ($env{'form.forceedit'}) {
710: $env{'request.state'} = 'edit';
711: }
712: }
713: }
714: } elsif ($requrl =~ m{^/+uploaded/\Q$cdom\E/\Q$cnum\E/portfolio/syllabus/.+\.html?$}) {
715: if (&Apache::lonnet::allowed('mdc',$env{'request.course.id'})) {
716: if ($query) {
717: &Apache::loncommon::get_unprocessed_cgi($query,['forceedit','editmode']);
718: if (($env{'form.forceedit'}) || ($env{'form.editmode'})) {
719: $env{'request.state'} = 'edit';
720: }
721: }
722: }
723: }
724: }
725: return OK;
726: } else {
727: my $defdom=$r->dir_config('lonDefDomain');
728: ($is_balancer,$otherserver) =
729: &Apache::lonnet::check_loadbalancing(undef,$defdom);
730: if ($is_balancer) {
731: $r->set_handlers('PerlResponseHandler'=>
732: [\&Apache::switchserver::handler]);
733: if ($otherserver ne '') {
734: $env{'form.otherserver'} = $otherserver;
735: }
736: }
737: }
738: # -------------------------------------------- See if this is a public resource
739: if ($requrl=~m|^/+adm/+help/+|) {
740: return OK;
741: }
742: # ------------------------------------ See if this is a viewable portfolio file
743: if (&Apache::lonnet::is_portfolio_url($requrl)) {
744: my $access=&Apache::lonnet::allowed('bre',$requrl);
745: if ($access eq 'A') {
746: &Apache::restrictedaccess::setup_handler($r);
747: return OK;
748: }
749: if (($access ne '2') && ($access ne 'F')) {
750: $env{'user.error.msg'}="$requrl:bre:1:1:Access Denied";
751: return HTTP_NOT_ACCEPTABLE;
752: }
753: }
754:
755: # -------------------------------------------------------------- Not authorized
756: $requrl=~/\.(\w+)$/;
757: # if ((&Apache::loncommon::fileembstyle($1) eq 'ssi') ||
758: # ($requrl=~/^\/adm\/(roles|logout|email|menu|remote)/) ||
759: # ($requrl=~m|^/prtspool/|)) {
760: # -------------------------- Store where they wanted to go and get login screen
761: $env{'request.querystring'}=$r->args;
762: $env{'request.firsturl'}=$requrl;
763: return FORBIDDEN;
764: # } else {
765: # --------------------------------------------------------------------- Goodbye
766: # return HTTP_BAD_REQUEST;
767: # }
768: }
769:
770: 1;
771: __END__
772:
773: =pod
774:
775: =back
776:
777: =cut
778:
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>