Return to lonauth.pm CVS log

Up to [LON-CAPA] / loncom / auth

- default to no remote control BUG#4337

# The LearningOnline Network
# User Authentication Module
#
# $Id: lonauth.pm,v 1.73 2006/01/19 22:14:38 albertel Exp $
#
# Copyright Michigan State University Board of Trustees
#
# This file is part of the LearningOnline Network with CAPA (LON-CAPA).
#
# LON-CAPA is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# LON-CAPA is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with LON-CAPA; if not, write to the Free Software
# Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
#
# /home/httpd/html/adm/gpl.txt
#
# http://www.lon-capa.org/
#

package Apache::lonauth;

use strict;
use Apache::Constants qw(:common);
use Apache::File;
use CGI qw(:standard);
use CGI::Cookie();
use DynaLoader; # for Crypt::DES version
use Crypt::DES;
use Apache::loncommon();
use Apache::lonnet;
use Apache::lonmenu();
use Fcntl qw(:flock);
use Apache::lonlocal;
use POSIX qw(strftime);

my %FORM;

# ------------------------------------------------------------ Successful login

sub success {
    my ($r, $username, $domain, $authhost,$lowerurl) = @_;
    my $lonids=$r->dir_config('lonIDsDir');

    my $public=($username eq 'public' && $domain eq 'public');

# See if old ID present, if so, remove

    my ($filename,$cookie,$userroles);
    my $now=time;

    if ($public) {
	my $max_public=100;
	my $oldest;
	my $oldest_time=0;
	for(my $next=1;$next<=$max_public;$next++) {
	    if (-e $lonids."/publicuser_$next.id") {
		my $mtime=(stat($lonids."/publicuser_$next.id"))[9];
		if ($mtime<$oldest_time || !$oldest_time) {
		    $oldest_time=$mtime;
		    $oldest=$next;
		}
	    } else {
		$cookie="publicuser_$next";
		last;
	    }
	}
	if (!$cookie) { $cookie="publicuser_$oldest"; }
    } else {
	opendir(DIR,$lonids);
	while ($filename=readdir(DIR)) {
	    if ($filename=~/^$username\_\d+\_$domain\_$authhost\.id$/) {
		unlink($lonids.'/'.$filename);
	    }
	}
	closedir(DIR);

# Give them a new cookie

	$cookie="$username\_$now\_$domain\_$authhost";
    
# Initialize roles

	$userroles=Apache::lonnet::rolesinit($domain,$username,$authhost);
    }
# ------------------------------------ Check browser type and MathML capability

    my ($httpbrowser,$clientbrowser,$clientversion,$clientmathml,
        $clientunicode,$clientos) = &Apache::loncommon::decode_user_agent($r);

# -------------------------------------- Any accessibility options to remember?
    if (($FORM{'interface'}) && ($FORM{'remember'} eq 'true')) {
	foreach ('imagesuppress','appletsuppress',
		 'embedsuppress','fontenhance','blackwhite') {
	    if ($FORM{$_} eq 'true') {
		&Apache::lonnet::put('environment',{$_ => 'on'},
				     $domain,$username);
	    } else {
		&Apache::lonnet::del('environment',[$_],$domain,$username);
	    }
	}
    }
# ------------------------------------------------------------- Get environment

    my $userenv;
    my %userenv=Apache::lonnet::dump('environment',$domain,$username);
    my ($tmp) = keys(%userenv);
    if ($tmp !~ /^(con_lost|error|no_such_host)/i) {
	# default remote control to off
	if ($userenv{'remote'} ne 'on') { $userenv{'remote'} = 'off'; }
	foreach my $key (keys(%userenv)) {
	    $userenv.="environment.$key=$userenv{$key}\n";
	}
    }
    if (($userenv{'interface'}) && (!$FORM{'interface'})) {
	$FORM{'interface'}=$userenv{'interface'};
    }
    $env{'environment.remote'}=$userenv{'remote'};
    if ($userenv{'texengine'} eq 'ttm') { $clientmathml=1; }

# --------------- Do not trust query string to be put directly into environment
    foreach ('imagesuppress','appletsuppress',
	     'embedsuppress','fontenhance','blackwhite',
	     'interface','localpath','localres') {
	$FORM{$_}=~s/[\n\r\=]//gs;
    }
# --------------------------------------------------------- Write first profile

    {
	my $idf=Apache::File->new(">$lonids/$cookie.id");
	unless (flock($idf,LOCK_EX)) {
	    &Apache::lonnet::logthis("<font color=blue>WARNING: ".
			   'Could not obtain exclusive lock in lonauth: '.$!);
	    $idf->close();
	    return 'error: '.$!;
	}
	if ($userenv ne '') { print $idf "$userenv\n"; }
	print $idf "user.name=$username\n";
	print $idf "user.domain=$domain\n";
	print $idf "user.home=$authhost\n";
	print $idf "browser.type=$clientbrowser\n";
	print $idf "browser.version=$clientversion\n";
	print $idf "browser.mathml=$clientmathml\n";
	print $idf "browser.unicode=$clientunicode\n";
	print $idf "browser.os=$clientos\n";
        if ($FORM{'localpath'}) {
           print $idf "browser.localpath=$FORM{'localpath'}\n";
           print $idf "browser.localres=$FORM{'localres'}\n";
        }
        print $idf "server.domain=".$r->dir_config('lonDefDomain')."\n";
        my $timezone=POSIX::strftime("%Z",localtime(time));
        print $idf "server.timezone=$timezone\n";
	print $idf "request.course.fn=\n";
	print $idf "request.course.uri=\n";
	print $idf "request.course.sec=\n";
	print $idf "request.role=cm\n";
        print $idf "request.role.adv=$env{'user.adv'}\n";
	print $idf "request.host=$ENV{'REMOTE_ADDR'}\n";
	if ($public) {
	    print $idf "environment.remote=off\n";
	}
	if ($FORM{'interface'}) {
	    $FORM{'interface'}=~s/\W//gs;
	    print $idf "browser.interface=$FORM{'interface'}\n";
	    $env{'browser.interface'}=$FORM{'interface'};
	    foreach ('imagesuppress','appletsuppress',
		     'embedsuppress','fontenhance','blackwhite') {
		if (($FORM{$_} eq 'true') ||
		    ($userenv{$_} eq 'on')) {
		    print $idf "browser.$_=on\n";
		}
	    }
	}
	if ($userroles ne '') { print $idf "$userroles"; }
	$idf->close();
    }
    $env{'request.role'}='cm';
    $env{'request.role.adv'}=$env{'user.adv'};
    $env{'browser.type'}=$clientbrowser;
# -------------------------------------------------------------------- Log this

    &Apache::lonnet::log($domain,$username,$authhost,
                         "Login $ENV{'REMOTE_ADDR'}");

# ------------------------------------------------- Check for critical messages

    my @what=&Apache::lonnet::dump('critical',$domain,$username);
    if ($what[0]) {
	if (($what[0] ne 'con_lost') && ($what[0]!~/^error\:/)) {
	    $lowerurl='/adm/email?critical=display';
        }
    }

# ------------------------------------------------------------ Get cookie ready

    if ($public or $lowerurl eq 'noredirect') { return $cookie; }

    $cookie="lonID=$cookie; path=/";
# -------------------------------------------------------- Menu script and info
    my $windowinfo=&Apache::lonmenu::open($clientos);
    my $startupremote=&Apache::lonmenu::startupremote($lowerurl);
    my $remoteinfo=&Apache::lonmenu::load_remote_msg($lowerurl);
    my $setflags=&Apache::lonmenu::setflags();
    my $maincall=&Apache::lonmenu::maincall();
    my $bodytag=&Apache::loncommon::bodytag('Successful Login');
    my $add=&addcontent();
    my $continuelink;
    if (($env{'browser.interface'} eq 'textual') ||
        ($env{'environment.remote'} eq 'off')) {
	$continuelink="<a href=\"$lowerurl\">".&mt('Continue')."</a>";
    }
# ------------------------------------------------- Output for successful login

    $r->send_cgi_header(<<ENDHEADER);
Content-type: text/html$add
Set-cookie: $cookie

ENDHEADER
    my %lt=&Apache::lonlocal::texthash(
				       'wel' => 'Welcome',
				       'mes' => 'Welcome to the Learning<i>Online</i> Network with CAPA. Please wait while your session is being set up',
				       'pro' => 'Problems',
				       'log' => 'loginproblems.html',
				       );
    $r->print(<<ENDSUCCESS);
<html>
<head>
<title>Successful Login to the LearningOnline Network with CAPA</title>
$startupremote
</head>
$bodytag
$setflags
$windowinfo
<h1>$lt{'wel'}</h1>
$lt{'mes'}.<p>
<a href="/adm/$lt{'log'}">$lt{'pro'}?</a></p>
$remoteinfo
$maincall
$continuelink
</body>
</html>
ENDSUCCESS
}

