Return to hint.pm CVS log

Up to [LON-CAPA] / loncom / homework

- Fixes Bug#2820 (internal vars were clashing with user vars)
- Cleans up the way data is put into safe space, less escaping, names scaping etc issues
- <stringhint> supports re mode now.

# The LearningOnline Network with CAPA 
# implements the tags that control the hints
#
# $Id: hint.pm,v 1.51 2004/03/16 19:47:47 albertel Exp $
#
# Copyright Michigan State University Board of Trustees
#
# This file is part of the LearningOnline Network with CAPA (LON-CAPA).
#
# LON-CAPA me&aree software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# LON-CAPA is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with LON-CAPA; if not, write to the Free Software
# Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
#
# /home/httpd/html/adm/gpl.txt
#
# http://www.lon-capa.org/
#

package Apache::hinttags; 

use strict;
use Apache::lonnet;
use capa;

BEGIN {
    &Apache::lonxml::register('Apache::hinttags',('hintgroup','hintpart','numericalhint','stringhint','formulahint','optionhint','radiobuttonhint'));
}


@Apache::hint::which=();
sub start_hintgroup {
    my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
    my $skiptoend='0';
    my $result;

    if ($target eq 'web') {
	my $id=$Apache::inputtags::part;
	my $numtries=$Apache::lonhomework::history{"resource.$id.tries"};
	if ( $numtries eq '') { $numtries = 0; }
	my $hinttries=&Apache::lonnet::EXT("resource.$id.hinttries");
	if ($ENV{'request.state'} eq 'construct' &&
	    defined($Apache::inputtags::params{'hinttries'})) {
	    $hinttries=$Apache::inputtags::params{'hinttries'};
	}

	if ( $hinttries eq '') { $hinttries = 1; }
	&Apache::lonxml::debug("found :$id:$numtries:$hinttries:");
	my $gradestatus=$Apache::lonhomework::history{"resource.$id.solved"};
	if ( $numtries < $hinttries || $gradestatus =~ /^correct/) {
	    &Apache::lonxml::get_all_text("/hintgroup",$parser);
	}
	&Apache::lonxml::startredirection;
    } elsif ($target eq 'tex') {
	$result .= '\keephidden{';
    }
    @Apache::hint::which=();
    return $result;
}

sub end_hintgroup {
    my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
    my $result;

    if ($target eq 'web') {
	my $id=$Apache::inputtags::part;
	my $numtries=$Apache::lonhomework::history{"resource.$id.tries"};
	if ( $numtries eq '') { $numtries = 0; }
	my $hinttries=&Apache::lonnet::EXT("resource.$id.hinttries");
	if ( $hinttries eq '') { $hinttries = 1; }
	&Apache::lonxml::debug("found :$id:$numtries:$hinttries:");
	my $hinttext=&Apache::lonxml::endredirection;
	if ($Apache::lonhomework::type ne 'exam' &&
	    $numtries >= $hinttries && $hinttext =~/\S/) {
	    $result='<table bgcolor="#dddddd"><tr><td>'.
		$hinttext.'</td></tr></table>';
	}
    } elsif ($target eq 'edit') {
	$result.=&Apache::edit::end_table();
    } elsif ($target eq 'tex') {
	$result .= '}';
    }
    @Apache::hint::which=();
    return $result;
}

