1: # The LearningOnline Network
2: # User Authentication Module
3: #
4: # $Id: lonauth.pm,v 1.121.2.6 2013/09/29 19:31:03 raeburn Exp $
5: #
6: # Copyright Michigan State University Board of Trustees
7: #
8: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
9: #
10: # LON-CAPA is free software; you can redistribute it and/or modify
11: # it under the terms of the GNU General Public License as published by
12: # the Free Software Foundation; either version 2 of the License, or
13: # (at your option) any later version.
14: #
15: # LON-CAPA is distributed in the hope that it will be useful,
16: # but WITHOUT ANY WARRANTY; without even the implied warranty of
17: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18: # GNU General Public License for more details.
19: #
20: # You should have received a copy of the GNU General Public License
21: # along with LON-CAPA; if not, write to the Free Software
22: # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
23: #
24: # /home/httpd/html/adm/gpl.txt
25: #
26: # http://www.lon-capa.org/
27: #
28:
29: package Apache::lonauth;
30:
31: use strict;
32: use LONCAPA;
33: use Apache::Constants qw(:common);
34: use CGI qw(:standard);
35: use DynaLoader; # for Crypt::DES version
36: use Crypt::DES;
37: use Apache::loncommon();
38: use Apache::lonnet;
39: use Apache::lonmenu();
40: use Apache::createaccount;
41: use Fcntl qw(:flock);
42: use Apache::lonlocal;
43: use Apache::File();
44: use HTML::Entities;
45:
46: # ------------------------------------------------------------ Successful login
47: sub success {
48: my ($r, $username, $domain, $authhost, $lowerurl, $extra_env,
49: $form) = @_;
50:
51: # ------------------------------------------------------------ Get cookie ready
52: my $cookie =
53: &Apache::loncommon::init_user_environment($r, $username, $domain,
54: $authhost, $form,
55: {'extra_env' => $extra_env,});
56:
57: my $public=($username eq 'public' && $domain eq 'public');
58:
59: if ($public or $lowerurl eq 'noredirect') { return $cookie; }
60:
61: # -------------------------------------------------------------------- Log this
62:
63: &Apache::lonnet::log($domain,$username,$authhost,
64: "Login $ENV{'REMOTE_ADDR'}");
65:
66: # ------------------------------------------------- Check for critical messages
67:
68: my @what=&Apache::lonnet::dump('critical',$domain,$username);
69: if ($what[0]) {
70: if (($what[0] ne 'con_lost') && ($what[0]!~/^error\:/)) {
71: $lowerurl='/adm/email?critical=display';
72: }
73: }
74:
75: # ------------------------------------------------------------ Get cookie ready
76: $cookie="lonID=$cookie; path=/";
77: # -------------------------------------------------------- Menu script and info
78: my $destination = $lowerurl;
79:
80: if (defined($form->{role})) {
81: my $envkey = 'user.role.'.$form->{role};
82: my $now=time;
83: my $then=$env{'user.login.time'};
84: my $refresh=$env{'user.refresh.time'};
85: my $update=$env{'user.update.time'};
86: if (!$update) {
87: $update = $then;
88: }
89: if (exists($env{$envkey})) {
90: my ($role,$where,$trolecode,$tstart,$tend,$tremark,$tstatus);
91: &Apache::lonnet::role_status($envkey,$update,$refresh,$now,\$role,\$where,
92: \$trolecode,\$tstatus,\$tstart,\$tend);
93: if ($tstatus eq 'is') {
94: $destination .= ($destination =~ /\?/) ? '&' : '?';
95: my $newrole = &HTML::Entities::encode($form->{role},'"<>&');
96: $destination .= 'selectrole=1&'.$newrole.'=1';
97: }
98: }
99: }
100: if (defined($form->{symb})) {
101: my $destsymb = $form->{symb};
102: $destination .= ($destination =~ /\?/) ? '&' : '?';
103: if ($destsymb =~ /___/) {
104: # FIXME Need to deal with encrypted symbs and urls as needed.
105: my ($map,$resid,$desturl)=split(/___/,$destsymb);
106: unless ($desturl=~/^(adm|editupload|public)/) {
107: $desturl = &Apache::lonnet::clutter($desturl);
108: }
109: $desturl = &HTML::Entities::encode($desturl,'"<>&');
110: $destsymb = &HTML::Entities::encode($destsymb,'"<>&');
111: $destination .= '&destinationurl='.$desturl.
112: '&destsymb='.$destsymb;
113: } else {
114: $destsymb = &HTML::Entities::encode($destsymb,'"<>&');
115: $destination .= '&destinationurl='.$destsymb;
116: }
117: }
118: if ($destination =~ m{^/adm/roles}) {
119: $destination .= ($destination =~ /\?/) ? '&' : '?';
120: $destination .= 'source=login';
121: }
122:
123: my $windowinfo=&Apache::lonmenu::open($env{'browser.os'});
124: my $startupremote=&Apache::lonmenu::startupremote($destination);
125: my $remoteinfo=&Apache::lonmenu::load_remote_msg($lowerurl);
126: my $setflags=&Apache::lonmenu::setflags();
127: my $maincall=&Apache::lonmenu::maincall();
128: my $brcrum = [{'href' => '',
129: 'text' => 'Successful Login'},];
130: my $start_page=&Apache::loncommon::start_page('Successful Login',
131: $startupremote,
132: {'no_inline_link' => 1,
133: 'bread_crumbs' => $brcrum,});
134: my $end_page =&Apache::loncommon::end_page();
135:
136: my $continuelink;
137: if ($env{'environment.remote'} eq 'off') {
138: $continuelink='<a href="'.$destination.'">'.&mt('Continue').'</a>';
139: }
140: # ------------------------------------------------- Output for successful login
141:
142: &Apache::loncommon::content_type($r,'text/html');
143: $r->header_out('Set-cookie' => $cookie);
144: $r->send_http_header;
145:
146: my %lt=&Apache::lonlocal::texthash(
147: 'wel' => 'Welcome',
148: 'pro' => 'Login problems?',
149: );
150: my $loginhelp = &loginhelpdisplay($domain);
151: if ($loginhelp) {
152: $loginhelp = '<p><a href="'.$loginhelp.'">'.$lt{'pro'}.'</a></p>';
153: }
154:
155: my $welcome = &mt('Welcome to the Learning[_1]Online[_2] Network with CAPA. Please wait while your session is being set up.','<i>','</i>');
156: $r->print(<<ENDSUCCESS);
157: $start_page
158: $setflags
159: $windowinfo
160: <h1>$lt{'wel'}</h1>
161: $welcome
162: $loginhelp
163: $remoteinfo
164: $maincall
165: $continuelink
166: $end_page
167: ENDSUCCESS
168: }
169:
170: # --------------------------------------------------------------- Failed login!
171:
172: sub failed {
173: my ($r,$message,$form) = @_;
174: my $start_page = &Apache::loncommon::start_page('Unsuccessful Login',undef);
175: my $retry = '/adm/login?username='.$form->{'uname'}.
176: '&domain='.$form->{'udom'};
177: if (exists($form->{role})) {
178: $retry .= '&role='.$form->{role};
179: }
180: if (exists($form->{symb})) {
181: $retry .= '&symb='.$form->{symb};
182: }
183: my $end_page = &Apache::loncommon::end_page();
184: &Apache::loncommon::content_type($r,'text/html');
185: $r->send_http_header;
186: my $loginhelp = &loginhelpdisplay($form->{'udom'});
187: if ($loginhelp) {
188: $loginhelp = '<p><a href="'.$loginhelp.'">'.&mt('Login problems?').'</a></p>';
189: }
190:
191: $r->print(
192: $start_page
193: .'<h1>'.&mt('Sorry ...').'</h1>'
194: .'<p class="LC_warning">'.&mt($message).'</p>'
195: .'<p>'.&mt('Please [_1]log in again[_2].','<a href="'.$retry.'">','</a>')
196: .'</p>'
197: .$loginhelp
198: .$end_page
199: );
200: }
201:
202: # ------------------------------------------------------------------ Rerouting!
203:
204: sub reroute {
205: my ($r) = @_;
206: &Apache::loncommon::content_type($r,'text/html');
207: $r->send_http_header;
208: my $msg='<b>'.&mt('Sorry ...').'</b><br />'
209: .&mt('Please [_1]log in again[_2].');
210: &Apache::loncommon::simple_error_page($r,'Rerouting',$msg,{'no_auto_mt_msg' => 1});
211: }
212:
213: # ---------------------------------------------------------------- Main handler
214:
215: sub handler {
216: my $r = shift;
217: my $londocroot = $r->dir_config('lonDocRoot');
218: my $form;
219: # Are we re-routing?
220: if (-e "$londocroot/lon-status/reroute.txt") {
221: &reroute($r);
222: return OK;
223: }
224:
225: &Apache::lonlocal::get_language_handle($r);
226:
227: # -------------------------------- Prevent users from attempting to login twice
228: my $handle = &Apache::lonnet::check_for_valid_session($r);
229: if ($handle ne '') {
230: my $lonidsdir=$r->dir_config('lonIDsDir');
231: if ($handle=~/^publicuser\_/) {
232: # For "public user" - remove it, we apparently really want to login
233: unlink($r->dir_config('lonIDsDir')."/$handle.id");
234: } else {
235: # Indeed, a valid token is found
236: &Apache::lonnet::transfer_profile_to_env($lonidsdir,$handle);
237: &Apache::loncommon::content_type($r,'text/html');
238: $r->send_http_header;
239: my $start_page =
240: &Apache::loncommon::start_page('Already logged in');
241: my $end_page =
242: &Apache::loncommon::end_page();
243: my $dest = '/adm/roles';
244: if ($env{'form.firsturl'} ne '') {
245: $dest = $env{'form.firsturl'};
246: }
247: $r->print(
248: $start_page
249: .'<p class="LC_warning">'.&mt('You are already logged in!').'</p>'
250: .'<p>'.&mt('Please either [_1]continue the current session[_2] or [_3]log out[_4].'
251: ,'<a href="'.$dest.'">','</a>','<a href="/adm/logout">','</a>')
252: .'</p>'
253: .$end_page
254: );
255: return OK;
256: }
257: }
258:
259: # ---------------------------------------------------- No valid token, continue
260:
261:
262: my $buffer;
263: if ($r->header_in('Content-length') > 0) {
264: $r->read($buffer,$r->header_in('Content-length'),0);
265: }
266: my %form;
267: foreach my $pair (split(/&/,$buffer)) {
268: my ($name,$value) = split(/=/,$pair);
269: $value =~ tr/+/ /;
270: $value =~ s/%([a-fA-F0-9][a-fA-F0-9])/pack("C",hex($1))/eg;
271: $form{$name}=$value;
272: }
273:
274: if ((!$form{'uname'}) || (!$form{'upass0'}) || (!$form{'udom'})) {
275: &failed($r,'Username, password and domain need to be specified.',
276: \%form);
277: return OK;
278: }
279:
280: # split user logging in and "su"-user
281:
282: ($form{'uname'},$form{'suname'})=split(/\:/,$form{'uname'});
283: $form{'uname'} = &LONCAPA::clean_username($form{'uname'});
284: $form{'suname'}= &LONCAPA::clean_username($form{'suname'});
285: $form{'udom'} = &LONCAPA::clean_domain( $form{'udom'});
286:
287: my $role = $r->dir_config('lonRole');
288: my $domain = $r->dir_config('lonDefDomain');
289: my $prodir = $r->dir_config('lonUsersDir');
290: my $contact_name = &mt('LON-CAPA helpdesk');
291:
292: # ---------------------------------------- Get the information from login token
293:
294: my $tmpinfo=Apache::lonnet::reply('tmpget:'.$form{'logtoken'},
295: $form{'serverid'});
296: my %sessiondata;
297: if ($form{'iptoken'}) {
298: %sessiondata = &Apache::lonnet::tmpget($form{'iptoken'});
299: my $delete = &Apache::lonnet::tmpdel($form{'token'});
300: }
301:
302: if (($tmpinfo=~/^error/) || ($tmpinfo eq 'con_lost') ||
303: ($tmpinfo eq 'no_such_host')) {
304: &failed($r,'Information needed to verify your login information is missing, inaccessible or expired.',\%form);
305: return OK;
306: } else {
307: my $reply = &Apache::lonnet::reply('tmpdel:'.$form{'logtoken'},
308: $form{'serverid'});
309: if ( $reply ne 'ok' ) {
310: &failed($r,'Session could not be opened.',\%form);
311: &Apache::lonnet::logthis("ERROR got a reply of $reply when trying to contact ". $form{'serverid'}." to get login token");
312: return OK;
313: }
314: }
315:
316: if (!&Apache::lonnet::domain($form{'udom'})) {
317: &failed($r,'The domain you provided is not a valid LON-CAPA domain.',\%form);
318: return OK;
319: }
320:
321: my ($key,$firsturl,$rolestr,$symbstr)=split(/&/,$tmpinfo);
322: if ($rolestr) {
323: $rolestr = &unescape($rolestr);
324: }
325: if ($symbstr) {
326: $symbstr= &unescape($symbstr);
327: }
328: if ($rolestr =~ /^role=/) {
329: (undef,$form{'role'}) = split('=',$rolestr);
330: }
331: if ($symbstr =~ /^symb=/) {
332: (undef,$form{'symb'}) = split('=',$symbstr);
333: }
334:
335: my $keybin=pack("H16",$key);
336:
337: my $cipher;
338: if ($Crypt::DES::VERSION>=2.03) {
339: $cipher=new Crypt::DES $keybin;
340: }
341: else {
342: $cipher=new DES $keybin;
343: }
344: my $upass='';
345: for (my $i=0;$i<=2;$i++) {
346: my $chunk=
347: $cipher->decrypt(unpack("a8",pack("H16",substr($form{'upass'.$i},0,16))));
348:
349: $chunk.=
350: $cipher->decrypt(unpack("a8",pack("H16",substr($form{'upass'.$i},16,16))));
351:
352: $chunk=substr($chunk,1,ord(substr($chunk,0,1)));
353: $upass.=$chunk;
354: }
355:
356: # ---------------------------------------------------------------- Authenticate
357:
358: my %domconfig = &Apache::lonnet::get_dom('configuration',['usercreation'],$form{'udom'});
359: my ($cancreate,$statustocreate) =
360: &Apache::createaccount::get_creation_controls($form{'udom'},$domconfig{'usercreation'});
361: my $defaultauth;
362: if (ref($cancreate) eq 'ARRAY') {
363: if (grep(/^login$/,@{$cancreate})) {
364: $defaultauth = 1;
365: }
366: }
367: my $clientcancheckhost = 1;
368: my $authhost=Apache::lonnet::authenticate($form{'uname'},$upass,
369: $form{'udom'},$defaultauth,
370: $clientcancheckhost);
371:
372: # --------------------------------------------------------------------- Failed?
373:
374: if ($authhost eq 'no_host') {
375: &failed($r,'Username and/or password could not be authenticated.',
376: \%form);
377: return OK;
378: } elsif ($authhost eq 'no_account_on_host') {
379: if ($defaultauth) {
380: my $domdesc = &Apache::lonnet::domain($form{'udom'},'description');
381: unless (&check_can_host($r,\%form,'no_account_on_host',$domdesc)) {
382: return OK;
383: }
384: my $start_page =
385: &Apache::loncommon::start_page('Create a user account in LON-CAPA',
386: '',{'no_inline_link' => 1,});
387: my $lonhost = $r->dir_config('lonHostID');
388: my $origmail = $Apache::lonnet::perlvar{'lonSupportEMail'};
389: my $contacts =
390: &Apache::loncommon::build_recipient_list(undef,'helpdeskmail',
391: $form{'udom'},$origmail);
392: my ($contact_email) = split(',',$contacts);
393: my $output =
394: &Apache::createaccount::username_check($form{'uname'},$form{'udom'},
395: $domdesc,'',$lonhost,
396: $contact_email,$contact_name,
397: undef,$statustocreate);
398: &Apache::loncommon::content_type($r,'text/html');
399: $r->send_http_header;
400: &Apache::createaccount::print_header($r,$start_page);
401: $r->print('<h3>'.&mt('Account creation').'</h3>'.
402: &mt('Although your username and password were authenticated, you do not currently have a LON-CAPA account at this institution.').'<br />'.
403: $output.&Apache::loncommon::end_page());
404: return OK;
405: } else {
406: &failed($r,'Although your username and password were authenticated, you do not currently have a LON-CAPA account in this domain, and you are not permitted to create one.',\%form);
407: return OK;
408: }
409: }
410:
411: if (($firsturl eq '') ||
412: ($firsturl=~/^\/adm\/(logout|remote)/)) {
413: $firsturl='/adm/roles';
414: }
415:
416: my $hosthere;
417: if ($form{'iptoken'}) {
418: if (($sessiondata{'domain'} eq $form{'udom'}) &&
419: ($sessiondata{'username'} eq $form{'uname'})) {
420: $hosthere = 1;
421: }
422: }
423:
424: # --------------------------------- Are we attempting to login as somebody else?
425: if ($form{'suname'}) {
426: # ------------ see if the original user has enough privileges to pull this stunt
427: if (&Apache::lonnet::privileged($form{'uname'},$form{'udom'})) {
428: # ---------------------------------------------------- see if the su-user exists
429: unless (&Apache::lonnet::homeserver($form{'suname'},$form{'udom'})
430: eq 'no_host') {
431: &Apache::lonnet::logthis(&Apache::lonnet::homeserver($form{'suname'},$form{'udom'}));
432: # ------------------------------ see if the su-user is not too highly privileged
433: unless (&Apache::lonnet::privileged($form{'suname'},$form{'udom'})) {
434: # -------------------------------------------------------- actually switch users
435: &Apache::lonnet::logperm('User '.$form{'uname'}.' at '.$form{'udom'}.
436: ' logging in as '.$form{'suname'});
437: $form{'uname'}=$form{'suname'};
438: } else {
439: &Apache::lonnet::logthis('Attempted switch user to privileged user');
440: }
441: }
442: } else {
443: &Apache::lonnet::logthis('Non-privileged user attempting switch user');
444: }
445: }
446:
447: my ($is_balancer,$otherserver);
448:
449: unless ($hosthere) {
450: ($is_balancer,$otherserver) =
451: &Apache::lonnet::check_loadbalancing($form{'uname'},$form{'udom'});
452: }
453:
454: if ($is_balancer) {
455: if (!$otherserver) {
456: ($otherserver) = &Apache::lonnet::choose_server($form{'udom'});
457: }
458: if ($otherserver) {
459: &success($r,$form{'uname'},$form{'udom'},$authhost,'noredirect',undef,
460: \%form);
461: $r->internal_redirect('/adm/switchserver?otherserver='.$otherserver.'&origurl='.$firsturl);
462: } else {
463: $r->print(&noswitch());
464: }
465: return OK;
466: } else {
467: if (!&check_can_host($r,\%form,$authhost)) {
468: my ($otherserver) = &Apache::lonnet::choose_server($form{'udom'});
469: if ($otherserver) {
470: &success($r,$form{'uname'},$form{'udom'},$authhost,'noredirect',undef,
471: \%form);
472: $r->internal_redirect('/adm/switchserver?otherserver='.$otherserver.'&origurl='.$firsturl);
473: } else {
474: $r->print(&noswitch());
475: }
476: return OK;
477: }
478:
479: # ------------------------------------------------------- Do the load balancing
480:
481: # ---------------------------------------------------------- Determine own load
482: my $loadlim = $r->dir_config('lonLoadLim');
483: my $loadavg;
484: {
485: my $loadfile=Apache::File->new('/proc/loadavg');
486: $loadavg=<$loadfile>;
487: }
488: $loadavg =~ s/\s.*//g;
489: my $loadpercent=sprintf("%.1f",100*$loadavg/$loadlim);
490: my $userloadpercent=&Apache::lonnet::userload();
491:
492: # ---------------------------------------------------------- Are we overloaded?
493: if ((($userloadpercent>100.0)||($loadpercent>100.0))) {
494: my $unloaded=Apache::lonnet::spareserver($loadpercent,$userloadpercent,1,$form{'udom'});
495: if (!$unloaded) {
496: ($unloaded) = &Apache::lonnet::choose_server($form{'udom'});
497: }
498: if ($unloaded) {
499: &success($r,$form{'uname'},$form{'udom'},$authhost,'noredirect',
500: undef,\%form);
501: $r->internal_redirect('/adm/switchserver?otherserver='.$unloaded.'&origurl='.$firsturl);
502: return OK;
503: }
504: }
505: &success($r,$form{'uname'},$form{'udom'},$authhost,$firsturl,undef,
506: \%form);
507: return OK;
508: }
509: }
510:
511: sub check_can_host {
512: my ($r,$form,$authhost,$domdesc) = @_;
513: return unless (ref($form) eq 'HASH');
514: my $canhost = 1;
515: my $lonhost = $r->dir_config('lonHostID');
516: my $udom = $form->{'udom'};
517: my @intdoms;
518: my $internet_names = &Apache::lonnet::get_internet_names($lonhost);
519: if (ref($internet_names) eq 'ARRAY') {
520: @intdoms = @{$internet_names};
521: }
522: my $uprimary_id = &Apache::lonnet::domain($udom,'primary');
523: my $uint_dom = &Apache::lonnet::internet_dom($uprimary_id);
524: unless ($uint_dom ne '' && grep(/^\Q$uint_dom\E$/,@intdoms)) {
525: my $machine_dom = &Apache::lonnet::host_domain($lonhost);
526: my $hostname = &Apache::lonnet::hostname($lonhost);
527: my $serverhomeID = &Apache::lonnet::get_server_homeID($hostname);
528: my $serverhomedom = &Apache::lonnet::host_domain($serverhomeID);
529: my %defdomdefaults = &Apache::lonnet::get_domain_defaults($serverhomedom);
530: my %udomdefaults = &Apache::lonnet::get_domain_defaults($udom);
531: my $loncaparev;
532: if ($authhost eq 'no_account_on_host') {
533: $loncaparev = &Apache::lonnet::get_server_loncaparev($machine_dom);
534: } else {
535: $loncaparev = &Apache::lonnet::get_server_loncaparev($machine_dom,$lonhost);
536: }
537: $canhost = &Apache::lonnet::can_host_session($udom,$lonhost,$loncaparev,
538: $udomdefaults{'remotesessions'},
539: $defdomdefaults{'hostedsessions'});
540: }
541: unless ($canhost) {
542: if ($authhost eq 'no_account_on_host') {
543: my $checkloginvia = 1;
544: my ($login_host,$hostname) =
545: &Apache::lonnet::choose_server($udom,$checkloginvia);
546: &Apache::loncommon::content_type($r,'text/html');
547: $r->send_http_header;
548: if ($login_host ne '') {
549: my $protocol = $Apache::lonnet::protocol{$login_host};
550: $protocol = 'http' if ($protocol ne 'https');
551: my $newurl = $protocol.'://'.$hostname.'/adm/createaccount';
552: $r->print(&Apache::loncommon::start_page('Create a user account in LON-CAPA').
553: '<h3>'.&mt('Account creation').'</h3>'.
554: &mt('You do not currently have a LON-CAPA account at this institution.').'<br />'.
555: '<p>'.&mt('You will be able to create one by logging into a LON-CAPA server within the [_1] domain.',$domdesc).'</p>'.
556: '<p>'.&mt('[_1]Log in[_2]','<a href="'.$newurl.'">','</a>').
557: &Apache::loncommon::end_page());
558: } else {
559: $r->print(&Apache::loncommon::start_page('Access to LON-CAPA unavailable').
560: '<h3>'.&mt('Account creation unavailable').'</h3>'.
561: &mt('You do not currently have a LON-CAPA account at this institution.').'<br />'.
562: '<p>'.&mt('Currently a LON-CAPA server is not available within the [_1] domain for you to log-in to, to create an account.',$domdesc).'</p>'.
563: &Apache::loncommon::end_page());
564: }
565: } else {
566: &success($r,$form->{'uname'},$udom,$authhost,'noredirect',undef,
567: $form);
568: my ($otherserver) = &Apache::lonnet::choose_server($udom);
569: $r->internal_redirect('/adm/switchserver?otherserver='.$otherserver);
570: }
571: }
572: return $canhost;
573: }
574:
575: sub noswitch {
576: my $result = &Apache::loncommon::start_page('Access to LON-CAPA unavailable').
577: '<h3>'.&mt('Session unavailable').'</h3>'.
578: &mt('This LON-CAPA server is unable to host your session.').'<br />'.
579: '<p>'.&mt('Currently no other LON-CAPA server is available to host your session either.').'</p>'.
580: &Apache::loncommon::end_page();
581: return $result;
582: }
583:
584: sub loginhelpdisplay {
585: my ($authdomain) = @_;
586: my $login_help = 1;
587: my $lang = &Apache::lonlocal::current_language();
588: if ($login_help) {
589: my $dom = $authdomain;
590: if ($dom eq '') {
591: $dom = &Apache::lonnet::default_login_domain();
592: }
593: my %domconfhash = &Apache::loncommon::get_domainconf($dom);
594: my $loginhelp_url;
595: if ($lang) {
596: $loginhelp_url = $domconfhash{$dom.'.login.helpurl_'.$lang};
597: if ($loginhelp_url ne '') {
598: return $loginhelp_url;
599: }
600: }
601: $loginhelp_url = $domconfhash{$dom.'.login.helpurl_nolang'};
602: if ($loginhelp_url ne '') {
603: return $loginhelp_url;
604: } else {
605: return '/adm/loginproblems.html';
606: }
607: }
608: return;
609: }
610:
611: 1;
612: __END__
613:
614:
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>