# --------------------------------------------------------------- Failed login!

sub failed {
    my ($r,$message) = @_;
    my $bodytag=&Apache::loncommon::bodytag('Unsuccessful Login');
    my $add=&addcontent();
    $r->send_cgi_header(<<ENDFHEADER);
Content-type: text/html$add

ENDFHEADER
    $r->print(<<ENDFAILED);
<html>
<head>
<title>Unsuccessful Login to the LearningOnline Network with CAPA</title>
</head>
$bodytag
<h1>Sorry ...</h1>
<p><b>$message</b></p>
<p>Please <a href="/adm/login?username=$FORM{'uname'}&domain=$FORM{'udom'}">log in again</a>.</p>
<p>
<a href="/adm/loginproblems.html">Problems?</a></p>
</body>
</html>
ENDFAILED
}

# --------------------------------------------------------------------- Charset

sub addcontent {
    my $encoding=&Apache::lonlocal::current_encoding;
    if ($encoding) {
	return '; charset='.$encoding;
    } else {
	return '';
    }
}

# ------------------------------------------------------------------ Rerouting!

sub reroute {
    my $r=shift;
    my $bodytag=&Apache::loncommon::bodytag('Rerouting');
    $r->send_cgi_header(<<ENDRFHEADER);
Content-type: text/html

ENDRFHEADER
    $r->print(<<ENDRFAILED);
<html>
<head>
<title>Rerouting Login to the LearningOnline Network with CAPA</title>
</head>
$bodytag
<h1>Sorry ...</h1>
Please <a href="/">log in again</a>.
</body>
</html>
ENDRFAILED
}

