Return to lonauth.pm CVS log

Up to [LON-CAPA] / loncom / auth

Created loncommon::decode_user_agent() subroutine with code removed from
lonauth.pm.  The code was modified to not require $r be passed along
ad nauseum.

Created lonhtmlcommon::javascript_nothing which returns an appropriate value
of nothing for use as the first parameter for window.open.  Most notably,
IE on macs get a different version, "'javascript:void(0);'", than everyone
one else, "''".  Of course IE on PC appearantly used to require the former
but now requires the latter.

lonmenu.pm and lonspreadsheet.pm were modified to use javascript_nothing.
lonauth was modified to use decode_user_agent.

# The LearningOnline Network
# User Authentication Module
#
# $Id: lonauth.pm,v 1.45 2003/03/10 20:21:45 matthew Exp $
#
# Copyright Michigan State University Board of Trustees
#
# This file is part of the LearningOnline Network with CAPA (LON-CAPA).
#
# LON-CAPA is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# LON-CAPA is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with LON-CAPA; if not, write to the Free Software
# Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
#
# /home/httpd/html/adm/gpl.txt
#
# http://www.lon-capa.org/
#
# 5/21/99,5/22,5/25,5/26,5/27,5/29,6/2,6/11,6/14,6/15
# 16/11,12/16,
# 1/14,2/24,2/28,2/29,3/7,5/29,5/30,5/31,6/1,6/5,6/29,
# 7/1,7/10,10/2,10/5,10/9,10/26,10/30,11/10,
# 05/28,05/29 Gerd Kortemeyer
# 07/28,08/03 Gerd Kortemeyer
# 8/20 Gerd Kortemeyer

package Apache::lonauth;

use strict;
use Apache::Constants qw(:common);
use Apache::File;
use CGI qw(:standard);
use CGI::Cookie();
use DynaLoader; # for Crypt::DES version
use Crypt::DES;
use Apache::loncommon();
use Apache::lonnet();
use Apache::lonmenu();
use Fcntl qw(:flock);

my %FORM;

# ------------------------------------------------------------ Successful login

sub success {
    my ($r, $username, $domain, $authhost,$lowerurl) = @_;
    my $lonids=$r->dir_config('lonIDsDir');

# See if old ID present, if so, remove

    my $filename;
    opendir(DIR,$lonids);
    while ($filename=readdir(DIR)) {
       if ($filename=~/^$username\_\d+\_$domain\_$authhost\.id$/) {
	  unlink($lonids.'/'.$filename);
       }
    }
    closedir(DIR);

# Give them a new cookie

    my $cookie;
    my $now=time;
    $cookie="$username\_$now\_$domain\_$authhost";

# Initialize roles

    my $userroles=Apache::lonnet::rolesinit($domain,$username,$authhost);

# ------------------------------------ Check browser type and MathML capability

    my ($httpbrowser,$clientbrowser,$clientversion,$clientmathml,
        $clientunicode,$clientos) = &Apache::loncommon::decode_user_agent($r);

# -------------------------------------- Any accessibility options to remember?
    if (($FORM{'interface'}) && ($FORM{'remember'} eq 'true')) {
	foreach ('imagesuppress','appletsuppress',
		 'embedsuppress','fontenhance','blackwhite') {
	    if ($FORM{$_} eq 'true') {
		&Apache::lonnet::put('environment',{$_ => 'on'},
				     $domain,$username);
	    } else {
		&Apache::lonnet::del('environment',[$_],$domain,$username);
	    }
	}
    }
# ------------------------------------------------------------- Get environment

    my $userenv;
    my %userenv=Apache::lonnet::dump('environment',$domain,$username);
    my ($tmp) = keys(%userenv);
    if ($tmp !~ /^(con_lost|error|no_such_host)/i) {
	foreach my $key (keys(%userenv)) {
	    $userenv.="environment.$key=$userenv{$key}\n";
	}
    }
    if (($userenv{'interface'}) && (!$FORM{'interface'})) {
	$FORM{'interface'}=$userenv{'interface'};
    }
# --------------------------------------------------------- Write first profile

    {
	my $idf=Apache::File->new(">$lonids/$cookie.id");
	unless (flock($idf,LOCK_EX)) {
	    &Apache::lonnet::logthis("<font color=blue>WARNING: ".
			   'Could not obtain exclusive lock in lonauth: '.$!);
	    $idf->close();
	    return 'error: '.$!;
	}
	if ($userenv ne '') { print $idf "$userenv\n"; }
	print $idf "user.name=$username\n";
	print $idf "user.domain=$domain\n";
	print $idf "user.home=$authhost\n";
	print $idf "browser.type=$clientbrowser\n";
	print $idf "browser.version=$clientversion\n";
	print $idf "browser.mathml=$clientmathml\n";
	print $idf "browser.unicode=$clientunicode\n";
	print $idf "browser.os=$clientos\n";
	print $idf "request.course.fn=\n";
	print $idf "request.course.uri=\n";
	print $idf "request.course.sec=\n";
	print $idf "request.role=cm\n";
	print $idf "request.host=$ENV{'REMOTE_ADDR'}\n";
	if ($FORM{'interface'}) {
	    $FORM{'interface'}=~s/\W//gs;
	    print $idf "browser.interface=$FORM{'interface'}\n";
	    $ENV{'browser.interface'}=$FORM{'interface'};
	    foreach ('imagesuppress','appletsuppress',
		     'embedsuppress','fontenhance','blackwhite') {
		if (($FORM{$_} eq 'true') ||
		    ($userenv{$_} eq 'on')) {
		    print $idf "browser.$_=on\n";
		}
	    }
	}
	if ($userroles ne '') { print $idf "$userroles"; }
	$idf->close();
    }
    $ENV{'request.role'}='cm';
    $ENV{'browser.type'}=$clientbrowser;
# -------------------------------------------------------------------- Log this

    &Apache::lonnet::log($domain,$username,$authhost,
                         "Login $ENV{'REMOTE_ADDR'}");

# ------------------------------------------------- Check for critical messages

    my @what=&Apache::lonnet::dump('critical',$domain,$username);
    if ($what[0]) {
	if (($what[0] ne 'con_lost') && ($what[0]!~/^error\:/)) {
	    $lowerurl='/adm/email?critical=display';
        }
    }

# ------------------------------------------------------------ Get cookie ready

    $cookie="lonID=$cookie; path=/";
# -------------------------------------------------------- Menu script and info
    my $windowinfo=&Apache::lonmenu::open($clientos);
    my $startupremote=&Apache::lonmenu::startupremote($lowerurl);
    my $setflags=&Apache::lonmenu::setflags();
    my $maincall=&Apache::lonmenu::maincall();
    my $bodytag=&Apache::loncommon::bodytag('Successful Login');
# ------------------------------------------------- Output for successful login

    $r->send_cgi_header(<<ENDHEADER);
Content-type: text/html
Set-cookie: $cookie

ENDHEADER
    $r->print(<<ENDSUCCESS);
<html>
<head>
<title>Successful Login to the LearningOnline Network with CAPA</title>
$startupremote
</head>
$bodytag
$setflags
$windowinfo
<h1>Welcome!</h1>
Welcome to the Learning<i>Online</i> Network with CAPA.
Please wait while your session
is being set up.<p>
<a href="/adm/loginproblems.html">Problems?</a></p>
$maincall
</body>
</html>
ENDSUCCESS
}

