Return to rankresponse.pm CVS log

Up to [LON-CAPA] / loncom / homework

- backport changes to make problemstatus work better

# The LearningOnline Network with CAPA
# rank style response
#
# $Id: rankresponse.pm,v 1.17.2.1 2003/09/23 01:52:57 albertel Exp $
# Copyright Michigan State University Board of Trustees
#
# This file is part of the LearningOnline Network with CAPA (LON-CAPA).
#
# LON-CAPA is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# LON-CAPA is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with LON-CAPA; if not, write to the Free Software
# Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
#
# /home/httpd/html/adm/gpl.txt
#
# http://www.lon-capa.org/
#
# 2/21 Guy

package Apache::rankresponse;
use strict;
use HTML::Entities();
use Apache::optionresponse;

BEGIN {
    &Apache::lonxml::register('Apache::rankresponse',('rankresponse'));
}

sub start_rankresponse {
    my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
    my $result;
    #when in a rank response use these
    &Apache::lonxml::register('Apache::rankresponse',
			      ('foilgroup','foil','conceptgroup'));
    push (@Apache::lonxml::namespace,'rankresponse');
    my $id = &Apache::response::start_response($parstack,$safeeval);
    %Apache::hint::rank=();
    if ($target eq 'meta') {
	$result=&Apache::response::meta_package_write('rankresponse');
    } elsif ($target eq 'edit' ) {
	$result.=&Apache::edit::start_table($token).
	    '<tr><td>'.&Apache::lonxml::description($token)."</td><td>Delete:".
	    &Apache::edit::deletelist($target,$token)
	    ."</td><td>&nbsp".&Apache::edit::end_row()
	    .&Apache::edit::start_spanning_row();
	
	$result.=
	    &Apache::edit::text_arg('Max Number Of Shown Foils:','max',$token,'4').
	    &Apache::edit::select_arg('Randomize Foil Order','randomize',
				      ['yes','no'],$token).
	    &Apache::edit::end_row().&Apache::edit::start_spanning_row()."\n";
    } elsif ($target eq 'modified') {
	my $constructtag=&Apache::edit::get_new_args($token,$parstack,
						     $safeeval,'max',
						     'randomize');
	if ($constructtag) { $result = &Apache::edit::rebuild_tag($token); }
    }
    return $result;
}

sub end_rankresponse {
    my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
    my $result;
    if ($target eq 'edit') { $result=&Apache::edit::end_table(); }
    &Apache::response::end_response;
    pop @Apache::lonxml::namespace;
    &Apache::lonxml::deregister('Apache::rankresponse',
				('foilgroup','foil','conceptgroup'));
    return $result;
}

%Apache::response::foilgroup=();
sub start_foilgroup {
    my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
    my $result;
    %Apache::response::foilgroup=();
    $Apache::rankresponse::conceptgroup=0;
    &Apache::response::setrandomnumber();
    return $result;
}

sub end_foilgroup {
    my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
    my $result;
    if ($target eq 'grade' || $target eq 'web' || $target eq 'answer' || $target eq 'tex') {
	my $max = &Apache::lonxml::get_param('max',$parstack,$safeeval,'-2');
	my $randomize = &Apache::lonxml::get_param('randomize',$parstack,
						   $safeeval,'-2');
	my $tol = &Apache::lonxml::get_param('tol',$parstack,$safeeval,'-2');
	if (!defined($tol)) { $tol=0; }
	if ($target eq 'web' || $target eq 'tex') {
	    $result=&displayfoils($target,$max,$randomize,$tol);
	} elsif ($target eq 'answer' ) {
	    $result=&displayanswers($max,$randomize,$tol);
	} elsif ( $target eq 'grade') {
	    &grade_response($max,$randomize,$tol);
	}
	&Apache::lonxml::increment_counter(&getfoilcounts($max));
    } elsif ($target eq 'edit') {
	$result=&Apache::edit::end_table();
    }
    return $result;
}

sub get_correct_order {
    my ($tol,@foils) =@_;
    my @correctorder;
    my @value_names;
    foreach my $name (@foils) {
	my @pair=($Apache::response::foilgroup{$name.'.value'},$name);
	push(@value_names,\@pair);
    }
    @value_names =
	sort {
	    if (abs($a->[0] - $b->[0]) > $tol) {return ($a->[0] <=> $b->[0]);}
	    return 0;
	} @value_names;
    my @value_names_tmp=@value_names;
    my $firstpair=shift(@value_names_tmp);
    my $order=1;
    my %order;
    my $count=1;
    my $lastvalue=$firstpair->[0];
    $order{$firstpair->[1]}=$order;
    foreach my $pair (@value_names_tmp) {
	$count++;
	if (abs($pair->[0]-$lastvalue) > $tol ) {
	    $order=$count;
	}
	$order{$pair->[1]}=$order;
	$lastvalue=$pair->[0];
    }
    foreach my $name (@foils) {
	push(@correctorder,$order{$name});
    }
    &Apache::lonhomework::showhash('b' => \@value_names);
    &Apache::lonhomework::showhash('b' => \@correctorder);
    return @correctorder;
}

