[BACK]Return to lonauth.pm CVS log [TXT] [DIR] Up to [LON-CAPA] / loncom / auth
File:  [LON-CAPA] / loncom / auth / lonauth.pm
Revision 1.10: download - view: text, annotated - select for diffs
Fri Jul 14 07:43:15 2000 UTC (24 years, 5 months ago) by www
Branches: MAIN
CVS tags: HEAD
lond propath now works for less than 3 char username
lonauth now recognizes Windows machines

# The LearningOnline Network
# User Authentication Module
# 5/21/99,5/22,5/25,5/26,5/27,5/29,6/2,6/11,6/14,6/15
# 16/11,12/16,
# 1/14,2/24,2/28,2/29,3/7,5/29,5/30,5/31,6/1,6/5,6/29,
# 7/1,7/10 Gerd Kortemeyer

package Apache::lonauth;

use Apache::Constants qw(:common);
use Apache::File;
use CGI qw(:standard);
use CGI::Cookie();
use Crypt::DES;
use Apache::lonnet();

# ------------------------------------------------------------ Successful login

sub success {
    my ($r, $username, $domain, $authhost,$lowerurl) = @_;
    my $lonids=$r->dir_config('lonIDsDir');

# See if old ID present, if so, remove
    my $cookie;
    while ($cookie=<$lonids/$username\_*\_$domain\_$authhost.id>) {
	unlink($cookie);
    }

# Give them a new cookie

    my $now=time;
    $cookie="$username\_$now\_$domain\_$authhost";

# Initialize roles

    my $userroles=Apache::lonnet::rolesinit($domain,$username,$authhost);

# ------------------------------------ Check browser type and MathML capability

    my @browsertype=split(/\&/,$r->dir_config("lonBrowsDet"));
    my %mathcap=split(/\&/,$r->dir_config("lonMathML"));
    my $httpbrowser=$ENV{"HTTP_USER_AGENT"};
    my $i;
    my $clientbrowser='unknown';
    my $clientversion='0';
    my $clientmathml='';
    for ($i=0;$i<=$#browsertype;$i++) {
        my ($bname,$match,$notmatch,$vreg,$minv)=split(/\:/,$browsertype[$i]);
	if (($httpbrowser=~/$match/i)  && ($httpbrowser!~/$notmatch/i)) {
	    $clientbrowser=$bname;
            $httpbrowser=~/$vreg/i;
	    $clientversion=$1;
            $clientmathml=($clientversion>=$minv);
        }
    }
    my $clientos='unknown';
    if (($httpbrowser=~/linux/i) ||
        ($httpbrowser=~/unix/i) ||
        ($httpbrowser=~/ux/i) ||
        ($httpbrowser=~/solaris/i)) { $clientos='unix'; }
    if (($httpbrowser=~/vax/i) ||
        ($httpbrowser=~/vms/i)) { $clientos='vms'; }
    if ($httpbrowser=~/next/i) { $clientos='next'; }
    if (($httpbrowser=~/mac/i) ||
        ($httpbrowser=~/powerpc/i)) { $clientos='mac'; }
    if ($httpbrowser=~/win/i) { $clientos='win'; }

# --------------------------------------------------------- Write first profile

       {
	    my $idf=Apache::File->new(">$lonids/$cookie.id");
            print $idf "user.name=$username\n";
            print $idf "user.domain=$domain\n";
            print $idf "user.home=$authhost\n";
            print $idf "browser.type=$clientbrowser\n";
            print $idf "browser.version=$clientversion\n";
            print $idf "browser.mathml=$clientmathml\n";
            print $idf "browser.os=$clientos\n";
            if ($userroles ne '') { print $idf "$userroles" };
        }
# -------------------------------------------------------------------- Log this

    &Apache::lonnet::log($domain,$username,$authhost,
                         "Login $ENV{'REMOTE_ADDR'}");

# ------------------------------------------------------------ Get cookie ready

    $cookie="lonID=$cookie; path=/";

# ------------------------------------------------- Output for successful login

    $r->send_cgi_header(<<ENDHEADER);
Content-type: text/html
Set-cookie: $cookie

ENDHEADER
    $r->print(<<ENDSUCCESS);
<html>
<head>
<title>Successful Login to the LearningOnline Network with CAPA</title>
<meta HTTP-EQUIV="Refresh" CONTENT="1; url=$lowerurl">
</head>
<body bgcolor="#FFFFFF">
<script>
menu=window.open("/res/adm/pages/menu.html","LONCAPAmenu",
                 "height=350,width=150,scrollbars=no,menubar=no");
</script>
<h1>Welcome!</h1>
</body>
</html>
ENDSUCCESS
}

# --------------------------------------------------------------- Failed login!

sub failed {
    my ($r,$message) = @_;
    $r->send_cgi_header(<<ENDFHEADER);
Content-type: text/html

ENDFHEADER
    $r->print(<<ENDFAILED);
<html>
<head>
<title>Unsuccessful Login to the LearningOnline Network with CAPA</title>
</head>
<html>
<body bgcolor="#FFFFFF">
<h1>Sorry ...</h1>
<h2>$message to use the Learning<i>Online</i> Network with CAPA</h2>
</body>
</html>
ENDFAILED
}

# ---------------------------------------------------------------- Main handler

sub handler {
    my $r = shift;

    my $buffer;
    $r->read($buffer,$r->header_in('Content-length'));
    my @pairs=split(/&/,$buffer);
    my $pair; my $name; my $value; my %FORM;
    foreach $pair (@pairs) {
       ($name,$value) = split(/=/,$pair);
       $value =~ tr/+/ /;
       $value =~ s/%([a-fA-F0-9][a-fA-F0-9])/pack("C",hex($1))/eg;
       $FORM{$name}=$value;
    } 

    if ((!$FORM{'uname'}) || (!$FORM{'upass'}) || (!$FORM{'udom'})) {
	failed($r,'Username, password and domain need to be specified');
        return OK;
    }
    $FORM{'uname'} =~ s/\W//g;
    $FORM{'udom'}  =~ s/\W//g;

    my $role   = $r->dir_config('lonRole');
    my $domain = $r->dir_config('lonDefDomain');
    my $prodir = $r->dir_config('lonUsersDir');

# ---------------------------------------- Get the information from login token

    my $tmpinfo=Apache::lonnet::reply('tmpget:'.$FORM{'logtoken'},
                                      $FORM{'serverid'});

    if (($tmpinfo=~/^error/) || ($tmpinfo eq 'con_lost')) {
	failed($r,'Login token missing, inaccessible or expired');
        return OK;
    }
    
    my ($key,$firsturl)=split(/&/,$tmpinfo);

    my $keybin=pack("H16",$key);

    my $cipher=new DES $keybin;

    my $upass=$cipher->decrypt(
       unpack("a8",pack("H16",substr($FORM{'upass'},0,16))));

    $upass.=$cipher->decrypt(
       unpack("a8",pack("H16",substr($FORM{'upass'},16,16))));

    $upass=substr($upass,1,ord(substr($upass,0,1)));

# ---------------------------------------------------------------- Authenticate
    my $authhost=Apache::lonnet::authenticate($FORM{'uname'},
                                              $upass,
                                              $FORM{'udom'});
    
# --------------------------------------------------------------------- Failed?

    if ($authhost eq 'no_host') {
	failed($r,'Username and/or password could not be authenticated');
        return OK;
    }

    if ($firsturl eq '') {
	$firsturl='/res/adm/pages/index.html';
    }

    success($r,$FORM{'uname'},$FORM{'udom'},$authhost,$firsturl);
    return OK;
}

1;
__END__
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>