sub start_numericalhint {
    my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
    #do everything in end, so intervening <responseparams> work
    &Apache::response::start_hintresponse($parstack,$safeeval);
    my $result;
    if ($target eq 'edit') {
	$result.=&Apache::edit::tag_start($target,$token);
	$result.=&Apache::edit::text_arg('Name:','name',$token);
	$result.=&Apache::edit::text_arg('Answer:','answer',$token);
	if ($token->[1] eq 'numericalhint') {
	    $result.=&Apache::edit::text_arg('Unit:','unit',$token,5).
		&Apache::loncommon::help_open_topic('Physical_Units');
	    $result.=&Apache::edit::text_arg('Format:','format',$token,4).
		&Apache::loncommon::help_open_topic('Numerical_Response_Format');
	} elsif ($token->[1] eq 'stringhint') {
	    $result.=&Apache::edit::select_arg('Type:','type',
			    [['cs','Case Sensitive'],['ci','Case Insensitive'],
			     ['mc','Case Insensitive, Any Order']],$token);
	} elsif ($token->[1] eq 'formulahint') {
	    $result.=&Apache::edit::text_arg('Sample Points:','samples',$token,40);
	}
	$result.=&Apache::edit::end_row();
	$result.=&Apache::edit::start_spanning_row();
    } elsif ($target eq 'modified') {
	my $constructtag;
	if ($token->[1] eq 'numericalhint') {
	    $constructtag=&Apache::edit::get_new_args($token,$parstack,
						     $safeeval,'name',
						     'answer','unit','format');
	} elsif ($token->[1] eq 'stringhint') {
	    $constructtag=&Apache::edit::get_new_args($token,$parstack,
						     $safeeval,'name','answer',
						     'type');
	} elsif ($token->[1] eq 'formulahint') {
	    $constructtag=&Apache::edit::get_new_args($token,$parstack,
						     $safeeval,'name','answer',
						     'samples');
	}
	if ($constructtag) {
	    $result  = &Apache::edit::rebuild_tag($token);
	    $result .= &Apache::edit::handle_insert();
	}
    } elsif ($target eq 'web') {
	&Apache::response::reset_params();
    }
    return $result;
}

sub end_numericalhint {
    my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
    my $result;
    if ($target eq 'web') {
	if (!$Apache::lonxml::default_homework_loaded) {
	    &Apache::lonxml::default_homework_load($safeeval);
	}
	$safeeval->share_from('capa',['&caparesponse_capa_check_answer']);
	my $name= &Apache::lonxml::get_param('name',$parstack,$safeeval);
	&Apache::response::setup_params('numericalhint',$safeeval);
	my $partid=$Apache::inputtags::part;
	my $id=$Apache::inputtags::response['-1'];
	#id submissions occured under
	my $submitid=$Apache::inputtags::response['-2'];
	my $response = $Apache::lonhomework::history{
			    "resource.$partid.$submitid.submission"};
	&Apache::lonxml::debug("hintgroup is using $response<br />\n");
	my $hideunit=&Apache::lonnet::EXT('resource.'.$submitid.'_'.$id.'.turnoffunit');
	my $args_ref= \%{$safeeval->varglob('LONCAPA::CAPAresponse_args')};
	$$args_ref{'response'}=$response;
	#need to get all possible parms
	foreach my $arg ('type','tol','sig','ans_fmt','unit','calc',
			 'samples') {
	    $$args_ref{$arg}=
		&Apache::lonxml::get_param($arg,$parstack,$safeeval);
	}
	foreach my $key (keys(%Apache::inputtags::params)) {
	    $$args_ref{$key}=$Apache::inputtags::params{$key};
	}
	if (lc($hideunit) eq "yes") { delete($$args_ref{'unit'}); }
	if ($$tagstack[-1] eq 'formulahint') {
	    $$args_ref{'type'}='fml';
	} elsif ($$tagstack[-1] eq 'numericalhint') {
	    $$args_ref{'type'}='float';
	}
	my @answer=&Apache::lonxml::get_param_var('answer',$parstack,$safeeval);
	&Apache::lonxml::debug('answer is'.join(':',@answer));
	@{$safeeval->varglob('LONCAPA::CAPAresponse_answer')}=@answer;
		
	($result,my @msgs) = &Apache::run::run("&caparesponse_check_list()",
						$safeeval);
	&Apache::lonxml::debug('msgs are'.join(':',@msgs));
	&Apache::lonxml::debug("result:$result:$Apache::lonxml::curdepth");
	my ($awards)=split(/:/,$result);
	my (@awards) = split(/,/,$awards);
	my ($ad, $msg) = &Apache::inputtags::finalizeawards(\@awards,\@msgs);
	if ($ad eq 'EXACT_ANS' || $ad eq 'APPROX_ANS') { push (@Apache::hint::which,$name); }
	$result='';
    } elsif ($target eq 'meta') {
	$result=&Apache::response::meta_package_write($token->[1]);
    } elsif ($target eq 'edit') {
	$result.='</td></tr>'.&Apache::edit::end_table;
    }
    &Apache::response::end_hintresponse();
    return $result;
}

