1: # The LearningOnline Network with CAPA
2: # The LON-CAPA Homework handler
3: #
4: # $Id: lonhomework.pm,v 1.106 2003/01/19 08:11:38 albertel Exp $
5: #
6: # Copyright Michigan State University Board of Trustees
7: #
8: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
9: #
10: # LON-CAPA is free software; you can redistribute it and/or modify
11: # it under the terms of the GNU General Public License as published by
12: # the Free Software Foundation; either version 2 of the License, or
13: # (at your option) any later version.
14: #
15: # LON-CAPA is distributed in the hope that it will be useful,
16: # but WITHOUT ANY WARRANTY; without even the implied warranty of
17: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18: # GNU General Public License for more details.
19: #
20: # You should have received a copy of the GNU General Public License
21: # along with LON-CAPA; if not, write to the Free Software
22: # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
23: #
24: # /home/httpd/html/adm/gpl.txt
25: #
26: # http://www.lon-capa.org/
27: #
28: # Guy Albertelli
29: # 11/30 Gerd Kortemeyer
30: # 6/1,8/17,8/18 Gerd Kortemeyer
31: # 7/18 Jeremy Bowers
32:
33: package Apache::lonhomework;
34: use strict;
35: use Apache::style();
36: use Apache::lonxml();
37: use Apache::lonnet();
38: use Apache::lonplot();
39: use Apache::inputtags();
40: use Apache::structuretags();
41: use Apache::randomlabel();
42: use Apache::response();
43: use Apache::hint();
44: use Apache::outputtags();
45: use Apache::caparesponse();
46: use Apache::radiobuttonresponse();
47: use Apache::optionresponse();
48: use Apache::imageresponse();
49: use Apache::essayresponse();
50: use Apache::externalresponse();
51: use Apache::rankresponse();
52: use Apache::Constants qw(:common);
53: use HTML::Entities();
54: use Apache::loncommon();
55: #use Time::HiRes qw( gettimeofday tv_interval );
56:
57: BEGIN {
58: &Apache::lonxml::register_insert();
59: }
60:
61: sub get_target {
62: if ( $ENV{'request.state'} eq "published") {
63: if ( defined($ENV{'form.grade_target'} )
64: && ($ENV{'form.grade_target'} eq 'tex')) {
65: return ($ENV{'form.grade_target'});
66: } elsif ( defined($ENV{'form.grade_target'} )
67: && ($Apache::lonhomework::viewgrades == 'F' )) {
68: return ($ENV{'form.grade_target'});
69: }
70:
71: if ( defined($ENV{'form.submitted'})) {
72: return ('grade', 'web');
73: } else {
74: return ('web');
75: }
76: } elsif ($ENV{'request.state'} eq "construct") {
77: if ( defined($ENV{'form.grade_target'}) ) {
78: return ($ENV{'form.grade_target'});
79: }
80: if ( defined($ENV{'form.preview'})) {
81: if ( defined($ENV{'form.submitted'})) {
82: return ('grade', 'web');
83: } else {
84: return ('web');
85: }
86: } else {
87: if ( $ENV{'form.problemmode'} eq 'View' ||
88: $ENV{'form.problemmode'} eq 'Discard Edits and View') {
89: if ( defined($ENV{'form.submitted'}) &&
90: (!defined($ENV{'form.resetdata'})) ) {
91: return ('grade', 'web','answer');
92: } else {
93: return ('web','answer');
94: }
95: } elsif ( $ENV{'form.problemmode'} eq 'Edit' ) {
96: if ( $ENV{'form.submitted'} eq 'edit' ) {
97: if ( $ENV{'form.submit'} eq 'Submit Changes and View' ) {
98: return ('modified','web','answer');
99: } else {
100: return ('modified','edit');
101: }
102: } else {
103: return ('edit');
104: }
105: } else {
106: return ('web');
107: }
108: }
109: }
110: return ();
111: }
112:
113: sub setup_vars {
114: my ($target) = @_;
115: return ';'
116: # return ';$external::target='.$target.';';
117: }
118:
119: sub send_header {
120: my ($request)= @_;
121: $request->print(&Apache::lontexconvert::header());
122: # $request->print('<form name='.$ENV{'form.request.prefix'}.'lonhomework method="POST" action="'.$request->uri.'">');
123: }
124:
125: sub createmenu {
126: my ($which,$request)=@_;
127: if ($which eq 'grade') {
128: $request->print('<script language="JavaScript">
129: hwkmenu=window.open("/res/adm/pages/homeworkmenu.html","homeworkremote",
130: "height=350,width=150,menubar=no");
131: </script>');
132: }
133: }
134:
135: sub send_footer {
136: my ($request)= @_;
137: # $request->print('</form>');
138: $request->print(&Apache::lontexconvert::footer());
139: }
140:
141: $Apache::lonxml::browse='';
142:
143: # JB, 9/24/2002: Any changes in this function may require a change
144: # in lonnavmaps::resource::getDateStatus.
145: sub check_access {
146: my ($id) = @_;
147: my $date ='';
148: my $status;
149: my $datemsg = '';
150: my $lastdate = '';
151: my $temp;
152: my $type;
153: my $passed;
154:
155: if ($ENV{'request.state'} eq "construct") {
156: &Apache::lonxml::debug("in construction ignoring dates");
157: $status='CAN_ANSWER';
158: $datemsg='is in under construction';
159: return ($status,$datemsg);
160: }
161:
162: &Apache::lonxml::debug("checking for part :$id:");
163: &Apache::lonxml::debug("time:".time);
164: foreach $temp ("opendate","duedate","answerdate") {
165: $lastdate = $date;
166: $date = &Apache::lonnet::EXT("resource.$id.$temp");
167: my $thistype = &Apache::lonnet::EXT("resource.$id.$temp.type");
168: if ($thistype =~ /^(con_lost|no_such_host)/ ||
169: $date =~ /^(con_lost|no_such_host)/) {
170: $status='UNAVAILABLE';
171: $date="may open later.";
172: return($status,$date);
173: }
174: if ($thistype eq 'date_interval') {
175: if ($temp eq 'opendate') {
176: $date=&Apache::lonnet::EXT("resource.$id.duedate")-$date;
177: }
178: if ($temp eq 'answerdate') {
179: $date=&Apache::lonnet::EXT("resource.$id.duedate")+$date;
180: }
181: }
182: &Apache::lonxml::debug("found :$date: for :$temp:");
183: if ($date eq '') {
184: $date = "an unknown date"; $passed = 0;
185: } elsif ($date eq 'con_lost') {
186: $date = "an indeterminate date"; $passed = 0;
187: } else {
188: if (time < $date) { $passed = 0; } else { $passed = 1; }
189: $date = localtime $date;
190: }
191: if (!$passed) { $type=$temp; last; }
192: }
193: &Apache::lonxml::debug("have :$type:$passed:");
194: if ($passed) {
195: $status='SHOW_ANSWER';
196: $datemsg=$date;
197: } elsif ($type eq 'opendate') {
198: $status='CLOSED';
199: $datemsg = "will open on $date";
200: } elsif ($type eq 'duedate') {
201: $status='CAN_ANSWER';
202: $datemsg = "is due at $date";
203: } elsif ($type eq 'answerdate') {
204: $status='CLOSED';
205: $datemsg = "was due on $lastdate, and answers will be available on $date";
206: }
207: if ($status eq 'CAN_ANSWER') {
208: #check #tries
209: my $tries = $Apache::lonhomework::history{"resource.$id.tries"};
210: my $maxtries = &Apache::lonnet::EXT("resource.$id.maxtries");
211: if ( $tries eq '' ) { $tries = '0'; }
212: if ( $maxtries eq '' ) { $maxtries = '2'; }
213: if ($tries >= $maxtries) { $status = 'CANNOT_ANSWER'; }
214: }
215:
216: if (($status ne 'CLOSED') && ($Apache::lonhomework::type eq 'exam') &&
217: (!$Apache::lonhomework::history{"resource.0.outtoken"})) {
218: return ('UNCHECKEDOUT','needs to be checked out');
219: }
220:
221:
222: &Apache::lonxml::debug("sending back :$status:$datemsg:");
223: if (($Apache::lonhomework::browse eq 'F') && ($status eq 'CLOSED')) {
224: &Apache::lonxml::debug("should be allowed to browse a resource when closed");
225: $status='CAN_ANSWER';
226: $datemsg='is closed but you are allowed to view it';
227: }
228:
229: return ($status,$datemsg);
230: }
231:
232: sub showhash {
233: my (%hash) = @_;
234: &showhashsubset(\%hash,'.');
235: return '';
236: }
237:
238: sub showarray {
239: my ($array)=@_;
240: my $string="(";
241: foreach my $elm (@{ $array }) {
242: if (ref($elm)) {
243: if ($elm =~ /ARRAY/ ) {
244: $string.=&showarray($elm);
245: }
246: } else {
247: $string.="$elm,"
248: }
249: }
250: chop($string);
251: $string.=")";
252: return $string;
253: }
254:
255: sub showhashsubset {
256: my ($hash,$keyre) = @_;
257: my $resultkey;
258: foreach $resultkey (sort keys %$hash) {
259: if ($resultkey =~ /$keyre/) {
260: if (ref($$hash{$resultkey})) {
261: if ($$hash{$resultkey} =~ /ARRAY/ ) {
262: &Apache::lonxml::debug("$resultkey ---- ".
263: &showarray($$hash{$resultkey}));
264: } elsif ($$hash{$resultkey} =~ /HASH/ ) {
265: &Apache::lonxml::debug("$resultkey ---- $$hash{$resultkey}");
266: &showhashsubset($$hash{$resultkey},'.');
267: } else {
268: &Apache::lonxml::debug("$resultkey ---- $$hash{$resultkey}");
269: }
270: } else {
271: &Apache::lonxml::debug("$resultkey ---- $$hash{$resultkey}");
272: }
273: }
274: }
275: &Apache::lonxml::debug("\n<br />restored values^</br>\n");
276: return '';
277: }
278:
279: sub setuppermissions {
280: $Apache::lonhomework::browse= &Apache::lonnet::allowed('bre',$ENV{'request.filename'});
281: $Apache::lonhomework::viewgrades=&Apache::lonnet::allowed('vgr',$ENV{'request.course.id'});
282: return ''
283: }
284:
285: sub setupheader {
286: my $request=$_[0];
287: if ($ENV{'browser.mathml'}) {
288: $request->content_type('text/xml');
289: } else {
290: $request->content_type('text/html');
291: }
292: if (!$Apache::lonxml::debug && ($ENV{'REQUEST_METHOD'} eq 'GET')) {
293: &Apache::loncommon::no_cache($request);
294: }
295: $request->send_http_header;
296: return OK if $request->header_only;
297: return ''
298: }
299:
300: sub handle_save_or_undo {
301: my ($request,$problem,$result) = @_;
302: my $file = &Apache::lonnet::filelocation("",$request->uri);
303: my $filebak =$file.".bak";
304: my $filetmp =$file.".tmp";
305: my $error=0;
306:
307: if ($ENV{'form.Undo'} eq 'undo') {
308: my $error=0;
309: if (!copy($file,$filetmp)) { $error=1; }
310: if ((!$error) && (!copy($filebak,$file))) { $error=1; }
311: if ((!$error) && (!move($filetmp,$filebak))) { $error=1; }
312: if (!$error) {
313: $request->print("<p><b>Undid changes, Switched $filebak and $file</b></p>");
314: } else {
315: $request->print("<p><font color=\"red\" size=\"+1\"><b>Unable to undo, unable to switch $filebak and $file</b></font></p>");
316: $error=1;
317: }
318: } else {
319: my $fs=Apache::File->new(">$filebak");
320: if (defined($fs)) {
321: print $fs $$problem;
322: $request->print("<b>Making Backup to $filebak</b><br />");
323: } else {
324: $request->print("<font color=\"red\" size=\"+1\"><b>Unable to make backup $filebak</b></font>");
325: $error=2;
326: }
327: my $fh=Apache::File->new(">$file");
328: if (defined($fh)) {
329: print $fh $$result;
330: $request->print("<b>Saving Modifications to $file</b><br />");
331: } else {
332: $request->print("<font color=\"red\" size=\"+1\"><b>Unable to write to $file</b></font>");
333: $error|=4;
334: }
335: }
336: return $error;
337: }
338:
339: sub analyze_header {
340: my ($request) = @_;
341: my $result.='<html><body bgcolor="#FFFFFF">
342: <form name="lonhomework" method="POST" action="'.
343: $ENV{'request.uri'}.'">
344: <input type="submit" name="problemmode" value="EditXML" />
345: <input type="submit" name="problemmode" value="Edit" />
346: <hr />
347: <input type="submit" name="submit" value="View" />
348: <hr />
349: List of possible answers:
350: </form>';
351: $request->print($result);
352: $request->rflush();
353: }
354:
355: sub analyze {
356: my ($request,$file) = @_;
357: &Apache::lonxml::debug("Analyze");
358: my $result;
359: my %overall;
360: my %allparts;
361: my $rndseed=$ENV{'form.rndseed'};
362: &analyze_header($request);
363: for(my $i=1;$i<$ENV{'form.numtoanalyze'}+1;$i++) {
364: my $subresult=&Apache::lonnet::ssi($request->uri,
365: ('grade_target' => 'analyze'),
366: ('rndseed' => $i));
367: &Apache::lonxml::debug(":$subresult:");
368: (my $garbage,$subresult)=split(/_HASH_REF__/,$subresult,2);
369: my %analyze=&Apache::lonnet::str2hash($subresult);
370: &Apache::lonhomework::showhash(%analyze);
371: my @parts = @{ $analyze{'parts'} };
372: foreach my $part (@parts) {
373: if (!exists($allparts{$part})) {$allparts{$part}=1;};
374: if ($analyze{$part.'.type'} eq 'numericalresponse') {
375: push( @{ $overall{$part.'.answer'} },
376: [@{ $analyze{$part.'.answer'} }]);
377: }
378: }
379: }
380: foreach my $part (keys(%allparts)) {
381: $request->print('<table><tr><td>Part '.$part.'</td></tr>');
382: foreach my $answer (sort {$a->[0] <=> $b->[0]} (@{ $overall{$part.'.answer'} })) {
383: $request->print('<tr><td>'.join('</td><td>',@{ $answer }).
384: '</td></tr>');
385: }
386: }
387: &Apache::lonhomework::showhash(%overall);
388: return $result;
389: }
390:
391: sub editxmlmode {
392: my ($request,$file) = @_;
393: my $result;
394: my $problem=&Apache::lonnet::getfile($file);
395: if ($problem == -1) {
396: &Apache::lonxml::error("<b> Unable to find <i>$file</i></b>");
397: $problem='';
398: }
399: if (defined($ENV{'form.editxmltext'}) || defined($ENV{'form.Undo'})) {
400: my $error=&handle_save_or_undo($request,\$problem,
401: \$ENV{'form.editxmltext'});
402: if (!$error) { $problem=&Apache::lonnet::getfile($file); }
403: }
404: &Apache::lonhomework::showhashsubset(\%ENV,'^form');
405: if ( $ENV{'form.submit'} eq 'Submit Changes and View' ) {
406: &Apache::lonhomework::showhashsubset(\%ENV,'^form');
407: $ENV{'form.problemmode'}='View';
408: &renderpage($request,$file);
409: } else {
410: my ($rows,$cols) = &Apache::edit::textarea_sizes(\$problem);
411: my $xml_help = Apache::loncommon::help_open_topic("Problem_Editor_XML_Index");
412: if ($cols > 80) { $cols = 80; }
413: if ($cols < 70) { $cols = 70; }
414: if ($rows < 20) { $rows = 20; }
415: $result.='<html><body bgcolor="#FFFFFF">
416: <form name="lonhomework" method="POST" action="'.
417: $ENV{'request.uri'}.'">
418: <input type="hidden" name="problemmode" value="EditXML" />
419: <input type="submit" name="problemmode" value="Discard Edits and View" />
420: <input type="submit" name="problemmode" value="Edit" />
421: <hr />
422: <input type="submit" name="submit" value="Submit Changes" />
423: <input type="submit" name="submit" value="Submit Changes and View" />
424: <input type="submit" name="Undo" value="undo" />
425: <hr />
426: ' . $xml_help . ' Problem Help<br>
427: <textarea rows="'.$rows.'" cols="'.$cols.'" name="editxmltext">'.
428: &HTML::Entities::encode($problem).'</textarea>
429: </form></body></html>';
430: $request->print($result);
431: }
432: return '';
433: }
434:
435: sub renderpage {
436: my ($request,$file) = @_;
437:
438: my (@targets) = &get_target();
439: &Apache::lonxml::debug("Running targets ".join(':',@targets));
440: foreach my $target (@targets) {
441: #my $t0 = [&gettimeofday()];
442: my $problem=&Apache::lonnet::getfile($file);
443: if ($problem == -1) {
444: &Apache::lonxml::error("<b> Unable to find <i>$file</i></b>");
445: $problem='';
446: }
447:
448: my %mystyle;
449: my $result = '';
450: &Apache::inputtags::initialize_inputtags();
451: &Apache::outputtags::initialize_outputtags();
452: &Apache::edit::initialize_edit();
453: if ($target eq 'analyze') { %Apache::lonhomework::anaylze=(); }
454: if ($target eq 'answer') { &showhash(%Apache::lonhomework::history); }
455: if ($target eq 'web') {&Apache::lonhomework::showhashsubset(\%ENV,'^form');}
456:
457: &Apache::lonxml::debug("Should be parsing now");
458: $result = &Apache::lonxml::xmlparse($request, $target, $problem,
459: &setup_vars($target),%mystyle);
460:
461: #$request->print("Result follows:");
462: if ($target eq 'modified') {
463: &handle_save_or_undo($request,\$problem,\$result);
464: } else {
465: if ($target eq 'analyze') {
466: $result=&Apache::lonnet::hashref2str(\%Apache::lonhomework::analyze);
467: undef(%Apache::lonhomework::analyze);
468: }
469: #my $td=&tv_interval($t0);
470: #if ( $Apache::lonxml::debug) {
471: #$result =~ s:</body>::;
472: #$result.="<br />Spent $td seconds processing target $target\n</body>";
473: #}
474: $request->print($result);
475: }
476: #$request->print(":Result ends");
477: #my $td=&tv_interval($t0);
478: }
479: }
480:
481: # with no arg it returns a HTML <option> list of the template titles
482: # with one arg it returns the filename associated with the arg passed
483: sub get_template_list {
484: my ($namewanted,$extension) = @_;
485: my $result;
486: my @allnames;
487: &Apache::lonxml::debug("Looking for :$extension:");
488: foreach my $file (</home/httpd/html/res/adm/includes/templates/*.$extension>) {
489: my $name=&Apache::lonnet::metadata($file,'title');
490: if ($namewanted && ($name eq $namewanted)) {
491: $result=$file;
492: last;
493: } else {
494: if ($name) { push (@allnames, $name); }
495: }
496: }
497: if (@allnames && !$result) {
498: $result="<option>Select a $extension type</option>\n<option>".
499: join('</option><option>',sort(@allnames)).'</option>';
500: }
501: return $result;
502: }
503:
504: sub newproblem {
505: my ($request) = @_;
506: my $extension=$request->uri;
507: $extension=~s:^.*\.([\w]+)$:$1:;
508: &Apache::lonxml::debug("Looking for :$extension:");
509: if ($ENV{'form.template'} &&
510: $ENV{'form.template'} ne "Select a $extension type") {
511: use File::Copy;
512: my $file = &get_template_list($ENV{'form.template'},$extension);
513: my $dest = &Apache::lonnet::filelocation("",$request->uri);
514: copy($file,$dest);
515: &renderpage($request,$dest);
516: } elsif($ENV{'form.newfile'}) {
517: # I don't like hard-coded filenames but for now, this will work.
518: use File::Copy;
519: my $templatefilename =
520: $request->dir_config('lonIncludes').'/templates/blank.problem';
521: &Apache::lonxml::debug("$templatefilename");
522: my $dest = &Apache::lonnet::filelocation("",$request->uri);
523: copy($templatefilename,$dest);
524: &renderpage($request,$dest);
525: } else {
526: my $templatelist=&get_template_list('',$extension);
527: my $url=$request->uri;
528: my $dest = &Apache::lonnet::filelocation("",$request->uri);
529: my $instructions;
530: if ($templatelist) { $instructions=", select a template from the pull-down menu below.<br />Then";}
531: $request->print(<<ENDNEWPROBLEM);
532: <body bgcolor="#FFFFFF">
533: <h1>Creating a new $extension resource</h1>
534: The requested file <tt>$url</tt> currently does not exist.
535: <p>
536: To create a new $extension$instructions click on the "Create $extension" button.
537: </p>
538: <p><form action="$url" method="POST">
539: ENDNEWPROBLEM
540: if (defined($templatelist)) {
541: $request->print("<select name=\"template\">$templatelist</select>");
542: }
543: $request->print("<br /><input type=\"submit\" name=\"newfile\" value=\"Create $extension\" />");
544: $request->print("</form></p></body>");
545: }
546: return '';
547: }
548:
549: sub view_or_edit_menu {
550: my ($request) = @_;
551: my $url=$request->uri;
552: $request->print(<<EDITMENU);
553: <body bgcolor="#FFFFFF">
554: <form action="$url" method="POST">
555: Would you like to <input type="submit" name="problemmode" value="View"> or
556: <input type="submit" name="problemmode" value="Edit"> the problem.
557: </form>
558: </body>
559: EDITMENU
560: }
561:
562: sub handler {
563: #my $t0 = [&gettimeofday()];
564: my $request=$_[0];
565:
566: # if ( $ENV{'user.name'} eq 'albertel' ) {$Apache::lonxml::debug=1;}
567: $Apache::lonxml::debug=$ENV{'user.debug'};
568:
569: if (&setupheader($request)) { return OK; }
570: $ENV{'request.uri'}=$request->uri;
571:
572: #setup permissions
573: $Apache::lonhomework::browse= &Apache::lonnet::allowed('bre',$ENV{'request.filename'});
574: $Apache::lonhomework::viewgrades=&Apache::lonnet::allowed('vgr',$ENV{'request.course.id'});
575: &Apache::lonxml::debug("Permissions:$Apache::lonhomework::browse:$Apache::lonhomework::viewgrades:");
576: # some times multiple problemmodes are submitted, need to select
577: # the last one
578: &Apache::lonxml::debug("Problem Mode ".$ENV{'form.problemmode'});
579: if ( defined($ENV{'form.problemmode'}) &&
580: ref($ENV{'form.problemmode'}) ) {
581: &Apache::lonxml::debug("Problem Mode ".join(",",@$ENV{'form.problemmode'}));
582: my $mode=$ENV{'form.problemmode'}->[-1];
583: undef $ENV{'form.problemmode'};
584: $ENV{'form.problemmode'}=$mode;
585: }
586: &Apache::lonxml::debug("Problem Mode ".$ENV{'form.problemmode'});
587: my $file=&Apache::lonnet::filelocation("",$request->uri);
588:
589: #check if we know where we are
590: if ($ENV{'request.course.fn'} && !&Apache::lonnet::symbread()) {
591: # if we are browsing we might not be able to know where we are
592: if ($Apache::lonhomework::browse ne 'F') {
593: #should know where we are, so ask
594: $request->internal_redirect('/adm/ambiguous'); return;
595: }
596: }
597:
598: if ($ENV{'request.state'} eq "construct") {
599: if ($ENV{'form.resetdata'} eq 'Reset Submissions') {
600: my ($symb,$courseid,$domain,$name) = &Apache::lonxml::whichuser();
601: &Apache::lonnet::tmpreset($symb,'',$domain,$name);
602: }
603: if ( -e $file ) {
604: if (!(defined $ENV{'form.problemmode'})) {
605: #first visit to problem in construction space
606: #&view_or_edit_menu($request);
607: $ENV{'form.problemmode'}='View';
608: &renderpage($request,$file);
609: } elsif ($ENV{'form.problemmode'} eq 'EditXML') {
610: &editxmlmode($request,$file);
611: } elsif ($ENV{'form.problemmode'} eq 'Answer Distribution') {
612: &analyze($request,$file);
613: } else {
614: &renderpage($request,$file);
615: }
616: } else {
617: # requested file doesn't exist in contruction space
618: &newproblem($request);
619: }
620: } else {
621: # just render the page normally outside of construction space
622: &Apache::lonxml::debug("not construct");
623: &renderpage($request,$file);
624: }
625: #my $td=&tv_interval($t0);
626: #&Apache::lonxml::debug("Spent $td seconds processing");
627: # &Apache::lonhomework::send_footer($request);
628: # always turn off debug messages
629: $Apache::lonxml::debug=0;
630: return OK;
631:
632: }
633:
634: 1;
635: __END__
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>