1: # The LearningOnline Network
2: # "About Me" Personal Information
3: #
4: # $Id: lonaboutme.pm,v 1.87 2008/12/17 00:44:53 ehlerst Exp $
5: #
6: # Copyright Michigan State University Board of Trustees
7: #
8: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
9: #
10: # LON-CAPA is free software; you can redistribute it and/or modify
11: # it under the terms of the GNU General Public License as published by
12: # the Free Software Foundation; either version 2 of the License, or
13: # (at your option) any later version.
14: #
15: # LON-CAPA is distributed in the hope that it will be useful,
16: # but WITHOUT ANY WARRANTY; without even the implied warranty of
17: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18: # GNU General Public License for more details.
19: #
20: # You should have received a copy of the GNU General Public License
21: # along with LON-CAPA; if not, write to the Free Software
22: # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
23: #
24: # /home/httpd/html/adm/gpl.txt
25: #
26: # http://www.lon-capa.org/
27: #
28:
29: =pod
30:
31: =head1 NAME
32:
33: pache::lonaboutme
34:
35: =head1 SYNOPSIS
36:
37: (empty)
38:
39: This is part of the LearningOnline Network with CAPA project
40: described at http://www.lon-capa.org.
41:
42: =head1 OVERVIEW
43:
44: (empty)
45:
46:
47: =head1 SUBROUTINES
48:
49: =over
50:
51: =item handler()
52:
53: =item in_course()
54:
55: =item aboutme_info()
56:
57: =item print_portfiles_link()
58:
59: =item build_query_string()
60:
61: =item display_portfolio_header()
62:
63: =item display_portfolio_files()
64:
65: =item portfolio_files()
66:
67: =item build_hierarchy()
68:
69: =item parse_directory()
70:
71: =back
72:
73: =cut
74:
75:
76: package Apache::lonaboutme;
77:
78: use strict;
79: use Apache::Constants qw(:common);
80: use Apache::loncommon;
81: use Apache::lonnet;
82: use Apache::lontexconvert;
83: use Apache::lonfeedback;
84: use Apache::lonrss();
85: use Apache::lonlocal;
86: use Apache::lonmsgdisplay();
87: use Apache::lontemplate;
88: use HTML::Entities();
89:
90: sub handler {
91: my $r = shift;
92: &Apache::loncommon::content_type($r,'text/html');
93: $r->send_http_header;
94: return OK if $r->header_only;
95: my $target=$env{'form.grade_target'};
96: # ------------------------------------------------------------ Print the screen
97: if ($target eq 'tex') {
98: $r->print(&Apache::lonprintout::print_latex_header($env{'form.latex_type'}));
99: }
100: my (undef,undef,$cdom,$cnum,undef,$action)=split(/\//,$r->uri);
101: my $is_course;
102: # Is this even a user?
103: if (&Apache::lonnet::homeserver($cnum,$cdom) eq 'no_host') {
104: &Apache::loncommon::simple_error_page($r,'No info',
105: 'No user information available');
106: return OK;
107: } else {
108: $is_course = &Apache::lonnet::is_course($cdom,$cnum);
109: }
110:
111: my $candisplay = 1;
112: if (!$is_course) {
113: if ($action ne 'portfolio') {
114: $candisplay = &Apache::lonnet::usertools_access($cnum,$cdom,'aboutme');
115: if ((!$candisplay) && ($env{'request.course.id'})) {
116: $candisplay = &aboutme_access($cnum,$cdom);
117: }
118: if (!$candisplay) {
119: if ($target eq 'tex') {
120: $r->print('\noindent{\large\textbf{'.&mt('No user home page available').'}}\\\\\\\\');
121: } else {
122: $r->print(&Apache::loncommon::start_page("Personal Information"));
123: $r->print('<h2>'.&mt('No user home page available') .'</h2>'.
124: &mt('This is a result of one of the following:').'<ul>'.
125: '<li>'.&mt('The administrator of this domain has disabled home page functionality for this specific user.').'</li>'.
126: '<li>'.&mt('The domain has been configured to disable, by default, home page functionality for all users in the domain.').'</li>'.
127: '</ul>');
128: $r->print(&Apache::loncommon::end_page());
129: }
130: return OK;
131: }
132: }
133: }
134:
135: # --------------------------------------------------------- The syllabus fields
136: my %syllabusfields=&Apache::lonlocal::texthash(
137: 'aaa_contactinfo' => 'Contact Information',
138: 'bbb_aboutme' => 'About Me',
139: 'ccc_webreferences' => 'Web References');
140:
141: # ------------------------------------------------------------ Get Query String
142: &Apache::loncommon::get_unprocessed_cgi($ENV{'QUERY_STRING'},
143: ['forceedit','forcestudent',
144: 'register','popup']);
145:
146: # ----------------------------------------------- Available Portfolio file display
147: if (($target ne 'tex') && ($action eq 'portfolio')) {
148: &display_portfolio_header($r,$is_course);
149: if ((!$is_course) && (!&Apache::lonnet::usertools_access($cnum,$cdom,'portfolio'))) {
150: $r->print('<h2>'.&mt('No user portfolio available') .'</h2>'.
151: &mt('This is a result of one of the following:').'<ul>'.
152: '<li>'.&mt('The administrator of this domain has disabled portfolio functionality for this specific user.').'</li>'.
153: '<li>'.&mt('The domain has been configured to disable, by default, portfolio functionality for all users in the domain.').'</li>'.
154: '</ul>');
155: } else {
156: my ($blocked,$blocktext) =
157: &Apache::loncommon::blocking_status('port',$cnum,$cdom);
158: if (!$blocked) {
159: &display_portfolio_files($r,$is_course);
160: } else {
161: $r->print($blocktext);
162: }
163: }
164: $r->print(&Apache::loncommon::end_page());
165: return OK;
166: }
167:
168: if ($is_course) {
169: if ($target ne 'tex') {
170: my $brcrum = [{href=>"/adm/navmaps",text=>"Navigate Course Contents"},
171: {href=>"/adm/aboutme",text=>"Course Information"}];
172: my $start_page =
173: &Apache::loncommon::start_page(
174: "Course Information",
175: undef,
176: {'function' => $env{'forcestudent'},
177: 'domain' => $cdom,
178: 'force_register' => $env{'forceregister'},
179: 'bread_crumbs' => $brcrum});
180: $r->print($start_page);
181: $r->print('<h2>'.&mt('Group files').'</h2>');
182: &print_portfiles_link($r,$is_course);
183: $r->print(&Apache::loncommon::end_page());
184: }
185: return OK;
186: }
187:
188: # --------------------------------------------------------------- Force Student
189: my $forcestudent='';
190: if ($env{'form.forcestudent'}) { $forcestudent='student'; };
191:
192: my $forceregister = '';
193: if ($forcestudent eq '') {
194: $forceregister = $env{'form.register'};
195: }
196:
197: # --------------------------------------- There is such a user, get environment
198: my %courseenv=&Apache::lonnet::dump('environment',$cdom,$cnum);
199: if ($target ne 'tex') {
200: my $rss_link = &Apache::lonrss::rss_link($cnum,$cdom);
201: my $args = {'function' => $forcestudent,
202: 'domain' => $cdom,
203: 'force_register' => $forceregister};
204: if ($env{'form.popup'}) {
205: $args->{'no_nav_bar'} = 1;
206: }
207: $args->{'bread_crumbs'} = [{href=>"/adm/fhwfdev/$cnum/aboutme",text=>"Personal Information"}];
208: my $start_page =
209: &Apache::loncommon::start_page("Personal Information",$rss_link,$args);
210: $r->print($start_page);
211: $r->print('<h2>'.&Apache::loncommon::plainname($cnum,$cdom).'</h2>');
212: } else {
213: $r->print('\noindent{\large\textbf{'.&Apache::loncommon::plainname($cnum,$cdom).'}}\\\\\\\\');
214: }
215: if ($courseenv{'nickname'}) {
216: $r->print(
217: '<h2>"'.$courseenv{'nickname'}.
218: '"</h2>');
219: }
220: if ($target ne 'tex') {
221: $r->print('<h3>'.&Apache::lonnet::domain($cdom,'description').'</h3>');#OLD SendMessage POS
222: } else {
223: $r->print('\textbf{'.&Apache::lonnet::domain($cdom,'description').'}\\\\');
224: }
225: my %syllabus=&Apache::lonnet::dump('aboutme',$cdom,$cnum);
226: my $allowed=0;
227:
228: # does this user have privileges to post, etc?
229:
230: my $privleged=$allowed=(($env{'user.name'} eq $cnum) &&
231: ($env{'user.domain'} eq $cdom));
232: if ($forcestudent or $target eq 'tex') { $allowed=0; }
233: my $query_string;
234: if ($allowed) {
235: $query_string = &build_query_string({'forcestudent' => '1','popup' => $env{'form.popup'}});
236: $r->print('<p><b>'.&mt('Privacy Note').':</b> '.
237: &mt('The information you submit can be viewed by anybody who is logged into LON-CAPA. Do not provide information that you are not ready to share publicly.').
238: '</p><p><a href="'.$r->uri.$query_string.'">'.&mt('Show Public View').'</a>'.
239: &Apache::loncommon::help_open_topic('Uploaded_Templates_PublicView').'</p>'.
240: &Apache::loncommon::help_open_topic('Uploaded_Templates_TextBoxes',&mt('Help with filling in text boxes')).'</p>');
241: } elsif ($privleged && $target ne 'tex') {
242: $query_string = &build_query_string({'forceedit' => '1','popup' => $env{'form.popup'}});
243: $r->print('<p><a href="'.$r->uri.$query_string.'">'.
244: &mt('Edit').'</a></p>');
245: }
246: if (($env{'form.uploaddoc.filename'}) &&
247: ($env{'form.storeupl'}) && ($allowed)) {
248: if ($env{'form.uploaddoc.filename'}=~/\.(gif|jpg|png|jpeg)$/i) {
249: if ($syllabus{'uploaded.photourl'}) {
250: &Apache::lonnet::removeuploadedurl($syllabus{'uploaded.photourl'});
251: }
252: $syllabus{'uploaded.photourl'}=
253: &Apache::lonnet::userphotoupload('uploaddoc','aboutme');
254: }
255: $syllabus{'uploaded.lastmodified'}=time;
256: &Apache::lonnet::put('aboutme',\%syllabus,$cdom,$cnum);
257: }
258: if ($allowed && $env{'form.delupl'}) {
259: if ($syllabus{'uploaded.photourl'}) {
260: &Apache::lonnet::removeuploadedurl($syllabus{'uploaded.photourl'});
261: delete($syllabus{'uploaded.photourl'});
262: &Apache::lonnet::del('aboutme',['uploaded.photourl'],$cdom,$cnum);
263: }
264: }
265: if (($allowed) && ($env{'form.storesyl'})) {
266: foreach my $syl_field (keys(%syllabusfields)) {
267: my $field=$env{'form.'.$syl_field};
268: $field=~s/\s+$//s;
269: $field=&Apache::lonfeedback::clear_out_html($field,
270: $env{'user.adv'});
271: $syllabus{$syl_field}=$field;
272: }
273: $syllabus{'uploaded.lastmodified'}=time;
274: &Apache::lonnet::put('aboutme',\%syllabus,$cdom,$cnum);
275: }
276:
277: my $lastmod;
278: my $image;
279: # ---------------------------------------------------------------- Get syllabus
280: if (($syllabus{'uploaded.lastmodified'}) || ($allowed)) {
281: $lastmod=$syllabus{'uploaded.lastmodified'};
282: $lastmod=($lastmod?&Apache::lonlocal::locallocaltime($lastmod):&mt('never'));
283: $r->print('<br />'.&mt('Last updated').': '.$lastmod);
284: if ($syllabus{'uploaded.photourl'}) {
285: &Apache::lonnet::allowuploaded('/adm/aboutme',
286: $syllabus{'uploaded.photourl'});
287: $image=qq{<img name="userPhoto" src="$syllabus{'uploaded.photourl'}" />};
288:
289: if ($target eq 'tex') {
290: $image=&Apache::lonxml::xmlparse($r,'tex',$image);
291: }
292: # $r->print($image); #Print old Image
293: }
294: if ($allowed) {
295: $r->print(
296: '<form method="post" enctype="multipart/form-data">'.
297: '<h3>'.&mt('Upload a Photo').'</h3>'.
298: '<input type="file" name="uploaddoc" size="50" />'.
299: '<input type="submit" name="storeupl" value="'.&mt('Upload').'" />'.
300: '<input type="hidden" name="popup" value="'.$env{'form.popup'}.'" />'.
301: '</form><form method="post"><input type="submit" name="delupl" value="'.&mt('Delete Photo').'" /> </form>
302: ');
303:
304: }
305:
306: if($allowed) {
307: $r->print('<form method="post">');
308: }
309:
310: &Apache::lontemplate::start_columnSection($r);
311: &Apache::lontemplate::print_content_template($r,$allowed,$target,\%syllabusfields,\%syllabus);
312: if($target ne 'tex')
313: {
314: &Apache::lontemplate::start_ContentBox($r);
315: $r->print($image);
316: &Apache::lontemplate::send_message($r,$cnum,$cdom);
317: &Apache::lontemplate::end_ContentBox($r);
318: &Apache::lontemplate::end_columnSection($r);
319:
320: &Apache::lontemplate::start_columnSection($r);
321: &Apache::lontemplate::start_ContentBox($r);
322: &print_portfiles_link($r,$is_course);
323: if(&Apache::lonrss::advertisefeeds($cnum,$cdom) ne ''){
324: $r->print('<div class="ContentBoxSpecial">');
325: $r->print('<h4 class="hcell">'.'RSS Feeds and Blogs'.'</h4>');
326: $r->print(&Apache::lonrss::advertisefeeds($cnum,$cdom));
327: $r->print('</div>');
328: }
329: &Apache::lontemplate::end_ContentBox($r);
330: &Apache::lontemplate::end_columnSection($r);
331: if($allowed){
332: $r->print('<p><a href="'.$r->uri.$query_string.'">'.&mt('Show Public View').'</a>'.
333: &Apache::loncommon::help_open_topic('Uploaded_Templates_PublicView').'</p>');
334: }
335: }
336: if ($allowed) {
337: if ($env{'form.popup'}) {
338: $r->print('<input type="hidden" name="popup" value="'.
339: $env{'form.popup'}.'" />');
340: }
341: $r->print('</form>');
342: }
343: if ($target ne 'tex') {$r->print('<br />');} else {$r->print('\\\\');}
344: } else {
345: $r->print('<p>'.&mt('No personal information provided').'.</p>');
346: }
347:
348: if ($target ne 'tex') {
349: # &print_portfiles_link($r,$is_course); #old Print files
350:
351: }
352:
353: if ($env{'request.course.id'}
354: && &Apache::lonnet::allowed('srm',$env{'request.course.id'})
355: && &in_course($cdom,$cnum)) {
356: if ($target ne 'tex') {
357: $r->print('<a name="coursecomment" />');
358: $r->print('<hr /><h3>'.
359: &mt('User Notes, Records of Face-To-Face Discussions, and Critical Messages in Course').'</h3>'.
360: &mt('Shared by course faculty and staff').
361: &Apache::loncommon::help_open_topic("Course_Face_To_Face_Records,Course_Critical_Message").
362: '<br />');
363: &Apache::lonmsgdisplay::disfacetoface($r,$cnum,$cdom);
364: $r->print('<hr />');
365: if (&Apache::lonnet::allowed('vsa',
366: $env{'request.course.id'}) ||
367: &Apache::lonnet::allowed('vsa',
368: $env{'request.course.id'}.'/'.
369: $env{'request.course.sec'})) {
370: $r->print(&Apache::loncommon::track_student_link
371: ('View recent activity by this student',
372: $cnum,$cdom).(' 'x2));
373: }
374: $r->print(&Apache::loncommon::noteswrapper('Add Records',$cnum,$cdom));
375: } else {
376: $r->print('\\\\\textbf{'.&mt('User Notes, Records of Face-To-Face Discussions, and Critical Messages in Course').'}\\\\'.&mt('Shared by course faculty and staff').'\\\\\\\\');
377: &Apache::lonmsgdisplay::disfacetoface($r,$cnum,$cdom);
378: }
379: }
380: if ($target ne 'tex') {
381: if ($env{'form.popup'}) {
382: $r->print('<p><a href="javascript:window.close()">'.&mt('Close window').'</a>');
383: }
384: $r->print(&Apache::loncommon::end_page());
385: } else {
386: $r->print('\end{document}');
387: }
388:
389:
390:
391: return OK;
392: }
393:
394: sub in_course {
395: my ($udom,$uname,$cdom,$cnum,$type) = @_;
396: $type ||= 'any';
397: if (!defined($cdom) || !defined($cnum)) {
398: my $cid = $env{'request.course.id'};
399: $cdom = $env{'course.'.$cid.'.domain'};
400: $cnum = $env{'course.'.$cid.'.num'};
401: }
402: my %roles = &Apache::lonnet::dump('roles',$udom,$uname);
403: my @course_roles = grep(m{^/\Q$cdom\E/\Q$cnum\E[/_]}, keys(%roles));
404: return 0 if (!@course_roles);
405: return 1 if ($type eq 'any');
406: my $now = time();
407: foreach my $role (@course_roles) {
408: my (undef,$role_end,$role_start)=split(/\_/,$roles{$role});
409: my $status = 'active';
410: if ($role_start > 0 && $now < $role_start) {
411: $status = 'future';
412: }
413: if ($role_end > 0 && $now > $role_end) {
414: $status = 'previous';
415: }
416: return 1 if ($status eq $type);
417: }
418: return 0;
419: }
420:
421: sub aboutme_info {
422: my ($r,$is_course) = @_;
423: my (undef,undef,$cdom,$cnum)=split(/\//,$r->uri);
424: my $name;
425: if (!$is_course) {
426: $name = &Apache::loncommon::plainname($cnum,$cdom);
427: }
428: return ($cdom,$cnum,$name);
429: }
430:
431: sub print_portfiles_link {
432: my ($r,$is_course) = @_;
433: my ($cdom,$cnum,$name) = &aboutme_info($r,$is_course);
434: my $filecounts = &portfolio_files($r,'showlink',undef,$is_course,
435: $cdom,$cnum,$name);
436: my $query_string = &build_query_string();
437: my $output;
438: my %lt = &Apache::lonlocal::texthash(
439: vpfi => 'Viewable portfolio files',
440: vgpf => 'Viewable group portfolio files',
441: difl => 'Display file listing',
442: );
443: if ($filecounts->{'both'} > 0) {
444: $output = '<div class="ContentBoxSpecial"><h4 class="hcell">';
445: $output .= ($is_course?$lt{'vgpf'}:$lt{'vpfi'}).'</h4>';
446:
447: #$output = '<h4>'.($is_course?$lt{'vgpf'}:$lt{'vpfi'}).'</h4>';
448: $output .= '<a href="/adm/'.$cdom.'/'.$cnum.'/aboutme/portfolio'.
449: $query_string.'">'.$lt{'difl'}.
450: '</a><br /><br />';
451: if ($filecounts->{'both'} == 1) {
452: if ($is_course) {
453: $output .= &mt('One group portfolio file is available.').'<ul>';
454: } else {
455: $output .= &mt('One portfolio file owned by [_1] is available.',$name).'<ul>';
456: }
457: } else {
458: if ($is_course) {
459: $output .= &mt('A total of [_1] group portfolio files are available.',$filecounts->{'both'}).'<ul>';
460: } else {
461: $output .= &mt('A total of [_1] portfolio files owned by [_2] are available.',$filecounts->{'both'},$name).'<ul>';
462: }
463: }
464: if ($filecounts->{'withoutpass'}) {
465: $output .= '<li>'.&mt('[quant,_1,file is,files are] publicly accessible.',$filecounts->{'withoutpass'}).'</li>';
466: }
467: if ($filecounts->{'withpass'}) {
468: $output .= '<li>'.&mt('[quant,_1,file requires,files require] a passphrase for access.',$filecounts->{'withpass'}).'</li>';
469: }
470: $output .= '</ul>';
471: $output .='</p>';
472: $output .='</div>';
473: }
474: $r->print($output);
475: return;
476: }
477:
478: sub build_query_string {
479: my ($new_items) = @_;
480: my $query_string;
481: my @formelements = ('register');
482: my $new = 0;
483: if (ref($new_items) eq 'HASH') {
484: $new = 1;
485: if (!defined($new_items->{'forceedit'}) &&
486: !defined($new_items->{'forcestudent'})) {
487: push(@formelements,('forceedit','forcestudent'));
488: }
489: } else {
490: push(@formelements,('forceedit','forcestudent'));
491: }
492: foreach my $element (@formelements) {
493: if (exists($env{'form.'.$element})) {
494: if ((!$new) || (!defined($new_items->{$element}))) {
495: $query_string .= '&'.$element.'='.$env{'form.'.$element};
496: }
497: }
498: }
499: if ($new) {
500: foreach my $key (keys(%{$new_items})) {
501: $query_string .= '&'.$key.'='.$new_items->{$key};
502: }
503: }
504: $query_string =~ s/^\&/\?/;
505: return $query_string;
506: }
507:
508: sub display_portfolio_header {
509: my ($r,$is_course) = @_;
510: my ($cdom,$cnum,$name) = &aboutme_info($r,$is_course);
511: my $query_string = &build_query_string();
512: &Apache::lonhtmlcommon::clear_breadcrumbs();
513: my $forcestudent='';
514: if ($env{'form.forcestudent'}) { $forcestudent='student'; };
515:
516: my $output;
517: if ($is_course) {
518: $output =
519: &Apache::loncommon::start_page('Viewable group portfolio files',undef,
520: {'function' => $forcestudent,
521: 'domain' => $cdom,});
522: $output .= '<h3>'.&mt('Group Portfolio files').'</h3>';
523: } else {
524: $output =
525: &Apache::loncommon::start_page('Viewable portfolio files',undef,
526: {'function' => $forcestudent,
527: 'domain' => $cdom,});
528: if (!($env{'user.name'} eq 'public' && $env{'user.domain'} eq 'public')) {
529: &Apache::lonhtmlcommon::add_breadcrumb
530: ({href=>"/adm/$cdom/$cnum/aboutme".$query_string,
531: text=>"Personal information - $name",
532: title=>"Go to personal information page for $name"}, {href=>"/adm/$cdom/$cnum/aboutme/portfolio",
533: text=>"Viewable files - $name",
534: title=>"Viewable portfolio files for $name"}
535: );
536: $output .= &Apache::lonhtmlcommon::breadcrumbs(&mt('Viewable portfolio files.'));
537: }
538: $output .= '<h3>'.&mt('Portfolio files for [_1]',$name).'</h3>';
539: }
540: $r->print($output);
541: return;
542: }
543:
544: sub display_portfolio_files {
545: my ($r,$is_course) = @_;
546: my ($cdom,$cnum,$name) = &aboutme_info($r,$is_course);
547: my %lt = ( withoutpass => 'passphrase not required',
548: withpass => 'passphrase protected',
549: both => 'all access types ',);
550: %lt = &Apache::lonlocal::texthash(%lt);
551:
552: my $portaccess = 'withoutpass';
553: if (exists($env{'form.portaccess'})) {
554: $portaccess = $env{'form.portaccess'};
555: }
556:
557: my $output = '<form action="'.&HTML::Entities::encode($r->uri,'<>&"')
558: .'" name="displaystatus" method="post">'.
559: &mt('File access type: ').'<select name="portaccess">';
560: foreach my $type ('withoutpass','withpass','both') {
561: $output .= '<option value="'.$type.'" ';
562: if ($portaccess eq $type) {
563: $output .= 'selected="selected"';
564: }
565: $output .= '>'.$lt{$type}.'</option>';
566: }
567: $output .= '</select>'."\n".
568: '<input type="submit" name="portaccessbutton" value="'.
569: &mt('Update display').'" />';
570: $output .= '</form><br /><br />';
571: $r->print($output);
572: my $filecounts = &portfolio_files($r,'listfiles',\%lt,$is_course,
573: $cdom,$cnum,$name);
574: if (!($env{'user.name'} eq 'public' && $env{'user.domain'} eq 'public')) {
575: my $query_string = &build_query_string();
576: $r->print('<br /><br /><a href="/adm/'.$cdom.'/'.$cnum.
577: '/aboutme'.$query_string.'">');
578: if ($is_course) {
579: $r->print(&mt('Course Information page'));
580: } else {
581: $r->print(&mt('Information about [_1]',$name));
582: }
583: $r->print('</a>');
584: }
585: return;
586: }
587:
588: sub portfolio_files {
589: my ($r,$mode,$lt,$is_course,$cdom,$cnum,$name) = @_;
590: my $filecounts = {
591: withpass => 0,
592: withoutpass => 0,
593: both => 0,
594: };
595: my $current_permissions =
596: &Apache::lonnet::get_portfile_permissions($cdom,$cnum);
597: my %access_controls =
598: &Apache::lonnet::get_access_controls($current_permissions);
599: my $portaccess;
600: if ($mode eq 'showlink') {
601: $portaccess = 'both';
602: } else {
603: $portaccess = 'withoutpass';
604: if (exists($env{'form.portaccess'})) {
605: $portaccess = $env{'form.portaccess'};
606: }
607: }
608:
609: my $diroutput;
610: if ($is_course) {
611: my %files_by_group;
612: foreach my $filename (sort(keys(%access_controls))) {
613: my ($group,$path) = split('/',$filename,2);
614: $files_by_group{$group}{$path} = $access_controls{$filename};
615: }
616: foreach my $group (sort(keys(%files_by_group))) {
617: my %fileshash;
618: my $grpout .= &build_hierarchy($r,$cdom,$cnum,$portaccess,
619: $is_course,$filecounts,$mode,
620: $files_by_group{$group},
621: \%fileshash,$group);
622: if ($grpout) {
623: $diroutput .= '<h3>'.$group.'</h3>'.$grpout.'<br />';
624: }
625: }
626: } else {
627: my %allfileshash;
628: $diroutput = &build_hierarchy($r,$cdom,$cnum,$portaccess,$is_course,
629: $filecounts,$mode,\%access_controls,
630: \%allfileshash);
631: }
632: if ($mode eq 'listfiles') {
633: if ($filecounts->{'both'}) {
634: $r->print($diroutput);
635: } else {
636: my $access_text;
637: if (ref($lt) eq 'HASH') {
638: $access_text = $lt->{$portaccess};
639: }
640: $r->print(&mt('There are no available files of the specified access type: [_1]',$access_text));
641: }
642: }
643: return $filecounts;
644: }
645:
646: {
647: my $count=0;
648: sub portfolio_table_start {
649: $count=0;
650: return '<table class="LC_aboutme_port">';
651: }
652: sub portfolio_row_start {
653: $count++;
654: my $class = ($count%2)?'LC_odd_row'
655: :'LC_even_row';
656: return '<tr class="'.$class.'">';
657: }
658: }
659:
660: sub build_hierarchy {
661: my ($r,$cdom,$cnum,$portaccess,$is_course,$filecounts,$mode,$access_info,
662: $allfileshash,$group) = @_;
663: foreach my $filename (sort(keys(%{$access_info}))) {
664: my $access_status =
665: &Apache::lonnet::get_portfolio_access($cdom,$cnum,$filename,$group, $$access_info{$filename});
666: if ($portaccess eq 'both') {
667: if (($access_status ne 'ok') &&
668: ($access_status !~ /^[^:]+:guest_/)) {
669: next;
670: }
671: } elsif ($portaccess eq 'withoutpass') {
672: if ($access_status ne 'ok') {
673: next;
674: }
675: } elsif ($portaccess eq 'withpass') {
676: if ($access_status !~ /^[^:]+:guest_/) {
677: next;
678: }
679: }
680: if ($mode eq 'listfiles') {
681: $filename =~ s/^\///;
682: my @pathitems = split('/',$filename);
683: my $lasthash = $allfileshash;
684: while (@pathitems > 1) {
685: my $newlevel = shift(@pathitems);
686: if (!exists($lasthash->{$newlevel})) {
687: $lasthash->{$newlevel} = {};
688: }
689: $lasthash = $lasthash->{$newlevel};
690: }
691: $lasthash->{$pathitems[0]} = $filename;
692: }
693: if ($access_status eq 'ok') {
694: $filecounts->{'withoutpass'} ++;
695: } elsif ($access_status =~ /^[^:]+:guest_/) {
696: $filecounts->{'withpass'} ++;
697: }
698: }
699: $filecounts->{'both'} = $filecounts->{'withoutpass'} +
700: $filecounts->{'withpass'};
701: my $output;
702: if ($mode eq 'listfiles') {
703: if ($filecounts->{'both'} > 0) {
704: $output = &portfolio_table_start();
705: $output .= &parse_directory($r,0,$allfileshash,'',$is_course,
706: $group);
707: $output .= '</table>';
708: }
709: }
710: return $output;
711: }
712:
713: sub parse_directory {
714: my ($r,$depth,$currhash,$path,$is_course,$group) = @_;
715: my ($cdom,$cnum,$name) = &aboutme_info($r,$is_course);
716: $depth++;
717: my $output;
718:
719: my $portfolio_root = &Apache::portfolio::get_portfolio_root($cdom,$cnum,
720: $group);
721: my $getpropath = 1;
722: my %dirlist = map {
723: ((split('&',$_,2))[0],1)
724: } &Apache::lonnet::dirlist($portfolio_root.$path,$cdom,$cnum,$getpropath);
725: foreach my $item (sort(keys(%{$currhash}))) {
726: $output .= &portfolio_row_start();
727: $output .= '<td style="padding-left: '.($depth*25).'px">';
728: if (ref($currhash->{$item}) eq 'HASH') {
729: my $title=&HTML::Entities::encode($item,'<>&"');
730: $output .= '<img src="'.&Apache::loncommon::lonhttpdurl("/adm/lonIcons/navmap.folder.open.gif").'" alt="'.&mt('Folder').' '.$title.'" class="LC_icon" /> '.$title;
731: $output .= '</td><td></td></tr>';
732: $output .= &parse_directory($r,$depth,$currhash->{$item},
733: $path.'/'.$item,$is_course,$group);
734: } else {
735: my $file_name;
736: if ($currhash->{$item} =~ m|/([^/]+)$|) {
737: $file_name = $1;
738: } else {
739: $file_name = $currhash->{$item};
740: }
741: my $have_meta = exists($dirlist{$file_name.'.meta'});
742: my $url;
743: if ($is_course) {
744: $url = '/uploaded/'.$cdom.'/'.$cnum.'/groups/'.$group.
745: '/portfolio/'.$currhash->{$item};
746: } else {
747: $url = '/uploaded/'.$cdom.'/'.$cnum.'/portfolio/'.
748: $currhash->{$item};
749: }
750: my $showname;
751: if ($have_meta) {
752: $showname = &Apache::lonnet::metadata($url,'title');
753: }
754: if ($showname eq '') {
755: $showname = $file_name;
756: } else {
757: $showname = $file_name.' ('.$showname.')';
758: }
759:
760: $showname=&HTML::Entities::encode($showname,'<>&"');
761: $output .= '<a href="'.$url.'">'.
762: '<img alt="" src="'.&Apache::loncommon::icon($currhash->{$item}).'" class="LC_icon" />'.
763: ' '.$showname.'</a>';
764: $output.='</td><td>';
765: if ($have_meta) {
766: $output.= '<a href="'.$url.'.meta"><img alt="'.&mt('Catalog Information').'" src="'.
767: &Apache::loncommon::lonhttpdurl('/res/adm/pages/catalog.gif').
768: '" class="LC_icon" /></a>';
769: }
770: $output .= '</td></tr>';
771: }
772: }
773: return $output;
774: }
775:
776: sub aboutme_access {
777: my ($uname,$udom) = @_;
778: my $privcheck = $env{'request.course.id'};
779: my $sec;
780: if ($env{'request.course.sec'} ne '') {
781: $sec = $env{'request.course.sec'};
782: $privcheck .= '/'.$sec;
783: }
784: my $cdom = $env{'course.'.$env{'request.course.id'}.'.domain'};
785: my $cnum = $env{'course.'.$env{'request.course.id'}.'.num'};
786: if (($cdom eq '') || ($cnum eq '')) {
787: my %coursehash = &coursedescription($env{'request.course.id'});
788: $cdom = $coursehash{'domain'};
789: $cnum = $coursehash{'cnum'};
790: }
791: if ((&Apache::lonnet::allowed('srm',$privcheck)) ||
792: (&Apache::lonnet::allowed('dff',$privcheck))) {
793: if (&in_course($uname,$udom,$cnum,$cdom)) {
794: return 1;
795: }
796: }
797: return;
798: }
799:
800: 1;
801: __END__
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>
![[BACK]](/icons/back.gif){kind=icon}
Return to lonaboutme.pm CVS log ![[TXT]](/icons/text.gif){kind=icon}
![[DIR]](/icons/dir.gif){kind=icon}
Up to [LON-CAPA] / loncom / interface