1: # The LearningOnline Network with CAPA
2: # caparesponse definition
3: #
4: # $Id: caparesponse.pm,v 1.167 2005/04/16 15:36:25 albertel Exp $
5: #
6: # Copyright Michigan State University Board of Trustees
7: #
8: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
9: #
10: # LON-CAPA is free software; you can redistribute it and/or modify
11: # it under the terms of the GNU General Public License as published by
12: # the Free Software Foundation; either version 2 of the License, or
13: # (at your option) any later version.
14: #
15: # LON-CAPA is distributed in the hope that it will be useful,
16: # but WITHOUT ANY WARRANTY; without even the implied warranty of
17: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18: # GNU General Public License for more details.
19: #
20: # You should have received a copy of the GNU General Public License
21: # along with LON-CAPA; if not, write to the Free Software
22: # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
23: #
24: # /home/httpd/html/adm/gpl.txt
25: #
26: # http://www.lon-capa.org/
27: #
28:
29: package Apache::caparesponse;
30: use strict;
31: use capa;
32: use Apache::lonlocal;
33: use Apache::lonnet;
34:
35: BEGIN {
36: &Apache::lonxml::register('Apache::caparesponse',('caparesponse','numericalresponse','stringresponse','formularesponse'));
37: }
38:
39: sub start_numericalresponse {
40: my ($target,$token,$tagstack,$parstack,$parser,$safeeval)=@_;
41: my $id = &Apache::response::start_response($parstack,$safeeval);
42: my $result;
43: undef %{$safeeval->varglob('LONCAPA::CAPAresponse_args')};
44: if ($target eq 'edit') {
45: $result.=&Apache::edit::tag_start($target,$token);
46: $result.=&Apache::edit::text_arg('Answer:','answer',$token);
47: if ($token->[1] eq 'numericalresponse') {
48: $result.=&Apache::edit::text_arg('Incorrect Answers:','incorrect',
49: $token).
50: &Apache::loncommon::help_open_topic('numerical_wrong_answers');
51: $result.=&Apache::edit::text_arg('Unit:','unit',$token,5).
52: &Apache::loncommon::help_open_topic('Physical_Units');
53: $result.=&Apache::edit::text_arg('Format:','format',$token,4).
54: &Apache::loncommon::help_open_topic('Numerical_Response_Format');
55: } elsif ($token->[1] eq 'formularesponse') {
56: $result.=&Apache::edit::text_arg('Sample Points:','samples',
57: $token,40).
58: &Apache::loncommon::help_open_topic('Formula_Response_Sampling');
59: }
60: $result.=&Apache::edit::end_row().&Apache::edit::start_spanning_row();
61: } elsif ($target eq 'modified') {
62: my $constructtag;
63: if ($token->[1] eq 'numericalresponse') {
64: $constructtag=&Apache::edit::get_new_args($token,$parstack,
65: $safeeval,'answer',
66: 'incorrect','unit',
67: 'format');
68: } elsif ($token->[1] eq 'formularesponse') {
69: $constructtag=&Apache::edit::get_new_args($token,$parstack,
70: $safeeval,'answer',
71: 'samples');
72: }
73: if ($constructtag) {
74: $result = &Apache::edit::rebuild_tag($token);
75: $result.=&Apache::edit::handle_insert();
76: }
77: } elsif ($target eq 'meta') {
78: $result=&Apache::response::meta_package_write('numericalresponse');
79: } elsif ($target eq 'answer' || $target eq 'grade') {
80: &Apache::response::reset_params();
81: } elsif ($target eq 'web') {
82: my $partid = $Apache::inputtags::part;
83: my $hideunit=&Apache::lonnet::EXT('resource.'.$partid.'_'.$id.'.turnoffunit');
84: &Apache::lonxml::debug("Got unit $hideunit for $partid $id");
85: #no way to enter units, with radio buttons
86: if (lc($hideunit) eq "yes") {
87: my $unit=&Apache::lonxml::get_param_var('unit',$parstack,
88: $safeeval);
89: if ($unit =~ /\S/) { $result.=" (in $unit) "; }
90: }
91: if ( &Apache::response::show_answer() ) {
92: my $answertxt;
93: my (@answers)=&Apache::lonxml::get_param_var('answer',$parstack,
94: $safeeval);
95: my (@formats)=&Apache::lonxml::get_param_var('format',$parstack,
96: $safeeval);
97: my $unit=&Apache::lonxml::get_param_var('unit',$parstack,
98: $safeeval);
99: for (my $i=0; $i <= $#answers; $i++) {
100: my $answer=$answers[$i];
101: my $format;
102: if ($#formats > 0) {
103: $format=$formats[$i];
104: } else {
105: $format=$formats[0];
106: }
107: if ($unit=~/\$/) { $format="\$".$format; $unit=~s/\$//g; }
108: if ($unit=~/\,/) { $format="\,".$format; $unit=~s/\,//g; }
109: my $formatted=&format_number($answer,$format,$target,
110: $safeeval);
111: $answertxt.=$formatted.',';
112: }
113: chop $answertxt;
114: if ($target eq 'web') {
115: $answertxt.=" $unit ";
116: }
117: $Apache::inputtags::answertxt{$id}=$answertxt;
118: }
119: }
120: return $result;
121: }
122:
123: sub check_submission {
124: my ($response,$partid,$id,$tag,$parstack,$safeeval)=@_;
125: my $args_ref= \%{$safeeval->varglob('LONCAPA::CAPAresponse_args')};
126: $$args_ref{'response'}=$response;
127: my $hideunit=&Apache::lonnet::EXT('resource.'.$partid.'_'.$id.'.turnoffunit');
128:
129: foreach my $arg ('type','tol','sig','format','unit','calc',
130: 'samples') {
131: $$args_ref{$arg}=
132: &Apache::lonxml::get_param($arg,$parstack,$safeeval);
133: }
134: foreach my $key (keys(%Apache::inputtags::params)) {
135: $$args_ref{$key}=$Apache::inputtags::params{$key};
136: }
137:
138: #no way to enter units, with radio buttons
139: if ($Apache::lonhomework::type eq 'exam' ||
140: lc($hideunit) eq "yes") {
141: delete($$args_ref{'unit'});
142: }
143: #sig fig don't make much sense either
144: if (($Apache::lonhomework::type eq 'exam' ||
145: &Apache::response::submitted('scantron')) &&
146: $tag eq 'numericalresponse') {
147: delete($$args_ref{'sig'});
148: }
149:
150: if ($tag eq 'formularesponse') {
151: $$args_ref{'type'}='fml';
152: } elsif ($tag eq 'numericalresponse') {
153: $$args_ref{'type'}='float';
154: }
155: my @answer=&Apache::lonxml::get_param_var('answer',$parstack,$safeeval);
156: &Apache::lonxml::debug('answer is'.join(':',@answer));
157: @{$safeeval->varglob('LONCAPA::CAPAresponse_answer')}=@answer;
158:
159: my ($result,@msgs) =
160: &Apache::run::run("&caparesponse_check_list()",$safeeval);
161: &Apache::lonxml::debug('msgs are'.join(':',@msgs));
162: my ($awards)=split(/:/,$result);
163: my @awards= split(/,/,$awards);
164: return(\@awards,\@msgs);
165: }
166:
167: sub end_numericalresponse {
168: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
169: my $increment=1;
170: my $result = '';
171: if (!$Apache::lonxml::default_homework_loaded) {
172: &Apache::lonxml::default_homework_load($safeeval);
173: }
174: my $partid = $Apache::inputtags::part;
175: my $id = $Apache::inputtags::response[-1];
176: my $tag;
177: if (scalar(@$tagstack)) { $tag=$$tagstack[-1]; }
178: if ( $target eq 'grade' && &Apache::response::submitted() ) {
179: &Apache::response::setup_params($tag,$safeeval);
180: $safeeval->share_from('capa',['&caparesponse_capa_check_answer']);
181: if ($Apache::lonhomework::type eq 'exam' &&
182: $tag eq 'formularesponse') {
183: $increment=&Apache::response::scored_response($partid,$id);
184: } else {
185: my $response = &Apache::response::getresponse();
186: if ( $response =~ /[^\s]/) {
187: my $ad;
188: my %previous = &Apache::response::check_for_previous($response,$partid,$id);
189: &Apache::lonxml::debug("submitted a $response<br>\n");
190: &Apache::lonxml::debug($$parstack[-1] . "\n<br>");
191:
192: if ( &Apache::response::submitted('scantron')) {
193: my $number_of_bubbles = &Apache::lonnet::EXT('resource.'.$partid.'_'.$id.'.numbubbles');
194: if (!$number_of_bubbles) { $number_of_bubbles=8; }
195: my (@formats)=&Apache::lonxml::get_param_var('format',$parstack,$safeeval);
196: my (@answers)=&Apache::lonxml::get_param_var('answer',$parstack,$safeeval);
197: my (@incorrect)=&Apache::lonxml::get_param_var('incorrect',$parstack,$safeeval);
198: if ($#incorrect eq 0) { @incorrect=(split(/,/,$incorrect[0])); }
199: my ($values,$display)=&make_numerical_bubbles($number_of_bubbles,$target,$answers[0],$formats[0],\@incorrect,$safeeval);
200: $response=$values->[$response];
201: }
202: $Apache::lonhomework::results{"resource.$partid.$id.submission"}=$response;
203: my ($awards,$msgs)=&check_submission($response,$partid,$id,
204: $tag,$parstack,$safeeval);
205:
206: ($ad,my $msg) = &Apache::inputtags::finalizeawards($awards,$msgs);
207: &Apache::lonxml::debug('ad is'.$ad);
208: if ($ad eq 'SIG_FAIL') {
209: my ($sig_u,$sig_l)=
210: &get_sigrange($Apache::inputtags::params{'sig'});
211: $msg=join(':',$msg,$sig_l,$sig_u);
212: &Apache::lonxml::debug("sigs bad $sig_u $sig_l ".
213: $Apache::inputtags::params{'sig'});
214: }
215: &Apache::lonxml::debug("\n<br>result:$result:$Apache::lonxml::curdepth<br>\n");
216: if ($Apache::lonhomework::type eq 'survey' &&
217: ($ad eq 'INCORRECT' || $ad eq 'APPROX_ANS' ||
218: $ad eq 'EXACT_ANS')) {
219: $ad='SUBMITTED';
220: }
221: &Apache::response::handle_previous(\%previous,$ad);
222: $Apache::lonhomework::results{"resource.$partid.$id.awarddetail"}=$ad;
223: $Apache::lonhomework::results{"resource.$partid.$id.awardmsg"}=$msg;
224: $result='';
225: }
226: }
227: } elsif ($target eq 'web' || $target eq 'tex') {
228: my (@answers)=&Apache::lonxml::get_param_var('answer',$parstack,
229: $safeeval);
230: my $award = $Apache::lonhomework::history{"resource.$Apache::inputtags::part.solved"};
231: my $status = $Apache::inputtags::status['-1'];
232: if ($Apache::lonhomework::type eq 'exam') {
233: my $number_of_bubbles = &Apache::lonnet::EXT('resource.'.$partid.'_'.$id.'.numbubbles');
234: if ($Apache::inputtags::params{'numbubbles'}) {
235: $number_of_bubbles = $Apache::inputtags::params{'numbubbles'};
236: }
237: if (!$number_of_bubbles) { $number_of_bubbles=8; }
238:
239: my (@formats)=&Apache::lonxml::get_param_var('format',$parstack,
240: $safeeval);
241: my $unit=&Apache::lonxml::get_param_var('unit',$parstack,
242: $safeeval);
243: my (@incorrect)=&Apache::lonxml::get_param_var('incorrect',$parstack,$safeeval);
244: if ($#incorrect eq 0) { @incorrect=(split(/,/,$incorrect[0])); }
245: my ($bubble_values,$bubble_display)=
246: &make_numerical_bubbles($number_of_bubbles,
247: $target,$answers[0],
248: $formats[0],\@incorrect,$safeeval);
249: my @alphabet=('A'..'Z');
250: if ($target eq 'web') {
251: if ($tag eq 'numericalresponse') {
252: if ($unit=~/\S/) {$result.=' (in '.$unit.')<br /><br />';}
253: $result.= '<table border="1"><tr>';
254: my $previous=$Apache::lonhomework::history{"resource.$Apache::inputtags::part.$id.submission"};
255: for (my $ind=0;$ind<$number_of_bubbles;$ind++) {
256: my $checked='';
257: if ($previous eq $bubble_values->[$ind]) {
258: $checked=" checked='on' ";
259: }
260: $result.='<td><input type="radio" name="HWVAL_'.$id.
261: '" value="'.$bubble_values->[$ind].'" '.$checked
262: .' /><b>'.$alphabet[$ind].'</b>: '.
263: $bubble_display->[$ind].'</td>';
264: }
265: $result.='</tr></table>';
266: } elsif ($tag eq 'formularesponse') {
267: $result.= '<br /><br /><font color="red">
268: <textarea name="HWVAL_'.$id.'" rows="4" cols="50">
269: </textarea></font> <br /><br />';
270: }
271: } elsif ($target eq 'tex') {
272: if ((defined $unit) and ($unit=~/\S/) and ($Apache::lonhomework::type eq 'exam')) {
273: $result.=' \textit{(in} \verb|'.$unit.'|\textit{)} ';
274: }
275: if ($tag eq 'numericalresponse') {
276: my ($celllength,$number_of_tables,@table_range)=
277: &get_table_sizes($number_of_bubbles,$bubble_display);
278: my $j=0;
279: my $cou=0;
280: $result.='\vskip -1 mm \noindent \begin{enumerate}\item[\textbf{'.$Apache::lonxml::counter.'}.]';
281: for (my $i=0;$i<$number_of_tables;$i++) {
282: $result.='\vskip -1 mm \noindent \setlength{\tabcolsep}{2 mm}\begin{tabular}{';
283: for (my $ind=0;$ind<$table_range[$j];$ind++) {
284: $result.='p{3 mm}p{'.$celllength.' mm}';
285: }
286: $result.='}';
287: for (my $ind=$cou;$ind<$cou+$table_range[$j];$ind++) {
288: $result.='\hskip -4 mm {\small \textbf{'.$alphabet[$ind].'}}$\bigcirc$ & \hskip -3 mm {\small '.$bubble_display->[$ind].'} ';
289: if ($ind != $cou+$table_range[$j]-1) {$result.=' & ';}
290: }
291: $cou += $table_range[$j];
292: $j++;
293: $result.='\\\\\end{tabular}\vskip 0 mm ';
294: }
295: $result.='\end{enumerate}';
296: } else {
297: $result.='\fbox{\fbox{\parbox{\textwidth-5mm}{\strut\\\\\strut\\\\\strut\\\\\strut\\\\}}}';
298: my $repetition = &Apache::response::repetition();
299: $result.='\begin{enumerate}';
300: for (my $i=0;$i<$repetition;$i++) {
301: $result.='\item[\textbf{'.($Apache::lonxml::counter+$i).'}.]\textit{Leave blank on scoring form}\vskip 0 mm';
302: }
303: $increment=$repetition;
304: $result.= '\end{enumerate}';
305: }
306: }
307: }
308: } elsif ($target eq 'edit') {
309: $result.='</td></tr>'.&Apache::edit::end_table;
310: } elsif ($target eq 'answer' || $target eq 'analyze') {
311: my $part_id="$partid.$id";
312: if ($target eq 'analyze') {
313: push (@{ $Apache::lonhomework::analyze{"parts"} },$part_id);
314: $Apache::lonhomework::analyze{"$part_id.type"} = $tag;
315: my (@incorrect)=&Apache::lonxml::get_param_var('incorrect',$parstack,$safeeval);
316: if ($#incorrect eq 0) { @incorrect=(split(/,/,$incorrect[0])); }
317: push (@{ $Apache::lonhomework::analyze{"$part_id.incorrect"} }, @incorrect);
318: &Apache::response::check_if_computed($token,$parstack,
319: $safeeval,'answer');
320: }
321: if (scalar(@$tagstack)) {
322: &Apache::response::setup_params($tag,$safeeval);
323: }
324: my (@answers)=&Apache::lonxml::get_param_var('answer',$parstack,$safeeval);
325: my (@formats)=&Apache::lonxml::get_param_var('format',$parstack,$safeeval);
326: my $unit=&Apache::lonxml::get_param_var('unit',$parstack,$safeeval);
327: my $type=&Apache::lonxml::get_param('type',$parstack,$safeeval);
328:
329: if ($target eq 'answer') {
330: $result.=&Apache::response::answer_header($tag);
331: }
332: for(my $i=0;$i<=$#answers;$i++) {
333: my $ans=$answers[$i];
334: my $fmt=$formats[0];
335: if (@formats && $#formats) {$fmt=$formats[$i];}
336: my ($high,$low);
337: if ($Apache::inputtags::params{'tol'}) {
338: ($high,$low)=&get_tolrange($ans,$Apache::inputtags::params{'tol'});
339: }
340: my ($sighigh,$siglow);
341: if ($Apache::inputtags::params{'sig'}) {
342: ($sighigh,$siglow)=&get_sigrange($Apache::inputtags::params{'sig'});
343: }
344: if ($fmt && $tag eq 'numericalresponse') {
345: $fmt=~s/e/E/g;
346: if ($unit=~/\$/) { $fmt="\$".$fmt; $unit=~s/\$//g; }
347: if ($unit=~/\,/) { $fmt="\,".$fmt; $unit=~s/\,//g; }
348: $ans = &format_number($ans,$fmt,$target,$safeeval);
349: #if ($high) {
350: # $high=&format_number($high,$fmt,$target,$safeeval);
351: # $low =&format_number($low,$fmt,$target,$safeeval);
352: #}
353: }
354: my $response=$ans;
355: if ($target eq 'answer') {
356: if ($high && $tag eq 'numericalresponse') { $ans.=' ['.$low.','.$high.']'; }
357: if (defined($sighigh) && $tag eq 'numericalresponse') {
358: if ($env{'form.answer_output_mode'} eq 'tex') {
359: $ans.= " Sig $siglow - $sighigh";
360: } else {
361: $ans.= " Sig <i>$siglow - $sighigh</i>";
362: }
363: }
364: $result.=&Apache::response::answer_part($tag,$ans);
365: } elsif ($target eq 'analyze') {
366: push (@{ $Apache::lonhomework::analyze{"$part_id.answer"} }, $ans);
367: if ($high) {
368: push (@{ $Apache::lonhomework::analyze{"$part_id.ans_high"} }, $high);
369: push (@{ $Apache::lonhomework::analyze{"$part_id.ans_low"} }, $low);
370: }
371: if ($fmt) {
372: push (@{ $Apache::lonhomework::analyze{"$part_id.format"} }, $fmt);
373: }
374: }
375: my ($awards,$msgs)=&check_submission($response,$partid,$id,$tag,
376: $parstack,$safeeval);
377: my ($ad,$msg) =&Apache::inputtags::finalizeawards($awards,$msgs);
378: if ($ad ne 'EXACT_ANS' && $ad ne 'APPROX_ANS') {
379: &Apache::lonxml::error(&mt('Computer\'s answer is incorrect. It is likely that the tolerance range or significant figures needs to be adjusted'));
380: }
381: }
382: if (defined($unit) and ($unit ne '') and
383: $tag eq 'numericalresponse') {
384: if ($target eq 'answer') {
385: if ($env{'form.answer_output_mode'} eq 'tex') {
386: $result.=&Apache::response::answer_part($tag,
387: " Unit: $unit ");
388: } else {
389: $result.=&Apache::response::answer_part($tag,
390: "Unit: <b>$unit</b>");
391: }
392: } elsif ($target eq 'analyze') {
393: push (@{ $Apache::lonhomework::analyze{"$part_id.unit"} }, $unit);
394: }
395: }
396: if ($tag eq 'formularesponse' && $target eq 'answer') {
397: my $samples=&Apache::lonxml::get_param('samples',$parstack,$safeeval);
398: $result.=&Apache::response::answer_part($tag,$samples);
399: }
400: if ($target eq 'answer') {
401: $result.=&Apache::response::answer_footer($tag);
402: }
403: }
404: if ($target eq 'grade' || $target eq 'web' || $target eq 'answer' ||
405: $target eq 'tex' || $target eq 'analyze') {
406: &Apache::lonxml::increment_counter($increment);
407: }
408: &Apache::response::end_response;
409: return $result;
410: }
411:
412: sub get_table_sizes {
413: my ($number_of_bubbles,$rbubble_values)=@_;
414: my $scale=2; #mm for one digit
415: my $cell_width=0;
416: foreach my $member (@$rbubble_values) {
417: my $cell_width_real=0;
418: if ($member=~/(\+|-)?(\d*)\.?(\d*)\s*\$?\\times\s*10\^{(\+|-)?(\d+)}\$?/) {
419: $cell_width_real=(length($2)+length($3)+length($5)+7)*$scale;
420: } elsif ($member=~/(\d*)\.?(\d*)(E|e)(\+|-)?(\d*)/) {
421: $cell_width_real=(length($1)+length($2)+length($5)+9)*$scale;
422: } elsif ($member=~/(\d*)\.(\d*)/) {
423: $cell_width_real=(length($1)+length($2)+3)*$scale;
424: } else {
425: $cell_width_real=(length($member)+1)*$scale*0.9;
426: }
427: if ($cell_width_real>$cell_width) {$cell_width=$cell_width_real;}
428: }
429: $cell_width+=8;
430: my $textwidth;
431: if ($env{'form.textwidth'} ne '') {
432: $env{'form.textwidth'}=~/(\d*)\.?(\d*)/;
433: $textwidth=$1.'.'.$2;
434: } else {
435: $env{'form.textwidth'}=~/(\d+)\.?(\d*)/;
436: $textwidth=$1.'.'.$2;
437: }
438: my $bubbles_per_line=int($textwidth/$cell_width);
439: if ($bubbles_per_line > $number_of_bubbles) {
440: $bubbles_per_line=$number_of_bubbles;
441: }elsif (($bubbles_per_line > $number_of_bubbles/2) && ($number_of_bubbles % 2==0)) {$bubbles_per_line=$number_of_bubbles/2;}
442: my $number_of_tables = int($number_of_bubbles/$bubbles_per_line);
443: my @table_range = ();
444: for (my $i=0;$i<$number_of_tables;$i++) {push @table_range,$bubbles_per_line;}
445: if ($number_of_bubbles % $bubbles_per_line) {
446: $number_of_tables++;
447: push @table_range,($number_of_bubbles % $bubbles_per_line);
448: }
449: $cell_width-=8;
450: $cell_width=$cell_width*3/4;
451: return ($cell_width,$number_of_tables,@table_range);
452: }
453:
454: sub format_number {
455: my ($number,$format,$target,$safeeval)=@_;
456: my $ans;
457: if ($format eq '') {
458: #What is the number? (integer,decimal,floating point)
459: if ($number=~/^(\d*\.?\d*)(E|e)(\d*)$/) {
460: $format = '3e';
461: } elsif ($number=~/^(\d*)\.(\d*)$/) {
462: $format = '4f';
463: } elsif ($number=~/^(\d*)$/) {
464: $format = 'd';
465: }
466: }
467: if (!$Apache::lonxml::default_homework_loaded) {
468: &Apache::lonxml::default_homework_load($safeeval);
469: }
470: $ans=&Apache::run::run("&prettyprint(q\0$number\0,q\0$format\0,q\0$target\0)",$safeeval);
471: return $ans;
472: }
473:
474: sub make_numerical_bubbles {
475: my ($number_of_bubbles,$target,$answer,$format,$incorrect,$safeeval) =@_;
476: my @bubble_values=();
477: &Apache::lonxml::debug("answer is $answer incorrect is $incorrect");
478: my @oldseed=&Math::Random::random_get_seed();
479: if (defined($incorrect) && ref($incorrect)) {
480: &Apache::lonxml::debug("inside ".(scalar(@$incorrect)+1 gt $number_of_bubbles));
481: if (defined($$incorrect[0]) &&
482: scalar(@$incorrect)+1 >= $number_of_bubbles) {
483: &Apache::lonxml::debug("inside ".(scalar(@$incorrect)+1).":$number_of_bubbles");
484: &Apache::response::setrandomnumber();
485: my @rand_inc=&Math::Random::random_permutation(@$incorrect);
486: @bubble_values=@rand_inc[0..($number_of_bubbles-2)];
487: @bubble_values=sort {$a <=> $b} (@bubble_values,$answer);
488: &Apache::lonxml::debug("Answer was :$answer: returning :".$#bubble_values.": whih are :".join(':',@bubble_values));
489: &Math::Random::random_set_seed(@oldseed);
490: if (defined($format) && $format ne '') {
491: my @bubble_display;
492: foreach my $value (@bubble_values) {
493: push(@bubble_display,
494: &format_number($value,$format,$target,$safeeval));
495: }
496: return (\@bubble_values,\@bubble_display);
497: } else {
498: return (\@bubble_values,\@bubble_values);
499: }
500: }
501: if (defined($$incorrect[0]) &&
502: scalar(@$incorrect)+1 < $number_of_bubbles) {
503: &Apache::lonxml::warning("Not enough incorrect answers were specified in the incorrect array, ignoring the specified incorrect answers and instead generating them (".join(',',@$incorrect).").");
504: }
505: }
506: my @factors = (1.13,1.17,1.25,1.33,1.45); #default values of factors
507: my @powers = (1..$number_of_bubbles);
508: &Apache::response::setrandomnumber();
509: my $ind=&Math::Random::random_uniform_integer(1,0,$#powers);
510: my $power = $powers[$ind];
511: $ind=&Math::Random::random_uniform_integer(1,0,$#factors);
512: my $factor = $factors[$ind];
513: my @bubble_display;
514: for ($ind=0;$ind<$number_of_bubbles;$ind++) {
515: $bubble_values[$ind] = $answer*($factor**($power-$powers[$#powers-$ind]));
516: $bubble_display[$ind] = &format_number($bubble_values[$ind],
517: $format,$target,$safeeval);
518:
519: }
520: &Math::Random::random_set_seed(@oldseed);
521: return (\@bubble_values,\@bubble_display);
522: }
523:
524: sub get_tolrange {
525: my ($ans,$tol)=@_;
526: my ($high,$low);
527: if ($tol =~ /%$/) {
528: chop($tol);
529: my $change=$ans*($tol/100.0);
530: $high=$ans+$change;
531: $low=$ans-$change;
532: } else {
533: $high=$ans+$tol;
534: $low=$ans-$tol;
535: }
536: return ($high,$low);
537: }
538:
539: sub get_sigrange {
540: my ($sig)=@_;
541: &Apache::lonxml::debug("Got a sig of :$sig:");
542: my $courseid=$env{'request.course.id'};
543: if (lc($env{"course.$courseid.disablesigfigs"}) eq 'yes') {
544: return (15,0);
545: }
546: my $sig_lbound;
547: my $sig_ubound;
548: if ($sig eq '') {
549: $sig_lbound = 0; #SIG_LB_DEFAULT
550: $sig_ubound =15; #SIG_UB_DEFAULT
551: } else {
552: ($sig_lbound,$sig_ubound) = split(/,/,$sig);
553: if (!defined($sig_lbound)) {
554: $sig_lbound = 0; #SIG_LB_DEFAULT
555: $sig_ubound =15; #SIG_UB_DEFAULT
556: }
557: if (!defined($sig_ubound)) { $sig_ubound=$sig_lbound; }
558: }
559: if (($sig_ubound<$sig_lbound) ||
560: ($sig_lbound > 15) ||
561: ($sig =~/(\+|-)/ ) ) {
562: my $errormsg=&mt("Invalid Significant figures detected")." ($sig)";
563: if ($env{'request.state'} eq 'construct') {
564: $errormsg.=
565: &Apache::loncommon::help_open_topic('Significant_Figures');
566: }
567: &Apache::lonxml::error($errormsg);
568: }
569: return ($sig_ubound,$sig_lbound);
570: }
571:
572: sub start_stringresponse {
573: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
574: my $result;
575: my $id = &Apache::response::start_response($parstack,$safeeval);
576: if ($target eq 'meta') {
577: $result=&Apache::response::meta_package_write('stringresponse');
578: } elsif ($target eq 'edit') {
579: $result.=&Apache::edit::tag_start($target,$token);
580: $result.=&Apache::edit::text_arg('Answer:','answer',$token);
581: $result.=&Apache::edit::select_arg('Type:','type',
582: [['cs','Case Sensitive'],['ci','Case Insensitive'],
583: ['mc','Case Insensitive, Any Order'],
584: ['re','Regular Expression']],$token);
585: $result.=&Apache::edit::text_arg('String to display for answer:',
586: 'answerdisplay',$token);
587: $result.=&Apache::edit::end_row().&Apache::edit::start_spanning_row();
588: } elsif ($target eq 'modified') {
589: my $constructtag;
590: $constructtag=&Apache::edit::get_new_args($token,$parstack,
591: $safeeval,'answer',
592: 'type','answerdisplay');
593: if ($constructtag) {
594: $result = &Apache::edit::rebuild_tag($token);
595: $result.=&Apache::edit::handle_insert();
596: }
597: } elsif ($target eq 'web') {
598: if ( &Apache::response::show_answer() ) {
599: my $answer=
600: &Apache::lonxml::get_param('answerdisplay',$parstack,$safeeval);
601: if (!defined $answer || $answer eq '') {
602: $answer=
603: &Apache::lonxml::get_param('answer',$parstack,$safeeval);
604: }
605: $Apache::inputtags::answertxt{$id}=$answer;
606: }
607: } elsif ($target eq 'answer' || $target eq 'grade') {
608: &Apache::response::reset_params();
609: }
610: return $result;
611: }
612:
613: sub end_stringresponse {
614: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
615: my $increment=1;
616: my $result = '';
617: my $part=$Apache::inputtags::part;
618: my $id=$Apache::inputtags::response[-1];
619: my $answer=&Apache::lonxml::get_param('answer',$parstack,$safeeval);
620: my $type=&Apache::lonxml::get_param('type',$parstack,$safeeval);
621: my $answerdisplay=&Apache::lonxml::get_param('answerdisplay',$parstack,$safeeval);
622: &Apache::lonxml::debug("current $answer ".$token->[2]);
623: if (!$Apache::lonxml::default_homework_loaded) {
624: &Apache::lonxml::default_homework_load($safeeval);
625: }
626: if ( $target eq 'grade' && &Apache::response::submitted() ) {
627: &Apache::response::setup_params('stringresponse',$safeeval);
628: $safeeval->share_from('capa',['&caparesponse_capa_check_answer']);
629: if ($Apache::lonhomework::type eq 'exam' ||
630: &Apache::response::submitted('scantron')) {
631: $increment=&Apache::response::scored_response($part,$id);
632: } else {
633: my $response = &Apache::response::getresponse();
634: if ( $response =~ /[^\s]/) {
635: my %previous = &Apache::response::check_for_previous($response,
636: $part,$id);
637: &Apache::lonxml::debug("submitted a $response<br>\n");
638: &Apache::lonxml::debug($$parstack[-1] . "\n<br>");
639: $Apache::lonhomework::results{"resource.$part.$id.submission"}=
640: $response;
641: my ($ad,$msg);
642: if ($type eq 're' ) {
643: # if the RE wasn't in a var it likely got munged,
644: # thus grab it from the var directly
645: # my $testans=$token->[2]->{'answer'};
646: # if ($testans !~ m/^\s*\$/) {
647: # $answer=$token->[2]->{'answer'};
648: # }
649: ${$safeeval->varglob('LONCAPA::response')}=$response;
650: $result = &Apache::run::run('return $LONCAPA::response=~m'.$answer,$safeeval);
651: &Apache::lonxml::debug("current $response");
652: &Apache::lonxml::debug("current $answer");
653: $ad = ($result) ? 'APPROX_ANS' : 'INCORRECT';
654: } else {
655: my $args_ref=
656: \%{$safeeval->varglob('LONCAPA::CAPAresponse_args')};
657:
658: $$args_ref{'response'}=$response;
659: &Apache::lonxml::debug("current $response");
660: $$args_ref{'type'}=
661: &Apache::lonxml::get_param('type',$parstack,$safeeval);
662: foreach my $key (keys(%Apache::inputtags::params)) {
663: $$args_ref{$key}=$Apache::inputtags::params{$key};
664: }
665: &Apache::lonxml::debug('answer is'.join(':',$answer));
666: @{$safeeval->varglob('LONCAPA::CAPAresponse_answer')}=($answer);
667: ($result, my @msgs)=&Apache::run::run("&caparesponse_check_list()",$safeeval);
668: &Apache::lonxml::debug('msgs are'.join(':',@msgs));
669: my ($awards)=split(/:/,$result);
670: my (@awards) = split(/,/,$awards);
671: ($ad,$msg) = &Apache::inputtags::finalizeawards(\@awards,\@msgs);
672: &Apache::lonxml::debug("\n<br>result:$result:$Apache::lonxml::curdepth<br>\n");
673: }
674: if ($Apache::lonhomework::type eq 'survey' &&
675: ($ad eq 'INCORRECT' || $ad eq 'APPROX_ANS' ||
676: $ad eq 'EXACT_ANS')) {
677: $ad='SUBMITTED';
678: }
679: &Apache::response::handle_previous(\%previous,$ad);
680: $Apache::lonhomework::results{"resource.$part.$id.awarddetail"}=$ad;
681: $Apache::lonhomework::results{"resource.$part.$id.awardmsg"}=$msg;
682: }
683: }
684: } elsif ($target eq 'web' || $target eq 'tex') {
685: my $award = $Apache::lonhomework::history{"resource.$Apache::inputtags::part.solved"};
686: my $status = $Apache::inputtags::status['-1'];
687: if ($Apache::lonhomework::type eq 'exam' && $target eq 'tex') {
688: $result.='\fbox{\fbox{\parbox{\textwidth-5mm}{\strut\\\\\strut\\\\\strut\\\\\strut\\\\}}}';
689: $increment = &Apache::response::repetition();
690: $result.='\begin{enumerate}';
691: for (my $i=0;$i<$increment;$i++) {
692: $result.='\item[\textbf{'.($Apache::lonxml::counter+$i).
693: '}.]\textit{Leave blank on scoring form}\vskip 0 mm';
694: }
695: $result.= '\end{enumerate}';
696: }
697: } elsif ($target eq 'answer' || $target eq 'analyze') {
698: if ($target eq 'analyze') {
699: push (@{ $Apache::lonhomework::analyze{"parts"} },"$part.$id");
700: $Apache::lonhomework::analyze{"$part.$id.type"} = 'stringresponse';
701: &Apache::response::check_if_computed($token,$parstack,$safeeval,
702: 'answer');
703: }
704: &Apache::response::setup_params('stringresponse',$safeeval);
705: if ($target eq 'answer') {
706: $result.=&Apache::response::answer_header('stringresponse');
707: }
708: # foreach my $ans (@answers) {
709: if ($target eq 'answer') {
710: $result.=&Apache::response::answer_part('stringresponse',$answer);
711: } elsif ($target eq 'analyze') {
712: push (@{ $Apache::lonhomework::analyze{"$part.$id.answer"} },
713: $answer);
714: }
715: # }
716: my $string='Case Insensitive';
717: if ($type eq 'mc') {
718: $string='Multiple Choice';
719: } elsif ($type eq 'cs') {
720: $string='Case Sensitive';
721: } elsif ($type eq 'ci') {
722: $string='Case Insensitive';
723: } elsif ($type eq 're') {
724: $string='Regular Expression';
725: }
726: if ($target eq 'answer') {
727: if ($env{'form.answer_output_mode'} eq 'tex') {
728: $result.=&Apache::response::answer_part('stringresponse',
729: "$string");
730: } else {
731: $result.=&Apache::response::answer_part('stringresponse',
732: "<b>$string</b>");
733: }
734: } elsif ($target eq 'analyze') {
735: push (@{$Apache::lonhomework::analyze{"$part.$id.str_type"}},
736: $type);
737: }
738: if ($target eq 'answer') {
739: $result.=&Apache::response::answer_footer('stringresponse');
740: }
741: } elsif ($target eq 'edit') {
742: $result.='</td></tr>'.&Apache::edit::end_table;
743: }
744: if ($target eq 'grade' || $target eq 'web' || $target eq 'answer' ||
745: $target eq 'tex' || $target eq 'analyze') {
746: &Apache::lonxml::increment_counter($increment);
747: }
748: &Apache::response::end_response;
749: return $result;
750: }
751:
752: sub start_formularesponse {
753: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
754: my $result;
755: if ($target eq 'meta') {
756: &Apache::response::start_response($parstack,$safeeval);
757: $result=&Apache::response::meta_package_write('formularesponse');
758: &Apache::response::end_response();
759: } else {
760: $result.=&start_numericalresponse(@_);
761: }
762: return $result;
763: }
764:
765: sub end_formularesponse {
766: return end_numericalresponse(@_);
767: }
768:
769: 1;
770: __END__
771:
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>