1: # The LearningOnline Network with CAPA
2: # input definitons
3: #
4: # $Id: inputtags.pm,v 1.235 2007/11/17 02:03:46 albertel Exp $
5: #
6: # Copyright Michigan State University Board of Trustees
7: #
8: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
9: #
10: # LON-CAPA is free software; you can redistribute it and/or modify
11: # it under the terms of the GNU General Public License as published by
12: # the Free Software Foundation; either version 2 of the License, or
13: # (at your option) any later version.
14: #
15: # LON-CAPA is distributed in the hope that it will be useful,
16: # but WITHOUT ANY WARRANTY; without even the implied warranty of
17: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18: # GNU General Public License for more details.
19: #
20: # You should have received a copy of the GNU General Public License
21: # along with LON-CAPA; if not, write to the Free Software
22: # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
23: #
24: # /home/httpd/html/adm/gpl.txt
25: #
26: # http://www.lon-capa.org/
27:
28: package Apache::inputtags;
29: use HTML::Entities();
30: use strict;
31: use Apache::loncommon;
32: use Apache::lonlocal;
33: use Apache::lonnet;
34: use LONCAPA;
35:
36:
37: BEGIN {
38: &Apache::lonxml::register('Apache::inputtags',('hiddenline','textfield','textline'));
39: }
40:
41: # Initializes a set of global variables used during the parse of the problem.
42: #
43: # @Apache::inputtags::input - List of current input ids.
44: # @Apache::inputtags::inputlist - List of all input ids seen this problem.
45: # @Apache::inputtags::response - List of all current resopnse ids.
46: # @Apache::inputtags::responselist - List of all response ids seen this
47: # problem.
48: # @Apache::inputtags::hint - List of all hint ids.
49: # @Apache::inputtags::hintlist - List of all hint ids seen this problem.
50: # @Apache::inputtags::previous - List describing if specific responseds
51: # have been used
52: # @Apache::inputtags::previous_version - Submission responses were used in.
53: # $Apache::inputtags::part - Current part id (valid only in
54: # <problem>)
55: # 0 if not in a part.
56: # @Apache::inputtags::partlist - List of part ids seen in the current
57: # <problem>
58: # @Apache::inputtags::status - List of problem statuses. First
59: # element is the status of the <problem>
60: # the remainder are for individual <part>s.
61: # %Apache::inputtags::params - Hash of defined parameters for the
62: # current response.
63: # @Apache::inputtags::import - List of all ids for <import> thes get
64: # join()ed and prepended.
65: # @Apache::inputtags::importlist - List of all import ids seen.
66: # $Apache::inputtags::response_with_no_part
67: # - Flag set true if we have seen a response
68: # that is not inside a <part>
69: # %Apache::inputtags::answertxt - <*response> tags store correct
70: # answer strings for display by <textline/>
71: # in this hash.
72: # %Apache::inputtags::submission_display
73: # - <*response> tags store improved display
74: # of submission strings for display by part
75: # end.
76:
77: sub initialize_inputtags {
78: @Apache::inputtags::input=();
79: @Apache::inputtags::inputlist=();
80: @Apache::inputtags::response=();
81: @Apache::inputtags::responselist=();
82: @Apache::inputtags::hint=();
83: @Apache::inputtags::hintlist=();
84: @Apache::inputtags::previous=();
85: @Apache::inputtags::previous_version=();
86: $Apache::inputtags::part='';
87: @Apache::inputtags::partlist=();
88: @Apache::inputtags::status=();
89: %Apache::inputtags::params=();
90: @Apache::inputtags::import=();
91: @Apache::inputtags::importlist=();
92: $Apache::inputtags::response_with_no_part=0;
93: %Apache::inputtags::answertxt=();
94: %Apache::inputtags::submission_display=();
95: }
96:
97: sub check_for_duplicate_ids {
98: my %check;
99: foreach my $id (@Apache::inputtags::partlist,
100: @Apache::inputtags::responselist,
101: @Apache::inputtags::hintlist,
102: @Apache::inputtags::importlist) {
103: $check{$id}++;
104: }
105: my @duplicates;
106: foreach my $id (sort(keys(%check))) {
107: if ($check{$id} > 1) {
108: push(@duplicates,$id);
109: }
110: }
111: if (@duplicates) {
112: &Apache::lonxml::error("Duplicated ids found, problem will operate incorrectly. Duplicated ids seen: ",join(', ',@duplicates));
113: }
114: }
115:
116: sub start_input {
117: my ($parstack,$safeeval)=@_;
118: my $id = &Apache::lonxml::get_id($parstack,$safeeval);
119: push (@Apache::inputtags::input,$id);
120: push (@Apache::inputtags::inputlist,$id);
121: return $id;
122: }
123:
124: sub end_input {
125: pop @Apache::inputtags::input;
126: return '';
127: }
128:
129: sub addchars {
130: my ($fieldid,$addchars)=@_;
131: my $output='';
132: foreach (split(/\,/,$addchars)) {
133: $output.='<a href="javascript:void(document.forms.lonhomework.'.
134: $fieldid.'.value+=\''.$_.'\')">'.$_.'</a> ';
135: }
136: return $output;
137: }
138:
139: sub start_textfield {
140: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
141: my $result = "";
142: my $id = &start_input($parstack,$safeeval);
143: my $resid=$Apache::inputtags::response[-1];
144: if ($target eq 'web') {
145: $Apache::lonxml::evaluate--;
146: my $partid=$Apache::inputtags::part;
147: my $oldresponse = &HTML::Entities::encode($Apache::lonhomework::history{"resource.$partid.$resid.submission"},'<>&"');
148: if ($Apache::inputtags::status[-1] eq 'CAN_ANSWER') {
149: my $cols = &Apache::lonxml::get_param('cols',$parstack,$safeeval);
150: if ( $cols eq '') { $cols = 80; }
151: my $rows = &Apache::lonxml::get_param('rows',$parstack,$safeeval);
152: if ( $rows eq '') { $rows = 16; }
153: my $addchars=&Apache::lonxml::get_param('addchars',$parstack,$safeeval);
154: $result='';
155: if ($addchars) {
156: $result.=&addchars('HWVAL_'.$resid,$addchars);
157: }
158: &Apache::lonhtmlcommon::add_htmlareafields('HWVAL_'.$resid);
159: $result.= '<textarea wrap="hard" name="HWVAL_'.$resid.'" id="HWVAL_'.$resid.'" '.
160: "rows=\"$rows\" cols=\"$cols\">".$oldresponse;
161: if ($oldresponse ne '') {
162:
163: #get rid of any startup text if the user has already responded
164: &Apache::lonxml::get_all_text("/textfield",$parser,$style);
165: }
166: } else {
167: #show past answer in the essayresponse case
168: if ($oldresponse =~ /\S/
169: && &Apache::londefdef::is_inside_of($tagstack,
170: 'essayresponse') ) {
171: $result='<table class="LC_pastsubmission"><tr><td>'.
172: $oldresponse.'</td></tr></table>';
173: }
174: #get rid of any startup text
175: &Apache::lonxml::get_all_text("/textfield",$parser,$style);
176: }
177: } elsif ($target eq 'grade') {
178: my $seedtext=&Apache::lonxml::get_all_text("/textfield",$parser,
179: $style);
180: if ($seedtext eq $env{'form.HWVAL_'.$resid}) {
181: # if the seed text is still there it wasn't a real submission
182: $env{'form.HWVAL_'.$resid}='';
183: }
184: } elsif ($target eq 'edit') {
185: $result.=&Apache::edit::tag_start($target,$token);
186: $result.=&Apache::edit::text_arg('Rows:','rows',$token,4);
187: $result.=&Apache::edit::text_arg('Columns:','cols',$token,4);
188: $result.=&Apache::edit::text_arg
189: ('Click-On Texts (comma sep):','addchars',$token,10);
190: my $bodytext=&Apache::lonxml::get_all_text("/textfield",$parser,
191: $style);
192: $result.=&Apache::edit::editfield($token->[1],$bodytext,'Text you want to appear by default:',80,2);
193: } elsif ($target eq 'modified') {
194: my $constructtag=&Apache::edit::get_new_args($token,$parstack,
195: $safeeval,'rows','cols',
196: 'addchars');
197: if ($constructtag) {
198: $result = &Apache::edit::rebuild_tag($token);
199: } else {
200: $result=$token->[4];
201: }
202: $result.=&Apache::edit::modifiedfield("/textfield",$parser);
203: } elsif ($target eq 'tex') {
204: my $number_of_lines = &Apache::lonxml::get_param('rows',$parstack,$safeeval);
205: my $width_of_box = &Apache::lonxml::get_param('cols',$parstack,$safeeval);
206: if ($$tagstack[-2] eq 'essayresponse' and $Apache::lonhomework::type eq 'exam') {
207: $result = '\fbox{\fbox{\parbox{\textwidth-5mm}{';
208: for (my $i=0;$i<int $number_of_lines*2;$i++) {$result.='\strut \\\\ ';}
209: $result.='\strut \\\\\strut \\\\\strut \\\\\strut \\\\}}}';
210: } else {
211: my $TeXwidth=$width_of_box/80;
212: $result = '\vskip 1 mm \fbox{\fbox{\parbox{'.$TeXwidth.'\textwidth-5mm}{';
213: for (my $i=0;$i<int $number_of_lines*2;$i++) {$result.='\strut \\\\ ';}
214: $result.='}}}\vskip 2 mm ';
215: }
216: }
217: return $result;
218: }
219:
220: sub end_textfield {
221: my ($target,$token,$tagstack,$parstack,$parser,$safeeval)=@_;
222: my $result;
223: if ($target eq 'web') {
224: $Apache::lonxml::evaluate++;
225: if ($Apache::inputtags::status[-1] eq 'CAN_ANSWER') {
226: return "</textarea>";
227: }
228: } elsif ($target eq 'edit') {
229: $result=&Apache::edit::end_table();
230: }
231: &end_input;
232: return $result;
233: }
234:
235: sub exam_score_line {
236: my ($target) = @_;
237:
238: my $result;
239: if ($target eq 'tex') {
240: my $repetition = &Apache::response::repetition();
241: $result.='\begin{enumerate}';
242: if ($env{'request.state'} eq "construct" ) {$result.='\item[\strut]';}
243: foreach my $i (0..$repetition-1) {
244: $result.='\item[\textbf{'.
245: ($Apache::lonxml::counter+$i).
246: '}.]\textit{Leave blank on scoring form}\vskip 0 mm';
247: }
248: $result.= '\end{enumerate}';
249: }
250:
251: return $result;
252: }
253:
254: sub exam_box {
255: my ($target) = @_;
256: my $result;
257:
258: if ($target eq 'tex') {
259: $result .= '\fbox{\fbox{\parbox{\textwidth-5mm}{\strut\\\\\strut\\\\\strut\\\\\strut\\\\}}}';
260: $result .= &exam_score_line($target);
261: } elsif ($target eq 'web') {
262: my $id=$Apache::inputtags::response[-1];
263: $result.= '<br /><br />
264: <textarea name="HWVAL_'.$id.'" rows="4" cols="50">
265: </textarea> <br /><br />';
266: }
267: return $result;
268: }
269:
270: sub needs_exam_box {
271: my ($tagstack) = @_;
272: my @tags = ('formularesponse',
273: 'stringresponse',
274: 'reactionresponse',
275: 'organicresponse',
276: );
277:
278: foreach my $tag (@tags) {
279: if (grep(/\Q$tag\E/,@$tagstack)) {
280: return 1;
281: }
282: }
283: return 0;
284: }
285:
286: sub start_textline {
287: my ($target,$token,$tagstack,$parstack,$parser,$safeeval)=@_;
288: my $result = "";
289: my $input_id = &start_input($parstack,$safeeval);
290: if ($target eq 'web') {
291: $Apache::lonxml::evaluate--;
292: my $partid=$Apache::inputtags::part;
293: my $id=$Apache::inputtags::response[-1];
294: if (!&Apache::response::show_answer()) {
295: my $size = &Apache::lonxml::get_param('size',$parstack,$safeeval);
296: my $maxlength;
297: if ($size eq '') { $size=20; } else {
298: if ($size < 20) {
299: $maxlength = ' maxlength="'.$size.'"';
300: }
301: }
302: my $oldresponse = $Apache::lonhomework::history{"resource.$partid.$id.submission"};
303: &Apache::lonxml::debug("oldresponse $oldresponse is ".ref($oldresponse));
304:
305: if (ref($oldresponse) eq 'ARRAY') {
306: $oldresponse = $oldresponse->[$#Apache::inputtags::inputlist];
307: }
308: $oldresponse = &HTML::Entities::encode($oldresponse,'<>&"');
309:
310: if ($Apache::lonhomework::type ne 'exam') {
311: my $addchars=&Apache::lonxml::get_param('addchars',$parstack,$safeeval);
312: $result='';
313: if ($addchars) {
314: $result.=&addchars('HWVAL_'.$id,$addchars);
315: }
316: my $readonly=&Apache::lonxml::get_param('readonly',$parstack,
317: $safeeval);
318: if (lc($readonly) eq 'yes'
319: || $Apache::inputtags::status[-1] eq 'CANNOT_ANSWER') {
320: $readonly=' readonly="readonly" ';
321: } else {
322: $readonly='';
323: }
324: my $name = 'HWVAL_'.$id;
325: if ($Apache::inputtags::status[-1] eq 'CANNOT_ANSWER') {
326: $name = "none";
327: }
328: $result.= '<input onkeydown="javascript:setSubmittedPart(\''.$partid.'\');" type="text" '.$readonly.' name="'.$name.'" value="'.
329: $oldresponse.'" size="'.$size.'"'.$maxlength.' />';
330: }
331: if ($Apache::lonhomework::type eq 'exam'
332: && &needs_exam_box($tagstack)) {
333: $result.=&exam_box($target);
334: }
335: } else {
336: #right or wrong don't show what was last typed in.
337: my $count = scalar(@Apache::inputtags::inputlist)-1;
338: $result='<b>'.$Apache::inputtags::answertxt{$id}[$count].'</b>';
339: #$result='';
340: }
341: } elsif ($target eq 'edit') {
342: $result=&Apache::edit::tag_start($target,$token);
343: $result.=&Apache::edit::text_arg('Size:','size',$token,'5').
344: &Apache::edit::text_arg('Click-On Texts (comma sep):',
345: 'addchars',$token,10);
346: $result.=&Apache::edit::select_arg('Readonly:','readonly',
347: ['no','yes'],$token);
348: $result.=&Apache::edit::end_row();
349: $result.=&Apache::edit::end_table();
350: } elsif ($target eq 'modified') {
351: my $constructtag=&Apache::edit::get_new_args($token,$parstack,
352: $safeeval,'size',
353: 'addchars','readonly');
354: if ($constructtag) { $result = &Apache::edit::rebuild_tag($token); }
355: } elsif ($target eq 'tex'
356: && $Apache::lonhomework::type ne 'exam') {
357: my $size = &Apache::lonxml::get_param('size',$parstack,$safeeval);
358: if ($size != 0) {$size=$size*2; $size.=' mm';} else {$size='40 mm';}
359: $result='\framebox['.$size.'][s]{\tiny\strut}';
360:
361: } elsif ($target eq 'tex'
362: && $Apache::lonhomework::type eq 'exam'
363: && &needs_exam_box($tagstack)) {
364: $result.=&exam_box($target);
365: }
366: return $result;
367: }
368:
369: sub end_textline {
370: my ($target,$token,$tagstack,$parstack,$parser,$safeeval)=@_;
371: if ($target eq 'web') { $Apache::lonxml::evaluate++; }
372: elsif ($target eq 'edit') { return ('','no'); }
373: &end_input();
374: return "";
375: }
376:
377: sub start_hiddenline {
378: my ($target,$token,$tagstack,$parstack,$parser,$safeeval)=@_;
379: my $result = "";
380: my $input_id = &start_input($parstack,$safeeval);
381: if ($target eq 'web') {
382: $Apache::lonxml::evaluate--;
383: if ($Apache::inputtags::status[-1] eq 'CAN_ANSWER') {
384: my $partid=$Apache::inputtags::part;
385: my $id=$Apache::inputtags::response[-1];
386: my $oldresponse = $Apache::lonhomework::history{"resource.$partid.$id.submission"};
387: if (ref($oldresponse) eq 'ARRAY') {
388: $oldresponse = $oldresponse->[$#Apache::inputtags::inputlist];
389: }
390: $oldresponse = &HTML::Entities::encode($oldresponse,'<>&"');
391:
392: if ($Apache::lonhomework::type ne 'exam') {
393: $result= '<input type="hidden" name="HWVAL_'.$id.'" value="'.
394: $oldresponse.'" />';
395: }
396: }
397: } elsif ($target eq 'edit') {
398: $result=&Apache::edit::tag_start($target,$token);
399: $result.=&Apache::edit::end_table;
400: }
401:
402: if ( ($target eq 'web' || $target eq 'tex')
403: && $Apache::lonhomework::type eq 'exam'
404: && &needs_exam_box($tagstack)) {
405: $result.=&exam_box($target);
406: }
407: return $result;
408: }
409:
410: sub end_hiddenline {
411: my ($target,$token,$tagstack,$parstack,$parser,$safeeval)=@_;
412: if ($target eq 'web') { $Apache::lonxml::evaluate++; }
413: elsif ($target eq 'edit') { return ('','no'); }
414: &end_input();
415: return "";
416: }
417:
418: # $part -> partid
419: # $id -> responseid
420: # $uploadefiletypes -> comma seperated list of extensions allowed or * for any
421: # $which -> 'uploadedonly' -> only newly uploaded files
422: # 'portfolioonly' -> only allow files from portfolio
423: # 'both' -> allow files from either location
424: # $extratext -> additional text to go between the link and the input box
425: # returns a table row <tr>
426: sub file_selector {
427: my ($part,$id,$uploadedfiletypes,$which,$extratext)=@_;
428: if (!$uploadedfiletypes) { return ''; }
429:
430: my $jspart=$part;
431: $jspart=~s/\./_/g;
432:
433: my $result;
434:
435: $result.='<tr><td>';
436: if ($uploadedfiletypes ne '*') {
437: $result.=
438: &mt('Allowed filetypes: <b>[_1]</b>',$uploadedfiletypes).'<br />';
439: }
440: if ($which eq 'uploadonly' || $which eq 'both') {
441: $result.=&mt('Submit a file: (only one file can be uploaded)').
442: ' <br /><input type="file" size="50" name="HWFILE'.
443: $jspart.'_'.$id.'" /><br />';
444: $result .= &show_past_file_submission($part,$id);
445: }
446: if ( $which eq 'both') {
447: $result.='<br />'.'<strong>'.&mt('OR:').'</strong><br />';
448: }
449: if ($which eq 'portfolioonly' || $which eq 'both') {
450: $result.=$extratext.'<a href='."'".'javascript:void(window.open("/adm/portfolio?mode=selectfile&fieldname='.$env{'form.request.prefix'}.'HWPORT'.$jspart.'_'.$id.'","cat","height=600,width=800,scrollbars=1,resizable=1,menubar=2,location=1"))'."'".'>'.
451: &mt('Select Portfolio Files').'</a><br />'.
452: '<input type="text" size="50" name="HWPORT'.$jspart.'_'.$id.'" value="" />'.
453: '<br />';
454: $result .= &show_past_portfile_submission($part,$id);
455:
456: }
457: $result.='</td></tr>';
458: return $result;
459: }
460:
461: sub show_past_file_submission {
462: my ($part,$id) = @_;
463: my $uploadedfile= &HTML::Entities::encode($Apache::lonhomework::history{"resource.$part.$id.uploadedfile"},'<>&"');
464:
465: return if (!$uploadedfile);
466:
467: my $url=$Apache::lonhomework::history{"resource.$part.$id.uploadedurl"};
468: &Apache::lonxml::extlink($url);
469: &Apache::lonnet::allowuploaded('/adm/essayresponse',$url);
470: my $icon=&Apache::loncommon::icon($url);
471: my $curfile='<a href="'.$url.'"><img src="'.$icon.
472: '" border="0" />'.$uploadedfile.'</a>';
473: return &mt('Currently submitted: <tt>[_1]</tt>',$curfile);
474:
475: }
476:
477: sub show_past_portfile_submission {
478: my ($part,$id) = @_;
479: if ($Apache::lonhomework::history{"resource.$part.$id.portfiles"}!~/[^\s]/){
480: return;
481: }
482: my (@file_list,@bad_file_list);
483: foreach my $file (split(/\s*,\s*/,&unescape($Apache::lonhomework::history{"resource.$part.$id.portfiles"}))) {
484: my (undef,undef,$domain,$user)=&Apache::lonnet::whichuser();
485: my $url="/uploaded/$domain/$user/portfolio$file";
486: my $icon=&Apache::loncommon::icon($url);
487: push(@file_list,'<a href="'.$url.'"><img src="'.$icon.
488: '" border="0" />'.$file.'</a>');
489: if (! &Apache::lonnet::stat_file($url)) {
490: &Apache::lonnet::logthis("bad file is $url");
491: push(@bad_file_list,'<a href="'.$url.'"><img src="'.$icon.
492: '" border="0" />'.$file.'</a>');
493: }
494: }
495: my $files = '<span class="LC_filename">'.
496: join('</span>, <span class="LC_filename">',@file_list).
497: '</span>';
498: my $result = &mt("Portfolio files previously selected: [_1]",$files);
499: if (@bad_file_list) {
500: my $bad_files = '<span class="LC_filename">'.
501: join('</span>, <span class="LC_filename">',@bad_file_list).
502: '</span>';
503: $result.='<br />'.&mt('<span class="LC_error">These file(s) don\'t exist:</span> [_1]',$bad_files);
504: }
505: return $result;
506:
507: }
508:
509: sub valid_award {
510: my ($award) =@_;
511: foreach my $possibleaward ('EXTRA_ANSWER','MISSING_ANSWER', 'ERROR',
512: 'NO_RESPONSE',
513: 'TOO_LONG', 'UNIT_INVALID_INSTRUCTOR',
514: 'UNIT_INVALID_STUDENT', 'UNIT_IRRECONCIBLE',
515: 'UNIT_FAIL', 'NO_UNIT',
516: 'UNIT_NOTNEEDED', 'WANTED_NUMERIC',
517: 'BAD_FORMULA', 'SIG_FAIL', 'INCORRECT',
518: 'MISORDERED_RANK', 'INVALID_FILETYPE',
519: 'DRAFT', 'SUBMITTED', 'ASSIGNED_SCORE',
520: 'APPROX_ANS', 'EXACT_ANS','COMMA_FAIL') {
521: if ($award eq $possibleaward) { return 1; }
522: }
523: return 0;
524: }
525:
526: {
527: my @awards = ('EXTRA_ANSWER', 'MISSING_ANSWER', 'ERROR', 'NO_RESPONSE',
528: 'TOO_LONG',
529: 'UNIT_INVALID_INSTRUCTOR', 'UNIT_INVALID_STUDENT',
530: 'UNIT_IRRECONCIBLE', 'UNIT_FAIL', 'NO_UNIT',
531: 'UNIT_NOTNEEDED', 'WANTED_NUMERIC', 'BAD_FORMULA',
532: 'COMMA_FAIL', 'SIG_FAIL', 'INCORRECT', 'MISORDERED_RANK',
533: 'INVALID_FILETYPE', 'DRAFT', 'SUBMITTED', 'ASSIGNED_SCORE',
534: 'APPROX_ANS', 'EXACT_ANS');
535: my $i=0;
536: my %fwd_awards = map { ($_,$i++) } @awards;
537: my $max=scalar(@awards);
538: @awards=reverse(@awards);
539: $i=0;
540: my %rev_awards = map { ($_,$i++) } @awards;
541:
542: sub awarddetail_to_awarded {
543: my ($awarddetail) = @_;
544: if ($awarddetail eq 'EXACT_ANS'
545: || $awarddetail eq 'APPROX_ANS') {
546: return 1;
547: }
548: return 0;
549: }
550:
551: sub hide_award {
552: my ($award) = @_;
553: if (&Apache::lonhomework::show_no_problem_status()) {
554: return 1;
555: }
556: if ($award =~
557: /^(?:EXACT_ANS|APPROX_ANS|SUBMITTED|ASSIGNED_SCORE|INCORRECT)/) {
558: return 1;
559: }
560: return 0;
561: }
562:
563: sub finalizeawards {
564: my ($awardref,$msgref,$nameref,$reverse,$final_scantron)=@_;
565: my $result;
566: if ($#$awardref == -1) { $result = "NO_RESPONSE"; }
567: if ($result eq '' ) {
568: my $blankcount;
569: foreach my $award (@$awardref) {
570: if ($award eq '') {
571: $result='MISSING_ANSWER';
572: $blankcount++;
573: }
574: }
575: if ($blankcount == ($#$awardref + 1)) {
576: return ('NO_RESPONSE');
577: }
578: }
579: if (!$final_scantron && defined($result)) { return ($result); }
580:
581: # if in scantron mode, if the award for any response is
582: # assigned score, then the part gets an assigned score
583: if ($final_scantron
584: && grep {$_ eq 'ASSIGNED_SCORE'} (@$awardref)) {
585: return ('ASSIGNED_SCORE');
586: }
587:
588: # if in scantron mode, if the award for any response is
589: # correct and there are non-correct responses,
590: # then the part gets an assigned score
591: if ($final_scantron
592: && (grep { $_ eq 'EXACT_ANS' ||
593: $_ eq 'APPROX_ANS' } (@$awardref))
594: && (grep { $_ ne 'EXACT_ANS' &&
595: $_ ne 'APPROX_ANS' } (@$awardref))) {
596: return ('ASSIGNED_SCORE');
597: }
598: # these awards are ordered from most important error through best correct
599: my $awards = (!$reverse) ? \%fwd_awards : \%rev_awards ;
600:
601: my $best = $max;
602: my $j=0;
603: my $which;
604: foreach my $award (@$awardref) {
605: if ($awards->{$award} < $best) {
606: $best = $awards->{$award};
607: $which = $j;
608: }
609: $j++;
610: }
611:
612: if (defined($which)) {
613: if (ref($nameref)) {
614: return ($$awardref[$which],$$msgref[$which],$$nameref[$which]);
615: } else {
616: return ($$awardref[$which],$$msgref[$which]);
617: }
618: }
619: return ('ERROR',undef);
620: }
621: }
622:
623: sub decideoutput {
624: my ($award,$awarded,$awardmsg,$solved,$previous,$target)=@_;
625: my $message='';
626: my $button=0;
627: my $previousmsg;
628: my $css_class='orange';
629: my $added_computer_text=0;
630: my %possible_class =
631: ( 'correct' => 'LC_answer_correct',
632: 'charged_try' => 'LC_answer_charged_try',
633: 'not_charged_try' => 'LC_answer_not_charged_try',
634: 'no_grade' => 'LC_answer_no_grade',
635: 'no_message' => 'LC_no_message',
636: );
637:
638: my $part = $Apache::inputtags::part;
639: my $handgrade =
640: ('yes' eq lc(&Apache::lonnet::EXT("resource.$part.handgrade")));
641:
642: my $computer = ($handgrade)? ''
643: : " ".&mt("Computer's answer now shown above.");
644: &Apache::lonxml::debug("handgrade has :$handgrade:");
645:
646: if ($previous) { $previousmsg=&mt('You have entered that answer before'); }
647:
648: if ($solved =~ /^correct/) {
649: $css_class=$possible_class{'correct'};
650: $message=&mt('You are correct.');
651: if ($awarded < 1 && $awarded > 0) {
652: $message=&mt('You are partially correct.');
653: $css_class=$possible_class{'not_charged_try'};
654: } elsif ($awarded < 1) {
655: $message=&mt('Incorrect.');
656: $css_class=$possible_class{'charged_try'};
657: }
658: if ($env{'request.filename'} =~
659: m|/res/lib/templates/examupload.problem$|) {
660: $message = &mt("A score has been assigned.");
661: $added_computer_text=1;
662: } else {
663: if ($target eq 'tex') {
664: $message = '\textbf{'.$message.'}';
665: } else {
666: $message = "<b>".$message."</b>";
667: $message.= $computer;
668: }
669: $added_computer_text=1;
670: if ($awarded > 0) {
671: my ($symb) = &Apache::lonnet::whichuser();
672: if (($symb ne '')
673: &&
674: ($env{'course.'.$env{'request.course.id'}.
675: '.disable_receipt_display'} ne 'yes')) {
676: $message.=(($target eq 'web')?'<br />':' ').
677: &mt('Your receipt is [_1]',
678: (&Apache::lonnet::receipt($Apache::inputtags::part).
679: (($target eq 'web')?&Apache::loncommon::help_open_topic('Receipt'):'')));
680: }
681: }
682: }
683: $button=0;
684: $previousmsg='';
685: } elsif ($solved =~ /^excused/) {
686: if ($target eq 'tex') {
687: $message = ' \textbf{'.&mt('You are excused from the problem.').'} ';
688: } else {
689: $message = "<b>".&mt('You are excused from the problem.')."</b>";
690: }
691: $css_class=$possible_class{'charged_try'};
692: $button=0;
693: $previousmsg='';
694: } elsif ($award eq 'EXACT_ANS' || $award eq 'APPROX_ANS' ) {
695: if ($solved =~ /^incorrect/ || $solved eq '') {
696: $message = &mt("Incorrect").".";
697: $css_class=$possible_class{'charged_try'};
698: $button=1;
699: } else {
700: if ($target eq 'tex') {
701: $message = '\textbf{'.&mt('You are correct.').'}';
702: } else {
703: $message = "<b>".&mt('You are correct.')."</b>";
704: $message.= $computer;
705: }
706: $added_computer_text=1;
707: if ($awarded > 0
708: && $env{'course.'.
709: $env{'request.course.id'}.
710: '.disable_receipt_display'} ne 'yes') {
711: $message.=(($target eq 'web')?'<br />':' ').
712: &mt('Your receipt is [_1]',
713: (&Apache::lonnet::receipt($Apache::inputtags::part).
714: (($target eq 'web')?&Apache::loncommon::help_open_topic('Receipt'):'')));
715: }
716: $css_class=$possible_class{'correct'};
717: $button=0;
718: $previousmsg='';
719: }
720: } elsif ($award eq 'NO_RESPONSE') {
721: $message = '';
722: $css_class=$possible_class{'no_feedback'};
723: $button=1;
724: } elsif ($award eq 'EXTRA_ANSWER') {
725: $message = &mt('Some extra items were submitted.');
726: $css_class=$possible_class{'not_charged_try'};
727: $button = 1;
728: } elsif ($award eq 'MISSING_ANSWER') {
729: $message = &mt('Some items were not submitted.');
730: $css_class=$possible_class{'not_charged_try'};
731: $button = 1;
732: } elsif ($award eq 'ERROR') {
733: $message = &mt('An error occured while grading your answer.');
734: $css_class=$possible_class{'not_charged_try'};
735: $button = 1;
736: } elsif ($award eq 'TOO_LONG') {
737: $message = &mt("The submitted answer was too long.");
738: $css_class=$possible_class{'not_charged_try'};
739: $button=1;
740: } elsif ($award eq 'WANTED_NUMERIC') {
741: $message = &mt("This question expects a numeric answer.");
742: $css_class=$possible_class{'not_charged_try'};
743: $button=1;
744: } elsif ($award eq 'MISORDERED_RANK') {
745: $message = &mt('You have provided an invalid ranking');
746: if ($target ne 'tex') {
747: $message.=', '.&mt('please refer to').' '.&Apache::loncommon::help_open_topic('Ranking_Problems','help on ranking problems');
748: }
749: $css_class=$possible_class{'not_charged_try'};
750: $button=1;
751: } elsif ($award eq 'INVALID_FILETYPE') {
752: $message = &mt('Submission won\'t be graded. The type of file submitted is not allowed.');
753: $css_class=$possible_class{'not_charged_try'};
754: $button=1;
755: } elsif ($award eq 'SIG_FAIL') {
756: my ($used,$min,$max)=split(':',$awardmsg);
757: my $word = ($used < $min) ? 'more' : 'fewer';
758: $message = &mt("Submission not graded. Use $word digits.",$used);
759: $css_class=$possible_class{'not_charged_try'};
760: $button=1;
761: } elsif ($award eq 'UNIT_INVALID_INSTRUCTOR') {
762: $message = &mt('Error in instructor specifed unit. This error has been reported to the instructor.', $awardmsg);
763: if ($target ne 'tex') {$message.=&Apache::loncommon::help_open_topic('Physical_Units');}
764: $css_class=$possible_class{'not_charged_try'};
765: $button=1;
766: } elsif ($award eq 'UNIT_INVALID_STUDENT') {
767: $message = &mt('Unable to interpret units. Computer reads units as "[_1]".',&markup_unit($awardmsg,$target));
768: if ($target ne 'tex') {$message.=&Apache::loncommon::help_open_topic('Physical_Units');}
769: $css_class=$possible_class{'not_charged_try'};
770: $button=1;
771: } elsif ($award eq 'UNIT_FAIL' || $award eq 'UNIT_IRRECONCIBLE') {
772: $message = &mt('Incompatible units. No conversion found between "[_1]" and the required units.',&markup_unit($awardmsg,$target));
773: if ($target ne 'tex') {$message.=&Apache::loncommon::help_open_topic('Physical_Units');}
774: $css_class=$possible_class{'not_charged_try'};
775: $button=1;
776: } elsif ($award eq 'UNIT_NOTNEEDED') {
777: $message = &mt('Only a number required. Computer reads units of "[_1]".',&markup_unit($awardmsg,$target));
778: $css_class=$possible_class{'not_charged_try'};
779: $button=1;
780: } elsif ($award eq 'NO_UNIT') {
781: $message = &mt("Units required").'.';
782: if ($target ne 'tex') {$message.=&Apache::loncommon::help_open_topic('Physical_Units')};
783: $css_class=$possible_class{'not_charged_try'};
784: $button=1;
785: } elsif ($award eq 'COMMA_FAIL') {
786: $message = &mt("Proper comma separation is required").'.';
787: $css_class=$possible_class{'not_charged_try'};
788: $button=1;
789: } elsif ($award eq 'BAD_FORMULA') {
790: $message = &mt("Unable to understand formula");
791: $css_class=$possible_class{'not_charged_try'};
792: $button=1;
793: } elsif ($award eq 'INCORRECT') {
794: $message = &mt("Incorrect").'.';
795: $css_class=$possible_class{'charged_try'};
796: $button=1;
797: } elsif ($award eq 'SUBMITTED') {
798: $message = &mt("Your submission has been recorded.");
799: $css_class=$possible_class{'no_grade'};
800: $button=1;
801: } elsif ($award eq 'DRAFT') {
802: $message = &mt("A draft copy has been saved.");
803: $css_class=$possible_class{'not_charged_try'};
804: $button=1;
805: } elsif ($award eq 'ASSIGNED_SCORE') {
806: $message = &mt("A score has been assigned.");
807: $css_class=$possible_class{'correct'};
808: $button=0;
809: } elsif ($award eq '') {
810: if ($handgrade && $Apache::inputtags::status[-1] eq 'SHOW_ANSWER') {
811: $message = &mt("Nothing submitted.");
812: $css_class=$possible_class{'charged_try'};
813: } else {
814: $css_class=$possible_class{'not_charged_try'};
815: }
816: $button=1;
817: } else {
818: $message = &mt("Unknown message").": $award";
819: $button=1;
820: }
821: my (undef,undef,$domain,$user)=&Apache::lonnet::whichuser();
822: foreach my $resid(@Apache::inputtags::response){
823: if ($Apache::lonhomework::history{"resource.$part.$resid.handback"}) {
824: $message.='<br />';
825: my @files = split(/\s*,\s*/,
826: $Apache::lonhomework::history{"resource.$part.$resid.handback"});
827: my $file_msg;
828: foreach my $file (@files) {
829: $file_msg.= '<br /><a href="/uploaded/'."$domain/$user".'/'.$file.'">'.$file.'</a>';
830: }
831: $message .= &mt('Returned file(s): [_1]',$file_msg);
832: }
833: }
834:
835: if (&Apache::lonhomework::hide_problem_status()
836: && $Apache::inputtags::status[-1] ne 'SHOW_ANSWER'
837: && &hide_award($award)) {
838: $message = &mt("Answer Submitted: Your final submission will be graded after the due date.");
839: $css_class=$possible_class{'no_grade'};
840: $button=1;
841: }
842: if ($Apache::inputtags::status[-1] eq 'SHOW_ANSWER' &&
843: !$added_computer_text && $target ne 'tex') {
844: $message.= $computer;
845: $added_computer_text=1;
846: }
847: return ($button,$css_class,$message,$previousmsg);
848: }
849:
850: sub markup_unit {
851: my ($unit,$target)=@_;
852: if ($target eq 'tex') {
853: return '\texttt{'.&Apache::lonxml::latex_special_symbols($unit).'}';
854: } else {
855: return "<tt>".$unit."</tt>";
856: }
857: }
858:
859: sub removealldata {
860: my ($id)=@_;
861: foreach my $key (keys(%Apache::lonhomework::results)) {
862: if (($key =~ /^resource\.\Q$id\E\./) && ($key !~ /\.collaborators$/)) {
863: &Apache::lonxml::debug("Removing $key");
864: delete($Apache::lonhomework::results{$key});
865: }
866: }
867: }
868:
869: sub hidealldata {
870: my ($id)=@_;
871: foreach my $key (keys(%Apache::lonhomework::results)) {
872: if (($key =~ /^resource\.\Q$id\E\./) && ($key !~ /\.collaborators$/)) {
873: &Apache::lonxml::debug("Hidding $key");
874: my $newkey=$key;
875: $newkey=~s/^(resource\.\Q$id\E\.[^\.]+\.)(.*)$/${1}hidden${2}/;
876: $Apache::lonhomework::results{$newkey}=
877: $Apache::lonhomework::results{$key};
878: delete($Apache::lonhomework::results{$key});
879: }
880: }
881: }
882:
883: sub setgradedata {
884: my ($award,$msg,$id,$previously_used) = @_;
885: if ($Apache::lonhomework::scantronmode &&
886: &Apache::lonnet::validCODE($env{'form.CODE'})) {
887: $Apache::lonhomework::results{"resource.CODE"}=$env{'form.CODE'};
888: } elsif ($Apache::lonhomework::scantronmode &&
889: $env{'form.CODE'} eq '' &&
890: $Apache::lonhomework::history{"resource.CODE"} ne '') {
891: $Apache::lonhomework::results{"resource.CODE"}='';
892: }
893:
894: if (!$Apache::lonhomework::scantronmode &&
895: $Apache::inputtags::status['-1'] ne 'CAN_ANSWER' &&
896: $Apache::inputtags::status['-1'] ne 'CANNOT_ANSWER') {
897: $Apache::lonhomework::results{"resource.$id.afterduedate"}=$award;
898: return '';
899: } elsif ( $Apache::lonhomework::history{"resource.$id.solved"} !~
900: /^correct/
901: || $Apache::lonhomework::scantronmode
902: || &Apache::lonhomework::hide_problem_status() ) {
903: # the student doesn't already have it correct,
904: # or we are in a mode (scantron orno problem status) where a correct
905: # can become incorrect
906: # handle assignment of tries and solved status
907: my $solvemsg;
908: if ($Apache::lonhomework::scantronmode) {
909: $solvemsg='correct_by_scantron';
910: } else {
911: $solvemsg='correct_by_student';
912: }
913: if ($Apache::lonhomework::history{"resource.$id.afterduedate"}) {
914: $Apache::lonhomework::results{"resource.$id.afterduedate"}='';
915: }
916: if ( $award eq 'ASSIGNED_SCORE') {
917: $Apache::lonhomework::results{"resource.$id.tries"} =
918: $Apache::lonhomework::history{"resource.$id.tries"} + 1;
919: $Apache::lonhomework::results{"resource.$id.solved"} =
920: $solvemsg;
921: my $numawards=scalar(@Apache::inputtags::response);
922: $Apache::lonhomework::results{"resource.$id.awarded"} = 0;
923: foreach my $res (@Apache::inputtags::response) {
924: if (defined($Apache::lonhomework::results{"resource.$id.$res.awarded"})) {
925: $Apache::lonhomework::results{"resource.$id.awarded"}+=
926: $Apache::lonhomework::results{"resource.$id.$res.awarded"};
927: } else {
928: $Apache::lonhomework::results{"resource.$id.awarded"}+=
929: &awarddetail_to_awarded($Apache::lonhomework::results{"resource.$id.$res.awarddetail"});
930: }
931: }
932: if ($numawards > 0) {
933: $Apache::lonhomework::results{"resource.$id.awarded"}/=
934: $numawards;
935: }
936: } elsif ( $award eq 'APPROX_ANS' || $award eq 'EXACT_ANS' ) {
937: $Apache::lonhomework::results{"resource.$id.tries"} =
938: $Apache::lonhomework::history{"resource.$id.tries"} + 1;
939: $Apache::lonhomework::results{"resource.$id.solved"} =
940: $solvemsg;
941: $Apache::lonhomework::results{"resource.$id.awarded"} = '1';
942: } elsif ( $award eq 'INCORRECT' ) {
943: $Apache::lonhomework::results{"resource.$id.tries"} =
944: $Apache::lonhomework::history{"resource.$id.tries"} + 1;
945: if (&Apache::lonhomework::hide_problem_status()
946: || $Apache::lonhomework::scantronmode) {
947: $Apache::lonhomework::results{"resource.$id.awarded"} = 0;
948: }
949: $Apache::lonhomework::results{"resource.$id.solved"} =
950: 'incorrect_attempted';
951: } elsif ( $award eq 'SUBMITTED' ) {
952: $Apache::lonhomework::results{"resource.$id.tries"} =
953: $Apache::lonhomework::history{"resource.$id.tries"} + 1;
954: $Apache::lonhomework::results{"resource.$id.solved"} =
955: 'ungraded_attempted';
956: } elsif ( $award eq 'DRAFT' ) {
957: $Apache::lonhomework::results{"resource.$id.solved"} = '';
958: } elsif ( $award eq 'NO_RESPONSE' ) {
959: #no real response so delete any data that got stored
960: &removealldata($id);
961: return '';
962: } else {
963: $Apache::lonhomework::results{"resource.$id.solved"} =
964: 'incorrect_attempted';
965: if (&Apache::lonhomework::show_no_problem_status()
966: || $Apache::lonhomework::scantronmode) {
967: $Apache::lonhomework::results{"resource.$id.tries"} =
968: $Apache::lonhomework::history{"resource.$id.tries"} + 1;
969: $Apache::lonhomework::results{"resource.$id.awarded"} = 0;
970: }
971:
972: if (&Apache::lonhomework::show_some_problem_status()) {
973: # clear out the awarded if they had gotten it wrong/right
974: # and are now in an error mode
975: $Apache::lonhomework::results{"resource.$id.awarded"} = '';
976: }
977: }
978: if (defined($msg)) {
979: $Apache::lonhomework::results{"resource.$id.awardmsg"} = $msg;
980: }
981: # did either of the overall awards chage? If so ignore the
982: # previous check
983: if (($Apache::lonhomework::results{"resource.$id.awarded"} eq
984: $Apache::lonhomework::history{"resource.$id.awarded"}) &&
985: ($Apache::lonhomework::results{"resource.$id.solved"} eq
986: $Apache::lonhomework::history{"resource.$id.solved"})) {
987: # check if this was a previous submission if it was delete the
988: # unneeded data and update the previously_used attribute
989: if ( $previously_used eq 'PREVIOUSLY_USED') {
990: if (&Apache::lonhomework::show_problem_status()) {
991: delete($Apache::lonhomework::results{"resource.$id.tries"});
992: $Apache::lonhomework::results{"resource.$id.previous"} = '1';
993: }
994: } elsif ( $previously_used eq 'PREVIOUSLY_LAST') {
995: #delete all data as they student didn't do anything, but save
996: #the list of collaborators.
997: &removealldata($id);
998: #and since they didn't do anything we were never here
999: return '';
1000: } else {
1001: $Apache::lonhomework::results{"resource.$id.previous"} = '0';
1002: }
1003: }
1004: } elsif ( $Apache::lonhomework::history{"resource.$id.solved"} =~
1005: /^correct/ ) {
1006: #delete all data as they student already has it correct
1007: &removealldata($id);
1008: #and since they didn't do anything we were never here
1009: return '';
1010: }
1011: $Apache::lonhomework::results{"resource.$id.award"} = $award;
1012: if ($award eq 'SUBMITTED') {
1013: &Apache::response::add_to_gradingqueue();
1014: }
1015: }
1016:
1017: sub find_which_previous {
1018: my ($version) = @_;
1019: my $part = $Apache::inputtags::part;
1020: my (@previous_version);
1021: foreach my $resp (@Apache::inputtags::response) {
1022: my $key = "$version:resource.$part.$resp.submission";
1023: my $submission = $Apache::lonhomework::history{$key};
1024: my %previous = &Apache::response::check_for_previous($submission,
1025: $part,$resp,
1026: $version);
1027: push(@previous_version,$previous{'version'});
1028: }
1029: return &previous_match(\@previous_version,
1030: scalar(@Apache::inputtags::response));
1031: }
1032:
1033: sub previous_match {
1034: my ($previous_array,$count) = @_;
1035: my $match = 0;
1036: my @matches;
1037: foreach my $versionar (@$previous_array) {
1038: foreach my $version (@$versionar) {
1039: $matches[$version]++;
1040: }
1041: }
1042: my $which=0;
1043: foreach my $elem (@matches) {
1044: if ($elem eq $count) {
1045: $match=1;
1046: last;
1047: }
1048: $which++;
1049: }
1050: return ($match,$which);
1051: }
1052:
1053: sub grade {
1054: my ($target) = @_;
1055: my $id = $Apache::inputtags::part;
1056: my $response='';
1057: if ( defined $env{'form.submitted'}) {
1058: my (@awards,@msgs);
1059: foreach $response (@Apache::inputtags::response) {
1060: &Apache::lonxml::debug("looking for response.$id.$response.awarddetail");
1061: my $value=$Apache::lonhomework::results{"resource.$id.$response.awarddetail"};
1062: &Apache::lonxml::debug("keeping $value from $response for $id");
1063: push (@awards,$value);
1064: $value=$Apache::lonhomework::results{"resource.$id.$response.awardmsg"};
1065: &Apache::lonxml::debug("got message $value from $response for $id");
1066: push (@msgs,$value);
1067: }
1068: my ($finalaward,$msg) =
1069: &finalizeawards(\@awards,\@msgs,undef,undef,
1070: $Apache::lonhomework::scantronmode);
1071: my $previously_used;
1072: if ( $#Apache::inputtags::previous eq $#awards ) {
1073: my ($match) =
1074: &previous_match(\@Apache::inputtags::previous_version,
1075: scalar(@Apache::inputtags::response));
1076:
1077: if ($match) {
1078: $previously_used = 'PREVIOUSLY_LAST';
1079: foreach my $value (@Apache::inputtags::previous) {
1080: if ($value eq 'PREVIOUSLY_USED' ) {
1081: $previously_used = $value;
1082: last;
1083: }
1084: }
1085: }
1086: }
1087: &Apache::lonxml::debug("final award $finalaward, $previously_used, message $msg");
1088: &setgradedata($finalaward,$msg,$id,$previously_used);
1089: }
1090: return '';
1091: }
1092:
1093: sub get_grade_messages {
1094: my ($id,$prefix,$target,$status) = @_;
1095:
1096: my ($message,$latemessage,$trystr,$previousmsg);
1097: my $showbutton = 1;
1098:
1099: my $award = $Apache::lonhomework::history{"$prefix.award"};
1100: my $awarded = $Apache::lonhomework::history{"$prefix.awarded"};
1101: my $solved = $Apache::lonhomework::history{"$prefix.solved"};
1102: my $previous = $Apache::lonhomework::history{"$prefix.previous"};
1103: my $awardmsg = $Apache::lonhomework::history{"$prefix.awardmsg"};
1104: &Apache::lonxml::debug("Found Award |$award|$solved|$awardmsg");
1105: if ( $award ne '' || $solved ne '' || $status eq 'SHOW_ANSWER') {
1106: &Apache::lonxml::debug('Getting message');
1107: ($showbutton,my $css_class,$message,$previousmsg) =
1108: &decideoutput($award,$awarded,$awardmsg,$solved,$previous,
1109: $target);
1110: if ($target eq 'tex') {
1111: $message='\vskip 2 mm '.$message.' ';
1112: } else {
1113: $message="<td class=\"$css_class\">$message</td>";
1114: if ($previousmsg) {
1115: $previousmsg="<td class=\"LC_answer_previous\">$previousmsg</td>";
1116: }
1117: }
1118: }
1119: my $tries = $Apache::lonhomework::history{"$prefix.tries"};
1120: my $maxtries = &Apache::lonnet::EXT("resource.$id.maxtries");
1121: &Apache::lonxml::debug("got maxtries of :$maxtries:");
1122: #if tries are set to negative turn off the Tries/Button and messages
1123: if (defined($maxtries) && $maxtries < 0) { return ''; }
1124: if ( $tries eq '' ) { $tries = '0'; }
1125: if ( $maxtries eq '' ) { $maxtries = '2'; }
1126: if ( $maxtries eq 'con_lost' ) { $maxtries = '0'; }
1127: my $tries_text=&mt('Tries');
1128: if ( $Apache::lonhomework::type eq 'survey' ||
1129: $Apache::lonhomework::parsing_a_task) {
1130: $tries_text=&mt('Submissions');
1131: }
1132:
1133: if ($showbutton) {
1134: if ($target eq 'tex') {
1135: if ($env{'request.state'} ne "construct"
1136: && $Apache::lonhomework::type ne 'exam'
1137: && $env{'form.suppress_tries'} ne 'yes') {
1138: $trystr = ' {\vskip 1 mm \small \textit{'.$tries_text.'} '.
1139: $tries.'/'.$maxtries.'} \vskip 2 mm ';
1140: } else {
1141: $trystr = '\vskip 0 mm ';
1142: }
1143: } else {
1144: $trystr = "<td><nobr>".$tries_text." $tries";
1145: if ($Apache::lonhomework::parsing_a_task) {
1146: } elsif($env{'request.state'} ne 'construct') {
1147: $trystr.="/$maxtries";
1148: } else {
1149: if (defined($Apache::inputtags::params{'maxtries'})) {
1150: $trystr.="/".$Apache::inputtags::params{'maxtries'};
1151: }
1152: }
1153: $trystr.="</nobr></td>";
1154: }
1155: }
1156:
1157: if ($Apache::lonhomework::history{"$prefix.afterduedate"}) {
1158: #last submissions was after due date
1159: $latemessage=&mt(' The last submission was after the Due Date ');;
1160: if ($target eq 'web') {
1161: $latemessage='<td class="LC_answer_late">'.$latemessage.'</td>';
1162: }
1163: }
1164: return ($previousmsg,$latemessage,$message,$trystr,$showbutton);
1165: }
1166:
1167: sub gradestatus {
1168: my ($id,$target,$no_previous) = @_;
1169: my $showbutton = 1;
1170: my $message = '';
1171: my $latemessage = '';
1172: my $trystr='';
1173: my $button='';
1174: my $previousmsg='';
1175:
1176: my $status = $Apache::inputtags::status['-1'];
1177: &Apache::lonxml::debug("gradestatus has :$status:");
1178: if ( $status ne 'CLOSED'
1179: && $status ne 'UNAVAILABLE'
1180: && $status ne 'INVALID_ACCESS'
1181: && $status ne 'NEEDS_CHECKIN'
1182: && $status ne 'NOT_IN_A_SLOT') {
1183:
1184: ($previousmsg,$latemessage,$message,$trystr) =
1185: &get_grade_messages($id,"resource.$id",$target,$status,
1186: $showbutton);
1187: if ( $status eq 'SHOW_ANSWER' || $status eq 'CANNOT_ANSWER') {
1188: $showbutton = 0;
1189: }
1190: if ( $status eq 'SHOW_ANSWER') {
1191: undef($previousmsg);
1192: }
1193: if ( $showbutton ) {
1194: if ($target ne 'tex') {
1195: $button =
1196: '<input
1197: onmouseup="javascript:setSubmittedPart(\''.$id.'\')"
1198: onsubmit="javascript:setSubmittedPart(\''.$id.'\')"
1199: type="submit" name="submit_'.$id.'"
1200: value="'.&mt('Submit Answer').'" />';
1201: }
1202: }
1203:
1204: }
1205: my $output= $previousmsg.$latemessage.$message.$trystr;
1206: if ($output =~ /^\s*$/) {
1207: return $button;
1208: } else {
1209: if ($target eq 'tex') {
1210: return $button.' \vskip 0 mm '.$output.' ';
1211: } else {
1212: $output =
1213: '<table><tr><td>'.$button.'</td>'.$output;
1214: if (!$no_previous) {
1215: $output.='<td>'.&previous_tries($id,$target).'</td>';
1216: }
1217: $output.= '</tr></table>';
1218: return $output;
1219: }
1220: }
1221: }
1222:
1223: sub previous_tries {
1224: my ($id,$target) = @_;
1225: my $output;
1226: my $status = $Apache::inputtags::status['-1'];
1227:
1228: my $count;
1229: my %count_lookup;
1230:
1231: foreach my $i (1..$Apache::lonhomework::history{'version'}) {
1232: my $prefix = $i.":resource.$id";
1233:
1234: next if (!exists($Apache::lonhomework::history{"$prefix.award"}));
1235: $count++;
1236: $count_lookup{$i} = $count;
1237:
1238: my ($previousmsg,$latemessage,$message,$trystr);
1239:
1240: ($previousmsg,$latemessage,$message,$trystr) =
1241: &get_grade_messages($id,"$prefix",$target,$status);
1242:
1243: if ($previousmsg ne '') {
1244: my ($match,$which) = &find_which_previous($i);
1245: $message=$previousmsg;
1246: my $previous = $count_lookup{$which};
1247: $message =~ s{(</td>)}{ as submission \# $previous $1};
1248: } elsif ($Apache::lonhomework::history{"$prefix.tries"}) {
1249: if (!(&Apache::lonhomework::hide_problem_status()
1250: && $Apache::inputtags::status[-1] ne 'SHOW_ANSWER')
1251: && $Apache::lonhomework::history{"$prefix.solved"} =~/^correct/
1252: ) {
1253:
1254: $message =~ s{(<td.*?>)(.*?)(</td>)}
1255: {$1 <strong>Correct</strong>. $3}s;
1256: }
1257: my $trystr = "(Try ".
1258: $Apache::lonhomework::history{"$prefix.tries"}.')';
1259: $message =~ s{(</td>)}{ $trystr $1};
1260: }
1261: my ($class) = ($message =~ m{<td.*class="([^"]*)"}); #"
1262: $message =~ s{(<td.*?>)}{<td>};
1263:
1264:
1265: $output.='<tr class="'.$class.'">';
1266: $output.='<td align="center">'.$count.'</td>';
1267: $output.=$message;
1268:
1269: foreach my $resid (@Apache::inputtags::response) {
1270: my $prefix = $prefix.".$resid";
1271: if (exists($Apache::lonhomework::history{"$prefix.submission"})) {
1272: my $submission =
1273: $Apache::inputtags::submission_display{"$prefix.submission"};
1274: if (!defined($submission)) {
1275: $submission =
1276: $Apache::lonhomework::history{"$prefix.submission"};
1277: }
1278: $output.='<td>'.$submission.'</td>';
1279: } else {
1280: $output.='<td></td>';
1281: }
1282: }
1283: $output.=&Apache::loncommon::end_data_table_row()."\n";
1284: }
1285: return if ($output eq '');
1286: my $headers =
1287: '<tr>'.'<th>'.&mt('Submission #').'</th><th>'.&mt('Try').
1288: '</th><th colspan="'.scalar(@Apache::inputtags::response).'">'.
1289: &mt('Submitted Answer').'</th>';
1290: $output ='<table class="LC_prior_tries">'.$headers.$output.'</table>';
1291: #return $output;
1292: $output = &Apache::loncommon::js_ready($output);
1293: $output.='<br /><form action=""><center><input type="button" name="close" value="'.&mt('Close Window').'" onClick="window.close()" /></center></form>';
1294:
1295: my $windowopen=&Apache::lonhtmlcommon::javascript_docopen();
1296: my $start_page =
1297: &Apache::loncommon::start_page('Previous Tries', undef,
1298: {'only_body' => 1,
1299: 'bgcolor' => '#FFFFFF',
1300: 'js_ready' => 1,
1301: 'inherit_jsmath' => 1, });
1302: my $end_page =
1303: &Apache::loncommon::end_page({'js_ready' => 1,});
1304: my $prefix = $env{'form.request.prefix'};
1305: $prefix =~ tr{.}{_};
1306: my $function_name = "LONCAPA_previous_tries_".$prefix.
1307: $Apache::lonxml::curdepth.'_'.$env{'form.counter'};
1308: my $result ="<script type=\"text/javascript\">
1309: // <![CDATA[
1310: function $function_name() {newWindow=open('','new_W','width=500,height=500,scrollbars=1,resizable=yes');newWindow.$windowopen;newWindow.document.writeln('$start_page $output $end_page');newWindow.document.close();newWindow.focus()}
1311: // ]]>
1312: </script><a href=\"javascript:$function_name();void(0);\">".&mt("Previous Tries")."</a><br />";
1313: #use Data::Dumper;
1314: #&Apache::lonnet::logthis(&Dumper(\%Apache::inputtags::submission_display));
1315: return $result;
1316: }
1317:
1318: 1;
1319: __END__
1320:
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>