# ---------------------------------------------------------------- Main handler

sub handler {
    my $r = shift;

# Are we re-routing?
    if (-e '/home/httpd/html/lon-status/reroute.txt') {
	&reroute($r);
	return OK;
    }

    &Apache::lonlocal::get_language_handle($r);

# -------------------------------- Prevent users from attempting to login twice
    my %cookies=CGI::Cookie->parse($r->header_in('Cookie'));
    my $lonid=$cookies{'lonID'};
    my $cookie;
    if ($lonid) {
	my $handle=$lonid->value;
        $handle=~s/\W//g;
        my $lonidsdir=$r->dir_config('lonIDsDir');
        if ((-e "$lonidsdir/$handle.id") && ($handle ne '')) {
# Indeed, a valid token is found
	    $r->send_cgi_header(<<ENDFHEADER);
Content-type: text/html

ENDFHEADER
	    my $bodytag=&Apache::loncommon::bodytag('Already logged in');
	    $r->print(<<ENDFAILED);
<html>
<head>
<title>Already logged in</title>
</head>
$bodytag
<h1>You are already logged in</h1>
<p>Please either <a href="/adm/roles">continue the current session</a> or
<a href="/adm/logout">logout</a>.</p>
<p>
<a href="/adm/loginproblems.html">Problems?</a></p>
</body>
</html>
ENDFAILED
           return OK;
	}
    }

# ---------------------------------------------------- No valid token, continue


    my $buffer;
    $r->read($buffer,$r->header_in('Content-length'),0);
    my @pairs=split(/&/,$buffer);
    my $pair; my $name; my $value;
    undef %FORM;
    %FORM=();
    foreach $pair (@pairs) {
       ($name,$value) = split(/=/,$pair);
       $value =~ tr/+/ /;
       $value =~ s/%([a-fA-F0-9][a-fA-F0-9])/pack("C",hex($1))/eg;
       $FORM{$name}=$value;
    } 

    if ((!$FORM{'uname'}) || (!$FORM{'upass0'}) || (!$FORM{'udom'})) {
	failed($r,'Username, password and domain need to be specified.');
        return OK;
    }

# split user logging in and "su"-user

    ($FORM{'uname'},$FORM{'suname'})=split(/\:/,$FORM{'uname'});
    $FORM{'uname'} =~ s/\W//g;
    $FORM{'suname'} =~ s/\W//g;
    $FORM{'udom'}  =~ s/\W//g;

    my $role   = $r->dir_config('lonRole');
    my $domain = $r->dir_config('lonDefDomain');
    my $prodir = $r->dir_config('lonUsersDir');

# ---------------------------------------- Get the information from login token

    my $tmpinfo=Apache::lonnet::reply('tmpget:'.$FORM{'logtoken'},
                                      $FORM{'serverid'});

    if (($tmpinfo=~/^error/) || ($tmpinfo eq 'con_lost')) {
	failed($r,'Information needed to verify your login information is missing, inaccessible or expired.');
        return OK;
    } else {
        unless (&Apache::lonnet::reply('tmpdel:'.$FORM{'logtoken'},
                                         $FORM{'serverid'}) eq 'ok') {
            &failed($r,'Session could not be opened.');
	}
    }
    my ($key,$firsturl)=split(/&/,$tmpinfo);

    my $keybin=pack("H16",$key);

    my $cipher;
    if ($Crypt::DES::VERSION>=2.03) {
	$cipher=new Crypt::DES $keybin;
    }
    else {
	$cipher=new DES $keybin;
    }
    my $upass='';
    for (my $i=0;$i<=2;$i++) {
	my $chunk=
	    $cipher->decrypt(unpack("a8",pack("H16",substr($FORM{'upass'.$i},0,16))));

	$chunk.=
	    $cipher->decrypt(unpack("a8",pack("H16",substr($FORM{'upass'.$i},16,16))));

	$chunk=substr($chunk,1,ord(substr($chunk,0,1)));
	$upass.=$chunk;
    }

# ---------------------------------------------------------------- Authenticate
    my $authhost=Apache::lonnet::authenticate($FORM{'uname'},
                                              $upass,
                                              $FORM{'udom'});
    
# --------------------------------------------------------------------- Failed?

    if ($authhost eq 'no_host') {
	failed($r,'Username and/or password could not be authenticated.');
        return OK;
    }

    if (($firsturl eq '') || 
	($firsturl=~/^\/adm\/(logout|remote)/)) {
	$firsturl='/adm/roles';
    }
# --------------------------------- Are we attempting to login as somebody else?
    if ($FORM{'suname'}) {
# ------------ see if the original user has enough privileges to pull this stunt
	if (&Apache::lonnet::privileged($FORM{'uname'},$FORM{'udom'})) {
# ---------------------------------------------------- see if the su-user exists
	    unless (&Apache::lonnet::homeserver($FORM{'suname'},$FORM{'udom'})
		eq 'no_host') {
		&Apache::lonnet::logthis(&Apache::lonnet::homeserver($FORM{'suname'},$FORM{'udom'}));
# ------------------------------ see if the su-user is not too highly privileged
		unless (&Apache::lonnet::privileged($FORM{'suname'},$FORM{'udom'})) {
# -------------------------------------------------------- actually switch users
		    &Apache::lonnet::logperm('User '.$FORM{'uname'}.' at '.$FORM{'udom'}.
			' logging in as '.$FORM{'suname'});
		    $FORM{'uname'}=$FORM{'suname'};
		} else {
		    &Apache::lonnet::logthis('Attempted switch user to privileged user');
		}
	    }
	} else {
	    &Apache::lonnet::logthis('Non-privileged user attempting switch user');
	}
    }
    &success($r,$FORM{'uname'},$FORM{'udom'},$authhost,$firsturl);
    return OK;
}

1;
__END__