1: #!/usr/bin/perl
2:
3: # sqltest.pl - script to test MySQL database connectivity for LON-CAPA
4: #
5: # $Id: sqltest.pl,v 1.9 2002/09/12 22:47:28 harris41 Exp $
6: #
7: ###
8:
9: =pod
10:
11: =head1 NAME
12:
13: B<sqltest.pl> - Test interoperability of the MySQL server for use by LON-CAPA
14:
15: =cut
16:
17: # Written to help LON-CAPA (The LearningOnline Network with CAPA)
18: #
19: # YEAR=2001
20: # 9/25,9/30 Scott Harrison
21: # YEAR=2002
22: # 5/10,5/11 Scott Harrison
23: # 8/6/2002 and onwards, Scott Harrison, sharrison@users.sourceforge.net
24:
25: =pod
26:
27: =head1 SYNOPSIS
28:
29: perl sqltest.pl
30:
31: This script is ordinarily located inside the LON-CAPA source code tree.
32: This script is normally invoked by test-related targets inside
33: F<loncapa/loncom/build/Makefile>.
34:
35: =head1 DESCRIPTION
36:
37: This program tests the status of the MySQL database needed by the LON-CAPA
38: system. As with the other LON-CAPA test scripts, when reasonable, I try
39: to avoid importing functionality from other LON-CAPA modules so as to
40: avoid indirectly testing software dependencies.
41:
42: =head2 ORGANIZATION OF THIS PERL SCRIPT
43:
44: The script is organized into the following sections.
45:
46: =over 4
47:
48: =item 1.
49:
50: Process version information of this file.
51:
52: =item 2.
53:
54: Modules used by this script,
55:
56: =item 3.
57:
58: Initializations.
59:
60: =item 4.
61:
62: Read in current configuration.
63:
64: =item 5.
65:
66: Is this a library or access server?
67:
68: This step in the script is both a sanity check and also allows for other
69: future LON-CAPA server types (e.g. "admin", "backup", "firewall") to not
70: be required to have MySQL.
71:
72: =item 6.
73:
74: Make sure that the database can be accessed.
75:
76: If not, a variety of possible problems should be tested for, and a status
77: report should be issued to standard output.
78:
79: =item 7.
80:
81: Close database connection.
82:
83: This part of the script is only reached if the database was successfully
84: connected to.
85:
86: =item 8.
87:
88: Subroutines.
89:
90: B<configuration_scan> - look for PerlSetVar and store inside hash variable.
91:
92: =back
93:
94: =head1 STATUS
95:
96: Ratings: 1=horrible 2=poor 3=fair 4=good 5=excellent
97:
98: =over 4
99:
100: =item Organization
101:
102: 5
103:
104: =item Functionality
105:
106: 4
107:
108: =item Has it been tested?
109:
110: 3
111:
112: =back
113:
114: =head1 AUTHOR
115:
116: Scott Harrison, sharrison@users.sourceforge.net, 2001, 2002
117:
118: This software is distributed under the General Public License,
119: version 2, June 1991 (which is the same terms as LON-CAPA).
120:
121: This is free software; you can redistribute it and/or modify
122: it under the terms of the GNU General Public License as published by
123: the Free Software Foundation; either version 2 of the License, or
124: (at your option) any later version.
125:
126: This software is distributed in the hope that it will be useful,
127: but WITHOUT ANY WARRANTY; without even the implied warranty of
128: MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
129: GNU General Public License for more details.
130:
131: You should have received a copy of the GNU General Public License
132: along with this software; if not, write to the Free Software
133: Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
134:
135: =cut
136:
137: # =================================== Process version information of this file.
138: my $VERSION = sprintf("%d.%02d", q$Revision: 1.9 $ =~ /(\d+)\.(\d+)/);
139:
140: print('Running sqltest.pl, version '.$VERSION.'.'."\n");
141: print('(Test interoperability of the MySQL server for use by LON-CAPA.)'."\n");
142:
143: # ================================================ Modules used by this script.
144: use strict;
145: use DBI; # Needed to interface with the database.
146:
147: # ============================================================ Initializations.
148: $|=1;
149: print 'Probing for SQL metadata database'."\n\n";
150:
151: # ============================================== Read in current configuration.
152: my %perlvar;
153:
154: my $webconfdir='/etc/httpd/conf/';
155:
156: # Scanning the standard loncapa configuration files.
157: &configuration_scan(\%perlvar,$webconfdir.'loncapa.conf');
158: &configuration_scan(\%perlvar,$webconfdir.'loncapa_apache.conf');
159: # Note that the authoritative value for 'lonSqlAccess' comes from
160: # loncapa_apache.conf; this is why loncapa_apache.conf is scanned
161: # after loncapa.conf (in case a system administrator mistakenly
162: # specifies lonSqlAccess inside loncapa.conf).
163:
164: # ========================================== Is lonSqlAccess defined correctly?
165: unless ($perlvar{'lonSqlAccess'} and $perlvar{'lonSqlAccess'}!~/^\{\[\[\[\[/) {
166: print('**** ERROR **** The lonSqlAccess variable was not defined '.
167: 'correctly inside '.$webconfdir.'loncapa_apache.conf'."\n");
168: exit(1);
169: }
170: unless ($perlvar{'lonSqlAccess'} eq 'localhostkey') {
171: print('**** WARNING **** The lonSqlAccess variable is not set to the '.
172: 'standard expected value of "localhostkey"'."\n");
173: }
174:
175: # ========================================= Is this a library or access server?
176: unless ($perlvar{'lonRole'} eq 'library' or $perlvar{'lonRole'} eq 'access') {
177: print('**** NOTE **** SQL testing can only be run on a library or access '.
178: 'server. Skipping test.'."\n");
179: exit(0);
180: }
181:
182: # ================================ Make sure that the database can be accessed.
183: my $dbh;
184: {
185: unless (
186: $dbh = DBI->connect("DBI:mysql:loncapa","www",
187: $perlvar{'lonSqlAccess'},
188: {RaiseError=>0,PrintError=>0})
189: ) {
190: print('Cannot connect to database!'."\n");
191: # ------------------------------------ Check through possible problems.
192: my $problem_flag=0;
193: my $checkDBImodule=`perl pmvers DBI 2>/dev/null`;
194: my $checkMYSQLmodule=`perl pmvers Mysql 2>/dev/null`;
195: my $checkprocess=`/etc/rc.d/init.d/mysqld status`;
196: my $process_ecode=system('/etc/rc.d/init.d/mysqld status');
197:
198: # ---------------------------------------------- Issue a status report.
199: if (!$checkDBImodule) {
200: print('**** ERROR **** SYSTEM IS MISSING THE DBI PERL '.
201: 'MODULE (DBI.pm)'."\n");
202: $problem_flag=1;
203: }
204: if (!$checkMYSQLmodule) {
205: print('**** ERROR **** SYSTEM IS MISSING THE MYSQL PERL '.
206: 'MODULE (Mysql.pm)'."\n");
207: $problem_flag=1;
208: }
209: if (!-e '/etc/rc.d/init.d/mysqld') {
210: print('**** ERROR **** IT APPEARS THAT THE MYSQL SERVER HAS NOT '.
211: 'BEEN INSTALLED'."\n");
212: $problem_flag=1;
213: }
214: if ($checkprocess=~/is stopped/) {
215: print('**** ERROR **** IT APPEARS THAT THE MYSQL SERVER IS NOT '.
216: 'RUNNING'."\n");
217: print(<<END);
218: To fix temporarily, run the command:
219: /etc/rc.d/init.d/mysqld start
220:
221: You may also want to check and see that mysqld is started on boot time.
222:
223: /sbin/chkconfig --list mysqld
224:
225: This is bad output:
226: mysqld 0:off 1:off 2:off 3:off 4:off 5:off 6:off
227:
228: This is good output:
229: mysqld 0:off 1:off 2:off 3:on 4:on 5:on 6:off
230:
231: To configure mysqld to launch correctly upon system startup, type the command:
232: /sbin/chkconfig --level 345 mysqld on
233: END
234: $problem_flag=1;
235: }
236: if ($checkprocess=~/mysqld dead but subsys locked/) {
237: print('**** ERROR **** IT APPEARS THAT THE MYSQLD PROCESSES'.
238: 'WERE SOMEHOW TERMINATED'."\n");
239: print(<<END);
240: To fix temporarily, run the command:
241: /etc/rc.d/init.d/mysqld restart
242: Double-check that your mysqld processes are running by using the command:
243: ps auxwww | grep mysqld
244:
245: Note that something really bad probably happened on your system to abnormally
246: shutdown the mysqld processes.
247: END
248: $problem_flag=1;
249: }
250: if ($process_ecode) { # The exit code for mysqld status was abnormal.
251: print('**** ERROR **** MYSQLD IS NOT AVAILABLE'."\n");
252: print(<<END);
253: To check (and fix), try running these commands:
254: /etc/rc.d/init.d/mysqld start
255: /etc/rc.d/init.d/mysqld status
256:
257: You may also want to check and see that mysqld is started on boot time.
258: /sbin/chkconfig --list mysqld
259: If everything is off, you should run "/sbin/chkconfig --level 345 mysqld on".
260: END
261: $problem_flag=1;
262: }
263: unless ($problem_flag) {
264: print('**** ERROR **** IT APPEARS THAT WWW@LOCALHOST AND/OR '.
265: 'PASSWORD ARE NOT CORRECTLY ENABLED'."\n");
266: print(<<END);
267: This is because all other known problems have been checked for.
268: By process of elimination, the assumption is that www\@localhost
269: must not be connecting to the database (a system administrator
270: at your institution may want to look at other possibilities however).
271:
272: To diagnose, try logging in from the command line with
273: mysql -u www -p mysql
274: and use the lonSqlAccess password
275: listed in loncapa_apache.conf (it normally is set to 'localhostkey').
276: If logging in fails to work, one possible approach is to REMOVE the
277: www\@localhost MySQL user.
278: [shell]\$ mysql -u root -p mysql
279: mysql> delete from user where user='www'
280: And then, you will need to repeat the MySQL configuration steps described at:
281: http://install.lon-capa.org/docs/install/index.html
282:
283: **** NOTE **** ANOTHER possibility is that you are not running
284: a compatible set of DBI, Mysql perl modules, and MySQL server software.
285: END
286: }
287: exit(1);
288: }
289: }
290: %perlvar=(); # clear memory
291:
292: print('SQL metadata database is found and is accessible'."\n");
293:
294: # ================================================== Close database connection.
295: $dbh->disconnect();
296:
297: # ================================================================ Subroutines.
298:
299: # --------- configuration_scan: look for PerlSetVar and store in hash variable.
300: sub configuration_scan {
301: my ($storagehashref,$filename)=@_;
302: open(CONFIG,$filename) or
303: (print("Can't read $filename\n") && exit(1));
304: while (my $configline=<CONFIG>) {
305: if ($configline =~ /^[^\#]*PerlSetVar/) {
306: my ($dummy,$varname,$varvalue)=split(/\s+/,$configline);
307: chomp($varvalue);
308: $storagehashref->{$varname}=$varvalue;
309: }
310: }
311: close(CONFIG);
312: }
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>
![[BACK]](/icons/back.gif){kind=icon}
Return to sqltest.pl CVS log ![[TXT]](/icons/text.gif){kind=icon}
![[DIR]](/icons/dir.gif){kind=icon}
Up to [LON-CAPA] / loncom / build / system_dependencies