1: # The LearningOnline Network with CAPA
2: # The LON-CAPA Homework handler
3: #
4: # $Id: lonhomework.pm,v 1.182 2004/10/18 18:08:54 albertel Exp $
5: #
6: # Copyright Michigan State University Board of Trustees
7: #
8: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
9: #
10: # LON-CAPA is free software; you can redistribute it and/or modify
11: # it under the terms of the GNU General Public License as published by
12: # the Free Software Foundation; either version 2 of the License, or
13: # (at your option) any later version.
14: #
15: # LON-CAPA is distributed in the hope that it will be useful,
16: # but WITHOUT ANY WARRANTY; without even the implied warranty of
17: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18: # GNU General Public License for more details.
19: #
20: # You should have received a copy of the GNU General Public License
21: # along with LON-CAPA; if not, write to the Free Software
22: # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
23: #
24: # /home/httpd/html/adm/gpl.txt
25: #
26: # http://www.lon-capa.org/
27:
28:
29: package Apache::lonhomework;
30: use strict;
31: use Apache::style();
32: use Apache::lonxml();
33: use Apache::lonnet();
34: use Apache::lonplot();
35: use Apache::inputtags();
36: use Apache::structuretags();
37: use Apache::randomlabel();
38: use Apache::response();
39: use Apache::hint();
40: use Apache::outputtags();
41: use Apache::caparesponse();
42: use Apache::radiobuttonresponse();
43: use Apache::optionresponse();
44: use Apache::imageresponse();
45: use Apache::essayresponse();
46: use Apache::externalresponse();
47: use Apache::rankresponse();
48: use Apache::matchresponse();
49: use Apache::chemresponse();
50: use Apache::drawimage();
51: use Apache::Constants qw(:common);
52: use HTML::Entities();
53: use Apache::loncommon();
54: use Apache::lonlocal;
55: use Time::HiRes qw( gettimeofday tv_interval );
56:
57: BEGIN {
58: &Apache::lonxml::register_insert();
59: }
60:
61: sub get_target {
62: if (($ENV{'request.state'} eq "published") ||
63: ($ENV{'request.state'} eq "uploaded")) {
64: if ( defined($ENV{'form.grade_target'} )
65: && ($ENV{'form.grade_target'} eq 'tex')) {
66: return ($ENV{'form.grade_target'});
67: } elsif ( defined($ENV{'form.grade_target'} )
68: && ($Apache::lonhomework::viewgrades eq 'F' )) {
69: return ($ENV{'form.grade_target'});
70: }
71:
72: if ( defined($ENV{'form.submitted'}) &&
73: ( !defined($ENV{'form.resetdata'})) &&
74: ( !defined($ENV{'form.newrandomization'}))) {
75: return ('grade', 'web');
76: } else {
77: return ('web');
78: }
79: } elsif ($ENV{'request.state'} eq "construct") {
80: if ( defined($ENV{'form.grade_target'}) ) {
81: return ($ENV{'form.grade_target'});
82: }
83: if ( defined($ENV{'form.preview'})) {
84: if ( defined($ENV{'form.submitted'})) {
85: return ('grade', 'web');
86: } else {
87: return ('web');
88: }
89: } else {
90: if ( $ENV{'form.problemmode'} eq &mt('View') ||
91: $ENV{'form.problemmode'} eq &mt('Discard Edits and View')) {
92: if ( defined($ENV{'form.submitted'}) &&
93: (!defined($ENV{'form.resetdata'})) &&
94: (!defined($ENV{'form.newrandomization'}))) {
95: return ('grade', 'web','answer');
96: } else {
97: return ('web','answer');
98: }
99: } elsif ( $ENV{'form.problemmode'} eq &mt('Edit') ) {
100: if ( $ENV{'form.submitted'} eq 'edit' ) {
101: if ( $ENV{'form.submit'} eq &mt('Submit Changes and View') ) {
102: return ('modified','web','answer');
103: } else {
104: return ('modified','edit');
105: }
106: } else {
107: return ('edit');
108: }
109: } else {
110: return ('web');
111: }
112: }
113: }
114: return ();
115: }
116:
117: sub setup_vars {
118: my ($target) = @_;
119: return ';'
120: # return ';$external::target='.$target.';';
121: }
122:
123: sub send_header {
124: my ($request)= @_;
125: $request->print(&Apache::lontexconvert::header());
126: # $request->print('<form name='.$ENV{'form.request.prefix'}.'lonhomework method="POST" action="'.$request->uri.'">');
127: }
128:
129: sub createmenu {
130: my ($which,$request)=@_;
131: if ($which eq 'grade') {
132: $request->print('<script language="JavaScript">
133: hwkmenu=window.open("/res/adm/pages/homeworkmenu.html","homeworkremote",
134: "height=350,width=150,menubar=no");
135: </script>');
136: }
137: }
138:
139: sub send_footer {
140: my ($request)= @_;
141: # $request->print('</form>');
142: $request->print(&Apache::lontexconvert::footer());
143: }
144:
145: $Apache::lonxml::browse='';
146:
147: sub check_ip_acc {
148: my ($acc)=@_;
149: if (!defined($acc) || $acc =~ /^\s*$/) { return 1; }
150: my $allowed=0;
151: my $ip=$ENV{'REMOTE_ADDR'};
152: my $name;
153: foreach my $pattern (split(',',$acc)) {
154: if ($pattern =~ /\*$/) {
155: #35.8.*
156: $pattern=~s/\*//;
157: if ($ip =~ /^\Q$pattern\E/) { $allowed=1; }
158: } elsif ($pattern =~ /(\d+\.\d+\.\d+)\.\[(\d+)-(\d+)\]$/) {
159: #35.8.3.[34-56]
160: my $low=$2;
161: my $high=$3;
162: $pattern=$1;
163: if ($ip =~ /^\Q$pattern\E/) {
164: my $last=(split(/\./,$ip))[3];
165: if ($last <=$high && $last >=$low) { $allowed=1; }
166: }
167: } elsif ($pattern =~ /^\*/) {
168: #*.msu.edu
169: $pattern=~s/\*//;
170: if (!defined($name)) {
171: use Socket;
172: my $netaddr=inet_aton($ip);
173: ($name)=gethostbyaddr($netaddr,AF_INET);
174: }
175: if ($name =~ /\Q$pattern\E$/i) { $allowed=1; }
176: } elsif ($pattern =~ /\d+\.\d+\.\d+\.\d+/) {
177: #127.0.0.1
178: if ($ip =~ /^\Q$pattern\E/) { $allowed=1; }
179: } else {
180: #some.name.com
181: if (!defined($name)) {
182: use Socket;
183: my $netaddr=inet_aton($ip);
184: ($name)=gethostbyaddr($netaddr,AF_INET);
185: }
186: if ($name =~ /\Q$pattern\E$/i) { $allowed=1; }
187: }
188: if ($allowed) { last; }
189: }
190: return $allowed;
191: }
192: # JB, 9/24/2002: Any changes in this function may require a change
193: # in lonnavmaps::resource::getDateStatus.
194: sub check_access {
195: my ($id) = @_;
196: my $date ='';
197: my $status;
198: my $datemsg = '';
199: my $lastdate = '';
200: my $temp;
201: my $type;
202: my $passed;
203:
204: if ($ENV{'request.state'} eq "construct") {
205: if ($ENV{'form.problemstate'}) {
206: if ($ENV{'form.problemstate'} =~ /^CANNOT_ANSWER/) {
207: if ( ! ($ENV{'form.problemstate'} eq 'CANNOT_ANSWER_correct' &&
208: lc($Apache::lonhomework::problemstatus) eq 'no')) {
209: return ('CANNOT_ANSWER',
210: &mt('is in this state due to author settings.'));
211: }
212: } else {
213: return ($ENV{'form.problemstate'},
214: &mt('is in this state due to author settings.'));
215: }
216: }
217: &Apache::lonxml::debug("in construction ignoring dates");
218: $status='CAN_ANSWER';
219: $datemsg=&mt('is in under construction');
220: # return ($status,$datemsg);
221: }
222:
223: &Apache::lonxml::debug("checking for part :$id:");
224: &Apache::lonxml::debug("time:".time);
225:
226: if ($ENV{'request.state'} ne "construct") {
227: my $allowed=&check_ip_acc(&Apache::lonnet::EXT("resource.$id.acc"));
228: if (!$allowed && ($Apache::lonhomework::browse ne 'F')) {
229: $status='INVALID_ACCESS';
230: $date=&mt("can not be accessed from your location.");
231: return($status,$date);
232: }
233:
234: foreach $temp ("opendate","duedate","answerdate") {
235: $lastdate = $date;
236: $date = &Apache::lonnet::EXT("resource.$id.$temp");
237: my $thistype = &Apache::lonnet::EXT("resource.$id.$temp.type");
238: if ($thistype =~ /^(con_lost|no_such_host)/ ||
239: $date =~ /^(con_lost|no_such_host)/) {
240: $status='UNAVAILABLE';
241: $date=&mt("may open later.");
242: return($status,$date);
243: }
244: if ($thistype eq 'date_interval') {
245: if ($temp eq 'opendate') {
246: $date=&Apache::lonnet::EXT("resource.$id.duedate")-$date;
247: }
248: if ($temp eq 'answerdate') {
249: $date=&Apache::lonnet::EXT("resource.$id.duedate")+$date;
250: }
251: }
252: &Apache::lonxml::debug("found :$date: for :$temp:");
253: if ($date eq '') {
254: $date = &mt("an unknown date"); $passed = 0;
255: } elsif ($date eq 'con_lost') {
256: $date = &mt("an indeterminate date"); $passed = 0;
257: } else {
258: if (time < $date) { $passed = 0; } else { $passed = 1; }
259: $date = localtime $date;
260: }
261: if (!$passed) { $type=$temp; last; }
262: }
263: &Apache::lonxml::debug("have :$type:$passed:");
264: if ($passed) {
265: $status='SHOW_ANSWER';
266: $datemsg=$date;
267: } elsif ($type eq 'opendate') {
268: $status='CLOSED';
269: $datemsg = &mt("will open on")." $date";
270: } elsif ($type eq 'duedate') {
271: $status='CAN_ANSWER';
272: $datemsg = &mt("is due at")." $date";
273: } elsif ($type eq 'answerdate') {
274: $status='CLOSED';
275: $datemsg = &mt("was due on")." $lastdate".&mt(", and answers will be available on")." $date";
276: }
277: }
278: if ($status eq 'CAN_ANSWER') {
279: #check #tries, and if correct.
280: my $tries = $Apache::lonhomework::history{"resource.$id.tries"};
281: my $maxtries = &Apache::lonnet::EXT("resource.$id.maxtries");
282: if ( $tries eq '' ) { $tries = '0'; }
283: if ( $maxtries eq '' &&
284: $ENV{'request.state'} ne 'construct') { $maxtries = '2'; }
285: if ($maxtries && $tries >= $maxtries) { $status = 'CANNOT_ANSWER'; }
286: # if (correct and show prob status) or excused then CANNOT_ANSWER
287: if(($Apache::lonhomework::history{"resource.$id.solved"}=~/^correct/
288: &&
289: lc($Apache::lonhomework::problemstatus) ne 'no')
290: ||
291: $Apache::lonhomework::history{"resource.$id.solved"}=~/^excused/) {
292: $status = 'CANNOT_ANSWER';
293: }
294: }
295: if ($status eq 'CAN_ANSWER' || $status eq 'CANNOT_ANSWER') {
296: my $interval=&Apache::lonnet::EXT("resource.$id.interval");
297: &Apache::lonxml::debug("looking for interval $interval");
298: if ($interval) {
299: my $first_access=&Apache::lonnet::get_first_access('map');
300: &Apache::lonxml::debug("looking for accesstime $first_access");
301: if (!$first_access) {
302: $status='NOT_YET_VIEWED';
303: $datemsg=' '.$interval.' seconds';
304: } else {
305: my $newdate=localtime($first_access+$interval);
306: if (time > ($first_access+$interval)) {
307: $status='CLOSED';
308: $datemsg = &mt("was due on")." $newdate".&mt(", and answers will be available on")." $date";
309: } else {
310: $datemsg = &mt("is due at")." $newdate";
311: }
312: }
313: }
314: }
315: #if (($status ne 'CLOSED') && ($Apache::lonhomework::type eq 'exam') &&
316: # (!$Apache::lonhomework::history{"resource.0.outtoken"})) {
317: # return ('UNCHECKEDOUT','needs to be checked out');
318: #}
319:
320:
321: &Apache::lonxml::debug("sending back :$status:$datemsg:");
322: if (($Apache::lonhomework::browse eq 'F') && ($status eq 'CLOSED')) {
323: &Apache::lonxml::debug("should be allowed to browse a resource when closed");
324: $status='CAN_ANSWER';
325: $datemsg=&mt('is closed but you are allowed to view it');
326: }
327:
328: return ($status,$datemsg);
329: }
330:
331: sub showhash {
332: my (%hash) = @_;
333: &showhashsubset(\%hash,'.');
334: return '';
335: }
336:
337: sub showarray {
338: my ($array)=@_;
339: my $string="(";
340: foreach my $elm (@{ $array }) {
341: if (ref($elm)) {
342: if ($elm =~ /ARRAY/ ) {
343: $string.=&showarray($elm);
344: }
345: } else {
346: $string.="$elm,"
347: }
348: }
349: chop($string);
350: $string.=")";
351: return $string;
352: }
353:
354: sub showhashsubset {
355: my ($hash,$keyre) = @_;
356: my $resultkey;
357: foreach $resultkey (sort keys %$hash) {
358: if ($resultkey =~ /$keyre/) {
359: if (ref($$hash{$resultkey})) {
360: if ($$hash{$resultkey} =~ /ARRAY/ ) {
361: &Apache::lonxml::debug("$resultkey ---- ".
362: &showarray($$hash{$resultkey}));
363: } elsif ($$hash{$resultkey} =~ /HASH/ ) {
364: &Apache::lonxml::debug("$resultkey ---- $$hash{$resultkey}");
365: &showhashsubset($$hash{$resultkey},'.');
366: } else {
367: &Apache::lonxml::debug("$resultkey ---- $$hash{$resultkey}");
368: }
369: } else {
370: &Apache::lonxml::debug("$resultkey ---- $$hash{$resultkey}");
371: }
372: }
373: }
374: &Apache::lonxml::debug("\n<br />restored values^</br>\n");
375: return '';
376: }
377:
378: sub setuppermissions {
379: $Apache::lonhomework::browse= &Apache::lonnet::allowed('bre',$ENV{'request.filename'});
380: my $viewgrades = &Apache::lonnet::allowed('vgr',$ENV{'request.course.id'});
381: if (! $viewgrades &&
382: exists($ENV{'request.course.sec'}) &&
383: $ENV{'request.course.sec'} !~ /^\s*$/) {
384: $viewgrades = &Apache::lonnet::allowed('vgr',$ENV{'request.course.id'}.
385: '/'.$ENV{'request.course.sec'});
386: }
387: $Apache::lonhomework::viewgrades = $viewgrades;
388: return ''
389: }
390:
391: sub setupheader {
392: my $request=$_[0];
393: if ($ENV{'browser.mathml'}) {
394: &Apache::loncommon::content_type($request,'text/xml');
395: } else {
396: &Apache::loncommon::content_type($request,'text/html');
397: }
398: if (!$Apache::lonxml::debug && ($ENV{'REQUEST_METHOD'} eq 'GET')) {
399: &Apache::loncommon::no_cache($request);
400: }
401: $request->send_http_header;
402: return OK if $request->header_only;
403: return ''
404: }
405:
406: sub handle_save_or_undo {
407: my ($request,$problem,$result) = @_;
408: my $file = &Apache::lonnet::filelocation("",$request->uri);
409: my $filebak =$file.".bak";
410: my $filetmp =$file.".tmp";
411: my $error=0;
412:
413: &Apache::lonnet::correct_line_ends($result);
414:
415: if ($ENV{'form.Undo'} eq &mt('undo')) {
416: my $error=0;
417: if (!copy($file,$filetmp)) { $error=1; }
418: if ((!$error) && (!copy($filebak,$file))) { $error=1; }
419: if ((!$error) && (!move($filetmp,$filebak))) { $error=1; }
420: if (!$error) {
421: &Apache::lonxml::info("<p><b>".&mt("Undid changes, Switched")." $filebak ".&mt("and")." $file</b></p>");
422: } else {
423: &Apache::lonxml::info("<p><font color=\"red\" size=\"+1\"><b>".&mt("Unable to undo, unable to switch")." $filebak ".&mt("and")." $file</b></font></p>");
424: $error=1;
425: }
426: } else {
427: my $fs=Apache::File->new(">$filebak");
428: if (defined($fs)) {
429: print $fs $$problem;
430: &Apache::lonxml::info("<b>".&mt("Making Backup to").
431: " $filebak</b>");
432: } else {
433: &Apache::lonxml::info("<font color=\"red\" size=\"+1\"><b>".&mt("Unable to make backup")." $filebak</b></font>");
434: $error=2;
435: }
436: my $fh=Apache::File->new(">$file");
437: if (defined($fh)) {
438: print $fh $$result;
439: &Apache::lonxml::info("<b>".&mt("Saving Modifications to").
440: " $file</b>");
441: } else {
442: &Apache::lonxml::info("<font color=\"red\" size=\"+1\"><b>".
443: &mt("Unable to write to")." $file</b></font>");
444: $error|=4;
445: }
446: }
447: return $error;
448: }
449:
450: sub analyze_header {
451: my ($request) = @_;
452: my $result.='<html>
453: <head><title>'.&mt("Analyzing a problem").'</title></head>
454: <body bgcolor="#FFFFFF">'.&Apache::lonxml::message_location().'
455: <form name="lonhomework" method="POST" action="'.
456: &HTML::Entities::encode($ENV{'request.uri'},'<>&"').'">'.
457: &Apache::structuretags::remember_problem_state().'
458: <input type="submit" name="problemmode" value="'.&mt("EditXML").'" />
459: <input type="submit" name="problemmode" value="'.&mt('Edit').'" />
460: <hr />
461: <input type="submit" name="submit" value="'.&mt("View").'" />
462: <hr />
463: </form>';
464: &Apache::lonxml::add_messages(\$result);
465: $request->print($result);
466: $request->rflush();
467: }
468:
469: sub analyze_footer {
470: my ($request) = @_;
471: my $result='</body></html>';
472: $request->print($result);
473: $request->rflush();
474: }
475:
476: sub analyze {
477: my ($request,$file) = @_;
478: &Apache::lonxml::debug("Analyze");
479: my $result;
480: my %overall;
481: my %allparts;
482: my $rndseed=$ENV{'form.rndseed'};
483: &analyze_header($request);
484: my %prog_state=
485: &Apache::lonhtmlcommon::Create_PrgWin($request,&mt('Analyze Progress'),
486: &mt('Getting Problem Variants'),
487: $ENV{'form.numtoanalyze'},
488: 'inline',undef);
489: for(my $i=1;$i<$ENV{'form.numtoanalyze'}+1;$i++) {
490: &Apache::lonhtmlcommon::Increment_PrgWin($request,\%prog_state,
491: &mt('last problem'));
492: if (&Apache::loncommon::connection_aborted($request)) { return; }
493: my $subresult=&Apache::lonnet::ssi($request->uri,
494: ('grade_target' => 'analyze'),
495: ('rndseed' => $i+$rndseed));
496: (my $garbage,$subresult)=split(/_HASH_REF__/,$subresult,2);
497: my %analyze=&Apache::lonnet::str2hash($subresult);
498: my @parts;
499: if (defined(@{ $analyze{'parts'} })) {
500: @parts=@{ $analyze{'parts'} };
501: }
502: foreach my $part (@parts) {
503: if (!exists($allparts{$part})) {$allparts{$part}=1;};
504: if ($analyze{$part.'.type'} eq 'numericalresponse' ||
505: $analyze{$part.'.type'} eq 'stringresponse' ||
506: $analyze{$part.'.type'} eq 'formularesponse' ) {
507: push( @{ $overall{$part.'.answer'} },
508: [@{ $analyze{$part.'.answer'} }]);
509: }
510: }
511: }
512: &Apache::lonhtmlcommon::Update_PrgWin($request,\%prog_state,
513: &mt('Analyzing Results'));
514: $request->print('<hr />'.&mt('List of possible answers').': ');
515: foreach my $part (sort(keys(%allparts))) {
516: if (defined(@{ $overall{$part.'.answer'} })) {
517: my $num_cols=scalar(@{ $overall{$part.'.answer'}->[0] });
518: $request->print('<table><tr><td colspan="'.($num_cols+1).'">'.&mt('Part').' '.$part.'</td></tr>');
519: my %frequency;
520: foreach my $answer (sort {$a->[0] <=> $b->[0]} (@{ $overall{$part.'.answer'} })) {
521: $frequency{join("\0",@{ $answer })}++;
522: }
523: $request->print('<tr><td colspan="'.($num_cols).'">'.&mt('Answer').'</td><td>'.&mt('Frequency').'</td></tr>');
524: foreach my $answer (sort {(split("\0",$a))[0] <=> (split("\0",$b))[0]} (keys(%frequency))) {
525: $request->print('<tr><td align="right">'.
526: join('</td><td align="right">',split("\0",$answer)).
527: '</td><td>('.$frequency{$answer}.
528: ')</td></tr>');
529: }
530: $request->print('</table>');
531: } else {
532: $request->print('<p>'.&mt('Response').' '.$part.' '.
533: &mt('is not analyzable at this time').'</p>');
534: }
535: }
536: if (scalar(keys(%allparts)) == 0 ) {
537: $request->print('<p>'.&mt('Found no analyzable respones in this problem, currently only Numerical, Formula and String response styles are supported.').'</p>');
538: }
539: &Apache::lonhtmlcommon::Close_PrgWin($request,\%prog_state);
540: &analyze_footer($request);
541: &Apache::lonhomework::showhash(%overall);
542: return $result;
543: }
544:
545: sub editxmlmode {
546: my ($request,$file) = @_;
547: my $result;
548: my $problem=&Apache::lonnet::getfile($file);
549: if ($problem eq -1) {
550: &Apache::lonxml::error("<b> ".&mt('Unable to find').
551: " <i>$file</i></b>");
552: $problem='';
553: }
554: if (defined($ENV{'form.editxmltext'}) || defined($ENV{'form.Undo'})) {
555: my $error=&handle_save_or_undo($request,\$problem,
556: \$ENV{'form.editxmltext'});
557: if (!$error) { $problem=&Apache::lonnet::getfile($file); }
558: }
559: &Apache::lonhomework::showhashsubset(\%ENV,'^form');
560: if ( $ENV{'form.submit'} eq &mt('Submit Changes and View') ) {
561: &Apache::lonhomework::showhashsubset(\%ENV,'^form');
562: $ENV{'form.problemmode'}='View';
563: &renderpage($request,$file);
564: } else {
565: my ($rows,$cols) = &Apache::edit::textarea_sizes(\$problem);
566: my $xml_help = '<table><tr><td>'.
567: &Apache::loncommon::helpLatexCheatsheet("Problem_Editor_XML_Index",
568: "Problem Editing Help").
569: '</td><td>'.
570: &Apache::loncommon::help_open_menu('',undef,undef,undef,5,'Authoring').
571: '</td></tr></table>';
572: if ($cols > 80) { $cols = 80; }
573: if ($cols < 70) { $cols = 70; }
574: if ($rows < 20) { $rows = 20; }
575: $result.='<html><body bgcolor="#FFFFFF">'.
576: &Apache::lonxml::message_location().'
577: <form name="lonhomework" method="POST" action="'.
578: &HTML::Entities::encode($ENV{'request.uri'},'<>&"').'">'.
579: &Apache::structuretags::remember_problem_state().'
580: <input type="hidden" name="problemmode" value="'.&mt('EditXML').'" />
581: <input type="submit" name="problemmode" accesskey="d" value="'.&mt('Discard Edits and View').'" />
582: <input type="submit" name="problemmode" accesskey="e" value="'.&mt('Edit').'" />
583: <hr />
584: <input type="submit" name="submit" accesskey="s" value="'.&mt('Submit Changes').'" />
585: <input type="submit" name="submit" accesskey="v" value="'.&mt('Submit Changes and View').'" />
586: <input type="submit" name="Undo" accesskey="u" value="'.&mt('undo').'" />
587: <hr />
588: ' . $xml_help . '
589: <textarea rows="'.$rows.'" cols="'.$cols.'" name="editxmltext">'.
590: &HTML::Entities::encode($problem,'<>&"').'</textarea>
591: </form></body></html>';
592: &Apache::lonxml::add_messages(\$result);
593: $request->print($result);
594: }
595: return '';
596: }
597:
598: sub renderpage {
599: my ($request,$file) = @_;
600:
601: my (@targets) = &get_target();
602: &Apache::lonhomework::showhashsubset(\%ENV,'form.');
603: &Apache::lonxml::debug("Running targets ".join(':',@targets));
604: my $overall_result;
605: foreach my $target (@targets) {
606: #my $t0 = [&gettimeofday()];
607: my $problem=&Apache::lonnet::getfile($file);
608: if ($problem eq -1) {
609: &Apache::lonxml::error("<b> ".&mt('Unable to find')." <i>$file</i></b>");
610: $problem='';
611: }
612:
613: my %mystyle;
614: my $result = '';
615: if ($target eq 'analyze') { %Apache::lonhomework::analyze=(); }
616: if ($target eq 'answer') { &showhash(%Apache::lonhomework::history); }
617: if ($target eq 'web') {&Apache::lonhomework::showhashsubset(\%ENV,'^form');}
618:
619: &Apache::lonxml::debug("Should be parsing now");
620: $result = &Apache::lonxml::xmlparse($request, $target, $problem,
621: &setup_vars($target),%mystyle);
622: undef($Apache::lonhomework::parsing_a_problem);
623: #$request->print("Result follows:");
624: if ($target eq 'modified') {
625: &handle_save_or_undo($request,\$problem,\$result);
626: } else {
627: if ($target eq 'analyze') {
628: $result=&Apache::lonnet::hashref2str(\%Apache::lonhomework::analyze);
629: undef(%Apache::lonhomework::analyze);
630: }
631: #my $td=&tv_interval($t0);
632: #if ( $Apache::lonxml::debug) {
633: #$result =~ s:</body>::;
634: #$result.="<br />Spent $td seconds processing target $target\n</body>";
635: #}
636: # $request->print($result);
637: $overall_result.=$result;
638: # $request->rflush();
639: }
640: #$request->print(":Result ends");
641: #my $td=&tv_interval($t0);
642: }
643: &Apache::lonxml::add_messages(\$overall_result);
644: $request->print($overall_result);
645: $request->rflush();
646: }
647:
648: # with no arg it returns a HTML <option> list of the template titles
649: # with one arg it returns the filename associated with the arg passed
650: sub get_template_list {
651: my ($namewanted,$extension) = @_;
652: my $result;
653: my @allnames;
654: &Apache::lonxml::debug("Looking for :$extension:");
655: foreach my $file (</home/httpd/html/res/adm/includes/templates/*.$extension>) {
656: my $name=&Apache::lonnet::metadata($file,'title');
657: if ($namewanted && ($name eq $namewanted)) {
658: $result=$file;
659: last;
660: } else {
661: if ($name) { push (@allnames, $name); }
662: }
663: }
664: if (@allnames && !$result) {
665: $result="<option>".&mt("Select a")." $extension ".&mt('template')."</option>\n<option>".
666: join('</option><option>',sort(@allnames)).'</option>';
667: }
668: return $result;
669: }
670:
671: sub newproblem {
672: my ($request) = @_;
673: my $extension=$request->uri;
674: $extension=~s:^.*\.([\w]+)$:$1:;
675: &Apache::lonxml::debug("Looking for :$extension:");
676: my $templatelist=&get_template_list('',$extension);
677: if ($ENV{'form.template'} &&
678: $ENV{'form.template'} ne "Select a $extension template") {
679: use File::Copy;
680: my $file = &get_template_list($ENV{'form.template'},$extension);
681: my $dest = &Apache::lonnet::filelocation("",$request->uri);
682: copy($file,$dest);
683: &renderpage($request,$dest);
684: } elsif($ENV{'form.newfile'} && !$templatelist) {
685: # I don't like hard-coded filenames but for now, this will work.
686: use File::Copy;
687: my $templatefilename =
688: $request->dir_config('lonIncludes').'/templates/blank.problem';
689: &Apache::lonxml::debug("$templatefilename");
690: my $dest = &Apache::lonnet::filelocation("",$request->uri);
691: copy($templatefilename,$dest);
692: &renderpage($request,$dest);
693: } else {
694: my $url=&HTML::Entities::encode($request->uri,'<>&"');
695: my $shownurl=$url;
696: $shownurl=~s-^/~-/priv/-;
697: my $dest = &Apache::lonnet::filelocation("",$request->uri);
698: my $errormsg;
699: if ($ENV{'form.newfile'}) {
700: $errormsg='<p><font color="red">'.&mt('You did not select a template.').'</font></p>'."\n";
701: }
702: my $instructions;
703: my $bodytag=&Apache::loncommon::bodytag(undef,undef,undef,1);
704: if ($templatelist) { $instructions=&mt(", select a template from the pull-down menu below.").'<br />'.&mt("Then");}
705: my %lt=&Apache::lonlocal::texthash( 'create' => 'Creating a new',
706: 'resource' => 'resource',
707: 'requested' => 'The requested file',
708: 'not exist' => 'currently does not exist',
709: 'createnew' => 'To create a new',
710: 'click' => 'click on the',
711: 'Create' => 'Create',
712: 'button' => 'button');
713: $request->print(<<ENDNEWPROBLEM);
714: $bodytag
715: <h1>$lt{'create'} $extension $lt{'resource'}</h1>
716: $errormsg
717: $lt{'requested'} <tt>$shownurl</tt> $lt{'not exist'}.
718: <p>
719: <b>$lt{'createnew'} $extension$instructions $lt{'click'} "$lt{'Create'} $extension" $lt{'button'}.</b>
720: </p>
721: <p><form action="$url" method="POST">
722: ENDNEWPROBLEM
723: if (defined($templatelist)) {
724: $request->print("<select name=\"template\">$templatelist</select>");
725: }
726: $request->print("<br /><input type=\"submit\" name=\"newfile\" value=\"".&mt('Create')." $extension\" />");
727: $request->print("</form></p></body>");
728: }
729: return '';
730: }
731:
732: sub view_or_edit_menu {
733: my ($request) = @_;
734: my $url=&HTML::Entities::encode($request->uri,'<>&"');
735: my %lt=&Apache::lonlocal::texthash( 'would' => 'Would you like to',
736: 'view' => 'View',
737: 'Edit' => 'edit',
738: 'or' => 'or',
739: 'the problem' => 'the problem');
740: $request->print(<<EDITMENU);
741: <body bgcolor="#FFFFFF">
742: <form action="$url" method="POST">
743: $lt{'would'} <input type="submit" name="problemmode" accesskey="v" value="<{'view'}">
744: <{'or'} <input type="submit" name="problemmode" accesskey="e" value="<{'Edit'}">
745: <{'the problem'}.
746: </form>
747: </body>
748: EDITMENU
749: }
750:
751: sub handler {
752: #my $t0 = [&gettimeofday()];
753: my $request=$_[0];
754:
755: $Apache::lonxml::debug=$ENV{'user.debug'};
756: if (&setupheader($request)) { return OK; }
757: $ENV{'request.uri'}=$request->uri;
758:
759: &setuppermissions();
760: &Apache::lonxml::debug("Permissions:$Apache::lonhomework::browse:$Apache::lonhomework::viewgrades:");
761: # some times multiple problemmodes are submitted, need to select
762: # the last one
763: &Apache::lonxml::debug("Problem Mode ".$ENV{'form.problemmode'});
764: if ( defined($ENV{'form.problemmode'}) &&
765: ref($ENV{'form.problemmode'}) ) {
766: &Apache::lonxml::debug("Problem Mode ".join(",",@$ENV{'form.problemmode'}));
767: my $mode=$ENV{'form.problemmode'}->[-1];
768: undef $ENV{'form.problemmode'};
769: $ENV{'form.problemmode'}=$mode;
770: }
771: &Apache::lonxml::debug("Problem Mode ".$ENV{'form.problemmode'});
772: my $file=&Apache::lonnet::filelocation("",$request->uri);
773:
774: #check if we know where we are
775: if ($ENV{'request.course.fn'} && !&Apache::lonnet::symbread()) {
776: # if we are browsing we might not be able to know where we are
777: if ($Apache::lonhomework::browse ne 'F' &&
778: $ENV{'request.state'} ne "construct") {
779: #should know where we are, so ask
780: if ( &Apache::lonnet::mod_perl_version() == 2 ) {
781: &Apache::lonnet::cleanenv();
782: }
783: $request->internal_redirect('/adm/ambiguous'); return;
784: }
785: }
786:
787: my ($symb) = &Apache::lonxml::whichuser();
788: &Apache::lonxml::debug('symb is '.$symb);
789: if ($ENV{'request.state'} eq "construct" || $symb eq '') {
790: if ($ENV{'form.resetdata'} eq &mt('Reset Submissions') ||
791: $ENV{'form.resetdata'} eq &mt('New Problem Variation') ||
792: $ENV{'form.newrandomization'} eq &mt('New Randomization')) {
793: my ($symb,$courseid,$domain,$name) = &Apache::lonxml::whichuser();
794: &Apache::lonnet::tmpreset($symb,'',$domain,$name);
795: &Apache::lonxml::debug("Attempt reset");
796: }
797: }
798: if ($ENV{'request.state'} eq "construct") {
799: if ( -e $file ) {
800: &Apache::loncommon::get_unprocessed_cgi($ENV{'QUERY_STRING'},
801: ['problemmode']);
802: if (!(defined $ENV{'form.problemmode'})) {
803: #first visit to problem in construction space
804: #&view_or_edit_menu($request);
805: $ENV{'form.problemmode'}='View';
806: &renderpage($request,$file);
807: } elsif ($ENV{'form.problemmode'} eq &mt('EditXML')) {
808: &editxmlmode($request,$file);
809: } elsif ($ENV{'form.problemmode'} eq &mt('Calculate answers')) {
810: &analyze($request,$file);
811: } else {
812: &renderpage($request,$file);
813: }
814: } else {
815: # requested file doesn't exist in contruction space
816: &newproblem($request);
817: }
818: } else {
819: # just render the page normally outside of construction space
820: &Apache::lonxml::debug("not construct");
821: &renderpage($request,$file);
822: }
823: #my $td=&tv_interval($t0);
824: #&Apache::lonxml::debug("Spent $td seconds processing");
825: # &Apache::lonhomework::send_footer($request);
826: # always turn off debug messages
827: $Apache::lonxml::debug=0;
828: return OK;
829:
830: }
831:
832: 1;
833: __END__
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>