Return to essayresponse.pm CVS log

Up to [LON-CAPA] / loncom / homework

- corrected some errors in changes

- end_*response routines should never call Apache::response::start_response
- start_*response needs tow write its packages out in meta mode
- ids are available in the @Apache::inputtags::response global

# The LearningOnline Network with CAPA
# essay (ungraded) style responses
#
# $Id: essayresponse.pm,v 1.14 2002/08/01 19:16:45 albertel Exp $
#
# Copyright Michigan State University Board of Trustees
#
# This file is part of the LearningOnline Network with CAPA (LON-CAPA).
#
# LON-CAPA is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# LON-CAPA is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with LON-CAPA; if not, write to the Free Software
# Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
#
# /home/httpd/html/adm/gpl.txt
#
# http://www.lon-capa.org/
#
# 4/3 Guy
# July, 2002, H. K. Ng
#
package Apache::essayresponse;
use strict;

BEGIN {
    &Apache::lonxml::register('Apache::essayresponse',('essayresponse'));
}

sub start_essayresponse {
    my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
    my $result;
    my $id = &Apache::response::start_response($parstack,$safeeval);
    if ($target eq 'meta') {
	$result=&Apache::response::meta_package_write('essayresponse');
    } elsif ($target eq 'web') {
	my $part= $Apache::inputtags::part;

	my $ncol= &Apache::lonnet::EXT("resource.$part".'_'."$id.maxcollaborators");
	my $coll= &HTML::Entities::encode($Apache::lonhomework::history{"resource.$part.$id.collaborators"});
	$result='<br /><table border="1">';
	if ($ncol > 0) {
	    $result .='<tr><td>'.
		'Collaborators: <input type="text" size="70" max="80" name="HWCOL'.
		$part.'_'.$id.'" value="'.$coll.'" /><br />'.
		'(Enter maximum '.$ncol.' collaborators using username or username@domain, e.g. '.
		'smithje or smithje@'.$ENV{'user.domain'}.'.)<br />';
	    $result .= &check_collaborators($ncol,$coll) if ($coll =~ /\w+/);
	    $result .='</td></tr>';
	}
	$result.='<tr><td>'.
	    '<input type="radio" name="HWDRAFT'.$part.'_'.$id.'" value="yes" checked>'.
	    ' Submit text below as answer to receive credit <br />'.
	    '<input type="radio" name="HWDRAFT'.$part.'_'.$id.'" value="no">'.
	    ' Save text below as a draft answer (not submitting it for credit yet) '.
	    '</td></tr></table>';
    }
    return $result;
}

sub end_essayresponse {
    my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
    my $part          = $Apache::inputtags::part;
    my $id            = $Apache::inputtags::response[-1];
    if ( $target eq 'grade' ) {
	my $collaborators = $ENV{'form.HWCOL'.$part.'_'.$id};	
	if ($collaborators =~ /[^\s]/) {
	    my $previous_list= &HTML::Entities::encode($Apache::lonhomework::history{"resource.$part.$id.collaborators"});
	    $Apache::lonhomework::results{"resource.$part.$id.collaborators"}=$collaborators
		if ($collaborators ne $previous_list);
	}
	if ( defined $ENV{'form.submitted'}) {
	    my $response      = $ENV{'form.HWVAL'.$id};
	    if ( $response =~ /[^\s]/) {
		my $award;
		if ($ENV{'form.HWDRAFT'.$part.'_'.$id} eq 'yes') {
		    $award='SUBMITTED';
		} else {
		    $award='DRAFT';
		}
		$Apache::lonhomework::results{"resource.$part.$id.submission"}=$response;
		$Apache::lonhomework::results{"resource.$part.$id.awarddetail"}=$award;
		my %previous=&Apache::response::check_for_previous($response,$part,$id);
		&Apache::response::handle_previous(\%previous,$award);
	    }
	}
    }

    &Apache::response::end_response;
    return '';
}

sub check_collaborators {
    my ($ncol,$coll) = @_;
    my %classlist=&Apache::lonnet::dump('classlist',
					$ENV{'course.'.$ENV{'request.course.id'}.'.domain'},
					$ENV{'course.'.$ENV{'request.course.id'}.'.num'});
    my (@badcollaborators,$result);
    my (@collaborators) = split(/\,?\s+/,$coll);
    foreach (@collaborators) {
	my $collaborator = $_;
	if (/@/) {
	    $collaborator =~ s/@/:/;
	} else {
	    $collaborator = $_.':'.$ENV{'user.domain'};
	}
	push @badcollaborators, $_ if (!grep /^$collaborator/i,keys %classlist);
    }
    
    if (scalar(@badcollaborators)) {
	$result = '<table border="0"><tr bgcolor="#ffbbbb"><td> The following user'.
	    (scalar(@badcollaborators) > 1 ? 's are' : ' is').' invalid: '.
	    join(', ',@badcollaborators).'. Please correct.</td></tr></table>';
    }
    my $toomany = scalar(@collaborators) - $ncol;
    if ($toomany > 0) {
	$result .= '<table border="0"><tr bgcolor="#ffbbbb"><td>'.
	    'You have too many collaborators. Please remove '.$toomany.' collaborator'.
	    ($toomany > 1 ? 's' :'').'.</td></tr></table>';
    }
    return $result;
}

1;
__END__