1: # The LearningOnline Network
2: # Switch Servers Handler
3: #
4: # $Id: switchserver.pm,v 1.35.2.5 2021/01/04 03:54:38 raeburn Exp $
5: #
6: # Copyright Michigan State University Board of Trustees
7: #
8: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
9: #
10: # LON-CAPA is free software; you can redistribute it and/or modify
11: # it under the terms of the GNU General Public License as published by
12: # the Free Software Foundation; either version 2 of the License, or
13: # (at your option) any later version.
14: #
15: # LON-CAPA is distributed in the hope that it will be useful,
16: # but WITHOUT ANY WARRANTY; without even the implied warranty of
17: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18: # GNU General Public License for more details.
19: #
20: # You should have received a copy of the GNU General Public License
21: # along with LON-CAPA; if not, write to the Free Software
22: # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
23: #
24: # /home/httpd/html/adm/gpl.txt
25: #
26: # http://www.lon-capa.org/
27: #
28:
29: package Apache::switchserver;
30:
31: use strict;
32: use Apache::Constants qw(:common);
33: use Apache::lonnet;
34: use Digest::MD5 qw(md5_hex);
35: use CGI::Cookie();
36: use Apache::lonlocal;
37: use LONCAPA qw(:DEFAULT :match);
38:
39: sub init_env {
40: my ($r) = @_;
41:
42: if (-e $env{'user.environment'}) {
43: return $env{'user.environment'};
44: }
45: my $requrl=$r->uri;
46: my $handle= &Apache::lonnet::check_for_valid_session($r);
47: if ($handle ne '') {
48: return undef;
49: }
50: my $lonidsdir=$r->dir_config('lonIDsDir');
51: &Apache::lonnet::transfer_profile_to_env($lonidsdir,$handle);
52:
53: return $r->dir_config('lonIDsDir')."/$handle.id";
54: }
55:
56: sub do_redirect {
57: my ($r,$url,$only_body,$extra_text) = @_;
58: $r->send_http_header;
59: my $delay = 0.5;
60: if ($only_body) {
61: $delay = 0;
62: }
63: my $start_page =
64: &Apache::loncommon::start_page('Switching Server ...',undef,
65: {'redirect' => [$delay,$url],
66: 'only_body' => $only_body,});
67: my $end_page = &Apache::loncommon::end_page();
68: $r->print($start_page.$extra_text.$end_page);
69: unless ($env{'user.name'} eq 'public' && ($env{'user.domain'} eq 'public')) {
70: $r->register_cleanup(\&flush_course_logs);
71: }
72: return OK;
73: }
74:
75: sub balancer_cookieid {
76: my ($r,$desthost,$uname,$udom) = @_;
77: my @hosts = &Apache::lonnet::current_machine_ids();
78: my $newcookieid;
79: unless (grep(/^\Q$desthost\E$/,@hosts)) {
80: my $balancedir=$r->dir_config('lonBalanceDir');
81: $newcookieid = &md5_hex(&md5_hex(time.{}.rand().$$));
82: my $cookie = $udom.'_'.$uname.'_'.$newcookieid;
83: my $balcookie = "balanceID=$cookie; path=/; HttpOnly;";
84: if (open(my $fh,'>',"$balancedir/$cookie.id")) {
85: print $fh $desthost;
86: close($fh);
87: $r->headers_out->add('Set-cookie' => $balcookie);
88: }
89: }
90: return $newcookieid;
91: }
92:
93: sub flush_course_logs {
94: &Apache::lonnet::flushcourselogs();
95: return OK;
96: }
97:
98: sub handler {
99: my ($r) = @_;
100:
101: my $handle=&init_env($r);
102: if (!defined($handle)) { return FORBIDDEN; }
103:
104: &Apache::loncommon::get_unprocessed_cgi($ENV{'QUERY_STRING'},
105: ['otherserver','role','origurl','symb']);
106:
107: my $switch_to=&Apache::lonnet::hostname($env{'form.otherserver'});
108: if (! $env{'form.otherserver'}) {
109: $env{'form.otherserver'} =
110: &Apache::lonnet::find_existing_session($env{'user.domain'},
111: $env{'user.name'});
112: if (! $env{'form.otherserver'}) {
113: $env{'form.otherserver'} =
114: &Apache::lonnet::spareserver(30000,undef,1);
115: }
116: $switch_to=&Apache::lonnet::hostname($env{'form.otherserver'});
117: }
118:
119: if (!defined($switch_to)) { return FORBIDDEN; }
120:
121: my $protocol = 'http';
122: if ($env{'form.otherserver'}) {
123: if ($Apache::lonnet::protocol{$env{'form.otherserver'}} eq 'https') {
124: $protocol = $Apache::lonnet::protocol{$env{'form.otherserver'}};
125: }
126: }
127:
128: if ($env{'user.name'} eq 'public'
129: && $env{'user.domain'} eq 'public') {
130: my $url = $protocol.'://'.$switch_to.$r->uri;
131: unlink($handle);
132: #expire the cookie
133: my $c = new CGI::Cookie(-name => 'lonPubID',
134: -value => '',
135: -expires => '-10y',);
136: $r->header_out('Set-cookie' => $c);
137: return &do_redirect($r,$url,1)
138: }
139:
140: my $skip_canhost_check = '';
141: my $now = time;
142: if ($env{'form.role'}) {
143: if (!exists($env{'user.role.'.$env{'form.role'}})) {
144: delete($env{'form.role'});
145: } else {
146: my ($start,$end) = split(/\./,$env{'user.role.'.$env{'form.role'}});
147: if (($start && $start > $now) || ($end && $end < $now)) {
148: delete($env{'form.role'});
149: } elsif ($env{'form.role'} eq 'au./'.$env{'user.domain'}.'/') {
150: if (&Apache::lonnet::homeserver($env{'user.name'},$env{'user.domain'}) eq $env{'form.otherserver'}) {
151: $skip_canhost_check = 1;
152: }
153: } elsif ($env{'form.role'} =~ m{^[ac]a\./($match_domain)/($match_username)$}) {
154: if (&Apache::lonnet::homeserver($2,$1) eq $env{'form.otherserver'}) {
155: $skip_canhost_check = 1;
156: }
157: }
158: }
159: }
160:
161: unless ($skip_canhost_check) {
162: my $canhost = 1;
163: my $uprimary_id = &Apache::lonnet::domain($env{'user.domain'},'primary');
164: my $uint_dom = &Apache::lonnet::internet_dom($uprimary_id);
165: my @intdoms;
166: my $internet_names = &Apache::lonnet::get_internet_names($env{'form.otherserver'});
167: if (ref($internet_names) eq 'ARRAY') {
168: @intdoms = @{$internet_names};
169: }
170: unless ($uint_dom ne '' && grep(/^\Q$uint_dom\E$/,@intdoms)) {
171: my $serverhomeID = &Apache::lonnet::get_server_homeID($switch_to);
172: my $serverhomedom = &Apache::lonnet::host_domain($serverhomeID);
173: my %defdomdefaults = &Apache::lonnet::get_domain_defaults($serverhomedom);
174: my %udomdefaults = &Apache::lonnet::get_domain_defaults($env{'user.domain'});
175: my $remoterev = &Apache::lonnet::get_server_loncaparev($env{'user.domain'},$env{'form.otherserver'});
176: $canhost =
177: &Apache::lonnet::can_host_session($env{'user.domain'},
178: $env{'form.otherserver'},
179: $remoterev,
180: $udomdefaults{'remotesessions'},
181: $defdomdefaults{'hostedsessions'});
182: }
183: unless ($canhost) { return FORBIDDEN; }
184: }
185:
186: #remove session env, and log event
187: if (unlink($handle)) {
188: if ($env{'user.linkedenv'} ne '') {
189: my $lonidsdir=$r->dir_config('lonIDsDir');
190: if (($env{'user.linkedenv'} =~ /^[a-f0-9]+_linked$/) &&
191: (-l "$lonidsdir/$env{'user.linkedenv'}.id") &&
192: (readlink("$lonidsdir/$env{'user.linkedenv'}.id") eq $handle)) {
193: unlink("$lonidsdir/$env{'user.linkedenv'}.id");
194: }
195: }
196: }
197: my %temp=('switchserver' => $now.':'.$env{'form.otherserver'},
198: $env{'form.role'});
199: &Apache::lonnet::put('email_status',\%temp);
200: my $logmsg = "Switch Server to $env{'form.otherserver'}";
201: if ($env{'form.role'}) {
202: $logmsg .= " with role: $env{'form.role'}";
203: } else {
204: $logmsg .= " (no role)";
205: }
206: my $ip = &Apache::lonnet::get_requestor_ip();
207: $logmsg .= ' '.$ip;
208: &Apache::lonnet::log($env{'user.domain'},$env{'user.name'},
209: $env{'user.home'},$logmsg);
210:
211: &Apache::loncommon::content_type($r,'text/html');
212:
213: #expire the cookies
214: my %cookies=CGI::Cookie->parse($r->header_in('Cookie'));
215: foreach my $name (keys(%cookies)) {
216: next unless ($name =~ /^lon(|S|Link|Pub)ID$/);
217: my $c = new CGI::Cookie(-name => $name,
218: -value => '',
219: -expires => '-10y',);
220: $r->headers_out->add('Set-cookie' => $c);
221: }
222: if ($r->header_only) {
223: $r->send_http_header;
224: return OK;
225: }
226: # -------------------------------------------------------- Menu script and info
227:
228: # ---------------------------------------------------------------- Get handover
229:
230: my ($is_balancer,$setcookie,$newcookieid,$otherbalcookie);
231: my $only_body = 0;
232: ($is_balancer,undef,$setcookie) =
233: &Apache::lonnet::check_loadbalancing($env{'user.name'},$env{'user.domain'},'switchserver');
234: if ($is_balancer && $setcookie && $env{'form.otherserver'}) {
235:
236: # Set a balancer cookie unless browser already sent LON-CAPA load balancer
237: # cookie which points at the target server
238: my ($found_server,$balancer_cookie) = &Apache::lonnet::check_for_balancer_cookie($r,1);
239:
240: if (($found_server eq $env{'form.otherserver'}) &&
241: ($balancer_cookie =~ /^\Q$env{'user.domain'}\E_\Q$env{'user.name'}\E_/)) {
242: $only_body = 1;
243: } else {
244: $newcookieid = &balancer_cookieid($r,$env{'form.otherserver'},
245: $env{'user.name'},$env{'user.domain'});
246: }
247: }
248: if ((!$is_balancer) && ($env{'request.balancercookie'})) {
249: $otherbalcookie = $env{'request.balancercookie'};
250: }
251:
252: my %info=('ip' => $ip,
253: 'domain' => $env{'user.domain'},
254: 'username' => $env{'user.name'},
255: 'role' => $env{'form.role'},
256: 'server' => $r->dir_config('lonHostID'),
257: 'balancer' => $is_balancer);
258: if ($newcookieid) {
259: $info{'balcookie'} = $newcookieid;
260: } elsif ($otherbalcookie) {
261: $info{'otherbalcookie'} = $otherbalcookie;
262: }
263: if ($env{'form.origurl'}) {
264: $info{'origurl'} = $env{'form.origurl'};
265: }
266: if ($env{'form.symb'}) {
267: $info{'symb'} = $env{'form.symb'};
268: }
269: if ($env{'request.sso.login'}) {
270: $info{'sso.login'} = $env{'request.sso.login'};
271: }
272: if ($env{'request.sso.reloginserver'}) {
273: $info{'sso.reloginserver'} = $env{'request.sso.reloginserver'};
274: }
275: my $token = &Apache::lonnet::tmpput(\%info,$env{'form.otherserver'});
276: my $url =$protocol.'://'.$switch_to.'/adm/login?'.
277: 'domain='.$env{'user.domain'}.
278: '&username='.$env{'user.name'}.
279: '&token='.$token;
280: # --------------------------------------------------------------- Screen Output
281: return &do_redirect($r, $url, $only_body);
282: }
283:
284: 1;
285: __END__
286:
287:
288:
289:
290:
291:
292:
293:
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>