1: # The LearningOnline Network with CAPA
2: # User Roles Screen
3: #
4: # $Id: lonroles.pm,v 1.201 2008/07/14 10:21:52 raeburn Exp $
5: #
6: # Copyright Michigan State University Board of Trustees
7: #
8: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
9: #
10: # LON-CAPA is free software; you can redistribute it and/or modify
11: # it under the terms of the GNU General Public License as published by
12: # the Free Software Foundation; either version 2 of the License, or
13: # (at your option) any later version.
14: #
15: # LON-CAPA is distributed in the hope that it will be useful,
16: # but WITHOUT ANY WARRANTY; without even the implied warranty of
17: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18: # GNU General Public License for more details.
19: #
20: # You should have received a copy of the GNU General Public License
21: # along with LON-CAPA; if not, write to the Free Software
22: # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
23: #
24: # /home/httpd/html/adm/gpl.txt
25: #
26: # http://www.lon-capa.org/
27: #
28: ###
29:
30: package Apache::lonroles;
31:
32: use strict;
33: use Apache::lonnet;
34: use Apache::lonuserstate();
35: use Apache::Constants qw(:common);
36: use Apache::File();
37: use Apache::lonmenu;
38: use Apache::loncommon;
39: use Apache::lonhtmlcommon;
40: use Apache::lonannounce;
41: use Apache::lonlocal;
42: use Apache::lonpageflip();
43: use Apache::lonnavdisplay();
44: use GDBM_File;
45: use LONCAPA qw(:DEFAULT :match);
46: use HTML::Entities;
47:
48:
49: sub redirect_user {
50: my ($r,$title,$url,$msg,$launch_nav) = @_;
51: $msg = $title if (! defined($msg));
52: &Apache::loncommon::content_type($r,'text/html');
53: &Apache::loncommon::no_cache($r);
54: $r->send_http_header;
55: my $swinfo=&Apache::lonmenu::rawconfig();
56: my $navwindow;
57: if ($launch_nav eq 'on') {
58: $navwindow.=&Apache::lonnavdisplay::launch_win('now',undef,undef,
59: ($url =~ m-^/adm/whatsnew-));
60: } else {
61: $navwindow.=&Apache::lonnavmaps::close();
62: }
63: my $start_page = &Apache::loncommon::start_page('Switching Role',undef,
64: {'redirect' => [1,$url],});
65: my $end_page = &Apache::loncommon::end_page();
66:
67: # Note to style police:
68: # This must only replace the spaces, nothing else, or it bombs elsewhere.
69: $url=~s/ /\%20/g;
70: $r->print(<<ENDREDIR);
71: $start_page
72: <script type="text/javascript">
73: $swinfo
74: </script>
75: $navwindow
76: <h1>$msg</h1>
77: $end_page
78: ENDREDIR
79: return;
80: }
81:
82: sub error_page {
83: my ($r,$error,$dest)=@_;
84: &Apache::loncommon::content_type($r,'text/html');
85: &Apache::loncommon::no_cache($r);
86: $r->send_http_header;
87: return OK if $r->header_only;
88: $r->print(&Apache::loncommon::start_page('Problems during Course Initialization').
89: '<script type="text/javascript">'.
90: &Apache::lonmenu::rawconfig().'</script>'.
91: '<p>'.&mt('The following problems occurred:').
92: $error.
93: '</p><br /><a href="'.$dest.'">'.&mt('Continue').'</a>'.
94: &Apache::loncommon::end_page());
95: }
96:
97: sub handler {
98:
99: my $r = shift;
100:
101: my $now=time;
102: my $then=$env{'user.login.time'};
103: my $envkey;
104: my %dcroles = ();
105: my $numdc = &check_fordc(\%dcroles,$then);
106: &Apache::loncommon::get_unprocessed_cgi($ENV{'QUERY_STRING'});
107:
108: # ================================================================== Roles Init
109: if ($env{'form.selectrole'}) {
110:
111: my $locknum=&Apache::lonnet::get_locks();
112: if ($locknum) { return 409; }
113:
114: if ($env{'form.newrole'}) {
115: $env{'form.'.$env{'form.newrole'}}=1;
116: }
117: if ($env{'request.course.id'}) {
118: # Check if user is CC trying to select a course role
119: if ($env{'form.switchrole'}) {
120: if (!defined($env{'user.role.'.$env{'form.switchrole'}})) {
121: &adhoc_course_role($then);
122: }
123: }
124: my %temp=('logout_'.$env{'request.course.id'} => time);
125: &Apache::lonnet::put('email_status',\%temp);
126: &Apache::lonnet::delenv('user.state.'.$env{'request.course.id'});
127: }
128: &Apache::lonnet::appenv({"request.course.id" => '',
129: "request.course.fn" => '',
130: "request.course.uri" => '',
131: "request.course.sec" => '',
132: "request.role" => 'cm',
133: "request.role.adv" => $env{'user.adv'},
134: "request.role.domain" => $env{'user.domain'}});
135: # Check if user is a DC trying to enter a course or author space and needs privs to be created
136: if ($numdc > 0) {
137: foreach my $envkey (keys %env) {
138: # Is this an ad-hoc CC-role?
139: if (my ($domain,$coursenum) =
140: ($envkey =~ m-^form\.cc\./($match_domain)/($match_courseid)$-)) {
141: if ($dcroles{$domain}) {
142: &check_privs($domain,$coursenum,$then,$now,'cc');
143: }
144: last;
145: }
146: # Is this an ad-hoc CA-role?
147: if (my ($domain,$user) =
148: ($envkey =~ m-^form\.ca\./($match_domain)/($match_username)$-)) {
149: # Check if author blocked ca-access
150: my %blocked=&Apache::lonnet::get('environment',['domcoord.author'],$domain,$user);
151: if ($blocked{'domcoord.author'} eq 'blocked') {
152: delete($env{$envkey});
153: $env{'user.error.msg'}=':::1:User '.$user.' in domain '.$domain.' blocked domain coordinator access';
154: last;
155: }
156: if ($dcroles{$domain}) {
157: my ($server_status,$home) = &check_author_homeserver($user,$domain);
158: if (($server_status eq 'ok') || ($server_status eq 'switchserver')) {
159: &check_privs($domain,$user,$then,$now,'ca');
160: if ($server_status eq 'switchserver') {
161: my $trolecode = 'ca./'.$domain.'/'.$user;
162: my $switchserver = '/adm/switchserver?'
163: .'otherserver='.$home.'&role='.$trolecode;
164: $r->internal_redirect($switchserver);
165: }
166: } else {
167: delete($env{$envkey});
168: }
169: } else {
170: delete($env{$envkey});
171: }
172: last;
173: }
174: }
175: }
176:
177: foreach $envkey (keys %env) {
178: next if ($envkey!~/^user\.role\./);
179: my ($where,$trolecode,$role,$tstatus,$tend,$tstart);
180: &role_status($envkey,$then,$now,\$role,\$where,\$trolecode,\$tstatus,\$tstart,\$tend);
181: if ($env{'form.'.$trolecode}) {
182: if ($tstatus eq 'is') {
183: $where=~s/^\///;
184: my ($cdom,$cnum,$csec)=split(/\//,$where);
185: # check for course groups
186: my %coursegroups = &Apache::lonnet::get_active_groups(
187: $env{'user.domain'},$env{'user.name'},$cdom, $cnum);
188: my $cgrps = join(':',keys(%coursegroups));
189:
190: # store role if recent_role list being kept
191: if ($env{'environment.recentroles'}) {
192: my %frozen_roles =
193: &Apache::lonhtmlcommon::get_recent_frozen('roles',$env{'environment.recentrolesn'});
194: &Apache::lonhtmlcommon::store_recent('roles',
195: $trolecode,' ',$frozen_roles{$trolecode});
196: }
197:
198:
199: # check for keyed access
200: if (($role eq 'st') &&
201: ($env{'course.'.$cdom.'_'.$cnum.'.keyaccess'} eq 'yes')) {
202: # who is key authority?
203: my $authdom=$cdom;
204: my $authnum=$cnum;
205: if ($env{'course.'.$cdom.'_'.$cnum.'.keyauth'}) {
206: ($authnum,$authdom)=
207: split(/:/,$env{'course.'.$cdom.'_'.$cnum.'.keyauth'});
208: }
209: # check with key authority
210: unless (&Apache::lonnet::validate_access_key(
211: $env{'environment.key.'.$cdom.'_'.$cnum},
212: $authdom,$authnum)) {
213: # there is no valid key
214: if ($env{'form.newkey'}) {
215: # student attempts to register a new key
216: &Apache::loncommon::content_type($r,'text/html');
217: &Apache::loncommon::no_cache($r);
218: $r->send_http_header;
219: my $swinfo=&Apache::lonmenu::rawconfig();
220: my $start_page=&Apache::loncommon::start_page
221: ('Verifying Access Key to Unlock this Course');
222: my $end_page=&Apache::loncommon::end_page();
223: my $buttontext=&mt('Enter Course');
224: my $message=&mt('Successfully registered key');
225: my $assignresult=
226: &Apache::lonnet::assign_access_key(
227: $env{'form.newkey'},
228: $authdom,$authnum,
229: $cdom,$cnum,
230: $env{'user.domain'},
231: $env{'user.name'},
232: 'Assigned from '.$ENV{'REMOTE_ADDR'}.' at '.localtime().' for '.
233: $trolecode);
234: unless ($assignresult eq 'ok') {
235: $assignresult=~s/^error\:\s*//;
236: $message=&mt($assignresult).
237: '<br /><a href="/adm/logout">'.
238: &mt('Logout').'</a>';
239: $buttontext=&mt('Re-Enter Key');
240: }
241: $r->print(<<ENDENTEREDKEY);
242: $start_page
243: <script type="text/javascript">
244: $swinfo
245: </script>
246: <form method="post">
247: <input type="hidden" name="selectrole" value="1" />
248: <input type="hidden" name="$trolecode" value="1" />
249: <font size="+2">$message</font><br />
250: <input type="submit" value="$buttontext" />
251: </form>
252: $end_page
253: ENDENTEREDKEY
254: return OK;
255: } else {
256: # print form to enter a new key
257: &Apache::loncommon::content_type($r,'text/html');
258: &Apache::loncommon::no_cache($r);
259: $r->send_http_header;
260: my $swinfo=&Apache::lonmenu::rawconfig();
261: my $start_page=&Apache::loncommon::start_page
262: ('Enter Access Key to Unlock this Course');
263: my $end_page=&Apache::loncommon::end_page();
264: $r->print(<<ENDENTERKEY);
265: $start_page
266: <script type="text/javascript">
267: $swinfo
268: </script>
269: <form method="post">
270: <input type="hidden" name="selectrole" value="1" />
271: <input type="hidden" name="$trolecode" value="1" />
272: <input type="text" size="20" name="newkey" value="$env{'form.newkey'}" />
273: <input type="submit" value="Enter key" />
274: </form>
275: $end_page
276: ENDENTERKEY
277: return OK;
278: }
279: }
280: }
281: &Apache::lonnet::log($env{'user.domain'},
282: $env{'user.name'},
283: $env{'user.home'},
284: "Role ".$trolecode);
285:
286: &Apache::lonnet::appenv(
287: {'request.role' => $trolecode,
288: 'request.role.domain' => $cdom,
289: 'request.course.sec' => $csec,
290: 'request.course.groups' => $cgrps});
291: my $tadv=0;
292:
293: if (($cnum) && ($role ne 'ca') && ($role ne 'aa')) {
294: my $msg;
295: my ($furl,$ferr)=
296: &Apache::lonuserstate::readmap($cdom.'/'.$cnum);
297: if (($env{'form.orgurl'}) &&
298: ($env{'form.orgurl'}!~/^\/adm\/flip/)) {
299: my $dest=$env{'form.orgurl'};
300: if (&Apache::lonnet::allowed('adv') eq 'F') { $tadv=1; }
301: &Apache::lonnet::appenv({'request.role.adv'=>$tadv});
302: if (($ferr) && ($tadv)) {
303: &error_page($r,$ferr,$dest);
304: } else {
305: $r->internal_redirect($dest);
306: }
307: return OK;
308: } else {
309: if (!$env{'request.course.id'}) {
310: &Apache::lonnet::appenv(
311: {"request.course.id" => $cdom.'_'.$cnum});
312: $furl='/adm/roles?tryagain=1';
313: $msg=
314: '<h1><span class="LC_error">'.
315: &mt('Could not initialize [_1] at this time.',
316: $env{'course.'.$cdom.'_'.$cnum.'.description'}).
317: '</span></h1><h3>'.&mt('Please try again.').'</h3>'.$ferr;
318: }
319: if (&Apache::lonnet::allowed('adv') eq 'F') { $tadv=1; }
320: &Apache::lonnet::appenv({'request.role.adv'=>$tadv});
321:
322: if (($ferr) && ($tadv)) {
323: &error_page($r,$ferr,$furl);
324: } else {
325: # Check to see if the user is a CC entering a course
326: # for the first time
327: my (undef, undef, $role, $courseid) = split(/\./, $envkey);
328: if (substr($courseid, 0, 1) eq '/') {
329: $courseid = substr($courseid, 1);
330: }
331: $courseid =~ s/\//_/;
332: if ($role eq 'cc' && $env{'course.' . $courseid .
333: '.course.helper.not.run'}) {
334: $furl = "/adm/helper/course.initialization.helper";
335: # Send the user to the course they selected
336: } elsif ($env{'request.course.id'}) {
337: if ($env{'form.destinationurl'}) {
338: my $dest = $env{'form.destinationurl'};
339: &redirect_user($r,&mt('Entering [_1]',
340: $env{'course.'.$courseid.'.description'}),
341: $dest,$msg,
342: $env{'environment.remotenavmap'});
343: return OK;
344: }
345: if (&Apache::lonnet::allowed('whn',
346: $env{'request.course.id'})
347: || &Apache::lonnet::allowed('whn',
348: $env{'request.course.id'}.'/'
349: .$env{'request.course.sec'})
350: ) {
351: my $startpage = &courseloadpage($courseid);
352: unless ($startpage eq 'firstres') {
353: $msg = &mt('Entering [_1] ....',
354: $env{'course.'.$courseid.'.description'});
355: &redirect_user($r,&mt('New in course'),
356: '/adm/whatsnew?refpage=start',$msg,
357: $env{'environment.remotenavmap'});
358: return OK;
359: }
360: }
361: }
362: # Are we allowed to look at the first resource?
363: if ($furl !~ m|^/adm/|) {
364: # Guess not ...
365: $furl=&Apache::lonpageflip::first_accessible_resource();
366: }
367: $msg = &mt('Entering [_1] ...',
368: $env{'course.'.$courseid.'.description'});
369: &redirect_user($r,&mt('Entering [_1]',
370: $env{'course.'.$courseid.'.description'}),
371: $furl,$msg,
372: $env{'environment.remotenavmap'});
373: }
374: return OK;
375: }
376: }
377: #
378: # Send the user to the construction space they selected
379: if ($role =~ /^(au|ca|aa)$/) {
380: my $redirect_url = '/priv/';
381: if ($role eq 'au') {
382: $redirect_url.=$env{'user.name'};
383: } else {
384: $where =~ /\/(.*)$/;
385: $redirect_url .= $1;
386: }
387: $redirect_url .= '/';
388: &redirect_user($r,&mt('Entering Construction Space'),
389: $redirect_url);
390: return OK;
391: }
392: if ($role eq 'dc') {
393: my $redirect_url = '/adm/menu/';
394: &redirect_user($r,&mt('Loading Domain Coordinator Menu'),
395: $redirect_url);
396: return OK;
397: }
398: }
399: }
400: }
401: }
402:
403:
404: # =============================================================== No Roles Init
405:
406: &Apache::loncommon::content_type($r,'text/html');
407: &Apache::loncommon::no_cache($r);
408: $r->send_http_header;
409: return OK if $r->header_only;
410:
411: my $swinfo=&Apache::lonmenu::rawconfig();
412: my $start_page=&Apache::loncommon::start_page('User Roles');
413: my $standby=&mt('Role selected. Please stand by.');
414: $standby=~s/\n/\\n/g;
415: my $noscript='<span class="LC_error">'.&mt('Use of LON-CAPA requires Javascript to be enabled in your web browser.').'<br />'.&mt('As this is not the case, most functionality in the system will be unavailable.').'</span><br />';
416:
417: $r->print(<<ENDHEADER);
418: $start_page
419: <br />
420: <noscript>
421: $noscript
422: </noscript>
423: <script type="text/javascript">
424: $swinfo
425: window.focus();
426:
427: active=true;
428:
429: function enterrole (thisform,rolecode,buttonname) {
430: if (active) {
431: active=false;
432: document.title='$standby';
433: window.status='$standby';
434: thisform.newrole.value=rolecode;
435: thisform.submit();
436: } else {
437: alert('$standby');
438: }
439: }
440: </script>
441: ENDHEADER
442:
443: # ------------------------------------------ Get Error Message from Environment
444:
445: my ($fn,$priv,$nochoose,$error,$msg)=split(/:/,$env{'user.error.msg'});
446: if ($env{'user.error.msg'}) {
447: $r->log_reason(
448: "$msg for $env{'user.name'} domain $env{'user.domain'} access $priv",$fn);
449: }
450:
451: # ------------------------------------------------- Can this user re-init, etc?
452:
453: my $advanced=$env{'user.adv'};
454: &Apache::loncommon::get_unprocessed_cgi($ENV{'QUERY_STRING'},['tryagain']);
455: my $tryagain=$env{'form.tryagain'};
456:
457: # -------------------------------------------------------- Generate Page Output
458: # --------------------------------------------------------------- Error Header?
459: if ($error) {
460: $r->print("<h1>".&mt('LON-CAPA Access Control')."</h1>");
461: $r->print("<!-- LONCAPAACCESSCONTROLERRORSCREEN --><hr /><pre>");
462: if ($priv ne '') {
463: $r->print(&mt('Access : ').&Apache::lonnet::plaintext($priv)."\n");
464: }
465: if ($fn ne '') {
466: $r->print(&mt('Resource: ').&Apache::lonenc::check_encrypt($fn)."\n");
467: }
468: if ($msg ne '') {
469: $r->print(&mt('Action : ').$msg."\n");
470: }
471: $r->print("</pre><hr />");
472: my $url=$fn;
473: my $last;
474: if (tie(my %hash,'GDBM_File',$env{'request.course.fn'}.'_symb.db',
475: &GDBM_READER(),0640)) {
476: $last=$hash{'last_known'};
477: untie(%hash);
478: }
479: if ($last) { $fn.='?symb='.&escape($last); }
480:
481: &Apache::londocs::changewarning($r,undef,'You have modified your course recently, [_1] may fix this access problem.',
482: &Apache::lonenc::check_encrypt($fn));
483: } else {
484: if ($env{'user.error.msg'}) {
485: $r->print(
486: '<h3><span class="LC_error">'.
487: &mt('You need to choose another user role or enter a specific course for this function').'</span></h3>');
488: }
489: }
490: # -------------------------------------------------------- Choice or no choice?
491: if ($nochoose) {
492: $r->print("<h2>".&mt('Sorry ...')."</h2>\n<span class='LC_error'>".
493: &mt('This action is currently not authorized.').'</span>'.
494: &Apache::loncommon::end_page());
495: return OK;
496: } else {
497: if (($ENV{'REDIRECT_QUERY_STRING'}) && ($fn)) {
498: $fn.='?'.$ENV{'REDIRECT_QUERY_STRING'};
499: }
500: $r->print('<form method="post" name="rolechoice" action="'.(($fn)?$fn:$r->uri).'">');
501: $r->print('<input type="hidden" name="orgurl" value="'.$fn.'" />');
502: $r->print('<input type="hidden" name="selectrole" value="1" />');
503: $r->print('<input type="hidden" name="newrole" value="" />');
504: }
505: my (%roletext,%sortrole,%roleclass);
506: my $countactive=0;
507: my $countfuture=0;
508: my $countwill=0;
509: my $inrole=0;
510: my $possiblerole='';
511: my %futureroles;
512: my %roles_nextlogin;
513: foreach $envkey (sort keys %env) {
514: my $button = 1;
515: my $switchserver='';
516: my $roletext;
517: my $sortkey;
518: if ($envkey=~/^user\.role\./) {
519: my ($role,$where,$trolecode,$tstart,$tend,$tremark,$tstatus,$tpstart,$tpend,$tfont);
520: &role_status($envkey,$then,$now,\$role,\$where,\$trolecode,\$tstatus,\$tstart,\$tend);
521: next if (!defined($role) || $role eq '' || $role =~ /^gr/);
522: $tremark='';
523: $tpstart=' ';
524: $tpend=' ';
525: $tfont='#000000';
526: if ($tstart) {
527: $tpstart=&Apache::lonlocal::locallocaltime($tstart);
528: }
529: if ($tend) {
530: $tpend=&Apache::lonlocal::locallocaltime($tend);
531: }
532: if ($env{'request.role'} eq $trolecode) {
533: $tstatus='selected';
534: }
535: my $tbg;
536: if (($tstatus eq 'is')
537: || ($tstatus eq 'selected')
538: || ($tstatus eq 'will')
539: || ($tstatus eq 'future')
540: || ($env{'form.showall'})) {
541: if ($tstatus eq 'is') {
542: $tbg='#77FF77';
543: $tfont='#003300';
544: $possiblerole=$trolecode;
545: $countactive++;
546: } elsif ($tstatus eq 'future') {
547: $tbg='#FFFF77';
548: $button=0;
549: $futureroles{$trolecode} = $tstart.':'.$tend;
550: $countfuture ++;
551: } elsif ($tstatus eq 'will') {
552: $tbg='#FFAA77';
553: $tremark.=&mt('Active at next login. ');
554: $roles_nextlogin{$trolecode} = $tstart.':'.$tend;
555: $countwill ++;
556: } elsif ($tstatus eq 'expired') {
557: $tbg='#FF7777';
558: $tfont='#330000';
559: $button=0;
560: } elsif ($tstatus eq 'will_not') {
561: $tbg='#AAFF77';
562: $tremark.=&mt('Expired after logout. ');
563: } elsif ($tstatus eq 'selected') {
564: $tbg='#11CC55';
565: $tfont='#002200';
566: $inrole=1;
567: $countactive++;
568: $tremark.=&mt('Currently selected. ');
569: }
570: my $trole;
571: if ($role =~ /^cr\//) {
572: my ($rdummy,$rdomain,$rauthor,$rrole)=split(/\//,$role);
573: if ($tremark) { $tremark.='<br />'; }
574: $tremark.=&mt('Defined by ').$rauthor.
575: &mt(' at ').$rdomain.'.';
576: }
577: $trole=Apache::lonnet::plaintext($role);
578: my $ttype;
579: my $twhere;
580: my ($tdom,$trest,$tsection)=
581: split(/\//,Apache::lonnet::declutter($where));
582: # First, Co-Authorship roles
583: if (($role eq 'ca') || ($role eq 'aa')) {
584: my $home = &Apache::lonnet::homeserver($trest,$tdom);
585: my $allowed=0;
586: my @ids=&Apache::lonnet::current_machine_ids();
587: foreach my $id (@ids) { if ($id eq $home) { $allowed=1; } }
588: if (!$allowed) {
589: $button=0;
590: $switchserver='otherserver='.$home.'&role='.$trolecode;
591: }
592: #next if ($home eq 'no_host');
593: $home = &Apache::lonnet::hostname($home);
594: $ttype='Construction Space';
595: $twhere=&mt('User').': '.$trest.'<br />'.&mt('Domain').
596: ': '.$tdom.'<br />'.
597: ' '.&mt('Server').': '.$home;
598: $env{'course.'.$tdom.'_'.$trest.'.description'}='ca';
599: $tremark.=&Apache::lonhtmlcommon::authorbombs('/res/'.$tdom.'/'.$trest.'/');
600: $sortkey=$role."$trest:$tdom";
601: } elsif ($role eq 'au') {
602: # Authors
603: my $home = &Apache::lonnet::homeserver
604: ($env{'user.name'},$env{'user.domain'});
605: my $allowed=0;
606: my @ids=&Apache::lonnet::current_machine_ids();
607: foreach my $id (@ids) { if ($id eq $home) { $allowed=1; } }
608: if (!$allowed) {
609: $button=0;
610: $switchserver='otherserver='.$home.'&role='.$trolecode;
611: }
612: #next if ($home eq 'no_host');
613: $home = &Apache::lonnet::hostname($home);
614: $ttype='Construction Space';
615: $twhere=&mt('Domain').': '.$tdom.'<br />'.&mt('Server').
616: ': '.$home;
617: $env{'course.'.$tdom.'_'.$trest.'.description'}='ca';
618: $tremark.=&Apache::lonhtmlcommon::authorbombs('/res/'.$tdom.'/'.$env{'user.name'}.'/');
619: $sortkey=$role;
620: } elsif ($trest) {
621: my $tcourseid=$tdom.'_'.$trest;
622: $ttype = &Apache::loncommon::course_type($tcourseid);
623: $trole = &Apache::lonnet::plaintext($role,$ttype);
624: if ($env{'course.'.$tcourseid.'.description'}) {
625: $twhere=$env{'course.'.$tcourseid.'.description'};
626: $sortkey=$role."\0".$tdom."\0".$twhere."\0".$envkey;
627: unless ($twhere eq &mt('Currently not available')) {
628: $twhere.=' <font size="-2">'.
629: &Apache::loncommon::syllabuswrapper(&mt('Syllabus'),$trest,$tdom,$tfont).
630: '</font>';
631: }
632: } else {
633: my %newhash=&Apache::lonnet::coursedescription($tcourseid);
634: if (%newhash) {
635: $sortkey=$role."\0".$tdom."\0".$newhash{'description'}.
636: "\0".$envkey;
637: $twhere=$newhash{'description'}.
638: ' <font size="-2">'.
639: &Apache::loncommon::syllabuswrapper(&mt('Syllabus'),$trest,$tdom,$tfont).
640: '</font>';
641: $ttype = $newhash{'type'};
642: $trole = &Apache::lonnet::plaintext($role,$ttype);
643: } else {
644: $twhere=&mt('Currently not available');
645: $env{'course.'.$tcourseid.'.description'}=$twhere;
646: $sortkey=$role."\0".$tdom."\0".$twhere."\0".$envkey;
647: $ttype = 'Unavailable';
648: }
649: }
650: if ($tsection) {
651: $twhere.='<br />'.&mt('Section').': '.$tsection;
652: }
653: if ($role ne 'st') { $twhere.="<br />".&mt('Domain').":".$tdom; }
654: } elsif ($tdom) {
655: $ttype='Domain';
656: $twhere=$tdom;
657: $sortkey=$role.$twhere;
658: } else {
659: $ttype='System';
660: $twhere=&mt('system wide');
661: $sortkey=$role.$twhere;
662: }
663: $roletext.=&build_roletext($trolecode,$tdom,$trest,$tstatus,$tryagain,$advanced,$tremark,$tbg,$tfont,$trole,$twhere,$tpstart,$tpend,$nochoose,$button,$switchserver);
664: $roletext{$envkey}=$roletext;
665: if (!$sortkey) {$sortkey=$twhere."\0".$envkey;}
666: $sortrole{$sortkey}=$envkey;
667: $roleclass{$envkey}=$ttype;
668: }
669: }
670: }
671: if ($env{'user.adv'}) {
672: $r->print(
673: '<br /><span class="LC_rolesinfo"><label>'.&mt('Show all roles').': <input type="checkbox" name="showall"');
674: if ($env{'form.showall'}) { $r->print(' checked="checked" '); }
675: $r->print(' /></label><input type="submit" value="'.&mt('Display').'" /></span>');
676: } else {
677: if ($countactive > 0) {
678: my $domdesc = &Apache::lonnet::domain($env{'user.domain'},'description');
679: my $esc_dom = &HTML::Entities::encode($env{'user.domain'},'"<>&');
680: $r->print('<p>'.&mt('[_1]Visit the [_2]Course Catalog[_3] to view all [_4] LON-CAPA courses.','<b>','<a href="/adm/coursecatalog?showdom='.$esc_dom.'">','</a></b>',$domdesc).'<br />'.&mt('If a course is [_1]not[_2] in your list of current courses below, you may be able to enroll if self-enrollment is permitted.','<b>','</b>').'</p>');
681: }
682: }
683:
684: # No active roles
685: if ($countactive==0) {
686: if ($inrole) {
687: $r->print('<h2>'.&mt('Currently no additional roles or courses').'</h2>');
688: } else {
689: $r->print('<h2>'.&mt('Currently no active roles or courses').'</h2>');
690: }
691: &findcourse_advice($r);
692: $r->print('</form>');
693: if ($countfuture) {
694: $r->print(&mt('The following [quant,_1,role,roles] will become active in the future:',$countfuture));
695: my $doheaders = &roletable_headers($r,\%roleclass,\%sortrole,
696: $nochoose);
697: &print_rolerows($r,$doheaders,\%roleclass,\%sortrole,\%dcroles,
698: \%roletext);
699: my $tremark='';
700: my $tfont='#003300';
701: if ($env{'request.role'} eq 'cm') {
702: $r->print('<tr bgcolor="#11CC55">');
703: $tremark=&mt('Currently selected. ');
704: $tfont='#002200';
705: } else {
706: $r->print('<tr bgcolor="#77FF77">');
707: }
708: $r->print('<td></td><td colspan="3"><font color="'.$tfont.'"><span class="LC_rolesinfo">'.&mt('No role specified').
709: '</span></font></td><td><font color="'.$tfont.'">'.$tremark.
710: ' </font></td></tr>'."\n");
711:
712: $r->print('</table>');
713: }
714: $r->print(&Apache::loncommon::end_page());
715: return OK;
716: # Is there only one choice?
717: } elsif (($countactive==1) && ($env{'request.role'} eq 'cm')) {
718: $r->print('<h3>'.&mt('Please stand by.').'</h3>'.
719: '<input type="hidden" name="'.$possiblerole.'" value="1" />'.
720: '<noscript><br /><input type="submit" name="submit" value="'.&mt('Continue').'" /></noscript>');
721: $r->print("</form>\n");
722: $r->rflush();
723: $r->print('<script type="text/javascript">document.forms.rolechoice.submit();</script>');
724: $r->print(&Apache::loncommon::end_page());
725: return OK;
726: }
727: # More than one possible role
728: # ----------------------------------------------------------------------- Table
729: unless ((!&Apache::lonmenu::show_course()) || ($nochoose)) {
730: $r->print("<h2>".&mt('Select a Course to Enter')."</h2>\n");
731: }
732: my $doheaders = &roletable_headers($r,\%roleclass,\%sortrole,$nochoose);
733: if ($env{'environment.recentroles'}) {
734: my %recent_roles =
735: &Apache::lonhtmlcommon::get_recent('roles',$env{'environment.recentrolesn'});
736: my $output='';
737: foreach (sort(keys(%recent_roles))) {
738: if (defined($roletext{'user.role.'.$_})) {
739: $output.=$roletext{'user.role.'.$_};
740: if ($_ =~ m-dc\./($match_domain)/-
741: && $dcroles{$1}) {
742: $output .= &adhoc_roles_row($1,'recent');
743: }
744: } elsif ($numdc > 0) {
745: unless ($_ =~/^error\:/) {
746: $output.=&display_cc_role('user.role.'.$_);
747: }
748: }
749: }
750: if ($output) {
751: $r->print("<tr><td align='center' colspan='5'><font face='arial'>".
752: &mt('Recent Roles')."</font></td></tr>");
753: $r->print($output);
754: $doheaders ++;
755: }
756: }
757:
758: if ($numdc > 0) {
759: $r->print(&coursepick_jscript());
760: $r->print(&Apache::loncommon::coursebrowser_javascript().
761: &Apache::loncommon::authorbrowser_javascript());
762: }
763: &print_rolerows($r,$doheaders,\%roleclass,\%sortrole,\%dcroles,\%roletext);
764: my $tremark='';
765: my $tfont='#003300';
766: if ($env{'request.role'} eq 'cm') {
767: $r->print('<tr bgcolor="#11CC55">');
768: $tremark=&mt('Currently selected. ');
769: $tfont='#002200';
770: } else {
771: $r->print('<tr bgcolor="#77FF77">');
772: }
773: unless ($nochoose) {
774: if ($env{'request.role'} ne 'cm') {
775: $r->print('<td><input type="submit" value="'.
776: &mt('Select').'" name="cm" /></td>');
777: } else {
778: $r->print('<td> </td>');
779: }
780: }
781: $r->print('<td colspan="3"><font color="'.$tfont.'"><span class="LC_rolesinfo">'.&mt('No role specified').
782: '</span></font></td><td><font color="'.$tfont.'">'.$tremark.
783: ' </font></td></tr>'."\n");
784:
785: $r->print('</table>');
786: unless ($nochoose) {
787: $r->print("</form>\n");
788: }
789: # ------------------------------------------------------------ Privileges Info
790: if (($advanced) && (($env{'user.error.msg'}) || ($error))) {
791: $r->print('<hr /><h2>Current Privileges</h2>');
792: $r->print(&privileges_info());
793: }
794: $r->print(&Apache::lonnet::getannounce());
795: if ($advanced) {
796: my $esc_dom = &HTML::Entities::encode($env{'user.domain'},'"<>&');
797: $r->print('<p><small><i>'
798: .&mt('This is LON-CAPA [_1]',$r->dir_config('lonVersion'))
799: .'</i><br />'
800: .'<a href="/adm/logout">'.&mt('Logout').'</a> '
801: .'<a href="/adm/coursecatalog?showdom='.$esc_dom.'">'
802: .&mt('Course Catalog')
803: .'</small></p>');
804: }
805: $r->print(&Apache::loncommon::end_page());
806: return OK;
807: }
808:
809: sub roletable_headers {
810: my ($r,$roleclass,$sortrole,$nochoose) = @_;
811: my $doheaders;
812: if ((ref($sortrole) eq 'HASH') && (ref($roleclass) eq 'HASH')) {
813: $r->print('<br /><table id="LC_rolesmenu"><tr>');
814: if (!$nochoose) { $r->print('<th> </th>'); }
815: $r->print('<th>'.&mt('User Role').'</th><th>'.&mt('Extent')
816: .'</th><th>'.&mt('Start').'</th><th>'.&mt('End')
817: .'</th></tr>'."\n");
818: $doheaders=-1;
819: my @roletypes = &roletypes();
820: foreach my $type (@roletypes) {
821: my $haverole=0;
822: foreach my $which (sort {uc($a) cmp uc($b)} (keys(%{$sortrole}))) {
823: if ($roleclass->{$sortrole->{$which}} =~ /^\Q$type\E/) {
824: $haverole=1;
825: }
826: }
827: if ($haverole) { $doheaders++; }
828: }
829: }
830: return $doheaders;
831: }
832:
833: sub roletypes {
834: my @types = ('Domain','Construction Space','Course','Unavailable','System');
835: return @types;
836: }
837:
838: sub print_rolerows {
839: my ($r,$doheaders,$roleclass,$sortrole,$dcroles,$roletext) = @_;
840: if ((ref($roleclass) eq 'HASH') && (ref($sortrole) eq 'HASH')) {
841: my @types = &roletypes();
842: foreach my $type (@types) {
843: my $output;
844: foreach my $which (sort {uc($a) cmp uc($b)} (keys(%{$sortrole}))) {
845: if ($roleclass->{$sortrole->{$which}} =~ /^\Q$type\E/) {
846: if (ref($roletext) eq 'HASH') {
847: $output.=$roletext->{$sortrole->{$which}};
848: if ($sortrole->{$which} =~ m-dc\./($match_domain)/-) {
849: if (ref($dcroles) eq 'HASH') {
850: if ($dcroles->{$1}) {
851: $output .= &adhoc_roles_row($1,'');
852: }
853: }
854: }
855: }
856: }
857: }
858: if ($output) {
859: if ($doheaders > 0) {
860: $r->print("<tr>".
861: "<td align='center' colspan='5'><font face='arial'>".
862: &mt($type)."</font></td></tr>");
863: }
864: $r->print($output);
865: }
866: }
867: }
868: }
869:
870: sub findcourse_advice {
871: my ($r) = @_;
872: my $domdesc = &Apache::lonnet::domain($env{'user.domain'},'description');
873: my $esc_dom = &HTML::Entities::encode($env{'user.domain'},'"<>&');
874: if (&Apache::lonnet::auto_run(undef,$env{'user.domain'})) {
875: $r->print(&mt('If you were expecting to see an active role listed for a particular course in the [_1] domain, it may be missing for one of the following reasons:',$domdesc).'
876: <ul>
877: <li>'.&mt('The course has yet to be created.').'</li>
878: <li>'.&mt('Automatic enrollment of registered students has not been enabled for the course.').'</li>
879: <li>'.&mt('You are in a section of course for which automatic enrollment in the corresponding LON-CAPA course is not active.').'</li>
880: <li>'.&mt('The start date for automated enrollment has yet to be reached.').'</li>
881: <li>'.&mt('You registered for the course recently and there is a time lag between the time you register, and the time this information becomes available for the update of LON-CAPA course rosters.').'</li>
882: </ul>');
883: } else {
884: $r->print(&mt('If you were expecting to see an active role listed for a particular course, that course may not have been created yet.').'<br />');
885: }
886: $r->print('<p>'.&mt('The [_1]Course Catalog[_2] provides information about all [_3] classes for which LON-CAPA courses have been created.','<a href="/adm/coursecatalog?showdom='.$esc_dom.'">','</a>',$domdesc).'<br />');
887: $r->print(&mt('You can search the course catalog for courses which permit self-enrollment, if you would like to enroll in a course.').'</p>');
888: return;
889: }
890:
891: sub privileges_info {
892: my ($which) = @_;
893: my $output;
894:
895: $which ||= $env{'request.role'};
896:
897: foreach my $envkey (sort(keys(%env))) {
898: next if ($envkey!~/^user\.priv\.\Q$which\E\.(.*)/);
899:
900: my $where=$1;
901: my $ttype;
902: my $twhere;
903: my (undef,$tdom,$trest,$tsec)=split(m{/},$where);
904: if ($trest) {
905: if ($env{'course.'.$tdom.'_'.$trest.'.description'} eq 'ca') {
906: $ttype='Construction Space';
907: $twhere='User: '.$trest.', Domain: '.$tdom;
908: } else {
909: $ttype= &Apache::loncommon::course_type($tdom.'_'.$trest);
910: $twhere=$env{'course.'.$tdom.'_'.$trest.'.description'};
911: if ($tsec) {
912: my $sec_type = 'Section';
913: if (exists($env{"user.role.gr.$where"})) {
914: $sec_type = 'Group';
915: }
916: $twhere.=' ('.$sec_type.': '.$tsec.')';
917: }
918: }
919: } elsif ($tdom) {
920: $ttype='Domain';
921: $twhere=$tdom;
922: } else {
923: $ttype='System';
924: $twhere='/';
925: }
926: $output .= "\n<h3>".$ttype.': '.$twhere.'</h3>'."\n<ul>";
927: foreach my $priv (sort(split(/:/,$env{$envkey}))) {
928: next if (!$priv);
929:
930: my ($prv,$restr)=split(/\&/,$priv);
931: my $trestr='';
932: if ($restr ne 'F') {
933: $trestr.=' ('.
934: join(', ',
935: map { &Apache::lonnet::plaintext($_) }
936: (split('',$restr))).') ';
937: }
938: $output .= "\n\t".
939: '<li>'.&Apache::lonnet::plaintext($prv).$trestr.'</li>';
940: }
941: $output .= "\n".'</ul>';
942: }
943: return $output;
944: }
945:
946: sub role_status {
947: my ($rolekey,$then,$now,$role,$where,$trolecode,$tstatus,$tstart,$tend) = @_;
948: my @pwhere = ();
949: if (exists($env{$rolekey}) && $env{$rolekey} ne '') {
950: (undef,undef,$$role,@pwhere)=split(/\./,$rolekey);
951: unless (!defined($$role) || $$role eq '') {
952: $$where=join('.',@pwhere);
953: $$trolecode=$$role.'.'.$$where;
954: ($$tstart,$$tend)=split(/\./,$env{$rolekey});
955: $$tstatus='is';
956: if ($$tstart && $$tstart>$then) {
957: $$tstatus='future';
958: if ($$tstart<$now) { $$tstatus='will'; }
959: }
960: if ($$tend) {
961: if ($$tend<$then) {
962: $$tstatus='expired';
963: } elsif ($$tend<$now) {
964: $$tstatus='will_not';
965: }
966: }
967: }
968: }
969: }
970:
971: sub build_roletext {
972: my ($trolecode,$tdom,$trest,$tstatus,$tryagain,$advanced,$tremark,$tbg,$tfont,$trole,$twhere,$tpstart,$tpend,$nochoose,$button,$switchserver) = @_;
973: my $roletext='<tr bgcolor="'.$tbg.'" class="LC_rolesmenu_'.$tstatus.'">';
974: my $is_dc=($trolecode =~ m/^dc\./);
975: my $rowspan=($is_dc) ? ''
976: : ' rowspan="2" ';
977:
978: unless ($nochoose) {
979: my $buttonname=$trolecode;
980: $buttonname=~s/\W//g;
981: if (!$button) {
982: if ($switchserver) {
983: $roletext.='<td'.$rowspan.'><span class="LC_rolesinfo"><a href="/adm/switchserver?'.
984: $switchserver.'">'.&mt('Switch Server').'</a></span></td>';
985: } else {
986: $roletext.=('<td'.$rowspan.'> </td>');
987: }
988: } elsif ($tstatus eq 'is') {
989: $roletext.='<td'.$rowspan.'><input name="'.$buttonname.'" type="button" value="'.
990: &mt('Select').'" onClick="javascript:enterrole(this.form,\''.
991: $trolecode."','".$buttonname.'\');" /></td>';
992: } elsif ($tryagain) {
993: $roletext.=
994: '<td'.$rowspan.'><input name="'.$buttonname.'" type="button" value="'.
995: &mt('Try Selecting Again').'" onClick="javascript:enterrole(this.form,\''.
996: $trolecode."','".$buttonname.'\');" /></td>';
997: } elsif ($advanced) {
998: $roletext.=
999: '<td'.$rowspan.'><input name="'.$buttonname.'" type="button" value="'.
1000: &mt('Re-Initialize').'" onClick="javascript:enterrole(this.form,\''.
1001: $trolecode."','".$buttonname.'\');" /></td>';
1002: } else {
1003: $roletext.='<td'.$rowspan.'> </td>';
1004: }
1005: }
1006: if ($trolecode !~ m/^(dc|ca|au|aa)\./) {
1007: $tremark.=&Apache::lonannounce::showday(time,1,
1008: &Apache::lonannounce::readcalendar($tdom.'_'.$trest));
1009: }
1010: $roletext.='<td><font color="'.$tfont.'">'.$trole.
1011: '</font></td><td><font color="'.$tfont.'">'.$twhere.
1012: '</font></td><td><font color="'.$tfont.'">'.$tpstart.
1013: '</font></td><td><font color="'.$tfont.'">'.$tpend.
1014: '</font></td></tr>';
1015: if (!$is_dc) {
1016: $roletext.='<tr bgcolor="'.$tbg.'"><td colspan="4"><font color="'.$tfont.'"><span class="LC_rolesinfo">'.$tremark.
1017: '</span> </font></td></tr><tr><td colspan="5" height="3"></td></tr>'."\n";
1018: }
1019: return $roletext;
1020: }
1021:
1022: sub check_author_homeserver {
1023: my ($uname,$udom)=@_;
1024: if (($uname eq '') || ($udom eq '')) {
1025: return ('fail','');
1026: }
1027: my $home = &Apache::lonnet::homeserver($uname,$udom);
1028: if (&Apache::lonnet::host_domain($home) ne $udom) {
1029: return ('fail',$home);
1030: }
1031: my @ids=&Apache::lonnet::current_machine_ids();
1032: if (grep(/^\Q$home\E$/,@ids)) {
1033: return ('ok',$home);
1034: } else {
1035: return ('switchserver',$home);
1036: }
1037: }
1038:
1039: sub check_privs {
1040: my ($cdom,$cnum,$then,$now,$checkrole) = @_;
1041: my $cckey = 'user.role.'.$checkrole.'./'.$cdom.'/'.$cnum;
1042: if ($env{$cckey}) {
1043: my ($role,$where,$trolecode,$tstart,$tend,$tremark,$tstatus,$tpstart,$tpend,$tfont);
1044: &role_status($cckey,$then,$now,\$role,\$where,\$trolecode,\$tstatus,\$tstart,\$tend);
1045: unless (($tstatus eq 'is') || ($tstatus eq 'will_not')) {
1046: &set_privileges($cdom,$cnum,$checkrole);
1047: }
1048: } else {
1049: &set_privileges($cdom,$cnum,$checkrole);
1050: }
1051: }
1052:
1053: sub check_fordc {
1054: my ($dcroles,$then) = @_;
1055: my $numdc = 0;
1056: if ($env{'user.adv'}) {
1057: foreach my $envkey (sort keys %env) {
1058: if ($envkey=~/^user\.role\.dc\.\/($match_domain)\/$/) {
1059: my $dcdom = $1;
1060: my $livedc = 1;
1061: my ($tstart,$tend)=split(/\./,$env{$envkey});
1062: if ($tstart && $tstart>$then) { $livedc = 0; }
1063: if ($tend && $tend <$then) { $livedc = 0; }
1064: if ($livedc) {
1065: $$dcroles{$dcdom} = $envkey;
1066: $numdc++;
1067: }
1068: }
1069: }
1070: }
1071: return $numdc;
1072: }
1073:
1074: sub adhoc_course_role {
1075: my ($then) = @_;
1076: my ($cdom,$cnum);
1077: $cdom = $env{'course.'.$env{'request.course.id'}.'.domain'};
1078: $cnum = $env{'course.'.$env{'request.course.id'}.'.num'};
1079: if (&check_forcc($cdom,$cnum,$then)) {
1080: my $setprivs;
1081: if (!defined($env{'user.role.'.$env{'form.switchrole'}})) {
1082: $setprivs = 1;
1083: } else {
1084: my ($start,$end) = split(/\./,$env{'user.role.'.$env{'form.switchrole'}});
1085: if (($start && ($start>$then || $start == -1)) ||
1086: ($end && $end<$then)) {
1087: $setprivs = 1;
1088: }
1089: }
1090: if ($setprivs) {
1091: if ($env{'form.switchrole'} =~ m-^(in|ta|ep|ad|st|cr)([\w/]*)\./\Q$cdom\E/\Q$cnum\E/?(\w*)$-) {
1092: my $role = $1;
1093: my $custom_role = $2;
1094: my $usec = $3;
1095: if ($role eq 'cr') {
1096: if ($custom_role =~ m-^/$match_domain/$match_username/\w+$-) {
1097: $role .= $custom_role;
1098: } else {
1099: return;
1100: }
1101: }
1102: my (%userroles,%newrole,%newgroups);
1103: my $area = '/'.$cdom.'/'.$cnum;
1104: my $spec = $role.'.'.$area;
1105: if ($usec ne '') {
1106: $spec .= '/'.$usec;
1107: $area .= '/'.$usec;
1108: }
1109: &Apache::lonnet::standard_roleprivs(\%newrole,$role,$cdom,$spec,$cnum,$area);
1110: &Apache::lonnet::set_userprivs(\%userroles,\%newrole,%newgroups);
1111: my $adhocstart = $then-1;
1112: $userroles{'user.role.'.$spec} = $adhocstart.'.';
1113: &Apache::lonnet::appenv(\%userroles,[$role,'cm']);
1114: }
1115: }
1116: }
1117: return;
1118: }
1119:
1120: sub check_forcc {
1121: my ($cdom,$cnum,$then) = @_;
1122: my $is_cc;
1123: if ($cdom ne '' && $cnum ne '') {
1124: if (&Apache::lonnet::is_course($cdom,$cnum)) {
1125: my $envkey = 'user.role.cc./'.$cdom.'/'.$cnum;
1126: if (defined($env{$envkey})) {
1127: $is_cc = 1;
1128: my ($tstart,$tend)=split(/\./,$env{$envkey});
1129: if ($tstart && $tstart>$then) { $is_cc = 0; }
1130: if ($tend && $tend <$then) { $is_cc = 0; }
1131: }
1132: }
1133: }
1134: return $is_cc;
1135: }
1136:
1137: sub courselink {
1138: my ($dcdom,$rowtype) = @_;
1139: my $courseform=&Apache::loncommon::selectcourse_link
1140: ('rolechoice','dccourse'.$rowtype.'_'.$dcdom,
1141: 'dcdomain'.$rowtype.'_'.$dcdom,'coursedesc'.$rowtype.'_'.
1142: $dcdom,$dcdom,undef);
1143: my $hiddenitems = '<input type="hidden" name="dcdomain'.$rowtype.'_'.$dcdom.'" value="'.$dcdom.'" />'.
1144: '<input type="hidden" name="origdom'.$rowtype.'_'.$dcdom.'" value="'.$dcdom.'" />'.
1145: '<input type="hidden" name="dccourse'.$rowtype.'_'.$dcdom.'" value="" />'.
1146: '<input type="hidden" name="coursedesc'.$rowtype.'_'.$dcdom.'" value="" />';
1147: return $courseform.$hiddenitems;
1148: }
1149:
1150: sub coursepick_jscript {
1151: my %lt = &Apache::lonlocal::texthash(
1152: plsu => "Please use the 'Select Course' link to open a separate pick course window where you may select the course you wish to enter.",
1153: youc => 'You can only use this screen to select courses in the current domain.',
1154: );
1155: my $verify_script = <<"END";
1156: <script type="text/javascript">
1157: function verifyCoursePick(caller) {
1158: var numbutton = getIndex(caller)
1159: var pickedCourse = document.rolechoice.elements[numbutton+4].value
1160: var pickedDomain = document.rolechoice.elements[numbutton+2].value
1161: if (document.rolechoice.elements[numbutton+2].value == document.rolechoice.elements[numbutton+3].value) {
1162: if (pickedCourse != '') {
1163: if (numbutton != -1) {
1164: var courseTarget = "cc./"+pickedDomain+"/"+pickedCourse
1165: document.rolechoice.elements[numbutton+1].name = courseTarget
1166: document.rolechoice.submit()
1167: }
1168: }
1169: else {
1170: alert("$lt{'plsu'}");
1171: }
1172: }
1173: else {
1174: alert("$lt{'youc'}")
1175: }
1176: }
1177: function getIndex(caller) {
1178: for (var i=0;i<document.rolechoice.elements.length;i++) {
1179: if (document.rolechoice.elements[i] == caller) {
1180: return i;
1181: }
1182: }
1183: return -1;
1184: }
1185: </script>
1186: END
1187: return $verify_script;
1188: }
1189:
1190: sub coauthorlink {
1191: my ($dcdom,$rowtype) = @_;
1192: my $coauthorform=&Apache::loncommon::selectauthor_link('rolechoice',$dcdom);
1193: my $hiddenitems = '<input type="hidden" name="adhoccauname'.$rowtype.'_'.$dcdom.'" value="" />';
1194: return $coauthorform.$hiddenitems;
1195: }
1196:
1197: sub display_cc_role {
1198: my $rolekey = shift;
1199: my $roletext;
1200: my $advanced = $env{'user.adv'};
1201: my $tryagain = $env{'form.tryagain'};
1202: unless ($rolekey =~/^error\:/) {
1203: if ($rolekey =~ m-^user\.role.cc\./($match_domain)/($match_courseid)$-) {
1204: my $tcourseid = $1.'_'.$2;
1205: my $trolecode = 'cc./'.$1.'/'.$2;
1206: my $twhere;
1207: my $ttype;
1208: my $tbg='#77FF77';
1209: my $tfont='#003300';
1210: my %newhash=&Apache::lonnet::coursedescription($tcourseid);
1211: if (%newhash) {
1212: $twhere=$newhash{'description'}.
1213: ' <font size="-2">'.
1214: &Apache::loncommon::syllabuswrapper(&mt('Syllabus'),$2,$1,$tfont).
1215: '</font>';
1216: $ttype = $newhash{'type'};
1217: } else {
1218: $twhere=&mt('Currently not available');
1219: $env{'course.'.$tcourseid.'.description'}=$twhere;
1220: }
1221: my $trole = &Apache::lonnet::plaintext('cc',$ttype);
1222: $twhere.="<br />".&mt('Domain').":".$1;
1223: $roletext = &build_roletext($trolecode,$1,$2,'is',$tryagain,$advanced,'',$tbg,$tfont,$trole,$twhere,'','','',1,'');
1224: }
1225: }
1226: return ($roletext);
1227: }
1228:
1229: sub adhoc_roles_row {
1230: my ($dcdom,$rowtype) = @_;
1231: my $output = '<tr bgcolor="#77FF77">'.
1232: ' <td colspan="5"><table><tr><td><span class="LC_rolesinfo">'
1233: .&mt('[_1]Ad hoc[_2] roles in domain [_3] --',
1234: '<span class="LC_cusr_emph">','</span>',$dcdom).'</span></td><td>';
1235: my $selectcclink = &courselink($dcdom,$rowtype);
1236: my $ccrole = &Apache::lonnet::plaintext('cc');
1237: my $carole = &Apache::lonnet::plaintext('ca');
1238: my $selectcalink = &coauthorlink($dcdom,$rowtype);
1239: $output.= '<span class="LC_rolesinfo">'.
1240: &mt('[_1]: [_2]',$ccrole,$selectcclink).
1241: '</span><br /></td><td> </td><td><span class="LC_rolesinfo">'.
1242: &mt('[_1]: [_2]',$carole,$selectcalink).
1243: '</span><br /></td></tr></table></td></tr>'.
1244: '<tr><td colspan="5" height="3"></td></tr>'."\n";
1245: return $output;
1246: }
1247:
1248: sub recent_filename {
1249: my $area=shift;
1250: return 'nohist_recent_'.&escape($area);
1251: }
1252:
1253: sub set_privileges {
1254: # role can be cc or ca
1255: my ($dcdom,$pickedcourse,$role) = @_;
1256: my $area = '/'.$dcdom.'/'.$pickedcourse;
1257: my $spec = $role.'.'.$area;
1258: my %userroles = &Apache::lonnet::set_arearole($role,$area,'','',
1259: $env{'user.domain'},
1260: $env{'user.name'});
1261: my %ccrole = ();
1262: &Apache::lonnet::standard_roleprivs(\%ccrole,$role,$dcdom,$spec,$pickedcourse,$area);
1263: my ($author,$adv)= &Apache::lonnet::set_userprivs(\%userroles,\%ccrole);
1264: &Apache::lonnet::appenv(\%userroles,[$role,'cm']);
1265:
1266: &Apache::lonnet::log($env{'user.domain'},
1267: $env{'user.name'},
1268: $env{'user.home'},
1269: "Role ".$role);
1270: &Apache::lonnet::appenv(
1271: {'request.role' => $spec,
1272: 'request.role.domain' => $dcdom,
1273: 'request.course.sec' => ''});
1274: my $tadv=0;
1275: if (&Apache::lonnet::allowed('adv') eq 'F') { $tadv=1; }
1276: &Apache::lonnet::appenv({'request.role.adv' => $tadv});
1277: }
1278:
1279: sub courseloadpage {
1280: my ($courseid) = @_;
1281: my $startpage;
1282: my %entry_settings = &Apache::lonnet::get('nohist_whatsnew',
1283: [$courseid.':courseinit']);
1284: my ($tmp) = %entry_settings;
1285: unless ($tmp =~ /^error: 2 /) {
1286: $startpage = $entry_settings{$courseid.':courseinit'};
1287: }
1288: if ($startpage eq '') {
1289: if (exists($env{'environment.course_init_display'})) {
1290: $startpage = $env{'environment.course_init_display'};
1291: }
1292: }
1293: return $startpage;
1294: }
1295:
1296: 1;
1297: __END__
1298:
1299: =head1 NAME
1300:
1301: Apache::lonroles - User Roles Screen
1302:
1303: =head1 SYNOPSIS
1304:
1305: Invoked by /etc/httpd/conf/srm.conf:
1306:
1307: <Location /adm/roles>
1308: PerlAccessHandler Apache::lonacc
1309: SetHandler perl-script
1310: PerlHandler Apache::lonroles
1311: ErrorDocument 403 /adm/login
1312: ErrorDocument 500 /adm/errorhandler
1313: </Location>
1314:
1315: =head1 OVERVIEW
1316:
1317: =head2 Choosing Roles
1318:
1319: C<lonroles> is a handler that allows a user to switch roles in
1320: mid-session. LON-CAPA attempts to work with "No Role Specified", the
1321: default role that a user has before selecting a role, as widely as
1322: possible, but certain handlers for example need specification which
1323: course they should act on, etc. Both in this scenario, and when the
1324: handler determines via C<lonnet>'s C<&allowed> function that a certain
1325: action is not allowed, C<lonroles> is used as error handler. This
1326: allows the user to select another role which may have permission to do
1327: what they were trying to do. C<lonroles> can also be accessed via the
1328: B<CRS> button in the Remote Control.
1329:
1330: =begin latex
1331:
1332: \begin{figure}
1333: \begin{center}
1334: \includegraphics[width=0.45\paperwidth,keepaspectratio]{Sample_Roles_Screen}
1335: \caption{\label{Sample_Roles_Screen}Sample Roles Screen}
1336: \end{center}
1337: \end{figure}
1338:
1339: =end latex
1340:
1341: =head2 Role Initialization
1342:
1343: The privileges for a user are established at login time and stored in the session environment. As a consequence, a new role does not become active till the next login. Handlers are able to query for privileges using C<lonnet>'s C<&allowed> function. When a user first logs in, their role is the "common" role, which means that they have the sum of all of their privileges. During a session it might become necessary to choose a particular role, which as a consequence also limits the user to only the privileges in that particular role.
1344:
1345: =head1 INTRODUCTION
1346:
1347: This module enables a user to select what role he wishes to
1348: operate under (instructor, student, teaching assistant, course
1349: coordinator, etc). These roles are pre-established by the actions
1350: of upper-level users.
1351:
1352: This is part of the LearningOnline Network with CAPA project
1353: described at http://www.lon-capa.org.
1354:
1355: =head1 HANDLER SUBROUTINE
1356:
1357: This routine is called by Apache and mod_perl.
1358:
1359: =over 4
1360:
1361: =item *
1362:
1363: Roles Initialization (yes/no)
1364:
1365: =item *
1366:
1367: Get Error Message from Environment
1368:
1369: =item *
1370:
1371: Who is this?
1372:
1373: =item *
1374:
1375: Generate Page Output
1376:
1377: =item *
1378:
1379: Choice or no choice
1380:
1381: =item *
1382:
1383: Table
1384:
1385: =item *
1386:
1387: Privileges
1388:
1389: =back
1390:
1391: =cut
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>