1: # The LearningOnline Network
2: # Cookie Based Access Handler
3: #
4: # $Id: lonacc.pm,v 1.47 2003/09/16 18:15:43 www Exp $
5: #
6: # Copyright Michigan State University Board of Trustees
7: #
8: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
9: #
10: # LON-CAPA is free software; you can redistribute it and/or modify
11: # it under the terms of the GNU General Public License as published by
12: # the Free Software Foundation; either version 2 of the License, or
13: # (at your option) any later version.
14: #
15: # LON-CAPA is distributed in the hope that it will be useful,
16: # but WITHOUT ANY WARRANTY; without even the implied warranty of
17: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18: # GNU General Public License for more details.
19: #
20: # You should have received a copy of the GNU General Public License
21: # along with LON-CAPA; if not, write to the Free Software
22: # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
23: #
24: # /home/httpd/html/adm/gpl.txt
25: #
26: # http://www.lon-capa.org/
27: #
28: # YEAR=1999
29: # 5/21/99,5/22,5/29,5/31,6/15,16/11,22/11,
30: # YEAR=2000
31: # 01/06,01/13,05/31,06/01,09/06,09/25,09/28,10/30,11/6,
32: # 12/25,12/26,
33: # YEAR=2001
34: # 01/06/01,05/28,8/11,9/26,11/29 Gerd Kortemeyer
35: # YEAR=2002
36: # 1/4,2/25 Gerd Kortemeyer
37: #
38: ###
39:
40: package Apache::lonacc;
41:
42: use strict;
43: use Apache::Constants qw(:common :http :methods);
44: use Apache::File;
45: use Apache::lonnet;
46: use Apache::loncommon();
47: use Apache::lonlocal;
48: use CGI::Cookie();
49: use Fcntl qw(:flock);
50:
51: sub handler {
52: my $r = shift;
53: my $requrl=$r->uri;
54: my %cookies=CGI::Cookie->parse($r->header_in('Cookie'));
55: my $lonid=$cookies{'lonID'};
56: my $cookie;
57: if ($lonid) {
58: my $handle=$lonid->value;
59: $handle=~s/\W//g;
60: my $lonidsdir=$r->dir_config('lonIDsDir');
61: if ((-e "$lonidsdir/$handle.id") && ($handle ne '')) {
62:
63: # ------------------------------------------------------ Initialize Environment
64:
65: &Apache::lonnet::transfer_profile_to_env($lonidsdir,$handle);
66:
67: # --------------------------------------------------------- Initialize Language
68:
69: &Apache::lonlocal::get_language_handle();
70:
71: # -------------------------------------------------------------- Resource State
72:
73: if ($requrl=~/^\/res\//) {
74: $ENV{'request.state'} = "published";
75: } else {
76: $ENV{'request.state'} = 'unknown';
77: }
78: $ENV{'request.filename'} = $r->filename;
79:
80: # -------------------------------------------------------- Load POST parameters
81:
82: &Apache::loncommon::get_posted_cgi($r);
83:
84: # ---------------------------------------------------------------- Check access
85:
86: if ($requrl!~/^\/adm|public|prtspool\//) {
87: my $access=&Apache::lonnet::allowed('bre',$requrl);
88: if ($access eq '1') {
89: $ENV{'user.error.msg'}="$requrl:bre:0:0:Choose Course";
90: return HTTP_NOT_ACCEPTABLE;
91: }
92: if (($access ne '2') && ($access ne 'F')) {
93: $ENV{'user.error.msg'}="$requrl:bre:1:1:Access Denied";
94: return HTTP_NOT_ACCEPTABLE;
95: }
96: }
97: if ($requrl =~ m|^/prtspool/|) {
98: my $start='/prtspool/'.$ENV{'user.name'}.'_'.
99: $ENV{'user.domain'};
100: if ($requrl !~ /^\Q$start\E/) {
101: $ENV{'user.error.msg'}="$requrl:bre:1:1:Access Denied";
102: return HTTP_NOT_ACCEPTABLE;
103: }
104: }
105: # ------------------------------------------------------------- This is allowed
106: if ($ENV{'request.course.id'}) {
107: &Apache::lonnet::countacc($requrl);
108: $requrl=~/\.(\w+)$/;
109: if ((&Apache::loncommon::fileembstyle($1) eq 'ssi') ||
110: ($requrl=~/^\/adm\/.*\/(aboutme|navmaps|smppg|bulletinboard)(\?|$)/) ||
111: ($requrl=~/^\/adm\/wrapper\//) ||
112: ($requrl=~/^\/public\/.*\/syllabus$/)) {
113: # ------------------------------------- This is serious stuff, get symb and log
114: my $query=$r->args;
115: my $symb;
116: if ($query) {
117: &Apache::loncommon::get_unprocessed_cgi($query,['symb']);
118: }
119: if ($ENV{'form.symb'}) {
120: $symb=&Apache::lonnet::symbclean($ENV{'form.symb'});
121: if (&Apache::lonnet::symbverify($symb,$requrl)) {
122: my ($map,$mid,$murl)=split(/\_\_\_/,$symb);
123: &Apache::lonnet::symblist($map,$murl => $mid,
124: 'last_known' => $murl);
125: } else {
126: $r->log_reason('Invalid symb for '.$requrl.': '.
127: $symb);
128: $ENV{'user.error.msg'}=
129: "$requrl:bre:1:1:Invalid Access";
130: return HTTP_NOT_ACCEPTABLE;
131: }
132: } else {
133: $symb=&Apache::lonnet::symbread($requrl);
134: my ($map,$mid,$murl)=split(/\_\_\_/,$symb);
135: &Apache::lonnet::symblist($map,$murl => $mid,
136: 'last_known' => $murl);
137: }
138: $ENV{'request.symb'}=$symb;
139: &Apache::lonnet::courseacclog($symb);
140: } else {
141: # ------------------------------------------------------- This is other content
142: &Apache::lonnet::courseacclog($requrl);
143: }
144: }
145: return OK;
146: } else {
147: $r->log_reason("Cookie $handle not valid", $r->filename)
148: };
149: }
150:
151: # -------------------------------------------- See if this is a public resource
152: if ($requrl=~m|^/public/|
153: || (&Apache::lonnet::metadata($requrl,'copyright') eq 'public')) {
154: &Apache::lonnet::logthis('Granting public access: '.$requrl);
155: my $buffer;
156: $r->read($buffer,$r->header_in('Content-length'),0);
157: &Apache::loncommon::get_unprocessed_cgi($buffer);
158: $ENV{'user.name'}='public';
159: $ENV{'user.domain'}='public';
160: $ENV{'request.state'} = "published";
161: $ENV{'request.publicaccess'} = 1;
162: $ENV{'request.filename'} = $r->filename;
163: return OK;
164: }
165: # -------------------------------------------------------------- Not authorized
166: $requrl=~/\.(\w+)$/;
167: if ((&Apache::loncommon::fileembstyle($1) eq 'ssi') ||
168: ($requrl=~/^\/adm\/(roles|logout|email|menu|remote)/) ||
169: ($requrl=~m|^/prtspool/|)) {
170: # -------------------------- Store where they wanted to go and get login screen
171: $ENV{'request.querystring'}=$r->args;
172: $ENV{'request.firsturl'}=$requrl;
173: return FORBIDDEN;
174: } else {
175: # --------------------------------------------------------------------- Goodbye
176: return HTTP_BAD_REQUEST;
177: }
178: }
179:
180: 1;
181: __END__
182:
183: =head1 NAME
184:
185: Apache::lonacc - Cookie Based Access Handler
186:
187: =head1 SYNOPSIS
188:
189: Invoked (for various locations) by /etc/httpd/conf/srm.conf:
190:
191: PerlAccessHandler Apache::lonacc
192:
193: =head1 INTRODUCTION
194:
195: This module enables cookie based authentication and is used
196: to control access for many different LON-CAPA URIs.
197:
198: Whenever the client sends the cookie back to the server,
199: this cookie is handled by either lonacc.pm or loncacc.pm
200: (see srm.conf for what is invoked when). If
201: the cookie is missing or invalid, the user is re-challenged
202: for login information.
203:
204: This is part of the LearningOnline Network with CAPA project
205: described at http://www.lon-capa.org.
206:
207: =head1 HANDLER SUBROUTINE
208:
209: This routine is called by Apache and mod_perl.
210:
211: =over 4
212:
213: =item *
214:
215: transfer profile into environment
216:
217: =item *
218:
219: load POST parameters
220:
221: =item *
222:
223: check access
224:
225: =item *
226:
227: if allowed, get symb, log, generate course statistics if applicable
228:
229: =item *
230:
231: otherwise return error
232:
233: =item *
234:
235: see if public resource
236:
237: =item *
238:
239: store attempted access
240:
241: =back
242:
243: =cut
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>