sub start_formulahint {
    return &start_numericalhint(@_);
}

sub end_formulahint {
    return &end_numericalhint(@_);
}

sub start_stringhint {
    my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
    #do everything in end, so intervening <responseparams> work
    &Apache::response::start_hintresponse($parstack,$safeeval);
    my $result;
    if ($target eq 'edit') {
	$result.=&Apache::edit::tag_start($target,$token);
	$result.=&Apache::edit::text_arg('Name:','name',$token);
	$result.=&Apache::edit::text_arg('Answer:','answer',$token);
	$result.=&Apache::edit::select_arg('Type:','type',
			 [['cs','Case Sensitive'],['ci','Case Insensitive'],
			  ['mc','Case Insensitive, Any Order'],
			  ['re','Regular Expression']],$token);
	$result.=&Apache::edit::end_row();
	$result.=&Apache::edit::start_spanning_row();
    } elsif ($target eq 'modified') {
	my $constructtag;
	$constructtag=&Apache::edit::get_new_args($token,$parstack,
						  $safeeval,'name','answer',
						  'type');
	$result  = &Apache::edit::rebuild_tag($token);
	$result .= &Apache::edit::handle_insert();
    } elsif ($target eq 'web') {
	&Apache::response::reset_params();
    }
    return $result;
}

sub end_stringhint {
    my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
    my $result;
    if ($target eq 'web') {
	if (!$Apache::lonxml::default_homework_loaded) {
	    &Apache::lonxml::default_homework_load($safeeval);
	}
	my $answer=&Apache::lonxml::get_param('answer',$parstack,$safeeval);
	$safeeval->share_from('capa',['&caparesponse_capa_check_answer']);
	my $name= &Apache::lonxml::get_param('name',$parstack,$safeeval);
	&Apache::response::setup_params('stringhint',$safeeval);
	my $partid=$Apache::inputtags::part;
	my $id=$Apache::inputtags::response['-1'];
	#id submissions occured under
	my $submitid=$Apache::inputtags::response['-2'];
	my $response = $Apache::lonhomework::history{
			    "resource.$partid.$submitid.submission"};
	&Apache::lonxml::debug("hintgroup is using $response<br />\n");
	my $args_ref= \%{$safeeval->varglob('LONCAPA::CAPAresponse_args')};
	$$args_ref{'response'}=$response;
	my $type=$$args_ref{'type'}=&Apache::lonxml::get_param('type',$parstack,$safeeval);
	my ($ad,$msg);
	if ($type eq 're' ) {
	    ${$safeeval->varglob('LONCAPA::response')}=$response;
	    $result = &Apache::run::run('return $LONCAPA::response=~m'.$answer,$safeeval);
	    &Apache::lonxml::debug("current $response");
	    &Apache::lonxml::debug("current $answer");
	    $ad = ($result) ? 'APPROX_ANS' : 'INCORRECT';
	} else { 
	    foreach my $key (keys(%Apache::inputtags::params)) {
		$$args_ref{$key}=$Apache::inputtags::params{$key};
	    }
	    &Apache::lonxml::debug('answer is'.$answer);
	    @{$safeeval->varglob('LONCAPA::CAPAresponse_answer')}=($answer);
	    
	    ($result,my @msgs)=&Apache::run::run("&caparesponse_check_list()",
						   $safeeval);
	    &Apache::lonxml::debug('msgs are'.join(':',@msgs));
	    &Apache::lonxml::debug("result:$result:$Apache::lonxml::curdepth");
	    my ($awards)=split(/:/,$result);
	    my (@awards) = split(/,/,$awards);
	    ($ad, $msg) = &Apache::inputtags::finalizeawards(\@awards,\@msgs);
	}
	if ($ad eq 'EXACT_ANS' || $ad eq 'APPROX_ANS') { 
	    push (@Apache::hint::which,$name);
	}
	$result='';
    } elsif ($target eq 'meta') {
	$result=&Apache::response::meta_package_write($token->[1]);
    } elsif ($target eq 'edit') {
	$result.='</td></tr>'.&Apache::edit::end_table;
    }
    &Apache::response::end_hintresponse();
    return $result;
}