sub displayanswers {
    my ($max,$randomize,$tol,@opt)=@_;
    if (!defined(@{ $Apache::response::foilgroup{'names'} })) { return; }
    my @names = @{ $Apache::response::foilgroup{'names'} };
    my @whichfoils = &whichfoils($max,$randomize);
    my $result=&Apache::response::answer_header('rankresponse');
    my @correctorder=&get_correct_order($tol,@whichfoils);
    foreach my $order (@correctorder) {
	$result.=&Apache::response::answer_part('rankresponse',$order);
    }
    $result.=&Apache::response::answer_footer('rankresponse');
    return $result;
}

sub check_response_order {
    my (%responsehash)=@_;
    my @order=sort(values(%responsehash));
    my $lastvalue=0;
    my $expected=1;
    my $malformed=0;
    foreach my $current (@order) {
	&Apache::lonxml::debug("$lastvalue $expected $malformed");
	if (!($current == $lastvalue || $current == $expected)) {
	    $malformed=1;
	}
	$expected++;
	$lastvalue=$current;
    }
    return $malformed;
}

sub grade_response {
    my ($max,$randomize,$tol)=@_;
    my (@whichfoils)=&whichfoils($max,$randomize);
    if (!defined($ENV{'form.submitted'})) { return; }
    my %responsehash;
    my %grade;
    my ($temp,$right,$wrong,$ignored)=(0,0,0,0);
    my @correctorder=&get_correct_order($tol,@whichfoils);
    foreach my $name (@whichfoils) {
	my $response = $ENV{'form.HWVAL_'.$Apache::inputtags::response['-1'].":$temp"};
	$responsehash{$name}=$response;
	my $value=shift(@correctorder);
	if ( $response =~ /[^\s]/) {
	    &Apache::lonxml::debug("submitted a $response for $value<br />\n");
	    if ($value eq $response) {
		$grade{$name}='1'; $right++;
	    } else {
		$grade{$name}='0'; $wrong++;
	    }
	} else {
	    $ignored++;
	}
	$temp++;
    }
    my $malformed=&check_response_order(%responsehash);
    my $part=$Apache::inputtags::part;
    my $id = $Apache::inputtags::response['-1'];
    my $responsestr=&Apache::lonnet::hash2str(%responsehash);
    my $gradestr   =&Apache::lonnet::hash2str(%grade);
    my %previous=&Apache::response::check_for_previous($responsestr,
						       $part,$id);
    &Apache::lonxml::debug("Got $right right and $wrong wrong, and $ignored were ignored and was $malformed malformed");
    my $ad;
    if ($malformed) {
	$ad='MISORDERED_RANK';
    } elsif ($wrong==0 && $ignored==0) {
	$ad='EXACT_ANS';
    } elsif ($wrong==0 && $right==0) {
	#nothing submitted
    } else {
	if ($ignored==0) {
	    $ad='INCORRECT';
	} else {
	    $ad='MISSING_ANSWER';
	}
    }
    $Apache::lonhomework::results{"resource.$part.$id.submission"}=
	$responsestr;
    $Apache::lonhomework::results{"resource.$part.$id.submissiongrading"}=$gradestr;
    $Apache::lonhomework::results{"resource.$part.$id.awarddetail"}=$ad;
    &Apache::response::handle_previous(\%previous,$ad);
}

