1: # LearningOnline Network with CAPA
2: # option list style responses
3: #
4: # $Id: optionresponse.pm,v 1.189 2012/12/18 16:30:23 raeburn Exp $
5: #
6: # Copyright Michigan State University Board of Trustees
7: #
8: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
9: #
10: # LON-CAPA is free software; you can redistribute it and/or modify
11: # it under the terms of the GNU General Public License as published by
12: # the Free Software Foundation; either version 2 of the License, or
13: # (at your option) any later version.
14: #
15: # LON-CAPA is distributed in the hope that it will be useful,
16: # but WITHOUT ANY WARRANTY; without even the implied warranty of
17: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18: # GNU General Public License for more details.
19: #
20: # You should have received a copy of the GNU General Public License
21: # along with LON-CAPA; if not, write to the Free Software
22: # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
23: #
24: # /home/httpd/html/adm/gpl.txt
25: #
26: # http://www.lon-capa.org/
27: #
28:
29:
30:
31:
32:
33: package Apache::optionresponse;
34: use strict;
35: use Apache::response();
36: use Apache::lonlocal;
37: use Apache::lonnet;
38:
39: BEGIN {
40: &Apache::lonxml::register('Apache::optionresponse',('optionresponse'));
41: }
42:
43: sub start_optionresponse {
44: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
45: my $result='';
46: #when in a option response use these
47: &Apache::lonxml::register('Apache::optionresponse',('foilgroup','foil','conceptgroup','drawoptionlist'));
48: push (@Apache::lonxml::namespace,'optionresponse');
49: my $id = &Apache::response::start_response($parstack,$safeeval);
50: %Apache::hint::option=();
51: undef(%Apache::response::foilnames);
52: if ($target eq 'edit') {
53: $result.=&Apache::edit::start_table($token)
54: .'<tr><td><span class="LC_nobreak">'.&mt('Multiple Option Response Question').'</span> '
55: .&Apache::loncommon::help_open_topic('Option_Response_Problems')."</td>"
56: .'<td><span class="LC_nobreak">'.&mt('Delete?').' '
57: .&Apache::edit::deletelist($target,$token)
58: .'</span></td>'
59: ."<td> "
60: .&Apache::edit::end_row()
61: .&Apache::edit::start_spanning_row()
62: ."\n";
63: $result.=&Apache::edit::text_arg('Max Number Of Shown Foils:','max',
64: $token,'4').
65: &Apache::edit::select_arg('Randomize Foil Order:','randomize',
66: ['yes','no'],$token).
67: &Apache::edit::select_arg(&mt('Display of options when printed'),'TeXlayout',
68: [['horizontal','Normal list'],
69: ['vertical','Listed in a vertical column']],$token).
70: &Apache::edit::end_row().&Apache::edit::start_spanning_row();
71: } elsif ($target eq 'modified') {
72: my $constructtag=&Apache::edit::get_new_args($token,$parstack,
73: $safeeval,'max','randomize',
74: 'TeXlayout');
75: if ($constructtag) { $result = &Apache::edit::rebuild_tag($token); }
76: } elsif ($target eq 'meta') {
77: $result=&Apache::response::meta_package_write('optionresponse');
78: } elsif ($target eq 'analyze') {
79: my $part_id="$Apache::inputtags::part.$id";
80: $Apache::lonhomework::analyze{"$part_id.type"} = 'optionresponse';
81: push (@{ $Apache::lonhomework::analyze{"parts"} },$part_id);
82: push (@{ $Apache::lonhomework::analyze{"$part_id.bubble_lines"} }, 1);
83:
84: }
85: return $result;
86: }
87:
88: sub end_optionresponse {
89: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
90: &Apache::response::end_response;
91: pop @Apache::lonxml::namespace;
92: &Apache::lonxml::deregister('Apache::optionresponse',('foilgroup','foil','conceptgroup','drawoptionlist'));
93: my $result;
94: if ($target eq 'edit') { $result=&Apache::edit::end_table(); }
95: undef(%Apache::response::foilnames);
96: return $result;
97: }
98:
99: %Apache::response::foilgroup=();
100: sub start_foilgroup {
101: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
102:
103: my $result='';
104: %Apache::response::foilgroup=();
105: $Apache::optionresponse::conceptgroup=0;
106: &Apache::response::pushrandomnumber(undef,$target);
107: if ($target eq 'edit') {
108: my $optionlist="<option></option>\n";
109: my $option;
110: my @opt;
111: my @raw_options = &Apache::lonxml::get_param('options', $parstack, $safeeval, 0, 0, 1);
112:
113:
114: eval '@opt ='. &Apache::lonxml::get_param('options',$parstack,$safeeval, 0, 0, 1);
115:
116: my $count=1;
117: foreach $option (@opt) {
118: $optionlist.="<option value=\"$count\">$option</option>\n";
119: $count++;
120: }
121: my $insertlist=&Apache::edit::insertlist($target,$token);
122: $result.=&Apache::edit::start_table($token);
123: $result.= (<<ENDTABLE);
124: <tr><td>Select Options</td>
125: <td>
126: Add new Option: <input type="text" name="$Apache::lonxml::curdepth.options" />
127: </td>
128: <td>Delete an Option:
129: <select name="$Apache::lonxml::curdepth.deleteopt">$optionlist</select>
130: </td>
131: ENDTABLE
132: $result.= '<td>'.&Apache::edit::checked_arg('Print options:','texoptions',
133: [ ['nochoice','Don\'t show option list'] ]
134: ,$token).'</td>';
135: $result.= '<td><label>'.&mt('Two-option checkboxes for:').
136: '<select name="checkboxvalue_'.$Apache::lonxml::curdepth.'">';
137: foreach $option (('',@opt)) {
138: $result.='<option value="'.$option.'"';
139: if ($option eq &Apache::lonxml::get_param('checkboxvalue',$parstack,$safeeval)) {
140: $result.=' selected="selected"';
141: }
142: $result.='>'.$option.'</option>';
143: }
144: $result.='</select></label>';
145: $result.=&Apache::edit::checked_arg('Checkbox options:','checkboxoptions',
146: [ ['nochoice','Don\'t show option list'] ]
147: ,$token).'</td>';
148: $result.= &Apache::edit::end_row();
149: $result.= &Apache::edit::start_spanning_row();
150: $result.= $insertlist.'<br />';
151: }
152: if ($target eq 'modified') {
153: my @options;
154: my $optchanged=0;
155:
156:
157: eval '@options ='.&Apache::lonxml::get_param('options',$parstack,$safeeval, 0, 0, 1);
158:
159: if ($env{"form.$Apache::lonxml::curdepth.deleteopt"}) {
160: my $delopt=$env{"form.$Apache::lonxml::curdepth.deleteopt"};
161: &Apache::lonxml::debug("Deleting :$delopt:");
162: splice(@options,$delopt-1,1);
163: $optchanged=1;
164: }
165: if ($env{"form.$Apache::lonxml::curdepth.options"} ne '') {
166: my $newopt = $env{"form.$Apache::lonxml::curdepth.options"};
167: push(@options,$newopt);
168: $optchanged=1;
169: }
170: my $rebuildtag = &Apache::edit::get_new_args($token,$parstack,$safeeval,
171: 'texoptions','checkboxvalue','checkboxoptions');
172: if ($optchanged || $rebuildtag ) {
173: $result = "<foilgroup options=\"(";
174: foreach my $option (@options) {
175: $option=~s/\'/\\\'/g;
176: &Apache::lonxml::debug("adding option :$option:");
177: $result .="'".$option."',";
178: }
179: chop $result;
180: $result.=')" ';
181: $result .= 'texoptions="'.$token->[2]{'texoptions'}.'" ';
182: $result .= 'checkboxoptions="'.$token->[2]{'checkboxoptions'}.'" ';
183: $result .= 'checkboxvalue="'.$token->[2]{'checkboxvalue'}.'"';
184: $result .= '>';
185: } # else nothing changed so just use the default mechanism
186: }
187: if ($target eq 'tex' and $Apache::lonhomework::type ne 'exam') {
188: if($env{'form.pdfFormFields'} ne 'yes') {
189: $result .= ' \begin{itemize} ';
190: } else {
191: $result .= "\\\\";
192: }
193: }
194: return $result;
195: }
196:
197: sub end_foilgroup {
198: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
199:
200: my $result;
201: if ($target eq 'grade' || $target eq 'web' || $target eq 'answer' ||
202: $target eq 'tex' || $target eq 'analyze') {
203: my $tex_option_switch=&Apache::lonxml::get_param('texoptions',$parstack,$safeeval);
204: my $name;
205: my @opt;
206: eval '@opt ='.&Apache::lonxml::get_param('options',$parstack,$safeeval);
207: &Apache::lonxml::debug("options:".join(':',@opt));
208:
209: my $TeXlayout=&Apache::lonxml::get_param('TeXlayout',$parstack,$safeeval,
210: -2,0);
211: my $checkboxvalue=&Apache::lonxml::get_param('checkboxvalue',$parstack,$safeeval);
212: my $checkboxchoices=(&Apache::lonxml::get_param('checkboxoptions',$parstack,$safeeval) ne 'nochoice');
213: my $noprompt =&Apache::lonxml::get_param('noprompt', $parstack, $safeeval);
214:
215: if ($target eq 'tex' && $tex_option_switch eq 'nochoice') {@opt=();}
216: &Apache::lonxml::debug("Options are $#opt");
217: my $max = &Apache::lonxml::get_param('max',$parstack,$safeeval,'-2');
218: my $randomize = &Apache::lonxml::get_param('randomize',$parstack,
219: $safeeval,'-2');
220: if ($target eq 'web' || $target eq 'tex') {
221: $result.=&displayfoils($target,$max,$randomize,$TeXlayout,$checkboxvalue,$checkboxchoices,$tex_option_switch, $noprompt, @opt);
222: $Apache::lonxml::post_evaluate=0;
223: } elsif ( $target eq 'answer') {
224: $result.=&displayanswers($max,$randomize,@opt);
225:
226: } elsif ( $target eq 'analyze') {
227: my @shown = &whichfoils($max,$randomize);
228: &Apache::response::analyze_store_foilgroup(\@shown,
229: ['text','value','location']);
230: my $part_id="$Apache::inputtags::part.$Apache::inputtags::response[-1]";
231: push (@{ $Apache::lonhomework::analyze{"$part_id.options"} },@opt);
232: } elsif ( $target eq 'grade') {
233:
234: if ( &Apache::response::submitted()) {
235:
236: my @whichopt = &whichfoils($max,$randomize);
237: my $temp=1;my $name;
238: my %responsehash;
239: my %grade;
240: my $right=0;
241: my $wrong=0;
242: my $ignored=0;
243: my ($numrows,$bubbles_per_row);
244: if ($Apache::lonhomework::scantronmode) {
245: my $numitems = scalar(@opt);
246: ($numrows,$bubbles_per_row) =
247: &Apache::optionresponse::getnumrows($numitems);
248: }
249: if ($numrows < 1) {
250: $numrows = 1;
251: }
252: foreach $name (@whichopt) {
253: my $response;
254: if ($env{'form.submitted'} eq 'scantron') {
255: if ($numrows > 1) {
256: my $num = $temp;
257: my $totalnum;
258: for (my $i=0; $i<$numrows; $i++) {
259: my $item = &Apache::response::getresponse($num);
260: if ($item =~ /^\d+$/) {
261: $totalnum = $i*$bubbles_per_row + $item;
262: }
263: $num ++;
264: }
265: if ($totalnum =~ /^\d+$/) {
266: $response = $opt[$totalnum];
267: }
268: $temp += $numrows;
269: } else {
270: $response=&Apache::response::getresponse($temp);
271: if ($response=~/\S/) {
272: $response = $opt[$response];
273: }
274: $temp ++;
275: }
276: } else {
277: $response=&Apache::response::getresponse($temp);
278: $temp ++;
279: }
280: if ( $response =~ /[^\s]/) {
281: $responsehash{$name}=$response;
282: my $value=$Apache::response::foilgroup{$name.'.value'};
283: &Apache::lonxml::debug("submitted a $response for $value<br />\n");
284: if ($value eq $response) {
285: $grade{$name}='1'; $right++;
286: } else {
287: $grade{$name}='0'; $wrong++;
288: }
289: } else {
290: $ignored++;
291: }
292: }
293: my $part=$Apache::inputtags::part;
294: my $nonlenient=&grading_is_nonlenient($part);
295: my $id = $Apache::inputtags::response['-1'];
296: my $responsestr=&Apache::lonnet::hash2str(%responsehash);
297: my $gradestr =&Apache::lonnet::hash2str(%grade);
298: my %previous=&Apache::response::check_for_previous($responsestr,
299: $part,$id);
300: &Apache::lonxml::debug("Got $right right and $wrong wrong, and $ignored were ignored");
301: $Apache::lonhomework::results{"resource.$part.$id.submission"}=
302: $responsestr;
303: $Apache::lonhomework::results{"resource.$part.$id.submissiongrading"}=$gradestr;
304: if ($Apache::lonhomework::type eq 'randomizetry') {
305: $Apache::lonhomework::results{"resource.$part.$id.foilorder"} = &Apache::lonnet::array2str(@whichopt);
306: }
307: if (($Apache::lonhomework::type eq 'survey') ||
308: ($Apache::lonhomework::type eq 'surveycred') ||
309: ($Apache::lonhomework::type eq 'anonsurvey') ||
310: ($Apache::lonhomework::type eq 'anonsurveycred')) {
311: if ($ignored == 0) {
312: my $ad;
313: if ($Apache::lonhomework::type eq 'anonsurveycred') {
314: $ad=$Apache::lonhomework::results{"resource.$part.$id.awarddetail"}='ANONYMOUS_CREDIT';
315: } elsif ($Apache::lonhomework::type eq 'anonsurvey') {
316: $ad=$Apache::lonhomework::results{"resource.$part.$id.awarddetail"}='ANONYMOUS';
317: } elsif ($Apache::lonhomework::type eq 'surveycred') {
318: $ad=$Apache::lonhomework::results{"resource.$part.$id.awarddetail"}='SUBMITTED_CREDIT';
319: } else {
320: $ad=$Apache::lonhomework::results{"resource.$part.$id.awarddetail"}='SUBMITTED';
321: }
322: &Apache::response::handle_previous(\%previous,$ad);
323: } elsif ($wrong==0 && $right==0) {
324: } else {
325: my $ad=$Apache::lonhomework::results{"resource.$part.$id.awarddetail"}='MISSING_ANSWER';
326: &Apache::response::handle_previous(\%previous,$ad);
327: }
328: } elsif ($nonlenient) {
329: #
330: # Non-lenient mode. All right or all wrong
331: #
332: my $ad;
333: if ($wrong==0 && $ignored==0) {
334: $ad='EXACT_ANS';
335: } elsif ($wrong==0 && $right==0) {
336: #nothing submitted
337: } else {
338: if ($ignored==0) {
339: $ad='INCORRECT';
340: } else {
341: $ad='MISSING_ANSWER';
342: }
343: }
344: $Apache::lonhomework::results{"resource.$part.$id.awarddetail"}=$ad;
345: &Apache::response::handle_previous(\%previous,$ad);
346: } else {
347: #
348: # This is lenient mode
349: #
350: my $ad;
351: if ($wrong==0 && $right==0) {
352: #nothing submitted only assign a score if we
353: #need to override a previous grade
354: if (defined($Apache::lonhomework::history{"resource.$part.$id.awarddetail"})) {
355: $ad='ASSIGNED_SCORE';
356: }
357: } else {
358: $ad='ASSIGNED_SCORE';
359: }
360: $Apache::lonhomework::results{"resource.$part.$id.awarddetail"}=$ad;
361: $Apache::lonhomework::results{"resource.$part.$id.awarded"}=
362: $right/(scalar(@whichopt));
363: $Apache::lonhomework::results{"resource.$part.$id.numfoils"}=
364: scalar(@whichopt);
365: }
366: }
367: }
368: my $part_id = $Apache::inputtags::part;
369: my $response_id = $Apache::inputtags::response[-1];
370: my ($numrows,$bubbles_per_row);
371: if (($target eq 'tex') && ($Apache::lonhomework::type eq 'exam')) {
372: ($numrows,$bubbles_per_row) =
373: &Apache::optionresponse::getnumrows(scalar(@opt));
374: }
375: if ($numrows < 1) {
376: $numrows = 1;
377: }
378: my $increment = &getfoilcounts($max) * $numrows;
379: &Apache::lonxml::increment_counter($increment,"$part_id.$response_id");
380: if ($target eq 'analyze') {
381: &Apache::lonhomework::set_bubble_lines();
382: }
383:
384: } elsif ($target eq 'edit') {
385: $result.=&Apache::edit::end_table();
386: }
387: if ($target eq 'tex' and $Apache::lonhomework::type ne 'exam') {
388: if($env{'form.pdfFormFields'} ne 'yes') {
389: $result .= '\end{itemize}';
390: } else {
391: $result .= "\\\\";
392: }
393: }
394: &Apache::response::poprandomnumber();
395: return $result;
396: }
397:
398: sub grading_is_nonlenient {
399: my ($part) = @_;
400: # Web mode: we are non-lenient unless told otherwise
401: my $defaultparm = 'off';
402: my $nonlenient = 0;
403: # Grading a bubblesheet exam: we are grading lenient unless told otherwise
404: if ($Apache::lonhomework::scantronmode) {
405: $defaultparm = 'on';
406: $nonlenient = 1;
407: }
408: my $lenientparm =
409: &Apache::response::get_response_param($part,'lenient',$defaultparm);
410: if ($lenientparm=~/^0|off|no$/i) {
411: $nonlenient = 1;
412: } elsif ($lenientparm=~/^1|on|yes$/i) {
413: $nonlenient = 0;
414: }
415: return $nonlenient;
416: }
417:
418: sub getfoilcounts {
419: my ($max)=@_;
420: # +1 since instructors will count from 1
421: my $count = $#{ $Apache::response::foilgroup{'names'} }+1;
422: if (&Apache::response::showallfoils()) { $max=$count; }
423: if ($count>$max) { $count=$max }
424: &Apache::lonxml::debug("Count is $count from $max");
425: return $count;
426: }
427:
428: sub whichfoils {
429: my ($max,$randomize)=@_;
430: return &Apache::response::whichorder($max,$randomize,
431: &Apache::response::showallfoils(),
432: \%Apache::response::foilgroup);
433: }
434:
435: sub displayanswers {
436: my ($max,$randomize,@opt)=@_;
437: my @names;
438: if (ref($Apache::response::foilgroup{'names'}) eq 'ARRAY') {
439: @names = @{ $Apache::response::foilgroup{'names'} };
440: }
441: return if (!@names);
442: my @whichopt = &whichfoils($max,$randomize);
443: my $result;
444: if ($Apache::lonhomework::type eq 'exam') {
445: my $i = 0;
446: my %opt = map { ($_,$i++) } @opt;
447:
448: $i = 0;
449: my @alphabet = ('A'..'Z');
450: foreach my $name (@whichopt) {
451: $result.=&Apache::response::answer_header('optionresponse',$i++);
452: $result.=&Apache::response::answer_part('optionresponse',
453: $alphabet[$opt{$Apache::response::foilgroup{$name.'.value'}}]);
454: $result.=&Apache::response::answer_part('optionresponse',
455: $Apache::response::foilgroup{$name.'.value'});
456: $result.=&Apache::response::answer_footer('optionresponse');
457: }
458: } else {
459: $result=&Apache::response::answer_header('optionresponse');
460: foreach my $name (@whichopt) {
461: $result.=&Apache::response::answer_part('optionresponse',
462: $Apache::response::foilgroup{$name.'.value'});
463: }
464: $result.=&Apache::response::answer_footer('optionresponse');
465: }
466: return $result;
467: }
468:
469: sub check_box_opt {
470: my ($target,$checkboxvalue,@opt)=@_;
471: # Check if we are in checkbox mode: checkboxvalue specified, on web, only two options.
472: # If so, return "checked" value
473: if ($#opt!=1) { return ''; }
474: if ($target ne 'web') { return ''; }
475: return $checkboxvalue;
476: }
477:
478: sub check_for_invalid {
479: my ($names,$options) = @_;
480: my %bad_names;
481: foreach my $name (@{ $names }) {
482: my $value=$Apache::response::foilgroup{$name.'.value'};
483: my $found=0;
484: foreach my $option (@{ $options }) {
485: if ($value eq $option) { $found=1; }
486: }
487: if (!$found) { $bad_names{$name}=$value; }
488: }
489: if (%bad_names) {
490: my $error=&mt('The question can not be gotten correct, '.
491: 'the following foils in the <optionresponse> '.
492: 'have invalid correct options').' <br /><tt>'.
493: join('<br />',(map { $_=&mt("[_1] with value [_2]",$_,$bad_names{$_}) } (keys(%bad_names)))).
494: "</tt>";
495: &Apache::lonxml::error($error);
496: }
497: }
498:
499: sub displayfoils {
500: my ($target,$max,$randomize,$TeXlayout,$checkboxvalue,$checkboxchoices,
501: $tex_option_switch, $no_tfprompt, @opt)=@_;
502: my @names;
503: if (ref($Apache::response::foilgroup{'names'}) eq 'ARRAY') {
504: @names = @{ $Apache::response::foilgroup{'names'} };
505: }
506: unless (@names > 0) { return;}
507: my @truelist;
508: my @falselist;
509: my $result;
510: my $name;
511: my $displayoptionintex=1;
512: my @alphabet = ('A'..'Z');
513: my @whichopt = &whichfoils($max,$randomize);
514: unless (($target eq 'tex') && ($tex_option_switch eq 'nochoice')) {
515: &check_for_invalid(\@whichopt,\@opt);
516: }
517: my $part=$Apache::inputtags::part;
518: my $id=$Apache::inputtags::response[-1];
519: my $break;
520: if ( ($target ne 'tex') &&
521: &Apache::response::show_answer() ) {
522: my $temp=1;
523: foreach $name (@whichopt) {
524: my $text=$Apache::response::foilgroup{$name.'.text'};
525: my $lastresp;
526: unless ((($Apache::lonhomework::history{"resource.$part.type"} eq 'anonsurvey') || ($Apache::lonhomework::history{"resource.$part.type"} eq 'anonsurveycred')) && (defined($env{'form.grade_symb'}))) {
527: $lastresp = $Apache::lonhomework::history{"resource.$part.$id.submission"};
528: }
529: my %lastresponse=&Apache::lonnet::str2hash($lastresp);
530: my $lastopt=$lastresponse{$name};
531: if ($text!~/^\s*$/) { $break='<br />'; }
532: $result.=$break;
533: if ($target eq 'web') {
534: my $value=$Apache::response::foilgroup{$name.'.value'};
535: if (!($text=~s|<drawoptionlist\s*/>|$value|)) {
536: if ($text=~/^\s*$/) {
537: $text=$value.$text;
538: } else {
539: $text='<b>'.$value.':</b> '.$text;
540: }
541: } else {
542: if (@whichopt > 1) {
543: $text='•'.$text;
544: }
545: }
546: $result.=$text."\n";
547: }
548: if ($Apache::lonhomework::type eq 'exam') {
549: $result.=&webbubbles(\@opt,\@alphabet,$temp,$lastopt);
550: }
551: $temp++;
552: }
553: } else {
554: my $temp=1;
555: my %lastresponse;
556: my $newvariation;
557: if ((($Apache::lonhomework::history{"resource.$part.type"} eq 'randomizetry') ||
558: ($Apache::lonhomework::type eq 'randomizetry')) &&
559: ($Apache::inputtags::status[-1] eq 'CAN_ANSWER')) {
560: if ($env{'form.'.$part.'.rndseed'} ne
561: $Apache::lonhomework::history{"resource.$part.rndseed"}) {
562: $newvariation = 1;
563: }
564: }
565: unless ($newvariation) {
566: %lastresponse=&Apache::lonnet::str2hash($Apache::lonhomework::history{"resource.$part.$id.submission"});
567: }
568: my $internal_counter=$Apache::lonxml::counter;
569: my $checkboxopt=&check_box_opt($target,$checkboxvalue,@opt);
570: if ($checkboxopt && (!$no_tfprompt)) {
571: $result.='<br />'.
572: ($checkboxchoices?&mt('Choices: ').'<b>'.$opt[0].','.$opt[1].'</b>. ':'').
573: &mt('Select all that are <b>[_1]</b>.',$checkboxopt);
574: }
575: foreach $name (@whichopt) {
576: my $text=$Apache::response::foilgroup{$name.'.text'};
577: if ($text!~/^\s*$/) {
578: if ($target eq 'tex') {
579: $break='\vskip 0 mm ';
580: } elsif ($target eq 'web') {
581: $break='<br />';
582: }
583: }
584: my $lastopt=$lastresponse{$name};
585: my $optionlist="<option></option>\n";
586:
587: if($target eq 'tex' and $env{'form.pdfFormFields'} eq 'yes'
588: && $Apache::inputtags::status[-1] eq 'CAN_ANSWER') {
589: my $fieldname = $env{'request.symb'}.'&part_'.$Apache::inputtags::part.'&optionresponse'.'&HWVAL_'.$Apache::inputtags::response['-1'].':'.$temp;
590: $optionlist = &Apache::lonxml::print_pdf_start_combobox($fieldname);
591: }
592:
593: foreach my $option (@opt) {
594: my $escopt=&HTML::Entities::encode($option,'\'"&<>');
595: if ($option eq $lastopt) {
596: if ($target eq 'tex' && $env{'form.pdfFormFields'} eq 'yes'
597: && $Apache::inputtags::status[-1] eq 'CAN_ANSWER'
598: && $Apache::lonhomework::type ne 'exam') {
599: $optionlist .= &Apache::lonxml::print_pdf_add_combobox_option($option);
600: } else {
601: $optionlist.="<option value='".$escopt."' selected=\"selected\">$option</option>\n";
602: }
603: } else {
604: if ($target eq 'tex' && $env{'form.pdfFormFields'} eq 'yes'
605: && $Apache::inputtags::status[-1] eq 'CAN_ANSWER'
606: && $Apache::lonhomework::type ne 'exam') {
607: $optionlist .= &Apache::lonxml::print_pdf_add_combobox_option($option);
608: } else {
609: $optionlist.="<option value='".$escopt."'>$option</option>\n";
610: }
611: }
612: }
613: if ($target ne 'tex') {
614: if ($Apache::lonhomework::type ne 'exam') {
615: # we are on the web, this is not an exam, and the problem can be answered
616: if ($checkboxopt) {
617: # generate checkboxes
618: my $fieldname=$Apache::inputtags::response['-1'].':'.$temp;
619: my $altopt=$opt[0];
620: if ($opt[0] eq $checkboxopt) {
621: $altopt=$opt[1];
622: }
623: my $defopt=$lastopt;
624: unless ($defopt) { $defopt=$altopt; }
625: my $escdefopt=&HTML::Entities::encode($defopt,'\'"&<>');
626: my $esccheckboxopt=&HTML::Entities::encode($checkboxopt,'\'"&<>');
627: my $escaltopt=&HTML::Entities::encode($altopt,'\'"&<>');
628: # checkboxopt is how the box is labelled
629: # altopt is the alternative option
630: # lastopt is what the user submitted before
631: # defopt is what the field is going to start out with: either previous choice or altopt
632: # fieldname is this input field's name after HWVAL_
633: $optionlist='<input type="hidden" name="HWVAL_'.$fieldname.'" value="'.$escdefopt.'" />'.
634: '<input type="checkbox" name="HWCHK_'.$fieldname.'" onclick="javascript:if (this.form.elements[\'HWCHK_'.
635: $fieldname.'\'].checked) { this.form.elements[\'HWVAL_'.$fieldname.'\'].value=\''.$esccheckboxopt.'\'; } else { this.form.elements[\'HWVAL_'.$fieldname.'\'].value=\''.$escaltopt.'\'; };setSubmittedPart(\''.$part.'\');"'.($defopt eq $checkboxopt?' checked="checked"':'')." />\n";
636: } else {
637: # classic selection list
638: $optionlist='<select onchange="javascript:setSubmittedPart(\''.
639: $part.'\');" name="HWVAL_'.
640: $Apache::inputtags::response['-1'].':'.$temp.'">'.
641: $optionlist."</select>\n";
642: }
643: } else {
644: $optionlist='<u>'.(' 'x10).'</u>';
645: }
646: if ($text=~s|<drawoptionlist\s*/>|$optionlist|) {
647: if ($Apache::lonhomework::type ne 'exam') {
648: if (@whichopt > 1) {
649: $text='•'.$text;
650: }
651: }
652: } else {
653: if ($Apache::lonhomework::type ne 'exam') {
654: $text=$optionlist.$text;
655: }
656: }
657: $result.=$break.$text."\n";
658: if ($Apache::lonhomework::type eq 'exam') {
659: $result.=&webbubbles(\@opt,\@alphabet,$temp,$lastopt);
660: }
661: $temp++;
662: } else {
663: my $texoptionlist='';
664: if ($displayoptionintex &&
665: $Apache::lonhomework::type ne 'exam') {
666: $texoptionlist = &optionlist_correction($TeXlayout,@opt);
667: }
668: if ($text=~/<drawoptionlist\s*\/>/) {
669: $text=~s|<drawoptionlist\s*\/>| \\makebox\[0\.3in\]\[b\]\{\\hrulefill\} |g;
670: }
671:
672: if ($text=~m/\\item /) {
673: if ($Apache::lonhomework::type eq 'exam') {
674: $text=~s/\\item/\\vskip 2 mm/;
675: } elsif ($env{'form.pdfFormFields'} ne 'yes') {
676: $result.= $texoptionlist.$text;
677: }
678: } else {
679: if ($Apache::lonhomework::type eq 'exam') {
680: $result.= $texoptionlist.' '.$text;
681: } elsif ($env{'form.pdfFormFields'} ne 'yes') {
682: if ($text=~/\S/) {
683: $result.= $texoptionlist.'\vspace*{-2 mm}\item '.$text;
684: } else {
685: $result.= $texoptionlist;
686: }
687: }
688: }
689: if ($Apache::lonhomework::type eq 'exam') {
690: $result.='\vskip -1 mm\noindent';
691: my ($numrows,$bubbles_per_row) = &getnumrows(scalar(@opt));
692: if ($numrows == 1) {
693: $result .= '\textbf{'.$internal_counter.'}. \vskip -3mm';
694: } else {
695: my $linetext;
696: for (my $i=0; $i<$numrows; $i++) {
697: $linetext .= $internal_counter+$i.', ';
698: }
699: $linetext =~ s/,\s$//;
700: $result .= '\small {\textbf{'.$linetext.'}} '.
701: '\hskip 2 mm {\footnotesize '.
702: &mt('(Bubble once in [_1] lines)',$numrows).
703: '} \vskip 1 mm';
704: }
705: $result.= &bubbles(\@alphabet,\@opt,undef,undef,$numrows,
706: $bubbles_per_row,$internal_counter).
707: ' \strut ';
708: $internal_counter += $numrows;
709: }
710: if ($target eq 'tex' && $env{'form.pdfFormFields'} eq 'yes'
711: && $Apache::inputtags::status[-1] eq 'CAN_ANSWER'
712: && $Apache::lonhomework::type ne 'exam') {
713: $text =~ s/\\item//m;
714: $result .= " $optionlist ". &Apache::lonxml::print_pdf_end_combobox($text).'\strut \\\\';
715: $temp++;
716: }
717: $displayoptionintex=0;
718: }
719: }
720: }
721:
722: if ($target eq 'web') {
723: my $data = [\@whichopt,'submissiongrading'];
724: my $questiontype;
725: if ($Apache::lonhomework::type eq 'randomizetry') {
726: $questiontype = $Apache::lonhomework::type,
727: }
728: &Apache::response::setup_prior_tries_hash(\&Apache::rankresponse::format_prior_answer,$data,$questiontype);
729: }
730:
731: if ($target ne 'tex') {
732: return $result.$break;
733: } else {
734: return $result;
735: }
736: }
737:
738:
739: sub optionlist_correction {
740: my ($TeXlayout,@options) = @_;
741: my $texoptionlist='\\item [] '.&mt('Choices:').' ';
742: if ($TeXlayout eq 'vertical') {$texoptionlist='\\item []';}
743: if (scalar(@options) > 0) {
744: foreach my $option (@options) {
745: $texoptionlist.='{\bf '.
746: &Apache::lonxml::latex_special_symbols($option).
747: '}';
748: if ($TeXlayout eq 'vertical') {
749: $texoptionlist.=' \vskip 0 mm ',
750: } else {
751: $texoptionlist.=', ';
752: }
753: }
754: $texoptionlist=~s/, $//;
755: if ($TeXlayout ne 'vertical') {$texoptionlist.='.';}
756: } else {
757: if ($TeXlayout ne 'vertical') {$texoptionlist='\\item [] \\vskip -5 mm';}
758: }
759: return $texoptionlist;
760: }
761:
762:
763: sub webbubbles {
764: my ($ropt,$ralphabet,$temp,$lastopt)=@_;
765: my @opt=@$ropt;
766: my @alphabet=@$ralphabet;
767: my $result='';
768: my $number_of_bubbles = $#opt + 1;
769: $result.= '<table border="1"><tr>';
770: for (my $ind=0;$ind<$number_of_bubbles;$ind++) {
771: my $checked='';
772: if ($lastopt eq $opt[$ind]) {
773: $checked=' checked="on" ';
774: }
775: $result.='<td><input type="radio" name="HWVAL_'.
776: $Apache::inputtags::response['-1'].':'.$temp.
777: '" value="'.$opt[$ind].'" '.$checked.' />';
778: if ($alphabet[$ind]) {
779: $result.=$alphabet[$ind].': ';
780: }
781: $result.=$opt[$ind].'</td>';
782: }
783: $result.='</tr></table>';
784: return $result;
785: }
786:
787:
788: sub bubbles {
789: my ($ralphabet,$ropt,$response,$max_width,$numrows,$bubbles_per_row,
790: $internal_counter) = @_;
791: my @alphabet = @$ralphabet;
792: my @opt = @$ropt;
793: my ($result,$head,$line) =('','','');
794: my $number_of_bubbles = $#opt + 1;
795: my $current_length = 0;
796: my $textwidth;
797: if (defined($max_width)) {
798: $textwidth=$max_width;
799: &Apache::lonxml::debug("Max width passed in: $max_width");
800: } elsif ($env{'form.textwidth'} ne '') {
801: $env{'form.textwidth'}=~/(\d+)/;
802: $textwidth=$1;
803: &Apache::lonxml::debug("Max width from form: $textwidth");
804: } else {
805: $env{'form.textwidth'}=~/(\d*)\.?(\d*)/;
806: $textwidth=$1.'.'.$2;
807: &Apache::lonxml::debug("Max width defaults? $textwidth");
808: }
809: &Apache::lonxml::debug("Final maxwidth: $textwidth");
810: for (my $ind=0;$ind<=$number_of_bubbles;$ind++) {
811: my $item;
812: if ($numrows > 1) {
813: my $num = $internal_counter+int($ind/$bubbles_per_row);
814: my $idx = int($ind % $bubbles_per_row);
815: $item = $num.$alphabet[$idx];
816: } else {
817: $item = $alphabet[$ind];
818: }
819: my $leftmargin;
820: $opt[$ind]=&Apache::lonxml::latex_special_symbols($opt[$ind]);
821: if ($response eq 'rankresponse') {$opt[$ind]='Rank '.$opt[$ind];}
822: if ($ind==0) {$leftmargin=6;} else {$leftmargin=10;}
823:
824: $current_length += (length($opt[$ind])+length($item)+5)*2;
825:
826: if ($current_length<($textwidth-$leftmargin) and $ind!=$number_of_bubbles) {
827:
828: $line.='\hskip 4 mm {\small \textbf{'.$item.'}}$\bigcirc$\hskip -1 mm & \hskip -3 mm {\small '.$opt[$ind].'} & ';
829: $head.='lr';
830: } else {
831: $line=~s/\&\s*$//;
832: $result.='\vskip -1 mm\noindent\setlength{\tabcolsep}{2 mm}\renewcommand{\arraystretch}{1.25}\begin{tabular}{'.$head.'}'.$line.'\\\\\end{tabular}\vskip 0 mm';
833: $line = '\hskip 4 mm {\small \textbf{'.$item.'}}$\bigcirc$\hskip -1 mm & \hskip -3 mm {\small '.$opt[$ind].'} & ';
834: $head ='lr';
835: $current_length = (length($opt[$ind])+length($item))*2;
836: }
837:
838: }
839: return $result;
840: }
841:
842: sub start_conceptgroup {
843: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
844: $Apache::optionresponse::conceptgroup=1;
845: %Apache::response::conceptgroup=();
846: my $result;
847: if ($target eq 'edit') {
848: $result.=&Apache::edit::tag_start($target,$token,"Concept Grouped Foils");
849: $result.=&Apache::edit::text_arg('Concept:','concept',$token,'50').
850: &Apache::edit::end_row().&Apache::edit::start_spanning_row();
851: }
852: if ($target eq 'modified') {
853: my $constructtag=&Apache::edit::get_new_args($token,$parstack,$safeeval,'concept');
854: if ($constructtag) { $result = &Apache::edit::rebuild_tag($token); }
855: }
856: return $result;
857: }
858:
859: sub end_conceptgroup {
860: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
861: $Apache::optionresponse::conceptgroup=0;
862: my $result='';
863: if ($target eq 'web' || $target eq 'grade' || $target eq 'answer' ||
864: $target eq 'tex' || $target eq 'analyze') {
865: #if not there aren't any foils to display and thus no question
866: &Apache::response::pick_foil_for_concept($target,
867: ['value','text','location'],
868: \%Apache::hint::option,
869: $parstack,$safeeval);
870: } elsif ($target eq 'edit') {
871: $result=&Apache::edit::end_table();
872: }
873: return $result;
874: }
875:
876: sub insert_conceptgroup {
877: my $result="\n\t\t<conceptgroup concept=\"\">".&insert_foil()."\n\t\t</conceptgroup>\n";
878: return $result;
879: }
880:
881: sub start_foil {
882: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
883: my $result='';
884: if ($target eq 'web' || $target eq 'tex' || $target eq 'analyze' ) {
885: &Apache::lonxml::startredirection;
886: if ($target eq 'analyze') {
887: &Apache::response::check_if_computed($token,$parstack,$safeeval,'value');
888: }
889: } elsif ($target eq 'edit') {
890: $result=&Apache::edit::tag_start($target,$token,"Foil");
891: my $level='-2';
892: if ($$tagstack['-2'] eq 'conceptgroup') { $level = '-3'; }
893: my @opt;
894: eval '@opt ='.&Apache::lonxml::get_param('options',$parstack,$safeeval,$level);
895: $result.=&Apache::edit::text_arg('Name:','name',$token);
896: $result.= &Apache::edit::select_or_text_arg('Correct Option:','value',
897: ['unused',(@opt)],$token,'15');
898: my $randomize=&Apache::lonxml::get_param('randomize',$parstack,
899: $safeeval,'-3');
900: if ($randomize ne 'no') {
901: $result.=&Apache::edit::select_arg('Location:','location',
902: ['random','top','bottom'],$token);
903: }
904: $result .=&Apache::edit::end_row().&Apache::edit::start_spanning_row();
905: } elsif ($target eq 'modified') {
906: my $constructtag=&Apache::edit::get_new_args($token,$parstack,$safeeval,
907: 'value','name','location');
908: if ($constructtag) { $result = &Apache::edit::rebuild_tag($token); }
909: }
910: return $result;
911: }
912:
913: sub end_foil {
914: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
915: my $text ='';
916: my $result = '';
917: if ($target eq 'web' || $target eq 'tex' || $target eq 'analyze') {
918: $text=&Apache::lonxml::endredirection;
919: if ($target eq 'tex') {$text=~s/\\strut\s*\\\\\s*\\strut/\\vskip 0 mm/;}
920: if (($target eq 'tex') and ($Apache::lonhomework::type ne 'exam') and ($text=~/\S/)) {$text = '\vspace*{-2 mm}\item '.$text;}
921: }
922: if ($target eq 'web' || $target eq 'grade' || $target eq 'answer'
923: || $target eq 'tex' || $target eq 'analyze') {
924: my $value = &Apache::lonxml::get_param('value',$parstack,$safeeval);
925: if ($target eq 'tex' && $Apache::lonhomework::type eq 'exam') {
926: $text='\vskip 5mm $\triangleright$ '.$text;
927: }
928: if ($value ne 'unused') {
929: my $name = &Apache::lonxml::get_param('name',$parstack,$safeeval);
930: &Apache::lonxml::debug("Got a name of :$name:");
931: if ($name eq "") {
932: &Apache::lonxml::warning(&mt('Foils without names exist. This can cause problems to malfunction.'));
933: $name=$Apache::lonxml::curdepth;
934: }
935: &Apache::lonxml::debug("Using a name of :$name:");
936: if (defined($Apache::response::foilnames{$name})) {
937: &Apache::lonxml::error(&mt("Foil name [_1] appears more than once. Foil names need to be unique.",'<b><tt>'.$name.'</tt></b>'));
938: }
939: $Apache::response::foilnames{$name}++;
940: my $location =&Apache::lonxml::get_param('location',$parstack,$safeeval);
941: if ( $Apache::optionresponse::conceptgroup
942: && !&Apache::response::showallfoils() ) {
943: push @{ $Apache::response::conceptgroup{'names'} }, $name;
944: $Apache::response::conceptgroup{"$name.value"} = $value;
945: $Apache::response::conceptgroup{"$name.text"} = $text;
946: $Apache::response::conceptgroup{"$name.location"} = $location;
947: } else {
948: push @{ $Apache::response::foilgroup{'names'} }, $name;
949: $Apache::response::foilgroup{"$name.value"} = $value;
950: $Apache::response::foilgroup{"$name.text"} = $text;
951: $Apache::response::foilgroup{"$name.location"} = $location;
952: }
953: }
954: }
955: if ($target eq 'edit') {
956: $result.= &Apache::edit::tag_end($target,$token,'');
957: }
958: return $result;
959: }
960:
961: sub start_drawoptionlist {
962: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
963: if ($target !~ /^(?:meta|answer|modified|edit)$/) {
964: return $token->[4];
965: }
966: }
967:
968: sub end_drawoptionlist {
969: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
970: if ($target !~ /^(?:meta|answer|modified|edit)$/) {
971: return $token->[2];
972: }
973: }
974:
975: sub insert_foil {
976: return '
977: <foil name="" value="unused">
978: <startouttext />
979: <endouttext />
980: </foil>';
981: }
982:
983: sub insert_drawoptionlist {
984: return '<drawoptionlist />';
985: }
986:
987: sub getnumrows {
988: my ($numitems) = @_;
989: my $bubbles_per_row;
990: my $default_numbubbles = 10;
991: if (($env{'form.bubbles_per_row'} =~ /^\d+$/) &&
992: ($env{'form.bubbles_per_row'} > 0)) {
993: $bubbles_per_row = $env{'form.bubbles_per_row'};
994: } else {
995: $bubbles_per_row = $default_numbubbles;
996: }
997: my $numrows = int ($numitems/$bubbles_per_row);
998: if (($numitems % $bubbles_per_row) != 0) {
999: $numrows ++;
1000: }
1001: return ($numrows,$bubbles_per_row);
1002: }
1003:
1004: 1;
1005: __END__
1006:
1007: =head1 NAME
1008:
1009: Apache::optionresponse.pm;
1010:
1011: =head1 SYNOPSIS
1012:
1013: Handles tags associated with showing a list of
1014: options.
1015:
1016: This is part of the LearningOnline Network with CAPA project
1017: described at http://www.lon-capa.org.
1018:
1019: =head1 HANDLER SUBROUTINE
1020:
1021: start_optionresponse()
1022:
1023: =head1 OTHER SUBROUTINES
1024:
1025: =over
1026:
1027: =item end_optionresponse()
1028:
1029: =item start_foilgroup()
1030:
1031: =item end_foilgroup()
1032:
1033: =item getfoilcounts()
1034:
1035: =item displayanswers()
1036:
1037: =item check_for_invalid()
1038:
1039: =item displayfoils()
1040:
1041: =item optionlist_correction()
1042:
1043: =item webbubbles()
1044:
1045: =item bubbles()
1046:
1047: =item start_conceptgroup()
1048:
1049: =item end_conceptgroup()
1050:
1051: =item insert_conceptgroup()
1052:
1053: =item start_foil()
1054:
1055: =item end_foil()
1056:
1057: =item start_drawoptionlist()
1058:
1059: =item end_drawoptionlist()
1060:
1061: =item insert_foil()
1062:
1063: =item insert_drawoptionlist()
1064:
1065: =back
1066:
1067: =cut
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>