1: # The LearningOnline Network with CAPA
2: # input definitons
3: #
4: # $Id: inputtags.pm,v 1.169 2005/06/20 21:31:07 albertel Exp $
5: #
6: # Copyright Michigan State University Board of Trustees
7: #
8: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
9: #
10: # LON-CAPA is free software; you can redistribute it and/or modify
11: # it under the terms of the GNU General Public License as published by
12: # the Free Software Foundation; either version 2 of the License, or
13: # (at your option) any later version.
14: #
15: # LON-CAPA is distributed in the hope that it will be useful,
16: # but WITHOUT ANY WARRANTY; without even the implied warranty of
17: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18: # GNU General Public License for more details.
19: #
20: # You should have received a copy of the GNU General Public License
21: # along with LON-CAPA; if not, write to the Free Software
22: # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
23: #
24: # /home/httpd/html/adm/gpl.txt
25: #
26: # http://www.lon-capa.org/
27:
28: package Apache::inputtags;
29: use HTML::Entities();
30: use strict;
31: use Apache::loncommon;
32: use Apache::lonlocal;
33: use Apache::lonnet;
34:
35: BEGIN {
36: &Apache::lonxml::register('Apache::inputtags',('hiddenline','textfield','textline'));
37: }
38:
39:
40: sub initialize_inputtags {
41: # list of current input ids
42: @Apache::inputtags::input=();
43: # list of all input ids seen in this problem
44: @Apache::inputtags::inputlist=();
45: # list of all current response ids
46: @Apache::inputtags::response=();
47: # list of all response ids seen in this problem
48: @Apache::inputtags::responselist=();
49: # list of whether or not a specific response was previously used
50: @Apache::inputtags::previous=();
51: # submission it was used in
52: @Apache::inputtags::previous_version=();
53: # id of current part, 0 means that no part is current
54: # (inside <problem> only
55: $Apache::inputtags::part='';
56: # list of all part ids seen
57: @Apache::inputtags::partlist=();
58: # list of problem date statuses, the first element is for <problem>
59: # if there is a second element it is for the current <part>
60: @Apache::inputtags::status=();
61: # hash of defined params for the current response
62: %Apache::inputtags::params=();
63: # list of all ids, for <import>, these get join()ed and prepended
64: @Apache::inputtags::import=();
65: # list of all import ids seen
66: @Apache::inputtags::importlist=();
67: # just used to note whether we have seen a response that isn't in a part
68: $Apache::inputtags::response_with_no_part=0;
69: # storage location so the begin <*response> tag can generate the correct
70: # answer string for display by the <textline />
71: %Apache::inputtags::answertxt=();
72: }
73:
74: sub check_for_duplicate_ids {
75: my %check;
76: foreach my $id (@Apache::inputtags::partlist,
77: @Apache::inputtags::responselist,
78: @Apache::inputtags::importlist) {
79: $check{$id}++;
80: }
81: my @duplicates;
82: foreach my $id (sort(keys(%check))) {
83: if ($check{$id} > 1) {
84: push(@duplicates,$id);
85: }
86: }
87: if (@duplicates) {
88: &Apache::lonxml::error("Duplicated ids found, problem will operate incorrectly. Duplicated ids seen: ",join(', ',@duplicates));
89: }
90: }
91:
92: sub start_input {
93: my ($parstack,$safeeval)=@_;
94: my $id = &Apache::lonxml::get_param('id',$parstack,$safeeval);
95: if ($id eq '') { $id = $Apache::lonxml::curdepth; }
96: push (@Apache::inputtags::input,$id);
97: push (@Apache::inputtags::inputlist,$id);
98: return $id;
99: }
100:
101: sub end_input {
102: pop @Apache::inputtags::input;
103: return '';
104: }
105:
106: sub addchars {
107: my ($fieldid,$addchars)=@_;
108: my $output='';
109: foreach (split(/\,/,$addchars)) {
110: $output.='<a href="javascript:void(document.forms.lonhomework.'.
111: $fieldid.'.value+=\''.$_.'\')">'.$_.'</a> ';
112: }
113: return $output;
114: }
115:
116: sub start_textfield {
117: my ($target,$token,$tagstack,$parstack,$parser,$safeeval)=@_;
118: my $result = "";
119: my $id = &start_input($parstack,$safeeval);
120: my $resid=$Apache::inputtags::response[-1];
121: if ($target eq 'web') {
122: $Apache::lonxml::evaluate--;
123: if ($Apache::inputtags::status[-1] eq 'CAN_ANSWER') {
124: my $partid=$Apache::inputtags::part;
125: my $oldresponse = &HTML::Entities::encode($Apache::lonhomework::history{"resource.$partid.$resid.submission"},'<>&"');
126: my $cols = &Apache::lonxml::get_param('cols',$parstack,$safeeval);
127: if ( $cols eq '') { $cols = 80; }
128: my $rows = &Apache::lonxml::get_param('rows',$parstack,$safeeval);
129: if ( $rows eq '') { $rows = 16; }
130: my $addchars=&Apache::lonxml::get_param('addchars',$parstack,$safeeval);
131: $result='';
132: if ($addchars) {
133: $result.=&addchars('HWVAL_'.$resid,$addchars);
134: }
135: push @Apache::lonxml::htmlareafields,'HWVAL_'.$resid;
136: $result.= '<textarea wrap="hard" name="HWVAL_'.$resid.'" id="HWVAL_'.$resid.'" '.
137: "rows=\"$rows\" cols=\"$cols\">".$oldresponse;
138: if ($oldresponse ne '') {
139:
140: #get rid of any startup text if the user has already responded
141: &Apache::lonxml::get_all_text("/textfield",$parser);
142: }
143: } else {
144: #right or wrong don't show it
145: #$result='<table border="1"><tr><td><i>'.$oldresponse.'</i></td></tr></table>';
146: $result='';
147: #get rid of any startup text
148: &Apache::lonxml::get_all_text("/textfield",$parser);
149: }
150: } elsif ($target eq 'grade') {
151: my $seedtext=&Apache::lonxml::get_all_text("/textfield",$parser);
152: if ($seedtext eq $env{'form.HWVAL_'.$resid}) {
153: # if the seed text is still there it wasn't a real submission
154: $env{'form.HWVAL_'.$resid}='';
155: }
156: } elsif ($target eq 'edit') {
157: $result.=&Apache::edit::tag_start($target,$token);
158: $result.=&Apache::edit::text_arg('Rows:','rows',$token,4);
159: $result.=&Apache::edit::text_arg('Columns:','cols',$token,4);
160: $result.=&Apache::edit::text_arg
161: ('Click-On Texts (comma sep):','addchars',$token,10);
162: my $bodytext=&Apache::lonxml::get_all_text("/textfield",$parser);
163: $result.=&Apache::edit::editfield($token->[1],$bodytext,'Text you want to appear by default:',80,2);
164: } elsif ($target eq 'modified') {
165: my $constructtag=&Apache::edit::get_new_args($token,$parstack,
166: $safeeval,'rows','cols',
167: 'addchars');
168: if ($constructtag) {
169: $result = &Apache::edit::rebuild_tag($token);
170: } else {
171: $result=$token->[4];
172: }
173: $result.=&Apache::edit::modifiedfield("/textfield",$parser);
174: } elsif ($target eq 'tex') {
175: my $number_of_lines = &Apache::lonxml::get_param('rows',$parstack,$safeeval);
176: my $width_of_box = &Apache::lonxml::get_param('cols',$parstack,$safeeval);
177: if ($$tagstack[-2] eq 'essayresponse' and $Apache::lonhomework::type eq 'exam') {
178: $result = '\fbox{\fbox{\parbox{\textwidth-5mm}{';
179: for (my $i=0;$i<int $number_of_lines*2;$i++) {$result.='\strut \\\\ ';}
180: $result.='\strut \\\\\strut \\\\\strut \\\\\strut \\\\}}}';
181: } else {
182: my $TeXwidth=$width_of_box/80;
183: $result = '\vskip 1 mm \fbox{\fbox{\parbox{'.$TeXwidth.'\textwidth-5mm}{';
184: for (my $i=0;$i<int $number_of_lines*2;$i++) {$result.='\strut \\\\ ';}
185: $result.='}}}\vskip 2 mm ';
186: }
187: }
188: return $result;
189: }
190:
191: sub end_textfield {
192: my ($target,$token,$tagstack,$parstack,$parser,$safeeval)=@_;
193: my $result;
194: if ($target eq 'web') {
195: $Apache::lonxml::evaluate++;
196: if ($Apache::inputtags::status[-1] eq 'CAN_ANSWER') {
197: return "</textarea>";
198: }
199: } elsif ($target eq 'edit') {
200: $result=&Apache::edit::end_table();
201: }
202: &end_input;
203: return $result;
204: }
205:
206: sub start_textline {
207: my ($target,$token,$tagstack,$parstack,$parser,$safeeval)=@_;
208: my $result = "";
209: if ($target eq 'web') {
210: $Apache::lonxml::evaluate--;
211: my $partid=$Apache::inputtags::part;
212: my $id=$Apache::inputtags::response[-1];
213: if ($Apache::inputtags::status[-1] eq 'CAN_ANSWER') {
214: my $size = &Apache::lonxml::get_param('size',$parstack,$safeeval);
215: my $maxlength;
216: if ($size eq '') { $size=20; } else {
217: if ($size < 20) { $maxlength=$size; }
218: }
219: my $oldresponse = &HTML::Entities::encode($Apache::lonhomework::history{"resource.$partid.$id.submission"},'<>&"');
220: if ($Apache::lonhomework::type ne 'exam') {
221: my $addchars=&Apache::lonxml::get_param('addchars',$parstack,$safeeval);
222: $result='';
223: if ($addchars) {
224: $result.=&addchars('HWVAL_'.$id,$addchars);
225: }
226: my $readonly=&Apache::lonxml::get_param('readonly',$parstack,
227: $safeeval);
228: if (lc($readonly) eq 'yes') {
229: $readonly=' readonly="readonly" ';
230: } else {
231: $readonly='';
232: }
233: $result.= '<input type="text" '.$readonly.' name="HWVAL_'.$id.'" value="'.
234: $oldresponse.'" size="'.$size.'" maxlength="'.$maxlength.'" />';
235: }
236: } else {
237: #right or wrong don't show what was last typed in.
238: $result='<b>'.$Apache::inputtags::answertxt{$id}.'</b>';
239: #$result='';
240: }
241: } elsif ($target eq 'edit') {
242: $result=&Apache::edit::tag_start($target,$token);
243: $result.=&Apache::edit::text_arg('Size:','size',$token,'5').
244: &Apache::edit::text_arg('Click-On Texts (comma sep):',
245: 'addchars',$token,10);
246: $result.=&Apache::edit::select_arg('Readonly:','readonly',
247: ['no','yes'],$token);
248: $result.=&Apache::edit::end_row();
249: $result.=&Apache::edit::end_table();
250: } elsif ($target eq 'modified') {
251: my $constructtag=&Apache::edit::get_new_args($token,$parstack,
252: $safeeval,'size',
253: 'addchars','readonly');
254: if ($constructtag) { $result = &Apache::edit::rebuild_tag($token); }
255: } elsif ($target eq 'tex' and $Apache::lonhomework::type ne 'exam') {
256: my $size = &Apache::lonxml::get_param('size',$parstack,$safeeval);
257: if ($size != 0) {$size=$size*2; $size.=' mm';} else {$size='40 mm';}
258: $result='\framebox['.$size.'][s]{\tiny\strut}';
259: }
260: return $result;
261: }
262:
263: sub end_textline {
264: my ($target,$token,$tagstack,$parstack,$parser,$safeeval)=@_;
265: if ($target eq 'web') { $Apache::lonxml::evaluate++; }
266: elsif ($target eq 'edit') { return ('','no'); }
267: return "";
268: }
269:
270: sub start_hiddenline {
271: my ($target,$token,$tagstack,$parstack,$parser,$safeeval)=@_;
272: my $result = "";
273: if ($target eq 'web') {
274: $Apache::lonxml::evaluate--;
275: if ($Apache::inputtags::status[-1] eq 'CAN_ANSWER') {
276: my $partid=$Apache::inputtags::part;
277: my $id=$Apache::inputtags::response[-1];
278: my $oldresponse = &HTML::Entities::encode($Apache::lonhomework::history{"resource.$partid.$id.submission"},'<>&"');
279: if ($Apache::lonhomework::type ne 'exam') {
280: $result= '<input type="hidden" name="HWVAL_'.$id.'" value="'.
281: $oldresponse.'" />';
282: }
283: }
284: } elsif ($target eq 'edit') {
285: $result=&Apache::edit::tag_start($target,$token);
286: $result.=&Apache::edit::end_table;
287: }
288: return $result;
289: }
290:
291: sub end_hiddenline {
292: my ($target,$token,$tagstack,$parstack,$parser,$safeeval)=@_;
293: if ($target eq 'web') { $Apache::lonxml::evaluate++; }
294: elsif ($target eq 'edit') { return ('','no'); }
295: return "";
296: }
297:
298: # $part -> partid
299: # $id -> responseid
300: # $uploadefiletypes -> comma seperated list of extensions allowed or * for any
301: # $which -> 'uploadedonly' -> only newly uploaded files
302: # 'portfolioonly' -> only allow files from portfolio
303: # 'both' -> allow files from either location
304: # returns a table row <tr>
305: sub file_selector {
306: my ($part,$id,$uploadedfiletypes,$which)=@_;
307: if (!$uploadedfiletypes) { return ''; }
308:
309: my $jspart=$part;
310: $jspart=~s/\./_/g;
311:
312: my $result;
313:
314: $result.='<tr><td>';
315: if ($uploadedfiletypes ne '*') {
316: $result.=
317: &mt('Allowed filetypes: <b>[_1]</b>',$uploadedfiletypes).'<br />';
318: }
319: if ($which eq 'uploadonly' || $which eq 'both') {
320: $result.=&mt('Submit a file: (only one file can be uploaded)').
321: ' <br /><input type="file" size="50" name="HWFILE'.
322: $jspart.'_'.$id.'" /><br />';
323: my $uploadedfile= &HTML::Entities::encode($Apache::lonhomework::history{"resource.$part.$id.uploadedfile"},'<>&"');
324:
325: if ($uploadedfile) {
326: my $url=$Apache::lonhomework::history{"resource.$part.$id.uploadedurl"};
327: push (@Apache::lonxml::extlinks,$url);
328: &Apache::lonnet::allowuploaded('/adm/essayresponse',$url);
329: my $icon=&Apache::loncommon::icon($url);
330: my $curfile='<a href="'.$url.'"><img src="'.$icon.
331: '" border="0" />'.$uploadedfile.'</a>';
332: $result.=&mt('Currently submitted: <tt>[_1]</tt>',$curfile);
333: } else {
334: #$result.=&mt('(Hand in a file you have prepared on your computer)');
335: }
336: }
337: if ( $which eq 'both') {
338: $result.='<br />'.'<strong>'.&mt('OR:').'</strong><br />';
339: }
340: if ($which eq 'portfolioonly' || $which eq 'both') {
341: $result.='<a href='."'".'javascript:void(window.open("/adm/portfolio?mode=selectfile&fieldname=HWPORT'.$jspart.'_'.$id.'","cat","height=600,width=800,scrollbars=1,resizable=1,menubar=2,location=1"))'."'".'>'.
342: &mt('Select Portfolio Files').'</a><br />'.
343: '<input type="text" size="50" name="HWPORT'.$jspart.'_'.$id.'" value="" />'.
344: '<br />';
345: if ($Apache::lonhomework::history{"resource.$part.$id.portfiles"}=~/[^\s]/){
346: my @filelist;
347: foreach my $file (split(',',&Apache::lonnet::unescape($Apache::lonhomework::history{"resource.$part.$id.portfiles"}))) {
348: my (undef,undef,$domain,$user)=&Apache::lonxml::whichuser();
349: my $url="/uploaded/$domain/$user/portfolio$file";
350: my $icon=&Apache::loncommon::icon($url);
351: push(@filelist,'<a href="'.$url.'"><img src="'.$icon.
352: '" border="0" />'.$file.'</a>');
353: }
354: $result.=&mt("Portfolio files previously selected: <strong>[_1]</strong>",join(', ',@filelist));
355: }
356: }
357: $result.='</td></tr>';
358: return $result;
359: }
360:
361: sub checkstatus {
362: my ($value,$awardref,$msgref)=@_;
363: for (my $i=0;$i<=$#$awardref;$i++) {
364: if ($$awardref[$i] eq $value) {
365: return ($$awardref[$i],$$msgref[$i]);
366: }
367: }
368: return(undef,undef);
369: }
370:
371: sub finalizeawards {
372: my ($awardref,$msgref)=@_;
373: my $result=undef;
374: my $award;
375: my $msg;
376: if ($#$awardref == -1) { $result = "NO_RESPONSE"; }
377: if ($result eq '' ) {
378: my $blankcount;
379: foreach $award (@$awardref) {
380: if ($award eq '') {
381: $result='MISSING_ANSWER';
382: $blankcount++;
383: }
384: }
385: if ($blankcount == ($#$awardref + 1)) { $result = 'NO_RESPONSE'; }
386: }
387: if (defined($result)) { return ($result,$msg); }
388: foreach my $possibleaward ('MISSING_ANSWER', 'ERROR', 'NO_RESPONSE',
389: 'TOO_LONG', 'UNIT_INVALID_INSTRUCTOR',
390: 'UNIT_INVALID_STUDENT', 'UNIT_IRRECONCIBLE',
391: 'UNIT_FAIL', 'NO_UNIT',
392: 'UNIT_NOTNEEDED', 'WANTED_NUMERIC',
393: 'BAD_FORMULA', 'SIG_FAIL', 'INCORRECT',
394: 'MISORDERED_RANK', 'INVALID_FILETYPE',
395: 'DRAFT', 'SUBMITTED', 'ASSIGNED_SCORE',
396: 'APPROX_ANS', 'EXACT_ANS','COMMA_FAIL') {
397: ($result,$msg)=&checkstatus($possibleaward,$awardref,$msgref);
398: if (defined($result)) { return ($result,$msg); }
399: }
400: return ('ERROR',undef);
401: }
402:
403: sub decideoutput {
404: my ($award,$awarded,$awardmsg,$solved,$previous,$target)=@_;
405: my $message='';
406: my $button=0;
407: my $previousmsg;
408: my $bgcolor='orange';
409: my $added_computer_text=0;
410: my %possiblecolors =
411: ( 'correct' => '#aaffaa',
412: 'charged_try' => '#ffaaaa',
413: 'not_charged_try' => '#ffffaa',
414: 'no_message' => '#fffff',
415: );
416:
417: if ($previous) { $previousmsg=&mt('You have entered that answer before'); }
418:
419: if ($solved =~ /^correct/) {
420: $bgcolor=$possiblecolors{'correct'};
421: if ($award eq 'ASSIGNED_SCORE') {
422: $message = &mt("A score has been assigned.");
423: if ($awarded < 1 && $awarded > 0) {
424: $bgcolor=$possiblecolors{'not_charged_try'};
425: } elsif ($awarded < 1) {
426: $bgcolor=$possiblecolors{'charged_try'};
427: }
428: } else {
429: if ($target eq 'tex') {
430: $message = '\textbf{'.&mt('You are correct.').'}';
431: } else {
432: $message = "<b>".&mt('You are correct.')."</b>";
433: $message.=" ".&mt("Computer's answer now shown above.");
434: }
435: $added_computer_text=1;
436: unless ($env{'course.'.
437: $env{'request.course.id'}.
438: '.disable_receipt_display'} eq 'yes') {
439: $message.=(($target eq 'web')?'<br />':' ').
440: &mt('Your receipt is').' '.&Apache::lonnet::receipt($Apache::inputtags::part).
441: (($target eq 'web')?&Apache::loncommon::help_open_topic('Receipt'):'');
442: }
443: }
444: $button=0;
445: $previousmsg='';
446: } elsif ($solved =~ /^excused/) {
447: if ($target eq 'tex') {
448: $message = ' \textbf{'.&mt('You are excused from the problem.').'} ';
449: } else {
450: $message = "<b>".&mt('You are excused from the problem.')."</b>";
451: }
452: $bgcolor=$possiblecolors{'charged_try'};
453: $button=0;
454: $previousmsg='';
455: } elsif ($award eq 'EXACT_ANS' || $award eq 'APPROX_ANS' ) {
456: if ($solved =~ /^incorrect/ || $solved eq '') {
457: $message = &mt("Incorrect").".";
458: $bgcolor=$possiblecolors{'charged_try'};
459: $button=1;
460: } else {
461: if ($target eq 'tex') {
462: $message = '\textbf{'.&mt('You are correct.').'}';
463: } else {
464: $message = "<b>".&mt('You are correct.')."</b>";
465: $message.=" ".&mt("Computer's answer now shown above.");
466: }
467: $added_computer_text=1;
468: unless ($env{'course.'.
469: $env{'request.course.id'}.
470: '.disable_receipt_display'} eq 'yes') {
471: $message.=(($target eq 'web')?'<br />':' ').
472: 'Your receipt is '.&Apache::lonnet::receipt($Apache::inputtags::part).
473: (($target eq 'web')?&Apache::loncommon::help_open_topic('Receipt'):'');
474: }
475: $bgcolor=$possiblecolors{'correct'};
476: $button=0;
477: $previousmsg='';
478: }
479: } elsif ($award eq 'NO_RESPONSE') {
480: $message = '';
481: $bgcolor=$possiblecolors{'no_feedback'};
482: $button=1;
483: } elsif ($award eq 'MISSING_ANSWER') {
484: $message = &mt('Some items were not submitted.');
485: $bgcolor=$possiblecolors{'not_charged_try'};
486: $button = 1;
487: } elsif ($award eq 'ERROR') {
488: $message = &mt('An error occured while grading your answer.');
489: $bgcolor=$possiblecolors{'not_charged_try'};
490: $button = 1;
491: } elsif ($award eq 'TOO_LONG') {
492: $message = &mt("The submitted answer was too long.");
493: $bgcolor=$possiblecolors{'not_charged_try'};
494: $button=1;
495: } elsif ($award eq 'WANTED_NUMERIC') {
496: $message = &mt("This question expects a numeric answer.");
497: $bgcolor=$possiblecolors{'not_charged_try'};
498: $button=1;
499: } elsif ($award eq 'MISORDERED_RANK') {
500: $message = &mt('You have provided an invalid ranking');
501: if ($target ne 'tex') {
502: $message.=', '.&mt('please refer to').' '.&Apache::loncommon::help_open_topic('Ranking_Problems','help on ranking problems');
503: }
504: $bgcolor=$possiblecolors{'not_charged_try'};
505: $button=1;
506: } elsif ($award eq 'INVALID_FILETYPE') {
507: $message = &mt('Submission won\'t be graded. The type of file submitted is not allowed.');
508: $bgcolor=$possiblecolors{'not_charged_try'};
509: $button=1;
510: } elsif ($award eq 'SIG_FAIL') {
511: my ($used,$min,$max)=split(':',$awardmsg);
512: my $word;
513: if ($used < $min) { $word=&mt('more'); }
514: if ($used > $max) { $word=&mt('fewer'); }
515: $message = &mt("Submission not graded. Use [_2] digits.",$used,$word);
516: $bgcolor=$possiblecolors{'not_charged_try'};
517: $button=1;
518: } elsif ($award eq 'UNIT_INVALID_INSTRUCTOR') {
519: $message = &mt('Error in instructor specifed unit. This error has been reported to the instructor.', $awardmsg);
520: if ($target ne 'tex') {$message.=&Apache::loncommon::help_open_topic('Physical_Units');}
521: $bgcolor=$possiblecolors{'not_charged_try'};
522: $button=1;
523: } elsif ($award eq 'UNIT_INVALID_STUDENT') {
524: $message = &mt('Unable to interpret units. Computer reads units as "[_1]".',&markup_unit($awardmsg,$target));
525: if ($target ne 'tex') {$message.=&Apache::loncommon::help_open_topic('Physical_Units');}
526: $bgcolor=$possiblecolors{'not_charged_try'};
527: $button=1;
528: } elsif ($award eq 'UNIT_FAIL' || $award eq 'UNIT_IRRECONCIBLE') {
529: $message = &mt('Incompatible units. No conversion found between "[_1]" and the required units.',&markup_unit($awardmsg,$target));
530: if ($target ne 'tex') {$message.=&Apache::loncommon::help_open_topic('Physical_Units');}
531: $bgcolor=$possiblecolors{'not_charged_try'};
532: $button=1;
533: } elsif ($award eq 'UNIT_NOTNEEDED') {
534: $message = &mt('Only a number required. Computer reads units of "[_1]".',&markup_unit($awardmsg,$target));
535: $bgcolor=$possiblecolors{'not_charged_try'};
536: $button=1;
537: } elsif ($award eq 'NO_UNIT') {
538: $message = &mt("Units required").'.';
539: if ($target ne 'tex') {$message.=&Apache::loncommon::help_open_topic('Physical_Units')};
540: $bgcolor=$possiblecolors{'not_charged_try'};
541: $button=1;
542: } elsif ($award eq 'COMMA_FAIL') {
543: $message = &mt("Proper comma separation is required").'.';
544: $bgcolor=$possiblecolors{'not_charged_try'};
545: $button=1;
546: } elsif ($award eq 'BAD_FORMULA') {
547: $message = &mt("Unable to understand formula");
548: $bgcolor=$possiblecolors{'not_charged_try'};
549: $button=1;
550: } elsif ($award eq 'INCORRECT') {
551: $message = &mt("Incorrect").'.';
552: $bgcolor=$possiblecolors{'charged_try'};
553: $button=1;
554: } elsif ($award eq 'SUBMITTED') {
555: $message = &mt("Your submission has been recorded.");
556: $bgcolor=$possiblecolors{'correct'};
557: $button=1;
558: } elsif ($award eq 'DRAFT') {
559: $message = &mt("A draft copy has been saved.");
560: $bgcolor=$possiblecolors{'not_charged_try'};
561: $button=1;
562: } elsif ($award eq 'ASSIGNED_SCORE') {
563: $message = &mt("A score has been assigned.");
564: $bgcolor=$possiblecolors{'correct'};
565: $button=0;
566: } elsif ($award eq '') {
567: $bgcolor=$possiblecolors{'not_charged_try'};
568: $button=1;
569: } else {
570: $message = &mt("Unknown message").": $award";
571: $button=1;
572: }
573: if (lc($Apache::lonhomework::problemstatus) eq 'no' &&
574: $Apache::inputtags::status[-1] ne 'SHOW_ANSWER') {
575: $message = &mt("Answer Submitted: Your final submission will be graded after the due date.");
576: $bgcolor=$possiblecolors{'correct'};
577: $button=1;
578: }
579: if ($Apache::inputtags::status[-1] eq 'SHOW_ANSWER' &&
580: !$added_computer_text && $target ne 'tex') {
581: $message.=" ".&mt("Computer's answer now shown above.");
582: $added_computer_text=1;
583: }
584: return ($button,$bgcolor,$message,$previousmsg);
585: }
586:
587: sub markup_unit {
588: my ($unit,$target)=@_;
589: if ($target eq 'tex') {
590: return '\texttt{'.&Apache::lonxml::latex_special_symbols($unit).'}';
591: } else {
592: return "<tt>".$unit."</tt>";
593: }
594: }
595:
596: sub removealldata {
597: my ($id)=@_;
598: foreach my $key (keys(%Apache::lonhomework::results)) {
599: if (($key =~ /^resource\.\Q$id\E\./) && ($key !~ /\.collaborators$/)) {
600: &Apache::lonxml::debug("Removing $key");
601: delete($Apache::lonhomework::results{$key});
602: }
603: }
604: }
605:
606: sub hidealldata {
607: my ($id)=@_;
608: foreach my $key (keys(%Apache::lonhomework::results)) {
609: if (($key =~ /^resource\.\Q$id\E\./) && ($key !~ /\.collaborators$/)) {
610: &Apache::lonxml::debug("Hidding $key");
611: my $newkey=$key;
612: $newkey=~s/^(resource\.\Q$id\E\.[^\.]+\.)(.*)$/${1}hidden${2}/;
613: $Apache::lonhomework::results{$newkey}=
614: $Apache::lonhomework::results{$key};
615: delete($Apache::lonhomework::results{$key});
616: }
617: }
618: }
619:
620: sub setgradedata {
621: my ($award,$msg,$id,$previously_used) = @_;
622: if ($Apache::lonhomework::scantronmode &&
623: &Apache::lonnet::validCODE($env{'form.CODE'})) {
624: $Apache::lonhomework::results{"resource.CODE"}=$env{'form.CODE'};
625: } elsif ($Apache::lonhomework::scantronmode &&
626: $env{'form.CODE'} eq '' &&
627: $Apache::lonhomework::history{"resource.CODE"} ne '') {
628: $Apache::lonhomework::results{"resource.CODE"}='';
629: }
630:
631: if (!$Apache::lonhomework::scantronmode &&
632: $Apache::inputtags::status['-1'] ne 'CAN_ANSWER' &&
633: $Apache::inputtags::status['-1'] ne 'CANNOT_ANSWER') {
634: $Apache::lonhomework::results{"resource.$id.afterduedate"}=$award;
635: return '';
636: } elsif ( $Apache::lonhomework::history{"resource.$id.solved"} !~
637: /^correct/ || $Apache::lonhomework::scantronmode ||
638: lc($Apache::lonhomework::problemstatus) eq 'no') {
639: # the student doesn't already have it correct,
640: # or we are in a mode (scantron orno problem status) where a correct
641: # can become incorrect
642: # handle assignment of tries and solved status
643: my $solvemsg;
644: if ($Apache::lonhomework::scantronmode) {
645: $solvemsg='correct_by_scantron';
646: } else {
647: $solvemsg='correct_by_student';
648: }
649: if ($Apache::lonhomework::history{"resource.$id.afterduedate"}) {
650: $Apache::lonhomework::results{"resource.$id.afterduedate"}='';
651: }
652: if ( $award eq 'ASSIGNED_SCORE') {
653: $Apache::lonhomework::results{"resource.$id.tries"} =
654: $Apache::lonhomework::history{"resource.$id.tries"} + 1;
655: $Apache::lonhomework::results{"resource.$id.solved"} =
656: $solvemsg;
657: my $numawards=scalar(@Apache::inputtags::response);
658: $Apache::lonhomework::results{"resource.$id.awarded"} = 0;
659: foreach my $res (@Apache::inputtags::response) {
660: $Apache::lonhomework::results{"resource.$id.awarded"}+=
661: $Apache::lonhomework::results{"resource.$id.$res.awarded"};
662: }
663: if ($numawards > 0) {
664: $Apache::lonhomework::results{"resource.$id.awarded"}/=
665: $numawards;
666: }
667: } elsif ( $award eq 'APPROX_ANS' || $award eq 'EXACT_ANS' ) {
668: $Apache::lonhomework::results{"resource.$id.tries"} =
669: $Apache::lonhomework::history{"resource.$id.tries"} + 1;
670: $Apache::lonhomework::results{"resource.$id.solved"} =
671: $solvemsg;
672: $Apache::lonhomework::results{"resource.$id.awarded"} = '1';
673: } elsif ( $award eq 'INCORRECT' ) {
674: $Apache::lonhomework::results{"resource.$id.tries"} =
675: $Apache::lonhomework::history{"resource.$id.tries"} + 1;
676: if (lc($Apache::lonhomework::problemstatus) eq 'no' ||
677: $Apache::lonhomework::scantronmode) {
678: $Apache::lonhomework::results{"resource.$id.awarded"} = 0;
679: }
680: $Apache::lonhomework::results{"resource.$id.solved"} =
681: 'incorrect_attempted';
682: } elsif ( $award eq 'SUBMITTED' ) {
683: $Apache::lonhomework::results{"resource.$id.tries"} =
684: $Apache::lonhomework::history{"resource.$id.tries"} + 1;
685: $Apache::lonhomework::results{"resource.$id.solved"} =
686: 'ungraded_attempted';
687: } elsif ( $award eq 'DRAFT' ) {
688: $Apache::lonhomework::results{"resource.$id.solved"} = '';
689: } elsif ( $award eq 'NO_RESPONSE' ) {
690: #no real response so delete any data that got stored
691: &removealldata($id);
692: return '';
693: } else {
694: $Apache::lonhomework::results{"resource.$id.solved"} =
695: 'incorrect_attempted';
696: if (lc($Apache::lonhomework::problemstatus) eq 'no' ||
697: $Apache::lonhomework::scantronmode) {
698: $Apache::lonhomework::results{"resource.$id.tries"} =
699: $Apache::lonhomework::history{"resource.$id.tries"} + 1;
700: $Apache::lonhomework::results{"resource.$id.awarded"} = 0;
701: }
702: }
703: if (defined($msg)) {
704: $Apache::lonhomework::results{"resource.$id.awardmsg"} = $msg;
705: }
706: # did either of the overall awards chage? If so ignore the
707: # previous check
708: if (($Apache::lonhomework::results{"resource.$id.awarded"} eq
709: $Apache::lonhomework::history{"resource.$id.awarded"}) &&
710: ($Apache::lonhomework::results{"resource.$id.solved"} eq
711: $Apache::lonhomework::history{"resource.$id.solved"})) {
712: # check if this was a previous submission if it was delete the
713: # unneeded data and update the previously_used attribute
714: if ( $previously_used eq 'PREVIOUSLY_USED') {
715: if (lc($Apache::lonhomework::problemstatus) ne 'no') {
716: delete($Apache::lonhomework::results{"resource.$id.tries"});
717: $Apache::lonhomework::results{"resource.$id.previous"} = '1';
718: }
719: } elsif ( $previously_used eq 'PREVIOUSLY_LAST') {
720: #delete all data as they student didn't do anything, but save
721: #the list of collaborators.
722: &removealldata($id);
723: #and since they didn't do anything we were never here
724: return '';
725: } else {
726: $Apache::lonhomework::results{"resource.$id.previous"} = '0';
727: }
728: }
729: } elsif ( $Apache::lonhomework::history{"resource.$id.solved"} =~
730: /^correct/ ) {
731: #delete all data as they student already has it correct
732: &removealldata($id);
733: #and since they didn't do anything we were never here
734: return '';
735: }
736: $Apache::lonhomework::results{"resource.$id.award"} = $award;
737: }
738:
739: sub grade {
740: my ($target) = @_;
741: my $id = $Apache::inputtags::part;
742: my $response='';
743: if ( defined $env{'form.submitted'}) {
744: my (@awards,@msgs);
745: foreach $response (@Apache::inputtags::response) {
746: &Apache::lonxml::debug("looking for response.$id.$response.awarddetail");
747: my $value=$Apache::lonhomework::results{"resource.$id.$response.awarddetail"};
748: &Apache::lonxml::debug("keeping $value from $response for $id");
749: push (@awards,$value);
750: $value=$Apache::lonhomework::results{"resource.$id.$response.awardmsg"};
751: &Apache::lonxml::debug("got message $value from $response for $id");
752: push (@msgs,$value);
753: }
754: my ($finalaward,$msg) = &finalizeawards(\@awards,\@msgs);
755: my $previously_used;
756: if ( $#Apache::inputtags::previous eq $#awards ) {
757: my $match=0;
758: my @matches;
759: foreach my $versionar (@Apache::inputtags::previous_version) {
760: foreach my $version (@$versionar) {
761: $matches[$version]++;
762: }
763: }
764: foreach my $elem (@matches) {if ($elem eq ($#awards+1)) {$match=1;}}
765: if ($match) {
766: $previously_used = 'PREVIOUSLY_LAST';
767: foreach my $value (@Apache::inputtags::previous) {
768: if ($value eq 'PREVIOUSLY_USED' ) {
769: $previously_used = $value;
770: last;
771: }
772: }
773: }
774: }
775: &Apache::lonxml::debug("final award $finalaward, $previously_used, message $msg");
776: &setgradedata($finalaward,$msg,$id,$previously_used);
777: }
778: return '';
779: }
780:
781: sub gradestatus {
782: my ($id,$target) = @_;
783: my $showbutton = 1;
784: my $bgcolor = '';
785: my $message = '';
786: my $latemessage = '';
787: my $trystr='';
788: my $button='';
789: my $previousmsg='';
790:
791: my $status = $Apache::inputtags::status['-1'];
792: &Apache::lonxml::debug("gradestatus has :$status:");
793: if ( $status ne 'CLOSED' && $status ne 'UNAVAILABLE' &&
794: $status ne 'INVALID_ACCESS') {
795: my $award = $Apache::lonhomework::history{"resource.$id.award"};
796: my $awarded = $Apache::lonhomework::history{"resource.$id.awarded"};
797: my $solved = $Apache::lonhomework::history{"resource.$id.solved"};
798: my $previous = $Apache::lonhomework::history{"resource.$id.previous"};
799: my $awardmsg = $Apache::lonhomework::history{"resource.$id.awardmsg"};
800: &Apache::lonxml::debug("Found Award |$award|$solved|$awardmsg");
801: if ( $award ne '' || $solved ne '' || $status eq 'SHOW_ANSWER') {
802: &Apache::lonxml::debug('Getting message');
803: ($showbutton,$bgcolor,$message,$previousmsg) =
804: &decideoutput($award,$awarded,$awardmsg,$solved,$previous,
805: $target);
806: if ($target eq 'tex') {
807: $message='\vskip 2 mm '.$message.' ';
808: } else {
809: $message="<td bgcolor=\"$bgcolor\">$message</td>";
810: if ($previousmsg) {
811: $previousmsg="<td bgcolor=\"#aaaaff\">$previousmsg</td>";
812: }
813: }
814: }
815: my $tries = $Apache::lonhomework::history{"resource.$id.tries"};
816: my $maxtries = &Apache::lonnet::EXT("resource.$id.maxtries");
817: &Apache::lonxml::debug("got maxtries of :$maxtries:");
818: #if tries are set to negative turn off the Tries/Button and messages
819: if (defined($maxtries) && $maxtries < 0) { return ''; }
820: if ( $tries eq '' ) { $tries = '0'; }
821: if ( $maxtries eq '' ) { $maxtries = '2'; }
822: if ( $maxtries eq 'con_lost' ) { $maxtries = '0'; }
823: my $tries_text=&mt('Tries');
824: if ( $Apache::lonhomework::type eq 'survey' ||
825: $Apache::lonhomework::parsing_a_task) {
826: $tries_text=&mt('Submissions');
827: }
828: if ( $showbutton ) {
829: if ($target eq 'tex') {
830: if ($env{'request.state'} ne "construct" && $Apache::lonhomework::type ne 'exam' && $env{'form.suppress_tries'} ne 'yes') {
831: $trystr = ' {\vskip 1 mm \small \textit{'.$tries_text.'} '.$tries.'/'.$maxtries.'} \vskip 2 mm ';
832: } else {
833: $trystr = '\vskip 0 mm ';
834: }
835: } else {
836: $trystr = "<td><nobr>".$tries_text." $tries";
837: if ($Apache::lonhomework::parsing_a_task) {
838: } elsif($env{'request.state'} ne 'construct') {
839: $trystr.="/$maxtries";
840: } else {
841: if (defined($Apache::inputtags::params{'maxtries'})) {
842: $trystr.="/".$Apache::inputtags::params{'maxtries'};
843: }
844: }
845: $trystr.="</nobr></td>";
846: }
847: }
848: if ( $status eq 'SHOW_ANSWER' || $status eq 'CANNOT_ANSWER') {$showbutton = 0;}
849: if ( $showbutton ) {
850: if ($target ne 'tex') {
851: $button = '<input type="submit" name="submit_'.$id.'" value="'.&mt('Submit Answer').'" />';
852: }
853: }
854: if ($Apache::lonhomework::history{"resource.$id.afterduedate"}) {
855: #last submissions was after due date
856: $latemessage=&mt(' The last submission was after the Due Date ');;
857: if ($target eq 'web') {
858: $latemessage='<td bgcolor="#ffaaaa">'.$latemessage.'</td>';
859: }
860: }
861: }
862: my $output= $previousmsg.$latemessage.$message.$trystr;
863: if ($output =~ /^\s*$/) {
864: return $button;
865: } else {
866: if ($target eq 'tex') {
867: return $button.' \vskip 0 mm '.$output.' ';
868: } else {
869: return '<table><tr><td>'.$button.'</td>'.$output.'</tr></table>';
870: }
871: }
872: }
873: 1;
874: __END__
875:
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>