1: # The LearningOnline Network
2: # User Authentication Module
3: #
4: # $Id: lonauth.pm,v 1.101.10.1 2010/09/15 18:28:45 raeburn Exp $
5: #
6: # Copyright Michigan State University Board of Trustees
7: #
8: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
9: #
10: # LON-CAPA is free software; you can redistribute it and/or modify
11: # it under the terms of the GNU General Public License as published by
12: # the Free Software Foundation; either version 2 of the License, or
13: # (at your option) any later version.
14: #
15: # LON-CAPA is distributed in the hope that it will be useful,
16: # but WITHOUT ANY WARRANTY; without even the implied warranty of
17: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18: # GNU General Public License for more details.
19: #
20: # You should have received a copy of the GNU General Public License
21: # along with LON-CAPA; if not, write to the Free Software
22: # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
23: #
24: # /home/httpd/html/adm/gpl.txt
25: #
26: # http://www.lon-capa.org/
27: #
28:
29: package Apache::lonauth;
30:
31: use strict;
32: use LONCAPA;
33: use Apache::Constants qw(:common);
34: use CGI qw(:standard);
35: use DynaLoader; # for Crypt::DES version
36: use Crypt::DES;
37: use Apache::loncommon();
38: use Apache::lonnet;
39: use Apache::lonmenu();
40: use Apache::createaccount;
41: use Fcntl qw(:flock);
42: use Apache::lonlocal;
43: use HTML::Entities;
44:
45: # ------------------------------------------------------------ Successful login
46: sub success {
47: my ($r, $username, $domain, $authhost, $lowerurl, $extra_env,
48: $form) = @_;
49:
50: # ------------------------------------------------------------ Get cookie ready
51: my $cookie =
52: &Apache::loncommon::init_user_environment($r, $username, $domain,
53: $authhost, $form,
54: {'extra_env' => $extra_env,});
55:
56: my $public=($username eq 'public' && $domain eq 'public');
57:
58: if ($public or $lowerurl eq 'noredirect') { return $cookie; }
59:
60: # -------------------------------------------------------------------- Log this
61:
62: &Apache::lonnet::log($domain,$username,$authhost,
63: "Login $ENV{'REMOTE_ADDR'}");
64:
65: # ------------------------------------------------- Check for critical messages
66:
67: my @what=&Apache::lonnet::dump('critical',$domain,$username);
68: if ($what[0]) {
69: if (($what[0] ne 'con_lost') && ($what[0]!~/^error\:/)) {
70: $lowerurl='/adm/email?critical=display';
71: }
72: }
73:
74: # ------------------------------------------------------------ Get cookie ready
75: $cookie="lonID=$cookie; path=/";
76: # -------------------------------------------------------- Menu script and info
77: my $destination = $lowerurl;
78:
79: if (defined($form->{role})) {
80: my $envkey = 'user.role.'.$form->{role};
81: my $now=time;
82: my $then=$env{'user.login.time'};
83: my $refresh=$env{'user.refresh.time'};
84: if (exists($env{$envkey})) {
85: my ($role,$where,$trolecode,$tstart,$tend,$tremark,$tstatus);
86: &Apache::lonnet::role_status($envkey,$then,$refresh,$now,\$role,\$where,
87: \$trolecode,\$tstatus,\$tstart,\$tend);
88: if ($tstatus eq 'is') {
89: $destination .= ($destination =~ /\?/) ? '&' : '?';
90: my $newrole = &HTML::Entities::encode($form->{role},'"<>&');
91: $destination .= 'selectrole=1&'.$newrole.'=1';
92: }
93: }
94: }
95: if (defined($form->{symb})) {
96: my $destsymb = $form->{symb};
97: $destination .= ($destination =~ /\?/) ? '&' : '?';
98: if ($destsymb =~ /___/) {
99: # FIXME Need to deal with encrypted symbs and urls as needed.
100: my ($map,$resid,$desturl)=split(/___/,$destsymb);
101: unless ($desturl=~/^(adm|uploaded|editupload|public)/) {
102: $desturl = &Apache::lonnet::clutter($desturl);
103: }
104: $desturl = &HTML::Entities::encode($desturl,'"<>&');
105: $destsymb = &HTML::Entities::encode($destsymb,'"<>&');
106: $destination .= '&destinationurl='.$desturl.
107: '&destsymb='.$destsymb;
108: } else {
109: $destsymb = &HTML::Entities::encode($destsymb,'"<>&');
110: $destination .= '&destinationurl='.$destsymb;
111: }
112: }
113:
114: my $windowinfo=&Apache::lonmenu::open($env{'browser.os'});
115: my $startupremote=&Apache::lonmenu::startupremote($destination);
116: my $remoteinfo=&Apache::lonmenu::load_remote_msg($lowerurl);
117: my $setflags=&Apache::lonmenu::setflags();
118: my $maincall=&Apache::lonmenu::maincall();
119: my $brcrum = [{'href' => '',
120: 'text' => 'Successful Login'},];
121: my $start_page=&Apache::loncommon::start_page('Successful Login',
122: $startupremote,
123: {'no_inline_link' => 1,
124: 'bread_crumbs' => $brcrum,});
125: my $end_page =&Apache::loncommon::end_page();
126:
127: my $continuelink;
128: if ($env{'environment.remote'} eq 'off') {
129: $continuelink='<a href="'.$destination.'">'.&mt('Continue').'</a>';
130: }
131: # ------------------------------------------------- Output for successful login
132:
133: &Apache::loncommon::content_type($r,'text/html');
134: $r->header_out('Set-cookie' => $cookie);
135: $r->send_http_header;
136:
137: my %lt=&Apache::lonlocal::texthash(
138: 'wel' => 'Welcome',
139: 'mes' => 'Welcome to the Learning<i>Online</i> Network with CAPA. Please wait while your session is being set up.',
140: 'pro' => 'Login problems?',
141: 'log' => 'loginproblems.html',
142: );
143: $r->print(<<ENDSUCCESS);
144: $start_page
145: $setflags
146: $windowinfo
147: <h1>$lt{'wel'}</h1>
148: $lt{'mes'}<p>
149: <a href="/adm/$lt{'log'}">$lt{'pro'}</a></p>
150: $remoteinfo
151: $maincall
152: $continuelink
153: $end_page
154: ENDSUCCESS
155: }
156:
157: # --------------------------------------------------------------- Failed login!
158:
159: sub failed {
160: my ($r,$message,$form) = @_;
161: my $start_page = &Apache::loncommon::start_page('Unsuccessful Login',undef,
162: {'no_inline_link' => 1,});
163: my $retry = '/adm/login?username='.$form->{'uname'}.
164: '&domain='.$form->{'udom'};
165: if (exists($form->{role})) {
166: $retry .= '&role='.$form->{role};
167: }
168: if (exists($form->{symb})) {
169: $retry .= '&symb='.$form->{symb};
170: }
171: my $end_page = &Apache::loncommon::end_page();
172: &Apache::loncommon::content_type($r,'text/html');
173: $r->send_http_header;
174: $r->print(
175: $start_page
176: .'<h1>'.&mt('Sorry ...').'</h1>'
177: .'<p class="LC_warning">'.&mt($message).'</p>'
178: .'<p>'.&mt('Please [_1]log in again[_2].','<a href="'.$retry.'">','</a>')
179: .'</p>'
180: .'<p><a href="/adm/loginproblems.html">'.&mt('Login problems?').'</a></p>'
181: .$end_page
182: );
183: }
184:
185: # ------------------------------------------------------------------ Rerouting!
186:
187: sub reroute {
188: my ($r) = @_;
189: &Apache::loncommon::content_type($r,'text/html');
190: $r->send_http_header;
191: my $msg='<h1>'.&mt('Sorry ...').'</h1>'
192: .&mt('Please [_1]log in again[_2].');
193: &Apache::loncommon::simple_error_page($r,'Rerouting',$msg);
194: }
195:
196: # ---------------------------------------------------------------- Main handler
197:
198: sub handler {
199: my $r = shift;
200: my $form;
201: # Are we re-routing?
202: if (-e '/home/httpd/html/lon-status/reroute.txt') {
203: &reroute($r);
204: return OK;
205: }
206:
207: &Apache::lonlocal::get_language_handle($r);
208:
209: # -------------------------------- Prevent users from attempting to login twice
210: my $handle = &Apache::lonnet::check_for_valid_session($r);
211: if ($handle ne '') {
212: # Indeed, a valid token is found
213: &Apache::loncommon::content_type($r,'text/html');
214: $r->send_http_header;
215: my $start_page =
216: &Apache::loncommon::start_page('Already logged in');
217: my $end_page =
218: &Apache::loncommon::end_page();
219: $r->print(
220: $start_page
221: .'<h1>'.&mt('You are already logged in!').'</h1>'
222: .'<p>'.&mt('Please either [_1]continue the current session[_2] or [_3]log out[_4].'
223: ,'<a href="/adm/roles">','</a>','<a href="/adm/logout">','</a>')
224: .'</p>'
225: .'<p><a href="/adm/loginproblems.html">'.&mt('Login problems?').'</a></p>'
226: .$end_page
227: );
228: return OK;
229: }
230:
231: # ---------------------------------------------------- No valid token, continue
232:
233:
234: my $buffer;
235: if ($r->header_in('Content-length') > 0) {
236: $r->read($buffer,$r->header_in('Content-length'),0);
237: }
238: my %form;
239: foreach my $pair (split(/&/,$buffer)) {
240: my ($name,$value) = split(/=/,$pair);
241: $value =~ tr/+/ /;
242: $value =~ s/%([a-fA-F0-9][a-fA-F0-9])/pack("C",hex($1))/eg;
243: $form{$name}=$value;
244: }
245:
246: if ((!$form{'uname'}) || (!$form{'upass0'}) || (!$form{'udom'})) {
247: &failed($r,'Username, password and domain need to be specified.',
248: \%form);
249: return OK;
250: }
251:
252: # split user logging in and "su"-user
253:
254: ($form{'uname'},$form{'suname'})=split(/\:/,$form{'uname'});
255: $form{'uname'} = &LONCAPA::clean_username($form{'uname'});
256: $form{'suname'}= &LONCAPA::clean_username($form{'suname'});
257: $form{'udom'} = &LONCAPA::clean_domain( $form{'udom'});
258:
259: my $role = $r->dir_config('lonRole');
260: my $domain = $r->dir_config('lonDefDomain');
261: my $prodir = $r->dir_config('lonUsersDir');
262: my $contact_name = &mt('LON-CAPA helpdesk');
263:
264: # ---------------------------------------- Get the information from login token
265:
266: my $tmpinfo=Apache::lonnet::reply('tmpget:'.$form{'logtoken'},
267: $form{'serverid'});
268:
269: if (($tmpinfo=~/^error/) || ($tmpinfo eq 'con_lost')) {
270: &failed($r,'Information needed to verify your login information is missing, inaccessible or expired.',\%form);
271: return OK;
272: } else {
273: my $reply = &Apache::lonnet::reply('tmpdel:'.$form{'logtoken'},
274: $form{'serverid'});
275: if ( $reply ne 'ok' ) {
276: &failed($r,'Session could not be opened.',\%form);
277: &Apache::lonnet::logthis("ERROR got a reply of $reply when trying to contact ". $form{'serverid'}." to get login token");
278: return OK;
279: }
280: }
281:
282: if (!&Apache::lonnet::domain($form{'udom'})) {
283: &failed($r,'The domain you provided is not a valid LON-CAPA domain.',\%form);
284: return OK;
285: }
286:
287: my ($key,$firsturl,$rolestr,$symbstr)=split(/&/,$tmpinfo);
288: if ($rolestr) {
289: $rolestr = &unescape($rolestr);
290: }
291: if ($symbstr) {
292: $symbstr= &unescape($symbstr);
293: }
294: if ($rolestr =~ /^role=/) {
295: (undef,$form{'role'}) = split('=',$rolestr);
296: }
297: if ($symbstr =~ /^symb=/) {
298: (undef,$form{'symb'}) = split('=',$symbstr);
299: }
300:
301: my $keybin=pack("H16",$key);
302:
303: my $cipher;
304: if ($Crypt::DES::VERSION>=2.03) {
305: $cipher=new Crypt::DES $keybin;
306: }
307: else {
308: $cipher=new DES $keybin;
309: }
310: my $upass='';
311: for (my $i=0;$i<=2;$i++) {
312: my $chunk=
313: $cipher->decrypt(unpack("a8",pack("H16",substr($form{'upass'.$i},0,16))));
314:
315: $chunk.=
316: $cipher->decrypt(unpack("a8",pack("H16",substr($form{'upass'.$i},16,16))));
317:
318: $chunk=substr($chunk,1,ord(substr($chunk,0,1)));
319: $upass.=$chunk;
320: }
321:
322: # ---------------------------------------------------------------- Authenticate
323: my @cancreate;
324: my %domconfig = &Apache::lonnet::get_dom('configuration',['usercreation'],$form{'udom'});
325: if (ref($domconfig{'usercreation'}) eq 'HASH') {
326: if (ref($domconfig{'usercreation'}{'cancreate'}) eq 'HASH') {
327: if (ref($domconfig{'usercreation'}{'cancreate'}{'selfcreate'}) eq 'ARRAY') {
328: @cancreate = @{$domconfig{'usercreation'}{'cancreate'}{'selfcreate'}};
329: } elsif (($domconfig{'usercreation'}{'cancreate'}{'selfcreate'} ne 'none') &&
330: ($domconfig{'usercreation'}{'cancreate'}{'selfcreate'} ne '')) {
331: @cancreate = ($domconfig{'usercreation'}{'cancreate'}{'selfcreate'});
332: }
333: }
334: }
335: my $defaultauth;
336: if (grep(/^login$/,@cancreate)) {
337: $defaultauth = 1;
338: }
339: my $uname = $form{'uname'};
340: my $authhost=Apache::lonnet::authenticate($uname,$upass,
341: $form{'udom'},$defaultauth);
342:
343: # --------------------------------------------------------------------- Failed?
344:
345: if ($authhost eq 'no_host') {
346: my $lc_uname = lc($form{'uname'});
347: if ($uname eq $lc_uname) {
348: &failed($r,'Username and/or password could not be authenticated.',
349: \%form);
350: return OK;
351: } else {
352: $authhost=Apache::lonnet::authenticate($lc_uname,$upass,
353: $form{'udom'},$defaultauth);
354: if ($authhost eq 'no_host') {
355: &failed($r,'Username (in lower case) and/or password could not be authenticated.',
356: \%form);
357: return OK;
358: } elsif ($authhost eq 'no_account_on_host') {
359: &create_account($r,\%form,\@cancreate,$lc_uname,$contact_name);
360: return OK;
361: } else {
362: $form{'uname'} = $lc_uname;
363: }
364: }
365: } elsif ($authhost eq 'no_account_on_host') {
366: &create_account($r,\%form,\@cancreate,$uname);
367: return OK;
368: }
369:
370: if (($firsturl eq '') ||
371: ($firsturl=~/^\/adm\/(logout|remote)/)) {
372: $firsturl='/adm/roles';
373: }
374: # --------------------------------- Are we attempting to login as somebody else?
375: if ($form{'suname'}) {
376: # ------------ see if the original user has enough privileges to pull this stunt
377: if (&Apache::lonnet::privileged($form{'uname'},$form{'udom'})) {
378: # ---------------------------------------------------- see if the su-user exists
379: unless (&Apache::lonnet::homeserver($form{'suname'},$form{'udom'})
380: eq 'no_host') {
381: &Apache::lonnet::logthis(&Apache::lonnet::homeserver($form{'suname'},$form{'udom'}));
382: # ------------------------------ see if the su-user is not too highly privileged
383: unless (&Apache::lonnet::privileged($form{'suname'},$form{'udom'})) {
384: # -------------------------------------------------------- actually switch users
385: &Apache::lonnet::logperm('User '.$form{'uname'}.' at '.$form{'udom'}.
386: ' logging in as '.$form{'suname'});
387: $form{'uname'}=$form{'suname'};
388: } else {
389: &Apache::lonnet::logthis('Attempted switch user to privileged user');
390: }
391: }
392: } else {
393: &Apache::lonnet::logthis('Non-privileged user attempting switch user');
394: }
395: }
396:
397: if ($r->dir_config("lonBalancer") eq 'yes') {
398: &success($r,$form{'uname'},$form{'udom'},$authhost,'noredirect',undef,
399: \%form);
400: $r->internal_redirect('/adm/switchserver');
401: } else {
402: &success($r,$form{'uname'},$form{'udom'},$authhost,$firsturl,undef,
403: \%form);
404: }
405: return OK;
406: }
407:
408: sub create_account {
409: my ($r,$form,$cancreate,$uname,$contact_name) = @_;
410: return unless((ref($form) eq 'HASH') && (ref($cancreate) eq 'ARRAY'));
411: my %domconfig =
412: &Apache::lonnet::get_dom('configuration',['usercreation'],$form->{'udom'});
413: if (grep(/^login$/,@{$cancreate})) {
414: my $start_page =
415: &Apache::loncommon::start_page('Create a user account in LON-CAPA',
416: '',{'no_inline_link' => 1,});
417: my $domdesc = &Apache::lonnet::domain($form->{'udom'},'description');
418: my $lonhost = $r->dir_config('lonHostID');
419: my $origmail = $Apache::lonnet::perlvar{'lonSupportEMail'};
420: my $contacts =
421: &Apache::loncommon::build_recipient_list(undef,'helpdeskmail',
422: $form->{'udom'},$origmail);
423: my ($contact_email) = split(',',$contacts);
424: my $output =
425: &Apache::createaccount::username_check($uname,$form->{'udom'},
426: $domdesc,'',$lonhost,
427: $contact_email,$contact_name);
428: &Apache::loncommon::content_type($r,'text/html');
429: $r->send_http_header;
430: &Apache::createaccount::print_header($r,$start_page);
431: $r->print('<h3>'.&mt('Account creation').'</h3>'.
432: &mt('Although your username and password were authenticated, you do not currently have a LON-CAPA account at this institution.').'<br />'.
433: $output.&Apache::loncommon::end_page());
434: } else {
435: &failed($r,'Although your username and password were authenticated, you do not currently have a LON-CAPA account in this domain, and you are not permitted to create one.',$form);
436: }
437: return;
438: }
439:
440: 1;
441: __END__
442:
443:
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>