1: # The LearningOnline Network with CAPA
2: # The LON-CAPA Homework handler
3: #
4: # $Id: lonhomework.pm,v 1.192 2005/01/11 19:38:53 albertel Exp $
5: #
6: # Copyright Michigan State University Board of Trustees
7: #
8: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
9: #
10: # LON-CAPA is free software; you can redistribute it and/or modify
11: # it under the terms of the GNU General Public License as published by
12: # the Free Software Foundation; either version 2 of the License, or
13: # (at your option) any later version.
14: #
15: # LON-CAPA is distributed in the hope that it will be useful,
16: # but WITHOUT ANY WARRANTY; without even the implied warranty of
17: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18: # GNU General Public License for more details.
19: #
20: # You should have received a copy of the GNU General Public License
21: # along with LON-CAPA; if not, write to the Free Software
22: # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
23: #
24: # /home/httpd/html/adm/gpl.txt
25: #
26: # http://www.lon-capa.org/
27:
28:
29: package Apache::lonhomework;
30: use strict;
31: use Apache::style();
32: use Apache::lonxml();
33: use Apache::lonnet();
34: use Apache::lonplot();
35: use Apache::inputtags();
36: use Apache::structuretags();
37: use Apache::randomlabel();
38: use Apache::response();
39: use Apache::hint();
40: use Apache::outputtags();
41: use Apache::caparesponse();
42: use Apache::radiobuttonresponse();
43: use Apache::optionresponse();
44: use Apache::imageresponse();
45: use Apache::essayresponse();
46: use Apache::externalresponse();
47: use Apache::rankresponse();
48: use Apache::matchresponse();
49: use Apache::chemresponse();
50: use Apache::drawimage();
51: use Apache::Constants qw(:common);
52: use HTML::Entities();
53: use Apache::loncommon();
54: use Apache::lonlocal;
55: use Time::HiRes qw( gettimeofday tv_interval );
56: use Apache::lonnet();
57:
58: # FIXME - improve commenting
59:
60:
61: BEGIN {
62: &Apache::lonxml::register_insert();
63: }
64:
65:
66: #
67: # Decides what targets to render for.
68: # Implicit inputs:
69: # Various session environment variables:
70: # request.state - published - is a /res/ resource
71: # uploaded - is a /uploaded/ resource
72: # contruct - is a /priv/ resource
73: # form.grade_target - a form parameter requesting a specific target
74: sub get_target {
75: &Apache::lonxml::debug("request.state = $ENV{'request.state'}");
76: if( defined($ENV{'form.grade_target'})) {
77: &Apache::lonxml::debug("form.grade_target= $ENV{'form.grade_target'}");
78: } else {
79: &Apache::lonxml::debug("form.grade_target <undefined>");
80: }
81: if (($ENV{'request.state'} eq "published") ||
82: ($ENV{'request.state'} eq "uploaded")) {
83: if ( defined($ENV{'form.grade_target'} )
84: && ($ENV{'form.grade_target'} eq 'tex')) {
85: return ($ENV{'form.grade_target'});
86: } elsif ( defined($ENV{'form.grade_target'} )
87: && ($Apache::lonhomework::viewgrades eq 'F' )) {
88: return ($ENV{'form.grade_target'});
89: }
90:
91: if ( defined($ENV{'form.submitted'}) &&
92: ( !defined($ENV{'form.resetdata'})) &&
93: ( !defined($ENV{'form.newrandomization'}))) {
94: return ('grade', 'web');
95: } else {
96: return ('web');
97: }
98: } elsif ($ENV{'request.state'} eq "construct") {
99: if ( defined($ENV{'form.grade_target'}) ) {
100: return ($ENV{'form.grade_target'});
101: }
102: if ( defined($ENV{'form.preview'})) {
103: if ( defined($ENV{'form.submitted'})) {
104: return ('grade', 'web');
105: } else {
106: return ('web');
107: }
108: } else {
109: if ( $ENV{'form.problemmode'} eq &mt('View') ||
110: $ENV{'form.problemmode'} eq &mt('Discard Edits and View')) {
111: if ( defined($ENV{'form.submitted'}) &&
112: (!defined($ENV{'form.resetdata'})) &&
113: (!defined($ENV{'form.newrandomization'}))) {
114: return ('grade', 'web','answer');
115: } else {
116: return ('web','answer');
117: }
118: } elsif ( $ENV{'form.problemmode'} eq &mt('Edit') ||
119: $ENV{'form.problemmode'} eq 'Edit') {
120: if ( $ENV{'form.submitted'} eq 'edit' ) {
121: if ( $ENV{'form.submit'} eq &mt('Submit Changes and View') ) {
122: return ('modified','web','answer');
123: } else {
124: return ('modified','edit');
125: }
126: } else {
127: return ('edit');
128: }
129: } else {
130: return ('web');
131: }
132: }
133: }
134: return ();
135: }
136:
137: sub setup_vars {
138: my ($target) = @_;
139: return ';'
140: # return ';$external::target='.$target.';';
141: }
142:
143: sub send_header {
144: my ($request)= @_;
145: $request->print(&Apache::lontexconvert::header());
146: # $request->print('<form name='.$ENV{'form.request.prefix'}.'lonhomework method="POST" action="'.$request->uri.'">');
147: }
148:
149: sub createmenu {
150: my ($which,$request)=@_;
151: if ($which eq 'grade') {
152: $request->print('<script language="JavaScript">
153: hwkmenu=window.open("/res/adm/pages/homeworkmenu.html","homeworkremote",
154: "height=350,width=150,menubar=no");
155: </script>');
156: }
157: }
158:
159: sub send_footer {
160: my ($request)= @_;
161: # $request->print('</form>');
162: $request->print(&Apache::lontexconvert::footer());
163: }
164:
165: $Apache::lonxml::browse='';
166:
167: sub check_ip_acc {
168: my ($acc)=@_;
169: if (!defined($acc) || $acc =~ /^\s*$/) { return 1; }
170: my $allowed=0;
171: my $ip=$ENV{'REMOTE_ADDR'};
172: my $name;
173: foreach my $pattern (split(',',$acc)) {
174: if ($pattern =~ /\*$/) {
175: #35.8.*
176: $pattern=~s/\*//;
177: if ($ip =~ /^\Q$pattern\E/) { $allowed=1; }
178: } elsif ($pattern =~ /(\d+\.\d+\.\d+)\.\[(\d+)-(\d+)\]$/) {
179: #35.8.3.[34-56]
180: my $low=$2;
181: my $high=$3;
182: $pattern=$1;
183: if ($ip =~ /^\Q$pattern\E/) {
184: my $last=(split(/\./,$ip))[3];
185: if ($last <=$high && $last >=$low) { $allowed=1; }
186: }
187: } elsif ($pattern =~ /^\*/) {
188: #*.msu.edu
189: $pattern=~s/\*//;
190: if (!defined($name)) {
191: use Socket;
192: my $netaddr=inet_aton($ip);
193: ($name)=gethostbyaddr($netaddr,AF_INET);
194: }
195: if ($name =~ /\Q$pattern\E$/i) { $allowed=1; }
196: } elsif ($pattern =~ /\d+\.\d+\.\d+\.\d+/) {
197: #127.0.0.1
198: if ($ip =~ /^\Q$pattern\E/) { $allowed=1; }
199: } else {
200: #some.name.com
201: if (!defined($name)) {
202: use Socket;
203: my $netaddr=inet_aton($ip);
204: ($name)=gethostbyaddr($netaddr,AF_INET);
205: }
206: if ($name =~ /\Q$pattern\E$/i) { $allowed=1; }
207: }
208: if ($allowed) { last; }
209: }
210: return $allowed;
211: }
212: # JB, 9/24/2002: Any changes in this function may require a change
213: # in lonnavmaps::resource::getDateStatus.
214: sub check_access {
215: my ($id) = @_;
216: my $date ='';
217: my $status;
218: my $datemsg = '';
219: my $lastdate = '';
220: my $temp;
221: my $type;
222: my $passed;
223:
224: if ($ENV{'request.state'} eq "construct") {
225: if ($ENV{'form.problemstate'}) {
226: if ($ENV{'form.problemstate'} =~ /^CANNOT_ANSWER/) {
227: if ( ! ($ENV{'form.problemstate'} eq 'CANNOT_ANSWER_correct' &&
228: lc($Apache::lonhomework::problemstatus) eq 'no')) {
229: return ('CANNOT_ANSWER',
230: &mt('is in this state due to author settings.'));
231: }
232: } else {
233: return ($ENV{'form.problemstate'},
234: &mt('is in this state due to author settings.'));
235: }
236: }
237: &Apache::lonxml::debug("in construction ignoring dates");
238: $status='CAN_ANSWER';
239: $datemsg=&mt('is in under construction');
240: # return ($status,$datemsg);
241: }
242:
243: &Apache::lonxml::debug("checking for part :$id:");
244: &Apache::lonxml::debug("time:".time);
245:
246: if ($ENV{'request.state'} ne "construct") {
247: my $allowed=&check_ip_acc(&Apache::lonnet::EXT("resource.$id.acc"));
248: if (!$allowed && ($Apache::lonhomework::browse ne 'F')) {
249: $status='INVALID_ACCESS';
250: $date=&mt("can not be accessed from your location.");
251: return($status,$date);
252: }
253:
254: foreach $temp ("opendate","duedate","answerdate") {
255: $lastdate = $date;
256: $date = &Apache::lonnet::EXT("resource.$id.$temp");
257: my $thistype = &Apache::lonnet::EXT("resource.$id.$temp.type");
258: if ($thistype =~ /^(con_lost|no_such_host)/ ||
259: $date =~ /^(con_lost|no_such_host)/) {
260: $status='UNAVAILABLE';
261: $date=&mt("may open later.");
262: return($status,$date);
263: }
264: if ($thistype eq 'date_interval') {
265: if ($temp eq 'opendate') {
266: $date=&Apache::lonnet::EXT("resource.$id.duedate")-$date;
267: }
268: if ($temp eq 'answerdate') {
269: $date=&Apache::lonnet::EXT("resource.$id.duedate")+$date;
270: }
271: }
272: &Apache::lonxml::debug("found :$date: for :$temp:");
273: if ($date eq '') {
274: $date = &mt("an unknown date"); $passed = 0;
275: } elsif ($date eq 'con_lost') {
276: $date = &mt("an indeterminate date"); $passed = 0;
277: } else {
278: if (time < $date) { $passed = 0; } else { $passed = 1; }
279: $date = localtime $date;
280: }
281: if (!$passed) { $type=$temp; last; }
282: }
283: &Apache::lonxml::debug("have :$type:$passed:");
284: if ($passed) {
285: $status='SHOW_ANSWER';
286: $datemsg=$date;
287: } elsif ($type eq 'opendate') {
288: $status='CLOSED';
289: $datemsg = &mt("will open on")." $date";
290: } elsif ($type eq 'duedate') {
291: $status='CAN_ANSWER';
292: $datemsg = &mt("is due at")." $date";
293: } elsif ($type eq 'answerdate') {
294: $status='CLOSED';
295: $datemsg = &mt("was due on")." $lastdate".&mt(", and answers will be available on")." $date";
296: }
297: }
298: if ($status eq 'CAN_ANSWER') {
299: #check #tries, and if correct.
300: my $tries = $Apache::lonhomework::history{"resource.$id.tries"};
301: my $maxtries = &Apache::lonnet::EXT("resource.$id.maxtries");
302: if ( $tries eq '' ) { $tries = '0'; }
303: if ( $maxtries eq '' &&
304: $ENV{'request.state'} ne 'construct') { $maxtries = '2'; }
305: if ($maxtries && $tries >= $maxtries) { $status = 'CANNOT_ANSWER'; }
306: # if (correct and show prob status) or excused then CANNOT_ANSWER
307: if(($Apache::lonhomework::history{"resource.$id.solved"}=~/^correct/
308: &&
309: lc($Apache::lonhomework::problemstatus) ne 'no')
310: ||
311: $Apache::lonhomework::history{"resource.$id.solved"}=~/^excused/) {
312: $status = 'CANNOT_ANSWER';
313: }
314: }
315: if ($status eq 'CAN_ANSWER' || $status eq 'CANNOT_ANSWER') {
316: my $interval=&Apache::lonnet::EXT("resource.$id.interval");
317: &Apache::lonxml::debug("looking for interval $interval");
318: if ($interval) {
319: my $first_access=&Apache::lonnet::get_first_access('map');
320: &Apache::lonxml::debug("looking for accesstime $first_access");
321: if (!$first_access) {
322: $status='NOT_YET_VIEWED';
323: $datemsg=&seconds_to_human_length($interval);
324: } else {
325: my $newdate=localtime($first_access+$interval);
326: if (time > ($first_access+$interval)) {
327: $status='CLOSED';
328: $datemsg = &mt("was due on")." $newdate".&mt(", and answers will be available on")." $date";
329: } else {
330: $datemsg = &mt("is due at")." $newdate";
331: }
332: }
333: }
334: }
335: #if (($status ne 'CLOSED') && ($Apache::lonhomework::type eq 'exam') &&
336: # (!$Apache::lonhomework::history{"resource.0.outtoken"})) {
337: # return ('UNCHECKEDOUT','needs to be checked out');
338: #}
339:
340:
341: &Apache::lonxml::debug("sending back :$status:$datemsg:");
342: if (($Apache::lonhomework::browse eq 'F') && ($status eq 'CLOSED')) {
343: &Apache::lonxml::debug("should be allowed to browse a resource when closed");
344: $status='CAN_ANSWER';
345: $datemsg=&mt('is closed but you are allowed to view it');
346: }
347:
348: return ($status,$datemsg);
349: }
350:
351: sub seconds_to_human_length {
352: my ($length)=@_;
353:
354: my $seconds=$length%60; $length=int($length/60);
355: my $minutes=$length%60; $length=int($length/60);
356: my $hours=$length%24; $length=int($length/24);
357: my $days=$length;
358:
359: my $timestr;
360: if ($days > 0) { $timestr.=&mt('[quant,_1,day]',$days); }
361: if ($hours > 0) { $timestr.=($timestr?", ":"").
362: &mt('[quant,_1,hour]',$hours); }
363: if ($minutes > 0) { $timestr.=($timestr?", ":"").
364: &mt('[quant,_1,minute]',$minutes); }
365: if ($seconds > 0) { $timestr.=($timestr?", ":"").
366: &mt('[quant,_1,second]',$seconds); }
367: return $timestr;
368: }
369:
370: sub showhash {
371: my (%hash) = @_;
372: &showhashsubset(\%hash,'.');
373: return '';
374: }
375:
376: sub showarray {
377: my ($array)=@_;
378: my $string="(";
379: foreach my $elm (@{ $array }) {
380: if (ref($elm)) {
381: if ($elm =~ /ARRAY/ ) {
382: $string.=&showarray($elm);
383: }
384: } else {
385: $string.="$elm,"
386: }
387: }
388: chop($string);
389: $string.=")";
390: return $string;
391: }
392:
393: sub showhashsubset {
394: my ($hash,$keyre) = @_;
395: my $resultkey;
396: foreach $resultkey (sort keys %$hash) {
397: if ($resultkey =~ /$keyre/) {
398: if (ref($$hash{$resultkey})) {
399: if ($$hash{$resultkey} =~ /ARRAY/ ) {
400: &Apache::lonxml::debug("$resultkey ---- ".
401: &showarray($$hash{$resultkey}));
402: } elsif ($$hash{$resultkey} =~ /HASH/ ) {
403: &Apache::lonxml::debug("$resultkey ---- $$hash{$resultkey}");
404: &showhashsubset($$hash{$resultkey},'.');
405: } else {
406: &Apache::lonxml::debug("$resultkey ---- $$hash{$resultkey}");
407: }
408: } else {
409: &Apache::lonxml::debug("$resultkey ---- $$hash{$resultkey}");
410: }
411: }
412: }
413: &Apache::lonxml::debug("\n<br />restored values^</br>\n");
414: return '';
415: }
416:
417: sub setuppermissions {
418: $Apache::lonhomework::browse= &Apache::lonnet::allowed('bre',$ENV{'request.filename'});
419: my $viewgrades = &Apache::lonnet::allowed('vgr',$ENV{'request.course.id'});
420: if (! $viewgrades &&
421: exists($ENV{'request.course.sec'}) &&
422: $ENV{'request.course.sec'} !~ /^\s*$/) {
423: $viewgrades = &Apache::lonnet::allowed('vgr',$ENV{'request.course.id'}.
424: '/'.$ENV{'request.course.sec'});
425: }
426: $Apache::lonhomework::viewgrades = $viewgrades; # File global variable...dirt.
427: if ($Apache::lonhomework::browse eq 'F' &&
428: $ENV{'form.devalidatecourseresdata'} eq 'on') {
429: my (undef,$courseid) = &Apache::lonxml::whichuser();
430: &Apache::lonnet::devalidatecourseresdata($ENV{"course.$courseid.num"},
431: $ENV{"course.$courseid.domain"});
432: }
433: return ''
434: }
435:
436: sub setupheader {
437: my $request=$_[0];
438: if ($ENV{'browser.mathml'}) {
439: &Apache::loncommon::content_type($request,'text/xml');
440: } else {
441: &Apache::loncommon::content_type($request,'text/html');
442: }
443: if (!$Apache::lonxml::debug && ($ENV{'REQUEST_METHOD'} eq 'GET')) {
444: &Apache::loncommon::no_cache($request);
445: }
446: $request->send_http_header;
447: return OK if $request->header_only;
448: return ''
449: }
450:
451: sub handle_save_or_undo {
452: my ($request,$problem,$result) = @_;
453: my $file = &Apache::lonnet::filelocation("",$request->uri);
454: my $filebak =$file.".bak";
455: my $filetmp =$file.".tmp";
456: my $error=0;
457:
458: &Apache::lonnet::correct_line_ends($result);
459:
460: if ($ENV{'form.Undo'} eq &mt('undo')) {
461: my $error=0;
462: if (!copy($file,$filetmp)) { $error=1; }
463: if ((!$error) && (!copy($filebak,$file))) { $error=1; }
464: if ((!$error) && (!move($filetmp,$filebak))) { $error=1; }
465: if (!$error) {
466: &Apache::lonxml::info("<p><b>".&mt("Undid changes, Switched")." $filebak ".&mt("and")." $file</b></p>");
467: } else {
468: &Apache::lonxml::info("<p><font color=\"red\" size=\"+1\"><b>".&mt("Unable to undo, unable to switch")." $filebak ".&mt("and")." $file</b></font></p>");
469: $error=1;
470: }
471: } else {
472: my $fs=Apache::File->new(">$filebak");
473: if (defined($fs)) {
474: print $fs $$problem;
475: &Apache::lonxml::info("<b>".&mt("Making Backup to").
476: " $filebak</b>");
477: } else {
478: &Apache::lonxml::info("<font color=\"red\" size=\"+1\"><b>".&mt("Unable to make backup")." $filebak</b></font>");
479: $error=2;
480: }
481: my $fh=Apache::File->new(">$file");
482: if (defined($fh)) {
483: print $fh $$result;
484: &Apache::lonxml::info("<b>".&mt("Saving Modifications to").
485: " $file</b>");
486: } else {
487: &Apache::lonxml::info("<font color=\"red\" size=\"+1\"><b>".
488: &mt("Unable to write to")." $file</b></font>");
489: $error|=4;
490: }
491: }
492: return $error;
493: }
494:
495: sub analyze_header {
496: my ($request) = @_;
497: my $bodytag='<body bgcolor="#ffffff">';
498: if ($ENV{'environment.remote'} eq 'off') {
499: $bodytag=&Apache::loncommon::bodytag();
500: }
501: my $result.='<html>
502: <head><title>'.&mt("Analyzing a problem").'</title></head>
503: '.$bodytag.&Apache::lonxml::message_location().'
504: <form name="lonhomework" method="POST" action="'.
505: &HTML::Entities::encode($ENV{'request.uri'},'<>&"').'">'.
506: &Apache::structuretags::remember_problem_state().'
507: <input type="submit" name="problemmode" value="'.&mt("EditXML").'" />
508: <input type="submit" name="problemmode" value="'.&mt('Edit').'" />
509: <hr />
510: <input type="submit" name="submit" value="'.&mt("View").'" />
511: <hr />
512: </form>';
513: &Apache::lonxml::add_messages(\$result);
514: $request->print($result);
515: $request->rflush();
516: }
517:
518: sub analyze_footer {
519: my ($request) = @_;
520: my $result='</body></html>';
521: $request->print($result);
522: $request->rflush();
523: }
524:
525: sub analyze {
526: my ($request,$file) = @_;
527: &Apache::lonxml::debug("Analyze");
528: my $result;
529: my %overall;
530: my %allparts;
531: my $rndseed=$ENV{'form.rndseed'};
532: &analyze_header($request);
533: my %prog_state=
534: &Apache::lonhtmlcommon::Create_PrgWin($request,&mt('Analyze Progress'),
535: &mt('Getting Problem Variants'),
536: $ENV{'form.numtoanalyze'},
537: 'inline',undef);
538: for(my $i=1;$i<$ENV{'form.numtoanalyze'}+1;$i++) {
539: &Apache::lonhtmlcommon::Increment_PrgWin($request,\%prog_state,
540: &mt('last problem'));
541: if (&Apache::loncommon::connection_aborted($request)) { return; }
542: my $subresult=&Apache::lonnet::ssi($request->uri,
543: ('grade_target' => 'analyze'),
544: ('rndseed' => $i+$rndseed));
545: (my $garbage,$subresult)=split(/_HASH_REF__/,$subresult,2);
546: my %analyze=&Apache::lonnet::str2hash($subresult);
547: my @parts;
548: if (defined(@{ $analyze{'parts'} })) {
549: @parts=@{ $analyze{'parts'} };
550: }
551: foreach my $part (@parts) {
552: if (!exists($allparts{$part})) {$allparts{$part}=1;};
553: if ($analyze{$part.'.type'} eq 'numericalresponse' ||
554: $analyze{$part.'.type'} eq 'stringresponse' ||
555: $analyze{$part.'.type'} eq 'formularesponse' ) {
556: push( @{ $overall{$part.'.answer'} },
557: [@{ $analyze{$part.'.answer'} }]);
558: }
559: }
560: }
561: &Apache::lonhtmlcommon::Update_PrgWin($request,\%prog_state,
562: &mt('Analyzing Results'));
563: $request->print('<hr />'.&mt('List of possible answers').': ');
564: foreach my $part (sort(keys(%allparts))) {
565: if (defined(@{ $overall{$part.'.answer'} })) {
566: my $num_cols=scalar(@{ $overall{$part.'.answer'}->[0] });
567: $request->print('<table><tr><th colspan="'.($num_cols+1).'">'.&mt('Part').' '.$part.'</th></tr>');
568: my %frequency;
569: foreach my $answer (sort {$a->[0] <=> $b->[0]} (@{ $overall{$part.'.answer'} })) {
570: $frequency{join("\0",@{ $answer })}++;
571: }
572: $request->print('<tr><th colspan="'.($num_cols).'">'.&mt('Answer').'</th><th>'.&mt('Frequency').'</th></tr>');
573: foreach my $answer (sort {(split("\0",$a))[0] <=> (split("\0",$b))[0]} (keys(%frequency))) {
574: $request->print('<tr><td align="right">'.
575: join('</td><td align="right">',split("\0",$answer)).
576: '</td><td>('.$frequency{$answer}.
577: ')</td></tr>');
578: }
579: $request->print('</table>');
580: } else {
581: $request->print('<p>'.&mt('Response').' '.$part.' '.
582: &mt('is not analyzable at this time').'</p>');
583: }
584: }
585: if (scalar(keys(%allparts)) == 0 ) {
586: $request->print('<p>'.&mt('Found no analyzable respones in this problem, currently only Numerical, Formula and String response styles are supported.').'</p>');
587: }
588: &Apache::lonhtmlcommon::Close_PrgWin($request,\%prog_state);
589: &analyze_footer($request);
590: &Apache::lonhomework::showhash(%overall);
591: return $result;
592: }
593:
594: sub editxmlmode {
595: my ($request,$file) = @_;
596: my $result;
597: my $problem=&Apache::lonnet::getfile($file);
598: if ($problem eq -1) {
599: &Apache::lonxml::error("<b> ".&mt('Unable to find').
600: " <i>$file</i></b>");
601: $problem='';
602: }
603: if (defined($ENV{'form.editxmltext'}) || defined($ENV{'form.Undo'})) {
604: my $error=&handle_save_or_undo($request,\$problem,
605: \$ENV{'form.editxmltext'});
606: if (!$error) { $problem=&Apache::lonnet::getfile($file); }
607: }
608: &Apache::lonhomework::showhashsubset(\%ENV,'^form');
609: if ( $ENV{'form.submit'} eq &mt('Submit Changes and View') ) {
610: &Apache::lonhomework::showhashsubset(\%ENV,'^form');
611: $ENV{'form.problemmode'}='View';
612: &renderpage($request,$file);
613: } else {
614: my ($rows,$cols) = &Apache::edit::textarea_sizes(\$problem);
615: my $xml_help = '<table><tr><td>'.
616: &Apache::loncommon::helpLatexCheatsheet("Problem_Editor_XML_Index",
617: "Problem Editing Help").
618: '</td><td>'.
619: &Apache::loncommon::help_open_menu('',undef,undef,undef,5,'Authoring').
620: '</td></tr></table>';
621: if ($cols > 80) { $cols = 80; }
622: if ($cols < 70) { $cols = 70; }
623: if ($rows < 20) { $rows = 20; }
624: my $bodytag='<body bgcolor="#ffffff">';
625: if ($ENV{'environment.remote'} eq 'off') {
626: $bodytag=&Apache::loncommon::bodytag();
627: }
628: $result.='<html>'.$bodytag.&Apache::lonxml::message_location().'
629: <form name="lonhomework" method="POST" action="'.
630: &HTML::Entities::encode($ENV{'request.uri'},'<>&"').'">'.
631: &Apache::structuretags::remember_problem_state().'
632: <input type="hidden" name="problemmode" value="'.&mt('EditXML').'" />
633: <input type="submit" name="problemmode" accesskey="d" value="'.&mt('Discard Edits and View').'" />
634: <input type="submit" name="problemmode" accesskey="e" value="'.&mt('Edit').'" />
635: <hr />
636: <input type="submit" name="submit" accesskey="s" value="'.&mt('Submit Changes').'" />
637: <input type="submit" name="submit" accesskey="v" value="'.&mt('Submit Changes and View').'" />
638: <input type="submit" name="Undo" accesskey="u" value="'.&mt('undo').'" />
639: <hr />
640: ' . $xml_help . '
641: <textarea rows="'.$rows.'" cols="'.$cols.'" name="editxmltext">'.
642: &HTML::Entities::encode($problem,'<>&"').'</textarea>
643: </form></body></html>';
644: &Apache::lonxml::add_messages(\$result);
645: $request->print($result);
646: }
647: return '';
648: }
649:
650: #
651: # Render the page in whatever target desired.
652: #
653: sub renderpage {
654: my ($request,$file) = @_;
655:
656: my (@targets) = &get_target();
657: &Apache::lonhomework::showhashsubset(\%ENV,'form.');
658: &Apache::lonxml::debug("Running targets ".join(':',@targets));
659: my $overall_result;
660: foreach my $target (@targets) {
661: # FIXME need to do something intelligent when a problem goes
662: # from viewable to not viewable due to map conditions
663: #&setuppermissions();
664: #if ( $Apache::lonhomework::browse ne '2'
665: # && $Apache::lonhomework::browse ne 'F' ) {
666: # $request->print(" You most likely shouldn't see me.");
667: #}
668: #my $t0 = [&gettimeofday()];
669: my $problem=&Apache::lonnet::getfile($file);
670: if ($problem eq -1) {
671: &Apache::lonxml::error("<b> ".&mt('Unable to find')." <i>$file</i></b>");
672: $problem='';
673: }
674:
675: my %mystyle;
676: my $result = '';
677: if ($target eq 'analyze') { %Apache::lonhomework::analyze=(); }
678: if ($target eq 'answer') { &showhash(%Apache::lonhomework::history); }
679: if ($target eq 'web') {&Apache::lonhomework::showhashsubset(\%ENV,'^form');}
680:
681: &Apache::lonxml::debug("Should be parsing now");
682: $result = &Apache::lonxml::xmlparse($request, $target, $problem,
683: &setup_vars($target),%mystyle);
684: undef($Apache::lonhomework::parsing_a_problem);
685: #$request->print("Result follows:");
686: if ($target eq 'modified') {
687: &handle_save_or_undo($request,\$problem,\$result);
688: } else {
689: if ($target eq 'analyze') {
690: $result=&Apache::lonnet::hashref2str(\%Apache::lonhomework::analyze);
691: undef(%Apache::lonhomework::analyze);
692: }
693: #my $td=&tv_interval($t0);
694: #if ( $Apache::lonxml::debug) {
695: #$result =~ s:</body>::;
696: #$result.="<br />Spent $td seconds processing target $target\n</body>";
697: #}
698: # $request->print($result);
699: $overall_result.=$result;
700: # $request->rflush();
701: }
702: #$request->print(":Result ends");
703: #my $td=&tv_interval($t0);
704: }
705: &Apache::lonxml::add_messages(\$overall_result);
706: $request->print($overall_result);
707: $request->rflush();
708: }
709:
710: # with no arg it returns a HTML <option> list of the template titles
711: # with one arg it returns the filename associated with the arg passed
712: sub get_template_list {
713: my ($namewanted,$extension) = @_;
714: my $result;
715: my @allnames;
716: &Apache::lonxml::debug("Looking for :$extension:");
717: foreach my $file (</home/httpd/html/res/adm/includes/templates/*.$extension>) {
718: my $name=&Apache::lonnet::metadata($file,'title');
719: if ($namewanted && ($name eq $namewanted)) {
720: $result=$file;
721: last;
722: } else {
723: if ($name) { push (@allnames, $name); }
724: }
725: }
726: if (@allnames && !$result) {
727: $result="<option>".&mt("Select a")." $extension ".&mt('template')."</option>\n<option>".
728: join('</option><option>',sort(@allnames)).'</option>';
729: }
730: return $result;
731: }
732:
733: sub newproblem {
734: my ($request) = @_;
735: my $extension=$request->uri;
736: $extension=~s:^.*\.([\w]+)$:$1:;
737: &Apache::lonxml::debug("Looking for :$extension:");
738: my $templatelist=&get_template_list('',$extension);
739: if ($ENV{'form.template'} &&
740: $ENV{'form.template'} ne "Select a $extension template") {
741: use File::Copy;
742: my $file = &get_template_list($ENV{'form.template'},$extension);
743: my $dest = &Apache::lonnet::filelocation("",$request->uri);
744: copy($file,$dest);
745: &renderpage($request,$dest);
746: } elsif($ENV{'form.newfile'} && !$templatelist) {
747: # I don't like hard-coded filenames but for now, this will work.
748: use File::Copy;
749: my $templatefilename =
750: $request->dir_config('lonIncludes').'/templates/blank.problem';
751: &Apache::lonxml::debug("$templatefilename");
752: my $dest = &Apache::lonnet::filelocation("",$request->uri);
753: copy($templatefilename,$dest);
754: &renderpage($request,$dest);
755: } else {
756: my $url=&HTML::Entities::encode($request->uri,'<>&"');
757: my $shownurl=$url;
758: $shownurl=~s-^/~-/priv/-;
759: my $dest = &Apache::lonnet::filelocation("",$request->uri);
760: my $errormsg;
761: if ($ENV{'form.newfile'}) {
762: $errormsg='<p><font color="red">'.&mt('You did not select a template.').'</font></p>'."\n";
763: }
764: my $instructions;
765: my $bodytag=&Apache::loncommon::bodytag(undef,undef,undef,
766: ($ENV{'environment.remote'} ne 'off'));
767: if ($templatelist) { $instructions=&mt(", select a template from the pull-down menu below.").'<br />'.&mt("Then");}
768: my %lt=&Apache::lonlocal::texthash( 'create' => 'Creating a new',
769: 'resource' => 'resource',
770: 'requested' => 'The requested file',
771: 'not exist' => 'currently does not exist',
772: 'createnew' => 'To create a new',
773: 'click' => 'click on the',
774: 'Create' => 'Create',
775: 'button' => 'button');
776: $request->print(<<ENDNEWPROBLEM);
777: $bodytag
778: <h1>$lt{'create'} $extension $lt{'resource'}</h1>
779: $errormsg
780: $lt{'requested'} <tt>$shownurl</tt> $lt{'not exist'}.
781: <p>
782: <b>$lt{'createnew'} $extension$instructions $lt{'click'} "$lt{'Create'} $extension" $lt{'button'}.</b>
783: </p>
784: <p><form action="$url" method="POST">
785: ENDNEWPROBLEM
786: if (defined($templatelist)) {
787: $request->print("<select name=\"template\">$templatelist</select>");
788: }
789: $request->print("<br /><input type=\"submit\" name=\"newfile\" value=\"".&mt('Create')." $extension\" />");
790: $request->print("</form></p></body>");
791: }
792: return '';
793: }
794:
795: sub view_or_edit_menu {
796: my ($request) = @_;
797: my $url=&HTML::Entities::encode($request->uri,'<>&"');
798: my %lt=&Apache::lonlocal::texthash( 'would' => 'Would you like to',
799: 'view' => 'View',
800: 'Edit' => 'edit',
801: 'or' => 'or',
802: 'the problem' => 'the problem');
803: $request->print(<<EDITMENU);
804: <body bgcolor="#FFFFFF">
805: <form action="$url" method="POST">
806: $lt{'would'} <input type="submit" name="problemmode" accesskey="v" value="<{'view'}">
807: <{'or'} <input type="submit" name="problemmode" accesskey="e" value="<{'Edit'}">
808: <{'the problem'}.
809: </form>
810: </body>
811: EDITMENU
812: }
813:
814: sub handler {
815: #my $t0 = [&gettimeofday()];
816: my $request=$_[0];
817:
818: $Apache::lonxml::debug=$ENV{'user.debug'};
819: $ENV{'request.uri'}=$request->uri;
820: &setuppermissions();
821: &Apache::lonxml::debug("Permissions:$Apache::lonhomework::browse:$Apache::lonhomework::viewgrades:");
822: # some times multiple problemmodes are submitted, need to select
823: # the last one
824: &Apache::lonxml::debug("Problem Mode ".$ENV{'form.problemmode'});
825: if ( defined($ENV{'form.problemmode'}) &&
826: ref($ENV{'form.problemmode'}) ) {
827: &Apache::lonxml::debug("Problem Mode ".join(",",@$ENV{'form.problemmode'}));
828: my $mode=$ENV{'form.problemmode'}->[-1];
829: undef $ENV{'form.problemmode'};
830: $ENV{'form.problemmode'}=$mode;
831: }
832: &Apache::lonxml::debug("Problem Mode ".$ENV{'form.problemmode'});
833: my $file=&Apache::lonnet::filelocation("",$request->uri);
834:
835: #check if we know where we are
836: if ($ENV{'request.course.fn'} && !&Apache::lonnet::symbread()) {
837: # if we are browsing we might not be able to know where we are
838: if ($Apache::lonhomework::browse ne 'F' &&
839: $ENV{'request.state'} ne "construct") {
840: #should know where we are, so ask
841: if ( &Apache::lonnet::mod_perl_version() == 2 ) {
842: &Apache::lonnet::cleanenv();
843: }
844: &Apache::lonnet::logthis(&Apache::lonnet::mod_perl_version());
845: $request->internal_redirect('/adm/ambiguous'); return OK;
846: }
847: }
848: if (&setupheader($request)) { return OK; }
849:
850: my ($symb) = &Apache::lonxml::whichuser();
851: &Apache::lonxml::debug('symb is '.$symb);
852: if ($ENV{'request.state'} eq "construct" || $symb eq '') {
853: if ($ENV{'form.resetdata'} eq &mt('Reset Submissions') ||
854: $ENV{'form.resetdata'} eq &mt('New Problem Variation') ||
855: $ENV{'form.newrandomization'} eq &mt('New Randomization')) {
856: my ($symb,$courseid,$domain,$name) = &Apache::lonxml::whichuser();
857: &Apache::lonnet::tmpreset($symb,'',$domain,$name);
858: &Apache::lonxml::debug("Attempt reset");
859: }
860: }
861: if ($ENV{'request.state'} eq "construct") {
862: if ( -e $file ) {
863: &Apache::loncommon::get_unprocessed_cgi($ENV{'QUERY_STRING'},
864: ['problemmode']);
865: if (!(defined $ENV{'form.problemmode'})) {
866: #first visit to problem in construction space
867: #&view_or_edit_menu($request);
868: $ENV{'form.problemmode'}='View';
869: &renderpage($request,$file);
870: } elsif ($ENV{'form.problemmode'} eq &mt('EditXML') ||
871: $ENV{'form.problemmode'} eq 'EditXML') {
872: &editxmlmode($request,$file);
873: } elsif ($ENV{'form.problemmode'} eq &mt('Calculate answers')) {
874: &analyze($request,$file);
875: } else {
876: &renderpage($request,$file);
877: }
878: } else {
879: # requested file doesn't exist in contruction space
880: &newproblem($request);
881: }
882: } else {
883: # just render the page normally outside of construction space
884: &Apache::lonxml::debug("not construct");
885: &renderpage($request,$file);
886: }
887: #my $td=&tv_interval($t0);
888: #&Apache::lonxml::debug("Spent $td seconds processing");
889: # &Apache::lonhomework::send_footer($request);
890: # always turn off debug messages
891: $Apache::lonxml::debug=0;
892: return OK;
893:
894: }
895:
896: 1;
897: __END__
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>