# a part shows if it is on, if no specific parts are on, then default shows
sub start_hintpart {
    my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;

    my $show ='0';
    my $result = '';
    if ($target eq 'web') {
	my $on= &Apache::lonxml::get_param('on',$parstack,$safeeval);
	&Apache::lonxml::debug("hintpart sees $on and ,$#Apache::hint::which");
	if ( $on eq 'default' && $#Apache::hint::which == '-1') {
	    $show=1;
	} else {
	    my $which;
	    foreach $which (@Apache::hint::which) { if ($which eq $on) { $show = 1; last } }
	}
	if (!$show) {
	    &Apache::lonxml::get_all_text("/hintpart",$parser);
	}
    } elsif ($target eq 'grade') {
	&Apache::lonxml::get_all_text("/hintpart",$parser);
    } elsif ($target eq 'edit') {
	$result.= &Apache::edit::tag_start($target,$token);
	$result.= &Apache::edit::text_arg('On:','on',$token);
	$result.= &Apache::edit::end_row();
	$result.= &Apache::edit::start_spanning_row();
    } elsif ($target eq 'modified') {
	my $constructtag=&Apache::edit::get_new_args($token,$parstack,
						     $safeeval,'on');
	if ($constructtag) {
	    $result = &Apache::edit::rebuild_tag($token);
	    $result.=&Apache::edit::handle_insert();
	}
    }
    return $result;
}

sub end_hintpart {
    my ($target,$token,$tagstack,$parstack,$parser,$safeeval)=@_;
    my $result;
    if ($target eq 'edit') { $result.=&Apache::edit::end_table; }
    return $result;
}

sub start_optionhint {
    my ($target,$token,$tagstack,$parstack,$parser,$safeeval)=@_;
    my $result;
    &Apache::response::start_hintresponse($parstack,$safeeval);
    if ($target eq 'edit') {
	$result.=&Apache::edit::tag_start($target,$token);
	$result.=&Apache::edit::text_arg('Name:','name',$token);
	$result.=&Apache::edit::text_arg('Answer:','answer',$token,40);
	$result.=&Apache::edit::text_arg('Concept:','concept',$token,50);
    } elsif ($target eq 'modified') {
	my $constructtag=&Apache::edit::get_new_args($token,$parstack,
						     $safeeval,'name',
						     'answer','concept');
	if ($constructtag) {
	    $result  = &Apache::edit::rebuild_tag($token);
	    $result .= &Apache::edit::handle_insert();
	}
    } elsif ($target eq 'meta') {
	$result=&Apache::response::meta_package_write('numericalhint');
    }
    return $result;
}

