1: # The LearningOnline Network with CAPA
2: # Routines for messaging
3: #
4: # $Id: lonmsg.pm,v 1.243 2015/07/21 21:26:32 raeburn Exp $
5: #
6: # Copyright Michigan State University Board of Trustees
7: #
8: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
9: #
10: # LON-CAPA is free software; you can redistribute it and/or modify
11: # it under the terms of the GNU General Public License as published by
12: # the Free Software Foundation; either version 2 of the License, or
13: # (at your option) any later version.
14: #
15: # LON-CAPA is distributed in the hope that it will be useful,
16: # but WITHOUT ANY WARRANTY; without even the implied warranty of
17: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18: # GNU General Public License for more details.
19: #
20: # You should have received a copy of the GNU General Public License
21: # along with LON-CAPA; if not, write to the Free Software
22: # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
23: #
24: # /home/httpd/html/adm/gpl.txt
25: #
26: # http://www.lon-capa.org/
27: #
28:
29: package Apache::lonmsg;
30:
31: =pod
32:
33: =head1 NAME
34:
35: Apache::lonmsg: supports internal messaging
36:
37: =head1 SYNOPSIS
38:
39: lonmsg provides routines for sending messages.
40:
41: Right now, this document will cover just how to send a message, since
42: it is likely you will not need to programmatically read messages,
43: since lonmsg already implements that functionality.
44:
45: The routines used to package messages and unpackage messages are not
46: only used by lonmsg when creating/extracting messages for LON-CAPA's
47: internal messaging system, but also by lonnotify.pm which is available
48: for use by Domain Coordinators to broadcast standard e-mail to specified
49: users in their domain. The XML packaging used in the two cases is very
50: similar. The differences are the use of <recuser>$uname</recuser> and
51: <recdomain>$udom</recdomain> in stored internal messages, compared
52: with <recipient username="$uname:$udom">$email</recipient> in stored
53: Domain Coordinator e-mail for the storage of information about
54: recipients of the message/e-mail.
55:
56: =head1 SUBROUTINES
57:
58: =over
59:
60: =pod
61:
62: =item packagemsg()
63:
64: Package
65:
66: =item get_course_context()
67:
68: =item unpackagemsg()
69:
70: Unpack message into a hash
71:
72: =item buildmsgid()
73:
74: Get info out of msgid
75:
76: =item unpackmsgid()
77:
78: =item sendemail()
79:
80: =item sendnotification()
81:
82: Send notification emails
83:
84: =item newmail()
85:
86: Check for email
87:
88: =item author_res_msg()
89:
90: Automated message to the author of a resource
91:
92: =item * B<author_res_msg($filename, $message)>: Sends message $message to the owner
93: of the resource with the URI $filename.
94:
95: =item retrieve_author_res_msg()
96:
97: Retrieve author resource messages
98:
99: =item del_url_author_res_msg()
100:
101: Delete all author messages related to one URL
102:
103: =item clear_author_res_msg()
104:
105: Clear out all author messages in URL path
106:
107: =item all_url_author_res_msg()
108:
109: Return hash with URLs for which there is a resource message
110:
111: =item store_instructor_comment()
112:
113: Add a comment to the User Notes screen
114:
115: =item user_crit_msg_raw()
116:
117: Critical message to a user
118:
119: =item user_crit_msg()
120:
121: New routine that respects "forward" and calls old routine
122:
123: =item * B<user_crit_msg($user, $domain, $subject, $message, $sendback, $nosentstore, $recipid, $attachmenturl, $permresults)>:
124: Sends a critical message $message to the $user at $domain. If $sendback
125: is true, a receipt will be sent to the current user when $user receives
126: the message.
127:
128: Additionally it will check if the user has a Forwarding address
129: set, and send the message to that address instead
130:
131: returns
132: - in array context a list of results for each message that was sent
133: - in scalar context a space seperated list of results for each
134: message sent
135:
136:
137: =item user_crit_received()
138:
139: Critical message received
140:
141: =item user_normal_msg_raw()
142:
143: Normal communication
144:
145: =item user_normal_msg()
146:
147: New routine that respects "forward" and calls old routine
148:
149: =item * B<user_normal_msg($user, $domain, $subject, $message, $citation,
150: $baseurl, $attachmenturl, $toperm, $sentmessage, $symb, $restitle,
151: $error,$nosentstore,$recipid,$permresults)>:
152: Sends a message to the $user at $domain, with subject $subject and message $message.
153:
154: Additionally it will check if the user has a Forwarding address
155: set, and send the message to that address instead
156:
157: returns
158: - in array context a list of results for each message that was sent
159: - in scalar context a space seperated list of results for each
160: message sent
161:
162: =item store_sent_mail()
163:
164: =item store_recipients()
165:
166: =item foldersuffix()
167:
168: =item get_user_folders()
169:
170: User-defined folders
171:
172: =item secapply()
173:
174: =item B<decide_receiver($feedurl,$author,$question,$course,$policy,$defaultflag)>:
175:
176: Arguments
177: $feedurl - /res/ url of resource (only need if $author is true)
178: $author,$question,$course,$policy - all true/false parameters
179: if true will attempt to find the addresses of user that should receive
180: this type of feedback (author - feedback to author of resource $feedurl,
181: $question 'Resource Content Questions', $course 'Course Content Question',
182: $policy 'Course Policy')
183: (Additionally it also checks $env for whether the corresponding form.<name>
184: element exists, for ease of use in a html response context)
185:
186: $defaultflag - (internal should be left blank) if true gather addresses
187: that aren't for a section even if I have a section
188: (used for reccursion internally, first we look for
189: addresses for our specific section then we recurse
190: and look for non section addresses)
191:
192: Returns
193: $typestyle - string of html text, describing what addresses were found
194: %to - a hash, which keys are addresses of users to send messages to
195: the keys will look like name:domain
196:
197: =back
198:
199: =cut
200:
201: use strict;
202: use Apache::lonnet;
203: use Apache::loncommon;
204: use HTML::TokeParser();
205: use Apache::lonlocal;
206: use HTML::Entities;
207: use Encode;
208: use LONCAPA qw(:DEFAULT :match);
209:
210: {
211: my $uniq;
212: sub get_uniq {
213: $uniq++;
214: return $uniq;
215: }
216: }
217:
218:
219:
220: sub packagemsg {
221: my ($subject,$message,$citation,$baseurl,$attachmenturl,
222: $recuser,$recdomain,$msgid,$type,$crsmsgid,$symb,$error,$recipid)=@_;
223: $message =&HTML::Entities::encode($message,'<>&"');
224: $citation=&HTML::Entities::encode($citation,'<>&"');
225: $subject =&HTML::Entities::encode($subject,'<>&"');
226: #remove machine specification
227: $baseurl =~ s|^https?://[^/]+/|/|;
228: $baseurl =&HTML::Entities::encode($baseurl,'<>&"');
229: #remove machine specification
230: $attachmenturl =~ s|^https?://[^/]+/|/|;
231: $attachmenturl =&HTML::Entities::encode($attachmenturl,'<>&"');
232: my $course_context = &get_course_context();
233: my $now=time;
234: my $msgcount = &get_uniq();
235: unless(defined($msgid)) {
236: $msgid = &buildmsgid($now,$subject,$env{'user.name'},$env{'user.domain'},
237: $msgcount,$course_context,$symb,$error,$$);
238: }
239: my $result = '<sendername>'.$env{'user.name'}.'</sendername>'.
240: '<senderdomain>'.$env{'user.domain'}.'</senderdomain>'.
241: '<subject>'.$subject.'</subject>'.
242: '<time>'.&Apache::lonlocal::locallocaltime($now).'</time>';
243: if (defined($crsmsgid)) {
244: $result.= '<courseid>'.$course_context.'</courseid>'.
245: '<coursesec>'.$env{'request.course.sec'}.'</coursesec>'.
246: '<msgid>'.$msgid.'</msgid>'.
247: '<coursemsgid>'.$crsmsgid.'</coursemsgid>'.
248: '<message>'.$message.'</message>';
249: return ($msgid,$result);
250: }
251: $result .= '<servername>'.$ENV{'SERVER_NAME'}.'</servername>'.
252: '<host>'.$ENV{'HTTP_HOST'}.'</host>'.
253: '<client>'.$ENV{'REMOTE_ADDR'}.'</client>'.
254: '<browsertype>'.$env{'browser.type'}.'</browsertype>'.
255: '<browseros>'.$env{'browser.os'}.'</browseros>'.
256: '<browserversion>'.$env{'browser.version'}.'</browserversion>'.
257: '<browsermathml>'.$env{'browser.mathml'}.'</browsermathml>'.
258: '<browserraw>'.$ENV{'HTTP_USER_AGENT'}.'</browserraw>'.
259: '<courseid>'.$course_context.'</courseid>'.
260: '<coursesec>'.$env{'request.course.sec'}.'</coursesec>'.
261: '<role>'.$env{'request.role'}.'</role>'.
262: '<resource>'.$env{'request.filename'}.'</resource>'.
263: '<msgid>'.$msgid.'</msgid>';
264: if (defined($env{'form.group'})) {
265: $result .= '<group>'.$env{'form.group'}.'</group>';
266: }
267: if (ref($recuser) eq 'ARRAY') {
268: for (my $i=0; $i<@{$recuser}; $i++) {
269: if ($type eq 'dcmail') {
270: my ($username,$email) = split(/:/,$$recuser[$i]);
271: $username = &unescape($username);
272: $email = &unescape($email);
273: $username = &HTML::Entities::encode($username,'<>&"');
274: $email = &HTML::Entities::encode($email,'<>&"');
275: $result .= '<recipient username="'.$username.'">'.
276: $email.'</recipient>';
277: } else {
278: $result .= '<recuser>'.$$recuser[$i].'</recuser>'.
279: '<recdomain>'.$$recdomain[$i].'</recdomain>';
280: }
281: }
282: } else {
283: $result .= '<recuser>'.$recuser.'</recuser>'.
284: '<recdomain>'.$recdomain.'</recdomain>';
285: }
286: $result .= '<message>'.$message.'</message>';
287: if (defined($citation)) {
288: $result.='<citation>'.$citation.'</citation>';
289: }
290: if (defined($baseurl)) {
291: $result.= '<baseurl>'.$baseurl.'</baseurl>';
292: }
293: if (defined($attachmenturl)) {
294: $result.= '<attachmenturl>'.$attachmenturl.'</attachmenturl>';
295: }
296: if (defined($symb)) {
297: $result.= '<symb>'.$symb.'</symb>';
298: if ($course_context ne '') {
299: if ($course_context eq $env{'request.course.id'}) {
300: my $resource_title = &Apache::lonnet::gettitle($symb);
301: if (defined($resource_title)) {
302: $result .= '<resource_title>'.$resource_title.'</resource_title>';
303: }
304: }
305: }
306: }
307: if (defined($recipid)) {
308: $result.= '<recipid>'.$recipid.'</recipid>';
309: }
310: if ($env{'form.can_reply'} eq 'N') {
311: $result .= '<noreplies>1</noreplies>';
312: }
313: if ($env{'form.reply_to_addr'}) {
314: my ($replytoname,$replytodom) = split(/:/,$env{'form.reply_to_addr'});
315: if (!($replytoname eq $env{'user.name'} && $replytodom eq $env{'user.domain'})) {
316: if (&Apache::lonnet::homeserver($replytoname,$replytodom) ne 'no_host') {
317: $result .= '<replytoaddr>'.$env{'form.reply_to_addr'}.'</replytoaddr>';
318: }
319: }
320: }
321: return ($msgid,$result);
322: }
323:
324: sub get_course_context {
325: my $course_context;
326: my $msgkey;
327: if (defined($env{'form.replyid'})) {
328: $msgkey = $env{'form.replyid'};
329: } elsif (defined($env{'form.forwid'})) {
330: $msgkey = $env{'form.forwid'}
331: } elsif (defined($env{'form.multiforwid'})) {
332: $msgkey = $env{'form.multiforwid'};
333: }
334: if ($msgkey ne '') {
335: my ($sendtime,$shortsubj,$fromname,$fromdomain,$count,$origcid)=
336: split(/\:/,&unescape($msgkey));
337: $course_context = $origcid;
338: }
339: foreach my $key (keys(%env)) {
340: if ($key=~/^form\.(rep)?rec\_(.*)$/) {
341: my ($sendtime,$shortsubj,$fromname,$fromdomain,$count,$origcid) =
342: split(/\:/,&unescape($2));
343: $course_context = $origcid;
344: last;
345: }
346: }
347: if ($course_context eq '') {
348: $course_context = $env{'request.course.id'};
349: }
350: return $course_context;
351: }
352:
353:
354: sub unpackagemsg {
355: my ($message,$notoken,$noattachmentlink)=@_;
356: my %content=();
357: my $parser=HTML::TokeParser->new(\$message);
358: my $token;
359: while ($token=$parser->get_token) {
360: if ($token->[0] eq 'S') {
361: my $entry=$token->[1];
362: my $value=$parser->get_text('/'.$entry);
363: if (($entry eq 'recuser') || ($entry eq 'recdomain')) {
364: push(@{$content{$entry}},$value);
365: } elsif ($entry eq 'recipient') {
366: my $username = $token->[2]{'username'};
367: $username = &HTML::Entities::decode($username,'<>&"');
368: $content{$entry}{$username} = $value;
369: } else {
370: $content{$entry}=$value;
371: }
372: }
373: }
374: if (!exists($content{'recuser'})) { $content{'recuser'} = []; }
375: if (($content{'attachmenturl'}) && (!$noattachmentlink)) {
376: my ($fname)=($content{'attachmenturl'}=~m|/([^/]+)$|);
377: if ($notoken) {
378: $content{'message'}.='<p>'.&mt('Attachment').': <tt>'.$fname.'</tt>';
379: } else {
380: &Apache::lonnet::allowuploaded('/adm/msg',
381: $content{'attachmenturl'});
382: $content{'message'}.='<p>'.&mt('Attachment').
383: ': <a href="'.$content{'attachmenturl'}.'"><tt>'.
384: $fname.'</tt></a>';
385: }
386: }
387: return %content;
388: }
389:
390:
391: sub buildmsgid {
392: my ($now,$subject,$uname,$udom,$msgcount,$course_context,$symb,$error,$pid) = @_;
393: $subject=&escape($subject);
394: $symb = &escape($symb);
395: return(&escape($now.':'.$subject.':'.$uname.':'.
396: $udom.':'.$msgcount.':'.$course_context.':'.$pid.':'.$symb.':'.$error));
397: }
398:
399: sub unpackmsgid {
400: my ($msgid,$folder,$skipstatus,$status_cache,$onlycid)=@_;
401: $msgid=&unescape($msgid);
402: my ($sendtime,$shortsubj,$fromname,$fromdomain,$count,$fromcid,
403: $processid,$symb,$error) = split(/\:/,&unescape($msgid));
404: if (!defined($processid)) { $fromcid = ''; }
405: if (($onlycid) && ($onlycid ne $fromcid)) {
406: return ($sendtime,'',$fromname,$fromdomain,'',$fromcid,'',$error);
407: }
408: $shortsubj = &unescape($shortsubj);
409: $shortsubj = &HTML::Entities::decode($shortsubj);
410: $symb = &unescape($symb);
411: my %status=();
412: unless ($skipstatus) {
413: if (ref($status_cache)) {
414: $status{$msgid} = $status_cache->{$msgid};
415: } else {
416: my $suffix=&foldersuffix($folder);
417: %status=&Apache::lonnet::get('email_status'.$suffix,[$msgid]);
418: }
419: if ($status{$msgid}=~/^error\:/) { $status{$msgid}=''; }
420: unless ($status{$msgid}) { $status{$msgid}='new'; }
421: }
422: return ($sendtime,$shortsubj,$fromname,$fromdomain,$status{$msgid},$fromcid,$symb,$error);
423: }
424:
425:
426: sub sendemail {
427: my ($to,$subject,$body,$to_uname,$to_udom,$user_lh,$attachmenturl)=@_;
428: my $senderaddress='';
429: my $replytoaddress='';
430: my $msgsent;
431: if ($env{'form.can_reply'} eq 'N') {
432: my $lonhost = $Apache::lonnet::perlvar{'lonHostID'};
433: my $hostname = &Apache::lonnet::hostname($lonhost);
434: $replytoaddress = 'do-not-reply@'.$hostname;
435: } else {
436: my %senderemails;
437: my $have_sender;
438: if ($env{'form.reply_to_addr'}) {
439: my ($replytoname,$replytodom) = split(/:/,$env{'form.reply_to_addr'});
440: if (!($replytoname eq $env{'user.name'} && $replytodom eq $env{'user.domain'})) {
441: if (&Apache::lonnet::homeserver($replytoname,$replytodom) ne 'no_host') {
442: %senderemails =
443: &Apache::loncommon::getemails($replytoname,$replytodom);
444: $have_sender = 1;
445: }
446: }
447: }
448: if (!$have_sender) {
449: %senderemails=&Apache::loncommon::getemails();
450: }
451: foreach my $type ('permanentemail','critnotification','notification') {
452: if ($senderemails{$type}) {
453: ($senderaddress) = split(/,/,$senderemails{$type});
454: last if ($senderaddress);
455: }
456: }
457: }
458: $body=
459: "*** ".&mt_user($user_lh,'This is an automatic e-mail generated by the LON-CAPA system.')."\n".
460: "*** ".($senderaddress?&mt_user($user_lh,'You can reply to this e-mail'):&mt_user($user_lh,'Please do not reply to this address.')."\n*** ".
461: &mt_user($user_lh,'A reply will not be received by the recipient!'))."\n\n".$body;
462:
463: $attachmenturl = &Apache::lonnet::filelocation("",$attachmenturl);
464: my $filesize = (stat($attachmenturl))[7];
465: if ($filesize > 1048576) {
466: # Don't send if it exceeds 1 MB.
467: print '<p><span class="LC_error">'
468: .&mt('Email not sent. Attachment exceeds permitted length.')
469: .'</span><br /></p>';
470: } else {
471: # Otherwise build and send the email
472: $subject = '[LON-CAPA] '.$subject;
473: &Apache::loncommon::mime_email($senderaddress, $to, $subject, $body, ,'',
474: '', $attachmenturl, '', '');
475: $msgsent = 1;
476: }
477: return $msgsent;
478: }
479:
480: # ==================================================== Send notification emails
481:
482: sub sendnotification {
483: my ($to,$touname,$toudom,$subj,$crit,$text,$msgid,$attachmenturl)=@_;
484: my $sender=$env{'environment.firstname'}.' '.$env{'environment.lastname'};
485: unless ($sender=~/\w/) {
486: $sender=$env{'user.name'}.':'.$env{'user.domain'};
487: }
488: my $critical=($crit?' critical':'');
489: my $numsent = 0;
490:
491: $text=~s/\<\;/\</gs;
492: $text=~s/\>\;/\>/gs;
493: my $homeserver = &Apache::lonnet::homeserver($touname,$toudom);
494: my $protocol = $Apache::lonnet::protocol{$homeserver};
495: $protocol = 'http' if ($protocol ne 'https');
496: my $url = $protocol.'://'.&Apache::lonnet::hostname($homeserver).
497: '/adm/email?username='.$touname.'&domain='.$toudom.
498: '&display='.&escape($msgid);
499: my ($sendtime,$shortsubj,$fromname,$fromdomain,$status,$fromcid,
500: $symb,$error) = &Apache::lonmsg::unpackmsgid($msgid);
501: my ($coursetext,$body,$bodybegin,$bodysubj,$bodyend);
502: my $user_lh = &Apache::loncommon::user_lang($touname,$toudom,$fromcid);
503: if ($fromcid ne '') {
504: $coursetext = "\n".&mt_user($user_lh,'Course').': ';
505: if ($env{'course.'.$fromcid.'.description'} ne '') {
506: $coursetext .= $env{'course.'.$fromcid.'.description'};
507: } else {
508: my %coursehash = &Apache::lonnet::coursedescription($fromcid,);
509: if ($coursehash{'description'} ne '') {
510: $coursetext .= $coursehash{'description'};
511: }
512: }
513: $coursetext .= "\n\n";
514: }
515: my @recipients = split(/,/,$to);
516: $bodybegin = $coursetext.
517: &mt_user($user_lh,
518: 'You received a'.$critical.' message from [_1] in LON-CAPA.',$sender).' ';
519: $bodysubj = &mt_user($user_lh,'The subject is
520:
521: [_1]
522:
523: ',$subj)."\n".
524: '=== '.&mt_user($user_lh,'Excerpt')." ============================================================
525: ";
526: $bodyend = "
527: ========================================================================
528:
529: ".&mt_user($user_lh,'Use
530:
531: [_1]
532:
533: to access the full message.',$url);
534: my %userenv = &Apache::lonnet::get('environment',['notifywithhtml'],$toudom,$touname);
535: my $subject = &mt_user($user_lh,"'New'$critical message from [_1]",$sender);
536: unless ($subj eq '') {
537: $subject = $subj;
538: }
539:
540: my ($blocked,$blocktext);
541: if (!$crit) {
542: my %setters;
543: my ($startblock,$endblock) =
544: &Apache::loncommon::blockcheck(\%setters,'com',$touname,$toudom);
545: if ($startblock && $endblock) {
546: $blocked = 1;
547: my $showstart = &Apache::lonlocal::locallocaltime($startblock);
548: my $showend = &Apache::lonlocal::locallocaltime($endblock);
549: $blocktext = &mt_user($user_lh,'LON-CAPA messages sent to you between [_1] and [_2] will be inaccessible until the end of this time period, because you are a student in a course with an active communications block.',$showstart,$showend);
550: }
551: }
552: if ($userenv{'notifywithhtml'} ne '') {
553: my @htmlexcerpt = split(/,/,$userenv{'notifywithhtml'});
554: my $htmlfree = &make_htmlfree($text);
555: foreach my $addr (@recipients) {
556: if ($blocked) {
557: $body = $bodybegin."\n".$blocktext."\n".$bodyend;
558: } else {
559: my $sendtext;
560: if (!grep/^\Q$addr\E/,@htmlexcerpt) {
561: $sendtext = $htmlfree;
562: } else {
563: $sendtext = $text;
564: }
565: $body = $bodybegin.$bodysubj.$sendtext.$bodyend;
566: }
567: if (&sendemail($addr,$subject,$body,$touname,$toudom,$user_lh,$attachmenturl)) {
568: $numsent ++;
569: }
570: }
571: } else {
572: if ($blocked) {
573: $body = $bodybegin."\n".$blocktext."\n".$bodyend;
574: } else {
575: my $htmlfree = &make_htmlfree($text);
576: $body = $bodybegin.$bodysubj.$htmlfree.$bodyend;
577: }
578: if (&sendemail($to,$subject,$body,$touname,$toudom,$user_lh,$attachmenturl)) {
579: $numsent ++;
580: }
581: }
582: return $numsent;
583: }
584:
585: sub make_htmlfree {
586: my ($text) = @_;
587: $text =~ s/\<\/*[^\>]+\>//gs;
588: $text = &HTML::Entities::decode($text);
589: $text = &Encode::encode('utf8',$text);
590: return $text;
591: }
592:
593: sub mynewmail{
594: &newmail();
595: return $env{'user.mailcheck.lastnewmessagetime'} > $env{'user.mailcheck.lastvisit'};
596: }
597:
598:
599: sub newmail {
600: if ((time-$env{'user.mailcheck.time'})>300) {
601: my %what=&Apache::lonnet::get('email_status',['recnewemail']);
602: &Apache::lonnet::appenv({'user.mailcheck.time'=>time});
603: &Apache::lonnet::appenv({'user.mailcheck.lastnewmessagetime'=> $what{'recnewemail'}});
604: if ($what{'recnewemail'}>0) { return 1; }
605: }
606: return 0;
607: }
608:
609:
610:
611: sub author_res_msg {
612: my ($filename,$message)=@_;
613: unless ($message) { return 'empty'; }
614: $filename=&Apache::lonnet::declutter($filename);
615: my ($domain,$author,@dummy)=split(/\//,$filename);
616: my $homeserver=&Apache::lonnet::homeserver($author,$domain);
617: if ($homeserver ne 'no_host') {
618: my $id=unpack("%32C*",$message);
619: $message .= " <p>This error occurred on machine ".
620: $Apache::lonnet::perlvar{'lonHostID'}."</p>";
621: my $msgid;
622: ($msgid,$message)=&packagemsg($filename,$message);
623: return &Apache::lonnet::reply('put:'.$domain.':'.$author.
624: ':nohist_res_msgs:'.
625: &escape($filename.'_'.$id).'='.
626: &escape($message),$homeserver);
627: }
628: return 'no_host';
629: }
630:
631:
632:
633: sub retrieve_author_res_msg {
634: my $url=shift;
635: $url=&Apache::lonnet::declutter($url);
636: my ($domain,$author)=($url=~/^($match_domain)\/($match_username)\//);
637: my %errormsgs=&Apache::lonnet::dump('nohist_res_msgs',$domain,$author);
638: my $msgs='';
639: foreach my $msg (keys(%errormsgs)) {
640: if ($msg =~ /^\Q$url\E\_\d+$/) {
641: my %content=&unpackagemsg($errormsgs{$msg});
642: $msgs.='<p><img src="/adm/lonMisc/bomb.gif" /><b>'.
643: $content{'time'}.'</b>: '.$content{'message'}.
644: '<br /></p>';
645: }
646: }
647: return $msgs;
648: }
649:
650:
651:
652:
653:
654: sub del_url_author_res_msg {
655: my $url=shift;
656: $url=&Apache::lonnet::declutter($url);
657: my ($domain,$author)=($url=~/^($match_domain)\/($match_username)\//);
658: my @delmsgs=();
659: foreach my $msg (&Apache::lonnet::getkeys('nohist_res_msgs',$domain,$author)) {
660: if ($msg =~ /^\Q$url\E\_\d+$/) {
661: push (@delmsgs,$msg);
662: }
663: }
664: return &Apache::lonnet::del('nohist_res_msgs',\@delmsgs,$domain,$author);
665: }
666:
667:
668: sub clear_author_res_msg {
669: my $url=shift;
670: $url=&Apache::lonnet::declutter($url);
671: my ($domain,$author)=($url=~/^($match_domain)\/($match_username)\//);
672: my @delmsgs=();
673: foreach my $msg (&Apache::lonnet::getkeys('nohist_res_msgs',$domain,$author)) {
674: if ($msg =~ /^\Q$url\E/) {
675: push (@delmsgs,$msg);
676: }
677: }
678: return &Apache::lonnet::del('nohist_res_msgs',\@delmsgs,$domain,$author);
679: }
680:
681:
682:
683: sub all_url_author_res_msg {
684: my ($author,$domain)=@_;
685: my %returnhash=();
686: foreach my $msg (&Apache::lonnet::getkeys('nohist_res_msgs',$domain,$author)) {
687: $msg =~ /^(.+)\_\d+/;
688: $returnhash{$1}=1;
689: }
690: return %returnhash;
691: }
692:
693:
694: sub store_instructor_comment {
695: my ($msg,$uname,$udom) = @_;
696: my $cid = $env{'request.course.id'};
697: my $cnum = $env{'course.'.$cid.'.num'};
698: my $cdom = $env{'course.'.$cid.'.domain'};
699: my $subject= &mt('Record').' ['.$uname.':'.$udom.']';
700: my $result = &user_normal_msg_raw($cnum,$cdom,$subject,$msg);
701: if ($result eq 'ok' || $result eq 'con_delayed') {
702:
703: }
704: return $result;
705: }
706:
707:
708: sub user_crit_msg_raw {
709: my ($user,$domain,$subject,$message,$sendback,$toperm,$sentmessage,
710: $nosentstore,$recipid,$attachmenturl,$permresults)=@_;
711: # Check if allowed missing
712: my ($status,$packed_message);
713: my $msgid='undefined';
714: unless (($message)&&($user)&&($domain)) { $status='empty'; };
715: my $text=$message;
716: my $homeserver=&Apache::lonnet::homeserver($user,$domain);
717: if ($homeserver ne 'no_host') {
718: ($msgid,$packed_message)=&packagemsg($subject,$message,undef,undef,
719: $attachmenturl,undef,undef,undef,undef,undef,
720: undef,undef,$recipid);
721: if ($sendback) { $packed_message.='<sendback>true</sendback>'; }
722: $status=&Apache::lonnet::cput('critical', {$msgid => $packed_message},
723: $domain,$user);
724: if (defined($sentmessage)) {
725: $$sentmessage = $packed_message;
726: }
727: if (!$nosentstore) {
728: (undef,my $packed_message_no_citation) =
729: &packagemsg($subject,$message,undef,undef,$attachmenturl,$user,
730: $domain,$msgid);
731: if ($status eq 'ok' || $status eq 'con_delayed') {
732: &store_sent_mail($msgid,$packed_message_no_citation);
733: }
734: }
735: } else {
736: $status='no_host';
737: }
738:
739: # Notifications
740: my %userenv = &Apache::loncommon::getemails($user,$domain);
741: my $critnotify = $userenv{'critnotification'};
742: my $permemail = $userenv{'permanentemail'};
743: my $numcrit = 0;
744: my $numperm = 0;
745: my $permlogmsgstatus;
746: if ($critnotify) {
747: $numcrit = &sendnotification($critnotify,$user,$domain,$subject,1,$text,$msgid,$attachmenturl);
748: }
749: if ($toperm && $permemail) {
750: if ($critnotify && $numcrit) {
751: if (grep(/^\Q$permemail\E/,split(/,/,$critnotify))) {
752: $numperm = 1;
753: }
754: }
755: unless ($numperm) {
756: $numperm = &sendnotification($permemail,$user,$domain,$subject,1,$text,$msgid,$attachmenturl);
757: }
758: }
759: if ($toperm) {
760: $permlogmsgstatus = '. Perm. email log status '.
761: &Apache::lonnet::log($env{'user.domain'},$env{'user.name'},$env{'user.home'},
762: "Perm. e-mail count $numperm for $user at $domain");
763: if (ref($permresults) eq 'HASH') {
764: $permresults->{"$user:$domain"} = $numperm;
765: }
766: }
767: # Log this
768: &Apache::lonnet::logthis(
769: 'Sending critical '.$msgid.
770: ', log status: '.
771: &Apache::lonnet::log($env{'user.domain'},$env{'user.name'},
772: $env{'user.home'},
773: 'Sending critical '.$msgid.' to '.$user.' at '.$domain.' with status '
774: .$status).$permlogmsgstatus);
775: return $status;
776: }
777:
778:
779:
780: sub user_crit_msg {
781: my ($user,$domain,$subject,$message,$sendback,$toperm,$sentmessage,
782: $nosentstore,$recipid,$attachmenturl,$permresults)=@_;
783: my @status;
784: my %userenv = &Apache::lonnet::get('environment',['msgforward'],
785: $domain,$user);
786: my $msgforward=$userenv{'msgforward'};
787: if ($msgforward) {
788: foreach my $addr (split(/\,/,$msgforward)) {
789: my ($forwuser,$forwdomain)=split(/\:/,$addr);
790: push(@status,
791: &user_crit_msg_raw($forwuser,$forwdomain,$subject,$message,
792: $sendback,$toperm,$sentmessage,$nosentstore,
793: $recipid,$attachmenturl,$permresults));
794: }
795: } else {
796: push(@status,
797: &user_crit_msg_raw($user,$domain,$subject,$message,$sendback,
798: $toperm,$sentmessage,$nosentstore,$recipid,
799: $attachmenturl,$permresults));
800: }
801: if (wantarray) {
802: return @status;
803: }
804: return join(' ',@status);
805: }
806:
807:
808: sub user_crit_received {
809: my $msgid=shift;
810: my %message=&Apache::lonnet::get('critical',[$msgid]);
811: my %contents=&unpackagemsg($message{$msgid},1);
812: my $destname = $contents{'sendername'};
813: my $destdom = $contents{'senderdomain'};
814: if ($contents{'replytoaddr'}) {
815: my ($repname,$repdom) = split(/:/,$contents{'replytoaddr'});
816: if (&Apache::lonnet::homeserver($repname,$repdom) ne 'no_host') {
817: $destname = $repname;
818: $destdom = $repdom;
819: }
820: }
821: my $status='rec: '.($contents{'sendback'}?
822: &user_normal_msg($destname,$destdom,&mt('Receipt').': '.$env{'user.name'}.
823: ' '.&mt('at').' '.$env{'user.domain'}.', '.
824: $contents{'subject'},&mt('User').' '.$env{'user.name'}.
825: ' '.&mt('at').' '.$env{'user.domain'}.
826: ' acknowledged receipt of message'."\n".' "'.
827: $contents{'subject'}.'"'."\n".&mt('dated').' '.
828: $contents{'time'}.".\n"
829: ):'no msg req');
830: $status.=' trans: '.
831: &Apache::lonnet::put(
832: 'nohist_email',{$contents{'msgid'} => $message{$msgid}});
833: $status.=' del: '.
834: &Apache::lonnet::del('critical',[$contents{'msgid'}]);
835: &Apache::lonnet::log($env{'user.domain'},$env{'user.name'},
836: $env{'user.home'},'Received critical message '.
837: $contents{'msgid'}.
838: ', '.$status);
839: return $status;
840: }
841:
842:
843:
844:
845: sub user_normal_msg_raw {
846: my ($user,$domain,$subject,$message,$citation,$baseurl,$attachmenturl,
847: $toperm,$currid,$newid,$sentmessage,$crsmsgid,$symb,$restitle,
848: $error,$nosentstore,$recipid,$permresults)=@_;
849: # Check if allowed missing
850: my ($status,$packed_message);
851: my $msgid='undefined';
852: my $text=$message;
853: unless (($message)&&($user)&&($domain)) { $status='empty'; };
854: my $homeserver=&Apache::lonnet::homeserver($user,$domain);
855: if ($homeserver ne 'no_host') {
856: ($msgid,$packed_message)=
857: &packagemsg($subject,$message,$citation,$baseurl,
858: $attachmenturl,$user,$domain,$currid,
859: undef,$crsmsgid,$symb,$error,$recipid);
860:
861: # Store in user folder
862: $status=
863: &Apache::lonnet::cput('nohist_email',{$msgid => $packed_message},
864: $domain,$user);
865: # Save new message received time
866: &Apache::lonnet::put
867: ('email_status',{'recnewemail'=>time},$domain,$user);
868: # Into sent-mail folder if sent mail storage required
869: if (!$nosentstore) {
870: (undef,my $packed_message_no_citation) =
871: &packagemsg($subject,$message,undef,$baseurl,$attachmenturl,
872: $user,$domain,$currid,undef,$crsmsgid,$symb,$error);
873: if ($status eq 'ok' || $status eq 'con_delayed') {
874: &store_sent_mail($msgid,$packed_message_no_citation);
875: }
876: }
877: if (ref($newid) eq 'SCALAR') {
878: $$newid = $msgid;
879: }
880: if (ref($sentmessage) eq 'SCALAR') {
881: $$sentmessage = $packed_message;
882: }
883: # Notifications
884: my %userenv = &Apache::loncommon::getemails($user,$domain);
885: my $notify = $userenv{'notification'};
886: my $permemail = $userenv{'permanentemail'};
887: my $numnotify = 0;
888: my $numperm = 0;
889: my $permlogmsgstatus;
890: if ($notify) {
891: $numnotify = &sendnotification($notify,$user,$domain,$subject,0,$text,$msgid,$attachmenturl);
892: }
893: if ($toperm && $permemail) {
894: if ($notify && $numnotify) {
895: if (grep(/^\Q$permemail\E/,split(/,/,$notify))) {
896: $numperm = 1;
897: }
898: }
899: unless ($numperm) {
900: $numperm = &sendnotification($permemail,$user,$domain,$subject,0,
901: $text,$msgid,$attachmenturl);
902: }
903: }
904: if ($toperm) {
905: $permlogmsgstatus = '. Perm. email log status '.
906: &Apache::lonnet::log($env{'user.domain'},$env{'user.name'},$env{'user.home'},
907: "Perm. e-mail count $numperm for $user at $domain");
908: if (ref($permresults) eq 'HASH') {
909: $permresults->{"$user:$domain"} = $numperm;
910: }
911: }
912: &Apache::lonnet::log($env{'user.domain'},$env{'user.name'},
913: $env{'user.home'},
914: 'Sending '.$msgid.' to '.$user.' at '.$domain.' with status '.$status.
915: $permlogmsgstatus);
916: } else {
917: $status='no_host';
918: }
919: return $status;
920: }
921:
922: sub user_normal_msg {
923: my ($user,$domain,$subject,$message,$citation,$baseurl,$attachmenturl,
924: $toperm,$sentmessage,$symb,$restitle,$error,$nosentstore,$recipid,
925: $permresults)=@_;
926: my @status;
927: my %userenv = &Apache::lonnet::get('environment',['msgforward'],
928: $domain,$user);
929: my $msgforward=$userenv{'msgforward'};
930: if ($msgforward) {
931: foreach my $fwd (split(/\,/,$msgforward)) {
932: my ($forwuser,$forwdomain)=split(/\:/,$fwd);
933: push(@status,
934: &user_normal_msg_raw($forwuser,$forwdomain,$subject,$message,
935: $citation,$baseurl,$attachmenturl,$toperm,
936: undef,undef,$sentmessage,undef,$symb,
937: $restitle,$error,$nosentstore,$recipid,$permresults));
938: }
939: } else {
940: push(@status,&user_normal_msg_raw($user,$domain,$subject,$message,
941: $citation,$baseurl,$attachmenturl,$toperm,
942: undef,undef,$sentmessage,undef,$symb,
943: $restitle,$error,$nosentstore,$recipid,$permresults));
944: }
945: if (wantarray) {
946: return @status;
947: }
948: return join(' ',@status);
949: }
950:
951: sub process_sent_mail {
952: my ($msgsubj,$subj_prefix,$numsent,$stamp,$msgname,$msgdom,$msgcount,
953: $context,$pid,$savemsg,$recusers,$recudoms,$baseurl,$attachmenturl,
954: $symb,$error,$senderuname,$senderdom,$recipid) = @_;
955: my $sentsubj;
956: if ($numsent > 1) {
957: $sentsubj = $subj_prefix.' ('.$numsent.' sent) '.$msgsubj;
958: } else {
959: if ($subj_prefix) {
960: $sentsubj = $subj_prefix.' ';
961: }
962: $sentsubj .= $msgsubj;
963: }
964: $sentsubj = &HTML::Entities::encode($sentsubj,'<>&"');
965: my $sentmsgid =
966: &buildmsgid($stamp,$sentsubj,$msgname,$msgdom,$msgcount,$context,$pid);
967: (undef,my $sentmessage) =
968: &packagemsg($msgsubj,$savemsg,undef,$baseurl,$attachmenturl,$recusers,
969: $recudoms,$sentmsgid,undef,undef,$symb,$error,$recipid);
970: my $status = &store_sent_mail($sentmsgid,$sentmessage,$senderuname,
971: $senderdom);
972: return $status;
973: }
974:
975: sub store_sent_mail {
976: my ($msgid,$message,$senderuname,$senderdom) = @_;
977: if ($senderuname eq '') {
978: $senderuname = $env{'user.name'};
979: }
980: if ($senderdom eq '') {
981: $senderdom = $env{'user.domain'};
982: }
983: my $status =' '.&Apache::lonnet::cput('nohist_email_sent',
984: {$msgid => $message},
985: $senderdom,$senderuname);
986: return $status;
987: }
988:
989: sub store_recipients {
990: my ($subject,$sendername,$senderdom,$reciphash) = @_;
991: my $context = &get_course_context();
992: my $now = time();
993: my $msgcount = &get_uniq();
994: my $recipid =
995: &buildmsgid($now,$subject,$sendername,$senderdom,$msgcount,$context,$$);
996: my %recipinfo = (
997: $recipid => $reciphash,
998: );
999: my $status = &Apache::lonnet::put('nohist_emailrecip',\%recipinfo,
1000: $senderdom,$sendername);
1001: if ($status eq 'ok') {
1002: return ($recipid,$status);
1003: } else {
1004: return (undef,$status);
1005: }
1006: }
1007:
1008:
1009: sub foldersuffix {
1010: my $folder=shift;
1011: unless ($folder) { return ''; }
1012: my $suffix;
1013: my %folderhash = &get_user_folders($folder);
1014: if (ref($folderhash{$folder}) eq 'HASH') {
1015: $suffix = '_'.&escape($folderhash{$folder}{'id'});
1016: } else {
1017: $suffix = '_'.&escape($folder);
1018: }
1019: return $suffix;
1020: }
1021:
1022:
1023: sub get_user_folders {
1024: my ($folder) = @_;
1025: my %userfolders =
1026: &Apache::lonnet::dump('email_folders',undef,undef,$folder);
1027: my $lock = "\0".'lock_counter'; # locks db while counter incremented
1028: my $counter = "\0".'idcount'; # used in suffix for email db files
1029: if (defined($userfolders{$lock})) {
1030: delete($userfolders{$lock});
1031: }
1032: if (defined($userfolders{$counter})) {
1033: delete($userfolders{$counter});
1034: }
1035: return %userfolders;
1036: }
1037:
1038: sub secapply {
1039: my $rec=shift;
1040: my $defaultflag=shift;
1041: $rec=~s/\s+//g;
1042: unless ($rec =~ /\:/) {
1043: $rec=~s/\@/\:/g;
1044: }
1045: my ($adr,$sections_or_groups)=($rec=~/^([^\(]+)\(([^\)]+)\)/);
1046: if ($sections_or_groups) {
1047: foreach my $item (split(/\;/,$sections_or_groups)) {
1048: if (($item eq $env{'request.course.sec'}) ||
1049: ($defaultflag && ($item eq '*'))) {
1050: return $adr;
1051: } elsif ($env{'request.course.groups'}) {
1052: my @usersgroups = split(/:/,$env{'request.course.groups'});
1053: if (grep(/^\Q$item\E$/,@usersgroups)) {
1054: return $adr;
1055: }
1056: }
1057: }
1058: } else {
1059: return $rec;
1060: }
1061: return '';
1062: }
1063:
1064: sub decide_receiver {
1065: my ($feedurl,$author,$question,$course,$policy,$defaultflag) = @_;
1066: &Apache::lonenc::check_decrypt(\$feedurl);
1067: my $typestyle='';
1068: my %to=();
1069: if ($env{'form.discuss'} eq 'author' ||$author) {
1070: $typestyle.='Submitting as Author Feedback<br />';
1071: $feedurl=~ m{^/res/($LONCAPA::domain_re)/($LONCAPA::username_re)/};
1072: $to{$2.':'.$1}=1;
1073: }
1074: my $cid = $env{'request.course.id'};
1075: if ($env{'form.discuss'} eq 'question' ||$question) {
1076: $typestyle.=&mt('Submitting as Question').'<br />';
1077: foreach my $item (split(/\,/,$env{'course.'.$cid.'.question.email'})) {
1078: my $rec=&secapply($item,$defaultflag);
1079: if ($rec) { $to{$rec}=1; }
1080: }
1081: }
1082: if ($env{'form.discuss'} eq 'course' ||$course) {
1083: $typestyle.=&mt('Submitting as Comment').'<br />';
1084: foreach my $item (split(/\,/,$env{'course.'.$cid.'.comment.email'})) {
1085: my $rec=&secapply($item,$defaultflag);
1086: if ($rec) { $to{$rec}=1; }
1087: }
1088: }
1089: if ($env{'form.discuss'} eq 'policy' ||$policy) {
1090: $typestyle.=&mt('Submitting as Policy Feedback').'<br />';
1091: foreach my $item (split(/\,/,$env{'course.'.$cid.'.policy.email'})) {
1092: my $rec=&secapply($item,$defaultflag);
1093: if ($rec) { $to{$rec}=1; }
1094: }
1095: }
1096: if ((scalar(%to) eq '0') && (!$defaultflag)) {
1097: ($typestyle,%to)=
1098: &decide_receiver($feedurl,$author,$question,$course,$policy,1);
1099: }
1100: return ($typestyle,%to);
1101: }
1102:
1103: 1;
1104: __END__
1105:
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>