1: #
2: # $Id: batchcreatecourse.pm,v 1.40.2.3 2020/05/22 20:55:45 raeburn Exp $
3: #
4: # Copyright Michigan State University Board of Trustees
5: #
6: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
7: #
8: # LON-CAPA is free software; you can redistribute it and/or modify
9: # it under the terms of the GNU General Public License as published by
10: # the Free Software Foundation; either version 2 of the License, or
11: # (at your option) any later version.
12: #
13: # LON-CAPA is distributed in the hope that it will be useful,
14: # but WITHOUT ANY WARRANTY; without even the implied warranty of
15: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
16: # GNU General Public License for more details.
17: #
18: # You should have received a copy of the GNU General Public License
19: # along with LON-CAPA; if not, write to the Free Software
20: # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
21: #
22: # /home/httpd/html/adm/gpl.txt
23: #
24: # http://www.lon-capa.org/
25: #
26:
27: package LONCAPA::batchcreatecourse;
28: use LONCAPA::Configuration;
29: use LONCAPA::Enrollment;
30: use HTML::Parser;
31: use Time::Local;
32: use Apache::lonnet;
33: use Apache::loncommon;
34: use Apache::lonlocal;
35: use LONCAPA qw(:match);
36:
37: use strict;
38:
39: # Collection of routines used for batch creation of courses and users.
40: # &create_courses() should be called by an Autocreate.pl
41: # script via a cron entry, or alternatively from a web page, after upload
42: # of a file containing an XML description of a course request (lonbatchccrs.pm).
43: #
44: # XML file(s) describing courses that are to be created in domain $dom are stored in
45: # /home/httpd/perl/tmp/addcourse/$dom
46: #
47: # &create_courses() will create an account for the course owner
48: # (if one does not currently exist), will create the course (cloning if necessary),
49: # and will add additional instructional staff (creating accounts if necessary).
50: #
51: # Example of XML file (which could contain more than one class to be created):
52: #
53: #<?xml version="1.0" encoding="UTF-8"?>
54: #<!DOCTYPE text>
55: #<class id="ss05ubw101">
56: # <title>Underwater Basket Weaving</title>
57: # <crstype>Course</crstype>
58: # <coursecode>ss05ubw101</coursecode>
59: # <defaultcredits>3</defaultcredits>
60: # <coursehome>msul1</coursehome>
61: # <coursedomain>msu</coursedomain>
62: # <reshome>/res/msu/</reshome>
63: # <optional_id></optional_id>
64: # <adds>1</adds>
65: # <drops>1</drops>
66: # <enrollstart>2005:01:04:10:30</enrollstart>
67: # <enrollend>2005:07:04:20:30</enrollend>
68: # <accessstart>2005:01:10:10:30</accessstart>
69: # <accessend>2005:05:31:10:30</accessend>
70: # <authentication>
71: # <method>krb4</method>
72: # <param>MSU.EDU</param>
73: # </authentication>
74: # <nonstandard></nonstandard>
75: # <topmap></topmap>
76: # <firstres>nav</firstres>
77: # <crsquota>20</crsquota>
78: # <uniquecode>1</uniquecode>
79: # <clonecrs>466011437c34194msul1</clonecrs>
80: # <clonedom>msu</clonedom>
81: # <datemode>shift</datemode>
82: # <dateshift>365</dateshift>
83: # <showphotos></showphotos>
84: # <setpolicy>1</setpolicy>
85: # <setcontent>1</setcontent>
86: # <setcomment>1</setcomment>
87: # <setkeys>0</setkeys>
88: # <keyauth>keyadmin:msu</keyauth>
89: # <disresdis>1</disresdis>
90: # <disablechat>1</disablechat>
91: # <openall></openall>
92: # <openallfrom></openallfrom>
93: # <notify_dc>1</notify_dc>
94: # <notify_owner>1</notify_owner>
95: # <owner>
96: # <username>sparty</username>
97: # <domain>msu</domain>
98: # <authtype>krb4</authtype>
99: # <autharg>MSU.EDU</autharg>
100: # </owner>
101: # <sections>
102: # <section>
103: # <inst>001</inst>
104: # <loncapa>1</loncapa>
105: # </section>
106: # <section>
107: # <inst>002</inst>
108: # <loncapa>2</loncapa>
109: # </section>
110: # </sections>
111: # <crosslists>
112: # <xlist>
113: # <inst>ss05zzz101001</inst>
114: # <loncapa>1</loncapa>
115: # </xlist>
116: # </crosslists>
117: # <users>
118: # <user>
119: # <username>sparty</username>
120: # <domain>msu</domain>
121: # <email>sparty@msu.edu</email>
122: # <authtype>krb4</authtype>
123: # <autharg></autharg>
124: # <firstname>MSU</firstname>
125: # <generation></generation>
126: # <lastname>Spartan</lastname>x
127: # <middlename></middlename>
128: # <studentID></studentID>
129: # <credits></credits>
130: # <roles></roles>
131: # </user>
132: # <user>
133: # <username>itds0001</username>
134: # <domain>northwood5</domain>
135: # <email>itds0001@msu.edu</email>
136: # <authtype>int</authtype>
137: # <autharg></autharg>
138: # <firstname>Info</firstname>
139: # <generation></generation>
140: # <lastname>Techc</lastname>x
141: # <middlename></middlename>
142: # <studentID></studentID>
143: # <roles>
144: # <role id='in'>
145: # <start>2005:01:01:12:10</start>
146: # <end>2005:12:01:12:10</end>
147: # <usec>1</usec>
148: # <usec>2</usec>
149: # </role>
150: # </roles>
151: # </user>
152: # </users>
153: #</class>
154: #
155: # Many of these are binary options (corresponding to either checkboxes or
156: # radio buttons in the interactive CCRS page). Examples include:
157: # setpolicy, setcontent, setcomment, setkeys, disableresdis, disablechat, openall,
158: # uniquecode
159: #
160: # A value of 1 between opening and closing tags is equivalent to a
161: # checked checkbox or 'Yes' response in the original CCRS web page.
162: # A value of 0 or blank is equivalent to an unchecked box or 'No'
163: # response. Dates are in format YYYY:MM:DD:HH:MM:SS (:separators required)
164: #
165: # firstres can be nav, syl, or blank for "Navigate Contents", Syllabus, or
166: # no entry respectively.
167: #
168: # crstype can be Course or Community
169: #
170: # crsquota is the total disk space permitted for course group portfolio files
171: # in all course groups.
172: #
173: # For format of other parameters, refer to the interactive CCRS page
174: # and view how the equivalent parameter is displayed in the web form.
175: #
176: ##############################################################
177: # create_courses() - creates courses described in @$requests,
178: # files listed in @$requests are deleted
179: # after the files have been parsed.
180: #
181: # Directory for retrieval of files listed in @$requests is:
182: # /home/httpd/perl/tmp/addcourse/$dom/auto/pending if $context = auto
183: # /home/httpd/perl/tmp/addcourse/$dom/web/$uname_$udom/pending if $context = web
184: #
185: # inputs (six) - requests - ref to array of filename(s) containing course requests
186: # courseids - ref to hash to store LON-CAPA course ids of new courses
187: # context - auto if called from command line, web if called from browser
188: # dom - domain for which the course is being created
189: # uname - username of DC who is requesting course creation
190: # udom - domain of DC who is requesting course creation
191: #
192: # outputs (four) - output - text recording user roles added etc.
193: # logmsg - text to be logged
194: # keysmsg - text containing link(s) to manage keys page(s)
195: # codehash - reference to hash containing courseID => unique code
196: # where unique code is a 6 character code, to distribute
197: # to students as a shortcut to the course.
198: #############################################################
199:
200: sub create_courses {
201: my ($requests,$courseids,$context,$dom,$uname,$udom) = @_;
202: my $output;
203: my $perlvarref = LONCAPA::Configuration::read_conf('loncapa.conf');
204: # Get role names
205: my %longroles = ();
206: open(FILE,"<$$perlvarref{'lonTabDir'}.'/rolesplain.tab");
207: my @rolesplain = <FILE>;
208: close(FILE);
209: foreach my $item (@rolesplain) {
210: if ($item =~ /^(st|ta|ep|ad|in|cc|co):([\w\s]+):?([\w\s]*)/) {
211: $longroles{'Course'}{$1} = $2;
212: $longroles{'Community'}{$1} = $3;
213: }
214: }
215: my ($logmsg,$keysmsg,$newusermsg,$addresult,%codehash,%instcodes);
216: my %enrollcount = ();
217: my $newcoursedir = LONCAPA::tempdir().'/addcourse/'.$dom.'/'.$context;
218: if ($context eq 'auto') {
219: $newcoursedir .= '/pending';
220: } else {
221: if ($uname && $udom) {
222: $newcoursedir .= '/'.$uname.'_'.$udom.'/pending';
223: } else {
224: $logmsg = "batchcreatecourse::create_courses() called without username and/or domain of requesting Domain Coordinator";
225: }
226: }
227: if (@{$requests} > 0) {
228: foreach my $request (@{$requests}) {
229: my %details = ();
230: if (-e $newcoursedir.'/'.$request) {
231: &parse_coursereqs($newcoursedir.'/'.$request, \%details);
232: foreach my $num (sort(keys(%details))) {
233: my $reqdetails = $details{$num};
234: my $code;
235: my $courseid =
236: &build_course($dom,$num,$context,$reqdetails,\%longroles,\$logmsg,\$newusermsg,
237: \$addresult,\%enrollcount,\$output,\$keysmsg,undef,undef,undef,undef,\$code);
238: if ($courseid =~m{^/$match_domain/$match_courseid}) {
239: $$courseids{$courseid} = $details{$num}{'class'};
240: if ($code) {
241: $codehash{$courseid} = $code;
242: }
243: if ($details{$num}{'coursecode'} ne '') {
244: push(@{$instcodes{$details{$num}{'coursecode'}}},$courseid);
245: }
246: }
247: }
248: }
249: }
250: }
251: return ($output,$logmsg,$keysmsg,\%codehash,\%instcodes);
252: }
253:
254: #############################################################
255: #
256: # parse_coursereqs()
257: # inputs (two) - coursefile - path to XML file containing course(s) to be created.
258: # - details - reference to hash containing extracted information.
259: # outputs (none)
260: #
261: ############################################################
262:
263: sub parse_coursereqs {
264: my ($coursefile,$details) = @_;
265: # Note all start and end dates should be in this format:
266: # YYYY:MM:DD:HH:MM:SS (:separators required).
267: my $uname = '';
268: my @state = ();
269: my $num = 0;
270: my $secid = 0;
271: my $xlist = 0;
272: my $userkey = '';
273: my $role = '';
274: my @items = ('title','optional_id','coursecode','defaultcredits','coursehome','reshome','nonstandard','adds','drops','topmap','firstres','clonecrs','clonedom','datemode','dateshift','showphotos','setpolicy','setcontent','setcomment','setkeys','keyauth','disresdis','disablechat','openall','notify_owner','notify_dc','crstype','crsquota','uniquecode');
275: my @possroles = qw(st ad ep ta in cc co);
276: my @dateitems = ('enrollstart','enrollend','accessstart','accessend','openallfrom');
277: my @useritems = ('autharg','authtype','firstname','generation','lastname','middlename','studentID');
278: my $p = HTML::Parser->new
279: (
280: xml_mode => 1,
281: start_h =>
282: [sub {
283: my ($tagname, $attr) = @_;
284: push(@state, $tagname);
285: if ("@state" eq "class") {
286: %{$$details{$num}} = ();
287: $$details{$num}{'class'} = $attr->{id};
288: %{$$details{$num}{'users'}} = ();
289: %{$$details{$num}{'sections'}} = ();
290: $secid = 0;
291: $xlist = 0;
292: }
293: if ("@state" eq "class users user roles role") {
294: $role = $attr->{id};
295: if (grep(/^\Q$role\E$/,@possroles)) {
296: push(@{$$details{$num}{'users'}{$userkey}{'roles'}}, $role);
297: %{$$details{$num}{'users'}{$userkey}{$role}} = ();
298: @{$$details{$num}{'users'}{$userkey}{$role}{'usec'}} = ();
299: }
300: }
301: if ("@state" eq "class sections section") {
302: $secid ++;
303: %{$$details{$num}{'sections'}{$secid}} = ();
304: }
305: if ("@state" eq "class crosslists xlist") {
306: $xlist ++;
307: %{$$details{$num}{'crosslists'}{$xlist}} = ();
308: }
309: }, "tagname, attr"],
310: text_h =>
311: [sub {
312: my ($text) = @_;
313: if ("@state" eq "class owner username") {
314: $$details{$num}{'owner'} = $text;
315: } elsif ("@state" eq "class owner domain") {
316: $$details{$num}{'domain'} = $text;
317: } elsif ("@state" eq "class sections section inst") {
318: $$details{$num}{'sections'}{$secid}{'inst'} = $text;
319: } elsif ("@state" eq "class sections section loncapa") {
320: $$details{$num}{'sections'}{$secid}{'loncapa'} = $text;
321: } elsif ("@state" eq "class crosslists xlist inst") {
322: $$details{$num}{'crosslists'}{$xlist}{'inst'} = $text;
323: } elsif ("@state" eq "class crosslists xlist loncapa") {
324: $$details{$num}{'crosslists'}{$xlist}{'loncapa'} = $text;
325: } elsif ("@state" eq "class owner authtype") {
326: $$details{$num}{'ownerauthtype'} = $text;
327: } elsif ("@state" eq "class owner autharg") {
328: $$details{$num}{'ownerauthparam'} = $text;
329: } elsif ("@state" eq "class authentication method") {
330: $$details{$num}{'authtype'} = $text;
331: } elsif ("@state" eq "class authentication param") {
332: $$details{$num}{'authparam'} = $text;
333: } elsif ("@state" eq "class users user username") {
334: $userkey = $text;
335: } elsif ("@state" eq "class users user domain") {
336: $userkey .= ':'.$text;
337: %{$$details{$num}{'users'}{$userkey}} = ();
338: @{$$details{$num}{'users'}{$userkey}{'roles'}} = ();
339: } elsif ("@state" eq "class users user email") {
340: $$details{$num}{'users'}{$userkey}{'emailaddr'} = $text;
341: $$details{$num}{'users'}{$userkey}{'emailenc'} = &LONCAPA::escape($text);
342: } elsif ("@state" eq "class users user roles role start") {
343: if (grep(/^\Q$role\E$/,@possroles)) {
344: $$details{$num}{'users'}{$userkey}{$role}{'start'} = &process_date($text);
345: }
346: } elsif ("@state" eq "class users user roles role end") {
347: if (grep(/^\Q$role\E$/,@possroles)) {
348: $$details{$num}{'users'}{$userkey}{$role}{'end'} = &process_date($text);
349: }
350: } elsif ("@state" eq "class users user roles role usec") {
351: if (grep(/^\Q$role\E$/,@possroles)) {
352: unless ($text eq '') {
353: push(@{$$details{$num}{'users'}{$userkey}{$role}{'usec'}},$text);
354: }
355: }
356: } else {
357: foreach my $item (@items) {
358: if ("@state" eq "class $item") {
359: $$details{$num}{$item} = $text;
360: }
361: }
362: foreach my $item (@dateitems) {
363: if ("@state" eq "class $item") {
364: $$details{$num}{$item} = &process_date($text);
365: }
366: }
367: foreach my $item (@useritems) {
368: if ("@state" eq "class users user $item") {
369: $$details{$num}{'users'}{$userkey}{$item} = $text;
370: }
371: }
372: }
373: }, "dtext"],
374: end_h =>
375: [sub {
376: my ($tagname) = @_;
377: if ("@state" eq "class") {
378: $num ++;
379: }
380: pop @state;
381: }, "tagname"],
382: );
383:
384: $p->parse_file($coursefile);
385: $p->eof;
386: return;
387: }
388:
389: #########################################################
390: #
391: # build_course()
392: #
393: # inputs
394: # course domain
395: # course request number
396: # context - auto if called from command line, web if called from DC web interface
397: # ref to hash of course creation information
398: # ref to hash of role descriptions
399: # ref to scalar used to accumulate log messages
400: # ref to scalar used to accumulate messages sent to new users
401: # ref to scalar used to accumulate results of new user additions
402: # ref to hash of enrollment counts for different roles
403: # ref to scalar used to accumulate information about added roles
404: # ref to scalar used to accumulate information about access keys
405: # domain of DC creating course
406: # username of DC creating course
407: # optional course number, if unique course number already obtained (e.g., for
408: # course requests submitted via course request form.
409: # optional category
410: # optional ref to scalar for six character unique identifier
411: #
412: # outputs
413: # LON-CAPA courseID for new (created) course
414: #
415: #########################################################
416:
417: sub build_course {
418: my ($cdom,$num,$context,$details,$longroles,$logmsg,$newusermsg,$addresult,
419: $enrollcount,$output,$keysmsg,$udom,$uname,$cnum,$category,$coderef) = @_;
420: return unless (ref($details) eq 'HASH');
421: my $owner_uname = $details->{'owner'};
422: my $owner_domain = $details->{'domain'};
423: my $owner = $owner_uname.':'.$owner_domain;
424: my $sectionstr = '';
425: my $xliststr = '';
426: my $noenddate = '';
427: my $outcome;
428: my ($courseid,$crsudom,$crsunum,$crstype,$ccrole,$rolenames);
429: if ($details->{'crstype'} eq 'Community') {
430: $crstype = $details->{'crstype'};
431: $ccrole ='co';
432: if (ref($longroles) eq 'HASH') {
433: $rolenames = $longroles->{'Community'};
434: }
435: } else {
436: $crstype = 'Course';
437: $ccrole = 'cc';
438: if (ref($longroles) eq 'HASH') {
439: $rolenames = $longroles->{'Course'};
440: }
441: }
442: my $linefeed;
443: if ($context eq 'auto') {
444: $linefeed = "\n";
445: } else {
446: $linefeed = "<br />\n";
447: }
448: if ($details->{'accessend'} eq '') {
449: $noenddate = 1;
450: }
451: my $reshome = $details->{'reshome'};
452: if ($reshome eq '') {
453: $reshome = '/res/'.$cdom;
454: }
455: my $firstres = $details->{'firstres'};
456: if ($firstres eq '') {
457: if ($crstype eq 'Community') {
458: $firstres = 'nav';
459: } else {
460: $firstres = 'syl';
461: }
462: }
463: foreach my $secid (sort(keys(%{$details->{'sections'}}))) {
464: $sectionstr .= $details->{'sections'}{$secid}{'inst'}.':'.$details->{'sections'}{$secid}{'loncapa'}.',';
465: }
466: $sectionstr =~ s/,$//;
467:
468: foreach my $xlist (sort(keys(%{$details->{'crosslists'}}))) {
469: $xliststr .= $details->{'crosslists'}{$xlist}{'inst'}.':'.$details->{'crosslists'}{$xlist}{'loncapa'}.',';
470: }
471: $xliststr =~ s/,$//;
472:
473: my %courseinfo = (
474: inst_code => $details->{'coursecode'},
475: description => $details->{'title'}
476: );
477: if (&Apache::lonnet::homeserver($details->{'owner'},$details->{'domain'}) eq 'no_host') { # Add user if no account
478: my $ownerargs = {'auth' => $details->{'ownerauthtype'},
479: 'authparam' => $details->{'ownerauthparam'},
480: 'emailenc' => $details->{'emailenc'},
481: 'udom' => $details->{'domain'},
482: 'uname' => $details->{'owner'},
483: 'pid' => $details->{'users'}{$owner}{'studentID'},
484: 'first' => $details->{'users'}{$owner}{'firstname'},
485: 'middle' => $details->{'users'}{$owner}{'middlename'},
486: 'last' => $details->{'users'}{$owner}{'lastname'},
487: 'gene' => $details->{'users'}{$owner}{'generation'},
488: 'usec' => '',
489: 'end' => '',
490: 'start' => '',
491: 'emailaddr' => $details->{'users'}{$owner}{'email'},
492: 'cid' => '',
493: 'context' => 'createowner',
494: 'linefeed' => $linefeed,
495: 'role' => $ccrole,
496: };
497: $outcome = &LONCAPA::Enrollment::create_newuser($ownerargs,$logmsg,$newusermsg,$enrollcount,$addresult,$rolenames,\%courseinfo,$context);
498: } else {
499: $outcome = 'ok';
500: }
501:
502: if ($outcome eq 'ok') {
503: if ($details->{'datemode'} !~ /^(preserve|shift|delete)$/) {
504: $details->{'datemode'} = 'shift';
505: $details->{'dateshift'} = 365;
506: }
507: my $courseargs = {
508: ccuname => $details->{'owner'},
509: ccdomain => $details->{'domain'},
510: cdescr => $details->{'title'},
511: crstype => $details->{'crstype'},
512: curl => $details->{'topmap'},
513: course_domain => $cdom,
514: course_home => $details->{'coursehome'},
515: nonstandard => $details->{'nonstandard'},
516: crscode => $details->{'coursecode'},
517: defaultcredits => $details->{'defaultcredits'},
518: crsquota => $details->{'crsquota'},
519: uniquecode => $details->{'uniquecode'},
520: clonecourse => $details->{'clonecrs'},
521: clonedomain => $details->{'clonedom'},
522: datemode => $details->{'datemode'},
523: dateshift => $details->{'dateshift'},
524: crsid => $details->{'optional_id'},
525: curruser => $details->{'owner'},
526: crssections => $sectionstr,
527: crsxlist => $xliststr,
528: autoadds => $details->{'adds'},
529: autodrops => $details->{'drops'},
530: notify => $details->{'notify_owner'},
531: notify_dc => $details->{'notify_dc'},
532: no_end_date => $noenddate,
533: showphotos => $details->{'showphotos'},
534: authtype => $details->{'authtype'},
535: autharg => $details->{'authparam'},
536: enrollstart => $details->{'enrollstart'},
537: enrollend => $details->{'enrollend'},
538: startaccess => $details->{'accessstart'},
539: endaccess => $details->{'accessend'},
540: setpolicy => $details->{'setpolicy'},
541: setcontent => $details->{'setcontent'},
542: setcomment => $details->{'setcomment'},
543: reshome => $reshome,
544: setkeys => $details->{'setkeys'},
545: keyauth => $details->{'keyauth'},
546: disresdis => $details->{'disresdis'},
547: disablechat => $details->{'disablechat'},
548: openall => $details->{'openall'},
549: openallfrom => $details->{'openallfrom'},
550: firstres => $firstres
551: };
552: if ($details->{'textbook'}) {
553: $courseargs->{'textbook'} = $details->{'textbook'};
554: }
555: my %host_servers = &Apache::lonnet::get_servers($cdom,'library');
556: if (! exists($host_servers{$details->{'coursehome'}})) {
557: $$logmsg .= &mt('Invalid home server for course').': '.$details->{'coursehome'};
558: return;
559: }
560: my ($success, $msg) =
561: &Apache::loncommon::construct_course($courseargs,$logmsg,\$courseid,\$crsudom,\$crsunum,
562: $udom,$uname,$context,$cnum,$category,$coderef);
563: $$logmsg .= $msg;
564: if (!$success) {
565: return;
566: }
567: } else {
568: return;
569: }
570:
571: #
572: # Make owner a coordinator
573: #
574: if (($owner_domain) && ($owner_uname)) {
575: &Apache::lonnet::assignrole($owner_domain,$owner_uname,$courseid,$ccrole,'','','','',$context);
576: }
577:
578: #
579: # Process other reqested users
580: #
581:
582: my @courseroles = qw(st ep ta in);
583: push(@courseroles,$ccrole);
584: if (&owner_is_dc($owner_uname,$owner_domain,$crsudom)) {
585: push(@courseroles,'ad');
586: }
587: my $stulogmsg = '';
588: foreach my $userkey (sort(keys(%{$details->{'users'}}))) {
589: my $url = '/'.$crsudom.'/'.$crsunum;
590: next if (ref($details->{'users'}{$userkey}{'roles'}) ne 'ARRAY');
591: if (@{$details->{'users'}{$userkey}{'roles'}} > 0) {
592: my ($username,$userdom) = split/:/,$userkey;
593: if (&Apache::lonnet::homeserver($username,$userdom) eq 'no_host') { # Add user if no account
594: my @reqroles = @{$details->{'users'}{$userkey}{'roles'}};
595: my @badroles;
596: my $firstrole = shift(@reqroles);
597: while (@reqroles > 0) {
598: if ($firstrole =~ m{^cr/($match_domain)/($match_username)/([^/]+)$}) {
599: if (($1 eq $owner_domain) && ($2 eq $owner_uname)) {
600: last;
601: } else {
602: push(@badroles,$firstrole);
603: $firstrole = shift(@reqroles);
604: }
605: } elsif (grep(/^\Q$firstrole\E$/,@courseroles)) {
606: last;
607: } else {
608: push(@badroles,$firstrole);
609: $firstrole = shift(@reqroles);
610: }
611: }
612: if (@badroles > 0) {
613: if (@badroles > 1) {
614: $$output .= &mt('The following requested roles are unavailable:').' '.join(', ',@badroles);
615: } else {
616: $$output .= &mt('The following requested role: [_1] is unavailable.',$badroles[0]);
617: }
618: }
619: my $firstsec;
620: unless (($firstrole eq $ccrole) || ($firstrole eq '')) {
621: $firstsec = $details->{'users'}{$userkey}{$firstrole}{'usec'}[0];
622: }
623: my $userargs = {
624: 'auth' => $details->{'users'}{$userkey}{'authtype'},
625: 'authparam' => $details->{'users'}{$userkey}{'autharg'},
626: 'emailenc' => $details->{'users'}{$userkey}{'emailenc'},
627: 'udom' => $userdom,
628: 'uname' => $username,
629: 'pid' => $details->{'users'}{$userkey}{'studentID'},
630: 'first' => $details->{'users'}{$userkey}{'firstname'},
631: 'middle' => $details->{'users'}{$userkey}{'middlename'},
632: 'last' => $details->{'users'}{$userkey}{'lastname'},
633: 'gene' => $details->{'users'}{$userkey}{'generation'},
634: 'usec' => $firstsec,
635: 'end' => $details->{'users'}{$userkey}{'end'},
636: 'start' => $details->{'users'}{$userkey}{'start'},
637: 'emailaddr' => $details->{'users'}{$userkey}{'emailaddr'},
638: 'cid' => $courseid,
639: 'crs' => $crsunum,
640: 'cdom' => $crsudom,
641: 'context' => 'createcourse',
642: 'linefeed' => $linefeed,
643: 'role' => $details->{'users'}{$userkey}{'roles'}[0],
644: };
645: if ($userargs->{'role'} eq 'st') {
646: if (exists($details->{'users'}{$userkey}{'credits'})) {
647: $userargs->{'credits'} = $details->{'users'}{$userkey}{'credits'};
648: $userargs->{'credits'} =~ s/[^\d\.]//g;
649: }
650: }
651: $outcome = &LONCAPA::Enrollment::create_newuser($userargs,$logmsg,$newusermsg,$enrollcount,$addresult,$longroles,\%courseinfo,$context);
652: # now add other roles and other sections.
653: if ($outcome eq 'ok') {
654: if ((($firstrole ne 'st') && ($firstrole ne $ccrole) && ($firstrole ne '')) && (@{$details->{'users'}{$userkey}{$firstrole}{'usec'}} > 1)) {
655: for (my $i=1; $i<@{$details->{'users'}{$userkey}{$firstrole}{'usec'}}; $i++) {
656: my $curr_role = $firstrole;
657: my $start = $details->{'users'}{$userkey}{$curr_role}{'start'};
658: my $end = $details->{'users'}{$userkey}{$curr_role}{'end'};
659: my $usec = $details->{'users'}{$userkey}{$firstrole}{'usec'}[$i];
660: $url = '/'.$crsudom.'/'.$crsunum;
661: if ($usec ne '') {
662: $url .= '/'.$usec;
663: }
664: if ($firstrole =~ m{^cr/($match_domain)/($match_username)/([^/]+)$}) {
665: $$output .= &Apache::loncommon::commit_customrole($userdom,$username,$url,$1,$2,$3,$start,$end,$context);
666: } else {
667: $$output .= &Apache::loncommon::commit_standardrole($userdom,$username,$url,$curr_role,$start,$end,$crsudom,$crsunum,$usec,$context);
668: }
669: }
670: }
671: if (@reqroles > 0) {
672: foreach my $curr_role (@reqroles) {
673: my $start = $details->{'users'}{$userkey}{$curr_role}{'start'};
674: my $end = $details->{'users'}{$userkey}{$curr_role}{'end'};
675: if ($curr_role eq 'st') {
676: my $usec = $details->{'users'}{$userkey}{$curr_role}{'usec'}[0];
677: $url = '/'.$crsudom.'/'.$crsunum;
678: if ($usec ne '') {
679: $url .= '/'.$usec;
680: }
681: my $credits;
682: if (exists($details->{'users'}{$userkey}{'credits'})) {
683: $credits = $details->{'users'}{$userkey}{'credits'};
684: $credits =~ s/[^\d\.]//g;
685: }
686: $$output .= &Apache::loncommon::commit_studentrole(\$stulogmsg,$userdom,$username,$url,$curr_role,$start,$end,$crsudom,$crsunum,$usec,$context,$credits);
687: } elsif ($curr_role eq $ccrole) {
688: $url = '/'.$crsudom.'/'.$crsunum;
689: my $usec = '';
690: $$output .=
691: &Apache::loncommon::commit_standardrole($userdom,$username,$url,$curr_role,$start,$end,$crsudom,$crsunum,$usec,$context);
692: } elsif ((grep(/^\Q$curr_role\E$/,@courseroles)) ||
693: ($curr_role =~ m{^cr/$match_domain/$match_username/[^/]+$})) {
694: foreach my $usec (@{$details->{'users'}{$userkey}{$curr_role}{'usec'}}) {
695: $url = '/'.$crsudom.'/'.$crsunum;
696: if ($usec ne '') {
697: $url .= '/'.$usec;
698: }
699: if ($curr_role =~ m{^cr/($match_domain)/($match_username)/([^/]+)$}) {
700: if (($1 eq $owner_domain) && ($2 eq $owner_uname)) {
701: $$output .=
702: &Apache::loncommon::commit_customrole($userdom,$username,$url,$1,$2,$3,$start,$end,$context);
703: } else {
704: $$output = &mt('Requested custom role: [_1] unavailable, as it was not defined by the course owner.',$curr_role);
705: }
706: } else {
707: $$output .=
708: &Apache::loncommon::commit_standardrole($userdom,$username,$url,$curr_role,$start,$end,$crsudom,$crsunum,$usec,$context);
709: }
710: }
711: } else {
712: $$output .= &mt('Requested role: [_1] is unavailable.',$curr_role);
713: }
714: }
715: }
716: }
717: } else {
718: foreach my $curr_role (@{$details->{'users'}{$userkey}{'roles'}}) {
719: my $start = $details->{'users'}{$userkey}{$curr_role}{'start'};
720: my $end = $details->{'users'}{$userkey}{$curr_role}{'end'};
721: if ($curr_role eq 'st') {
722: my $usec = $details->{'users'}{$userkey}{$curr_role}{'usec'}[0];
723: $url = '/'.$crsudom.'/'.$crsunum;
724: if ($usec ne '') {
725: $url .= '/'.$usec;
726: }
727: my $credits;
728: if (exists($details->{'users'}{$userkey}{'credits'})) {
729: $credits = $details->{'users'}{$userkey}{'credits'};
730: $credits =~ s/[^\d\.]//g;
731: }
732: $$output .= &Apache::loncommon::commit_studentrole(\$stulogmsg,$userdom,$username,$url,$curr_role,$start,$end,$crsudom,$crsunum,$usec,$context,$credits);
733: } elsif ((grep(/^\Q$curr_role\E$/,@courseroles)) ||
734: ($curr_role =~ m{^cr/$match_domain/$match_username/[^/]+$})) {
735: if (@{$details->{'users'}{$userkey}{$curr_role}{'usec'}} > 0) {
736: foreach my $usec (@{$details->{'users'}{$userkey}{$curr_role}{'usec'}}) {
737: $url = '/'.$crsudom.'/'.$crsunum;
738: if ($usec ne '') {
739: $url .= '/'.$usec;
740: }
741: my $stdresult;
742: if ($curr_role =~ m{/^cr/($match_domain)/($match_username)/([^/]+)$}) {
743: if (($1 eq $owner_domain) && ($2 eq $owner_uname)) {
744: $stdresult =
745: &Apache::loncommon::commit_customrole($userdom,$username,$url,$1,$2,$3,$start,$end,$context);
746: } else {
747: $stdresult = &mt('Requested custom role: [_1] unavailable, as it was not defined by the course owner.',$curr_role);
748: }
749: } else {
750: $stdresult =
751: &Apache::loncommon::commit_standardrole($userdom,$username,$url,$curr_role,$start,$end,$crsudom,$crsunum,$usec,$context);
752: }
753: $$output .= $stdresult;
754: }
755: } else {
756: $url = '/'.$crsudom.'/'.$crsunum;
757: if ($curr_role =~ m{^cr/($match_domain)/($match_username)/([^/]+)$}) {
758: if (($1 eq $owner_domain) && ($2 eq $owner_uname)) {
759: $$output .=
760: &Apache::loncommon::commit_customrole($userdom,$username,$url,$1,$2,$3,$start,$end,$context);
761: } else {
762: $$output .= &mt('Requested custom role: [_1] unavailable, as it was not defined by the course owner.',$curr_role);
763: }
764: } else {
765: $$output .=
766: &Apache::loncommon::commit_standardrole($userdom,$username,$url,$curr_role,$start,$end,$crsudom,$crsunum,'',$context);
767: }
768: }
769: } else {
770: $$output .= &mt('Requested role: [_1] is unavailable.',$curr_role);
771: }
772: }
773: }
774: }
775: }
776:
777: # Information about keys.
778: if ($details->{'setkeys'}) {
779: $$keysmsg .=
780: '<a href="/adm/managekeys?cid='.$crsudom.'_'.$crsunum.'">'.&mt('Manage Access Keys').'</a> for '.$details->{'title'}.$linefeed;
781: }
782: # Flush the course logs so reverse user roles immediately updated
783: &Apache::lonnet::flushcourselogs();
784: return $courseid;
785: }
786:
787: sub owner_is_dc {
788: my ($owner_uname,$owner_dom,$cdom) = @_;
789: my $is_dc = 0;
790: my %roles = &Apache::lonnet::get_my_roles($owner_uname,$owner_dom,'userroles',
791: ['active'],['dc'],[$cdom]);
792: if ($roles{$owner_uname.':'.$owner_dom.':dc'}) {
793: $is_dc = 1;
794: }
795: return $is_dc;
796: }
797:
798: #########################################################
799: #
800: # process_date()
801: #
802: # input - date/time string in format YYYY:MM:DD:HH:MM:SS (:separators required).
803: # output - corresponding UNIX time (seconds since epoch).
804: #
805: #########################################################
806:
807: sub process_date {
808: my $timestr = shift;
809: my $timestamp = '';
810: if ($timestr !~ /:/) {
811: $timestamp = '';
812: } else {
813: my @entries = split(/:/,$timestr);
814: for (my $j=0; $j<@entries; $j++) {
815: if ( length($entries[$j]) > 1 ) {
816: $entries[$j] =~ s/^0//;
817: }
818: $entries[$j] =~ s/\D//g;
819: if ($entries[$j] < 0) {
820: $entries[$j] = 0;
821: }
822: }
823: if ($entries[1] > 0) {
824: $entries[1] = $entries[1] - 1;
825: }
826: if ($entries[5] > 60) {
827: $entries[5] = 60;
828: }
829: if ($entries[4] > 59) {
830: $entries[4] = 59;
831: }
832: if ($entries[3] > 23) {
833: $entries[3] = 23;
834: }
835: if ($entries[2] > 31) {
836: $entries[2] = 31;
837: }
838: if ($entries[1] > 11) {
839: $entries[1] = 11;
840: }
841: if ($entries[2] == 31) {
842: if (($entries[1] == 3) || ($entries[1] == 5) ||
843: ($entries[1] == 8) || ($entries[1] == 10)) {
844: $entries[2] = 30;
845: }
846: }
847: if ($entries[1] == 1) {
848: if ($entries[2] > 29) {
849: $entries[2] = 29;
850: }
851: if ($entries[2] == 29) {
852: if ($entries[0]%4 != 0) {
853: $entries[2] = 28;
854: } elsif ( $entries[0]%100 == 0
855: && $entries[0]%400 != 0) {
856: $entries[2] = 28;
857: }
858: }
859: }
860: $timestamp = timelocal($entries[5],$entries[4],$entries[3],$entries[2],$entries[1],$entries[0]);
861: }
862: return $timestamp;
863: }
864:
865: 1;
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>