1: # The LearningOnline Network
2: # User Authentication Module
3: #
4: # $Id: lonauth.pm,v 1.121.2.11 2014/05/04 15:16:10 raeburn Exp $
5: #
6: # Copyright Michigan State University Board of Trustees
7: #
8: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
9: #
10: # LON-CAPA is free software; you can redistribute it and/or modify
11: # it under the terms of the GNU General Public License as published by
12: # the Free Software Foundation; either version 2 of the License, or
13: # (at your option) any later version.
14: #
15: # LON-CAPA is distributed in the hope that it will be useful,
16: # but WITHOUT ANY WARRANTY; without even the implied warranty of
17: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18: # GNU General Public License for more details.
19: #
20: # You should have received a copy of the GNU General Public License
21: # along with LON-CAPA; if not, write to the Free Software
22: # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
23: #
24: # /home/httpd/html/adm/gpl.txt
25: #
26: # http://www.lon-capa.org/
27: #
28:
29: package Apache::lonauth;
30:
31: use strict;
32: use LONCAPA;
33: use Apache::Constants qw(:common);
34: use CGI qw(:standard);
35: use DynaLoader; # for Crypt::DES version
36: use Crypt::DES;
37: use Apache::loncommon();
38: use Apache::lonnet;
39: use Apache::lonmenu();
40: use Apache::createaccount;
41: use Fcntl qw(:flock);
42: use Apache::lonlocal;
43: use Apache::File();
44: use HTML::Entities;
45:
46: # ------------------------------------------------------------ Successful login
47: sub success {
48: my ($r, $username, $domain, $authhost, $lowerurl, $extra_env,
49: $form) = @_;
50:
51: # ------------------------------------------------------------ Get cookie ready
52: my $cookie =
53: &Apache::loncommon::init_user_environment($r, $username, $domain,
54: $authhost, $form,
55: {'extra_env' => $extra_env,});
56:
57: my $public=($username eq 'public' && $domain eq 'public');
58:
59: if ($public or $lowerurl eq 'noredirect') { return $cookie; }
60:
61: # -------------------------------------------------------------------- Log this
62:
63: &Apache::lonnet::log($domain,$username,$authhost,
64: "Login $ENV{'REMOTE_ADDR'}");
65:
66: # ------------------------------------------------- Check for critical messages
67:
68: my @what=&Apache::lonnet::dump('critical',$domain,$username);
69: if ($what[0]) {
70: if (($what[0] ne 'con_lost') && ($what[0]!~/^error\:/)) {
71: $lowerurl='/adm/email?critical=display';
72: }
73: }
74:
75: # ------------------------------------------------------------ Get cookie ready
76: $cookie="lonID=$cookie; path=/";
77: # -------------------------------------------------------- Menu script and info
78: my $destination = $lowerurl;
79:
80: if (defined($form->{role})) {
81: my $envkey = 'user.role.'.$form->{role};
82: my $now=time;
83: my $then=$env{'user.login.time'};
84: my $refresh=$env{'user.refresh.time'};
85: my $update=$env{'user.update.time'};
86: if (!$update) {
87: $update = $then;
88: }
89: if (exists($env{$envkey})) {
90: my ($role,$where,$trolecode,$tstart,$tend,$tremark,$tstatus);
91: &Apache::lonnet::role_status($envkey,$update,$refresh,$now,\$role,\$where,
92: \$trolecode,\$tstatus,\$tstart,\$tend);
93: if ($tstatus eq 'is') {
94: $destination .= ($destination =~ /\?/) ? '&' : '?';
95: my $newrole = &HTML::Entities::encode($form->{role},'"<>&');
96: $destination .= 'selectrole=1&'.$newrole.'=1';
97: }
98: }
99: }
100: if (defined($form->{symb})) {
101: my $destsymb = $form->{symb};
102: $destination .= ($destination =~ /\?/) ? '&' : '?';
103: if ($destsymb =~ /___/) {
104: # FIXME Need to deal with encrypted symbs and urls as needed.
105: my ($map,$resid,$desturl)=split(/___/,$destsymb);
106: unless ($desturl=~/^(adm|editupload|public)/) {
107: $desturl = &Apache::lonnet::clutter($desturl);
108: }
109: $desturl = &HTML::Entities::encode($desturl,'"<>&');
110: $destsymb = &HTML::Entities::encode($destsymb,'"<>&');
111: $destination .= 'destinationurl='.$desturl.
112: '&destsymb='.$destsymb;
113: } else {
114: $destsymb = &HTML::Entities::encode($destsymb,'"<>&');
115: $destination .= 'destinationurl='.$destsymb;
116: }
117: }
118: if ($destination =~ m{^/adm/roles}) {
119: $destination .= ($destination =~ /\?/) ? '&' : '?';
120: $destination .= 'source=login';
121: }
122:
123: my $windowinfo=&Apache::lonmenu::open($env{'browser.os'});
124: my $startupremote=&Apache::lonmenu::startupremote($destination);
125: my $remoteinfo=&Apache::lonmenu::load_remote_msg($lowerurl);
126: my $setflags=&Apache::lonmenu::setflags();
127: my $maincall=&Apache::lonmenu::maincall();
128: my $brcrum = [{'href' => '',
129: 'text' => 'Successful Login'},];
130: my $start_page=&Apache::loncommon::start_page('Successful Login',
131: $startupremote,
132: {'no_inline_link' => 1,
133: 'bread_crumbs' => $brcrum,});
134: my $end_page =&Apache::loncommon::end_page();
135:
136: my $continuelink;
137: if ($env{'environment.remote'} eq 'off') {
138: $continuelink='<a href="'.$destination.'">'.&mt('Continue').'</a>';
139: }
140: # ------------------------------------------------- Output for successful login
141:
142: &Apache::loncommon::content_type($r,'text/html');
143: $r->header_out('Set-cookie' => $cookie);
144: $r->send_http_header;
145:
146: my %lt=&Apache::lonlocal::texthash(
147: 'wel' => 'Welcome',
148: 'pro' => 'Login problems?',
149: );
150: my $loginhelp = &loginhelpdisplay($domain);
151: if ($loginhelp) {
152: $loginhelp = '<p><a href="'.$loginhelp.'">'.$lt{'pro'}.'</a></p>';
153: }
154:
155: my $welcome = &mt('Welcome to the Learning[_1]Online[_2] Network with CAPA. Please wait while your session is being set up.','<i>','</i>');
156: $r->print(<<ENDSUCCESS);
157: $start_page
158: $setflags
159: $windowinfo
160: <h1>$lt{'wel'}</h1>
161: $welcome
162: $loginhelp
163: $remoteinfo
164: $maincall
165: $continuelink
166: $end_page
167: ENDSUCCESS
168: return;
169: }
170:
171: # --------------------------------------------------------------- Failed login!
172:
173: sub failed {
174: my ($r,$message,$form) = @_;
175: (undef,undef,undef,my $clientmathml,my $clientunicode) =
176: &Apache::loncommon::decode_user_agent();
177: my $args = {};
178: if ($clientunicode && !$clientmathml) {
179: $args = {'browser.unicode' => 1};
180: }
181:
182: my $start_page = &Apache::loncommon::start_page('Unsuccessful Login',undef,$args);
183: my $uname = &Apache::loncommon::cleanup_html($form->{'uname'});
184: my $udom = &Apache::loncommon::cleanup_html($form->{'udom'});
185: if (&Apache::lonnet::domain($udom,'description') eq '') {
186: undef($udom);
187: }
188: my $retry = '/adm/login';
189: if ($uname eq $form->{'uname'}) {
190: $retry .= '?username='.$uname;
191: }
192: if ($udom) {
193: $retry .= (($retry=~/\?/)?'&':'?').'domain='.$udom;
194: }
195: if (exists($form->{role})) {
196: my $role = &Apache::loncommon::cleanup_html($form->{role});
197: if ($role ne '') {
198: $retry .= (($retry=~/\?/)?'&':'?').'role='.$role;
199: }
200: }
201: if (exists($form->{symb})) {
202: my $symb = &Apache::loncommon::cleanup_html($form->{symb});
203: if ($symb ne '') {
204: $retry .= (($retry=~/\?/)?'&':'?').'symb='.$symb;
205: }
206: }
207: my $end_page = &Apache::loncommon::end_page();
208: &Apache::loncommon::content_type($r,'text/html');
209: $r->send_http_header;
210: my @actions =
211: (&mt('Please [_1]log in again[_2].','<a href="'.$retry.'">','</a>'));
212: my $loginhelp = &loginhelpdisplay($udom);
213: if ($loginhelp) {
214: push(@actions, '<a href="'.$loginhelp.'">'.&mt('Login problems?').'</a>');
215: }
216: #FIXME: link to helpdesk might be added here
217:
218: $r->print(
219: $start_page
220: .'<h2>'.&mt('Sorry ...').'</h2>'
221: .&Apache::lonhtmlcommon::confirm_success(&mt($message),1).'<br /><br />'
222: .&Apache::lonhtmlcommon::actionbox(\@actions)
223: .$end_page
224: );
225: }
226:
227: # ------------------------------------------------------------------ Rerouting!
228:
229: sub reroute {
230: my ($r) = @_;
231: &Apache::loncommon::content_type($r,'text/html');
232: $r->send_http_header;
233: my $msg='<b>'.&mt('Sorry ...').'</b><br />'
234: .&mt('Please [_1]log in again[_2].');
235: &Apache::loncommon::simple_error_page($r,'Rerouting',$msg,{'no_auto_mt_msg' => 1});
236: }
237:
238: # ---------------------------------------------------------------- Main handler
239:
240: sub handler {
241: my $r = shift;
242: my $londocroot = $r->dir_config('lonDocRoot');
243: my $form;
244: # Are we re-routing?
245: if (-e "$londocroot/lon-status/reroute.txt") {
246: &reroute($r);
247: return OK;
248: }
249:
250: &Apache::lonlocal::get_language_handle($r);
251:
252: # -------------------------------- Prevent users from attempting to login twice
253: my $handle = &Apache::lonnet::check_for_valid_session($r);
254: if ($handle ne '') {
255: my $lonidsdir=$r->dir_config('lonIDsDir');
256: if ($handle=~/^publicuser\_/) {
257: # For "public user" - remove it, we apparently really want to login
258: unlink($r->dir_config('lonIDsDir')."/$handle.id");
259: } else {
260: # Indeed, a valid token is found
261: &Apache::lonnet::transfer_profile_to_env($lonidsdir,$handle);
262: &Apache::loncommon::content_type($r,'text/html');
263: $r->send_http_header;
264: my $start_page =
265: &Apache::loncommon::start_page('Already logged in');
266: my $end_page =
267: &Apache::loncommon::end_page();
268: my $dest = '/adm/roles';
269: if ($env{'form.firsturl'} ne '') {
270: $dest = $env{'form.firsturl'};
271: }
272: $r->print(
273: $start_page
274: .'<p class="LC_warning">'.&mt('You are already logged in!').'</p>'
275: .'<p>'.&mt('Please either [_1]continue the current session[_2] or [_3]log out[_4].'
276: ,'<a href="'.$dest.'">','</a>','<a href="/adm/logout">','</a>')
277: .'</p>'
278: .$end_page
279: );
280: return OK;
281: }
282: }
283:
284: # ---------------------------------------------------- No valid token, continue
285:
286:
287: my $buffer;
288: if ($r->header_in('Content-length') > 0) {
289: $r->read($buffer,$r->header_in('Content-length'),0);
290: }
291: my %form;
292: foreach my $pair (split(/&/,$buffer)) {
293: my ($name,$value) = split(/=/,$pair);
294: $value =~ tr/+/ /;
295: $value =~ s/%([a-fA-F0-9][a-fA-F0-9])/pack("C",hex($1))/eg;
296: $form{$name}=$value;
297: }
298:
299: if ((!$form{'uname'}) || (!$form{'upass0'}) || (!$form{'udom'})) {
300: &failed($r,'Username, password and domain need to be specified.',
301: \%form);
302: return OK;
303: }
304:
305: # split user logging in and "su"-user
306:
307: ($form{'uname'},$form{'suname'})=split(/\:/,$form{'uname'});
308: $form{'uname'} = &LONCAPA::clean_username($form{'uname'});
309: $form{'suname'}= &LONCAPA::clean_username($form{'suname'});
310: $form{'udom'} = &LONCAPA::clean_domain( $form{'udom'});
311:
312: my $role = $r->dir_config('lonRole');
313: my $domain = $r->dir_config('lonDefDomain');
314: my $prodir = $r->dir_config('lonUsersDir');
315: my $contact_name = &mt('LON-CAPA helpdesk');
316:
317: # ---------------------------------------- Get the information from login token
318:
319: my $tmpinfo=Apache::lonnet::reply('tmpget:'.$form{'logtoken'},
320: $form{'serverid'});
321:
322: my %sessiondata;
323: if ($form{'iptoken'}) {
324: %sessiondata = &Apache::lonnet::tmpget($form{'iptoken'});
325: my $delete = &Apache::lonnet::tmpdel($form{'iptoken'});
326: }
327:
328: if (($tmpinfo=~/^error/) || ($tmpinfo eq 'con_lost') ||
329: ($tmpinfo eq 'no_such_host')) {
330: &failed($r,'Information needed to verify your login information is missing, inaccessible or expired.',\%form);
331: return OK;
332: } else {
333: my $reply = &Apache::lonnet::reply('tmpdel:'.$form{'logtoken'},
334: $form{'serverid'});
335: if ( $reply ne 'ok' ) {
336: &failed($r,'Session could not be opened.',\%form);
337: &Apache::lonnet::logthis("ERROR got a reply of $reply when trying to contact ". $form{'serverid'}." to get login token");
338: return OK;
339: }
340: }
341:
342: if (!&Apache::lonnet::domain($form{'udom'})) {
343: &failed($r,'The domain you provided is not a valid LON-CAPA domain.',\%form);
344: return OK;
345: }
346:
347: my ($key,$firsturl,$rolestr,$symbstr)=split(/&/,$tmpinfo);
348: if ($rolestr) {
349: $rolestr = &unescape($rolestr);
350: }
351: if ($symbstr) {
352: $symbstr= &unescape($symbstr);
353: }
354: if ($rolestr =~ /^role=/) {
355: (undef,$form{'role'}) = split('=',$rolestr);
356: }
357: if ($symbstr =~ /^symb=/) {
358: (undef,$form{'symb'}) = split('=',$symbstr);
359: }
360:
361: my $keybin=pack("H16",$key);
362:
363: my $cipher;
364: if ($Crypt::DES::VERSION>=2.03) {
365: $cipher=new Crypt::DES $keybin;
366: }
367: else {
368: $cipher=new DES $keybin;
369: }
370: my $upass='';
371: for (my $i=0;$i<=2;$i++) {
372: my $chunk=
373: $cipher->decrypt(unpack("a8",pack("H16",substr($form{'upass'.$i},0,16))));
374:
375: $chunk.=
376: $cipher->decrypt(unpack("a8",pack("H16",substr($form{'upass'.$i},16,16))));
377:
378: $chunk=substr($chunk,1,ord(substr($chunk,0,1)));
379: $upass.=$chunk;
380: }
381:
382: # ---------------------------------------------------------------- Authenticate
383:
384: my %domconfig = &Apache::lonnet::get_dom('configuration',['usercreation'],$form{'udom'});
385: my ($cancreate,$statustocreate) =
386: &Apache::createaccount::get_creation_controls($form{'udom'},$domconfig{'usercreation'});
387: my $defaultauth;
388: if (ref($cancreate) eq 'ARRAY') {
389: if (grep(/^login$/,@{$cancreate})) {
390: $defaultauth = 1;
391: }
392: }
393: my $clientcancheckhost = 1;
394: my $authhost=Apache::lonnet::authenticate($form{'uname'},$upass,
395: $form{'udom'},$defaultauth,
396: $clientcancheckhost);
397:
398: # --------------------------------------------------------------------- Failed?
399:
400: if ($authhost eq 'no_host') {
401: &failed($r,'Username and/or password could not be authenticated.',
402: \%form);
403: return OK;
404: } elsif ($authhost eq 'no_account_on_host') {
405: if ($defaultauth) {
406: my $domdesc = &Apache::lonnet::domain($form{'udom'},'description');
407: unless (&check_can_host($r,\%form,'no_account_on_host',$domdesc)) {
408: return OK;
409: }
410: my $start_page =
411: &Apache::loncommon::start_page('Create a user account in LON-CAPA',
412: '',{'no_inline_link' => 1,});
413: my $lonhost = $r->dir_config('lonHostID');
414: my $origmail = $Apache::lonnet::perlvar{'lonSupportEMail'};
415: my $contacts =
416: &Apache::loncommon::build_recipient_list(undef,'helpdeskmail',
417: $form{'udom'},$origmail);
418: my ($contact_email) = split(',',$contacts);
419: my $output =
420: &Apache::createaccount::username_check($form{'uname'},$form{'udom'},
421: $domdesc,'',$lonhost,
422: $contact_email,$contact_name,
423: undef,$statustocreate);
424: &Apache::loncommon::content_type($r,'text/html');
425: $r->send_http_header;
426: &Apache::createaccount::print_header($r,$start_page);
427: $r->print('<h3>'.&mt('Account creation').'</h3>'.
428: &mt('Although your username and password were authenticated, you do not currently have a LON-CAPA account at this institution.').'<br />'.
429: $output.&Apache::loncommon::end_page());
430: return OK;
431: } else {
432: &failed($r,'Although your username and password were authenticated, you do not currently have a LON-CAPA account in this domain, and you are not permitted to create one.',\%form);
433: return OK;
434: }
435: }
436:
437: if (($firsturl eq '') ||
438: ($firsturl=~/^\/adm\/(logout|remote)/)) {
439: $firsturl='/adm/roles';
440: }
441:
442: my $hosthere;
443: if ($form{'iptoken'}) {
444: if (($sessiondata{'domain'} eq $form{'udom'}) &&
445: ($sessiondata{'username'} eq $form{'uname'})) {
446: $hosthere = 1;
447: }
448: }
449:
450: # --------------------------------- Are we attempting to login as somebody else?
451: if ($form{'suname'}) {
452: # ------------ see if the original user has enough privileges to pull this stunt
453: if (&Apache::lonnet::privileged($form{'uname'},$form{'udom'})) {
454: # ---------------------------------------------------- see if the su-user exists
455: unless (&Apache::lonnet::homeserver($form{'suname'},$form{'udom'})
456: eq 'no_host') {
457: &Apache::lonnet::logthis(&Apache::lonnet::homeserver($form{'suname'},$form{'udom'}));
458: # ------------------------------ see if the su-user is not too highly privileged
459: unless (&Apache::lonnet::privileged($form{'suname'},$form{'udom'})) {
460: # -------------------------------------------------------- actually switch users
461: &Apache::lonnet::logperm('User '.$form{'uname'}.' at '.$form{'udom'}.
462: ' logging in as '.$form{'suname'});
463: $form{'uname'}=$form{'suname'};
464: } else {
465: &Apache::lonnet::logthis('Attempted switch user to privileged user');
466: }
467: }
468: } else {
469: &Apache::lonnet::logthis('Non-privileged user attempting switch user');
470: }
471: }
472:
473: my ($is_balancer,$otherserver);
474:
475: unless ($hosthere) {
476: ($is_balancer,$otherserver) =
477: &Apache::lonnet::check_loadbalancing($form{'uname'},$form{'udom'});
478: }
479:
480: if ($is_balancer) {
481: if (!$otherserver) {
482: ($otherserver) = &Apache::lonnet::choose_server($form{'udom'});
483: }
484: if ($otherserver) {
485: &success($r,$form{'uname'},$form{'udom'},$authhost,'noredirect',undef,
486: \%form);
487: my $switchto = '/adm/switchserver?otherserver='.$otherserver;
488: if (($firsturl) && ($firsturl ne '/adm/switchserver') && ($firsturl ne '/adm/roles')) {
489: $switchto .= '&origurl='.$firsturl;
490: }
491: if ($form{'role'}) {
492: $switchto .= '&role='.$form{'role'};
493: }
494: if ($form{'symb'}) {
495: $switchto .= '&symb='.$form{'symb'};
496: }
497: $r->internal_redirect($switchto);
498: } else {
499: $r->print(&noswitch());
500: }
501: return OK;
502: } else {
503: if (!&check_can_host($r,\%form,$authhost)) {
504: my ($otherserver) = &Apache::lonnet::choose_server($form{'udom'});
505: if ($otherserver) {
506: &success($r,$form{'uname'},$form{'udom'},$authhost,'noredirect',undef,
507: \%form);
508: my $switchto = '/adm/switchserver?otherserver='.$otherserver;
509: if (($firsturl) && ($firsturl ne '/adm/switchserver') && ($firsturl ne '/adm/roles')) {
510: $switchto .= '&origurl='.$firsturl;
511: }
512: if ($form{'role'}) {
513: $switchto .= '&role='.$form{'role'};
514: }
515: if ($form{'symb'}) {
516: $switchto .= '&symb='.$form{'symb'};
517: }
518: $r->internal_redirect($switchto);
519: } else {
520: $r->print(&noswitch());
521: }
522: return OK;
523: }
524:
525: # ------------------------------------------------------- Do the load balancing
526:
527: # ---------------------------------------------------------- Determine own load
528: my $loadlim = $r->dir_config('lonLoadLim');
529: my $loadavg;
530: {
531: my $loadfile=Apache::File->new('/proc/loadavg');
532: $loadavg=<$loadfile>;
533: }
534: $loadavg =~ s/\s.*//g;
535: my $loadpercent=sprintf("%.1f",100*$loadavg/$loadlim);
536: my $userloadpercent=&Apache::lonnet::userload();
537:
538: # ---------------------------------------------------------- Are we overloaded?
539: if ((($userloadpercent>100.0)||($loadpercent>100.0))) {
540: my $unloaded=Apache::lonnet::spareserver($loadpercent,$userloadpercent,1,$form{'udom'});
541: if (!$unloaded) {
542: ($unloaded) = &Apache::lonnet::choose_server($form{'udom'});
543: }
544: if ($unloaded) {
545: &success($r,$form{'uname'},$form{'udom'},$authhost,'noredirect',
546: undef,\%form);
547: $r->internal_redirect('/adm/switchserver?otherserver='.$unloaded.'&origurl='.$firsturl);
548: return OK;
549: }
550: }
551: &success($r,$form{'uname'},$form{'udom'},$authhost,$firsturl,undef,
552: \%form);
553: return OK;
554: }
555: }
556:
557: sub check_can_host {
558: my ($r,$form,$authhost,$domdesc) = @_;
559: return unless (ref($form) eq 'HASH');
560: my $canhost = 1;
561: my $lonhost = $r->dir_config('lonHostID');
562: my $udom = $form->{'udom'};
563: my @intdoms;
564: my $internet_names = &Apache::lonnet::get_internet_names($lonhost);
565: if (ref($internet_names) eq 'ARRAY') {
566: @intdoms = @{$internet_names};
567: }
568: my $uprimary_id = &Apache::lonnet::domain($udom,'primary');
569: my $uint_dom = &Apache::lonnet::internet_dom($uprimary_id);
570: unless ($uint_dom ne '' && grep(/^\Q$uint_dom\E$/,@intdoms)) {
571: my $machine_dom = &Apache::lonnet::host_domain($lonhost);
572: my $hostname = &Apache::lonnet::hostname($lonhost);
573: my $serverhomeID = &Apache::lonnet::get_server_homeID($hostname);
574: my $serverhomedom = &Apache::lonnet::host_domain($serverhomeID);
575: my %defdomdefaults = &Apache::lonnet::get_domain_defaults($serverhomedom);
576: my %udomdefaults = &Apache::lonnet::get_domain_defaults($udom);
577: my $loncaparev;
578: if ($authhost eq 'no_account_on_host') {
579: $loncaparev = &Apache::lonnet::get_server_loncaparev($machine_dom);
580: } else {
581: $loncaparev = &Apache::lonnet::get_server_loncaparev($machine_dom,$lonhost);
582: }
583: $canhost = &Apache::lonnet::can_host_session($udom,$lonhost,$loncaparev,
584: $udomdefaults{'remotesessions'},
585: $defdomdefaults{'hostedsessions'});
586: }
587: unless ($canhost) {
588: if ($authhost eq 'no_account_on_host') {
589: my $checkloginvia = 1;
590: my ($login_host,$hostname) =
591: &Apache::lonnet::choose_server($udom,$checkloginvia);
592: &Apache::loncommon::content_type($r,'text/html');
593: $r->send_http_header;
594: if ($login_host ne '') {
595: my $protocol = $Apache::lonnet::protocol{$login_host};
596: $protocol = 'http' if ($protocol ne 'https');
597: my $newurl = $protocol.'://'.$hostname.'/adm/createaccount';
598: $r->print(&Apache::loncommon::start_page('Create a user account in LON-CAPA').
599: '<h3>'.&mt('Account creation').'</h3>'.
600: &mt('You do not currently have a LON-CAPA account at this institution.').'<br />'.
601: '<p>'.&mt('You will be able to create one by logging into a LON-CAPA server within the [_1] domain.',$domdesc).'</p>'.
602: '<p>'.&mt('[_1]Log in[_2]','<a href="'.$newurl.'">','</a>').
603: &Apache::loncommon::end_page());
604: } else {
605: $r->print(&Apache::loncommon::start_page('Access to LON-CAPA unavailable').
606: '<h3>'.&mt('Account creation unavailable').'</h3>'.
607: &mt('You do not currently have a LON-CAPA account at this institution.').'<br />'.
608: '<p>'.&mt('Currently a LON-CAPA server is not available within the [_1] domain for you to log-in to, to create an account.',$domdesc).'</p>'.
609: &Apache::loncommon::end_page());
610: }
611: } else {
612: &success($r,$form->{'uname'},$udom,$authhost,'noredirect',undef,
613: $form);
614: my ($otherserver) = &Apache::lonnet::choose_server($udom);
615: $r->internal_redirect('/adm/switchserver?otherserver='.$otherserver);
616: }
617: }
618: return $canhost;
619: }
620:
621: sub noswitch {
622: my $result = &Apache::loncommon::start_page('Access to LON-CAPA unavailable').
623: '<h3>'.&mt('Session unavailable').'</h3>'.
624: &mt('This LON-CAPA server is unable to host your session.').'<br />'.
625: '<p>'.&mt('Currently no other LON-CAPA server is available to host your session either.').'</p>'.
626: &Apache::loncommon::end_page();
627: return $result;
628: }
629:
630: sub loginhelpdisplay {
631: my ($authdomain) = @_;
632: my $login_help = 1;
633: my $lang = &Apache::lonlocal::current_language();
634: if ($login_help) {
635: my $dom = $authdomain;
636: if ($dom eq '') {
637: $dom = &Apache::lonnet::default_login_domain();
638: }
639: my %domconfhash = &Apache::loncommon::get_domainconf($dom);
640: my $loginhelp_url;
641: if ($lang) {
642: $loginhelp_url = $domconfhash{$dom.'.login.helpurl_'.$lang};
643: if ($loginhelp_url ne '') {
644: return $loginhelp_url;
645: }
646: }
647: $loginhelp_url = $domconfhash{$dom.'.login.helpurl_nolang'};
648: if ($loginhelp_url ne '') {
649: return $loginhelp_url;
650: } else {
651: return '/adm/loginproblems.html';
652: }
653: }
654: return;
655: }
656:
657: 1;
658: __END__
659:
660:
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>