1: # The LearningOnline Network with CAPA
2: # rank style response
3: #
4: # $Id: rankresponse.pm,v 1.50 2007/02/22 01:25:31 albertel Exp $
5: # Copyright Michigan State University Board of Trustees
6: #
7: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
8: #
9: # LON-CAPA is free software; you can redistribute it and/or modify
10: # it under the terms of the GNU General Public License as published by
11: # the Free Software Foundation; either version 2 of the License, or
12: # (at your option) any later version.
13: #
14: # LON-CAPA is distributed in the hope that it will be useful,
15: # but WITHOUT ANY WARRANTY; without even the implied warranty of
16: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
17: # GNU General Public License for more details.
18: #
19: # You should have received a copy of the GNU General Public License
20: # along with LON-CAPA; if not, write to the Free Software
21: # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
22: #
23: # /home/httpd/html/adm/gpl.txt
24: #
25: # http://www.lon-capa.org/
26: #
27:
28: package Apache::rankresponse;
29: use strict;
30: use HTML::Entities();
31: use Apache::optionresponse();
32: use Apache::lonlocal;
33:
34: BEGIN {
35: &Apache::lonxml::register('Apache::rankresponse',('rankresponse'));
36: }
37:
38: sub start_rankresponse {
39: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
40: my $result;
41: #when in a rank response use these
42: &Apache::lonxml::register('Apache::rankresponse',
43: ('foilgroup','foil','conceptgroup'));
44: push (@Apache::lonxml::namespace,'rankresponse');
45: my $id = &Apache::response::start_response($parstack,$safeeval);
46: %Apache::hint::rank=();
47: undef(%Apache::response::foilnames);
48: if ($target eq 'meta') {
49: $result=&Apache::response::meta_package_write('rankresponse');
50: } elsif ($target eq 'edit' ) {
51: $result.=&Apache::edit::start_table($token).
52: '<tr><td>'.&Apache::lonxml::description($token)."</td><td>Delete:".
53: &Apache::edit::deletelist($target,$token)
54: ."</td><td> ".&Apache::edit::end_row()
55: .&Apache::edit::start_spanning_row();
56:
57: $result.=
58: &Apache::edit::text_arg('Max Number Of Shown Foils:','max',$token,'4').
59: &Apache::edit::select_arg('Randomize Foil Order','randomize',
60: ['yes','no'],$token).
61: &Apache::edit::end_row().&Apache::edit::start_spanning_row()."\n";
62: } elsif ($target eq 'modified') {
63: my $constructtag=&Apache::edit::get_new_args($token,$parstack,
64: $safeeval,'max',
65: 'randomize');
66: if ($constructtag) { $result = &Apache::edit::rebuild_tag($token); }
67: } elsif ($target eq 'analyze') {
68: my $part_id="$Apache::inputtags::part.$id";
69: push (@{ $Apache::lonhomework::analyze{"parts"} },$part_id);
70: }
71: return $result;
72: }
73:
74: sub end_rankresponse {
75: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
76: my $result;
77: if ($target eq 'edit') { $result=&Apache::edit::end_table(); }
78: &Apache::response::end_response;
79: pop @Apache::lonxml::namespace;
80: &Apache::lonxml::deregister('Apache::rankresponse',
81: ('foilgroup','foil','conceptgroup'));
82: undef(%Apache::response::foilnames);
83: return $result;
84: }
85:
86: %Apache::response::foilgroup=();
87: sub start_foilgroup {
88: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
89: my $result;
90: %Apache::response::foilgroup=();
91: $Apache::rankresponse::conceptgroup=0;
92: &Apache::response::pushrandomnumber();
93: return $result;
94: }
95:
96: sub end_foilgroup {
97: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
98: my $result;
99: if ($target eq 'grade' || $target eq 'web' || $target eq 'answer' ||
100: $target eq 'tex' || $target eq 'analyze') {
101: my $max = &Apache::lonxml::get_param('max',$parstack,$safeeval,'-2');
102: my $randomize = &Apache::lonxml::get_param('randomize',$parstack,
103: $safeeval,'-2');
104: my $tol = &Apache::lonxml::get_param('tol',$parstack,$safeeval,'-2');
105: if (!defined($tol)) { $tol=0; }
106: if ($target eq 'web' || $target eq 'tex') {
107: $result=&displayfoils($target,$max,$randomize,$tol);
108: $Apache::lonxml::post_evaluate=0;
109: } elsif ($target eq 'answer' ) {
110: $result=&displayanswers($max,$randomize,$tol);
111: } elsif ( $target eq 'grade') {
112: &grade_response($max,$randomize,$tol);
113: } elsif ( $target eq 'analyze') {
114: my @shown = &whichfoils($max,$randomize);
115: &Apache::response::analyze_store_foilgroup(\@shown,
116: ['text','value','location']);
117: my $part_id=
118: "$Apache::inputtags::part.$Apache::inputtags::response[-1]";
119: $Apache::lonhomework::analyze{"$part_id.tol"}=$tol;
120: }
121: &Apache::lonxml::increment_counter(&getfoilcounts($max));
122: } elsif ($target eq 'edit') {
123: $result=&Apache::edit::end_table();
124: }
125: &Apache::response::poprandomnumber();
126: return $result;
127: }
128:
129: sub get_correct_order {
130: my ($tol,@foils) =@_;
131: my @correctorder;
132: my @value_names;
133: foreach my $name (@foils) {
134: my @pair=($Apache::response::foilgroup{$name.'.value'},$name);
135: push(@value_names,\@pair);
136: }
137: @value_names =
138: sort {
139: if (abs($a->[0] - $b->[0]) > $tol) {return ($a->[0] <=> $b->[0]);}
140: return 0;
141: } @value_names;
142: my @value_names_tmp=@value_names;
143: my $firstpair=shift(@value_names_tmp);
144: my $order=1;
145: my %order;
146: my $count=1;
147: my $lastvalue=$firstpair->[0];
148: $order{$firstpair->[1]}=$order;
149: foreach my $pair (@value_names_tmp) {
150: $count++;
151: if (abs($pair->[0]-$lastvalue) > $tol ) {
152: $order=$count;
153: }
154: $order{$pair->[1]}=$order;
155: $lastvalue=$pair->[0];
156: }
157: foreach my $name (@foils) {
158: push(@correctorder,$order{$name});
159: }
160: &Apache::lonhomework::showhash('b' => \@value_names);
161: &Apache::lonhomework::showhash('b' => \@correctorder);
162: return @correctorder;
163: }
164:
165: sub displayanswers {
166: my ($max,$randomize,$tol,@opt)=@_;
167: if (!defined(@{ $Apache::response::foilgroup{'names'} })) { return; }
168: my @names = @{ $Apache::response::foilgroup{'names'} };
169: my @whichfoils = &whichfoils($max,$randomize);
170: my @correctorder=&get_correct_order($tol,@whichfoils);
171: my $result;
172: if ($Apache::lonhomework::type eq 'exam') {
173: my @alphabet = ('A'..'Z');
174: my $i=0;
175: foreach my $order (@correctorder) {
176: $result.=&Apache::response::answer_header('rankresponse',$i++);
177: $result.=&Apache::response::answer_part('rankresponse',
178: $alphabet[$order-1]);
179: $result.=&Apache::response::answer_part('rankresponse',$order);
180: $result.=&Apache::response::answer_footer('rankresponse');
181: }
182: } else {
183: $result=&Apache::response::answer_header('rankresponse');
184: foreach my $order (@correctorder) {
185: $result.=&Apache::response::answer_part('rankresponse',$order);
186: }
187: $result.=&Apache::response::answer_footer('rankresponse');
188: }
189: return $result;
190: }
191:
192: sub check_response_order {
193: my (%responsehash)=@_;
194: my @order=sort( {$a <=> $b} values(%responsehash));
195: my $lastvalue=0;
196: my $expected=1;
197: my $malformed=0;
198: foreach my $current (@order) {
199: &Apache::lonxml::debug("$lastvalue $expected $malformed");
200: if (!($current == $lastvalue || $current == $expected)) {
201: $malformed=1;
202: }
203: $expected++;
204: $lastvalue=$current;
205: }
206: return $malformed;
207: }
208:
209: sub grade_response {
210: my ($max,$randomize,$tol)=@_;
211: my (@whichfoils)=&whichfoils($max,$randomize);
212: if (!&Apache::response::submitted()) { return; }
213: my %responsehash;
214: my %grade;
215: my ($temp,$right,$wrong,$ignored)=(1,0,0,0);
216: my @correctorder=&get_correct_order($tol,@whichfoils);
217: foreach my $name (@whichfoils) {
218: my $response = &Apache::response::getresponse($temp,'A is 1');
219: my $value=shift(@correctorder);
220: if ( $response =~ /[^\s]/) {
221: $responsehash{$name}=$response;
222: &Apache::lonxml::debug("submitted a $response for $value<br />\n");
223: if ($value eq $response) {
224: $grade{$name}='1'; $right++;
225: } else {
226: $grade{$name}='0'; $wrong++;
227: }
228: } else {
229: $ignored++;
230: }
231: $temp++;
232: }
233: my $malformed=&check_response_order(%responsehash);
234: my $part=$Apache::inputtags::part;
235: my $id = $Apache::inputtags::response['-1'];
236: my $responsestr=&Apache::lonnet::hash2str(%responsehash);
237: my $gradestr =&Apache::lonnet::hash2str(%grade);
238: my %previous=&Apache::response::check_for_previous($responsestr,
239: $part,$id);
240: &Apache::lonxml::debug("Got $right right and $wrong wrong, and $ignored were ignored and was $malformed malformed");
241: my $ad;
242: if ($malformed) {
243: $ad='MISORDERED_RANK';
244: } elsif ($wrong==0 && $ignored==0) {
245: $ad='EXACT_ANS';
246: } elsif ($wrong==0 && $right==0) {
247: #nothing submitted
248: } else {
249: if ($ignored==0) {
250: $ad='INCORRECT';
251: } else {
252: $ad='MISSING_ANSWER';
253: }
254: }
255: if ($Apache::lonhomework::type eq 'survey' &&
256: ($ad eq 'INCORRECT' || $ad eq 'EXACT_ANS') ) {
257: $ad='SUBMITTED';
258: } else {
259: $Apache::lonhomework::results{"resource.$part.$id.submissiongrading"}=$gradestr;
260: }
261: $Apache::lonhomework::results{"resource.$part.$id.submission"}=
262: $responsestr;
263: $Apache::lonhomework::results{"resource.$part.$id.awarddetail"}=$ad;
264: &Apache::response::handle_previous(\%previous,$ad);
265: }
266:
267: sub displayfoils {
268: my ($target,$max,$randomize,$tol)=@_;
269: my $result;
270: my @alphabet=('A'..'Z');
271: my (@whichfoils)=&whichfoils($max,$randomize);
272: my $part=$Apache::inputtags::part;
273: my $solved=$Apache::lonhomework::history{"resource.$part.solved"};
274: my @whichopt=(1..($#whichfoils+1));
275: my @correctorder=&get_correct_order($tol,@whichfoils);
276: if ( &Apache::response::show_answer() && ($target ne 'tex')) {
277: foreach my $name (@whichfoils) {
278: my $text=$Apache::response::foilgroup{$name.'.text'};
279: my $value=shift(@correctorder);
280: if ($target eq 'web') {
281: $result.='<br /><b>'.$value.':</b> '.$text;
282: } else {
283: $result.=' \strut\\\\\strut '.$value.':'.$text;
284: }
285: }
286: } else {
287: my $i = 0;
288: my $temp=1;
289: my $id=$Apache::inputtags::response[-1];
290: my $part=$Apache::inputtags::part;
291: my $lastresponse=$Apache::lonhomework::history{"resource.$part.$id.submission"};
292: my %lastresponse=&Apache::lonnet::str2hash($lastresponse);
293: my @alp = splice @alphabet, 0, $#whichopt + 1;
294: my $internal_counter=$Apache::lonxml::counter;
295: foreach my $name (@whichfoils) {
296: my $lastopt=$lastresponse{$name};
297: my $optionlist='';
298: if ($target ne 'tex') {$optionlist="<option></option>\n";}
299: my $option;
300: foreach $option (@whichopt) {
301: if ($option eq $lastopt) {
302: if ($target ne 'tex') {$optionlist.="<option selected=\"on\">$option</option>\n";}
303: } else {
304: if ($target ne 'tex') {$optionlist.="<option>$option</option>\n";}
305: }
306: }
307: if ($target ne 'tex' && $Apache::lonhomework::type ne 'exam') {
308: $optionlist='<select name="HWVAL_'.
309: $Apache::inputtags::response[-1].':'.$temp.'">'.
310: $optionlist."</select>\n";
311: } else {
312: $optionlist=' '.$temp.' '.$optionlist.' ';
313: }
314: my $text=$Apache::response::foilgroup{$name.'.text'};
315: if ($target ne 'tex') {
316: if ($Apache::lonhomework::type ne 'exam') {
317: $result.='<br />'.$optionlist.$text."\n";
318: } else {
319: $result.='<br />'.$text."\n";
320: }
321: if ($Apache::lonhomework::type eq 'exam') {
322: my @values=(1..scalar(@whichopt));
323: $result.=&Apache::optionresponse::webbubbles(\@values,\@whichopt,$temp,$lastopt);
324: }
325: } else {
326: if ($Apache::lonhomework::type eq 'exam') {
327: $result.='\vskip 0 mm '.$text.' \vskip 0 mm '."\n";
328: $result.='\vskip -1 mm\noindent\begin{enumerate}\item[\textbf{'.$internal_counter.'}.]'.&Apache::optionresponse::bubbles(\@alp,\@whichopt,'rankresponse').'\end{enumerate} \vskip -8 mm \strut ';
329: $internal_counter++;
330: } else {
331: $result.=' \vskip 0mm \framebox[5 mm][s]{\tiny\strut} '.$text."\n";
332: }
333: }
334: $temp++;
335: }
336: }
337: if ($target ne 'tex') {$result.="<br />";} else {$result.=' \vskip 0 mm ';}
338: return $result;
339: }
340:
341: sub getfoilcounts {
342: my ($max)=@_;
343: # +1 since instructors will count from 1
344: my $count = $#{ $Apache::response::foilgroup{'names'} }+1;
345: if (&Apache::response::showallfoils()) { $max=$count; }
346: if ($count>$max) { $count=$max }
347: &Apache::lonxml::debug("Count is $count from $max");
348: return $count;
349: }
350:
351: sub whichfoils {
352: my ($max,$randomize)=@_;
353: return &Apache::response::whichorder($max,$randomize,
354: &Apache::response::showallfoils(),
355: \%Apache::response::foilgroup);
356: }
357:
358: sub start_conceptgroup {
359: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
360: $Apache::rankresponse::conceptgroup=1;
361: %Apache::response::conceptgroup=();
362: my $result;
363: if ($target eq 'edit') {
364: $result.=&Apache::edit::tag_start($target,$token,
365: "Concept Grouped Foils");
366: $result.=&Apache::edit::text_arg('Concept:','concept',$token,'50').
367: &Apache::edit::end_row().&Apache::edit::start_spanning_row();
368: }
369: if ($target eq 'modified') {
370: my $constructtag=&Apache::edit::get_new_args($token,$parstack,
371: $safeeval,'concept');
372: if ($constructtag) { $result = &Apache::edit::rebuild_tag($token); }
373: }
374: return $result;
375: }
376:
377: sub end_conceptgroup {
378: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
379: $Apache::rankresponse::conceptgroup=0;
380: my $result='';
381: if ($target eq 'web' || $target eq 'grade' || $target eq 'answer' ||
382: $target eq 'tex' || $target eq 'analyze') {
383: #if not there aren't any foils to display and thus no question
384: &Apache::response::pick_foil_for_concept($target,
385: ['value','text','location'],
386: \%Apache::hint::rank,
387: $parstack,$safeeval);
388: } elsif ($target eq 'edit') {
389: $result=&Apache::edit::end_table();
390: }
391: return $result;
392: }
393:
394: sub insert_conceptgroup {
395: my $result="\n\t\t<conceptgroup concept=\"\">".&insert_foil()."\n\t\t</conceptgroup>\n";
396: return $result;
397: }
398:
399: sub start_foil {
400: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
401: my $result='';
402: if ($target eq 'web' || $target eq 'tex' || $target eq 'analyze') {
403: &Apache::lonxml::startredirection;
404: if ($target eq 'analyze') {
405: &Apache::response::check_if_computed($token,$parstack,$safeeval,'value');
406: }
407: } elsif ($target eq 'edit') {
408: $result=&Apache::edit::tag_start($target,$token,"Foil");
409: my $level='-2';
410: if ($$tagstack[-2] eq 'conceptgroup') { $level = '-3'; }
411: $result.=&Apache::edit::text_arg('Name:','name',$token);
412: $result.= &Apache::edit::text_arg('Rank Value:','value',$token,'15');
413: my $randomize=&Apache::lonxml::get_param('randomize',$parstack,
414: $safeeval,'-3');
415: if ($randomize ne 'no') {
416: $result.=&Apache::edit::select_arg('Location:','location',
417: ['random','top','bottom'],$token);
418: }
419: $result .=&Apache::edit::end_row().&Apache::edit::start_spanning_row();
420: } elsif ($target eq 'modified') {
421: my $constructtag=&Apache::edit::get_new_args($token,$parstack,
422: $safeeval,'value',
423: 'name','location');
424: if ($constructtag) { $result = &Apache::edit::rebuild_tag($token); }
425: }
426: return $result;
427: }
428:
429: sub end_foil {
430: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
431: my $text ='';
432: my $result = '';
433: if ($target eq 'web' || $target eq 'tex' || $target eq 'analyze') {
434: $text=&Apache::lonxml::endredirection;
435: }
436: if ($target eq 'web' || $target eq 'grade' || $target eq 'answer' ||
437: $target eq 'tex' || $target eq 'analyze') {
438: my $value = &Apache::lonxml::get_param('value',$parstack,$safeeval);
439: if ($target eq 'tex' && $Apache::lonhomework::type eq 'exam') {
440: $text='\vskip 5mm $\triangleright$ '.$text;
441: }
442: if ($value ne 'unused') {
443: my $name = &Apache::lonxml::get_param('name',$parstack,$safeeval);
444: &Apache::lonxml::debug("Got a name of :$name:");
445: if ($name eq "") {
446: &Apache::lonxml::warning("Foils without names exist. This can cause problems to malfunction.");
447: $name=$Apache::lonxml::curdepth;
448: }
449: &Apache::lonxml::debug("Using a name of :$name:");
450: if (defined($Apache::response::foilnames{$name})) {
451: &Apache::lonxml::error(&mt("Foil name <b><tt>[_1]</tt></b> appears more than once. Foil names need to be unique.",$name));
452: }
453: $Apache::response::foilnames{$name}++;
454: my $location =&Apache::lonxml::get_param('location',$parstack,
455: $safeeval);
456: if ( $Apache::rankresponse::conceptgroup
457: && !&Apache::response::showallfoils() ) {
458: push @{ $Apache::response::conceptgroup{'names'} }, $name;
459: $Apache::response::conceptgroup{"$name.value"} = $value;
460: $Apache::response::conceptgroup{"$name.text"} = $text;
461: $Apache::response::conceptgroup{"$name.location"} = $location;
462: } else {
463: push @{ $Apache::response::foilgroup{'names'} }, $name;
464: $Apache::response::foilgroup{"$name.value"} = $value;
465: $Apache::response::foilgroup{"$name.text"} = $text;
466: $Apache::response::foilgroup{"$name.location"} = $location;
467: }
468: }
469: }
470: if ($target eq 'edit') {
471: $result.= &Apache::edit::tag_end($target,$token,'');
472: }
473: return $result;
474: }
475:
476: sub insert_foil {
477: return '
478: <foil name="" value="unused">
479: <startouttext />
480: <endouttext />
481: </foil>';
482: }
483: 1;
484: __END__
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>