# --------------------------------------------------------------- Failed login!

sub failed {
    my ($r,$message) = @_;
    my $bodytag=&Apache::loncommon::bodytag('Unsuccessful Login');
    $r->send_cgi_header(<<ENDFHEADER);
Content-type: text/html

ENDFHEADER
    $r->print(<<ENDFAILED);
<html>
<head>
<title>Unsuccessful Login to the LearningOnline Network with CAPA</title>
</head>
<html>
$bodytag
<h1>Sorry ...</h1>
<p><b>$message</b></p>
<p>Please <a href="/adm/login?username=$FORM{'uname'}&domain=$FORM{'udom'}">login</a> again.</p>
<p>
<a href="/adm/loginproblems.html">Problems?</a></p>
</body>
</html>
ENDFAILED
}

# ---------------------------------------------------------------- Main handler

sub handler {
    my $r = shift;

    my $buffer;
    $r->read($buffer,$r->header_in('Content-length'));
    my @pairs=split(/&/,$buffer);
    my $pair; my $name; my $value;
    undef %FORM;
    %FORM=();
    foreach $pair (@pairs) {
       ($name,$value) = split(/=/,$pair);
       $value =~ tr/+/ /;
       $value =~ s/%([a-fA-F0-9][a-fA-F0-9])/pack("C",hex($1))/eg;
       $FORM{$name}=$value;
    } 

    if ((!$FORM{'uname'}) || (!$FORM{'upass'}) || (!$FORM{'udom'})) {
	failed($r,'Username, password and domain need to be specified.');
        return OK;
    }
    $FORM{'uname'} =~ s/\W//g;
    $FORM{'udom'}  =~ s/\W//g;

    my $role   = $r->dir_config('lonRole');
    my $domain = $r->dir_config('lonDefDomain');
    my $prodir = $r->dir_config('lonUsersDir');

# ---------------------------------------- Get the information from login token

    my $tmpinfo=Apache::lonnet::reply('tmpget:'.$FORM{'logtoken'},
                                      $FORM{'serverid'});

    if (($tmpinfo=~/^error/) || ($tmpinfo eq 'con_lost')) {
	failed($r,'Information needed to verify your login information is missing, inaccessible or expired.');
        return OK;
    } else {
        unless (&Apache::lonnet::reply('tmpdel:'.$FORM{'logtoken'},
                                         $FORM{'serverid'}) eq 'ok') {
            &failed($r,'Session could not be opened.');
	}
    }
    my ($key,$firsturl)=split(/&/,$tmpinfo);

    my $keybin=pack("H16",$key);

    my $cipher;
    if ($Crypt::DES::VERSION>=2.03) {
	$cipher=new Crypt::DES $keybin;
    }
    else {
	$cipher=new DES $keybin;
    }

    my $upass=$cipher->decrypt(
       unpack("a8",pack("H16",substr($FORM{'upass'},0,16))));

    $upass.=$cipher->decrypt(
       unpack("a8",pack("H16",substr($FORM{'upass'},16,16))));

    $upass=substr($upass,1,ord(substr($upass,0,1)));

# ---------------------------------------------------------------- Authenticate
    my $authhost=Apache::lonnet::authenticate($FORM{'uname'},
                                              $upass,
                                              $FORM{'udom'});
    
# --------------------------------------------------------------------- Failed?

    if ($authhost eq 'no_host') {
	failed($r,'Username and/or password could not be authenticated.');
        return OK;
    }

    if (($firsturl eq '') || ($firsturl eq '/adm/logout')) {
	$firsturl='/adm/roles';
    }

    success($r,$FORM{'uname'},$FORM{'udom'},$authhost,$firsturl);
    return OK;
}

1;
__END__