1: # The LearningOnline Network with CAPA
2: # caparesponse definition
3: #
4: # $Id: caparesponse.pm,v 1.227.2.2 2008/09/13 02:46:59 raeburn Exp $
5: #
6: # Copyright Michigan State University Board of Trustees
7: #
8: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
9: #
10: # LON-CAPA is free software; you can redistribute it and/or modify
11: # it under the terms of the GNU General Public License as published by
12: # the Free Software Foundation; either version 2 of the License, or
13: # (at your option) any later version.
14: #
15: # LON-CAPA is distributed in the hope that it will be useful,
16: # but WITHOUT ANY WARRANTY; without even the implied warranty of
17: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18: # GNU General Public License for more details.
19: #
20: # You should have received a copy of the GNU General Public License
21: # along with LON-CAPA; if not, write to the Free Software
22: # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
23: #
24: # /home/httpd/html/adm/gpl.txt
25: #
26: # http://www.lon-capa.org/
27: #
28:
29: package Apache::caparesponse;
30: use strict;
31: use capa;
32: use Safe::Hole;
33: use Apache::lonmaxima();
34: use Apache::lonlocal;
35: use Apache::lonnet;
36: use Apache::response();
37: use Storable qw(dclone);
38:
39: BEGIN {
40: &Apache::lonxml::register('Apache::caparesponse',('numericalresponse','stringresponse','formularesponse'));
41: }
42:
43: my %answer;
44: my @answers;
45: sub get_answer { return %answer; };
46: sub push_answer{ push(@answers,dclone(\%answer)); undef(%answer) }
47: sub pop_answer { %answer = %{pop(@answers)}; };
48:
49: my $cur_name;
50: my $tag_internal_answer_name = 'INTERNAL';
51:
52: sub start_answer {
53: my ($target,$token,$tagstack,$parstack,$parser,$safeeval)=@_;
54: my $result;
55: $cur_name = &Apache::lonxml::get_param('name',$parstack,$safeeval);
56: if ($cur_name =~ /^\s*$/) { $cur_name = $Apache::lonxml::curdepth; }
57: my $type = &Apache::lonxml::get_param('type',$parstack,$safeeval);
58: if (!defined($type) && $tagstack->[-2] eq 'answergroup') {
59: $type = &Apache::lonxml::get_param('type',$parstack,$safeeval,-2);
60: }
61: if (!defined($type)) { $type = 'ordered' };
62: $answer{$cur_name}= { 'type' => $type,
63: 'answers' => [] };
64: if ($target eq 'edit') {
65: $result.=&Apache::edit::tag_start($target,$token);
66: $result.=&Apache::edit::text_arg('Name:','name',$token);
67: $result.=&Apache::edit::select_arg('Type:','type',
68: [['ordered', 'Ordered' ],
69: ['unordered','Unordered'],],
70: $token);
71: $result.=&Apache::edit::end_row().&Apache::edit::start_spanning_row();
72: } elsif ($target eq 'modified') {
73: my $constructtag = &Apache::edit::get_new_args($token,$parstack,
74: $safeeval,'name',
75: 'type');
76: if ($constructtag) {
77: $result = &Apache::edit::rebuild_tag($token);
78: $result.= &Apache::edit::handle_insert();
79: }
80: }
81: return $result;
82: }
83:
84: sub end_answer {
85: my ($target,$token,$tagstack,$parstack,$parser,$safeeval)=@_;
86: my $result;
87: if ($target eq 'edit') {
88: $result .= &Apache::edit::tag_end();
89: }
90:
91: undef($cur_name);
92: return $result;
93: }
94:
95: sub insert_answer {
96: return '
97: <answer>
98: <value></value>
99: </answer>';
100: }
101:
102: sub start_answergroup {
103: my ($target,$token,$tagstack,$parstack,$parser,$safeeval)=@_;
104: my $result;
105: if ($target eq 'edit') {
106: $result.=&Apache::edit::tag_start($target,$token);
107: $result.=&Apache::edit::select_arg('Type:','type',
108: [['ordered', 'Ordered' ],
109: ['unordered','Unordered'],],
110: $token);
111: $result.=&Apache::edit::end_row().&Apache::edit::start_spanning_row();
112: } elsif ($target eq 'modified') {
113: my $constructtag = &Apache::edit::get_new_args($token,$parstack,
114: $safeeval,'name',
115: 'type');
116: if ($constructtag) {
117: $result = &Apache::edit::rebuild_tag($token);
118: $result.= &Apache::edit::handle_insert();
119: }
120: }
121: return $result;
122: }
123:
124: sub end_answergroup {
125: my ($target,$token,$tagstack,$parstack,$parser,$safeeval)=@_;
126: my $result;
127: if ($target eq 'web') {
128: if ( &Apache::response::show_answer() ) {
129: my $partid = $Apache::inputtags::part;
130: my $id = $Apache::inputtags::response[-1];
131: &set_answertext($Apache::lonhomework::history{"resource.$partid.$id.answername"},
132: $target,$token,$tagstack,$parstack,$parser,
133: $safeeval,-2);
134: }
135: } elsif ($target eq 'edit') {
136: $result .= &Apache::edit::tag_end();
137: }
138: return $result;
139: }
140:
141: sub insert_answergroup {
142: return '
143: <answergroup>
144: <answer>
145: <value></value>
146: </answer>
147: </answergroup>';
148: }
149:
150: sub start_value {
151: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
152: my $result;
153: if ( $target eq 'web' || $target eq 'tex' ||
154: $target eq 'grade' || $target eq 'webgrade' ||
155: $target eq 'answer' || $target eq 'analyze' ) {
156: my $bodytext = &Apache::lonxml::get_all_text("/value",$parser,$style);
157: $bodytext = &Apache::run::evaluate($bodytext,$safeeval,
158: $$parstack[-1]);
159:
160: push(@{ $answer{$cur_name}{'answers'} },[$bodytext]);
161:
162: } elsif ($target eq 'edit') {
163: $result.=&Apache::edit::tag_start($target,$token);
164: my $bodytext = &Apache::lonxml::get_all_text("/value",$parser,$style);
165: $result.=&Apache::edit::editline($token->[1],$bodytext,undef,40).
166: &Apache::edit::end_row();
167: } elsif ($target eq 'modified') {
168: $result=$token->[4].&Apache::edit::modifiedfield('/value',$parser);
169: }
170: return $result;
171: }
172:
173: sub end_value {
174: my ($target,$token,$tagstack,$parstack,$parser,$safeeval)=@_;
175: my $result;
176: if ($target eq 'edit') {
177: $result = &Apache::edit::end_table();
178: }
179: return $result;
180: }
181:
182: sub insert_value {
183: return '
184: <value></value>';
185: }
186:
187: sub start_vector {
188: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
189: my $result;
190: if ( $target eq 'web' || $target eq 'tex' ||
191: $target eq 'grade' || $target eq 'webgrade' ||
192: $target eq 'answer' || $target eq 'analyze' ) {
193: my $bodytext = &Apache::lonxml::get_all_text("/vector",$parser,$style);
194: my @values = &Apache::run::run($bodytext,$safeeval,$$parstack[-1]);
195: if (@values == 1) {
196: @values = split(',',$values[0]);
197: }
198: push(@{ $answer{$cur_name}{'answers'} },\@values);
199: } elsif ($target eq 'edit') {
200: $result.=&Apache::edit::tag_start($target,$token);
201: my $bodytext = &Apache::lonxml::get_all_text("/vector",$parser,$style);
202: $result.=&Apache::edit::editline($token->[1],$bodytext,undef,40).
203: &Apache::edit::end_row();
204: } elsif ($target eq 'modified') {
205: $result=$token->[4].&Apache::edit::modifiedfield('/vector',$parser);
206: }
207: return $result;
208: }
209:
210: sub end_vector {
211: my ($target,$token,$tagstack,$parstack,$parser,$safeeval)=@_;
212: my $result;
213: if ($target eq 'edit') {
214: $result = &Apache::edit::end_table();
215: }
216: return $result;
217: }
218:
219: sub insert_vector {
220: return '
221: <value></value>';
222: }
223:
224: sub start_array {
225: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
226: my $result;
227: if ( $target eq 'web' || $target eq 'tex' ||
228: $target eq 'grade' || $target eq 'webgrade' ||
229: $target eq 'answer' || $target eq 'analyze' ) {
230: my $bodytext = &Apache::lonxml::get_all_text("/array",$parser,$style);
231: my @values = &Apache::run::evaluate($bodytext,$safeeval,
232: $$parstack[-1]);
233: push(@{ $answer{$cur_name}{'answers'} },@values);
234: }
235: return $result;
236: }
237:
238: sub end_array {
239: my ($target,$token,$tagstack,$parstack,$parser,$safeeval)=@_;
240: my $result;
241: return $result;
242: }
243:
244: sub start_unit {
245: my ($target,$token,$tagstack,$parstack,$parser,$safeeval)=@_;
246: my $result;
247: return $result;
248: }
249:
250: sub end_unit {
251: my ($target,$token,$tagstack,$parstack,$parser,$safeeval)=@_;
252: my $result;
253: return $result;
254: }
255:
256: sub start_numericalresponse {
257: my ($target,$token,$tagstack,$parstack,$parser,$safeeval)=@_;
258: &Apache::lonxml::register('Apache::caparesponse',
259: ('answer','answergroup','value','array','unit',
260: 'vector'));
261: push(@Apache::lonxml::namespace,'caparesponse');
262: my $id = &Apache::response::start_response($parstack,$safeeval);
263: my $result;
264: undef(%answer);
265: undef(%{$safeeval->varglob('LONCAPA::CAPAresponse_args')});
266: if ($target eq 'edit') {
267: $result.=&Apache::edit::tag_start($target,$token);
268: $result.=&Apache::edit::text_arg('Answer:','answer',$token);
269: if ($token->[1] eq 'numericalresponse') {
270: $result.=&Apache::edit::text_arg('Incorrect Answers:','incorrect',
271: $token).
272: &Apache::loncommon::help_open_topic('numerical_wrong_answers');
273: $result.=&Apache::edit::text_arg('Unit:','unit',$token,5).
274: &Apache::loncommon::help_open_topic('Physical_Units');
275: $result.=&Apache::edit::text_arg('Format:','format',$token,4).
276: &Apache::loncommon::help_open_topic('Numerical_Response_Format');
277: } elsif ($token->[1] eq 'formularesponse') {
278: $result.=&Apache::edit::text_arg('Sample Points:','samples',
279: $token,40).
280: &Apache::loncommon::help_open_topic('Formula_Response_Sampling');
281: }
282: $result.=&Apache::edit::end_row().&Apache::edit::start_spanning_row();
283: } elsif ($target eq 'modified') {
284: my $constructtag;
285: if ($token->[1] eq 'numericalresponse') {
286: $constructtag=&Apache::edit::get_new_args($token,$parstack,
287: $safeeval,'answer',
288: 'incorrect','unit',
289: 'format');
290: } elsif ($token->[1] eq 'formularesponse') {
291: $constructtag=&Apache::edit::get_new_args($token,$parstack,
292: $safeeval,'answer',
293: 'samples');
294: }
295: if ($constructtag) {
296: $result = &Apache::edit::rebuild_tag($token);
297: $result.=&Apache::edit::handle_insert();
298: }
299: } elsif ($target eq 'meta') {
300: $result=&Apache::response::meta_package_write('numericalresponse');
301: } elsif ($target eq 'answer' || $target eq 'grade') {
302: &Apache::response::reset_params();
303: } elsif ($target eq 'web') {
304: my $partid = $Apache::inputtags::part;
305: my $hideunit=&Apache::lonnet::EXT('resource.'.$partid.'_'.$id.'.turnoffunit');
306: &Apache::lonxml::debug("Got unit $hideunit for $partid $id");
307: #no way to enter units, with radio buttons
308: if (lc($hideunit) eq "yes") {
309: my $unit=&Apache::lonxml::get_param_var('unit',$parstack,
310: $safeeval);
311: if ($unit =~ /\S/) { $result.=" (in $unit) "; }
312: }
313: if (($token->[1] eq 'formularesponse') &&
314: ($Apache::inputtags::status['-1'] eq 'CAN_ANSWER')) {
315: $result.=&edit_formula_button($id,"HWVAL_$id");
316: }
317: if ( &Apache::response::show_answer() ) {
318: &set_answertext($tag_internal_answer_name,$target,$token,$tagstack,
319: $parstack,$parser,$safeeval,-1);
320: }
321: }
322: return $result;
323: }
324:
325: sub edit_formula_button {
326: my ($id,$field)=@_;
327: my $button=&mt('Edit Answer');
328: my $helplink=&Apache::loncommon::help_open_topic('Formula_Editor');
329: return(<<ENDFORMULABUTTON);
330: <script language="JavaScript">
331: function edit_${id}_${field} (textarea) {
332: thenumber = textarea;
333: thedata = document.forms['lonhomework'].elements[textarea].value;
334: newwin = window.open("/adm/dragmath/applet/MaximaPopup.html","","width=565,height=400,resizable");
335: }
336: </script>
337: <input type='button' value='$button' onclick="javascript:edit_${id}_${field}('${field}');void(0);" />$helplink
338: ENDFORMULABUTTON
339: }
340:
341: sub set_answertext {
342: my ($name,$target,$token,$tagstack,$parstack,$parser,$safeeval,
343: $response_level) = @_;
344: &add_in_tag_answer($parstack,$safeeval,$response_level);
345:
346: if ($name eq '' || !ref($answer{$name})) {
347: if (ref($answer{$tag_internal_answer_name})) {
348: $name = $tag_internal_answer_name;
349: } else {
350: $name = (sort(keys(%answer)))[0];
351: }
352: }
353: return if ($name eq '' || !ref($answer{$name}));
354:
355: my (@formats)=&Apache::lonxml::get_param_var('format',$parstack,
356: $safeeval,$response_level);
357: my $unit=&Apache::lonxml::get_param_var('unit',$parstack,$safeeval,
358: $response_level);
359:
360: &Apache::lonxml::debug("answer looks to be $name");
361: my @answertxt;
362: for (my $i=0; $i < scalar(@{$answer{$name}{'answers'}}); $i++) {
363: my $answertxt;
364: my $answer=$answer{$name}{'answers'}[$i];
365: foreach my $element (@$answer) {
366: if ( scalar(@$tagstack)
367: && $tagstack->[$response_level] ne 'numericalresponse') {
368: $answertxt.=$element.',';
369: } else {
370: my $format;
371: if ($#formats > 0) {
372: $format=$formats[$i];
373: } else {
374: $format=$formats[0];
375: }
376: if ($unit=~/\$/) { $format="\$".$format; $unit=~s/\$//g; }
377: if ($unit=~/\,/) { $format="\,".$format; $unit=~s/\,//g; }
378: my $formatted=&format_number($element,$format,$target,
379: $safeeval);
380: $answertxt.=' '.$formatted.',';
381: }
382:
383: }
384: chop($answertxt);
385: if ($target eq 'web') {
386: $answertxt.=" $unit ";
387: }
388:
389: push(@answertxt,$answertxt)
390: }
391:
392: my $id = $Apache::inputtags::response[-1];
393: $Apache::inputtags::answertxt{$id}=\@answertxt;
394: }
395:
396: sub setup_capa_args {
397: my ($safeeval,$parstack,$args,$response) = @_;
398: my $args_ref= \%{$safeeval->varglob('LONCAPA::CAPAresponse_args')};
399: undef(%{ $args_ref });
400:
401: foreach my $arg (@{$args}) {
402: $$args_ref{$arg}=
403: &Apache::lonxml::get_param($arg,$parstack,$safeeval);
404: }
405: foreach my $key (keys(%Apache::inputtags::params)) {
406: $$args_ref{$key}=$Apache::inputtags::params{$key};
407: }
408: &setup_capa_response($args_ref,$response);
409: return $args_ref;
410: }
411:
412: sub setup_capa_response {
413: my ($args_ref,$response) = @_;
414:
415: if (ref($response)) {
416: $$args_ref{'response'}=dclone($response);
417: } else {
418: $$args_ref{'response'}=dclone([$response]);
419: }
420: }
421:
422: sub check_submission {
423: my ($response,$partid,$id,$tag,$parstack,$safeeval,$ignore_sig)=@_;
424: my @args = ('type','tol','sig','format','unit','calc','samples');
425: my $args_ref = &setup_capa_args($safeeval,$parstack,\@args,$response);
426:
427: my $hideunit=
428: &Apache::lonnet::EXT('resource.'.$partid.'_'.$id.'.turnoffunit');
429: #no way to enter units, with radio buttons
430: if ($Apache::lonhomework::type eq 'exam' ||
431: lc($hideunit) eq "yes") {
432: delete($$args_ref{'unit'});
433: }
434: #sig fig don't make much sense either
435: if (($Apache::lonhomework::type eq 'exam' ||
436: &Apache::response::submitted('scantron') ||
437: $ignore_sig) &&
438: $tag eq 'numericalresponse') {
439: delete($$args_ref{'sig'});
440: }
441:
442: if ($tag eq 'formularesponse') {
443: if ($$args_ref{'samples'}) {
444: $$args_ref{'type'}='fml';
445: } else {
446: $$args_ref{'type'}='math';
447: }
448: } elsif ($tag eq 'numericalresponse') {
449: $$args_ref{'type'}='float';
450: } elsif ($tag eq 'stringresponse') {
451: if ($$args_ref{'type'} eq '') {
452: $$args_ref{'type'} = 'ci';
453: }
454: }
455:
456: &add_in_tag_answer($parstack,$safeeval);
457:
458: if (!%answer) {
459: &Apache::lonxml::error("No answers are defined");
460: }
461:
462: my (@final_awards,@final_msgs,@names);
463: foreach my $name (keys(%answer)) {
464: &Apache::lonxml::debug(" doing $name with ".join(':',@{ $answer{$name}{'answers'} }));
465:
466: ${$safeeval->varglob('LONCAPA::CAPAresponse_answer')}=dclone($answer{$name});
467: &setup_capa_response($args_ref,$response);
468: use Time::HiRes;
469: my $t0 = [Time::HiRes::gettimeofday()];
470: my ($result,@msgs) =
471: &Apache::run::run("&caparesponse_check_list()",$safeeval);
472: &Apache::lonxml::debug("checking $name $result with $response took ".&Time::HiRes::tv_interval($t0));
473: &Apache::lonxml::debug('msgs are '.join(':',@msgs));
474: my ($awards)=split(/:/,$result);
475: my @awards= split(/,/,$awards);
476: my ($ad, $msg) = &Apache::inputtags::finalizeawards(\@awards,\@msgs);
477: push(@final_awards,$ad);
478: push(@final_msgs,$msg);
479: push(@names,$name);
480: }
481: my ($ad, $msg, $name) = &Apache::inputtags::finalizeawards(\@final_awards,
482: \@final_msgs,
483: \@names,1);
484: &Apache::lonxml::debug(" name of picked award is $name from ".join(', ',@names));
485: return($ad,$msg, $name);
486: }
487:
488: sub add_in_tag_answer {
489: my ($parstack,$safeeval,$response_level) = @_;
490: my @answer=&Apache::lonxml::get_param_var('answer',$parstack,$safeeval,
491: $response_level);
492: &Apache::lonxml::debug('answer is'.join(':',@answer));
493: if (@answer && $answer[0] =~ /\S/) {
494: $answer{$tag_internal_answer_name}= {'type' => 'ordered',
495: 'answers' => [\@answer] };
496: }
497: }
498:
499: sub capa_formula_fix {
500: my ($expression)=@_;
501: return &Apache::response::implicit_multiplication($expression);
502: }
503:
504: sub end_numericalresponse {
505: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
506:
507: &Apache::lonxml::deregister('Apache::caparesponse',
508: ('answer','answergroup','value','array','unit',
509: 'vector'));
510: pop(@Apache::lonxml::namespace);
511:
512: my $increment=1;
513: my $result = '';
514: if (!$Apache::lonxml::default_homework_loaded) {
515: &Apache::lonxml::default_homework_load($safeeval);
516: }
517: my $partid = $Apache::inputtags::part;
518: my $id = $Apache::inputtags::response[-1];
519: my $tag;
520: my $safehole = new Safe::Hole;
521: $safeeval->share_from('capa',['&caparesponse_capa_check_answer']);
522:
523: if (scalar(@$tagstack)) { $tag=$$tagstack[-1]; }
524: if ( $target eq 'grade' && &Apache::response::submitted() ) {
525: &Apache::response::setup_params($tag,$safeeval);
526: if ($Apache::lonhomework::type eq 'exam' &&
527: (($tag eq 'formularesponse') || ($tag eq 'mathresponse'))) {
528: $increment=&Apache::response::scored_response($partid,$id);
529: } else {
530: my $response = &Apache::response::getresponse();
531: if ( $response =~ /[^\s]/) {
532: my %previous = &Apache::response::check_for_previous($response,$partid,$id);
533: &Apache::lonxml::debug("submitted a $response<br>\n");
534: &Apache::lonxml::debug($$parstack[-1] . "\n<br>");
535:
536: if ( &Apache::response::submitted('scantron')) {
537: &add_in_tag_answer($parstack,$safeeval);
538: my ($values,$display)=&make_numerical_bubbles($partid,$id,
539: $target,$parstack,$safeeval);
540: $response=$values->[$response];
541: }
542: $Apache::lonhomework::results{"resource.$partid.$id.submission"}=$response;
543: my ($ad,$msg,$name)=&check_submission($response,$partid,$id,
544: $tag,$parstack,
545: $safeeval);
546:
547: &Apache::lonxml::debug('ad is'.$ad);
548: if ($ad eq 'SIG_FAIL') {
549: my ($sig_u,$sig_l)=
550: &get_sigrange($Apache::inputtags::params{'sig'});
551: $msg=join(':',$msg,$sig_l,$sig_u);
552: &Apache::lonxml::debug("sigs bad $sig_u $sig_l ".
553: $Apache::inputtags::params{'sig'});
554: }
555: &Apache::lonxml::debug("\n<br>result:$result:$Apache::lonxml::curdepth<br>\n");
556: if ($Apache::lonhomework::type eq 'survey' &&
557: ($ad eq 'INCORRECT' || $ad eq 'APPROX_ANS' ||
558: $ad eq 'EXACT_ANS')) {
559: $ad='SUBMITTED';
560: }
561: &Apache::response::handle_previous(\%previous,$ad);
562: $Apache::lonhomework::results{"resource.$partid.$id.awarddetail"}=$ad;
563: $Apache::lonhomework::results{"resource.$partid.$id.awardmsg"}=$msg;
564: $Apache::lonhomework::results{"resource.$partid.$id.answername"}=$name;
565: $result='';
566: }
567: }
568: } elsif ($target eq 'web' || $target eq 'tex') {
569: &check_for_answer_errors($parstack,$safeeval);
570: my $award = $Apache::lonhomework::history{"resource.$Apache::inputtags::part.solved"};
571: my $status = $Apache::inputtags::status['-1'];
572: if ($Apache::lonhomework::type eq 'exam') {
573: # FIXME support multi dimensional numerical problems
574: # in exam bubbles
575: my ($bubble_values,$bubble_display)=
576: &make_numerical_bubbles($partid,$id,$target,$parstack,
577: $safeeval);
578: my $number_of_bubbles = scalar(@{ $bubble_values });
579: my $unit=&Apache::lonxml::get_param_var('unit',$parstack,
580: $safeeval);
581: my @alphabet=('A'..'Z');
582: if ($target eq 'web') {
583: if ($tag eq 'numericalresponse') {
584: if ($unit=~/\S/) {$result.=' (in '.$unit.')<br /><br />';}
585: $result.= '<table border="1"><tr>';
586: my $previous=$Apache::lonhomework::history{"resource.$Apache::inputtags::part.$id.submission"};
587: for (my $ind=0;$ind<$number_of_bubbles;$ind++) {
588: my $checked='';
589: if ($previous eq $bubble_values->[$ind]) {
590: $checked=" checked='on' ";
591: }
592: $result.='<td><input type="radio" name="HWVAL_'.$id.
593: '" value="'.$bubble_values->[$ind].'" '.$checked
594: .' /><b>'.$alphabet[$ind].'</b>: '.
595: $bubble_display->[$ind].'</td>';
596: }
597: $result.='</tr></table>';
598: }
599: } elsif ($target eq 'tex') {
600: if ((defined $unit) and ($unit=~/\S/) and ($Apache::lonhomework::type eq 'exam')) {
601: $result.=' \textit{(in} \verb|'.$unit.'|\textit{)} ';
602: }
603: if ($tag eq 'numericalresponse') {
604: my ($celllength,$number_of_tables,@table_range)=
605: &get_table_sizes($number_of_bubbles,$bubble_display);
606: my $j=0;
607: my $cou=0;
608: $result.='\vskip -1 mm \noindent \begin{enumerate}\item[\textbf{'.$Apache::lonxml::counter.'}.]';
609: for (my $i=0;$i<$number_of_tables;$i++) {
610: $result.='\vskip -1 mm \noindent \setlength{\tabcolsep}{2 mm}\begin{tabular}{';
611: for (my $ind=0;$ind<$table_range[$j];$ind++) {
612: $result.='p{3 mm}p{'.$celllength.' mm}';
613: }
614: $result.='}';
615: for (my $ind=$cou;$ind<$cou+$table_range[$j];$ind++) {
616: $result.='\hskip -4 mm {\small \textbf{'.$alphabet[$ind].'}}$\bigcirc$ & \hskip -3 mm {\small '.$bubble_display->[$ind].'} ';
617: if ($ind != $cou+$table_range[$j]-1) {$result.=' & ';}
618: }
619: $cou += $table_range[$j];
620: $j++;
621: $result.='\\\\\end{tabular}\vskip 0 mm ';
622: }
623: $result.='\end{enumerate}';
624: } else {
625: $increment = &Apache::response::repetition();
626: }
627: }
628: }
629: &Apache::response::setup_prior_tries_hash(\&format_prior_response_numerical);
630: } elsif ($target eq 'edit') {
631: $result.='</td></tr>'.&Apache::edit::end_table;
632: } elsif ($target eq 'answer' || $target eq 'analyze') {
633: my $part_id="$partid.$id";
634: if ($target eq 'analyze') {
635: push (@{ $Apache::lonhomework::analyze{"parts"} },$part_id);
636: $Apache::lonhomework::analyze{"$part_id.type"} = $tag;
637: my (@incorrect)=&Apache::lonxml::get_param_var('incorrect',$parstack,$safeeval);
638: if ($#incorrect eq 0) { @incorrect=(split(/,/,$incorrect[0])); }
639: push (@{ $Apache::lonhomework::analyze{"$part_id.incorrect"} }, @incorrect);
640: &Apache::response::check_if_computed($token,$parstack,
641: $safeeval,'answer');
642: }
643: if (scalar(@$tagstack)) {
644: &Apache::response::setup_params($tag,$safeeval);
645: }
646: &add_in_tag_answer($parstack,$safeeval);
647: my (@formats)=&Apache::lonxml::get_param_var('format',$parstack,$safeeval);
648:
649: my $unit=&Apache::lonxml::get_param_var('unit',$parstack,$safeeval);
650:
651: if ($target eq 'answer') {
652: $result.=&Apache::response::answer_header($tag,undef,
653: scalar(keys(%answer)));
654: if ($tag eq 'numericalresponse'
655: && $Apache::lonhomework::type eq 'exam') {
656: my ($bubble_values,undef,$correct) = &make_numerical_bubbles($partid,
657: $id,$target,$parstack,$safeeval);
658: $result.=&Apache::response::answer_part($tag,$correct);
659: }
660: }
661: foreach my $name (sort(keys(%answer))) {
662: my @answers = @{ $answer{$name}{'answers'} };
663: if ($target eq 'analyze') {
664: foreach my $info ('answer','ans_high','ans_low','format') {
665: $Apache::lonhomework::analyze{"$part_id.$info"}{$name}=[];
666: }
667: }
668: my ($sigline,$tolline);
669: if ($name ne $tag_internal_answer_name
670: || scalar(keys(%answer)) > 1) {
671: $result.=&Apache::response::answer_part($tag,$name);
672: }
673: for(my $i=0;$i<=$#answers;$i++) {
674: my $ans=$answers[$i];
675: my $fmt=$formats[0];
676: if (@formats && $#formats) {$fmt=$formats[$i];}
677: my ($sighigh,$siglow);
678: if ($Apache::inputtags::params{'sig'}) {
679: ($sighigh,$siglow)=&get_sigrange($Apache::inputtags::params{'sig'});
680: }
681: my @vector;
682: if (ref($ans)) {
683: @vector = @{ $ans };
684: } else {
685: @vector = ($ans);
686: }
687: my @all_answer_info;
688: foreach my $element (@vector) {
689: my ($high,$low);
690: if ($Apache::inputtags::params{'tol'}) {
691: ($high,$low)=&get_tolrange($element,$Apache::inputtags::params{'tol'});
692: }
693: if ($target eq 'answer') {
694: if ($fmt && $tag eq 'numericalresponse') {
695: $fmt=~s/e/E/g;
696: if ($unit=~/\$/) { $fmt="\$".$fmt; $unit=~s/\$//g; }
697: if ($unit=~/\,/) { $fmt="\,".$fmt; $unit=~s/\,//g; }
698: $element = &format_number($element,$fmt,$target,$safeeval);
699: #if ($high) {
700: # $high=&format_number($high,$fmt,$target,$safeeval);
701: # $low =&format_number($low,$fmt,$target,$safeeval);
702: #}
703: }
704: if ($high && $tag eq 'numericalresponse') {
705: $element.='; ['.$low.'; '.$high.']';
706: $tolline .= "[$low, $high]";
707: }
708: if (defined($sighigh) && $tag eq 'numericalresponse') {
709: if ($env{'form.answer_output_mode'} eq 'tex') {
710: $element.= "; Sig $siglow - $sighigh";
711: } else {
712: $element.= " Sig <i>$siglow - $sighigh</i>";
713: $sigline .= "[$siglow, $sighigh]";
714: }
715: }
716: push(@all_answer_info,$element);
717:
718: } elsif ($target eq 'analyze') {
719: push (@{ $Apache::lonhomework::analyze{"$part_id.answer"}{$name}[$i] }, $element);
720: if ($high) {
721: push (@{ $Apache::lonhomework::analyze{"$part_id.ans_high"}{$name}[$i] }, $high);
722: push (@{ $Apache::lonhomework::analyze{"$part_id.ans_low"}{$name}[$i] }, $low);
723: }
724: if ($fmt) {
725: push (@{ $Apache::lonhomework::analyze{"$part_id.format"}{$name}[$i] }, $fmt);
726: }
727: }
728: }
729: if ($target eq 'answer') {
730: $result.= &Apache::response::answer_part($tag,join('; ',@all_answer_info));
731: }
732: }
733:
734: my @fmt_ans;
735: for(my $i=0;$i<=$#answers;$i++) {
736: my $ans=$answers[$i];
737: my $fmt=$formats[0];
738: if (@formats && $#formats) {$fmt=$formats[$i];}
739: foreach my $element (@$ans) {
740: if ($fmt && $tag eq 'numericalresponse') {
741: $fmt=~s/e/E/g;
742: if ($unit=~/\$/) { $fmt="\$".$fmt; $unit=~s/\$//g; }
743: if ($unit=~/\,/) { $fmt="\,".$fmt; $unit=~s/\,//g; }
744: $element = &format_number($element,$fmt,$target,
745: $safeeval);
746: if ($fmt=~/\$/ && $unit!~/\$/) { $element=~s/\$//; }
747: }
748: }
749: push(@fmt_ans,join(',',@$ans));
750: }
751: my $response=\@fmt_ans;
752:
753: my $hideunit=&Apache::lonnet::EXT('resource.'.$partid.'_'.
754: $id.'.turnoffunit');
755: if ($unit ne '' &&
756: ! ($Apache::lonhomework::type eq 'exam' ||
757: lc($hideunit) eq "yes") ) {
758: my $cleanunit=$unit;
759: $cleanunit=~s/\$\,//g;
760: foreach my $ans (@fmt_ans) {
761: $ans.=" $cleanunit";
762: }
763: }
764: my ($ad,$msg)=&check_submission($response,$partid,$id,$tag,
765: $parstack,$safeeval);
766: if ($ad ne 'EXACT_ANS' && $ad ne 'APPROX_ANS') {
767: my $error;
768: if ($tag eq 'formularesponse') {
769: $error=&mt('Computer\'s answer is incorrect ("[_1]").',join(', ',@$response));
770: } else {
771: # answer failed check if it is sig figs that is failing
772: my ($ad,$msg)=&check_submission($response,$partid,$id,
773: $tag,$parstack,
774: $safeeval,1);
775: if ($sigline ne '') {
776: $error=&mt('Computer\'s answer is incorrect ("[_1]"). It is likely that the tolerance range [_2] or significant figures [_3] need to be adjusted.',join(', ',@$response),$tolline,$sigline);
777: } else {
778: $error=&mt('Computer\'s answer is incorrect ("[_1]"). It is likely that the tolerance range [_2] needs to be adjusted.',join(', ',@$response),$tolline);
779: }
780: }
781: if ($ad ne 'EXACT_ANS' && $ad ne 'APPROX_ANS') {
782: &Apache::lonxml::error($error);
783: } else {
784: &Apache::lonxml::warning($error);
785: }
786: }
787:
788: if (defined($unit) and ($unit ne '') and
789: $tag eq 'numericalresponse') {
790: if ($target eq 'answer') {
791: if ($env{'form.answer_output_mode'} eq 'tex') {
792: $result.=&Apache::response::answer_part($tag,
793: " Unit: $unit ");
794: } else {
795: $result.=&Apache::response::answer_part($tag,
796: "Unit: <b>$unit</b>");
797: }
798: } elsif ($target eq 'analyze') {
799: push (@{ $Apache::lonhomework::analyze{"$part_id.unit"} }, $unit);
800: }
801: }
802: if ($tag eq 'formularesponse' && $target eq 'answer') {
803: my $samples=&Apache::lonxml::get_param('samples',$parstack,$safeeval);
804: $result.=&Apache::response::answer_part($tag,$samples);
805: }
806: $result.=&Apache::response::next_answer($tag,$name);
807: }
808: if ($target eq 'answer') {
809: $result.=&Apache::response::answer_footer($tag);
810: }
811: }
812: if ($target eq 'grade' || $target eq 'web' || $target eq 'answer' ||
813: $target eq 'tex' || $target eq 'analyze') {
814: if (($tag eq 'formularesponse') && ($target eq 'analyze')) {
815: my $type = &Apache::lonnet::EXT('resource.'.$partid.'_'.$id.'.type');
816: if ($type eq 'exam') {
817: $increment = &Apache::response::repetition();
818: }
819: }
820: &Apache::lonxml::increment_counter($increment,"$partid.$id");
821: if ($target eq 'analyze') {
822: &Apache::lonhomework::set_bubble_lines();
823: }
824: }
825: &Apache::response::end_response();
826: return $result;
827: }
828:
829: sub format_prior_response_numerical {
830: my ($mode,$answer) = @_;
831: if (ref($answer)) {
832: my $result = '<table class="LC_prior_numerical"><tr>';
833: foreach my $element (@{ $answer }) {
834: $result.= '<td><span class="LC_prior_numerical">'.
835: &HTML::Entities::encode($element,'"<>&').'</span></td>';
836: }
837: $result.='</tr></table>';
838: return $result;
839: }
840: return '<span class="LC_prior_numerical">'.
841: &HTML::Entities::encode($answer,'"<>&').'</span>';
842:
843: }
844:
845: sub check_for_answer_errors {
846: my ($parstack,$safeeval) = @_;
847: &add_in_tag_answer($parstack,$safeeval);
848: my %counts;
849: foreach my $name (keys(%answer)) {
850: push(@{$counts{scalar(@{$answer{$name}{'answers'}})}},$name);
851: }
852: if (scalar(keys(%counts)) > 1) {
853: my $counts = join(' ',map {
854: my $count = $_;
855: &mt("Answers [_1] had [_2] components.",
856: '<tt>'.join(', ',@{$counts{$count}}).'</tt>',
857: $count);
858: } (sort(keys(%counts))));
859: &Apache::lonxml::error(&mt("All answers must have the same number of components. Varying numbers of answers were seen. ").$counts);
860: }
861: my $expected_number_of_inputs = (keys(%counts))[0];
862: if ( $expected_number_of_inputs > 0
863: && $expected_number_of_inputs != scalar(@Apache::inputtags::inputlist)) {
864: &Apache::lonxml::error(&mt("Expected [_1] input fields, but there were only [_2] seen.",
865: $expected_number_of_inputs,
866: scalar(@Apache::inputtags::inputlist)));
867: }
868: }
869:
870: sub get_table_sizes {
871: my ($number_of_bubbles,$rbubble_values)=@_;
872: my $scale=2; #mm for one digit
873: my $cell_width=0;
874: foreach my $member (@$rbubble_values) {
875: my $cell_width_real=0;
876: if ($member=~/(\+|-)?(\d*)\.?(\d*)\s*\$?\\times\s*10\^{(\+|-)?(\d+)}\$?/) {
877: $cell_width_real=(length($2)+length($3)+length($5)+7)*$scale;
878: } elsif ($member=~/(\d*)\.?(\d*)(E|e)(\+|-)?(\d*)/) {
879: $cell_width_real=(length($1)+length($2)+length($5)+9)*$scale;
880: } elsif ($member=~/(\d*)\.(\d*)/) {
881: $cell_width_real=(length($1)+length($2)+3)*$scale;
882: } else {
883: $cell_width_real=(length($member)+1)*$scale*0.9;
884: }
885: if ($cell_width_real>$cell_width) {$cell_width=$cell_width_real;}
886: }
887: $cell_width+=8;
888: my $textwidth;
889: if ($env{'form.textwidth'} ne '') {
890: $env{'form.textwidth'}=~/(\d*)\.?(\d*)/;
891: $textwidth=$1.'.'.$2;
892: } else {
893: $env{'form.textwidth'}=~/(\d+)\.?(\d*)/;
894: $textwidth=$1.'.'.$2;
895: }
896: my $bubbles_per_line=int($textwidth/$cell_width);
897: if ($bubbles_per_line > $number_of_bubbles) {
898: $bubbles_per_line=$number_of_bubbles;
899: } elsif (($bubbles_per_line > $number_of_bubbles/2)
900: && ($number_of_bubbles % 2==0)) {
901: $bubbles_per_line=$number_of_bubbles/2;
902: }
903: if ($bubbles_per_line < 1) {
904: $bubbles_per_line=1;
905: }
906: my $number_of_tables = int($number_of_bubbles/$bubbles_per_line);
907: my @table_range = ();
908: for (my $i=0;$i<$number_of_tables;$i++) {push @table_range,$bubbles_per_line;}
909: if ($number_of_bubbles % $bubbles_per_line) {
910: $number_of_tables++;
911: push @table_range,($number_of_bubbles % $bubbles_per_line);
912: }
913: $cell_width-=8;
914: $cell_width=$cell_width*3/4;
915: return ($cell_width,$number_of_tables,@table_range);
916: }
917:
918: sub format_number {
919: my ($number,$format,$target,$safeeval)=@_;
920: my $ans;
921: if ($format eq '') {
922: #What is the number? (integer,decimal,floating point)
923: if ($number=~/^(\d*\.?\d*)(E|e)[+\-]?(\d*)$/) {
924: $format = '3e';
925: } elsif ($number=~/^(\d*)\.(\d*)$/) {
926: $format = '4f';
927: } elsif ($number=~/^(\d*)$/) {
928: $format = 'd';
929: }
930: }
931: if (!$Apache::lonxml::default_homework_loaded) {
932: &Apache::lonxml::default_homework_load($safeeval);
933: }
934: $ans=&Apache::run::run("&prettyprint(q\0$number\0,q\0$format\0,q\0$target\0)",$safeeval);
935: return $ans;
936: }
937:
938: sub make_numerical_bubbles {
939: my ($part,$id,$target,$parstack,$safeeval) =@_;
940:
941: if (!%answer) {
942: &Apache::lonxml::error(&mt("No answers defined for response [_1] in part [_2] to make bubbles for.",$id,$part));
943: return ([],[],undef);
944: }
945:
946: my $number_of_bubbles =
947: &Apache::response::get_response_param($part.'_'.$id,'numbubbles',8);
948:
949: my ($format)=&Apache::lonxml::get_param_var('format',$parstack,$safeeval);
950: my $name = (exists($answer{$tag_internal_answer_name})
951: ? $tag_internal_answer_name
952: : (sort(keys(%answer)))[0]);
953:
954: if ( scalar(@{$answer{$name}{'answers'}}) > 1) {
955: &Apache::lonxml::error("Only answers with 1 component are supported in exam mode");
956: }
957: if (scalar(@{$answer{$name}{'answers'}[0]}) > 1) {
958: &Apache::lonxml::error("Vector answers are unsupported in exam mode.");
959: }
960:
961: my $answer = $answer{$name}{'answers'}[0][0];
962: my (@incorrect)=&Apache::lonxml::get_param_var('incorrect',$parstack,
963: $safeeval);
964: if ($#incorrect eq 0) { @incorrect=(split(/,/,$incorrect[0])); }
965:
966: my @bubble_values=();
967: my @alphabet=('A'..'Z');
968:
969: &Apache::lonxml::debug("answer is $answer incorrect is @incorrect");
970: my @oldseed=&Math::Random::random_get_seed();
971: if (@incorrect) {
972: &Apache::lonxml::debug("inside ".(scalar(@incorrect)+1 gt $number_of_bubbles));
973: if (defined($incorrect[0]) &&
974: scalar(@incorrect)+1 >= $number_of_bubbles) {
975: &Apache::lonxml::debug("inside ".(scalar(@incorrect)+1).":$number_of_bubbles");
976: &Apache::response::setrandomnumber();
977: my @rand_inc=&Math::Random::random_permutation(@incorrect);
978: @bubble_values=@rand_inc[0..($number_of_bubbles-2)];
979: @bubble_values=sort {$a <=> $b} (@bubble_values,$answer);
980: &Apache::lonxml::debug("Answer was :$answer: returning :".$#bubble_values.": which are :".join(':',@bubble_values));
981: &Math::Random::random_set_seed(@oldseed);
982:
983: my $correct;
984: for(my $i=0; $i<=$#bubble_values;$i++) {
985: if ($bubble_values[$i] eq $answer) {
986: $correct = $alphabet[$i];
987: last;
988: }
989: }
990:
991: if (defined($format) && $format ne '') {
992: my @bubble_display;
993: foreach my $value (@bubble_values) {
994: push(@bubble_display,
995: &format_number($value,$format,$target,$safeeval));
996: }
997: return (\@bubble_values,\@bubble_display,$correct);
998: } else {
999: return (\@bubble_values,\@bubble_values,$correct);
1000: }
1001: }
1002: if (defined($incorrect[0]) &&
1003: scalar(@incorrect)+1 < $number_of_bubbles) {
1004: &Apache::lonxml::warning("Not enough incorrect answers were specified in the incorrect array, ignoring the specified incorrect answers and instead generating them (".join(',',@incorrect).").");
1005: }
1006: }
1007: my @factors = (1.13,1.17,1.25,1.33,1.45); #default values of factors
1008: my @powers = (1..$number_of_bubbles);
1009: &Apache::response::setrandomnumber();
1010: my $ind=&Math::Random::random_uniform_integer(1,0,$#powers);
1011: my $power = $powers[$ind];
1012: $ind=&Math::Random::random_uniform_integer(1,0,$#factors);
1013: my $factor = $factors[$ind];
1014: my @bubble_display;
1015: my $answerfactor=$answer;
1016: if ($answer==0) {
1017: $answerfactor=&Math::Random::random_uniform_integer(1,1,100)/
1018: &Math::Random::random_uniform_integer(1,1,10);
1019: }
1020: for ($ind=0;$ind<$number_of_bubbles;$ind++) {
1021: $bubble_values[$ind] = $answerfactor*($factor**($power-$powers[$#powers-$ind]));
1022: $bubble_display[$ind] = &format_number($bubble_values[$ind],
1023: $format,$target,$safeeval);
1024: }
1025: my $correct = $alphabet[$number_of_bubbles-$power];
1026: if ($answer==0) {
1027: $correct='A';
1028: $bubble_values[0]=0;
1029: $bubble_display[0] = &format_number($bubble_values[0],
1030: $format,$target,$safeeval);
1031: }
1032: &Math::Random::random_set_seed(@oldseed);
1033: return (\@bubble_values,\@bubble_display,$correct);
1034: }
1035:
1036: sub get_tolrange {
1037: my ($ans,$tol)=@_;
1038: my ($high,$low);
1039: if ($tol =~ /%$/) {
1040: chop($tol);
1041: my $change=$ans*($tol/100.0);
1042: $high=$ans+$change;
1043: $low=$ans-$change;
1044: } else {
1045: $high=$ans+$tol;
1046: $low=$ans-$tol;
1047: }
1048: return ($high,$low);
1049: }
1050:
1051: sub get_sigrange {
1052: my ($sig)=@_;
1053: #&Apache::lonxml::debug("Got a sig of :$sig:");
1054: my $courseid=$env{'request.course.id'};
1055: if ($env{'request.state'} ne 'construct'
1056: && lc($env{"course.$courseid.disablesigfigs"}) eq 'yes') {
1057: return (15,0);
1058: }
1059: my $sig_lbound;
1060: my $sig_ubound;
1061: if ($sig eq '') {
1062: $sig_lbound = 0; #SIG_LB_DEFAULT
1063: $sig_ubound =15; #SIG_UB_DEFAULT
1064: } else {
1065: ($sig_lbound,$sig_ubound) = split(/,/,$sig);
1066: if (!defined($sig_lbound)) {
1067: $sig_lbound = 0; #SIG_LB_DEFAULT
1068: $sig_ubound =15; #SIG_UB_DEFAULT
1069: }
1070: if (!defined($sig_ubound)) { $sig_ubound=$sig_lbound; }
1071: }
1072: if (($sig_ubound<$sig_lbound) ||
1073: ($sig_lbound > 15) ||
1074: ($sig =~/(\+|-)/ ) ) {
1075: my $errormsg=&mt("Invalid Significant figures detected")." ($sig)";
1076: if ($env{'request.state'} eq 'construct') {
1077: $errormsg.=
1078: &Apache::loncommon::help_open_topic('Significant_Figures');
1079: }
1080: &Apache::lonxml::error($errormsg);
1081: }
1082: return ($sig_ubound,$sig_lbound);
1083: }
1084:
1085: sub format_prior_response_string {
1086: my ($mode,$answer) =@_;
1087: return '<span class="LC_prior_string">'.
1088: &HTML::Entities::encode($answer,'"<>&').'</span>';
1089: }
1090:
1091: sub start_stringresponse {
1092: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
1093: my $result;
1094: my $id = &Apache::response::start_response($parstack,$safeeval);
1095: if ($target eq 'meta') {
1096: $result=&Apache::response::meta_package_write('stringresponse');
1097: } elsif ($target eq 'edit') {
1098: $result.=&Apache::edit::tag_start($target,$token);
1099: $result.=&Apache::edit::text_arg('Answer:','answer',$token);
1100: $result.=&Apache::edit::select_arg('Type:','type',
1101: [['cs','Case Sensitive'],['ci','Case Insensitive'],
1102: ['mc','Case Insensitive, Any Order'],
1103: ['re','Regular Expression']],$token);
1104: $result.=&Apache::edit::text_arg('String to display for answer:',
1105: 'answerdisplay',$token);
1106: $result.=&Apache::edit::end_row().&Apache::edit::start_spanning_row();
1107: } elsif ($target eq 'modified') {
1108: my $constructtag;
1109: $constructtag=&Apache::edit::get_new_args($token,$parstack,
1110: $safeeval,'answer',
1111: 'type','answerdisplay');
1112: if ($constructtag) {
1113: $result = &Apache::edit::rebuild_tag($token);
1114: $result.=&Apache::edit::handle_insert();
1115: }
1116: } elsif ($target eq 'web') {
1117: if ( &Apache::response::show_answer() ) {
1118: my $answer=
1119: &Apache::lonxml::get_param('answerdisplay',$parstack,$safeeval);
1120: if (!defined $answer || $answer eq '') {
1121: $answer=
1122: &Apache::lonxml::get_param('answer',$parstack,$safeeval);
1123: }
1124: $Apache::inputtags::answertxt{$id}=[$answer];
1125: }
1126: } elsif ($target eq 'answer' || $target eq 'grade') {
1127: &Apache::response::reset_params();
1128: }
1129: return $result;
1130: }
1131:
1132: sub end_stringresponse {
1133: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
1134:
1135: my $result = '';
1136: my $part=$Apache::inputtags::part;
1137: my $id=$Apache::inputtags::response[-1];
1138: my $answer=&Apache::lonxml::get_param('answer',$parstack,$safeeval);
1139: my $type=&Apache::lonxml::get_param('type',$parstack,$safeeval);
1140: my $answerdisplay=&Apache::lonxml::get_param('answerdisplay',$parstack,$safeeval);
1141: &Apache::lonxml::debug("current $answer ".$token->[2]);
1142: if (!$Apache::lonxml::default_homework_loaded) {
1143: &Apache::lonxml::default_homework_load($safeeval);
1144: }
1145: if ( $target eq 'grade' && &Apache::response::submitted() ) {
1146: &Apache::response::setup_params('stringresponse',$safeeval);
1147: $safeeval->share_from('capa',['&caparesponse_capa_check_answer']);
1148: if ($Apache::lonhomework::type eq 'exam' ||
1149: &Apache::response::submitted('scantron')) {
1150: &Apache::response::scored_response($part,$id);
1151:
1152: } else {
1153: my $response = &Apache::response::getresponse();
1154: if ( $response =~ /[^\s]/) {
1155: my %previous = &Apache::response::check_for_previous($response,
1156: $part,$id);
1157: &Apache::lonxml::debug("submitted a $response<br>\n");
1158: &Apache::lonxml::debug($$parstack[-1] . "\n<br>");
1159: $Apache::lonhomework::results{"resource.$part.$id.submission"}=
1160: $response;
1161: my ($ad,$msg);
1162: if ($type eq 're' ) {
1163: # if the RE wasn't in a var it likely got munged,
1164: # thus grab it from the var directly
1165: # my $testans=$token->[2]->{'answer'};
1166: # if ($testans !~ m/^\s*\$/) {
1167: # $answer=$token->[2]->{'answer'};
1168: # }
1169: ${$safeeval->varglob('LONCAPA::response')}=$response;
1170: $result = &Apache::run::run('if ($LONCAPA::response=~m'.$answer.') { return 1; } else { return 0; }',$safeeval);
1171: &Apache::lonxml::debug("current $response");
1172: &Apache::lonxml::debug("current $answer");
1173: $ad = ($result) ? 'APPROX_ANS' : 'INCORRECT';
1174: } else {
1175: my @args = ('type');
1176: my $args_ref = &setup_capa_args($safeeval,$parstack,
1177: \@args,$response);
1178: if ($$args_ref{'type'} eq '') {
1179: $$args_ref{'type'} = 'ci';
1180: }
1181: &add_in_tag_answer($parstack,$safeeval);
1182: my (@final_awards,@final_msgs,@names);
1183: foreach my $name (keys(%answer)) {
1184: &Apache::lonxml::debug(" doing $name with ".join(':',@{ $answer{$name}{'answers'} }));
1185: ${$safeeval->varglob('LONCAPA::CAPAresponse_answer')}=dclone($answer{$name});
1186: my ($result, @msgs)=&Apache::run::run("&caparesponse_check_list()",$safeeval);
1187: &Apache::lonxml::debug('msgs are'.join(':',@msgs));
1188: my ($awards)=split(/:/,$result);
1189: my (@awards) = split(/,/,$awards);
1190: ($ad,$msg) =
1191: &Apache::inputtags::finalizeawards(\@awards,\@msgs);
1192: push(@final_awards,$ad);
1193: push(@final_msgs,$msg);
1194: push(@names,$name);
1195: &Apache::lonxml::debug("\n<br>result:$result:$Apache::lonxml::curdepth<br>\n");
1196: }
1197: my ($ad, $msg, $name) =
1198: &Apache::inputtags::finalizeawards(\@final_awards,
1199: \@final_msgs,
1200: \@names,1);
1201: }
1202: if ($Apache::lonhomework::type eq 'survey' &&
1203: ($ad eq 'INCORRECT' || $ad eq 'APPROX_ANS' ||
1204: $ad eq 'EXACT_ANS')) {
1205: $ad='SUBMITTED';
1206: }
1207: &Apache::response::handle_previous(\%previous,$ad);
1208: $Apache::lonhomework::results{"resource.$part.$id.awarddetail"}=$ad;
1209: $Apache::lonhomework::results{"resource.$part.$id.awardmsg"}=$msg;
1210: }
1211: }
1212: } elsif ($target eq 'answer' || $target eq 'analyze') {
1213: &add_in_tag_answer($parstack,$safeeval);
1214: if ($target eq 'analyze') {
1215: push (@{ $Apache::lonhomework::analyze{"parts"} },"$part.$id");
1216: $Apache::lonhomework::analyze{"$part.$id.type"} = 'stringresponse';
1217: &Apache::response::check_if_computed($token,$parstack,$safeeval,
1218: 'answer');
1219: }
1220: &Apache::response::setup_params('stringresponse',$safeeval);
1221: if ($target eq 'answer') {
1222: $result.=&Apache::response::answer_header('stringresponse');
1223: }
1224: foreach my $name (keys(%answer)) {
1225: my @answers = @{ $answer{$name}{'answers'} };
1226: for (my $i=0;$i<=$#answers;$i++) {
1227: my $answer_part = $answers[$i];
1228: foreach my $element (@{$answer_part}) {
1229: if ($target eq 'answer') {
1230: $result.=&Apache::response::answer_part('stringresponse',
1231: $element);
1232: } elsif ($target eq 'analyze') {
1233: push (@{ $Apache::lonhomework::analyze{"$part.$id.answer"}{$name}[$i] },
1234: $element);
1235: }
1236: }
1237: if ($target eq 'answer' && $type eq 're') {
1238: $result.=&Apache::response::answer_part('stringresponse',
1239: $answerdisplay);
1240: }
1241: }
1242: }
1243: my $string='Case Insensitive';
1244: if ($type eq 'mc') {
1245: $string='Multiple Choice';
1246: } elsif ($type eq 'cs') {
1247: $string='Case Sensitive';
1248: } elsif ($type eq 'ci') {
1249: $string='Case Insensitive';
1250: } elsif ($type eq 're') {
1251: $string='Regular Expression';
1252: }
1253: if ($target eq 'answer') {
1254: if ($env{'form.answer_output_mode'} eq 'tex') {
1255: $result.=&Apache::response::answer_part('stringresponse',
1256: "$string");
1257: } else {
1258: $result.=&Apache::response::answer_part('stringresponse',
1259: "<b>$string</b>");
1260: }
1261: } elsif ($target eq 'analyze') {
1262: push (@{$Apache::lonhomework::analyze{"$part.$id.str_type"}},
1263: $type);
1264: }
1265: if ($target eq 'answer') {
1266: $result.=&Apache::response::answer_footer('stringresponse');
1267: }
1268: } elsif ($target eq 'edit') {
1269: $result.='</td></tr>'.&Apache::edit::end_table;
1270: } elsif ($target eq 'web' || $target eq 'tex') {
1271: &Apache::response::setup_prior_tries_hash(\&format_prior_response_string);
1272: }
1273: if ($target eq 'grade' || $target eq 'web' || $target eq 'answer' ||
1274: $target eq 'tex' || $target eq 'analyze') {
1275: &Apache::lonxml::increment_counter(&Apache::response::repetition(),
1276: "$part.$id");
1277: if ($target eq 'analyze') {
1278: &Apache::lonhomework::set_bubble_lines();
1279: }
1280: }
1281: &Apache::response::end_response;
1282: return $result;
1283: }
1284:
1285: sub start_formularesponse {
1286: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
1287: my $result;
1288: if ($target eq 'meta') {
1289: &Apache::response::start_response($parstack,$safeeval);
1290: $result=&Apache::response::meta_package_write('formularesponse');
1291: &Apache::response::end_response();
1292: } else {
1293: $result.=&start_numericalresponse(@_);
1294: }
1295: return $result;
1296: }
1297:
1298: sub end_formularesponse {
1299: return end_numericalresponse(@_);
1300: }
1301:
1302: 1;
1303: __END__
1304:
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>