sub displayfoils {
    my ($target,$max,$randomize,$tol)=@_;
    my $result;
    my @alphabet=('A'..'Z');
    my (@whichfoils)=&whichfoils($max,$randomize);
    my $part=$Apache::inputtags::part;
    my $solved=$Apache::lonhomework::history{"resource.$part.solved"};
    my $status=$Apache::inputtags::status[-1];
    my @whichopt=(1..($#whichfoils+1));
    my @correctorder=&get_correct_order($tol,@whichfoils);
    if ( &Apache::response::show_answer() ) {
	foreach my $name (@whichfoils) {
	    my $text=$Apache::response::foilgroup{$name.'.text'};
	    my $value=shift(@correctorder);
	    $result.='<br />'.$value.':'.$text;
	}
    } else {
	my $i = 0;
	my $temp=0;
	my $id=$Apache::inputtags::response[-1];
	my $part=$Apache::inputtags::part;
	my $lastresponse=$Apache::lonhomework::history{"resource.$part.$id.submission"};
	my %lastresponse=&Apache::lonnet::str2hash($lastresponse); 
	my @alp = splice @alphabet, 0, $#whichopt + 1;
	my $internal_counter=$Apache::lonxml::counter;
	foreach my $name (@whichfoils) {
	    my $lastopt=$lastresponse{$name};
	    my $optionlist='';
	    if ($target ne 'tex') {$optionlist="<option></option>\n";}
	    my $option;
	    foreach $option (@whichopt) {
		if ($option eq $lastopt) {
		    if ($target ne 'tex') {$optionlist.="<option selected=\"on\">$option</option>\n";}
		} else {
		    if ($target ne 'tex') {$optionlist.="<option>$option</option>\n";}
		}
	    }
	    if ($target ne 'tex' && $Apache::lonhomework::type ne 'exam') {
		$optionlist='<select name="HWVAL_'.
		    $Apache::inputtags::response[-1].':'.$temp.'">'.
		        $optionlist."</select>\n";
	    } else {
		$optionlist=' '.$temp.' '.$optionlist.' ';
	    }
	    my $text=$Apache::response::foilgroup{$name.'.text'};
	    if ($target ne 'tex') {
		if ($Apache::lonhomework::type ne 'exam') {
		    $result.='<br />'.$optionlist.$text."\n";
		} else {
		    $result.='<br />'.$text."\n";
		}
		if ($Apache::lonhomework::type eq 'exam') {
		    $result.=&Apache::optionresponse::webbubbles(\@alp,\@whichopt,$temp);
		}
	    } else {
		if ($Apache::lonhomework::type eq 'exam') {
		    $result.='\vskip 0 mm   '.$text.' \vskip -3 mm '."\n";
		    $result.='\vskip -5 mm\begin{enumerate}\item[\textbf{'.$internal_counter.'}.]\parbox{\textwidth - 5 mm}{'.&Apache::optionresponse::bubbles(\@alp,\@whichopt).'}\end{enumerate} \vskip -5 mm \strut ';
		    $internal_counter++;
		} else {
		    $result.=' \vskip 0mm \framebox[5 mm][s]{\tiny\strut} '.$text."\n";
		}
	    }
	    $temp++;
	}
    }
    if ($target ne 'tex') {$result.="<br />";} else {$result.=' \vskip 0 mm ';}
    return $result;
}

sub getfoilcounts {
    my ($max)=@_;
    # +1 since instructors will count from 1
    my $count = $#{ $Apache::response::foilgroup{'names'} }+1;
    if (&Apache::response::showallfoils()) { $max=$count; }
    if ($count>$max) { $count=$max } 
    &Apache::lonxml::debug("Count is $count from $max");
    return $count;
}

sub whichfoils {
    my ($max,$randomize)=@_;
    return &Apache::response::whichorder($max,$randomize,
					 &Apache::response::showallfoils(),
					 \%Apache::response::foilgroup);
}

sub start_conceptgroup {
    my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
    $Apache::rankresponse::conceptgroup=1;
    %Apache::response::conceptgroup=();
    my $result;
    if ($target eq 'edit') {
	$result.=&Apache::edit::tag_start($target,$token,
					  "Concept Grouped Foils");
	$result.=&Apache::edit::text_arg('Concept:','concept',$token,'50').
	    &Apache::edit::end_row().&Apache::edit::start_spanning_row();
    }
    if ($target eq 'modified') {
	my $constructtag=&Apache::edit::get_new_args($token,$parstack,
						     $safeeval,'concept');
	if ($constructtag) { $result = &Apache::edit::rebuild_tag($token); }
    }
    return $result;
}

sub end_conceptgroup {
    my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
    $Apache::rankresponse::conceptgroup=0;
    my $result='';
    if ($target eq 'web' || $target eq 'grade' || $target eq 'answer' || $target eq 'tex') {
	#if not there aren't any foils to display and thus no question
	if (defined(@{ $Apache::response::conceptgroup{'names'} })) {
	    my @names = @{ $Apache::response::conceptgroup{'names'} };
	    my $pick=int(&Math::Random::random_uniform() * ($#names+1));
	    my $name=$names[$pick];
	    push @{ $Apache::response::foilgroup{'names'} }, $name;
	    $Apache::response::foilgroup{"$name.value"} =
		$Apache::response::conceptgroup{"$name.value"};
	    $Apache::response::foilgroup{"$name.text"} =
		$Apache::response::conceptgroup{"$name.text"};
	    $Apache::response::foilgroup{"$name.location"} =
		$Apache::response::conceptgroup{"$name.location"};
	    my $concept = &Apache::lonxml::get_param('concept',$parstack,
						     $safeeval);
	    $Apache::response::foilgroup{"$name.concept"} = $concept;
	    &Apache::lonxml::debug("Selecting $name in $concept");
	    if ($target eq 'web' || $target eq 'tex') {
		my $part_id="$Apache::inputtags::part.$Apache::inputtags::response[-1]";
		push(@{ $Apache::hint::rank{"$part_id.concepts"} },
		     $concept);
		$Apache::hint::rank{"$part_id.concept.$concept"}=
		    $Apache::response::conceptgroup{'names'};
	    }
	}
    } elsif ($target eq 'edit') {
	$result=&Apache::edit::end_table();
    }
    return $result;
}

sub insert_conceptgroup {
    my $result="\n\t\t<conceptgroup concept=\"\">".&insert_foil()."\n\t\t</conceptgroup>\n";
    return $result;
}

sub start_foil {
    my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
    my $result='';
    if ($target eq 'web' || $target eq 'tex') {
	&Apache::lonxml::startredirection;
    } elsif ($target eq 'edit') {
	$result=&Apache::edit::tag_start($target,$token,"Foil");
	my $level='-2';
	if ($$tagstack[-2] eq 'conceptgroup') { $level = '-3'; }
	$result.=&Apache::edit::text_arg('Name:','name',$token);
	$result.= &Apache::edit::text_arg('Rank Value:','value',$token,'15');
	my $randomize=&Apache::lonxml::get_param('randomize',$parstack,
						 $safeeval,'-3');
	if ($randomize ne 'no') {
	    $result.=&Apache::edit::select_arg('Location:','location',
					     ['random','top','bottom'],$token);
	}
	$result .=&Apache::edit::end_row().&Apache::edit::start_spanning_row();
    } elsif ($target eq 'modified') {
	my $constructtag=&Apache::edit::get_new_args($token,$parstack,
						     $safeeval,'value',
						     'name','location');
	if ($constructtag) { $result = &Apache::edit::rebuild_tag($token); }
    }
    return $result;
}

sub end_foil {
    my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
    my $text ='';
    my $result = '';
    if ($target eq 'web' || $target eq 'tex') {
	$text=&Apache::lonxml::endredirection;
    }
    if ($target eq 'web' || $target eq 'grade' || $target eq 'answer' || $target eq 'tex') {
	my $value = &Apache::lonxml::get_param('value',$parstack,$safeeval);
	if ($value ne 'unused') {
	    my $name = &Apache::lonxml::get_param('name',$parstack,$safeeval);
	    my $location =&Apache::lonxml::get_param('location',$parstack,$safeeval);
	    &Apache::lonxml::debug("Got a name of :$name:");
	    if (!$name) { $name=$Apache::lonxml::curdepth; }
	    &Apache::lonxml::debug("Using a name of :$name:");
	    if ( $Apache::rankresponse::conceptgroup
		 && !&Apache::response::showallfoils() ) {
		push @{ $Apache::response::conceptgroup{'names'} }, $name;
		$Apache::response::conceptgroup{"$name.value"} = $value;
		if ($target eq 'tex' and $Apache::lonhomework::type eq 'exam') {
		    $Apache::response::conceptgroup{"$name.text"} = ' $\triangleright$ '.$text;
		} else {
		    $Apache::response::conceptgroup{"$name.text"} = $text;
		}
		$Apache::response::conceptgroup{"$name.location"} = $location;
	    } else {
		push @{ $Apache::response::foilgroup{'names'} }, $name;
		$Apache::response::foilgroup{"$name.value"} = $value;
		if ($target eq 'tex' and $Apache::lonhomework::type eq 'exam') {
		    $Apache::response::foilgroup{"$name.text"} = '\vskip 5 mm $\triangleright$ '.$text;
		} else {
		    if ($target eq 'tex' and $Apache::lonhomework::type eq 'exam') {
			$Apache::response::foilgroup{"$name.text"} = ' $\triangleright$ '.$text;
		    } else {
			$Apache::response::foilgroup{"$name.text"} = $text;
		    } 
		}
		$Apache::response::foilgroup{"$name.location"} = $location;
	    }
	}
    }
    if ($target eq 'edit') {
	$result.= &Apache::edit::tag_end($target,$token,'');
    }
    return $result;
}

sub insert_foil {
    return '
<foil name="" value="unused">
<startouttext />
<endouttext />
</foil>';
}
1;
__END__