sub end_optionhint {
    my ($target,$token,$tagstack,$parstack,$parser,$safeeval)=@_;
    my $result;
    if ($target eq 'web') {
	my ($foilmatch,$conceptmatch)=(-1,-1);
	my $name= &Apache::lonxml::get_param('name',$parstack,$safeeval);
	my $partid=$Apache::inputtags::part;
	#id submissions occured under
	my $submitid=$Apache::inputtags::response['-2'];
	my $part_id="$partid.$submitid";
	my %answer;
	my $answer=&Apache::lonxml::get_param('answer',$parstack,$safeeval);
	if ($answer) {
	    eval('%answer ='.$answer);
	    &Apache::lonhomework::showhash(%answer);
	    my $response = $Apache::lonhomework::history{
				            "resource.$part_id.submission"};
	    my %response=&Apache::lonnet::str2hash($response);
	    &Apache::lonhomework::showhash(%response);
	    foreach my $foil (keys(%answer)) {
		$foilmatch=1;
		if ($answer{$foil} ne $response{$foil}) {$foilmatch=0;last;}
	    }
	}
	my %concept;
	my $constr=&Apache::lonxml::get_param('concept',$parstack,$safeeval);
	if ( $constr ) { eval('%concept ='.$constr);	}
	my $response = $Apache::lonhomework::history{
					"resource.$part_id.submissiongrading"};
	my %response=&Apache::lonnet::str2hash($response);
	foreach my $concept (keys(%concept)) {
	    my $compare;
	    if ($concept{$concept} eq 'correct') {$compare=1}else{$compare=0}
	    $conceptmatch=1;
	    if (ref($Apache::hint::option{"$part_id.concepts"})) {
		foreach my $foil (@{ $Apache::hint::option{"$part_id.concept.$concept"} }) {
		    &Apache::lonxml::debug("compare -$foil- -$response{$foil}-$compare-");
		    if ( exists($response{$foil}) && 
			 $response{$foil} ne $compare) {$conceptmatch=0;last;}
		}
	    } else {
		$conceptmatch=0;
	    }
	    if ($conceptmatch eq '0') { last; }
	}
	if ( ($conceptmatch eq '-1' || $conceptmatch eq '1') &&
	     ($foilmatch    eq '-1' || $foilmatch    eq '1') ) {
	    push(@Apache::hint::which,$name);
	}
    } elsif ($target eq 'edit') { $result.=&Apache::edit::end_table; }
    if ($target eq 'edit') { $result.=&Apache::edit::end_table; }
    &Apache::response::end_hintresponse();
    return $result;
}

sub start_radiobuttonhint {
    my ($target,$token,$tagstack,$parstack,$parser,$safeeval)=@_;
    my $result;
    &Apache::response::start_hintresponse($parstack,$safeeval);
    if ($target eq 'edit') {
	$result.=&Apache::edit::tag_start($target,$token);
	$result.=&Apache::edit::text_arg('Name:','name',$token);
	$result.=&Apache::edit::text_arg('Answer:','answer',$token);
    } elsif ($target eq 'modified') {
	my $constructtag=&Apache::edit::get_new_args($token,$parstack,
						     $safeeval,'name',
						     'answer');
	if ($constructtag) {
	    $result  = &Apache::edit::rebuild_tag($token);
	    $result .= &Apache::edit::handle_insert();
	}
    } elsif ($target eq 'meta') {
	$result=&Apache::response::meta_package_write('numericalhint');
    }
    return $result;
}

sub end_radiobuttonhint {
    my ($target,$token,$tagstack,$parstack,$parser,$safeeval)=@_;
    my $result;
    if ($target eq 'web') {
	my $name= &Apache::lonxml::get_param('name',$parstack,$safeeval);
	my @answer;
	my $answer=&Apache::lonxml::get_param('answer',$parstack,$safeeval);
	eval('@answer ='.$answer);
	my $partid=$Apache::inputtags::part;
	#id submissions occured under
	my $submitid=$Apache::inputtags::response['-2'];
	my $part_id="$partid.$submitid";
	my $response = $Apache::lonhomework::history{
			    "resource.$part_id.submission"};
	($response)=&Apache::lonnet::str2hash($response);
	&Apache::lonxml::debug("response is $response");
	
	if ($answer[0] eq 'foil') {
	    shift(@answer);
	    foreach my $answer (@answer) {
		if ($response eq $answer) {
		    push (@Apache::hint::which,$name);
		    last;
		}
	    }
	} elsif ($answer[0] eq 'concept') {
	    shift(@answer);
	    foreach my $answer (@answer) {
		if (ref($Apache::hint::radiobutton{"$part_id.concept.".$answer})) {
		    my @names=@{ $Apache::hint::radiobutton{"$part_id.concept.".$answer} };
		    if (grep(/^\Q$response\E$/,@names)) {
			push(@Apache::hint::which,$name);
			last;
		    }
		}
	    }
	}
    } elsif ($target eq 'edit') { $result.=&Apache::edit::end_table; }
    &Apache::response::end_hintresponse();
    return $result;
}
1;
__END__