1: # The LearningOnline Network with CAPA
2: # a pile of common routines
3: #
4: # $Id: loncommon.pm,v 1.57 2002/08/22 21:02:49 albertel Exp $
5: #
6: # Copyright Michigan State University Board of Trustees
7: #
8: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
9: #
10: # LON-CAPA is free software; you can redistribute it and/or modify
11: # it under the terms of the GNU General Public License as published by
12: # the Free Software Foundation; either version 2 of the License, or
13: # (at your option) any later version.
14: #
15: # LON-CAPA is distributed in the hope that it will be useful,
16: # but WITHOUT ANY WARRANTY; without even the implied warranty of
17: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18: # GNU General Public License for more details.
19: #
20: # You should have received a copy of the GNU General Public License
21: # along with LON-CAPA; if not, write to the Free Software
22: # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
23: #
24: # /home/httpd/html/adm/gpl.txt
25: #
26: # http://www.lon-capa.org/
27: #
28: # YEAR=2001
29: # 2/13-12/7 Guy Albertelli
30: # 12/11,12/12,12/17 Scott Harrison
31: # 12/21 Gerd Kortemeyer
32: # 12/21 Scott Harrison
33: # 12/25,12/28 Gerd Kortemeyer
34: # YEAR=2002
35: # 1/4 Gerd Kortemeyer
36: # 6/24,7/2 H. K. Ng
37:
38: # Makes a table out of the previous attempts
39: # Inputs result_from_symbread, user, domain, course_id
40: # Reads in non-network-related .tab files
41:
42: # POD header:
43:
44: =pod
45:
46: =head1 NAME
47:
48: Apache::loncommon - pile of common routines
49:
50: =head1 SYNOPSIS
51:
52: Referenced by other mod_perl Apache modules.
53:
54: Invocation:
55: &Apache::loncommon::SUBROUTINENAME(ARGUMENTS);
56:
57: =head1 INTRODUCTION
58:
59: Common collection of used subroutines. This collection helps remove
60: redundancy from other modules and increase efficiency of memory usage.
61:
62: Current things done:
63:
64: Makes a table out of the previous homework attempts
65: Inputs result_from_symbread, user, domain, course_id
66: Reads in non-network-related .tab files
67:
68: This is part of the LearningOnline Network with CAPA project
69: described at http://www.lon-capa.org.
70:
71: =head2 General Subroutines
72:
73: =over 4
74:
75: =cut
76:
77: # End of POD header
78: package Apache::loncommon;
79:
80: use strict;
81: use Apache::lonnet();
82: use GDBM_File;
83: use POSIX qw(strftime mktime);
84: use Apache::Constants qw(:common);
85: use Apache::lonmsg();
86: my $readit;
87:
88: =pod
89:
90: =item Global Variables
91:
92: =over 4
93:
94: =cut
95: # ----------------------------------------------- Filetypes/Languages/Copyright
96: my %language;
97: my %cprtag;
98: my %fe; my %fd;
99: my %category_extensions;
100:
101: # ---------------------------------------------- Thesaurus variables
102:
103: =pod
104:
105: =item %Keywords
106:
107: A hash used by &keyword to determine if a word is considered a keyword.
108:
109: =item $thesaurus_db_file
110:
111: Scalar containing the full path to the thesaurus database.
112:
113: =cut
114:
115: my %Keywords;
116: my $thesaurus_db_file;
117:
118:
119: =pod
120:
121: =back
122:
123: =cut
124:
125: # ----------------------------------------------------------------------- BEGIN
126:
127: =pod
128:
129: =item BEGIN()
130:
131: Initialize values from language.tab, copyright.tab, filetypes.tab,
132: thesaurus.tab, and filecategories.tab.
133:
134: =cut
135:
136: # ----------------------------------------------------------------------- BEGIN
137:
138: BEGIN {
139: # Variable initialization
140: $thesaurus_db_file = $Apache::lonnet::perlvar{'lonTabDir'}."/thesaurus.db";
141: #
142: unless ($readit) {
143: # ------------------------------------------------------------------- languages
144: {
145: my $fh=Apache::File->new($Apache::lonnet::perlvar{'lonTabDir'}.
146: '/language.tab');
147: if ($fh) {
148: while (<$fh>) {
149: next if /^\#/;
150: chomp;
151: my ($key,$val)=(split(/\s+/,$_,2));
152: $language{$key}=$val;
153: }
154: }
155: }
156: # ------------------------------------------------------------------ copyrights
157: {
158: my $fh=Apache::File->new($Apache::lonnet::perlvar{'lonIncludes'}.
159: '/copyright.tab');
160: if ($fh) {
161: while (<$fh>) {
162: next if /^\#/;
163: chomp;
164: my ($key,$val)=(split(/\s+/,$_,2));
165: $cprtag{$key}=$val;
166: }
167: }
168: }
169: # ------------------------------------------------------------- file categories
170: {
171: my $fh=Apache::File->new($Apache::lonnet::perlvar{'lonTabDir'}.
172: '/filecategories.tab');
173: if ($fh) {
174: while (<$fh>) {
175: next if /^\#/;
176: chomp;
177: my ($extension,$category)=(split(/\s+/,$_,2));
178: push @{$category_extensions{lc($category)}},$extension;
179: }
180: }
181: }
182: # ------------------------------------------------------------------ file types
183: {
184: my $fh=Apache::File->new($Apache::lonnet::perlvar{'lonTabDir'}.
185: '/filetypes.tab');
186: if ($fh) {
187: while (<$fh>) {
188: next if (/^\#/);
189: chomp;
190: my ($ending,$emb,$descr)=split(/\s+/,$_,3);
191: if ($descr ne '') {
192: $fe{$ending}=lc($emb);
193: $fd{$ending}=$descr;
194: }
195: }
196: }
197: }
198: &Apache::lonnet::logthis(
199: "<font color=yellow>INFO: Read file types</font>");
200: $readit=1;
201: } # end of unless($readit)
202:
203: }
204: # ============================================================= END BEGIN BLOCK
205: ###############################################################
206: ## HTML and Javascript Helper Functions ##
207: ###############################################################
208:
209: =pod
210:
211: =item browser_and_searcher_javascript
212:
213: Returns scalar containing javascript to open a browser window
214: or a searcher window. Also creates
215:
216: =over 4
217:
218: =item openbrowser(formname,elementname,only,omit) [javascript]
219:
220: inputs: formname, elementname, only, omit
221:
222: formname and elementname indicate the name of the html form and name of
223: the element that the results of the browsing selection are to be placed in.
224:
225: Specifying 'only' will restrict the browser to displaying only files
226: with the given extension. Can be a comma seperated list.
227:
228: Specifying 'omit' will restrict the browser to NOT displaying files
229: with the given extension. Can be a comma seperated list.
230:
231: =item opensearcher(formname, elementname) [javascript]
232:
233: Inputs: formname, elementname
234:
235: formname and elementname specify the name of the html form and the name
236: of the element the selection from the search results will be placed in.
237:
238: =back
239:
240: =cut
241:
242: ###############################################################
243: sub browser_and_searcher_javascript {
244: return <<END;
245: var editbrowser = null;
246: function openbrowser(formname,elementname,only,omit) {
247: var url = '/res/?';
248: if (editbrowser == null) {
249: url += 'launch=1&';
250: }
251: url += 'catalogmode=interactive&';
252: url += 'mode=edit&';
253: url += 'form=' + formname + '&';
254: if (only != null) {
255: url += 'only=' + only + '&';
256: }
257: if (omit != null) {
258: url += 'omit=' + omit + '&';
259: }
260: url += 'element=' + elementname + '';
261: var title = 'Browser';
262: var options = 'scrollbars=1,resizable=1,menubar=0';
263: options += ',width=700,height=600';
264: editbrowser = open(url,title,options,'1');
265: editbrowser.focus();
266: }
267: var editsearcher;
268: function opensearcher(formname,elementname) {
269: var url = '/adm/searchcat?';
270: if (editsearcher == null) {
271: url += 'launch=1&';
272: }
273: url += 'catalogmode=interactive&';
274: url += 'mode=edit&';
275: url += 'form=' + formname + '&';
276: url += 'element=' + elementname + '';
277: var title = 'Search';
278: var options = 'scrollbars=1,resizable=1,menubar=0';
279: options += ',width=700,height=600';
280: editsearcher = open(url,title,options,'1');
281: editsearcher.focus();
282: }
283: END
284: }
285:
286:
287:
288: ###############################################################
289:
290: =pod
291:
292: =item linked_select_forms(...)
293:
294: linked_select_forms returns a string containing a <script></script> block
295: and html for two <select> menus. The select menus will be linked in that
296: changing the value of the first menu will result in new values being placed
297: in the second menu. The values in the select menu will appear in alphabetical
298: order.
299:
300: linked_select_forms takes the following ordered inputs:
301:
302: =over 4
303:
304: =item $formname, the name of the <form> tag
305:
306: =item $middletext, the text which appears between the <select> tags
307:
308: =item $firstdefault, the default value for the first menu
309:
310: =item $firstselectname, the name of the first <select> tag
311:
312: =item $secondselectname, the name of the second <select> tag
313:
314: =item $hashref, a reference to a hash containing the data for the menus.
315:
316: =back
317:
318: Below is an example of such a hash. Only the 'text', 'default', and
319: 'select2' keys must appear as stated. keys(%menu) are the possible
320: values for the first select menu. The text that coincides with the
321: first menu value is given in $menu{$choice1}->{'text'}. The values
322: and text for the second menu are given in the hash pointed to by
323: $menu{$choice1}->{'select2'}.
324:
325: my %menu = ( A1 => { text =>"Choice A1" ,
326: default => "B3",
327: select2 => {
328: B1 => "Choice B1",
329: B2 => "Choice B2",
330: B3 => "Choice B3",
331: B4 => "Choice B4"
332: }
333: },
334: A2 => { text =>"Choice A2" ,
335: default => "C2",
336: select2 => {
337: C1 => "Choice C1",
338: C2 => "Choice C2",
339: C3 => "Choice C3"
340: }
341: },
342: A3 => { text =>"Choice A3" ,
343: default => "D6",
344: select2 => {
345: D1 => "Choice D1",
346: D2 => "Choice D2",
347: D3 => "Choice D3",
348: D4 => "Choice D4",
349: D5 => "Choice D5",
350: D6 => "Choice D6",
351: D7 => "Choice D7"
352: }
353: }
354: );
355:
356: =cut
357:
358: # ------------------------------------------------
359:
360: sub linked_select_forms {
361: my ($formname,
362: $middletext,
363: $firstdefault,
364: $firstselectname,
365: $secondselectname,
366: $hashref
367: ) = @_;
368: my $second = "document.$formname.$secondselectname";
369: my $first = "document.$formname.$firstselectname";
370: # output the javascript to do the changing
371: my $result = '';
372: $result.="<script>\n";
373: $result.="var select2data = new Object();\n";
374: $" = '","';
375: my $debug = '';
376: foreach my $s1 (sort(keys(%$hashref))) {
377: $result.="select2data.d_$s1 = new Object();\n";
378: $result.="select2data.d_$s1.def = new String('".
379: $hashref->{$s1}->{'default'}."');\n";
380: $result.="select2data.d_$s1.values = new Array(";
381: my @s2values = sort(keys( %{ $hashref->{$s1}->{'select2'} } ));
382: $result.="\"@s2values\");\n";
383: $result.="select2data.d_$s1.texts = new Array(";
384: my @s2texts;
385: foreach my $value (@s2values) {
386: push @s2texts, $hashref->{$s1}->{'select2'}->{$value};
387: }
388: $result.="\"@s2texts\");\n";
389: }
390: $"=' ';
391: $result.= <<"END";
392:
393: function select1_changed() {
394: // Determine new choice
395: var newvalue = "d_" + $first.value;
396: // update select2
397: var values = select2data[newvalue].values;
398: var texts = select2data[newvalue].texts;
399: var select2def = select2data[newvalue].def;
400: var i;
401: // out with the old
402: for (i = 0; i < $second.options.length; i++) {
403: $second.options[i] = null;
404: }
405: // in with the nuclear
406: for (i=0;i<values.length; i++) {
407: $second.options[i] = new Option(values[i]);
408: $second.options[i].text = texts[i];
409: if (values[i] == select2def) {
410: $second.options[i].selected = true;
411: }
412: }
413: }
414: </script>
415: END
416: # output the initial values for the selection lists
417: $result .= "<select size=\"1\" name=\"$firstselectname\" onchange=\"select1_changed()\">\n";
418: foreach my $value (sort(keys(%$hashref))) {
419: $result.=" <option value=\"$value\" ";
420: $result.=" selected=\"true\" " if ($value eq $firstdefault);
421: $result.=">$hashref->{$value}->{'text'}</option>\n";
422: }
423: $result .= "</select>\n";
424: my %select2 = %{$hashref->{$firstdefault}->{'select2'}};
425: $result .= $middletext;
426: $result .= "<select size=\"1\" name=\"$secondselectname\">\n";
427: my $seconddefault = $hashref->{$firstdefault}->{'default'};
428: foreach my $value (sort(keys(%select2))) {
429: $result.=" <option value=\"$value\" ";
430: $result.=" selected=\"true\" " if ($value eq $seconddefault);
431: $result.=">$select2{$value}</option>\n";
432: }
433: $result .= "</select>\n";
434: # return $debug;
435: return $result;
436: } # end of sub linked_select_forms {
437:
438: ###############################################################
439:
440: =pod
441:
442: =item help_open_topic($topic, $text, $stayOnPage, $width, $height)
443:
444: Returns a string corresponding to an HTML link to the given help $topic, where $topic corresponds to the name of a .tex file in /home/httpd/html/adm/help/tex, with underscores replaced by spaces.
445:
446: $text will optionally be linked to the same topic, allowing you to link text in addition to the graphic. If you do not want to link text, but wish to specify one of the later parameters, pass an empty string.
447:
448: $stayOnPage is a value that will be interpreted as a boolean. If true, the link will not open a new window. If false, the link will open a new window using Javascript. (Default is false.)
449:
450: $width and $height are optional numerical parameters that will override the width and height of the popped up window, which may be useful for certain help topics with big pictures included.
451:
452: =cut
453:
454: sub help_open_topic {
455: my ($topic, $text, $stayOnPage, $width, $height) = @_;
456: $text = "" if (not defined $text);
457: $stayOnPage = 0 if (not defined $stayOnPage);
458: $width = 350 if (not defined $width);
459: $height = 400 if (not defined $height);
460: my $filename = $topic;
461: $filename =~ s/ /_/g;
462:
463: my $template = "";
464: my $link;
465:
466: if (!$stayOnPage)
467: {
468: $link = "javascript:void(open('/adm/help/${filename}.hlp', 'Help_for_$topic', 'menubar=0,toolbar=1,scrollbars=1,width=$width,height=$height'))";
469: }
470: else
471: {
472: $link = "/adm/help/${filename}.hlp";
473: }
474:
475: # Add the text
476: if ($text ne "")
477: {
478: $template .= "<a href=\"$link\">$text</a> ";
479: }
480:
481: # Add the graphic
482: $template .= <<"ENDTEMPLATE";
483: <a href="$link"><image src="/adm/help/gif/smallHelp.gif" border="0" alt="(Help: $topic)" /></a>
484: ENDTEMPLATE
485:
486: return $template;
487:
488: }
489:
490: =pod
491:
492: =item csv_translate($text)
493:
494: Translate $text to allow it to be output as a 'comma seperated values'
495: format.
496:
497: =cut
498:
499: sub csv_translate {
500: my $text = shift;
501: $text =~ s/\"/\"\"/g;
502: $text =~ s/\n//g;
503: return $text;
504: }
505:
506: ###############################################################
507: ## Home server <option> list generating code ##
508: ###############################################################
509: #-------------------------------------------
510:
511: =pod
512:
513: =item get_domains()
514:
515: Returns an array containing each of the domains listed in the hosts.tab
516: file.
517:
518: =cut
519:
520: #-------------------------------------------
521: sub get_domains {
522: # The code below was stolen from "The Perl Cookbook", p 102, 1st ed.
523: my @domains;
524: my %seen;
525: foreach (sort values(%Apache::lonnet::hostdom)) {
526: push (@domains,$_) unless $seen{$_}++;
527: }
528: return @domains;
529: }
530:
531: #-------------------------------------------
532:
533: =pod
534:
535: =item select_dom_form($defdom,$name)
536:
537: Returns a string containing a <select name='$name' size='1'> form to
538: allow a user to select the domain to preform an operation in.
539: See loncreateuser.pm for an example invocation and use.
540:
541: =cut
542:
543: #-------------------------------------------
544: sub select_dom_form {
545: my ($defdom,$name) = @_;
546: my @domains = get_domains();
547: my $selectdomain = "<select name=\"$name\" size=\"1\">\n";
548: foreach (@domains) {
549: $selectdomain.="<option value=\"$_\" ".
550: ($_ eq $defdom ? 'selected' : '').
551: ">$_</option>\n";
552: }
553: $selectdomain.="</select>";
554: return $selectdomain;
555: }
556:
557: #-------------------------------------------
558:
559: =pod
560:
561: =item get_library_servers($domain)
562:
563: Returns a hash which contains keys like '103l3' and values like
564: 'kirk.lite.msu.edu'. All of the keys will be for machines in the
565: given $domain.
566:
567: =cut
568:
569: #-------------------------------------------
570: sub get_library_servers {
571: my $domain = shift;
572: my %library_servers;
573: foreach (keys(%Apache::lonnet::libserv)) {
574: if ($Apache::lonnet::hostdom{$_} eq $domain) {
575: $library_servers{$_} = $Apache::lonnet::hostname{$_};
576: }
577: }
578: return %library_servers;
579: }
580:
581: #-------------------------------------------
582:
583: =pod
584:
585: =item home_server_option_list($domain)
586:
587: returns a string which contains an <option> list to be used in a
588: <select> form input. See loncreateuser.pm for an example.
589:
590: =cut
591:
592: #-------------------------------------------
593: sub home_server_option_list {
594: my $domain = shift;
595: my %servers = &get_library_servers($domain);
596: my $result = '';
597: foreach (sort keys(%servers)) {
598: $result.=
599: '<option value="'.$_.'">'.$_.' '.$servers{$_}."</option>\n";
600: }
601: return $result;
602: }
603: ###############################################################
604: ## End of home server <option> list generating code ##
605: ###############################################################
606:
607: ###############################################################
608: ## Authentication changing form generation subroutines ##
609: ###############################################################
610: ##
611: ## All of the authform_xxxxxxx subroutines take their inputs in a
612: ## hash, and have reasonable default values.
613: ##
614: ## formname = the name given in the <form> tag.
615: #-------------------------------------------
616:
617: =pod
618:
619: =item authform_xxxxxx
620:
621: The authform_xxxxxx subroutines provide javascript and html forms which
622: handle some of the conveniences required for authentication forms.
623: This is not an optimal method, but it works.
624:
625: See loncreateuser.pm for invocation and use examples.
626:
627: =over 4
628:
629: =item authform_header
630:
631: =item authform_authorwarning
632:
633: =item authform_nochange
634:
635: =item authform_kerberos
636:
637: =item authform_internal
638:
639: =item authform_filesystem
640:
641: =back
642:
643: =cut
644:
645: #-------------------------------------------
646: sub authform_header{
647: my %in = (
648: formname => 'cu',
649: kerb_def_dom => 'MSU.EDU',
650: @_,
651: );
652: $in{'formname'} = 'document.' . $in{'formname'};
653: my $result='';
654: $result.=<<"END";
655: var current = new Object();
656: current.radiovalue = 'nochange';
657: current.argfield = null;
658:
659: function changed_radio(choice,currentform) {
660: var choicearg = choice + 'arg';
661: // If a radio button in changed, we need to change the argfield
662: if (current.radiovalue != choice) {
663: current.radiovalue = choice;
664: if (current.argfield != null) {
665: currentform.elements[current.argfield].value = '';
666: }
667: if (choice == 'nochange') {
668: current.argfield = null;
669: } else {
670: current.argfield = choicearg;
671: switch(choice) {
672: case 'krb':
673: currentform.elements[current.argfield].value =
674: "$in{'kerb_def_dom'}";
675: break;
676: default:
677: break;
678: }
679: }
680: }
681: return;
682: }
683:
684: function changed_text(choice,currentform) {
685: var choicearg = choice + 'arg';
686: if (currentform.elements[choicearg].value !='') {
687: switch (choice) {
688: case 'krb': currentform.elements[choicearg].value =
689: currentform.elements[choicearg].value.toUpperCase();
690: break;
691: default:
692: }
693: // clear old field
694: if ((current.argfield != choicearg) && (current.argfield != null)) {
695: currentform.elements[current.argfield].value = '';
696: }
697: current.argfield = choicearg;
698: }
699: set_auth_radio_buttons(choice,currentform);
700: return;
701: }
702:
703: function set_auth_radio_buttons(newvalue,currentform) {
704: var i=0;
705: while (i < currentform.login.length) {
706: if (currentform.login[i].value == newvalue) { break; }
707: i++;
708: }
709: if (i == currentform.login.length) {
710: return;
711: }
712: current.radiovalue = newvalue;
713: currentform.login[i].checked = true;
714: return;
715: }
716: END
717: return $result;
718: }
719:
720: sub authform_authorwarning{
721: my $result='';
722: $result=<<"END";
723: <i>As a general rule, only authors or co-authors should be filesystem
724: authenticated (which allows access to the server filesystem).</i>
725: END
726: return $result;
727: }
728:
729: sub authform_nochange{
730: my %in = (
731: formname => 'document.cu',
732: kerb_def_dom => 'MSU.EDU',
733: @_,
734: );
735: my $result='';
736: $result.=<<"END";
737: <input type="radio" name="login" value="nochange" checked="checked"
738: onclick="javascript:changed_radio('nochange',$in{'formname'});" />
739: Do not change login data
740: END
741: return $result;
742: }
743:
744: sub authform_kerberos{
745: my %in = (
746: formname => 'document.cu',
747: kerb_def_dom => 'MSU.EDU',
748: @_,
749: );
750: my $result='';
751: $result.=<<"END";
752: <input type="radio" name="login" value="krb"
753: onclick="javascript:changed_radio('krb',$in{'formname'});"
754: onchange="javascript:changed_radio('krb',$in{'formname'});" />
755: Kerberos authenticated with domain
756: <input type="text" size="10" name="krbarg" value=""
757: onchange="javascript:changed_text('krb',$in{'formname'});" />
758: END
759: return $result;
760: }
761:
762: sub authform_internal{
763: my %args = (
764: formname => 'document.cu',
765: kerb_def_dom => 'MSU.EDU',
766: @_,
767: );
768: my $result='';
769: $result.=<<"END";
770: <input type="radio" name="login" value="int"
771: onchange="javascript:changed_radio('int',$args{'formname'});"
772: onclick="javascript:changed_radio('int',$args{'formname'});" />
773: Internally authenticated (with initial password
774: <input type="text" size="10" name="intarg" value=""
775: onchange="javascript:changed_text('int',$args{'formname'});" />
776: END
777: return $result;
778: }
779:
780: sub authform_local{
781: my %in = (
782: formname => 'document.cu',
783: kerb_def_dom => 'MSU.EDU',
784: @_,
785: );
786: my $result='';
787: $result.=<<"END";
788: <input type="radio" name="login" value="loc"
789: onchange="javascript:changed_radio('loc',$in{'formname'});"
790: onclick="javascript:changed_radio('loc',$in{'formname'});" />
791: Local Authentication with argument
792: <input type="text" size="10" name="locarg" value=""
793: onchange="javascript:changed_text('loc',$in{'formname'});" />
794: END
795: return $result;
796: }
797:
798: sub authform_filesystem{
799: my %in = (
800: formname => 'document.cu',
801: kerb_def_dom => 'MSU.EDU',
802: @_,
803: );
804: my $result='';
805: $result.=<<"END";
806: <input type="radio" name="login" value="fsys"
807: onchange="javascript:changed_radio('fsys',$in{'formname'});"
808: onclick="javascript:changed_radio('fsys',$in{'formname'});" />
809: Filesystem authenticated (with initial password
810: <input type="text" size="10" name="fsysarg" value=""
811: onchange="javascript:changed_text('fsys',$in{'formname'});">
812: END
813: return $result;
814: }
815:
816: ###############################################################
817: ## End Authentication changing form generation functions ##
818: ###############################################################
819:
820: ###############################################################
821: ## Thesaurus Functions ##
822: ###############################################################
823:
824: =pod
825:
826: =item initialize_keywords
827:
828: Initializes the package variable %Keywords if it is empty. Uses the
829: package variable $thesaurus_db_file.
830:
831: =cut
832:
833: ###################################################
834:
835: sub initialize_keywords {
836: return 1 if (scalar keys(%Keywords));
837: # If we are here, %Keywords is empty, so fill it up
838: # Make sure the file we need exists...
839: if (! -e $thesaurus_db_file) {
840: &Apache::lonnet::logthis("Attempt to access $thesaurus_db_file".
841: " failed because it does not exist");
842: return 0;
843: }
844: # Set up the hash as a database
845: my %thesaurus_db;
846: if (! tie(%thesaurus_db,'GDBM_File',
847: $thesaurus_db_file,&GDBM_READER(),0640)){
848: &Apache::lonnet::logthis("Could not tie \%thesaurus_db to ".
849: $thesaurus_db_file);
850: return 0;
851: }
852: # Get the average number of appearances of a word.
853: my $avecount = $thesaurus_db{'average.count'};
854: # Put keywords (those that appear > average) into %Keywords
855: while (my ($word,$data)=each (%thesaurus_db)) {
856: my ($count,undef) = split /:/,$data;
857: $Keywords{$word}++ if ($count > $avecount);
858: }
859: untie %thesaurus_db;
860: # Remove special values from %Keywords.
861: foreach ('total.count','average.count') {
862: delete($Keywords{$_}) if (exists($Keywords{$_}));
863: }
864: return 1;
865: }
866:
867: ###################################################
868:
869: =pod
870:
871: =item keyword($word)
872:
873: Returns true if $word is a keyword. A keyword is a word that appears more
874: than the average number of times in the thesaurus database. Calls
875: &initialize_keywords
876:
877: =cut
878:
879: ###################################################
880:
881: sub keyword {
882: return if (!&initialize_keywords());
883: my $word=lc(shift());
884: $word=~s/\W//g;
885: return exists($Keywords{$word});
886: }
887:
888: ###############################################################
889:
890: =pod
891:
892: =item get_related_words
893:
894: Look up a word in the thesaurus. Takes a scalar arguement and returns
895: an array of words. If the keyword is not in the thesaurus, an empty array
896: will be returned. The order of the words returned is determined by the
897: database which holds them.
898:
899: Uses global $thesaurus_db_file.
900:
901: =cut
902:
903: ###############################################################
904: sub get_related_words {
905: my $keyword = shift;
906: my %thesaurus_db;
907: if (! -e $thesaurus_db_file) {
908: &Apache::lonnet::logthis("Attempt to access $thesaurus_db_file ".
909: "failed because the file does not exist");
910: return ();
911: }
912: if (! tie(%thesaurus_db,'GDBM_File',
913: $thesaurus_db_file,&GDBM_READER(),0640)){
914: return ();
915: }
916: my @Words=();
917: if (exists($thesaurus_db{$keyword})) {
918: $_ = $thesaurus_db{$keyword};
919: (undef,@Words) = split/:/; # The first element is the number of times
920: # the word appears. We do not need it now.
921: for (my $i=0;$i<=$#Words;$i++) {
922: ($Words[$i],undef)= split/\,/,$Words[$i];
923: }
924: }
925: untie %thesaurus_db;
926: return @Words;
927: }
928:
929: ###############################################################
930: ## End Thesaurus Functions ##
931: ###############################################################
932:
933: # ---------------------------------------------------------------- Language IDs
934: sub languageids {
935: return sort(keys(%language));
936: }
937:
938: # -------------------------------------------------------- Language Description
939: sub languagedescription {
940: return $language{shift(@_)};
941: }
942:
943: # --------------------------------------------------------------- Copyright IDs
944: sub copyrightids {
945: return sort(keys(%cprtag));
946: }
947:
948: # ------------------------------------------------------- Copyright Description
949: sub copyrightdescription {
950: return $cprtag{shift(@_)};
951: }
952:
953: # ------------------------------------------------------------- File Categories
954: sub filecategories {
955: return sort(keys(%category_extensions));
956: }
957:
958: # -------------------------------------- File Types within a specified category
959: sub filecategorytypes {
960: return @{$category_extensions{lc($_[0])}};
961: }
962:
963: # ------------------------------------------------------------------ File Types
964: sub fileextensions {
965: return sort(keys(%fe));
966: }
967:
968: # ------------------------------------------------------------- Embedding Style
969: sub fileembstyle {
970: return $fe{lc(shift(@_))};
971: }
972:
973: # ------------------------------------------------------------ Description Text
974: sub filedescription {
975: return $fd{lc(shift(@_))};
976: }
977:
978: # ------------------------------------------------------------ Description Text
979: sub filedescriptionex {
980: my $ex=shift;
981: return '.'.$ex.' '.$fd{lc($ex)};
982: }
983:
984: # ---- Retrieve attempts by students
985: # input
986: # $symb - problem including path
987: # $username,$domain - that of the student
988: # $course - course name
989: # $getattempt - leave blank if want all attempts, else put something.
990: # $regexp - regular expression. If string matches regexp send to
991: # $gradesub - routine that process the string if it matches regexp
992: #
993: # output
994: # formatted as a table all the attempts, if any.
995: #
996: sub get_previous_attempt {
997: my ($symb,$username,$domain,$course,$getattempt,$regexp,$gradesub)=@_;
998: my $prevattempts='';
999: no strict 'refs';
1000: if ($symb) {
1001: my (%returnhash)=
1002: &Apache::lonnet::restore($symb,$course,$domain,$username);
1003: if ($returnhash{'version'}) {
1004: my %lasthash=();
1005: my $version;
1006: for ($version=1;$version<=$returnhash{'version'};$version++) {
1007: foreach (sort(split(/\:/,$returnhash{$version.':keys'}))) {
1008: $lasthash{$_}=$returnhash{$version.':'.$_};
1009: }
1010: }
1011: $prevattempts='<table border="0" width="100%"><tr><td bgcolor="#777777">';
1012: $prevattempts.='<table border="0" width="100%"><tr bgcolor="#e6ffff"><td>History</td>';
1013: foreach (sort(keys %lasthash)) {
1014: my ($ign,@parts) = split(/\./,$_);
1015: if ($#parts > 0) {
1016: my $data=$parts[-1];
1017: pop(@parts);
1018: $prevattempts.='<td>Part '.join('.',@parts).'<br />'.$data.' </td>';
1019: } else {
1020: if ($#parts == 0) {
1021: $prevattempts.='<th>'.$parts[0].'</th>';
1022: } else {
1023: $prevattempts.='<th>'.$ign.'</th>';
1024: }
1025: }
1026: }
1027: if ($getattempt eq '') {
1028: for ($version=1;$version<=$returnhash{'version'};$version++) {
1029: $prevattempts.='</tr><tr bgcolor="#ffffe6"><td>Transaction '.$version.'</td>';
1030: foreach (sort(keys %lasthash)) {
1031: my $value;
1032: if ($_ =~ /timestamp/) {
1033: $value=scalar(localtime($returnhash{$version.':'.$_}));
1034: } else {
1035: $value=$returnhash{$version.':'.$_};
1036: }
1037: $prevattempts.='<td>'.$value.' </td>';
1038: }
1039: }
1040: }
1041: $prevattempts.='</tr><tr bgcolor="#ffffe6"><td>Current</td>';
1042: foreach (sort(keys %lasthash)) {
1043: my $value;
1044: if ($_ =~ /timestamp/) {
1045: $value=scalar(localtime($lasthash{$_}));
1046: } else {
1047: $value=$lasthash{$_};
1048: }
1049: if ($_ =~/$regexp$/ && (defined &$gradesub)) {$value = &$gradesub($value)}
1050: $prevattempts.='<td>'.$value.' </td>';
1051: }
1052: $prevattempts.='</tr></table></td></tr></table>';
1053: } else {
1054: $prevattempts='Nothing submitted - no attempts.';
1055: }
1056: } else {
1057: $prevattempts='No data.';
1058: }
1059: }
1060:
1061: sub get_student_view {
1062: my ($symb,$username,$domain,$courseid) = @_;
1063: my ($map,$id,$feedurl) = split(/___/,$symb);
1064: my (%old,%moreenv);
1065: my @elements=('symb','courseid','domain','username');
1066: foreach my $element (@elements) {
1067: $old{$element}=$ENV{'form.grade_'.$element};
1068: $moreenv{'form.grade_'.$element}=eval '$'.$element #'
1069: }
1070: &Apache::lonnet::appenv(%moreenv);
1071: my $userview=&Apache::lonnet::ssi('/res/'.$feedurl);
1072: &Apache::lonnet::delenv('form.grade_');
1073: foreach my $element (@elements) {
1074: $ENV{'form.grade_'.$element}=$old{$element};
1075: }
1076: $userview=~s/\<body[^\>]*\>//gi;
1077: $userview=~s/\<\/body\>//gi;
1078: $userview=~s/\<html\>//gi;
1079: $userview=~s/\<\/html\>//gi;
1080: $userview=~s/\<head\>//gi;
1081: $userview=~s/\<\/head\>//gi;
1082: $userview=~s/action\s*\=/would_be_action\=/gi;
1083: return $userview;
1084: }
1085:
1086: sub get_student_answers {
1087: my ($symb,$username,$domain,$courseid) = @_;
1088: my ($map,$id,$feedurl) = split(/___/,$symb);
1089: my (%old,%moreenv);
1090: my @elements=('symb','courseid','domain','username');
1091: foreach my $element (@elements) {
1092: $old{$element}=$ENV{'form.grade_'.$element};
1093: $moreenv{'form.grade_'.$element}=eval '$'.$element #'
1094: }
1095: $moreenv{'form.grade_target'}='answer';
1096: &Apache::lonnet::appenv(%moreenv);
1097: my $userview=&Apache::lonnet::ssi('/res/'.$feedurl);
1098: &Apache::lonnet::delenv('form.grade_');
1099: foreach my $element (@elements) {
1100: $ENV{'form.grade_'.$element}=$old{$element};
1101: }
1102: return $userview;
1103: }
1104:
1105: ###############################################
1106:
1107:
1108: sub timehash {
1109: my @ltime=localtime(shift);
1110: return ( 'seconds' => $ltime[0],
1111: 'minutes' => $ltime[1],
1112: 'hours' => $ltime[2],
1113: 'day' => $ltime[3],
1114: 'month' => $ltime[4]+1,
1115: 'year' => $ltime[5]+1900,
1116: 'weekday' => $ltime[6],
1117: 'dayyear' => $ltime[7]+1,
1118: 'dlsav' => $ltime[8] );
1119: }
1120:
1121: sub maketime {
1122: my %th=@_;
1123: return POSIX::mktime(
1124: ($th{'seconds'},$th{'minutes'},$th{'hours'},
1125: $th{'day'},$th{'month'}-1,$th{'year'}-1900,0,0,$th{'dlsav'}));
1126: }
1127:
1128:
1129: sub findallcourses {
1130: my %courses=();
1131: my $now=time;
1132: foreach (keys %ENV) {
1133: if ($_=~/^user\.role\.\w+\.\/(\w+)\/(\w+)/) {
1134: my ($starttime,$endtime)=$ENV{$_};
1135: my $active=1;
1136: if ($starttime) {
1137: if ($now<$starttime) { $active=0; }
1138: }
1139: if ($endtime) {
1140: if ($now>$endtime) { $active=0; }
1141: }
1142: if ($active) { $courses{$1.'_'.$2}=1; }
1143: }
1144: }
1145: return keys %courses;
1146: }
1147:
1148: ###############################################
1149:
1150: sub bodytag {
1151: my ($title,$function,$addentries)=@_;
1152: unless ($function) {
1153: $function='student';
1154: if ($ENV{'request.role'}=~/^(cc|in|ta|ep)/) {
1155: $function='coordinator';
1156: }
1157: if ($ENV{'request.role'}=~/^(su|dc|ad|li)/) {
1158: $function='admin';
1159: }
1160: if (($ENV{'request.role'}=~/^(au|ca)/) ||
1161: ($ENV{'REQUEST_URI'}=~/^(\/priv|\~)/)) {
1162: $function='author';
1163: }
1164: }
1165: my $img='';
1166: my $pgbg='';
1167: my $tabbg='';
1168: my $font='';
1169: my $link='';
1170: my $alink='#CC0000';
1171: my $vlink='';
1172: if ($function eq 'admin') {
1173: $img='admin';
1174: $pgbg='#FFFFCC';
1175: $tabbg='#CCCC99';
1176: $font='#772200';
1177: $link='#663300';
1178: $vlink='#666600';
1179: } elsif ($function eq 'coordinator') {
1180: $img='coordinator';
1181: $pgbg='#CCFFFF';
1182: $tabbg='#CCCCFF';
1183: $font='#000044';
1184: $link='#003333';
1185: $vlink='#006633';
1186: } elsif ($function eq 'author') {
1187: $img='author';
1188: $pgbg='#CCFFFF';
1189: $tabbg='#CCFFCC';
1190: $font='#004400';
1191: $link='#003333';
1192: $vlink='#006666';
1193: } else {
1194: $img='student';
1195: $pgbg='#FFFFAA';
1196: $tabbg='#FF9900';
1197: $font='#991100';
1198: $link='#993300';
1199: $vlink='#996600';
1200: }
1201: # role and realm
1202: my ($role,$realm)
1203: =&Apache::lonnet::plaintext((split(/\./,$ENV{'request.role'}))[0]);
1204: # realm
1205: if ($ENV{'request.course.id'}) {
1206: $realm=
1207: $ENV{'course.'.$ENV{'request.course.id'}.'.description'};
1208: }
1209: unless ($realm) { $realm=' '; }
1210: # Set messages
1211: my $messages=localtime();
1212: # Output
1213: return(<<ENDBODY);
1214: <body bgcolor="$pgbg" text="$font" alink="$alink" vlink="$vlink" link="$link"
1215: $addentries>
1216: <table width="100%" cellspacing="0" border="0" cellpadding="0">
1217: <tr><td bgcolor="$font">
1218: <img src="/adm/lonInterFace/$img.jpg" /></td>
1219: <td bgcolor="$font"><font color='$pgbg'>$messages</font></td>
1220: </tr>
1221: <tr>
1222: <td rowspan="3" bgcolor="$tabbg">
1223: <font size="5"><b>$title</b></font>
1224: <td bgcolor="$tabbg" align="right">
1225: <font size="2">
1226: $ENV{'environment.firstname'}
1227: $ENV{'environment.middlename'}
1228: $ENV{'environment.lastname'}
1229: $ENV{'environment.generation'}
1230: </font>
1231: </td>
1232: </tr>
1233: <tr><td bgcolor="$tabbg" align="right">
1234: <font size="2">$role</font>
1235: </td></tr>
1236: <tr>
1237: <td bgcolor="$tabbg" align="right"><font size="2">$realm</font> </td></tr>
1238: </table><br>
1239: ENDBODY
1240: }
1241: ###############################################
1242:
1243: sub get_unprocessed_cgi {
1244: my ($query,$possible_names)= @_;
1245: # $Apache::lonxml::debug=1;
1246: foreach (split(/&/,$query)) {
1247: my ($name, $value) = split(/=/,$_);
1248: $name = &Apache::lonnet::unescape($name);
1249: if (!defined($possible_names) || (grep {$_ eq $name} @$possible_names)) {
1250: $value =~ tr/+/ /;
1251: $value =~ s/%([a-fA-F0-9][a-fA-F0-9])/pack("C",hex($1))/eg;
1252: &Apache::lonxml::debug("Seting :$name: to :$value:");
1253: unless (defined($ENV{'form.'.$name})) { &add_to_env('form.'.$name,$value) };
1254: }
1255: }
1256: }
1257:
1258: sub cacheheader {
1259: unless ($ENV{'request.method'} eq 'GET') { return ''; }
1260: my $date=strftime("%a, %d %b %Y %H:%M:%S GMT",gmtime);
1261: my $output .='<meta HTTP-EQUIV="Expires" CONTENT="'.$date.'" />
1262: <meta HTTP-EQUIV="Cache-control" CONTENT="no-cache" />
1263: <meta HTTP-EQUIV="Pragma" CONTENT="no-cache" />';
1264: return $output;
1265: }
1266:
1267: sub no_cache {
1268: my ($r) = @_;
1269: unless ($ENV{'request.method'} eq 'GET') { return ''; }
1270: #my $date=strftime("%a, %d %b %Y %H:%M:%S GMT",gmtime);
1271: $r->no_cache(1);
1272: $r->header_out("Pragma" => "no-cache");
1273: #$r->header_out("Expires" => $date);
1274: }
1275:
1276: sub add_to_env {
1277: my ($name,$value)=@_;
1278: if (defined($ENV{$name})) {
1279: if (ref($ENV{$name})) {
1280: #already have multiple values
1281: push(@{ $ENV{$name} },$value);
1282: } else {
1283: #first time seeing multiple values, convert hash entry to an arrayref
1284: my $first=$ENV{$name};
1285: undef($ENV{$name});
1286: push(@{ $ENV{$name} },$first,$value);
1287: }
1288: } else {
1289: $ENV{$name}=$value;
1290: }
1291: }
1292:
1293: =pod
1294:
1295: =back
1296:
1297: =head2 CSV Upload/Handling functions
1298:
1299: =over 4
1300:
1301: =item upfile_store($r)
1302:
1303: Store uploaded file, $r should be the HTTP Request object,
1304: needs $ENV{'form.upfile'}
1305: returns $datatoken to be put into hidden field
1306:
1307: =cut
1308:
1309: sub upfile_store {
1310: my $r=shift;
1311: $ENV{'form.upfile'}=~s/\r/\n/gs;
1312: $ENV{'form.upfile'}=~s/\f/\n/gs;
1313: $ENV{'form.upfile'}=~s/\n+/\n/gs;
1314: $ENV{'form.upfile'}=~s/\n+$//gs;
1315:
1316: my $datatoken=$ENV{'user.name'}.'_'.$ENV{'user.domain'}.
1317: '_enroll_'.$ENV{'request.course.id'}.'_'.time.'_'.$$;
1318: {
1319: my $fh=Apache::File->new('>'.$r->dir_config('lonDaemons').
1320: '/tmp/'.$datatoken.'.tmp');
1321: print $fh $ENV{'form.upfile'};
1322: }
1323: return $datatoken;
1324: }
1325:
1326: =pod
1327:
1328: =item load_tmp_file($r)
1329:
1330: Load uploaded file from tmp, $r should be the HTTP Request object,
1331: needs $ENV{'form.datatoken'},
1332: sets $ENV{'form.upfile'} to the contents of the file
1333:
1334: =cut
1335:
1336: sub load_tmp_file {
1337: my $r=shift;
1338: my @studentdata=();
1339: {
1340: my $fh;
1341: if ($fh=Apache::File->new($r->dir_config('lonDaemons').
1342: '/tmp/'.$ENV{'form.datatoken'}.'.tmp')) {
1343: @studentdata=<$fh>;
1344: }
1345: }
1346: $ENV{'form.upfile'}=join('',@studentdata);
1347: }
1348:
1349: =pod
1350:
1351: =item upfile_record_sep()
1352:
1353: Separate uploaded file into records
1354: returns array of records,
1355: needs $ENV{'form.upfile'} and $ENV{'form.upfiletype'}
1356:
1357: =cut
1358:
1359: sub upfile_record_sep {
1360: if ($ENV{'form.upfiletype'} eq 'xml') {
1361: } else {
1362: return split(/\n/,$ENV{'form.upfile'});
1363: }
1364: }
1365:
1366: =pod
1367:
1368: =item record_sep($record)
1369:
1370: Separate a record into fields $record should be an item from the upfile_record_sep(), needs $ENV{'form.upfiletype'}
1371:
1372: =cut
1373:
1374: sub record_sep {
1375: my $record=shift;
1376: my %components=();
1377: if ($ENV{'form.upfiletype'} eq 'xml') {
1378: } elsif ($ENV{'form.upfiletype'} eq 'space') {
1379: my $i=0;
1380: foreach (split(/\s+/,$record)) {
1381: my $field=$_;
1382: $field=~s/^(\"|\')//;
1383: $field=~s/(\"|\')$//;
1384: $components{$i}=$field;
1385: $i++;
1386: }
1387: } elsif ($ENV{'form.upfiletype'} eq 'tab') {
1388: my $i=0;
1389: foreach (split(/\t+/,$record)) {
1390: my $field=$_;
1391: $field=~s/^(\"|\')//;
1392: $field=~s/(\"|\')$//;
1393: $components{$i}=$field;
1394: $i++;
1395: }
1396: } else {
1397: my @allfields=split(/\,/,$record);
1398: my $i=0;
1399: my $j;
1400: for ($j=0;$j<=$#allfields;$j++) {
1401: my $field=$allfields[$j];
1402: if ($field=~/^\s*(\"|\')/) {
1403: my $delimiter=$1;
1404: while (($field!~/$delimiter$/) && ($j<$#allfields)) {
1405: $j++;
1406: $field.=','.$allfields[$j];
1407: }
1408: $field=~s/^\s*$delimiter//;
1409: $field=~s/$delimiter\s*$//;
1410: }
1411: $components{$i}=$field;
1412: $i++;
1413: }
1414: }
1415: return %components;
1416: }
1417:
1418: =pod
1419:
1420: =item upfile_select_html()
1421:
1422: return HTML code to select file and specify its type
1423:
1424: =cut
1425:
1426: sub upfile_select_html {
1427: return (<<'ENDUPFORM');
1428: <input type="file" name="upfile" size="50" />
1429: <br />Type: <select name="upfiletype">
1430: <option value="csv">CSV (comma separated values, spreadsheet)</option>
1431: <option value="space">Space separated</option>
1432: <option value="tab">Tabulator separated</option>
1433: <option value="xml">HTML/XML</option>
1434: </select>
1435: ENDUPFORM
1436: }
1437:
1438: =pod
1439:
1440: =item csv_print_samples($r,$records)
1441:
1442: Prints a table of sample values from each column uploaded $r is an
1443: Apache Request ref, $records is an arrayref from
1444: &Apache::loncommon::upfile_record_sep
1445:
1446: =cut
1447:
1448: sub csv_print_samples {
1449: my ($r,$records) = @_;
1450: my (%sone,%stwo,%sthree);
1451: %sone=&record_sep($$records[0]);
1452: if (defined($$records[1])) {%stwo=&record_sep($$records[1]);}
1453: if (defined($$records[2])) {%sthree=&record_sep($$records[2]);}
1454:
1455: $r->print('Samples<br /><table border="2"><tr>');
1456: foreach (sort({$a <=> $b} keys(%sone))) { $r->print('<th>Column '.($_+1).'</th>'); }
1457: $r->print('</tr>');
1458: foreach my $hash (\%sone,\%stwo,\%sthree) {
1459: $r->print('<tr>');
1460: foreach (sort({$a <=> $b} keys(%sone))) {
1461: $r->print('<td>');
1462: if (defined($$hash{$_})) { $r->print($$hash{$_}); }
1463: $r->print('</td>');
1464: }
1465: $r->print('</tr>');
1466: }
1467: $r->print('</tr></table><br />'."\n");
1468: }
1469:
1470: =pod
1471:
1472: =item csv_print_select_table($r,$records,$d)
1473:
1474: Prints a table to create associations between values and table columns.
1475: $r is an Apache Request ref,
1476: $records is an arrayref from &Apache::loncommon::upfile_record_sep,
1477: $d is an array of 2 element arrays (internal name, displayed name)
1478:
1479: =cut
1480:
1481: sub csv_print_select_table {
1482: my ($r,$records,$d) = @_;
1483: my $i=0;my %sone;
1484: %sone=&record_sep($$records[0]);
1485: $r->print('Associate columns with student attributes.'."\n".
1486: '<table border="2"><tr><th>Attribute</th><th>Column</th></tr>'."\n");
1487: foreach (@$d) {
1488: my ($value,$display)=@{ $_ };
1489: $r->print('<tr><td>'.$display.'</td>');
1490:
1491: $r->print('<td><select name=f'.$i.
1492: ' onchange="javascript:flip(this.form,'.$i.');">');
1493: $r->print('<option value="none"></option>');
1494: foreach (sort({$a <=> $b} keys(%sone))) {
1495: $r->print('<option value="'.$_.'">Column '.($_+1).'</option>');
1496: }
1497: $r->print('</select></td></tr>'."\n");
1498: $i++;
1499: }
1500: $i--;
1501: return $i;
1502: }
1503:
1504: =pod
1505:
1506: =item csv_samples_select_table($r,$records,$d)
1507:
1508: Prints a table of sample values from the upload and can make associate samples to internal names.
1509:
1510: $r is an Apache Request ref,
1511: $records is an arrayref from &Apache::loncommon::upfile_record_sep,
1512: $d is an array of 2 element arrays (internal name, displayed name)
1513:
1514: =cut
1515:
1516: sub csv_samples_select_table {
1517: my ($r,$records,$d) = @_;
1518: my %sone; my %stwo; my %sthree;
1519: my $i=0;
1520:
1521: $r->print('<table border=2><tr><th>Field</th><th>Samples</th></tr>');
1522: %sone=&record_sep($$records[0]);
1523: if (defined($$records[1])) {%stwo=&record_sep($$records[1]);}
1524: if (defined($$records[2])) {%sthree=&record_sep($$records[2]);}
1525:
1526: foreach (sort keys %sone) {
1527: $r->print('<tr><td><select name=f'.$i.
1528: ' onchange="javascript:flip(this.form,'.$i.');">');
1529: foreach (@$d) {
1530: my ($value,$display)=@{ $_ };
1531: $r->print('<option value='.$value.'>'.$display.'</option>');
1532: }
1533: $r->print('</select></td><td>');
1534: if (defined($sone{$_})) { $r->print($sone{$_}."</br>\n"); }
1535: if (defined($stwo{$_})) { $r->print($stwo{$_}."</br>\n"); }
1536: if (defined($sthree{$_})) { $r->print($sthree{$_}."</br>\n"); }
1537: $r->print('</td></tr>');
1538: $i++;
1539: }
1540: $i--;
1541: return($i);
1542: }
1543: 1;
1544: __END__;
1545:
1546: =pod
1547:
1548: =back
1549:
1550: =head2 Access .tab File Data
1551:
1552: =over 4
1553:
1554: =item languageids()
1555:
1556: returns list of all language ids
1557:
1558: =item languagedescription()
1559:
1560: returns description of a specified language id
1561:
1562: =item copyrightids()
1563:
1564: returns list of all copyrights
1565:
1566: =item copyrightdescription()
1567:
1568: returns description of a specified copyright id
1569:
1570: =item filecategories()
1571:
1572: returns list of all file categories
1573:
1574: =item filecategorytypes()
1575:
1576: returns list of file types belonging to a given file
1577: category
1578:
1579: =item fileembstyle()
1580:
1581: returns embedding style for a specified file type
1582:
1583: =item filedescription()
1584:
1585: returns description for a specified file type
1586:
1587: =item filedescriptionex()
1588:
1589: returns description for a specified file type with
1590: extra formatting
1591:
1592: =back
1593:
1594: =head2 Alternate Problem Views
1595:
1596: =over 4
1597:
1598: =item get_previous_attempt()
1599:
1600: return string with previous attempt on problem
1601:
1602: =item get_student_view()
1603:
1604: show a snapshot of what student was looking at
1605:
1606: =item get_student_answers()
1607:
1608: show a snapshot of how student was answering problem
1609:
1610: =back
1611:
1612: =head2 HTTP Helper
1613:
1614: =over 4
1615:
1616: =item get_unprocessed_cgi($query,$possible_names)
1617:
1618: Modify the %ENV hash to contain unprocessed CGI form parameters held in
1619: $query. The parameters listed in $possible_names (an array reference),
1620: will be set in $ENV{'form.name'} if they do not already exist.
1621:
1622: Typically called with $ENV{'QUERY_STRING'} as the first parameter.
1623: $possible_names is an ref to an array of form element names. As an example:
1624: get_unprocessed_cgi($ENV{'QUERY_STRING'},['uname','udom']);
1625: will result in $ENV{'form.uname'} and $ENV{'form.udom'} being set.
1626:
1627: =item cacheheader()
1628:
1629: returns cache-controlling header code
1630:
1631: =item nocache()
1632:
1633: specifies header code to not have cache
1634:
1635: =item add_to_env($name,$value)
1636:
1637: adds $name to the %ENV hash with value
1638: $value, if $name already exists, the entry is converted to an array
1639: reference and $value is added to the array.
1640:
1641: =back
1642:
1643: =cut
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>