1: # The LearningOnline Network with CAPA
2: # a pile of common html routines
3: #
4: # $Id: lonhtmlcommon.pm,v 1.109 2005/06/18 17:23:25 www Exp $
5: #
6: # Copyright Michigan State University Board of Trustees
7: #
8: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
9: #
10: # LON-CAPA is free software; you can redistribute it and/or modify
11: # it under the terms of the GNU General Public License as published by
12: # the Free Software Foundation; either version 2 of the License, or
13: # (at your option) any later version.
14: #
15: # LON-CAPA is distributed in the hope that it will be useful,
16: # but WITHOUT ANY WARRANTY; without even the implied warranty of
17: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18: # GNU General Public License for more details.
19: #
20: # You should have received a copy of the GNU General Public License
21: # along with LON-CAPA; if not, write to the Free Software
22: # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
23: #
24: # /home/httpd/html/adm/gpl.txt
25: #
26: # http://www.lon-capa.org/
27: #
28: ######################################################################
29: ######################################################################
30:
31: =pod
32:
33: =head1 NAME
34:
35: Apache::lonhtmlcommon - routines to do common html things
36:
37: =head1 SYNOPSIS
38:
39: Referenced by other mod_perl Apache modules.
40:
41: =head1 INTRODUCTION
42:
43: lonhtmlcommon is a collection of subroutines used to present information
44: in a consistent html format, or provide other functionality related to
45: html.
46:
47: =head2 General Subroutines
48:
49: =over 4
50:
51: =cut
52:
53: ######################################################################
54: ######################################################################
55:
56: package Apache::lonhtmlcommon;
57:
58: use strict;
59: use Time::Local;
60: use Time::HiRes;
61: use Apache::lonlocal;
62: use Apache::lonnet;
63:
64: ##############################################
65: ##############################################
66:
67: =pod
68:
69: =item authorbombs
70:
71: =cut
72:
73: ##############################################
74: ##############################################
75:
76: sub authorbombs {
77: my $url=shift;
78: $url=&Apache::lonnet::declutter($url);
79: my ($udom,$uname)=($url=~/^(\w+)\/(\w+)\//);
80: my %bombs=&Apache::lonmsg::all_url_author_res_msg($uname,$udom);
81: foreach (keys %bombs) {
82: if ($_=~/^$udom\/$uname\//) {
83: return '<a href="/adm/bombs/'.$url.
84: '"><img src="'.&Apache::loncommon::lonhttpdurl('/adm/lonMisc/bomb.gif').'" border="0" /></a>'.
85: &Apache::loncommon::help_open_topic('About_Bombs');
86: }
87: }
88: return '';
89: }
90:
91: ##############################################
92: ##############################################
93:
94: sub recent_filename {
95: my $area=shift;
96: return 'nohist_recent_'.&Apache::lonnet::escape($area);
97: }
98:
99: sub store_recent {
100: my ($area,$name,$value)=@_;
101: my $file=&recent_filename($area);
102: my %recent=&Apache::lonnet::dump($file);
103: if (scalar(keys(%recent))>10) {
104: # remove oldest value
105: my $oldest=time;
106: my $delkey='';
107: foreach (keys %recent) {
108: my $thistime=(split(/\&/,$recent{$_}))[0];
109: if ($thistime<$oldest) {
110: $oldest=$thistime;
111: $delkey=$_;
112: }
113: }
114: &Apache::lonnet::del($file,[$delkey]);
115: }
116: # store new value
117: &Apache::lonnet::put($file,{ $name =>
118: time.'&'.&Apache::lonnet::escape($value) });
119: }
120:
121: sub remove_recent {
122: my ($area,$names)=@_;
123: my $file=&recent_filename($area);
124: return &Apache::lonnet::del($file,$names);
125: }
126:
127: sub select_recent {
128: my ($area,$fieldname,$event)=@_;
129: my %recent=&Apache::lonnet::dump(&recent_filename($area));
130: my $return="\n<select name='$fieldname'".
131: ($event?" onchange='$event'":'').
132: ">\n<option value=''>--- ".&mt('Recent')." ---</option>";
133: foreach (sort keys %recent) {
134: unless ($_=~/^error\:/) {
135: my $escaped = &Apache::loncommon::escape_url($_);
136: $return.="\n<option value='$escaped'>".
137: &Apache::lonnet::unescape((split(/\&/,$recent{$_}))[1]).
138: '</option>';
139: }
140: }
141: $return.="\n</select>\n";
142: return $return;
143: }
144:
145: sub get_recent {
146: my ($area, $n) = @_;
147: my %recent=&Apache::lonnet::dump(&recent_filename($area));
148:
149: # Create hash with key as time and recent as value
150: my %time_hash = ();
151: foreach (keys %recent) {
152: my $thistime=(split(/\&/,$recent{$_}))[0];
153: $time_hash{$thistime} = $_;
154: }
155:
156: # Sort by decreasing time and return key value pairs
157: my %return_hash = ();
158: my $idx = 1;
159: foreach (reverse sort keys %time_hash) {
160: $return_hash{$time_hash{$_}} =
161: &Apache::lonnet::unescape((split(/\&/,$recent{$_}))[1]);
162: if ($n && ($idx++ >= $n)) {last;}
163: }
164:
165: return %return_hash;
166: }
167:
168:
169:
170: =pod
171:
172: =item textbox
173:
174: =cut
175:
176: ##############################################
177: ##############################################
178: sub textbox {
179: my ($name,$value,$size,$special) = @_;
180: $size = 40 if (! defined($size));
181: my $Str = '<input type="text" name="'.$name.'" size="'.$size.'" '.
182: 'value="'.$value.'" '.$special.' />';
183: return $Str;
184: }
185:
186: ##############################################
187: ##############################################
188:
189: =pod
190:
191: =item checkbox
192:
193: =cut
194:
195: ##############################################
196: ##############################################
197: sub checkbox {
198: my ($name,$checked,$value) = @_;
199: my $Str = '<input type="checkbox" name="'.$name.'" ';
200: if (defined($value)) {
201: $Str .= 'value="'.$value.'"';
202: }
203: if ($checked) {
204: $Str .= ' checked="1"';
205: }
206: $Str .= ' />';
207: return $Str;
208: }
209:
210: ##############################################
211: ##############################################
212:
213: =pod
214:
215: =item &date_setter
216:
217: &date_setter returns html and javascript for a compact date-setting form.
218: To retrieve values from it, use &get_date_from_form().
219:
220: Inputs
221:
222: =over 4
223:
224: =item $dname
225:
226: The name to prepend to the form elements.
227: The form elements defined will be dname_year, dname_month, dname_day,
228: dname_hour, dname_min, and dname_sec.
229:
230: =item $currentvalue
231:
232: The current setting for this time parameter. A unix format time
233: (time in seconds since the beginning of Jan 1st, 1970, GMT.
234: An undefined value is taken to indicate the value is the current time.
235: Also, to be explicit, a value of 'now' also indicates the current time.
236:
237: =item $special
238:
239: Additional html/javascript to be associated with each element in
240: the date_setter. See lonparmset for example usage.
241:
242: =item $includeempty
243:
244: =item $state
245:
246: Specifies the initial state of the form elements. Either 'disabled' or empty.
247: Defaults to empty, which indiciates the form elements are not disabled.
248:
249: =back
250:
251: Bugs
252:
253: The method used to restrict user input will fail in the year 2400.
254:
255: =cut
256:
257: ##############################################
258: ##############################################
259: sub date_setter {
260: my ($formname,$dname,$currentvalue,$special,$includeempty,$state,
261: $no_hh_mm_ss,$defhour,$defmin,$defsec) = @_;
262: my $wasdefined=1;
263: if (! defined($state) || $state ne 'disabled') {
264: $state = '';
265: }
266: if (! defined($no_hh_mm_ss)) {
267: $no_hh_mm_ss = 0;
268: }
269: if (! defined($currentvalue) || $currentvalue eq 'now') {
270: unless ($includeempty) {
271: $currentvalue = time;
272: $wasdefined=0;
273: } else {
274: $currentvalue = 0;
275: }
276: }
277: # other potentially useful values: wkday,yrday,is_daylight_savings
278: my ($sec,$min,$hour,$mday,$month,$year)=('','',undef,'','','');
279: if ($currentvalue) {
280: ($sec,$min,$hour,$mday,$month,$year,undef,undef,undef) =
281: localtime($currentvalue);
282: $year += 1900;
283: }
284: unless ($wasdefined) {
285: $sec=($defsec?$defsec:0);
286: $min=($defmin?$defmin:0);
287: $hour=($defhour?$defhour:0);
288: }
289: my $result = "\n<!-- $dname date setting form -->\n";
290: $result .= <<ENDJS;
291: <script language="Javascript">
292: function $dname\_checkday() {
293: var day = document.$formname.$dname\_day.value;
294: var month = document.$formname.$dname\_month.value;
295: var year = document.$formname.$dname\_year.value;
296: var valid = true;
297: if (day < 1) {
298: document.$formname.$dname\_day.value = 1;
299: }
300: if (day > 31) {
301: document.$formname.$dname\_day.value = 31;
302: }
303: if ((month == 1) || (month == 3) || (month == 5) ||
304: (month == 7) || (month == 8) || (month == 10) ||
305: (month == 12)) {
306: if (day > 31) {
307: document.$formname.$dname\_day.value = 31;
308: day = 31;
309: }
310: } else if (month == 2 ) {
311: if ((year % 4 == 0) && (year % 100 != 0)) {
312: if (day > 29) {
313: document.$formname.$dname\_day.value = 29;
314: }
315: } else if (day > 29) {
316: document.$formname.$dname\_day.value = 28;
317: }
318: } else if (day > 30) {
319: document.$formname.$dname\_day.value = 30;
320: }
321: }
322:
323: function $dname\_disable() {
324: document.$formname.$dname\_month.disabled=true;
325: document.$formname.$dname\_day.disabled=true;
326: document.$formname.$dname\_year.disabled=true;
327: document.$formname.$dname\_hour.disabled=true;
328: document.$formname.$dname\_minute.disabled=true;
329: document.$formname.$dname\_second.disabled=true;
330: }
331:
332: function $dname\_enable() {
333: document.$formname.$dname\_month.disabled=false;
334: document.$formname.$dname\_day.disabled=false;
335: document.$formname.$dname\_year.disabled=false;
336: document.$formname.$dname\_hour.disabled=false;
337: document.$formname.$dname\_minute.disabled=false;
338: document.$formname.$dname\_second.disabled=false;
339: }
340:
341: function $dname\_opencalendar() {
342: if (! document.$formname.$dname\_month.disabled) {
343: var calwin=window.open(
344: "/adm/announcements?pickdate=yes&formname=$formname&element=$dname&month="+
345: document.$formname.$dname\_month.value+"&year="+
346: document.$formname.$dname\_year.value,
347: "LONCAPAcal",
348: "height=350,width=350,scrollbars=yes,resizable=yes,menubar=no");
349: }
350:
351: }
352: </script>
353: ENDJS
354: $result .= ' <nobr>';
355: my $monthselector = qq{<select name="$dname\_month" $special $state onchange="javascript:$dname\_checkday()" >};
356: # Month
357: my @Months = qw/January February March April May June
358: July August September October November December/;
359: # Pad @Months with a bogus value to make indexing easier
360: unshift(@Months,'If you can read this an error occurred');
361: if ($includeempty) { $monthselector.="<option value=''></option>"; }
362: for(my $m = 1;$m <=$#Months;$m++) {
363: $monthselector .= qq{ <option value="$m" };
364: $monthselector .= "selected " if ($m-1 eq $month);
365: $monthselector .= '> '.&mt($Months[$m]).' </option>';
366: }
367: $monthselector.= ' </select>';
368: # Day
369: my $dayselector = qq{<input type="text" name="$dname\_day" $state value="$mday" size="3" $special onchange="javascript:$dname\_checkday()" />};
370: # Year
371: my $yearselector = qq{<input type="year" name="$dname\_year" $state value="$year" size="5" $special onchange="javascript:$dname\_checkday()" />};
372: #
373: my $hourselector = qq{<select name="$dname\_hour" $special $state >};
374: if ($includeempty) {
375: $hourselector.=qq{<option value=''></option>};
376: }
377: for (my $h = 0;$h<24;$h++) {
378: $hourselector .= qq{<option value="$h" };
379: $hourselector .= "selected " if (defined($hour) && $hour == $h);
380: $hourselector .= ">";
381: my $timest='';
382: if ($h == 0) {
383: $timest .= "12 am";
384: } elsif($h == 12) {
385: $timest .= "12 noon";
386: } elsif($h < 12) {
387: $timest .= "$h am";
388: } else {
389: $timest .= $h-12 ." pm";
390: }
391: $timest=&mt($timest);
392: $hourselector .= $timest." </option>\n";
393: }
394: $hourselector .= " </select>\n";
395: my $minuteselector = qq{<input type="text" name="$dname\_minute" $special $state value="$min" size="3" />};
396: my $secondselector= qq{<input type="text" name="$dname\_second" $special $state value="$sec" size="3" />};
397: my $cal_link = qq{<a href="javascript:$dname\_opencalendar()">};
398: #
399: if ($no_hh_mm_ss) {
400: $result .= &mt('[_1] [_2] [_3] [_4]Select Date[_5]',
401: $monthselector,$dayselector,$yearselector,
402: $cal_link,'</a>');
403: } else {
404: $result .= &mt('[_1] [_2] [_3] [_4] [_5]m [_6]s [_7]Select Date[_8]',
405: $monthselector,$dayselector,$yearselector,
406: $hourselector,$minuteselector,$secondselector,
407: $cal_link,'</a>');
408: }
409: $result .= "</nobr>\n<!-- end $dname date setting form -->\n";
410: return $result;
411: }
412:
413: ##############################################
414: ##############################################
415:
416: =pod
417:
418: =item &get_date_from_form
419:
420: get_date_from_form retrieves the date specified in an &date_setter form.
421:
422: Inputs:
423:
424: =over 4
425:
426: =item $dname
427:
428: The name passed to &datesetter, which prefixes the form elements.
429:
430: =item $defaulttime
431:
432: The unix time to use as the default in case of poor inputs.
433:
434: =back
435:
436: Returns: Unix time represented in the form.
437:
438: =cut
439:
440: ##############################################
441: ##############################################
442: sub get_date_from_form {
443: my ($dname) = @_;
444: my ($sec,$min,$hour,$day,$month,$year);
445: #
446: if (defined($env{'form.'.$dname.'_second'})) {
447: my $tmpsec = $env{'form.'.$dname.'_second'};
448: if (($tmpsec =~ /^\d+$/) && ($tmpsec >= 0) && ($tmpsec < 60)) {
449: $sec = $tmpsec;
450: }
451: if (!defined($tmpsec) || $tmpsec eq '') { $sec = 0; }
452: } else {
453: $sec = 0;
454: }
455: if (defined($env{'form.'.$dname.'_minute'})) {
456: my $tmpmin = $env{'form.'.$dname.'_minute'};
457: if (($tmpmin =~ /^\d+$/) && ($tmpmin >= 0) && ($tmpmin < 60)) {
458: $min = $tmpmin;
459: }
460: if (!defined($tmpmin) || $tmpmin eq '') { $min = 0; }
461: } else {
462: $min = 0;
463: }
464: if (defined($env{'form.'.$dname.'_hour'})) {
465: my $tmphour = $env{'form.'.$dname.'_hour'};
466: if (($tmphour =~ /^\d+$/) && ($tmphour >= 0) && ($tmphour < 24)) {
467: $hour = $tmphour;
468: }
469: } else {
470: $hour = 0;
471: }
472: if (defined($env{'form.'.$dname.'_day'})) {
473: my $tmpday = $env{'form.'.$dname.'_day'};
474: if (($tmpday =~ /^\d+$/) && ($tmpday > 0) && ($tmpday < 32)) {
475: $day = $tmpday;
476: }
477: }
478: if (defined($env{'form.'.$dname.'_month'})) {
479: my $tmpmonth = $env{'form.'.$dname.'_month'};
480: if (($tmpmonth =~ /^\d+$/) && ($tmpmonth > 0) && ($tmpmonth < 13)) {
481: $month = $tmpmonth - 1;
482: }
483: }
484: if (defined($env{'form.'.$dname.'_year'})) {
485: my $tmpyear = $env{'form.'.$dname.'_year'};
486: if (($tmpyear =~ /^\d+$/) && ($tmpyear > 1900)) {
487: $year = $tmpyear - 1900;
488: }
489: }
490: if (($year<70) || ($year>137)) { return undef; }
491: if (defined($sec) && defined($min) && defined($hour) &&
492: defined($day) && defined($month) && defined($year) &&
493: eval(&timelocal($sec,$min,$hour,$day,$month,$year))) {
494: return &timelocal($sec,$min,$hour,$day,$month,$year);
495: } else {
496: return undef;
497: }
498: }
499:
500: ##############################################
501: ##############################################
502:
503: =pod
504:
505: =item &pjump_javascript_definition()
506:
507: Returns javascript defining the 'pjump' function, which opens up a
508: parameter setting wizard.
509:
510: =cut
511:
512: ##############################################
513: ##############################################
514: sub pjump_javascript_definition {
515: my $Str = <<END;
516: function pjump(type,dis,value,marker,ret,call,hour,min,sec) {
517: parmwin=window.open("/adm/rat/parameter.html?type="+escape(type)
518: +"&value="+escape(value)+"&marker="+escape(marker)
519: +"&return="+escape(ret)
520: +"&call="+escape(call)+"&name="+escape(dis)
521: +"&defhour="+escape(hour)+"&defmin="+escape(min)
522: +"&defsec="+escape(sec),"LONCAPAparms",
523: "height=350,width=350,scrollbars=no,menubar=no");
524: }
525: END
526: return $Str;
527: }
528:
529: ##############################################
530: ##############################################
531:
532: =pod
533:
534: =item &javascript_nothing()
535:
536: Return an appropriate null for the users browser. This is used
537: as the first arguement for window.open calls when you want a blank
538: window that you can then write to.
539:
540: =cut
541:
542: ##############################################
543: ##############################################
544: sub javascript_nothing {
545: # mozilla and other browsers work with "''", but IE on mac does not.
546: my $nothing = "''";
547: my $user_browser;
548: my $user_os;
549: $user_browser = $env{'browser.type'} if (exists($env{'browser.type'}));
550: $user_os = $env{'browser.os'} if (exists($env{'browser.os'}));
551: if (! defined($user_browser) || ! defined($user_os)) {
552: (undef,$user_browser,undef,undef,undef,$user_os) =
553: &Apache::loncommon::decode_user_agent();
554: }
555: if ($user_browser eq 'explorer' && $user_os =~ 'mac') {
556: $nothing = "'javascript:void(0);'";
557: }
558: return $nothing;
559: }
560:
561: ##############################################
562: ##############################################
563: sub javascript_docopen {
564: # safari does not understand document.open() and loads "text/html"
565: my $nothing = "''";
566: my $user_browser;
567: my $user_os;
568: $user_browser = $env{'browser.type'} if (exists($env{'browser.type'}));
569: $user_os = $env{'browser.os'} if (exists($env{'browser.os'}));
570: if (! defined($user_browser) || ! defined($user_os)) {
571: (undef,$user_browser,undef,undef,undef,$user_os) =
572: &Apache::loncommon::decode_user_agent();
573: }
574: if ($user_browser eq 'safari' && $user_os =~ 'mac') {
575: $nothing = "document.clear()";
576: } else {
577: $nothing = "document.open('text/html','replace')";
578: }
579: return $nothing;
580: }
581:
582:
583: ##############################################
584: ##############################################
585:
586: =pod
587:
588: =item &StatusOptions()
589:
590: Returns html for a selection box which allows the user to choose the
591: enrollment status of students. The selection box name is 'Status'.
592:
593: Inputs:
594:
595: $status: the currently selected status. If undefined the value of
596: $env{'form.Status'} is taken. If that is undefined, a value of 'Active'
597: is used.
598:
599: $formname: The name of the form. If defined the onchange attribute of
600: the selection box is set to document.$formname.submit().
601:
602: $size: the size (number of lines) of the selection box.
603:
604: $onchange: javascript to use when the value is changed. Enclosed in
605: double quotes, ""s, not single quotes.
606:
607: Returns: a perl string as described.
608:
609: =cut
610:
611: ##############################################
612: ##############################################
613: sub StatusOptions {
614: my ($status, $formName,$size,$onchange)=@_;
615: $size = 1 if (!defined($size));
616: if (! defined($status)) {
617: $status = 'Active';
618: $status = $env{'form.Status'} if (exists($env{'form.Status'}));
619: }
620:
621: my $OpSel1 = '';
622: my $OpSel2 = '';
623: my $OpSel3 = '';
624:
625: if($status eq 'Any') { $OpSel3 = ' selected'; }
626: elsif($status eq 'Expired' ) { $OpSel2 = ' selected'; }
627: else { $OpSel1 = ' selected'; }
628:
629: my $Str = '';
630: $Str .= '<select name="Status"';
631: if(defined($formName) && $formName ne '' && ! defined($onchange)) {
632: $Str .= ' onchange="document.'.$formName.'.submit()"';
633: }
634: if (defined($onchange)) {
635: $Str .= ' onchange="'.$onchange.'"';
636: }
637: $Str .= ' size="'.$size.'" ';
638: $Str .= '>'."\n";
639: $Str .= '<option value="Active" '.$OpSel1.'>'.
640: &mt('Currently Enrolled').'</option>'."\n";
641: $Str .= '<option value="Expired" '.$OpSel2.'>'.
642: &mt('Previously Enrolled').'</option>'."\n";
643: $Str .= '<option value="Any" '.$OpSel3.'>'.
644: &mt('Any Enrollment Status').'</option>'."\n";
645: $Str .= '</select>'."\n";
646: }
647:
648: ########################################################
649: ########################################################
650:
651: =pod
652:
653: =item Progess Window Handling Routines
654:
655: These routines handle the creation, update, increment, and closure of
656: progress windows. The progress window reports to the user the number
657: of items completed and an estimate of the time required to complete the rest.
658:
659: =over 4
660:
661:
662: =item &Create_PrgWin
663:
664: Writes javascript to the client to open a progress window and returns a
665: data structure used for bookkeeping.
666:
667: Inputs
668:
669: =over 4
670:
671: =item $r Apache request
672:
673: =item $title The title of the progress window
674:
675: =item $heading A description (usually 1 line) of the process being initiated.
676:
677: =item $number_to_do The total number of items being processed.
678:
679: =item $type Either 'popup' or 'inline' (popup is assumed if nothing is
680: specified)
681:
682: =item $width Specify the width in charaters of the input field.
683:
684: =item $formname Only useful in the inline case, if a form already exists, this needs to be used and specfiy the name of the form, otherwise the Progress line will be created in a new form of it's own
685:
686: =item $inputname Only useful in the inline case, if a form and an input of type text exists, use this to specify the name of the input field
687:
688: =back
689:
690: Returns a hash containing the progress state data structure.
691:
692:
693: =item &Update_PrgWin
694:
695: Updates the text in the progress indicator. Does not increment the count.
696: See &Increment_PrgWin.
697:
698: Inputs:
699:
700: =over 4
701:
702: =item $r Apache request
703:
704: =item $prog_state Pointer to the data structure returned by &Create_PrgWin
705:
706: =item $displaystring The string to write to the status indicator
707:
708: =back
709:
710: Returns: none
711:
712:
713: =item Increment_PrgWin
714:
715: Increment the count of items completed for the progress window by 1.
716:
717: Inputs:
718:
719: =over 4
720:
721: =item $r Apache request
722:
723: =item $prog_state Pointer to the data structure returned by Create_PrgWin
724:
725: =item $extraInfo A description of the items being iterated over. Typically
726: 'student'.
727:
728: =back
729:
730: Returns: none
731:
732:
733: =item Close_PrgWin
734:
735: Closes the progress window.
736:
737: Inputs:
738:
739: =over 4
740:
741: =item $r Apache request
742:
743: =item $prog_state Pointer to the data structure returned by Create_PrgWin
744:
745: =back
746:
747: Returns: none
748:
749: =back
750:
751: =cut
752:
753: ########################################################
754: ########################################################
755:
756: my $uniq=0;
757: sub get_uniq_name {
758: $uniq++;
759: return 'uniquename'.$uniq;
760: }
761:
762: # Create progress
763: sub Create_PrgWin {
764: my ($r, $title, $heading, $number_to_do,$type,$width,$formname,
765: $inputname)=@_;
766: if (!defined($type)) { $type='popup'; }
767: if (!defined($width)) { $width=55; }
768: my %prog_state;
769: $prog_state{'type'}=$type;
770: if ($type eq 'popup') {
771: $prog_state{'window'}='popwin';
772: my $html=&Apache::lonxml::xmlbegin();
773: #the whole function called through timeout is due to issues
774: #in mozilla Read BUG #2665 if you want to know the whole story
775: &r_print($r,'<script>'.
776: "var popwin;
777: function openpopwin () {
778: popwin=open(\'\',\'popwin\',\'width=400,height=100\');".
779: "popwin.document.writeln(\'".$html."<head><title>$title</title></head>".
780: "<body bgcolor=\"#88DDFF\">".
781: "<h4>$heading</h4>".
782: "<form name=popremain>".
783: '<input type="text" size="'.$width.'" name="remaining" value="'.
784: &mt('Starting').'"></form>'.
785: "</body></html>\');".
786: "popwin.document.close();}".
787: "\nwindow.setTimeout(openpopwin,0)</script>");
788: $prog_state{'formname'}='popremain';
789: $prog_state{'inputname'}="remaining";
790: } elsif ($type eq 'inline') {
791: $prog_state{'window'}='window';
792: if (!$formname) {
793: $prog_state{'formname'}=&get_uniq_name();
794: &r_print($r,'<form name="'.$prog_state{'formname'}.'">');
795: } else {
796: $prog_state{'formname'}=$formname;
797: }
798: if (!$inputname) {
799: $prog_state{'inputname'}=&get_uniq_name();
800: &r_print($r,$heading.' <input type="text" name="'.$prog_state{'inputname'}.
801: '" size="'.$width.'" />');
802: } else {
803: $prog_state{'inputname'}=$inputname;
804:
805: }
806: if (!$formname) { &r_print($r,'</form>'); }
807: &Update_PrgWin($r,\%prog_state,&mt('Starting'));
808: }
809:
810: $prog_state{'done'}=0;
811: $prog_state{'firststart'}=&Time::HiRes::time();
812: $prog_state{'laststart'}=&Time::HiRes::time();
813: $prog_state{'max'}=$number_to_do;
814:
815: return %prog_state;
816: }
817:
818: # update progress
819: sub Update_PrgWin {
820: my ($r,$prog_state,$displayString)=@_;
821: &r_print($r,'<script>'.$$prog_state{'window'}.'.document.'.
822: $$prog_state{'formname'}.'.'.
823: $$prog_state{'inputname'}.'.value="'.
824: $displayString.'";</script>');
825: $$prog_state{'laststart'}=&Time::HiRes::time();
826: }
827:
828: # increment progress state
829: sub Increment_PrgWin {
830: my ($r,$prog_state,$extraInfo)=@_;
831: $$prog_state{'done'}++;
832: my $time_est= (&Time::HiRes::time() - $$prog_state{'firststart'})/
833: $$prog_state{'done'} *
834: ($$prog_state{'max'}-$$prog_state{'done'});
835: $time_est = int($time_est);
836: #
837: my $min = int($time_est/60);
838: my $sec = $time_est % 60;
839: #
840: my $str;
841: if ($min == 0 && $sec > 1) {
842: $str = '[_2] seconds';
843: } elsif ($min == 1 && $sec > 1) {
844: $str = '1 minute [_2] seconds';
845: } elsif ($min == 1 && $sec < 2) {
846: $str = '1 minute';
847: } elsif ($min < 10 && $sec > 1) {
848: $str = '[_1] minutes, [_2] seconds';
849: } elsif ($min >= 10 || $sec < 2) {
850: $str = '[_1] minutes';
851: }
852: $time_est = &mt($str,$min,$sec);
853: #
854: my $lasttime = &Time::HiRes::time()-$$prog_state{'laststart'};
855: if ($lasttime > 9) {
856: $lasttime = int($lasttime);
857: } elsif ($lasttime < 0.01) {
858: $lasttime = 0;
859: } else {
860: $lasttime = sprintf("%3.2f",$lasttime);
861: }
862: if ($lasttime == 1) {
863: $lasttime = '('.$lasttime.' '.&mt('second for').' '.$extraInfo.')';
864: } else {
865: $lasttime = '('.$lasttime.' '.&mt('seconds for').' '.$extraInfo.')';
866: }
867: #
868: my $user_browser = $env{'browser.type'} if (exists($env{'browser.type'}));
869: my $user_os = $env{'browser.os'} if (exists($env{'browser.os'}));
870: if (! defined($user_browser) || ! defined($user_os)) {
871: (undef,$user_browser,undef,undef,undef,$user_os) =
872: &Apache::loncommon::decode_user_agent();
873: }
874: if ($user_browser eq 'explorer' && $user_os =~ 'mac') {
875: $lasttime = '';
876: }
877: &r_print($r,'<script>'.$$prog_state{'window'}.'.document.'.
878: $$prog_state{'formname'}.'.'.
879: $$prog_state{'inputname'}.'.value="'.
880: $$prog_state{'done'}.'/'.$$prog_state{'max'}.
881: ': '.$time_est.' '.&mt('remaining').' '.$lasttime.'";'.'</script>');
882: $$prog_state{'laststart'}=&Time::HiRes::time();
883: }
884:
885: # close Progress Line
886: sub Close_PrgWin {
887: my ($r,$prog_state)=@_;
888: if ($$prog_state{'type'} eq 'popup') {
889: &r_print($r,'<script>popwin.close()</script>'."\n");
890: } elsif ($$prog_state{'type'} eq 'inline') {
891: &Update_PrgWin($r,$prog_state,&mt('Done'));
892: }
893: undef(%$prog_state);
894: }
895:
896: sub r_print {
897: my ($r,$to_print)=@_;
898: if ($r) {
899: $r->print($to_print);
900: $r->rflush();
901: } else {
902: print($to_print);
903: }
904: }
905:
906: # ------------------------------------------------------- Puts directory header
907:
908: sub crumbs {
909: my ($uri,$target,$prefix,$form,$size,$noformat)=@_;
910: if (! defined($size)) {
911: $size = '+2';
912: }
913: if ($target) {
914: $target = ' target="'.
915: &Apache::loncommon::escape_single($target).'"';
916: }
917: my $output='';
918: unless ($noformat) { $output.='<br /><tt><b>'; }
919: $output.='<font size="'.$size.'">'.$prefix.'/';
920: if ($env{'user.adv'}) {
921: my $path=$prefix.'/';
922: foreach my $dir (split('/',$uri)) {
923: if (! $dir) { next; }
924: $path .= $dir;
925: unless ($path eq $uri) { $path.='/'; }
926: my $linkpath = &Apache::loncommon::escape_single($path);
927: if ($form) {
928: $linkpath=
929: qq{javascript:$form.action='$linkpath';$form.submit();};
930: }
931: $output.=qq{<a href="$linkpath" $target>$dir</a>/};
932: }
933: } else {
934: $output.=$uri;
935: }
936: unless ($uri=~/\/$/) { $output=~s/\/$//; }
937: return $output.'</font>'.($noformat?'':'</b></tt><br />');
938: }
939:
940: # --------------------- A function that generates a window for the spellchecker
941:
942: sub spellheader {
943: my $html=&Apache::lonxml::xmlbegin();
944: my $nothing=&javascript_nothing();
945: return (<<ENDCHECK);
946: <script type="text/javascript">
947: //<!-- BEGIN LON-CAPA Internal
948: var checkwin;
949:
950: function spellcheckerwindow() {
951: checkwin=window.open($nothing,'spellcheckwin','height=320,width=280,resizable=yes,scrollbars=yes,location=no,menubar=no,toolbar=no');
952: checkwin.document.writeln('$html<head></head><body bgcolor="#DDDDDD"><form name="spellcheckform" action="/adm/spellcheck" method="post"><input type="hidden" name="text" value="" /></form></body></html>');
953: checkwin.document.close();
954: }
955: // END LON-CAPA Internal -->
956: </script>
957: ENDCHECK
958: }
959:
960: # ---------------------------------- Generate link to spell checker for a field
961:
962: sub spelllink {
963: my ($form,$field)=@_;
964: my $linktext=&mt('Check Spelling');
965: return (<<ENDLINK);
966: <a href="javascript:if (typeof(document.$form.onsubmit)!='undefined') { if (document.$form.onsubmit!=null) { document.$form.onsubmit();}};spellcheckerwindow();checkwin.document.forms.spellcheckform.text.value=this.document.forms.$form.$field.value;checkwin.document.forms.spellcheckform.submit();">$linktext</a>
967: ENDLINK
968: }
969:
970: # ------------------------------------------------- Output headers for HTMLArea
971:
972: sub htmlareaheaders {
973: if (&htmlareablocked()) { return ''; }
974: unless (&htmlareabrowser()) { return ''; }
975: my $lang='en';
976: if (&mt('htmlarea_lang') ne 'htmlarea_lang') {
977: $lang=&mt('htmlarea_lang');
978: }
979: return (<<ENDHEADERS);
980: <script type="text/javascript">
981: _editor_url='/htmlarea/';
982: _editor_lang='$lang';
983: </script>
984: <script type="text/javascript" src="/htmlarea/htmlarea.js"></script>
985: ENDHEADERS
986: }
987:
988: # ------------------------------------------------- Activate additional buttons
989:
990: sub htmlareaaddbuttons {
991: if (&htmlareablocked()) { return ''; }
992: unless (&htmlareabrowser()) { return ''; }
993: return (<<ENDADDBUTTON);
994: var config=new HTMLArea.Config();
995: config.registerButton('ed_math','LaTeX Inline',
996: '/htmlarea/images/ed_math.gif',false,
997: function(editor,id) {
998: editor.surroundHTML(' <m>\$','\$</m> ');
999: }
1000: );
1001: config.registerButton('ed_math_eqn','LaTeX Equation',
1002: '/htmlarea/images/ed_math_eqn.gif',false,
1003: function(editor,id) {
1004: editor.surroundHTML(
1005: ' \\n<center><m>\\\\[','\\\\]</m></center>\\n ');
1006: }
1007: );
1008: config.toolbar.push(['ed_math','ed_math_eqn']);
1009: ENDADDBUTTON
1010: }
1011:
1012: # ----------------------------------------------------------------- Preferences
1013:
1014: sub disablelink {
1015: my @fields=@_;
1016: if (defined($#fields)) {
1017: unless ($#fields>=0) { return ''; }
1018: }
1019: return '<a href="'.&HTML::Entities::encode('/adm/preferences?action=set_wysiwyg&wysiwyg=off&returnurl=','<>&"').&Apache::lonnet::escape($ENV{'REQUEST_URI'}).'">'.&mt('Disable WYSIWYG Editor').'</a>';
1020: }
1021:
1022: sub enablelink {
1023: my @fields=@_;
1024: if (defined($#fields)) {
1025: unless ($#fields>=0) { return ''; }
1026: }
1027: return '<a href="'.&HTML::Entities::encode('/adm/preferences?action=set_wysiwyg&wysiwyg=on&returnurl=','<>&"').&Apache::lonnet::escape($ENV{'REQUEST_URI'}).'">'.&mt('Enable WYSIWYG Editor').'</a>';
1028: }
1029:
1030: # ----------------------------------------- Script to activate only some fields
1031:
1032: sub htmlareaselectactive {
1033: my @fields=@_;
1034: unless (&htmlareabrowser()) { return ''; }
1035: if (&htmlareablocked()) { return '<br />'.&enablelink(@fields); }
1036: my $output='<script type="text/javascript" defer="1">'.
1037: &htmlareaaddbuttons();
1038: foreach(@fields) {
1039: $output.="\nHTMLArea.replace('$_',config);";
1040: }
1041: $output.="\nwindow.status='Activated Editfields';\n</script><br />".
1042: &disablelink(@fields);
1043: return $output;
1044: }
1045:
1046: # --------------------------------------------------------------------- Blocked
1047:
1048: sub htmlareablocked {
1049: unless ($env{'environment.wysiwygeditor'} eq 'on') { return 1; }
1050: return 0;
1051: }
1052:
1053: # ---------------------------------------- Browser capable of running HTMLArea?
1054:
1055: sub htmlareabrowser {
1056: return 1;
1057: }
1058:
1059: ############################################################
1060: ############################################################
1061:
1062: =pod
1063:
1064: =item breadcrumbs
1065:
1066: Compiles the previously registered breadcrumbs into an series of links.
1067: FAQ and BUG links will be placed on the left side of the table if they
1068: are defined for the last registered breadcrumb.
1069: Additionally supports a 'component', which will be displayed on the
1070: right side of the table (without a link).
1071: A link to help for the component will be included if one is specified.
1072:
1073: All inputs can be undef without problems.
1074:
1075: Inputs: $color (the background color of the table returned),
1076: $component (the large text on the right side of the table),
1077: $component_help
1078: $function (role to get colors from)
1079: $domain (domian of role)
1080: $menulink (boolean, controls whether to include a link to /adm/menu)
1081:
1082: Returns a string containing breadcrumbs for the current page.
1083:
1084: =item clear_breadcrumbs
1085:
1086: Clears the previously stored breadcrumbs.
1087:
1088: =item add_breadcrumb
1089:
1090: Pushes a breadcrumb on the stack of crumbs.
1091:
1092: input: $breadcrumb, a hash reference. The keys 'href','title', and 'text'
1093: are required. If present the keys 'faq' and 'bug' will be used to provide
1094: links to the FAQ and bug sites.
1095:
1096: returns: nothing
1097:
1098: =cut
1099:
1100: ############################################################
1101: ############################################################
1102: {
1103: my @Crumbs;
1104:
1105: sub breadcrumbs {
1106: my ($color,$component,$component_help,$function,$domain,$menulink,
1107: $helplink) = @_;
1108: if (! defined($color)) {
1109: if (! defined($function)) {
1110: $function = &Apache::loncommon::get_users_function();
1111: }
1112: $color = &Apache::loncommon::designparm($function.'.tabbg',
1113: $domain);
1114: }
1115: #
1116: my $Str = "\n".
1117: '<table width="100%" border="0" cellpadding="0" cellspacing="0">'.
1118: '<tr><td bgcolor="'.$color.'">'.
1119: '<font size="-1">';
1120: #
1121: # Make the faq and bug data cascade
1122: my $faq = '';
1123: my $bug = '';
1124: my $help='';
1125: # The last breadcrumb does not have a link, so handle it separately.
1126: my $last = pop(@Crumbs);
1127: #
1128: # The first one should be the course or a menu link
1129: if (!defined($menulink)) { $menulink=1; }
1130: if ($menulink) {
1131: my $description = 'Menu';
1132: if (exists($env{'request.course.id'}) &&
1133: $env{'request.course.id'} ne '') {
1134: $description =
1135: $env{'course.'.$env{'request.course.id'}.'.description'};
1136: }
1137: unshift(@Crumbs,{
1138: href =>'/adm/menu',
1139: title =>'Go to main menu',
1140: target =>'_top',
1141: text =>$description,
1142: });
1143: }
1144: my $links .=
1145: join('->',
1146: map {
1147: $faq = $_->{'faq'} if (exists($_->{'faq'}));
1148: $bug = $_->{'bug'} if (exists($_->{'bug'}));
1149: $help = $_->{'help'} if (exists($_->{'help'}));
1150: my $result = '<a href="'.$_->{'href'}.'" ';
1151: if (defined($_->{'target'}) && $_->{'target'} ne '') {
1152: $result .= 'target="'.$_->{'target'}.'" ';
1153: }
1154: $result .='title="'.&mt($_->{'title'}).'">'.
1155: &mt($_->{'text'}).'</a>';
1156: $result;
1157: } @Crumbs
1158: );
1159: $links .= '->' if ($links ne '');
1160: $links .= '<b>'.&mt($last->{'text'}).'</b>';
1161: #
1162: my $icons = '';
1163: $faq = $last->{'faq'} if (exists($last->{'faq'}));
1164: $bug = $last->{'bug'} if (exists($last->{'bug'}));
1165: $help = $last->{'help'} if (exists($last->{'help'}));
1166: $component_help=($component_help?$component_help:$help);
1167: # if ($faq ne '') {
1168: # $icons .= &Apache::loncommon::help_open_faq($faq);
1169: # }
1170: # if ($bug ne '') {
1171: # $icons .= &Apache::loncommon::help_open_bug($bug);
1172: # }
1173: if ($helplink ne 'nohelp') {
1174: $icons .= &Apache::loncommon::help_open_menu($color,$component,$component_help,$function,$faq,$bug);
1175: }
1176: if ($icons ne '') {
1177: $Str .= $icons.' ';
1178: }
1179: #
1180: $Str .= $links.'</font></td>';
1181: #
1182: if (defined($component)) {
1183: $Str .= '<td align="right" bgcolor="'.$color.'">'.
1184: '<font size="+1">'.&mt($component).'</font></td>';
1185: }
1186: $Str .= '</tr></table>'."\n";
1187: #
1188: # Return the @Crumbs stack to what we started with
1189: push(@Crumbs,$last);
1190: shift(@Crumbs);
1191: #
1192: return $Str;
1193: }
1194:
1195: sub clear_breadcrumbs {
1196: undef(@Crumbs);
1197: }
1198:
1199: sub add_breadcrumb {
1200: push (@Crumbs,@_);
1201: }
1202:
1203: } # End of scope for @Crumbs
1204:
1205: ############################################################
1206: ############################################################
1207:
1208:
1209: 1;
1210:
1211: __END__
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>