1: # The LearningOnline Network with CAPA
2: # caparesponse definition
3: #
4: # $Id: caparesponse.pm,v 1.226 2008/06/10 15:22:39 www Exp $
5: #
6: # Copyright Michigan State University Board of Trustees
7: #
8: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
9: #
10: # LON-CAPA is free software; you can redistribute it and/or modify
11: # it under the terms of the GNU General Public License as published by
12: # the Free Software Foundation; either version 2 of the License, or
13: # (at your option) any later version.
14: #
15: # LON-CAPA is distributed in the hope that it will be useful,
16: # but WITHOUT ANY WARRANTY; without even the implied warranty of
17: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18: # GNU General Public License for more details.
19: #
20: # You should have received a copy of the GNU General Public License
21: # along with LON-CAPA; if not, write to the Free Software
22: # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
23: #
24: # /home/httpd/html/adm/gpl.txt
25: #
26: # http://www.lon-capa.org/
27: #
28:
29: package Apache::caparesponse;
30: use strict;
31: use capa;
32: use Safe::Hole;
33: use Apache::lonmaxima();
34: use Apache::lonlocal;
35: use Apache::lonnet;
36: use Apache::response();
37: use Storable qw(dclone);
38:
39: BEGIN {
40: &Apache::lonxml::register('Apache::caparesponse',('numericalresponse','stringresponse','formularesponse'));
41: }
42:
43: my %answer;
44: my @answers;
45: sub get_answer { return %answer; };
46: sub push_answer{ push(@answers,dclone(\%answer)); undef(%answer) }
47: sub pop_answer { %answer = %{pop(@answers)}; };
48:
49: my $cur_name;
50: my $tag_internal_answer_name = 'INTERNAL';
51:
52: sub start_answer {
53: my ($target,$token,$tagstack,$parstack,$parser,$safeeval)=@_;
54: my $result;
55: $cur_name = &Apache::lonxml::get_param('name',$parstack,$safeeval);
56: if ($cur_name =~ /^\s*$/) { $cur_name = $Apache::lonxml::curdepth; }
57: my $type = &Apache::lonxml::get_param('type',$parstack,$safeeval);
58: if (!defined($type) && $tagstack->[-2] eq 'answergroup') {
59: $type = &Apache::lonxml::get_param('type',$parstack,$safeeval,-2);
60: }
61: if (!defined($type)) { $type = 'ordered' };
62: $answer{$cur_name}= { 'type' => $type,
63: 'answers' => [] };
64: if ($target eq 'edit') {
65: $result.=&Apache::edit::tag_start($target,$token);
66: $result.=&Apache::edit::text_arg('Name:','name',$token);
67: $result.=&Apache::edit::select_arg('Type:','type',
68: [['ordered', 'Ordered' ],
69: ['unordered','Unordered'],],
70: $token);
71: $result.=&Apache::edit::end_row().&Apache::edit::start_spanning_row();
72: } elsif ($target eq 'modified') {
73: my $constructtag = &Apache::edit::get_new_args($token,$parstack,
74: $safeeval,'name',
75: 'type');
76: if ($constructtag) {
77: $result = &Apache::edit::rebuild_tag($token);
78: $result.= &Apache::edit::handle_insert();
79: }
80: }
81: return $result;
82: }
83:
84: sub end_answer {
85: my ($target,$token,$tagstack,$parstack,$parser,$safeeval)=@_;
86: my $result;
87: if ($target eq 'edit') {
88: $result .= &Apache::edit::tag_end();
89: }
90:
91: undef($cur_name);
92: return $result;
93: }
94:
95: sub insert_answer {
96: return '
97: <answer>
98: <value></value>
99: </answer>';
100: }
101:
102: sub start_answergroup {
103: my ($target,$token,$tagstack,$parstack,$parser,$safeeval)=@_;
104: my $result;
105: if ($target eq 'edit') {
106: $result.=&Apache::edit::tag_start($target,$token);
107: $result.=&Apache::edit::select_arg('Type:','type',
108: [['ordered', 'Ordered' ],
109: ['unordered','Unordered'],],
110: $token);
111: $result.=&Apache::edit::end_row().&Apache::edit::start_spanning_row();
112: } elsif ($target eq 'modified') {
113: my $constructtag = &Apache::edit::get_new_args($token,$parstack,
114: $safeeval,'name',
115: 'type');
116: if ($constructtag) {
117: $result = &Apache::edit::rebuild_tag($token);
118: $result.= &Apache::edit::handle_insert();
119: }
120: }
121: return $result;
122: }
123:
124: sub end_answergroup {
125: my ($target,$token,$tagstack,$parstack,$parser,$safeeval)=@_;
126: my $result;
127: if ($target eq 'web') {
128: if ( &Apache::response::show_answer() ) {
129: my $partid = $Apache::inputtags::part;
130: my $id = $Apache::inputtags::response[-1];
131: &set_answertext($Apache::lonhomework::history{"resource.$partid.$id.answername"},
132: $target,$token,$tagstack,$parstack,$parser,
133: $safeeval,-2);
134: }
135: } elsif ($target eq 'edit') {
136: $result .= &Apache::edit::tag_end();
137: }
138: return $result;
139: }
140:
141: sub insert_answergroup {
142: return '
143: <answergroup>
144: <answer>
145: <value></value>
146: </answer>
147: </answergroup>';
148: }
149:
150: sub start_value {
151: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
152: my $result;
153: if ( $target eq 'web' || $target eq 'tex' ||
154: $target eq 'grade' || $target eq 'webgrade' ||
155: $target eq 'answer' || $target eq 'analyze' ) {
156: my $bodytext = &Apache::lonxml::get_all_text("/value",$parser,$style);
157: $bodytext = &Apache::run::evaluate($bodytext,$safeeval,
158: $$parstack[-1]);
159:
160: push(@{ $answer{$cur_name}{'answers'} },[$bodytext]);
161:
162: } elsif ($target eq 'edit') {
163: $result.=&Apache::edit::tag_start($target,$token);
164: my $bodytext = &Apache::lonxml::get_all_text("/value",$parser,$style);
165: $result.=&Apache::edit::editline($token->[1],$bodytext,undef,40).
166: &Apache::edit::end_row();
167: } elsif ($target eq 'modified') {
168: $result=$token->[4].&Apache::edit::modifiedfield('/value',$parser);
169: }
170: return $result;
171: }
172:
173: sub end_value {
174: my ($target,$token,$tagstack,$parstack,$parser,$safeeval)=@_;
175: my $result;
176: if ($target eq 'edit') {
177: $result = &Apache::edit::end_table();
178: }
179: return $result;
180: }
181:
182: sub insert_value {
183: return '
184: <value></value>';
185: }
186:
187: sub start_vector {
188: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
189: my $result;
190: if ( $target eq 'web' || $target eq 'tex' ||
191: $target eq 'grade' || $target eq 'webgrade' ||
192: $target eq 'answer' || $target eq 'analyze' ) {
193: my $bodytext = &Apache::lonxml::get_all_text("/vector",$parser,$style);
194: my @values = &Apache::run::run($bodytext,$safeeval,$$parstack[-1]);
195: if (@values == 1) {
196: @values = split(',',$values[0]);
197: }
198: push(@{ $answer{$cur_name}{'answers'} },\@values);
199: } elsif ($target eq 'edit') {
200: $result.=&Apache::edit::tag_start($target,$token);
201: my $bodytext = &Apache::lonxml::get_all_text("/vector",$parser,$style);
202: $result.=&Apache::edit::editline($token->[1],$bodytext,undef,40).
203: &Apache::edit::end_row();
204: } elsif ($target eq 'modified') {
205: $result=$token->[4].&Apache::edit::modifiedfield('/vector',$parser);
206: }
207: return $result;
208: }
209:
210: sub end_vector {
211: my ($target,$token,$tagstack,$parstack,$parser,$safeeval)=@_;
212: my $result;
213: if ($target eq 'edit') {
214: $result = &Apache::edit::end_table();
215: }
216: return $result;
217: }
218:
219: sub insert_vector {
220: return '
221: <value></value>';
222: }
223:
224: sub start_array {
225: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
226: my $result;
227: if ( $target eq 'web' || $target eq 'tex' ||
228: $target eq 'grade' || $target eq 'webgrade' ||
229: $target eq 'answer' || $target eq 'analyze' ) {
230: my $bodytext = &Apache::lonxml::get_all_text("/array",$parser,$style);
231: my @values = &Apache::run::evaluate($bodytext,$safeeval,
232: $$parstack[-1]);
233: push(@{ $answer{$cur_name}{'answers'} },@values);
234: }
235: return $result;
236: }
237:
238: sub end_array {
239: my ($target,$token,$tagstack,$parstack,$parser,$safeeval)=@_;
240: my $result;
241: return $result;
242: }
243:
244: sub start_unit {
245: my ($target,$token,$tagstack,$parstack,$parser,$safeeval)=@_;
246: my $result;
247: return $result;
248: }
249:
250: sub end_unit {
251: my ($target,$token,$tagstack,$parstack,$parser,$safeeval)=@_;
252: my $result;
253: return $result;
254: }
255:
256: sub start_numericalresponse {
257: my ($target,$token,$tagstack,$parstack,$parser,$safeeval)=@_;
258: &Apache::lonxml::register('Apache::caparesponse',
259: ('answer','answergroup','value','array','unit',
260: 'vector'));
261: push(@Apache::lonxml::namespace,'caparesponse');
262: my $id = &Apache::response::start_response($parstack,$safeeval);
263: my $result;
264: undef(%answer);
265: undef(%{$safeeval->varglob('LONCAPA::CAPAresponse_args')});
266: if ($target eq 'edit') {
267: $result.=&Apache::edit::tag_start($target,$token);
268: $result.=&Apache::edit::text_arg('Answer:','answer',$token);
269: if ($token->[1] eq 'numericalresponse') {
270: $result.=&Apache::edit::text_arg('Incorrect Answers:','incorrect',
271: $token).
272: &Apache::loncommon::help_open_topic('numerical_wrong_answers');
273: $result.=&Apache::edit::text_arg('Unit:','unit',$token,5).
274: &Apache::loncommon::help_open_topic('Physical_Units');
275: $result.=&Apache::edit::text_arg('Format:','format',$token,4).
276: &Apache::loncommon::help_open_topic('Numerical_Response_Format');
277: } elsif ($token->[1] eq 'formularesponse') {
278: $result.=&Apache::edit::text_arg('Sample Points:','samples',
279: $token,40).
280: &Apache::loncommon::help_open_topic('Formula_Response_Sampling');
281: }
282: $result.=&Apache::edit::end_row().&Apache::edit::start_spanning_row();
283: } elsif ($target eq 'modified') {
284: my $constructtag;
285: if ($token->[1] eq 'numericalresponse') {
286: $constructtag=&Apache::edit::get_new_args($token,$parstack,
287: $safeeval,'answer',
288: 'incorrect','unit',
289: 'format');
290: } elsif ($token->[1] eq 'formularesponse') {
291: $constructtag=&Apache::edit::get_new_args($token,$parstack,
292: $safeeval,'answer',
293: 'samples');
294: }
295: if ($constructtag) {
296: $result = &Apache::edit::rebuild_tag($token);
297: $result.=&Apache::edit::handle_insert();
298: }
299: } elsif ($target eq 'meta') {
300: $result=&Apache::response::meta_package_write('numericalresponse');
301: } elsif ($target eq 'answer' || $target eq 'grade') {
302: &Apache::response::reset_params();
303: } elsif ($target eq 'web') {
304: my $partid = $Apache::inputtags::part;
305: my $hideunit=&Apache::lonnet::EXT('resource.'.$partid.'_'.$id.'.turnoffunit');
306: &Apache::lonxml::debug("Got unit $hideunit for $partid $id");
307: #no way to enter units, with radio buttons
308: if (lc($hideunit) eq "yes") {
309: my $unit=&Apache::lonxml::get_param_var('unit',$parstack,
310: $safeeval);
311: if ($unit =~ /\S/) { $result.=" (in $unit) "; }
312: }
313: if (($token->[1] eq 'formularesponse') &&
314: ($Apache::inputtags::status['-1'] eq 'CAN_ANSWER') &&
315: (!&Apache::lonxml::get_param_var('samples',$parstack,$safeeval))) {
316: $result.=&edit_formula_button($id,"HWVAL_$id");
317: }
318: if ( &Apache::response::show_answer() ) {
319: &set_answertext($tag_internal_answer_name,$target,$token,$tagstack,
320: $parstack,$parser,$safeeval,-1);
321: }
322: }
323: return $result;
324: }
325:
326: sub edit_formula_button {
327: my ($id,$field)=@_;
328: my $button=&mt('Edit Answer');
329: my $helplink=&Apache::loncommon::help_open_topic('Formula_Editor');
330: return(<<ENDFORMULABUTTON);
331: <script language="JavaScript">
332: function edit_${id}_${field} (textarea) {
333: thenumber = textarea;
334: thedata = document.forms['lonhomework'].elements[textarea].value;
335: newwin = window.open("/adm/dragmath/applet/MaximaPopup.html","","width=565,height=400,resizable");
336: }
337: </script>
338: <input type='button' value='$button' onclick="javascript:edit_${id}_${field}('${field}');void(0);" />$helplink
339: ENDFORMULABUTTON
340: }
341:
342: sub set_answertext {
343: my ($name,$target,$token,$tagstack,$parstack,$parser,$safeeval,
344: $response_level) = @_;
345: &add_in_tag_answer($parstack,$safeeval,$response_level);
346:
347: if ($name eq '' || !ref($answer{$name})) {
348: if (ref($answer{$tag_internal_answer_name})) {
349: $name = $tag_internal_answer_name;
350: } else {
351: $name = (sort(keys(%answer)))[0];
352: }
353: }
354: return if ($name eq '' || !ref($answer{$name}));
355:
356: my (@formats)=&Apache::lonxml::get_param_var('format',$parstack,
357: $safeeval,$response_level);
358: my $unit=&Apache::lonxml::get_param_var('unit',$parstack,$safeeval,
359: $response_level);
360:
361: &Apache::lonxml::debug("answer looks to be $name");
362: my @answertxt;
363: for (my $i=0; $i < scalar(@{$answer{$name}{'answers'}}); $i++) {
364: my $answertxt;
365: my $answer=$answer{$name}{'answers'}[$i];
366: foreach my $element (@$answer) {
367: if ( scalar(@$tagstack)
368: && $tagstack->[$response_level] ne 'numericalresponse') {
369: $answertxt.=$element.',';
370: } else {
371: my $format;
372: if ($#formats > 0) {
373: $format=$formats[$i];
374: } else {
375: $format=$formats[0];
376: }
377: if ($unit=~/\$/) { $format="\$".$format; $unit=~s/\$//g; }
378: if ($unit=~/\,/) { $format="\,".$format; $unit=~s/\,//g; }
379: my $formatted=&format_number($element,$format,$target,
380: $safeeval);
381: $answertxt.=' '.$formatted.',';
382: }
383:
384: }
385: chop($answertxt);
386: if ($target eq 'web') {
387: $answertxt.=" $unit ";
388: }
389:
390: push(@answertxt,$answertxt)
391: }
392:
393: my $id = $Apache::inputtags::response[-1];
394: $Apache::inputtags::answertxt{$id}=\@answertxt;
395: }
396:
397: sub setup_capa_args {
398: my ($safeeval,$parstack,$args,$response) = @_;
399: my $args_ref= \%{$safeeval->varglob('LONCAPA::CAPAresponse_args')};
400: undef(%{ $args_ref });
401:
402: foreach my $arg (@{$args}) {
403: $$args_ref{$arg}=
404: &Apache::lonxml::get_param($arg,$parstack,$safeeval);
405: }
406: foreach my $key (keys(%Apache::inputtags::params)) {
407: $$args_ref{$key}=$Apache::inputtags::params{$key};
408: }
409: &setup_capa_response($args_ref,$response);
410: return $args_ref;
411: }
412:
413: sub setup_capa_response {
414: my ($args_ref,$response) = @_;
415:
416: if (ref($response)) {
417: $$args_ref{'response'}=dclone($response);
418: } else {
419: $$args_ref{'response'}=dclone([$response]);
420: }
421: }
422:
423: sub check_submission {
424: my ($response,$partid,$id,$tag,$parstack,$safeeval,$ignore_sig)=@_;
425: my @args = ('type','tol','sig','format','unit','calc','samples');
426: my $args_ref = &setup_capa_args($safeeval,$parstack,\@args,$response);
427:
428: my $hideunit=
429: &Apache::lonnet::EXT('resource.'.$partid.'_'.$id.'.turnoffunit');
430: #no way to enter units, with radio buttons
431: if ($Apache::lonhomework::type eq 'exam' ||
432: lc($hideunit) eq "yes") {
433: delete($$args_ref{'unit'});
434: }
435: #sig fig don't make much sense either
436: if (($Apache::lonhomework::type eq 'exam' ||
437: &Apache::response::submitted('scantron') ||
438: $ignore_sig) &&
439: $tag eq 'numericalresponse') {
440: delete($$args_ref{'sig'});
441: }
442:
443: if ($tag eq 'formularesponse') {
444: if ($$args_ref{'samples'}) {
445: $$args_ref{'type'}='fml';
446: } else {
447: $$args_ref{'type'}='math';
448: }
449: } elsif ($tag eq 'numericalresponse') {
450: $$args_ref{'type'}='float';
451: }
452:
453: &add_in_tag_answer($parstack,$safeeval);
454:
455: if (!%answer) {
456: &Apache::lonxml::error("No answers are defined");
457: }
458:
459: my (@final_awards,@final_msgs,@names);
460: foreach my $name (keys(%answer)) {
461: &Apache::lonxml::debug(" doing $name with ".join(':',@{ $answer{$name}{'answers'} }));
462:
463: ${$safeeval->varglob('LONCAPA::CAPAresponse_answer')}=dclone($answer{$name});
464: &setup_capa_response($args_ref,$response);
465: use Time::HiRes;
466: my $t0 = [Time::HiRes::gettimeofday()];
467: my ($result,@msgs) =
468: &Apache::run::run("&caparesponse_check_list()",$safeeval);
469: &Apache::lonxml::debug("checking $name $result with $response took ".&Time::HiRes::tv_interval($t0));
470: &Apache::lonxml::debug('msgs are '.join(':',@msgs));
471: my ($awards)=split(/:/,$result);
472: my @awards= split(/,/,$awards);
473: my ($ad, $msg) = &Apache::inputtags::finalizeawards(\@awards,\@msgs);
474: push(@final_awards,$ad);
475: push(@final_msgs,$msg);
476: push(@names,$name);
477: }
478: my ($ad, $msg, $name) = &Apache::inputtags::finalizeawards(\@final_awards,
479: \@final_msgs,
480: \@names,1);
481: &Apache::lonxml::debug(" name of picked award is $name from ".join(', ',@names));
482: return($ad,$msg, $name);
483: }
484:
485: sub add_in_tag_answer {
486: my ($parstack,$safeeval,$response_level) = @_;
487: my @answer=&Apache::lonxml::get_param_var('answer',$parstack,$safeeval,
488: $response_level);
489: &Apache::lonxml::debug('answer is'.join(':',@answer));
490: if (@answer && $answer[0] =~ /\S/) {
491: $answer{$tag_internal_answer_name}= {'type' => 'ordered',
492: 'answers' => [\@answer] };
493: }
494: }
495:
496: sub capa_formula_fix {
497: my ($expression)=@_;
498: return &Apache::response::implicit_multiplication($expression);
499: }
500:
501: sub end_numericalresponse {
502: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
503:
504: &Apache::lonxml::deregister('Apache::caparesponse',
505: ('answer','answergroup','value','array','unit',
506: 'vector'));
507: pop(@Apache::lonxml::namespace);
508:
509: my $increment=1;
510: my $result = '';
511: if (!$Apache::lonxml::default_homework_loaded) {
512: &Apache::lonxml::default_homework_load($safeeval);
513: }
514: my $partid = $Apache::inputtags::part;
515: my $id = $Apache::inputtags::response[-1];
516: my $tag;
517: my $safehole = new Safe::Hole;
518: $safeeval->share_from('capa',['&caparesponse_capa_check_answer']);
519:
520: if (scalar(@$tagstack)) { $tag=$$tagstack[-1]; }
521: if ( $target eq 'grade' && &Apache::response::submitted() ) {
522: &Apache::response::setup_params($tag,$safeeval);
523: if ($Apache::lonhomework::type eq 'exam' &&
524: (($tag eq 'formularesponse') || ($tag eq 'mathresponse'))) {
525: $increment=&Apache::response::scored_response($partid,$id);
526: } else {
527: my $response = &Apache::response::getresponse();
528: if ( $response =~ /[^\s]/) {
529: my %previous = &Apache::response::check_for_previous($response,$partid,$id);
530: &Apache::lonxml::debug("submitted a $response<br>\n");
531: &Apache::lonxml::debug($$parstack[-1] . "\n<br>");
532:
533: if ( &Apache::response::submitted('scantron')) {
534: &add_in_tag_answer($parstack,$safeeval);
535: my ($values,$display)=&make_numerical_bubbles($partid,$id,
536: $target,$parstack,$safeeval);
537: $response=$values->[$response];
538: }
539: $Apache::lonhomework::results{"resource.$partid.$id.submission"}=$response;
540: my ($ad,$msg,$name)=&check_submission($response,$partid,$id,
541: $tag,$parstack,
542: $safeeval);
543:
544: &Apache::lonxml::debug('ad is'.$ad);
545: if ($ad eq 'SIG_FAIL') {
546: my ($sig_u,$sig_l)=
547: &get_sigrange($Apache::inputtags::params{'sig'});
548: $msg=join(':',$msg,$sig_l,$sig_u);
549: &Apache::lonxml::debug("sigs bad $sig_u $sig_l ".
550: $Apache::inputtags::params{'sig'});
551: }
552: &Apache::lonxml::debug("\n<br>result:$result:$Apache::lonxml::curdepth<br>\n");
553: if ($Apache::lonhomework::type eq 'survey' &&
554: ($ad eq 'INCORRECT' || $ad eq 'APPROX_ANS' ||
555: $ad eq 'EXACT_ANS')) {
556: $ad='SUBMITTED';
557: }
558: &Apache::response::handle_previous(\%previous,$ad);
559: $Apache::lonhomework::results{"resource.$partid.$id.awarddetail"}=$ad;
560: $Apache::lonhomework::results{"resource.$partid.$id.awardmsg"}=$msg;
561: $Apache::lonhomework::results{"resource.$partid.$id.answername"}=$name;
562: $result='';
563: }
564: }
565: } elsif ($target eq 'web' || $target eq 'tex') {
566: &check_for_answer_errors($parstack,$safeeval);
567: my $award = $Apache::lonhomework::history{"resource.$Apache::inputtags::part.solved"};
568: my $status = $Apache::inputtags::status['-1'];
569: if ($Apache::lonhomework::type eq 'exam') {
570: # FIXME support multi dimensional numerical problems
571: # in exam bubbles
572: my ($bubble_values,$bubble_display)=
573: &make_numerical_bubbles($partid,$id,$target,$parstack,
574: $safeeval);
575: my $number_of_bubbles = scalar(@{ $bubble_values });
576: my $unit=&Apache::lonxml::get_param_var('unit',$parstack,
577: $safeeval);
578: my @alphabet=('A'..'Z');
579: if ($target eq 'web') {
580: if ($tag eq 'numericalresponse') {
581: if ($unit=~/\S/) {$result.=' (in '.$unit.')<br /><br />';}
582: $result.= '<table border="1"><tr>';
583: my $previous=$Apache::lonhomework::history{"resource.$Apache::inputtags::part.$id.submission"};
584: for (my $ind=0;$ind<$number_of_bubbles;$ind++) {
585: my $checked='';
586: if ($previous eq $bubble_values->[$ind]) {
587: $checked=" checked='on' ";
588: }
589: $result.='<td><input type="radio" name="HWVAL_'.$id.
590: '" value="'.$bubble_values->[$ind].'" '.$checked
591: .' /><b>'.$alphabet[$ind].'</b>: '.
592: $bubble_display->[$ind].'</td>';
593: }
594: $result.='</tr></table>';
595: }
596: } elsif ($target eq 'tex') {
597: if ((defined $unit) and ($unit=~/\S/) and ($Apache::lonhomework::type eq 'exam')) {
598: $result.=' \textit{(in} \verb|'.$unit.'|\textit{)} ';
599: }
600: if ($tag eq 'numericalresponse') {
601: my ($celllength,$number_of_tables,@table_range)=
602: &get_table_sizes($number_of_bubbles,$bubble_display);
603: my $j=0;
604: my $cou=0;
605: $result.='\vskip -1 mm \noindent \begin{enumerate}\item[\textbf{'.$Apache::lonxml::counter.'}.]';
606: for (my $i=0;$i<$number_of_tables;$i++) {
607: $result.='\vskip -1 mm \noindent \setlength{\tabcolsep}{2 mm}\begin{tabular}{';
608: for (my $ind=0;$ind<$table_range[$j];$ind++) {
609: $result.='p{3 mm}p{'.$celllength.' mm}';
610: }
611: $result.='}';
612: for (my $ind=$cou;$ind<$cou+$table_range[$j];$ind++) {
613: $result.='\hskip -4 mm {\small \textbf{'.$alphabet[$ind].'}}$\bigcirc$ & \hskip -3 mm {\small '.$bubble_display->[$ind].'} ';
614: if ($ind != $cou+$table_range[$j]-1) {$result.=' & ';}
615: }
616: $cou += $table_range[$j];
617: $j++;
618: $result.='\\\\\end{tabular}\vskip 0 mm ';
619: }
620: $result.='\end{enumerate}';
621: } else {
622: $increment = &Apache::response::repetition();
623: }
624: }
625: }
626: &Apache::response::setup_prior_tries_hash(\&format_prior_response_numerical);
627: } elsif ($target eq 'edit') {
628: $result.='</td></tr>'.&Apache::edit::end_table;
629: } elsif ($target eq 'answer' || $target eq 'analyze') {
630: my $part_id="$partid.$id";
631: if ($target eq 'analyze') {
632: push (@{ $Apache::lonhomework::analyze{"parts"} },$part_id);
633: $Apache::lonhomework::analyze{"$part_id.type"} = $tag;
634: my (@incorrect)=&Apache::lonxml::get_param_var('incorrect',$parstack,$safeeval);
635: if ($#incorrect eq 0) { @incorrect=(split(/,/,$incorrect[0])); }
636: push (@{ $Apache::lonhomework::analyze{"$part_id.incorrect"} }, @incorrect);
637: &Apache::response::check_if_computed($token,$parstack,
638: $safeeval,'answer');
639: }
640: if (scalar(@$tagstack)) {
641: &Apache::response::setup_params($tag,$safeeval);
642: }
643: &add_in_tag_answer($parstack,$safeeval);
644: my (@formats)=&Apache::lonxml::get_param_var('format',$parstack,$safeeval);
645:
646: my $unit=&Apache::lonxml::get_param_var('unit',$parstack,$safeeval);
647:
648: if ($target eq 'answer') {
649: $result.=&Apache::response::answer_header($tag,undef,
650: scalar(keys(%answer)));
651: if ($tag eq 'numericalresponse'
652: && $Apache::lonhomework::type eq 'exam') {
653: my ($bubble_values,undef,$correct) = &make_numerical_bubbles($partid,
654: $id,$target,$parstack,$safeeval);
655: $result.=&Apache::response::answer_part($tag,$correct);
656: }
657: }
658: foreach my $name (sort(keys(%answer))) {
659: my @answers = @{ $answer{$name}{'answers'} };
660: if ($target eq 'analyze') {
661: foreach my $info ('answer','ans_high','ans_low','format') {
662: $Apache::lonhomework::analyze{"$part_id.$info"}{$name}=[];
663: }
664: }
665: my ($sigline,$tolline);
666: if ($name ne $tag_internal_answer_name
667: || scalar(keys(%answer)) > 1) {
668: $result.=&Apache::response::answer_part($tag,$name);
669: }
670: for(my $i=0;$i<=$#answers;$i++) {
671: my $ans=$answers[$i];
672: my $fmt=$formats[0];
673: if (@formats && $#formats) {$fmt=$formats[$i];}
674: my ($sighigh,$siglow);
675: if ($Apache::inputtags::params{'sig'}) {
676: ($sighigh,$siglow)=&get_sigrange($Apache::inputtags::params{'sig'});
677: }
678: my @vector;
679: if (ref($ans)) {
680: @vector = @{ $ans };
681: } else {
682: @vector = ($ans);
683: }
684: my @all_answer_info;
685: foreach my $element (@vector) {
686: my ($high,$low);
687: if ($Apache::inputtags::params{'tol'}) {
688: ($high,$low)=&get_tolrange($element,$Apache::inputtags::params{'tol'});
689: }
690: if ($target eq 'answer') {
691: if ($fmt && $tag eq 'numericalresponse') {
692: $fmt=~s/e/E/g;
693: if ($unit=~/\$/) { $fmt="\$".$fmt; $unit=~s/\$//g; }
694: if ($unit=~/\,/) { $fmt="\,".$fmt; $unit=~s/\,//g; }
695: $element = &format_number($element,$fmt,$target,$safeeval);
696: #if ($high) {
697: # $high=&format_number($high,$fmt,$target,$safeeval);
698: # $low =&format_number($low,$fmt,$target,$safeeval);
699: #}
700: }
701: if ($high && $tag eq 'numericalresponse') {
702: $element.='; ['.$low.'; '.$high.']';
703: $tolline .= "[$low, $high]";
704: }
705: if (defined($sighigh) && $tag eq 'numericalresponse') {
706: if ($env{'form.answer_output_mode'} eq 'tex') {
707: $element.= "; Sig $siglow - $sighigh";
708: } else {
709: $element.= " Sig <i>$siglow - $sighigh</i>";
710: $sigline .= "[$siglow, $sighigh]";
711: }
712: }
713: push(@all_answer_info,$element);
714:
715: } elsif ($target eq 'analyze') {
716: push (@{ $Apache::lonhomework::analyze{"$part_id.answer"}{$name}[$i] }, $element);
717: if ($high) {
718: push (@{ $Apache::lonhomework::analyze{"$part_id.ans_high"}{$name}[$i] }, $high);
719: push (@{ $Apache::lonhomework::analyze{"$part_id.ans_low"}{$name}[$i] }, $low);
720: }
721: if ($fmt) {
722: push (@{ $Apache::lonhomework::analyze{"$part_id.format"}{$name}[$i] }, $fmt);
723: }
724: }
725: }
726: if ($target eq 'answer') {
727: $result.= &Apache::response::answer_part($tag,join('; ',@all_answer_info));
728: }
729: }
730:
731: my @fmt_ans;
732: for(my $i=0;$i<=$#answers;$i++) {
733: my $ans=$answers[$i];
734: my $fmt=$formats[0];
735: if (@formats && $#formats) {$fmt=$formats[$i];}
736: foreach my $element (@$ans) {
737: if ($fmt && $tag eq 'numericalresponse') {
738: $fmt=~s/e/E/g;
739: if ($unit=~/\$/) { $fmt="\$".$fmt; $unit=~s/\$//g; }
740: if ($unit=~/\,/) { $fmt="\,".$fmt; $unit=~s/\,//g; }
741: $element = &format_number($element,$fmt,$target,
742: $safeeval);
743: if ($fmt=~/\$/ && $unit!~/\$/) { $element=~s/\$//; }
744: }
745: }
746: push(@fmt_ans,join(',',@$ans));
747: }
748: my $response=\@fmt_ans;
749:
750: my $hideunit=&Apache::lonnet::EXT('resource.'.$partid.'_'.
751: $id.'.turnoffunit');
752: if ($unit ne '' &&
753: ! ($Apache::lonhomework::type eq 'exam' ||
754: lc($hideunit) eq "yes") ) {
755: my $cleanunit=$unit;
756: $cleanunit=~s/\$\,//g;
757: foreach my $ans (@fmt_ans) {
758: $ans.=" $cleanunit";
759: }
760: }
761: my ($ad,$msg)=&check_submission($response,$partid,$id,$tag,
762: $parstack,$safeeval);
763: if ($ad ne 'EXACT_ANS' && $ad ne 'APPROX_ANS') {
764: my $error;
765: if ($tag eq 'formularesponse') {
766: $error=&mt('Computer\'s answer is incorrect ("[_1]").',join(', ',@$response));
767: } else {
768: # answer failed check if it is sig figs that is failing
769: my ($ad,$msg)=&check_submission($response,$partid,$id,
770: $tag,$parstack,
771: $safeeval,1);
772: if ($sigline ne '') {
773: $error=&mt('Computer\'s answer is incorrect ("[_1]"). It is likely that the tolerance range [_2] or significant figures [_3] need to be adjusted.',join(', ',@$response),$tolline,$sigline);
774: } else {
775: $error=&mt('Computer\'s answer is incorrect ("[_1]"). It is likely that the tolerance range [_2] needs to be adjusted.',join(', ',@$response),$tolline);
776: }
777: }
778: if ($ad ne 'EXACT_ANS' && $ad ne 'APPROX_ANS') {
779: &Apache::lonxml::error($error);
780: } else {
781: &Apache::lonxml::warning($error);
782: }
783: }
784:
785: if (defined($unit) and ($unit ne '') and
786: $tag eq 'numericalresponse') {
787: if ($target eq 'answer') {
788: if ($env{'form.answer_output_mode'} eq 'tex') {
789: $result.=&Apache::response::answer_part($tag,
790: " Unit: $unit ");
791: } else {
792: $result.=&Apache::response::answer_part($tag,
793: "Unit: <b>$unit</b>");
794: }
795: } elsif ($target eq 'analyze') {
796: push (@{ $Apache::lonhomework::analyze{"$part_id.unit"} }, $unit);
797: }
798: }
799: if ($tag eq 'formularesponse' && $target eq 'answer') {
800: my $samples=&Apache::lonxml::get_param('samples',$parstack,$safeeval);
801: $result.=&Apache::response::answer_part($tag,$samples);
802: }
803: $result.=&Apache::response::next_answer($tag,$name);
804: }
805: if ($target eq 'answer') {
806: $result.=&Apache::response::answer_footer($tag);
807: }
808: }
809: if ($target eq 'grade' || $target eq 'web' || $target eq 'answer' ||
810: $target eq 'tex' || $target eq 'analyze') {
811: if (($tag eq 'formularesponse') && ($target eq 'analyze')) {
812: my $type = &Apache::lonnet::EXT('resource.'.$partid.'_'.$id.'.type');
813: if ($type eq 'exam') {
814: $increment = &Apache::response::repetition();
815: }
816: }
817: &Apache::lonxml::increment_counter($increment,"$partid.$id");
818: if ($target eq 'analyze') {
819: &Apache::lonhomework::set_bubble_lines();
820: }
821: }
822: &Apache::response::end_response();
823: return $result;
824: }
825:
826: sub format_prior_response_numerical {
827: my ($mode,$answer) = @_;
828: if (ref($answer)) {
829: my $result = '<table class="LC_prior_numerical"><tr>';
830: foreach my $element (@{ $answer }) {
831: $result.= '<td><span class="LC_prior_numerical">'.
832: &HTML::Entities::encode($element,'"<>&').'</span></td>';
833: }
834: $result.='</tr></table>';
835: return $result;
836: }
837: return '<span class="LC_prior_numerical">'.
838: &HTML::Entities::encode($answer,'"<>&').'</span>';
839:
840: }
841:
842: sub check_for_answer_errors {
843: my ($parstack,$safeeval) = @_;
844: &add_in_tag_answer($parstack,$safeeval);
845: my %counts;
846: foreach my $name (keys(%answer)) {
847: push(@{$counts{scalar(@{$answer{$name}{'answers'}})}},$name);
848: }
849: if (scalar(keys(%counts)) > 1) {
850: my $counts = join(' ',map {
851: my $count = $_;
852: &mt("Answers [_1] had [_2] components.",
853: '<tt>'.join(', ',@{$counts{$count}}).'</tt>',
854: $count);
855: } (sort(keys(%counts))));
856: &Apache::lonxml::error(&mt("All answers must have the same number of components. Varying numbers of answers were seen. ").$counts);
857: }
858: my $expected_number_of_inputs = (keys(%counts))[0];
859: if ( $expected_number_of_inputs > 0
860: && $expected_number_of_inputs != scalar(@Apache::inputtags::inputlist)) {
861: &Apache::lonxml::error(&mt("Expected [_1] input fields, but there were only [_2] seen.",
862: $expected_number_of_inputs,
863: scalar(@Apache::inputtags::inputlist)));
864: }
865: }
866:
867: sub get_table_sizes {
868: my ($number_of_bubbles,$rbubble_values)=@_;
869: my $scale=2; #mm for one digit
870: my $cell_width=0;
871: foreach my $member (@$rbubble_values) {
872: my $cell_width_real=0;
873: if ($member=~/(\+|-)?(\d*)\.?(\d*)\s*\$?\\times\s*10\^{(\+|-)?(\d+)}\$?/) {
874: $cell_width_real=(length($2)+length($3)+length($5)+7)*$scale;
875: } elsif ($member=~/(\d*)\.?(\d*)(E|e)(\+|-)?(\d*)/) {
876: $cell_width_real=(length($1)+length($2)+length($5)+9)*$scale;
877: } elsif ($member=~/(\d*)\.(\d*)/) {
878: $cell_width_real=(length($1)+length($2)+3)*$scale;
879: } else {
880: $cell_width_real=(length($member)+1)*$scale*0.9;
881: }
882: if ($cell_width_real>$cell_width) {$cell_width=$cell_width_real;}
883: }
884: $cell_width+=8;
885: my $textwidth;
886: if ($env{'form.textwidth'} ne '') {
887: $env{'form.textwidth'}=~/(\d*)\.?(\d*)/;
888: $textwidth=$1.'.'.$2;
889: } else {
890: $env{'form.textwidth'}=~/(\d+)\.?(\d*)/;
891: $textwidth=$1.'.'.$2;
892: }
893: my $bubbles_per_line=int($textwidth/$cell_width);
894: if ($bubbles_per_line > $number_of_bubbles) {
895: $bubbles_per_line=$number_of_bubbles;
896: } elsif (($bubbles_per_line > $number_of_bubbles/2)
897: && ($number_of_bubbles % 2==0)) {
898: $bubbles_per_line=$number_of_bubbles/2;
899: }
900: if ($bubbles_per_line < 1) {
901: $bubbles_per_line=1;
902: }
903: my $number_of_tables = int($number_of_bubbles/$bubbles_per_line);
904: my @table_range = ();
905: for (my $i=0;$i<$number_of_tables;$i++) {push @table_range,$bubbles_per_line;}
906: if ($number_of_bubbles % $bubbles_per_line) {
907: $number_of_tables++;
908: push @table_range,($number_of_bubbles % $bubbles_per_line);
909: }
910: $cell_width-=8;
911: $cell_width=$cell_width*3/4;
912: return ($cell_width,$number_of_tables,@table_range);
913: }
914:
915: sub format_number {
916: my ($number,$format,$target,$safeeval)=@_;
917: my $ans;
918: if ($format eq '') {
919: #What is the number? (integer,decimal,floating point)
920: if ($number=~/^(\d*\.?\d*)(E|e)[+\-]?(\d*)$/) {
921: $format = '3e';
922: } elsif ($number=~/^(\d*)\.(\d*)$/) {
923: $format = '4f';
924: } elsif ($number=~/^(\d*)$/) {
925: $format = 'd';
926: }
927: }
928: if (!$Apache::lonxml::default_homework_loaded) {
929: &Apache::lonxml::default_homework_load($safeeval);
930: }
931: $ans=&Apache::run::run("&prettyprint(q\0$number\0,q\0$format\0,q\0$target\0)",$safeeval);
932: return $ans;
933: }
934:
935: sub make_numerical_bubbles {
936: my ($part,$id,$target,$parstack,$safeeval) =@_;
937:
938: if (!%answer) {
939: &Apache::lonxml::error(&mt("No answers defined for response [_1] in part [_2] to make bubbles for.",$id,$part));
940: return ([],[],undef);
941: }
942:
943: my $number_of_bubbles =
944: &Apache::response::get_response_param($part.'_'.$id,'numbubbles',8);
945:
946: my ($format)=&Apache::lonxml::get_param_var('format',$parstack,$safeeval);
947: my $name = (exists($answer{$tag_internal_answer_name})
948: ? $tag_internal_answer_name
949: : (sort(keys(%answer)))[0]);
950:
951: if ( scalar(@{$answer{$name}{'answers'}}) > 1) {
952: &Apache::lonxml::error("Only answers with 1 component are supported in exam mode");
953: }
954: if (scalar(@{$answer{$name}{'answers'}[0]}) > 1) {
955: &Apache::lonxml::error("Vector answers are unsupported in exam mode.");
956: }
957:
958: my $answer = $answer{$name}{'answers'}[0][0];
959: my (@incorrect)=&Apache::lonxml::get_param_var('incorrect',$parstack,
960: $safeeval);
961: if ($#incorrect eq 0) { @incorrect=(split(/,/,$incorrect[0])); }
962:
963: my @bubble_values=();
964: my @alphabet=('A'..'Z');
965:
966: &Apache::lonxml::debug("answer is $answer incorrect is @incorrect");
967: my @oldseed=&Math::Random::random_get_seed();
968: if (@incorrect) {
969: &Apache::lonxml::debug("inside ".(scalar(@incorrect)+1 gt $number_of_bubbles));
970: if (defined($incorrect[0]) &&
971: scalar(@incorrect)+1 >= $number_of_bubbles) {
972: &Apache::lonxml::debug("inside ".(scalar(@incorrect)+1).":$number_of_bubbles");
973: &Apache::response::setrandomnumber();
974: my @rand_inc=&Math::Random::random_permutation(@incorrect);
975: @bubble_values=@rand_inc[0..($number_of_bubbles-2)];
976: @bubble_values=sort {$a <=> $b} (@bubble_values,$answer);
977: &Apache::lonxml::debug("Answer was :$answer: returning :".$#bubble_values.": which are :".join(':',@bubble_values));
978: &Math::Random::random_set_seed(@oldseed);
979:
980: my $correct;
981: for(my $i=0; $i<=$#bubble_values;$i++) {
982: if ($bubble_values[$i] eq $answer) {
983: $correct = $alphabet[$i];
984: last;
985: }
986: }
987:
988: if (defined($format) && $format ne '') {
989: my @bubble_display;
990: foreach my $value (@bubble_values) {
991: push(@bubble_display,
992: &format_number($value,$format,$target,$safeeval));
993: }
994: return (\@bubble_values,\@bubble_display,$correct);
995: } else {
996: return (\@bubble_values,\@bubble_values,$correct);
997: }
998: }
999: if (defined($incorrect[0]) &&
1000: scalar(@incorrect)+1 < $number_of_bubbles) {
1001: &Apache::lonxml::warning("Not enough incorrect answers were specified in the incorrect array, ignoring the specified incorrect answers and instead generating them (".join(',',@incorrect).").");
1002: }
1003: }
1004: my @factors = (1.13,1.17,1.25,1.33,1.45); #default values of factors
1005: my @powers = (1..$number_of_bubbles);
1006: &Apache::response::setrandomnumber();
1007: my $ind=&Math::Random::random_uniform_integer(1,0,$#powers);
1008: my $power = $powers[$ind];
1009: $ind=&Math::Random::random_uniform_integer(1,0,$#factors);
1010: my $factor = $factors[$ind];
1011: my @bubble_display;
1012: my $answerfactor=$answer;
1013: if ($answer==0) {
1014: $answerfactor=&Math::Random::random_uniform_integer(1,1,100)/
1015: &Math::Random::random_uniform_integer(1,1,10);
1016: }
1017: for ($ind=0;$ind<$number_of_bubbles;$ind++) {
1018: $bubble_values[$ind] = $answerfactor*($factor**($power-$powers[$#powers-$ind]));
1019: $bubble_display[$ind] = &format_number($bubble_values[$ind],
1020: $format,$target,$safeeval);
1021: }
1022: my $correct = $alphabet[$number_of_bubbles-$power];
1023: if ($answer==0) {
1024: $correct='A';
1025: $bubble_values[0]=0;
1026: $bubble_display[0] = &format_number($bubble_values[0],
1027: $format,$target,$safeeval);
1028: }
1029: &Math::Random::random_set_seed(@oldseed);
1030: return (\@bubble_values,\@bubble_display,$correct);
1031: }
1032:
1033: sub get_tolrange {
1034: my ($ans,$tol)=@_;
1035: my ($high,$low);
1036: if ($tol =~ /%$/) {
1037: chop($tol);
1038: my $change=$ans*($tol/100.0);
1039: $high=$ans+$change;
1040: $low=$ans-$change;
1041: } else {
1042: $high=$ans+$tol;
1043: $low=$ans-$tol;
1044: }
1045: return ($high,$low);
1046: }
1047:
1048: sub get_sigrange {
1049: my ($sig)=@_;
1050: #&Apache::lonxml::debug("Got a sig of :$sig:");
1051: my $courseid=$env{'request.course.id'};
1052: if ($env{'request.state'} ne 'construct'
1053: && lc($env{"course.$courseid.disablesigfigs"}) eq 'yes') {
1054: return (15,0);
1055: }
1056: my $sig_lbound;
1057: my $sig_ubound;
1058: if ($sig eq '') {
1059: $sig_lbound = 0; #SIG_LB_DEFAULT
1060: $sig_ubound =15; #SIG_UB_DEFAULT
1061: } else {
1062: ($sig_lbound,$sig_ubound) = split(/,/,$sig);
1063: if (!defined($sig_lbound)) {
1064: $sig_lbound = 0; #SIG_LB_DEFAULT
1065: $sig_ubound =15; #SIG_UB_DEFAULT
1066: }
1067: if (!defined($sig_ubound)) { $sig_ubound=$sig_lbound; }
1068: }
1069: if (($sig_ubound<$sig_lbound) ||
1070: ($sig_lbound > 15) ||
1071: ($sig =~/(\+|-)/ ) ) {
1072: my $errormsg=&mt("Invalid Significant figures detected")." ($sig)";
1073: if ($env{'request.state'} eq 'construct') {
1074: $errormsg.=
1075: &Apache::loncommon::help_open_topic('Significant_Figures');
1076: }
1077: &Apache::lonxml::error($errormsg);
1078: }
1079: return ($sig_ubound,$sig_lbound);
1080: }
1081:
1082: sub format_prior_response_string {
1083: my ($mode,$answer) =@_;
1084: return '<span class="LC_prior_string">'.
1085: &HTML::Entities::encode($answer,'"<>&').'</span>';
1086: }
1087:
1088: sub start_stringresponse {
1089: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
1090: my $result;
1091: my $id = &Apache::response::start_response($parstack,$safeeval);
1092: if ($target eq 'meta') {
1093: $result=&Apache::response::meta_package_write('stringresponse');
1094: } elsif ($target eq 'edit') {
1095: $result.=&Apache::edit::tag_start($target,$token);
1096: $result.=&Apache::edit::text_arg('Answer:','answer',$token);
1097: $result.=&Apache::edit::select_arg('Type:','type',
1098: [['cs','Case Sensitive'],['ci','Case Insensitive'],
1099: ['mc','Case Insensitive, Any Order'],
1100: ['re','Regular Expression']],$token);
1101: $result.=&Apache::edit::text_arg('String to display for answer:',
1102: 'answerdisplay',$token);
1103: $result.=&Apache::edit::end_row().&Apache::edit::start_spanning_row();
1104: } elsif ($target eq 'modified') {
1105: my $constructtag;
1106: $constructtag=&Apache::edit::get_new_args($token,$parstack,
1107: $safeeval,'answer',
1108: 'type','answerdisplay');
1109: if ($constructtag) {
1110: $result = &Apache::edit::rebuild_tag($token);
1111: $result.=&Apache::edit::handle_insert();
1112: }
1113: } elsif ($target eq 'web') {
1114: if ( &Apache::response::show_answer() ) {
1115: my $answer=
1116: &Apache::lonxml::get_param('answerdisplay',$parstack,$safeeval);
1117: if (!defined $answer || $answer eq '') {
1118: $answer=
1119: &Apache::lonxml::get_param('answer',$parstack,$safeeval);
1120: }
1121: $Apache::inputtags::answertxt{$id}=[$answer];
1122: }
1123: } elsif ($target eq 'answer' || $target eq 'grade') {
1124: &Apache::response::reset_params();
1125: }
1126: return $result;
1127: }
1128:
1129: sub end_stringresponse {
1130: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
1131:
1132: my $result = '';
1133: my $part=$Apache::inputtags::part;
1134: my $id=$Apache::inputtags::response[-1];
1135: my $answer=&Apache::lonxml::get_param('answer',$parstack,$safeeval);
1136: my $type=&Apache::lonxml::get_param('type',$parstack,$safeeval);
1137: my $answerdisplay=&Apache::lonxml::get_param('answerdisplay',$parstack,$safeeval);
1138: &Apache::lonxml::debug("current $answer ".$token->[2]);
1139: if (!$Apache::lonxml::default_homework_loaded) {
1140: &Apache::lonxml::default_homework_load($safeeval);
1141: }
1142: if ( $target eq 'grade' && &Apache::response::submitted() ) {
1143: &Apache::response::setup_params('stringresponse',$safeeval);
1144: $safeeval->share_from('capa',['&caparesponse_capa_check_answer']);
1145: if ($Apache::lonhomework::type eq 'exam' ||
1146: &Apache::response::submitted('scantron')) {
1147: &Apache::response::scored_response($part,$id);
1148:
1149: } else {
1150: my $response = &Apache::response::getresponse();
1151: if ( $response =~ /[^\s]/) {
1152: my %previous = &Apache::response::check_for_previous($response,
1153: $part,$id);
1154: &Apache::lonxml::debug("submitted a $response<br>\n");
1155: &Apache::lonxml::debug($$parstack[-1] . "\n<br>");
1156: $Apache::lonhomework::results{"resource.$part.$id.submission"}=
1157: $response;
1158: my ($ad,$msg);
1159: if ($type eq 're' ) {
1160: # if the RE wasn't in a var it likely got munged,
1161: # thus grab it from the var directly
1162: # my $testans=$token->[2]->{'answer'};
1163: # if ($testans !~ m/^\s*\$/) {
1164: # $answer=$token->[2]->{'answer'};
1165: # }
1166: ${$safeeval->varglob('LONCAPA::response')}=$response;
1167: $result = &Apache::run::run('if ($LONCAPA::response=~m'.$answer.') { return 1; } else { return 0; }',$safeeval);
1168: &Apache::lonxml::debug("current $response");
1169: &Apache::lonxml::debug("current $answer");
1170: $ad = ($result) ? 'APPROX_ANS' : 'INCORRECT';
1171: } else {
1172: my @args = ('type');
1173: my $args_ref = &setup_capa_args($safeeval,$parstack,
1174: \@args,$response);
1175:
1176: &add_in_tag_answer($parstack,$safeeval);
1177: my (@final_awards,@final_msgs,@names);
1178: foreach my $name (keys(%answer)) {
1179: &Apache::lonxml::debug(" doing $name with ".join(':',@{ $answer{$name}{'answers'} }));
1180: ${$safeeval->varglob('LONCAPA::CAPAresponse_answer')}=dclone($answer{$name});
1181: my ($result, @msgs)=&Apache::run::run("&caparesponse_check_list()",$safeeval);
1182: &Apache::lonxml::debug('msgs are'.join(':',@msgs));
1183: my ($awards)=split(/:/,$result);
1184: my (@awards) = split(/,/,$awards);
1185: ($ad,$msg) =
1186: &Apache::inputtags::finalizeawards(\@awards,\@msgs);
1187: push(@final_awards,$ad);
1188: push(@final_msgs,$msg);
1189: push(@names,$name);
1190: &Apache::lonxml::debug("\n<br>result:$result:$Apache::lonxml::curdepth<br>\n");
1191: }
1192: my ($ad, $msg, $name) =
1193: &Apache::inputtags::finalizeawards(\@final_awards,
1194: \@final_msgs,
1195: \@names,1);
1196: }
1197: if ($Apache::lonhomework::type eq 'survey' &&
1198: ($ad eq 'INCORRECT' || $ad eq 'APPROX_ANS' ||
1199: $ad eq 'EXACT_ANS')) {
1200: $ad='SUBMITTED';
1201: }
1202: &Apache::response::handle_previous(\%previous,$ad);
1203: $Apache::lonhomework::results{"resource.$part.$id.awarddetail"}=$ad;
1204: $Apache::lonhomework::results{"resource.$part.$id.awardmsg"}=$msg;
1205: }
1206: }
1207: } elsif ($target eq 'answer' || $target eq 'analyze') {
1208: &add_in_tag_answer($parstack,$safeeval);
1209: if ($target eq 'analyze') {
1210: push (@{ $Apache::lonhomework::analyze{"parts"} },"$part.$id");
1211: $Apache::lonhomework::analyze{"$part.$id.type"} = 'stringresponse';
1212: &Apache::response::check_if_computed($token,$parstack,$safeeval,
1213: 'answer');
1214: }
1215: &Apache::response::setup_params('stringresponse',$safeeval);
1216: if ($target eq 'answer') {
1217: $result.=&Apache::response::answer_header('stringresponse');
1218: }
1219: foreach my $name (keys(%answer)) {
1220: my @answers = @{ $answer{$name}{'answers'} };
1221: for (my $i=0;$i<=$#answers;$i++) {
1222: my $answer_part = $answers[$i];
1223: foreach my $element (@{$answer_part}) {
1224: if ($target eq 'answer') {
1225: $result.=&Apache::response::answer_part('stringresponse',
1226: $element);
1227: } elsif ($target eq 'analyze') {
1228: push (@{ $Apache::lonhomework::analyze{"$part.$id.answer"}{$name}[$i] },
1229: $element);
1230: }
1231: }
1232: if ($target eq 'answer' && $type eq 're') {
1233: $result.=&Apache::response::answer_part('stringresponse',
1234: $answerdisplay);
1235: }
1236: }
1237: }
1238: my $string='Case Insensitive';
1239: if ($type eq 'mc') {
1240: $string='Multiple Choice';
1241: } elsif ($type eq 'cs') {
1242: $string='Case Sensitive';
1243: } elsif ($type eq 'ci') {
1244: $string='Case Insensitive';
1245: } elsif ($type eq 're') {
1246: $string='Regular Expression';
1247: }
1248: if ($target eq 'answer') {
1249: if ($env{'form.answer_output_mode'} eq 'tex') {
1250: $result.=&Apache::response::answer_part('stringresponse',
1251: "$string");
1252: } else {
1253: $result.=&Apache::response::answer_part('stringresponse',
1254: "<b>$string</b>");
1255: }
1256: } elsif ($target eq 'analyze') {
1257: push (@{$Apache::lonhomework::analyze{"$part.$id.str_type"}},
1258: $type);
1259: }
1260: if ($target eq 'answer') {
1261: $result.=&Apache::response::answer_footer('stringresponse');
1262: }
1263: } elsif ($target eq 'edit') {
1264: $result.='</td></tr>'.&Apache::edit::end_table;
1265: } elsif ($target eq 'web' || $target eq 'tex') {
1266: &Apache::response::setup_prior_tries_hash(\&format_prior_response_string);
1267: }
1268: if ($target eq 'grade' || $target eq 'web' || $target eq 'answer' ||
1269: $target eq 'tex' || $target eq 'analyze') {
1270: &Apache::lonxml::increment_counter(&Apache::response::repetition(),
1271: "$part.$id");
1272: if ($target eq 'analyze') {
1273: &Apache::lonhomework::set_bubble_lines();
1274: }
1275: }
1276: &Apache::response::end_response;
1277: return $result;
1278: }
1279:
1280: sub start_formularesponse {
1281: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
1282: my $result;
1283: if ($target eq 'meta') {
1284: &Apache::response::start_response($parstack,$safeeval);
1285: $result=&Apache::response::meta_package_write('formularesponse');
1286: &Apache::response::end_response();
1287: } else {
1288: $result.=&start_numericalresponse(@_);
1289: }
1290: return $result;
1291: }
1292:
1293: sub end_formularesponse {
1294: return end_numericalresponse(@_);
1295: }
1296:
1297: 1;
1298: __END__
1299:
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>