1: # The LearningOnline Network
2: # Login Screen
3: #
4: # $Id: lonlogin.pm,v 1.158.2.13.2.5 2022/06/01 12:21:06 raeburn Exp $
5: #
6: # Copyright Michigan State University Board of Trustees
7: #
8: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
9: #
10: # LON-CAPA is free software; you can redistribute it and/or modify
11: # it under the terms of the GNU General Public License as published by
12: # the Free Software Foundation; either version 2 of the License, or
13: # (at your option) any later version.
14: #
15: # LON-CAPA is distributed in the hope that it will be useful,
16: # but WITHOUT ANY WARRANTY; without even the implied warranty of
17: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18: # GNU General Public License for more details.
19: #
20: # You should have received a copy of the GNU General Public License
21: # along with LON-CAPA; if not, write to the Free Software
22: # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
23: #
24: # /home/httpd/html/adm/gpl.txt
25: #
26: # http://www.lon-capa.org/
27: #
28:
29: package Apache::lonlogin;
30:
31: use strict;
32: use Apache::Constants qw(:common);
33: use Apache::File ();
34: use Apache::lonnet;
35: use Apache::loncommon();
36: use Apache::lonauth();
37: use Apache::lonlocal;
38: use Apache::migrateuser();
39: use lib '/home/httpd/lib/perl/';
40: use LONCAPA qw(:DEFAULT :match);
41: use URI::Escape;
42: use HTML::Entities();
43: use CGI::Cookie();
44:
45: sub handler {
46: my $r = shift;
47:
48: &Apache::loncommon::get_unprocessed_cgi
49: (join('&',$ENV{'QUERY_STRING'},$env{'request.querystring'},
50: $ENV{'REDIRECT_QUERY_STRING'}),
51: ['interface','username','domain','firsturl','localpath','localres',
52: 'token','role','symb','iptoken','btoken','ltoken','ttoken','linkkey',
53: 'saml','sso','retry']);
54:
55: # -- check if they are a migrating user
56: if (defined($env{'form.token'})) {
57: return &Apache::migrateuser::handler($r);
58: }
59:
60: my $lonhost = $r->dir_config('lonHostID');
61: if ($env{'form.ttoken'}) {
62: my %info = &Apache::lonnet::tmpget($env{'form.ttoken'});
63: &Apache::lonnet::tmpdel($env{'form.ttoken'});
64: if ($info{'origurl'}) {
65: $env{'form.firsturl'} = $info{'origurl'};
66: }
67: if ($info{'ltoken'}) {
68: $env{'form.ltoken'} = $info{'ltoken'};
69: } elsif ($info{'linkprot'}) {
70: $env{'form.linkprot'} = $info{'linkprot'};
71: } elsif ($info{'linkkey'} ne '') {
72: $env{'form.linkkey'} = $info{'linkkey'};
73: }
74: } elsif (($env{'form.sso'}) || ($env{'form.retry'})) {
75: my $infotoken;
76: if ($env{'form.sso'}) {
77: $infotoken = $env{'form.sso'};
78: } else {
79: $infotoken = $env{'form.retry'};
80: }
81: my $data = &Apache::lonnet::reply('tmpget:'.$infotoken,$lonhost);
82: unless (($data=~/^error/) || ($data eq 'con_lost') ||
83: ($data eq 'no_such_host')) {
84: my %info = &decode_token($data);
85: foreach my $item (keys(%info)) {
86: $env{'form.'.$item} = $info{$item};
87: }
88: &Apache::lonnet::tmpdel($infotoken);
89: }
90: } else {
91: if (!defined($env{'form.firsturl'})) {
92: &Apache::lonacc::get_posted_cgi($r,['firsturl']);
93: }
94: if (!defined($env{'form.firsturl'})) {
95: if ($ENV{'REDIRECT_URL'} =~ m{^/+tiny/+$LONCAPA::match_domain/+\w+$}) {
96: $env{'form.firsturl'} = $ENV{'REDIRECT_URL'};
97: }
98: }
99: if (($env{'form.firsturl'} =~ m{^/+tiny/+$LONCAPA::match_domain/+\w+$}) &&
100: (!$env{'form.ltoken'}) && (!$env{'form.linkprot'}) && (!$env{'form.linkkey'})) {
101: &Apache::lonacc::get_posted_cgi($r,['linkkey']);
102: }
103: if ($env{'form.firsturl'} eq '/adm/logout') {
104: delete($env{'form.firsturl'});
105: }
106: }
107:
108: # For "public user" - remove any exising "public" cookie, as user really wants to log-in
109: my ($handle,$lonidsdir,$expirepub,$userdom);
110: $lonidsdir=$r->dir_config('lonIDsDir');
111: unless ($r->header_only) {
112: $handle = &Apache::lonnet::check_for_valid_session($r,'lonID',undef,\$userdom);
113: if ($handle ne '') {
114: if ($handle=~/^publicuser\_/) {
115: unlink($r->dir_config('lonIDsDir')."/$handle.id");
116: undef($handle);
117: undef($userdom);
118: $expirepub = 1;
119: }
120: }
121: }
122:
123: &Apache::loncommon::no_cache($r);
124: &Apache::lonlocal::get_language_handle($r);
125: &Apache::loncommon::content_type($r,'text/html');
126: if ($expirepub) {
127: my $c = new CGI::Cookie(-name => 'lonPubID',
128: -value => '',
129: -expires => '-10y',);
130: $r->header_out('Set-cookie' => $c);
131: } elsif (($handle eq '') && ($userdom ne '')) {
132: my %cookies=CGI::Cookie->parse($r->header_in('Cookie'));
133: foreach my $name (keys(%cookies)) {
134: next unless ($name =~ /^lon(|S|Link|Pub)ID$/);
135: my $c = new CGI::Cookie(-name => $name,
136: -value => '',
137: -expires => '-10y',);
138: $r->headers_out->add('Set-cookie' => $c);
139: }
140: }
141: $r->send_http_header;
142: return OK if $r->header_only;
143:
144:
145: # Are we re-routing?
146: my $londocroot = $r->dir_config('lonDocRoot');
147: if (-e "$londocroot/lon-status/reroute.txt") {
148: &Apache::lonauth::reroute($r);
149: return OK;
150: }
151:
152: # Check if browser sent a LON-CAPA load balancer cookie (and this is a balancer)
153:
154: my ($found_server,$balancer_cookie) = &Apache::lonnet::check_for_balancer_cookie($r,1);
155: if ($found_server) {
156: my $hostname = &Apache::lonnet::hostname($found_server);
157: if ($hostname ne '') {
158: my $protocol = $Apache::lonnet::protocol{$found_server};
159: $protocol = 'http' if ($protocol ne 'https');
160: my $dest = '/adm/roles';
161: if ($env{'form.firsturl'} ne '') {
162: $dest = &HTML::Entities::encode($env{'form.firsturl'},'\'"<>&');
163: }
164: my %info = (
165: balcookie => $lonhost.':'.$balancer_cookie,
166: );
167: if ($env{'form.role'}) {
168: $info{'role'} = $env{'form.role'};
169: }
170: if ($env{'form.symb'}) {
171: $info{'symb'} = $env{'form.symb'};
172: }
173: my $balancer_token = &Apache::lonnet::tmpput(\%info,$found_server);
174: unless (($balancer_token eq 'con_lost') || ($balancer_token eq 'refused') ||
175: ($balancer_token eq 'unknown_cmd') || ($balancer_token eq 'no_such_host')) {
176: $dest .= (($dest=~/\?/)?'&':'?') . 'btoken='.$balancer_token;
177: }
178: if ($env{'form.firsturl'} =~ m{^/tiny/$match_domain/\w+$}) {
179: my %link_info;
180: if ($env{'form.ltoken'}) {
181: $link_info{'ltoken'} = $env{'form.ltoken'};
182: } elsif ($env{'form.linkprot'}) {
183: $link_info{'linkprot'} = $env{'form.linkprot'};
184: } elsif ($env{'form.linkkey'} ne '') {
185: $link_info{'linkkey'} = $env{'form.linkkey'};
186: }
187: if (keys(%link_info)) {
188: $link_info{'origurl'} = $env{'form.firsturl'};
189: my $token = &Apache::lonnet::tmpput(\%link_info,$found_server,'link');
190: unless (($token eq 'con_lost') || ($token eq 'refused') ||
191: ($token eq 'unknown_cmd') || ($token eq 'no_such_host')) {
192: $dest .= (($dest=~/\?/)?'&':'?') . 'ttoken='.$token;
193: }
194: }
195: }
196: unless ($found_server eq $lonhost) {
197: my $alias = &Apache::lonnet::use_proxy_alias($r,$found_server);
198: $hostname = $alias if ($alias ne '');
199: }
200: my $url = $protocol.'://'.$hostname.$dest;
201: my $start_page =
202: &Apache::loncommon::start_page('Switching Server ...',undef,
203: {'redirect' => [0,$url],});
204: my $end_page = &Apache::loncommon::end_page();
205: $r->print($start_page.$end_page);
206: return OK;
207: }
208: }
209:
210: #
211: # Check if a LON-CAPA load balancer sent user here because user's browser sent
212: # it a balancer cookie for an active session on this server.
213: #
214:
215: my $balcookie;
216: if ($env{'form.btoken'}) {
217: my %info = &Apache::lonnet::tmpget($env{'form.btoken'});
218: $balcookie = $info{'balcookie'};
219: &Apache::lonnet::tmpdel($env{'form.btoken'});
220: delete($env{'form.btoken'});
221: }
222:
223: #
224: # If browser sent an old cookie for which the session file had been removed
225: # check if configuration for user's domain has a portal URL set. If so
226: # switch user's log-in to the portal.
227: #
228:
229: if (($handle eq '') && ($userdom ne '')) {
230: my %domdefaults = &Apache::lonnet::get_domain_defaults($userdom);
231: if ($domdefaults{'portal_def'} =~ /^https?\:/) {
232: my $start_page = &Apache::loncommon::start_page('Switching Server ...',undef,
233: {'redirect' => [0,$domdefaults{'portal_def'}],});
234: my $end_page = &Apache::loncommon::end_page();
235: $r->print($start_page.$end_page);
236: return OK;
237: }
238: }
239:
240: # -------------------------------- Prevent users from attempting to login twice
241: if ($handle ne '') {
242: &Apache::lonnet::transfer_profile_to_env($lonidsdir,$handle);
243: my $start_page =
244: &Apache::loncommon::start_page('Already logged in');
245: my $end_page =
246: &Apache::loncommon::end_page();
247: my $dest = '/adm/roles';
248: if ($env{'form.firsturl'} ne '') {
249: $dest = &HTML::Entities::encode($env{'form.firsturl'},'\'"<>&');
250: }
251: if (($env{'form.ltoken'}) || ($env{'form.linkprot'})) {
252: my $linkprot;
253: if ($env{'form.ltoken'}) {
254: my %info = &Apache::lonnet::tmpget($env{'form.ltoken'});
255: $linkprot = $info{'linkprot'};
256: my $delete = &Apache::lonnet::tmpdel($env{'form.ltoken'});
257: } else {
258: $linkprot = $env{'form.linkprot'};
259: }
260: if ($linkprot) {
261: my ($linkprotector,$deeplink) = split(/:/,$linkprot,2);
262: if ($env{'user.linkprotector'}) {
263: my @protectors = split(/,/,$env{'user.linkprotector'});
264: unless (grep(/^\Q$linkprotector\E$/,@protectors)) {
265: push(@protectors,$linkprotector);
266: @protectors = sort { $a <=> $b } @protectors;
267: &Apache::lonnet::appenv({'user.linkprotector' => join(',',@protectors)});
268: }
269: } else {
270: &Apache::lonnet::appenv({'user.linkprotector' => $linkprotector });
271: }
272: if ($env{'user.linkproturi'}) {
273: my @proturis = split(/,/,$env{'user.linkproturi'});
274: unless (grep(/^\Q$deeplink\E$/,@proturis)) {
275: push(@proturis,$deeplink);
276: @proturis = sort @proturis;
277: &Apache::lonnet::appenv({'user.linkproturi' => join(',',@proturis)});
278: }
279: } else {
280: &Apache::lonnet::appenv({'user.linkproturi' => $deeplink});
281: }
282: }
283: } elsif ($env{'form.linkkey'} ne '') {
284: if ($env{'form.firsturl'} =~ m{^/tiny/$match_domain/\w+$}) {
285: my $linkkey = $env{'form.linkkey'};
286: if ($env{'user.deeplinkkey'}) {
287: my @linkkeys = split(/,/,$env{'user.deeplinkkey'});
288: unless (grep(/^\Q$linkkey\E$/,@linkkeys)) {
289: push(@linkkeys,$linkkey);
290: &Apache::lonnet::appenv({'user.deeplinkkey' => join(',',sort(@linkkeys))});
291: }
292: } else {
293: &Apache::lonnet::appenv({'user.deeplinkkey' => $linkkey});
294: }
295: my $deeplink = $env{'form.firsturl'};
296: if ($env{'user.keyedlinkuri'}) {
297: my @keyeduris = split(/,/,$env{'user.keyedlinkuri'});
298: unless (grep(/^\Q$deeplink\E$/,@keyeduris)) {
299: push(@keyeduris,$deeplink);
300: &Apache::lonnet::appenv({'user.keyedlinkuri' => join(',',sort(@keyeduris))});
301: }
302: } else {
303: &Apache::lonnet::appenv({'user.keyedlinkuri' => $deeplink});
304: }
305: }
306: }
307: $r->print(
308: $start_page
309: .'<p class="LC_warning">'.&mt('You are already logged in!').'</p>'
310: .'<p>'.&mt('Please either [_1]continue the current session[_2] or [_3]log out[_4].',
311: '<a href="'.$dest.'">','</a>','<a href="/adm/logout">','</a>').'</p>'
312: .$end_page
313: );
314: return OK;
315: }
316:
317: # ---------------------------------------------------- No valid token, continue
318:
319: # ---------------------------- Not possible to really login to domain "public"
320: if ($env{'form.domain'} eq 'public') {
321: $env{'form.domain'}='';
322: $env{'form.username'}='';
323: }
324:
325: # ------ Is this page requested because /adm/migrateuser detected an IP change?
326: my %sessiondata;
327: if ($env{'form.iptoken'}) {
328: %sessiondata = &Apache::lonnet::tmpget($env{'form.iptoken'});
329: unless ($sessiondata{'sessionserver'}) {
330: my $delete = &Apache::lonnet::tmpdel($env{'form.iptoken'});
331: delete($env{'form.iptoken'});
332: }
333: }
334: # ----------------------------------------------------------- Process Interface
335: $env{'form.interface'}=~s/\W//g;
336:
337: (undef,undef,undef,undef,undef,undef,my $clientmobile) =
338: &Apache::loncommon::decode_user_agent($r);
339:
340: my $iconpath=
341: &Apache::loncommon::lonhttpdurl($r->dir_config('lonIconsURL'));
342:
343: my $domain = &Apache::lonnet::default_login_domain();
344: my $defdom = $domain;
345: if ($lonhost ne '') {
346: unless ($sessiondata{'sessionserver'}) {
347: my $redirect = &check_loginvia($domain,$lonhost,$lonidsdir,$balcookie);
348: if ($redirect) {
349: $r->print($redirect);
350: return OK;
351: }
352: }
353: }
354:
355: if (($sessiondata{'domain'}) &&
356: (&Apache::lonnet::domain($sessiondata{'domain'},'description'))) {
357: $domain=$sessiondata{'domain'};
358: } elsif (($env{'form.domain'}) &&
359: (&Apache::lonnet::domain($env{'form.domain'},'description'))) {
360: $domain=$env{'form.domain'};
361: }
362:
363: my $role = $r->dir_config('lonRole');
364: my $loadlim = $r->dir_config('lonLoadLim');
365: my $uloadlim= $r->dir_config('lonUserLoadLim');
366: my $servadm = $r->dir_config('lonAdmEMail');
367: my $tabdir = $r->dir_config('lonTabDir');
368: my $include = $r->dir_config('lonIncludes');
369: my $expire = $r->dir_config('lonExpire');
370: my $version = $r->dir_config('lonVersion');
371: my $host_name = &Apache::lonnet::hostname($lonhost);
372:
373: # --------------------------------------------- Default values for login fields
374:
375: my ($authusername,$authdomain);
376: if ($sessiondata{'username'}) {
377: $authusername=$sessiondata{'username'};
378: } else {
379: $env{'form.username'} = &Apache::loncommon::cleanup_html($env{'form.username'});
380: $authusername=($env{'form.username'}?$env{'form.username'}:'');
381: }
382: if ($sessiondata{'domain'}) {
383: $authdomain=$sessiondata{'domain'};
384: } else {
385: $env{'form.domain'} = &Apache::loncommon::cleanup_html($env{'form.domain'});
386: $authdomain=($env{'form.domain'}?$env{'form.domain'}:$domain);
387: }
388:
389: # ---------------------------------------------------------- Determine own load
390: my $loadavg;
391: {
392: my $loadfile=Apache::File->new('/proc/loadavg');
393: $loadavg=<$loadfile>;
394: }
395: $loadavg =~ s/\s.*//g;
396:
397: my ($loadpercent,$userloadpercent);
398: if ($loadlim) {
399: $loadpercent=sprintf("%.1f",100*$loadavg/$loadlim);
400: }
401: if ($uloadlim) {
402: $userloadpercent=&Apache::lonnet::userload();
403: }
404:
405: my $firsturl=
406: ($env{'request.firsturl'}?$env{'request.firsturl'}:$env{'form.firsturl'});
407:
408: # ----------------------------------------------------------- Get announcements
409: my $announcements=&Apache::lonnet::getannounce();
410: # -------------------------------------------------------- Set login parameters
411:
412: my @hexstr=('0','1','2','3','4','5','6','7',
413: '8','9','a','b','c','d','e','f');
414: my $lkey='';
415: for (0..7) {
416: $lkey.=$hexstr[rand(15)];
417: }
418:
419: my $ukey='';
420: for (0..7) {
421: $ukey.=$hexstr[rand(15)];
422: }
423:
424: my $lextkey=hex($lkey);
425: if ($lextkey>2147483647) { $lextkey-=4294967296; }
426:
427: my $uextkey=hex($ukey);
428: if ($uextkey>2147483647) { $uextkey-=4294967296; }
429:
430: # -------------------------------------------------------- Store away log token
431: my ($tokenextras,$tokentype,$linkprot_for_login);
432: my @names = ('role','symb','iptoken','ltoken','linkprot','linkkey');
433: foreach my $name (@names) {
434: if ($env{'form.'.$name} ne '') {
435: if ($name eq 'ltoken') {
436: my %info = &Apache::lonnet::tmpget($env{'form.'.$name});
437: if ($info{'linkprot'}) {
438: $linkprot_for_login = $info{'linkprot'};
439: $tokenextras .= '&linkprot='.&escape($info{'linkprot'});
440: $tokentype = 'link';
441: last;
442: }
443: } else {
444: $tokenextras .= '&'.$name.'='.&escape($env{'form.'.$name});
445: if (($name eq 'linkkey') || ($name eq 'linkprot')) {
446: if ((($env{'form.retry'}) || ($env{'form.sso'})) &&
447: (!$env{'form.ltoken'}) && ($name eq 'linkprot')) {
448: $linkprot_for_login = $env{'form.linkprot'};
449: }
450: $tokentype = 'link';
451: }
452: }
453: }
454: }
455: if ($tokentype) {
456: $tokenextras .= ":$tokentype";
457: }
458: my $logtoken=Apache::lonnet::reply(
459: 'tmpput:'.$ukey.$lkey.'&'.&escape($firsturl).$tokenextras,
460: $lonhost);
461:
462: # -- If we cannot talk to ourselves, or hostID does not map to a hostname
463: # we are in serious trouble
464:
465: if (($logtoken eq 'con_lost') || ($logtoken eq 'no_such_host')) {
466: if ($logtoken eq 'no_such_host') {
467: &Apache::lonnet::logthis('No valid logtoken for log-in page -- unable to determine hostname for hostID: '.$lonhost.'. Check entry in hosts.tab');
468: }
469: if ($env{'form.ltoken'}) {
470: &Apache::lonnet::tmpdel($env{'form.ltoken'});
471: delete($env{'form.ltoken'});
472: }
473: my $spares='';
474: my (@sparehosts,%spareservers);
475: my $sparesref = &Apache::lonnet::this_host_spares($defdom);
476: if (ref($sparesref) eq 'HASH') {
477: foreach my $key (keys(%{$sparesref})) {
478: if (ref($sparesref->{$key}) eq 'ARRAY') {
479: my @sorted = sort { &Apache::lonnet::hostname($a) cmp
480: &Apache::lonnet::hostname($b);
481: } @{$sparesref->{$key}};
482: if (@sorted) {
483: if ($key eq 'primary') {
484: unshift(@sparehosts,@sorted);
485: } elsif ($key eq 'default') {
486: push(@sparehosts,@sorted);
487: }
488: }
489: }
490: }
491: }
492: foreach my $hostid (@sparehosts) {
493: next if ($hostid eq $lonhost);
494: my $hostname = &Apache::lonnet::hostname($hostid);
495: next if (($hostname eq '') || ($spareservers{$hostname}));
496: $spareservers{$hostname} = 1;
497: my $protocol = $Apache::lonnet::protocol{$hostid};
498: $protocol = 'http' if ($protocol ne 'https');
499: $spares.='<br /><span style="font-size: larger;"><a href="'.$protocol.'://'.
500: $hostname.
501: '/adm/login?domain='.$authdomain.'">'.
502: $hostname.'</a>'.
503: ' '.&mt('(preferred)').'</span>'.$/;
504: }
505: if ($spares) {
506: $spares.= '<br />';
507: }
508: my %all_hostnames = &Apache::lonnet::all_hostnames();
509: foreach my $hostid (sort
510: {
511: &Apache::lonnet::hostname($a) cmp
512: &Apache::lonnet::hostname($b);
513: }
514: keys(%all_hostnames)) {
515: next if ($hostid eq $lonhost);
516: my $hostname = &Apache::lonnet::hostname($hostid);
517: next if (($hostname eq '') || ($spareservers{$hostname}));
518: $spareservers{$hostname} = 1;
519: my $protocol = $Apache::lonnet::protocol{$hostid};
520: $protocol = 'http' if ($protocol ne 'https');
521: $spares.='<br /><a href="'.$protocol.'://'.
522: $hostname.
523: '/adm/login?domain='.$authdomain.'">'.
524: $hostname.'</a>';
525: }
526: $r->print(
527: '<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">'
528: .'<html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">'
529: .'<head><meta http-equiv="Content-Type" content="text/html; charset=utf-8" /><title>'
530: .&mt('The LearningOnline Network with CAPA')
531: .'</title></head>'
532: .'<body bgcolor="#FFFFFF">'
533: .'<h1>'.&mt('The LearningOnline Network with CAPA').'</h1>'
534: .'<img src="/adm/lonKaputt/lonlogo_broken.gif" alt="broken icon" align="right" />'
535: .'<h3>'.&mt('This LON-CAPA server is temporarily not available for login.').'</h3>');
536: if ($spares) {
537: $r->print('<p>'.&mt('Please attempt to login to one of the following servers:')
538: .'</p>'
539: .$spares);
540: }
541: $r->print('</body>'
542: .'</html>'
543: );
544: return OK;
545: }
546:
547: # ----------------------------------------------- Apparently we are in business
548: $servadm=~s/\,/\<br \/\>/g;
549:
550: # ----------------------------------------------------------- Front page design
551: my $pgbg=&Apache::loncommon::designparm('login.pgbg',$domain);
552: my $font=&Apache::loncommon::designparm('login.font',$domain);
553: my $link=&Apache::loncommon::designparm('login.link',$domain);
554: my $vlink=&Apache::loncommon::designparm('login.vlink',$domain);
555: my $alink=&Apache::loncommon::designparm('login.alink',$domain);
556: my $mainbg=&Apache::loncommon::designparm('login.mainbg',$domain);
557: my $loginbox_bg=&Apache::loncommon::designparm('login.sidebg',$domain);
558: my $loginbox_header_bgcol=&Apache::loncommon::designparm('login.bgcol',$domain);
559: my $loginbox_header_textcol=&Apache::loncommon::designparm('login.textcol',$domain);
560: my $logo=&Apache::loncommon::designparm('login.logo',$domain);
561: my $img=&Apache::loncommon::designparm('login.img',$domain);
562: my $domainlogo=&Apache::loncommon::domainlogo($domain);
563: my $showbanner = 1;
564: my $showmainlogo = 1;
565: if (defined(&Apache::loncommon::designparm('login.showlogo_img',$domain))) {
566: $showbanner = &Apache::loncommon::designparm('login.showlogo_img',$domain);
567: }
568: if (defined(&Apache::loncommon::designparm('login.showlogo_logo',$domain))) {
569: $showmainlogo = &Apache::loncommon::designparm('login.showlogo_logo',$domain);
570: }
571: my $showadminmail;
572: my @possdoms = &Apache::lonnet::current_machine_domains();
573: if (grep(/^\Q$domain\E$/,@possdoms)) {
574: $showadminmail=&Apache::loncommon::designparm('login.adminmail',$domain);
575: }
576: my $showcoursecat =
577: &Apache::loncommon::designparm('login.coursecatalog',$domain);
578: my $shownewuserlink =
579: &Apache::loncommon::designparm('login.newuser',$domain);
580: my $showhelpdesk =
581: &Apache::loncommon::designparm('login.helpdesk',$domain);
582: my $now=time;
583: my $js = (<<ENDSCRIPT);
584:
585: <script type="text/javascript" language="JavaScript">
586: // <![CDATA[
587: function send()
588: {
589: this.document.server.elements.uname.value
590: =this.document.client.elements.uname.value;
591:
592: this.document.server.elements.udom.value
593: =this.document.client.elements.udom.value;
594:
595: uextkey=this.document.client.elements.uextkey.value;
596: lextkey=this.document.client.elements.lextkey.value;
597: initkeys();
598:
599: this.document.server.elements.upass0.value
600: =getCrypted(this.document.client.elements.upass$now.value);
601:
602: this.document.client.elements.uname.value='';
603: this.document.client.elements.upass$now.value='';
604:
605: this.document.server.submit();
606: return false;
607: }
608:
609: function enableInput() {
610: this.document.client.elements.upass$now.removeAttribute("readOnly");
611: this.document.client.elements.uname.removeAttribute("readOnly");
612: this.document.client.elements.udom.removeAttribute("readOnly");
613: return;
614: }
615:
616: // ]]>
617: </script>
618:
619: ENDSCRIPT
620:
621: my ($lonhost_in_use,@hosts,%defaultdomconf,$saml_prefix,$saml_landing,
622: $samlssotext,$samlnonsso,$samlssoimg,$samlssoalt,$samlssourl,$samltooltip);
623: %defaultdomconf = &Apache::loncommon::get_domainconf($defdom);
624: @hosts = &Apache::lonnet::current_machine_ids();
625: $lonhost_in_use = $lonhost;
626: if (@hosts > 1) {
627: foreach my $hostid (@hosts) {
628: if (&Apache::lonnet::host_domain($hostid) eq $defdom) {
629: $lonhost_in_use = $hostid;
630: last;
631: }
632: }
633: }
634: $saml_prefix = $defdom.'.login.saml_';
635: if ($defaultdomconf{$saml_prefix.$lonhost_in_use}) {
636: $saml_landing = 1;
637: $samlssotext = $defaultdomconf{$saml_prefix.'text_'.$lonhost_in_use};
638: $samlnonsso = $defaultdomconf{$saml_prefix.'notsso_'.$lonhost_in_use};
639: $samlssoimg = $defaultdomconf{$saml_prefix.'img_'.$lonhost_in_use};
640: $samlssoalt = $defaultdomconf{$saml_prefix.'alt_'.$lonhost_in_use};
641: $samlssourl = $defaultdomconf{$saml_prefix.'url_'.$lonhost_in_use};
642: $samltooltip = $defaultdomconf{$saml_prefix.'title_'.$lonhost_in_use};
643: }
644: if ($saml_landing) {
645: if ($samlssotext eq '') {
646: $samlssotext = 'SSO Login';
647: }
648: if ($samlnonsso eq '') {
649: $samlnonsso = 'Non-SSO Login';
650: }
651: $js .= <<"ENDSAMLJS";
652:
653: <script type="text/javascript">
654: // <![CDATA[
655: function toggleLClogin() {
656: if (document.getElementById('LC_standard_login')) {
657: if (document.getElementById('LC_standard_login').style.display == 'none') {
658: document.getElementById('LC_standard_login').style.display = 'inline-block';
659: if (document.getElementById('LC_login_text')) {
660: document.getElementById('LC_login_text').innerHTML = '$samlnonsso';
661: }
662: if ( document.client.uname ) { document.client.uname.focus(); }
663: if (document.getElementById('LC_SSO_login')) {
664: document.getElementById('LC_SSO_login').style.display = 'none';
665: }
666: } else {
667: document.getElementById('LC_standard_login').style.display = 'none';
668: if (document.getElementById('LC_login_text')) {
669: document.getElementById('LC_login_text').innerHTML = '$samlssotext';
670: }
671: if (document.getElementById('LC_SSO_login')) {
672: document.getElementById('LC_SSO_login').style.display = 'inline-block';
673: }
674: }
675: }
676: return;
677: }
678:
679: // ]]>
680: </script>
681:
682: ENDSAMLJS
683: }
684:
685: # --------------------------------------------------- Print login screen header
686:
687: my %add_entries = (
688: bgcolor => "$mainbg",
689: text => "$font",
690: link => "$link",
691: vlink => "$vlink",
692: alink => "$alink",
693: onload => 'javascript:enableInput();',);
694:
695: my ($headextra,$headextra_exempt);
696: $headextra = $defaultdomconf{$defdom.'.login.headtag_'.$lonhost_in_use};
697: $headextra_exempt = $defaultdomconf{$domain.'.login.headtag_exempt_'.$lonhost_in_use};
698: if ($headextra) {
699: my $omitextra;
700: if ($headextra_exempt ne '') {
701: my @exempt = split(',',$headextra_exempt);
702: my $ip = &Apache::lonnet::get_requestor_ip();
703: if (grep(/^\Q$ip\E$/,@exempt)) {
704: $omitextra = 1;
705: }
706: }
707: unless ($omitextra) {
708: my $confname = $defdom.'-domainconfig';
709: if ($headextra =~ m{^\Q/res/$defdom/$confname/login/headtag/$lonhost_in_use/\E}) {
710: my $extra = &Apache::lonnet::getfile(&Apache::lonnet::filelocation("",$headextra));
711: unless ($extra eq '-1') {
712: $js .= "\n".$extra."\n";
713: }
714: }
715: }
716: }
717:
718: $r->print(&Apache::loncommon::start_page('The LearningOnline Network with CAPA Login',$js,
719: { 'redirect' => [$expire,'/adm/roles'],
720: 'add_entries' => \%add_entries,
721: 'only_body' => 1,}));
722:
723: # ----------------------------------------------------------------------- Texts
724:
725: my %lt=&Apache::lonlocal::texthash(
726: 'un' => 'Username',
727: 'pw' => 'Password',
728: 'dom' => 'Domain',
729: 'perc' => 'percent',
730: 'load' => 'Server Load',
731: 'userload' => 'User Load',
732: 'catalog' => 'Course/Community Catalog',
733: 'log' => 'Log in',
734: 'help' => 'Log-in Help',
735: 'serv' => 'Server',
736: 'servadm' => 'Server Administration',
737: 'helpdesk' => 'Contact Helpdesk',
738: 'forgotpw' => 'Forgot password?',
739: 'newuser' => 'New User?',
740: 'change' => 'Change?',
741: );
742: # -------------------------------------------------- Change password field name
743:
744: my $forgotpw = &forgotpwdisplay(%lt);
745: $forgotpw .= '<br />' if $forgotpw;
746: my $loginhelp = &Apache::lonauth::loginhelpdisplay($authdomain);
747: if ($loginhelp) {
748: $loginhelp = '<a href="'.$loginhelp.'">'.$lt{'help'}.'</a><br />';
749: }
750:
751: # ---------------------------------------------------- Serve out DES JavaScript
752: {
753: my $jsh=Apache::File->new($include."/londes.js");
754: $r->print(<$jsh>);
755: }
756: # ---------------------------------------------------------- Serve rest of page
757:
758: $r->print(
759: '<div class="LC_Box"'
760: .' style="margin:0 auto; padding:10px; width:90%; height: auto; background-color:#FFFFFF;">'
761: );
762:
763: $r->print(<<ENDSERVERFORM);
764: <form name="server" action="/adm/authenticate" method="post" target="_top">
765: <input type="hidden" name="logtoken" value="$logtoken" />
766: <input type="hidden" name="serverid" value="$lonhost" />
767: <input type="hidden" name="uname" value="" />
768: <input type="hidden" name="upass0" value="" />
769: <input type="hidden" name="udom" value="" />
770: <input type="hidden" name="localpath" value="$env{'form.localpath'}" />
771: <input type="hidden" name="localres" value="$env{'form.localres'}" />
772: </form>
773: ENDSERVERFORM
774: my $coursecatalog;
775: if (($showcoursecat eq '') || ($showcoursecat)) {
776: $coursecatalog = &coursecatalog_link($lt{'catalog'}).'<br />';
777: }
778: my $newuserlink;
779: if ($shownewuserlink) {
780: $newuserlink = &newuser_link($lt{'newuser'}).'<br />';
781: }
782: my $logintitle =
783: '<h2 class="LC_hcell"'
784: .' style="background:'.$loginbox_header_bgcol.';'
785: .' color:'.$loginbox_header_textcol.'">'
786: .$lt{'log'}
787: .'</h2>';
788:
789: my $noscript_warning='<noscript><span class="LC_warning"><b>'
790: .&mt('Use of LON-CAPA requires Javascript to be enabled in your web browser.')
791: .'</b></span></noscript>';
792: my $helpdeskscript;
793: my $contactblock = &contactdisplay(\%lt,$servadm,$showadminmail,
794: $authdomain,\$helpdeskscript,
795: $showhelpdesk,\@possdoms);
796:
797: my $mobileargs;
798: if ($clientmobile) {
799: $mobileargs = 'autocapitalize="off" autocorrect="off"';
800: }
801: my $loginform=(<<LFORM);
802: <form name="client" action="" onsubmit="return(send())" id="lclogin">
803: <input type="hidden" name="lextkey" value="$lextkey" />
804: <input type="hidden" name="uextkey" value="$uextkey" />
805: <b><label for="uname">$lt{'un'}</label>:</b><br />
806: <input type="text" name="uname" id="uname" size="15" value="$authusername" readonly="readonly" $mobileargs /><br />
807: <b><label for="upass$now">$lt{'pw'}</label>:</b><br />
808: <input type="password" name="upass$now" id="upass$now" size="15" readonly="readonly" /><br />
809: <b><label for="udom">$lt{'dom'}</label>:</b><br />
810: <input type="text" name="udom" id="udom" size="15" value="$authdomain" readonly="readonly" $mobileargs /><br />
811: <input type="submit" value="$lt{'log'}" />
812: </form>
813: LFORM
814:
815: if ($showbanner) {
816: my $alttext = &Apache::loncommon::designparm('login.alttext_img',$domain);
817: if ($alttext eq '') {
818: $alttext = 'The Learning Online Network with CAPA';
819: }
820: $r->print(<<HEADER);
821: <!-- The LON-CAPA Header -->
822: <div style="background:$pgbg;margin:0;width:100%;">
823: <img src="$img" border="0" alt="$alttext" class="LC_maxwidth" id="lcloginbanner" />
824: </div>
825: HEADER
826: }
827:
828: my $stdauthformstyle = 'inline-block';
829: my $ssoauthstyle = 'none';
830: my $logintype;
831: $r->print('<div style="float:left;margin-top:0;">');
832: if ($saml_landing) {
833: $ssoauthstyle = 'inline-block';
834: $stdauthformstyle = 'none';
835: $logintype = $samlssotext;
836: my $ssologin = '/adm/sso';
837: if ($samlssourl ne '') {
838: $ssologin = $samlssourl;
839: }
840: if (($logtoken eq 'con_lost') || ($logtoken eq 'no_such_host')) {
841: my $querystring;
842: if ($env{'form.firsturl'} ne '') {
843: $querystring = 'origurl=';
844: if ($env{'form.firsturl'} =~ /[^\x00-\xFF]/) {
845: $querystring .= &uri_escape_utf8($env{'form.firsturl'});
846: } else {
847: $querystring .= &uri_escape($env{'form.firsturl'});
848: }
849: $querystring = &HTML::Entities::encode($querystring,"'");
850: }
851: if ($env{'form.ltoken'} ne '') {
852: $querystring .= (($querystring eq '')?'':'&') . 'ltoken='.
853: &HTML::Entities::encode(&uri_escape($env{'form.ltoken'}));
854: } elsif ($env{'form.linkkey'}) {
855: $querystring .= (($querystring eq '')?'':'&') . 'linkkey='.
856: &HTML::Entities::encode(&uri_escape($env{'form.linkkey'}));
857: }
858: if ($querystring ne '') {
859: $ssologin .= (($ssologin=~/\?/)?'&':'?') . $querystring;
860: }
861: } elsif ($logtoken ne '') {
862: $ssologin .= (($ssologin=~/\?/)?'&':'?') . 'logtoken='.$logtoken;
863: }
864: my $ssohref;
865: if ($samlssoimg ne '') {
866: $ssohref = '<a href="'.$ssologin.'" title="'.$samltooltip.'">'.
867: '<img src="'.$samlssoimg.'" alt="'.$samlssoalt.'" id="lcssobutton" /></a>';
868: } else {
869: $ssohref = '<a href="'.$ssologin.'">'.$samlssotext.'</a>';
870: }
871: if (($env{'form.saml'} eq 'no') ||
872: (($env{'form.username'} ne '') && ($env{'form.domain'} ne ''))) {
873: $ssoauthstyle = 'none';
874: $stdauthformstyle = 'inline-block';
875: $logintype = $samlnonsso;
876: }
877: $r->print(<<ENDSAML);
878: <p>
879: Log-in type:
880: <span style="font-weight:bold" id="LC_login_text">$logintype</span><br />
881: <span><a href="javascript:toggleLClogin();" style="color:#000000">$lt{'change'}</a></span>
882: </p>
883: <div style="display:$ssoauthstyle" id="LC_SSO_login">
884: <div class="LC_Box" style="padding-top: 10px;">
885: $ssohref
886: $noscript_warning
887: </div>
888: <div class="LC_Box" style="padding-top: 10px;">
889: $loginhelp
890: $contactblock
891: $coursecatalog
892: </div>
893: </div>
894: ENDSAML
895: } else {
896: if ($env{'form.ltoken'}) {
897: &Apache::lonnet::tmpdel($env{'form.ltoken'});
898: delete($env{'form.ltoken'});
899: }
900: }
901: my $in_frame_js;
902: if ($linkprot_for_login) {
903: my ($linkprotector,$linkproturi) = split(/:/,$linkprot_for_login,2);
904: if (($linkprotector =~ /^\d+(c|d)$/) && ($linkproturi =~ m{^/+tiny/+$LONCAPA::match_domain/+\w+$})) {
905: my $set_target;
906: if (($env{'form.retry'}) || ($env{'form.sso'})) {
907: if ($linkproturi eq $env{'form.firsturl'}) {
908: $set_target = " document.server.target = '_self';";
909: }
910: } else {
911: $set_target = <<ENDTARG;
912: var linkproturi = '$linkproturi';
913: var path = document.location.pathname.replace( new RegExp('^/adm/launch'),'');
914: if (linkproturi == path) {
915: document.server.target = '_self';
916: }
917: ENDTARG
918: }
919: $in_frame_js = <<ENDJS;
920: <script type="text/javascript">
921: // <![CDATA[
922: if ((window.self !== window.top) && (document.server.target != '_self')) {
923: $set_target
924: }
925: // ]]>
926: </script>
927: ENDJS
928: }
929: }
930:
931: $r->print(<<ENDLOGIN);
932: <div style="display:$stdauthformstyle;" id="LC_standard_login">
933: <div class="LC_Box" style="background:$loginbox_bg;">
934: $logintitle
935: $loginform
936: $noscript_warning
937: </div>
938:
939: <div class="LC_Box" style="padding-top: 10px;">
940: $loginhelp
941: $forgotpw
942: $contactblock
943: $newuserlink
944: $coursecatalog
945: </div>
946: </div>
947:
948: ENDLOGIN
949: $r->print('</div><div>'."\n");
950: if ($showmainlogo) {
951: my $alttext = &Apache::loncommon::designparm('login.alttext_logo',$domain);
952: $r->print(' <img src="'.$logo.'" alt="'.$alttext.'" class="LC_maxwidth" id="lcloginmainlogo" />'."\n");
953: }
954: $r->print(<<ENDTOP);
955: $announcements
956: </div>
957: <hr style="clear:both;" />
958: ENDTOP
959: my ($domainrow,$serverrow,$loadrow,$userloadrow,$versionrow);
960: $domainrow = <<"END";
961: <tr>
962: <td align="left" valign="top">
963: <small><b>$lt{'dom'}: </b></small>
964: </td>
965: <td align="left" valign="top">
966: <small><tt> $domain</tt></small>
967: </td>
968: </tr>
969: END
970: $serverrow = <<"END";
971: <tr>
972: <td align="left" valign="top">
973: <small><b>$lt{'serv'}: </b></small>
974: </td>
975: <td align="left" valign="top">
976: <small><tt> $lonhost ($role)</tt></small>
977: </td>
978: </tr>
979: END
980: if ($loadlim) {
981: $loadrow = <<"END";
982: <tr>
983: <td align="left" valign="top">
984: <small><b>$lt{'load'}: </b></small>
985: </td>
986: <td align="left" valign="top">
987: <small><tt> $loadpercent $lt{'perc'}</tt></small>
988: </td>
989: </tr>
990: END
991: }
992: if ($uloadlim) {
993: $userloadrow = <<"END";
994: <tr>
995: <td align="left" valign="top">
996: <small><b>$lt{'userload'}: </b></small>
997: </td>
998: <td align="left" valign="top">
999: <small><tt> $userloadpercent $lt{'perc'}</tt></small>
1000: </td>
1001: </tr>
1002: END
1003: }
1004: if (($version ne '') && ($version ne '<!-- VERSION -->')) {
1005: $versionrow = <<"END";
1006: <tr>
1007: <td colspan="2" align="left">
1008: <small>$version</small>
1009: </td>
1010: </tr>
1011: END
1012: }
1013:
1014: $r->print(<<ENDDOCUMENT);
1015: <div style="float: left;">
1016: <table border="0" cellspacing="0" cellpadding="0">
1017: $domainrow
1018: $serverrow
1019: $loadrow
1020: $userloadrow
1021: $versionrow
1022: </table>
1023: </div>
1024: <div style="float: right;">
1025: $domainlogo
1026: </div>
1027: <br style="clear:both;" />
1028: </div>
1029:
1030: $in_frame_js
1031: <script type="text/javascript">
1032: // <![CDATA[
1033: // the if prevents the script error if the browser can not handle this
1034: if ( document.client.uname ) { document.client.uname.focus(); }
1035: // ]]>
1036: </script>
1037: $helpdeskscript
1038:
1039: ENDDOCUMENT
1040: my %endargs = ( 'noredirectlink' => 1, );
1041: $r->print(&Apache::loncommon::end_page(\%endargs));
1042: return OK;
1043: }
1044:
1045: sub check_loginvia {
1046: my ($domain,$lonhost,$lonidsdir,$balcookie) = @_;
1047: if ($domain eq '' || $lonhost eq '' || $lonidsdir eq '') {
1048: return;
1049: }
1050: my %domconfhash = &Apache::loncommon::get_domainconf($domain);
1051: my $loginvia = $domconfhash{$domain.'.login.loginvia_'.$lonhost};
1052: my $loginvia_exempt = $domconfhash{$domain.'.login.loginvia_exempt_'.$lonhost};
1053: my $output;
1054: if ($loginvia ne '') {
1055: my $noredirect;
1056: my $ip = &Apache::lonnet::get_requestor_ip();
1057: if ($ip eq '127.0.0.1') {
1058: $noredirect = 1;
1059: } else {
1060: if ($loginvia_exempt ne '') {
1061: my @exempt = split(',',$loginvia_exempt);
1062: if (grep(/^\Q$ip\E$/,@exempt)) {
1063: $noredirect = 1;
1064: }
1065: }
1066: }
1067: unless ($noredirect) {
1068: my ($newhost,$path);
1069: if ($loginvia =~ /:/) {
1070: ($newhost,$path) = split(':',$loginvia);
1071: } else {
1072: $newhost = $loginvia;
1073: }
1074: if ($newhost ne $lonhost) {
1075: if (&Apache::lonnet::hostname($newhost) ne '') {
1076: if ($balcookie) {
1077: my ($balancer,$cookie) = split(/:/,$balcookie);
1078: if ($cookie =~ /^($match_domain)_($match_username)_([a-f0-9]+)$/) {
1079: my ($udom,$uname,$cookieid) = ($1,$2,$3);
1080: unless (&Apache::lonnet::delbalcookie($cookie,$balancer) eq 'ok') {
1081: if ((-d $lonidsdir) && (opendir(my $dh,$lonidsdir))) {
1082: while (my $filename=readdir($dh)) {
1083: if ($filename=~/^(\Q$uname\E_\d+_\Q$udom\E_$match_lonid)\.id$/) {
1084: my $handle = $1;
1085: my %hash =
1086: &Apache::lonnet::get_sessionfile_vars($handle,$lonidsdir,
1087: ['request.balancercookie',
1088: 'user.linkedenv']);
1089: if ($hash{'request.balancercookie'} eq "$balancer:$cookieid") {
1090: if (unlink("$lonidsdir/$filename")) {
1091: if (($hash{'user.linkedenv'} =~ /^[a-f0-9]+_linked$/) &&
1092: (-l "$lonidsdir/$hash{'user.linkedenv'}.id") &&
1093: (readlink("$lonidsdir/$hash{'user.linkedenv'}.id") eq "$lonidsdir/$filename")) {
1094: unlink("$lonidsdir/$hash{'user.linkedenv'}.id");
1095: }
1096: }
1097: }
1098: last;
1099: }
1100: }
1101: closedir($dh);
1102: }
1103: }
1104: }
1105: }
1106: $output = &redirect_page($newhost,$path);
1107: }
1108: }
1109: }
1110: }
1111: return $output;
1112: }
1113:
1114: sub redirect_page {
1115: my ($desthost,$path) = @_;
1116: my $hostname = &Apache::lonnet::hostname($desthost);
1117: my $protocol = $Apache::lonnet::protocol{$desthost};
1118: $protocol = 'http' if ($protocol ne 'https');
1119: unless ($path =~ m{^/}) {
1120: $path = '/'.$path;
1121: }
1122: my $url = $protocol.'://'.$hostname.$path;
1123: if ($env{'form.firsturl'} ne '') {
1124: my $querystring;
1125: if ($env{'form.firsturl'} =~ /[^\x00-\xFF]/) {
1126: $querystring = &uri_escape_utf8($env{'form.firsturl'});
1127: } else {
1128: $querystring = &uri_escape($env{'form.firsturl'});
1129: }
1130: $querystring = &HTML::Entities::encode($querystring,"'");
1131: $url .='?firsturl='.$querystring;
1132: }
1133: if (($env{'form.ltoken'}) || ($env{'form.linkkey'} ne '')) {
1134: my %link_info;
1135: if ($env{'form.ltoken'}) {
1136: $link_info{'ltoken'} = $env{'form.ltoken'};
1137: } elsif ($env{'form.linkkey'} ne '') {
1138: $link_info{'linkkey'} = $env{'form.linkkey'};
1139: }
1140: my $token = &Apache::lonnet::tmpput(\%link_info,$desthost,'link');
1141: unless (($token eq 'con_lost') || ($token eq 'refused') ||
1142: ($token eq 'unknown_cmd') || ($token eq 'no_such_host')) {
1143: $url .= (($url=~/\?/)?'&':'?') . 'ttoken='.$token;
1144: }
1145: }
1146: my $start_page = &Apache::loncommon::start_page('Switching Server ...',undef,
1147: {'redirect' => [0,$url],});
1148: my $end_page = &Apache::loncommon::end_page();
1149: return $start_page.$end_page;
1150: }
1151:
1152: sub contactdisplay {
1153: my ($lt,$servadm,$showadminmail,$authdomain,$helpdeskscript,$showhelpdesk,
1154: $possdoms) = @_;
1155: my $contactblock;
1156: my $origmail;
1157: if (ref($possdoms) eq 'ARRAY') {
1158: if (grep(/^\Q$authdomain\E$/,@{$possdoms})) {
1159: $origmail = $Apache::lonnet::perlvar{'lonSupportEMail'};
1160: }
1161: }
1162: my $requestmail =
1163: &Apache::loncommon::build_recipient_list(undef,'helpdeskmail',
1164: $authdomain,$origmail);
1165: unless ($showhelpdesk eq '0') {
1166: if ($requestmail =~ m/[^\@]+\@[^\@]+/) {
1167: $showhelpdesk = 1;
1168: } else {
1169: $showhelpdesk = 0;
1170: }
1171: }
1172: if ($servadm && $showadminmail) {
1173: $contactblock .= $$lt{'servadm'}.':<br />'.
1174: '<tt>'.$servadm.'</tt><br />';
1175: }
1176: if ($showhelpdesk) {
1177: $contactblock .= '<a href="javascript:helpdesk()">'.$lt->{'helpdesk'}.'</a><br />';
1178: my $thisurl = &escape('/adm/login');
1179: $$helpdeskscript = <<"ENDSCRIPT";
1180: <script type="text/javascript">
1181: // <![CDATA[
1182: function helpdesk() {
1183: var possdom = document.client.udom.value;
1184: var codedom = possdom.replace( new RegExp("[^A-Za-z0-9.\\-]","g"),'');
1185: if (codedom == '') {
1186: codedom = "$authdomain";
1187: }
1188: var querystr = "origurl=$thisurl&codedom="+codedom;
1189: document.location.href = "/adm/helpdesk?"+querystr;
1190: return;
1191: }
1192: // ]]>
1193: </script>
1194: ENDSCRIPT
1195: }
1196: return $contactblock;
1197: }
1198:
1199: sub forgotpwdisplay {
1200: my (%lt) = @_;
1201: my $prompt_for_resetpw = 1;
1202: if ($prompt_for_resetpw) {
1203: return '<a href="/adm/resetpw">'.$lt{'forgotpw'}.'</a>';
1204: }
1205: return;
1206: }
1207:
1208: sub coursecatalog_link {
1209: my ($linkname) = @_;
1210: return <<"END";
1211: <a href="/adm/coursecatalog">$linkname</a>
1212: END
1213: }
1214:
1215: sub newuser_link {
1216: my ($linkname) = @_;
1217: return '<a href="/adm/createaccount">'.$linkname.'</a>';
1218: }
1219:
1220: sub decode_token {
1221: my ($info) = @_;
1222: my ($firsturl,@rest)=split(/\&/,$info);
1223: my %form;
1224: if ($firsturl ne '') {
1225: $form{'firsturl'} = &unescape($firsturl);
1226: }
1227: foreach my $item (@rest) {
1228: my ($key,$value) = split(/=/,$item);
1229: $form{$key} = &unescape($value);
1230: }
1231: return %form;
1232: }
1233:
1234: 1;
1235: __END__
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>