1: # The LearningOnline Network with CAPA
2: # Routines for messaging
3: #
4: # $Id: lonmsg.pm,v 1.239.2.5 2024/02/08 03:09:10 raeburn Exp $
5: #
6: # Copyright Michigan State University Board of Trustees
7: #
8: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
9: #
10: # LON-CAPA is free software; you can redistribute it and/or modify
11: # it under the terms of the GNU General Public License as published by
12: # the Free Software Foundation; either version 2 of the License, or
13: # (at your option) any later version.
14: #
15: # LON-CAPA is distributed in the hope that it will be useful,
16: # but WITHOUT ANY WARRANTY; without even the implied warranty of
17: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18: # GNU General Public License for more details.
19: #
20: # You should have received a copy of the GNU General Public License
21: # along with LON-CAPA; if not, write to the Free Software
22: # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
23: #
24: # /home/httpd/html/adm/gpl.txt
25: #
26: # http://www.lon-capa.org/
27: #
28:
29: package Apache::lonmsg;
30:
31: =pod
32:
33: =head1 NAME
34:
35: Apache::lonmsg: supports internal messaging
36:
37: =head1 SYNOPSIS
38:
39: lonmsg provides routines for sending messages.
40:
41: Right now, this document will cover just how to send a message, since
42: it is likely you will not need to programmatically read messages,
43: since lonmsg already implements that functionality.
44:
45: The routines used to package messages and unpackage messages are not
46: only used by lonmsg when creating/extracting messages for LON-CAPA's
47: internal messaging system, but also by lonnotify.pm which is available
48: for use by Domain Coordinators to broadcast standard e-mail to specified
49: users in their domain. The XML packaging used in the two cases is very
50: similar. The differences are the use of <recuser>$uname</recuser> and
51: <recdomain>$udom</recdomain> in stored internal messages, compared
52: with <recipient username="$uname:$udom">$email</recipient> in stored
53: Domain Coordinator e-mail for the storage of information about
54: recipients of the message/e-mail.
55:
56: =head1 SUBROUTINES
57:
58: =over
59:
60: =pod
61:
62: =item packagemsg()
63:
64: Package
65:
66: =item get_course_context()
67:
68: =item unpackagemsg()
69:
70: Unpack message into a hash
71:
72: =item buildmsgid()
73:
74: Get info out of msgid
75:
76: =item unpackmsgid()
77:
78: =item sendemail()
79:
80: =item sendnotification()
81:
82: Send notification emails
83:
84: =item newmail()
85:
86: Check for email
87:
88: =item author_res_msg()
89:
90: Automated message to the author of a resource
91:
92: =item * B<author_res_msg($filename, $message)>: Sends message $message to the owner
93: of the resource with the URI $filename.
94:
95: =item retrieve_author_res_msg()
96:
97: Retrieve author resource messages
98:
99: =item del_url_author_res_msg()
100:
101: Delete all author messages related to one URL
102:
103: =item clear_author_res_msg()
104:
105: Clear out all author messages in URL path
106:
107: =item all_url_author_res_msg()
108:
109: Return hash with URLs for which there is a resource message
110:
111: =item store_instructor_comment()
112:
113: Add a comment to the User Notes screen
114:
115: =item user_crit_msg_raw()
116:
117: Critical message to a user
118:
119: =item user_crit_msg()
120:
121: New routine that respects "forward" and calls old routine
122:
123: =item * B<user_crit_msg($user, $domain, $subject, $message, $sendback, $toperm, $sentmessage, $nosentstore, $recipid, $attachmenturl, $permresults, $senthide)>:
124: Sends a critical message $message to the $user at $domain. If $sendback
125: is true, a receipt will be sent to the current user when $user receives
126: the message.
127:
128: Additionally it will check if the user has a Forwarding address
129: set, and send the message to that address instead
130:
131: returns
132: - in array context a list of results for each message that was sent
133: - in scalar context a space seperated list of results for each
134: message sent
135:
136:
137: =item user_crit_received()
138:
139: Critical message received
140:
141: =item user_normal_msg_raw()
142:
143: Normal communication
144:
145: =item user_normal_msg()
146:
147: New routine that respects "forward" and calls old routine
148:
149: =item * B<user_normal_msg($user, $domain, $subject, $message, $citation,
150: $baseurl, $attachmenturl, $toperm, $sentmessage, $symb, $restitle,
151: $error,$nosentstore,$recipid,$permresults,$senthide)>:
152: Sends a message to the $user at $domain, with subject $subject and message $message.
153:
154: Additionally it will check if the user has a Forwarding address
155: set, and send the message to that address instead
156:
157: returns
158: - in array context a list of results for each message that was sent
159: - in scalar context a space seperated list of results for each
160: message sent
161:
162: =item store_sent_mail()
163:
164: =item store_recipients()
165:
166: =item foldersuffix()
167:
168: =item get_user_folders()
169:
170: User-defined folders
171:
172: =item secapply()
173:
174: =item B<decide_receiver($feedurl,$author,$question,$course,$policy,$defaultflag)>:
175:
176: Arguments
177: $feedurl - /res/ url of resource (only need if $author is true)
178: $author,$question,$course,$policy - all true/false parameters
179: if true will attempt to find the addresses of user that should receive
180: this type of feedback (author - feedback to author of resource $feedurl,
181: $question 'Resource Content Questions', $course 'Course Content Question',
182: $policy 'Course Policy')
183: (Additionally it also checks $env for whether the corresponding form.<name>
184: element exists, for ease of use in a html response context)
185:
186: $defaultflag - (internal should be left blank) if true gather addresses
187: that aren't for a section even if I have a section
188: (used for reccursion internally, first we look for
189: addresses for our specific section then we recurse
190: and look for non section addresses)
191:
192: Returns
193: $typestyle - string of html text, describing what addresses were found
194: %to - a hash, which keys are addresses of users to send messages to
195: the keys will look like name:domain
196:
197: =back
198:
199: =cut
200:
201: use strict;
202: use Apache::lonnet;
203: use HTML::TokeParser();
204: use Apache::lonlocal;
205: use Mail::Send;
206: use HTML::Entities;
207: use Encode;
208: use LONCAPA qw(:DEFAULT :match);
209:
210: {
211: my $uniq;
212: sub get_uniq {
213: $uniq++;
214: return $uniq;
215: }
216: }
217:
218:
219:
220: sub packagemsg {
221: my ($subject,$message,$citation,$baseurl,$attachmenturl,$recuser,$recdomain,
222: $msgid,$type,$crsmsgid,$symb,$error,$recipid,$senthide,$origmsgid)=@_;
223: $message =&HTML::Entities::encode($message,'<>&"');
224: $citation=&HTML::Entities::encode($citation,'<>&"');
225: $subject =&HTML::Entities::encode($subject,'<>&"');
226: #remove machine specification
227: $baseurl =~ s|^https?://[^/]+/|/|;
228: $baseurl =&HTML::Entities::encode($baseurl,'<>&"');
229: #remove machine specification
230: $attachmenturl =~ s|^https?://[^/]+/|/|;
231: $attachmenturl =&HTML::Entities::encode($attachmenturl,'<>&"');
232: if ($senthide) {
233: foreach my $item ($subject,$message) {
234: if ($item ne '') {
235: $item = 'Not shown due to IP block';
236: }
237: }
238: if ($attachmenturl ne '') {
239: $attachmenturl = '';
240: }
241: if ($citation ne '') {
242: $citation = '';
243: }
244: if ($msgid ne '') {
245: $msgid = '';
246: }
247: }
248: my $course_context = &get_course_context();
249: my $now=time;
250: my $ip = &Apache::lonnet::get_requestor_ip();
251: my $msgcount = &get_uniq();
252: unless(defined($msgid)) {
253: $msgid = &buildmsgid($now,$subject,$env{'user.name'},$env{'user.domain'},
254: $msgcount,$course_context,$symb,$error,$$);
255: }
256: my $result = '<sendername>'.$env{'user.name'}.'</sendername>'.
257: '<senderdomain>'.$env{'user.domain'}.'</senderdomain>'.
258: '<subject>'.$subject.'</subject>'.
259: '<time>'.&Apache::lonlocal::locallocaltime($now).'</time>';
260: if (defined($crsmsgid)) {
261: $result.= '<courseid>'.$course_context.'</courseid>'.
262: '<coursesec>'.$env{'request.course.sec'}.'</coursesec>'.
263: '<msgid>'.$msgid.'</msgid>'.
264: '<coursemsgid>'.$crsmsgid.'</coursemsgid>'.
265: '<message>'.$message.'</message>';
266: return ($msgid,$result);
267: }
268: $result .= '<servername>'.$ENV{'SERVER_NAME'}.'</servername>'.
269: '<host>'.$ENV{'HTTP_HOST'}.'</host>'.
270: '<client>'.$ip.'</client>'.
271: '<browsertype>'.$env{'browser.type'}.'</browsertype>'.
272: '<browseros>'.$env{'browser.os'}.'</browseros>'.
273: '<browserversion>'.$env{'browser.version'}.'</browserversion>'.
274: '<browsermathml>'.$env{'browser.mathml'}.'</browsermathml>'.
275: '<browserraw>'.$ENV{'HTTP_USER_AGENT'}.'</browserraw>'.
276: '<courseid>'.$course_context.'</courseid>'.
277: '<coursesec>'.$env{'request.course.sec'}.'</coursesec>'.
278: '<role>'.$env{'request.role'}.'</role>'.
279: '<resource>'.$env{'request.filename'}.'</resource>'.
280: '<msgid>'.$msgid.'</msgid>';
281: if (defined($env{'form.group'})) {
282: $result .= '<group>'.$env{'form.group'}.'</group>';
283: }
284: if (ref($recuser) eq 'ARRAY') {
285: for (my $i=0; $i<@{$recuser}; $i++) {
286: if ($type eq 'dcmail') {
287: my ($username,$email) = split(/:/,$$recuser[$i]);
288: $username = &unescape($username);
289: $email = &unescape($email);
290: $username = &HTML::Entities::encode($username,'<>&"');
291: $email = &HTML::Entities::encode($email,'<>&"');
292: $result .= '<recipient username="'.$username.'">'.
293: $email.'</recipient>';
294: } else {
295: $result .= '<recuser>'.$$recuser[$i].'</recuser>'.
296: '<recdomain>'.$$recdomain[$i].'</recdomain>';
297: }
298: }
299: } else {
300: $result .= '<recuser>'.$recuser.'</recuser>'.
301: '<recdomain>'.$recdomain.'</recdomain>';
302: }
303: $result .= '<message>'.$message.'</message>';
304: if (defined($citation)) {
305: $result.='<citation>'.$citation.'</citation>';
306: }
307: if (defined($baseurl)) {
308: $result.= '<baseurl>'.$baseurl.'</baseurl>';
309: }
310: if (defined($attachmenturl)) {
311: $result.= '<attachmenturl>'.$attachmenturl.'</attachmenturl>';
312: }
313: if (defined($symb)) {
314: $result.= '<symb>'.$symb.'</symb>';
315: if ($course_context ne '') {
316: if ($course_context eq $env{'request.course.id'}) {
317: my $resource_title = &Apache::lonnet::gettitle($symb);
318: if (defined($resource_title)) {
319: $result .= '<resource_title>'.$resource_title.'</resource_title>';
320: }
321: }
322: }
323: }
324: if (defined($recipid)) {
325: $result.= '<recipid>'.$recipid.'</recipid>';
326: }
327: if ($env{'form.can_reply'} eq 'N') {
328: $result .= '<noreplies>1</noreplies>';
329: }
330: if ($env{'form.reply_to_addr'}) {
331: my ($replytoname,$replytodom) = split(/:/,$env{'form.reply_to_addr'});
332: if (!($replytoname eq $env{'user.name'} && $replytodom eq $env{'user.domain'})) {
333: if (&Apache::lonnet::homeserver($replytoname,$replytodom) ne 'no_host') {
334: $result .= '<replytoaddr>'.$env{'form.reply_to_addr'}.'</replytoaddr>';
335: }
336: }
337: }
338: if ($senthide) {
339: $result .= '<senthide>$origmsgid</senthide>';
340: }
341: return ($msgid,$result);
342: }
343:
344: sub get_course_context {
345: my $course_context;
346: my $msgkey;
347: if (defined($env{'form.replyid'})) {
348: $msgkey = $env{'form.replyid'};
349: } elsif (defined($env{'form.forwid'})) {
350: $msgkey = $env{'form.forwid'}
351: } elsif (defined($env{'form.multiforwid'})) {
352: $msgkey = $env{'form.multiforwid'};
353: }
354: if ($msgkey ne '') {
355: my ($sendtime,$shortsubj,$fromname,$fromdomain,$count,$origcid)=
356: split(/\:/,&unescape($msgkey));
357: $course_context = $origcid;
358: }
359: foreach my $key (keys(%env)) {
360: if ($key=~/^form\.(rep)?rec\_(.*)$/) {
361: my ($sendtime,$shortsubj,$fromname,$fromdomain,$count,$origcid) =
362: split(/\:/,&unescape($2));
363: $course_context = $origcid;
364: last;
365: }
366: }
367: if ($course_context eq '') {
368: $course_context = $env{'request.course.id'};
369: }
370: return $course_context;
371: }
372:
373:
374: sub unpackagemsg {
375: my ($message,$notoken,$noattachmentlink)=@_;
376: my %content=();
377: my $parser=HTML::TokeParser->new(\$message);
378: my $token;
379: while ($token=$parser->get_token) {
380: if ($token->[0] eq 'S') {
381: my $entry=$token->[1];
382: my $value=$parser->get_text('/'.$entry);
383: if (($entry eq 'recuser') || ($entry eq 'recdomain')) {
384: push(@{$content{$entry}},$value);
385: } elsif ($entry eq 'recipient') {
386: my $username = $token->[2]{'username'};
387: $username = &HTML::Entities::decode($username,'<>&"');
388: $content{$entry}{$username} = $value;
389: } else {
390: $content{$entry}=$value;
391: }
392: }
393: }
394: if (!exists($content{'recuser'})) { $content{'recuser'} = []; }
395: if (($content{'attachmenturl'}) && (!$noattachmentlink)) {
396: my ($fname)=($content{'attachmenturl'}=~m|/([^/]+)$|);
397: if ($notoken) {
398: $content{'message'}.='<p>'.&mt('Attachment').': <tt>'.$fname.'</tt>';
399: } else {
400: &Apache::lonnet::allowuploaded('/adm/msg',
401: $content{'attachmenturl'});
402: $content{'message'}.='<p>'.&mt('Attachment').
403: ': <a href="'.$content{'attachmenturl'}.'"><tt>'.
404: $fname.'</tt></a>';
405: }
406: }
407: return %content;
408: }
409:
410:
411: sub buildmsgid {
412: my ($now,$subject,$uname,$udom,$msgcount,$course_context,$symb,$error,$pid) = @_;
413: $subject=&escape($subject);
414: $symb = &escape($symb);
415: return(&escape($now.':'.$subject.':'.$uname.':'.
416: $udom.':'.$msgcount.':'.$course_context.':'.$pid.':'.$symb.':'.$error));
417: }
418:
419: sub unpackmsgid {
420: my ($msgid,$folder,$skipstatus,$status_cache,$onlycid)=@_;
421: $msgid=&unescape($msgid);
422: my ($sendtime,$shortsubj,$fromname,$fromdomain,$count,$fromcid,
423: $processid,$symb,$error) = split(/\:/,&unescape($msgid));
424: if (!defined($processid)) { $fromcid = ''; }
425: if (($onlycid) && ($onlycid ne $fromcid)) {
426: return ($sendtime,'',$fromname,$fromdomain,'',$fromcid,'',$error);
427: }
428: $shortsubj = &unescape($shortsubj);
429: $shortsubj = &HTML::Entities::decode($shortsubj);
430: $symb = &unescape($symb);
431: if (!defined($processid)) { $fromcid = ''; }
432: my %status=();
433: unless ($skipstatus) {
434: if (ref($status_cache)) {
435: $status{$msgid} = $status_cache->{$msgid};
436: } else {
437: my $suffix=&foldersuffix($folder);
438: %status=&Apache::lonnet::get('email_status'.$suffix,[$msgid]);
439: }
440: if ($status{$msgid}=~/^error\:/) { $status{$msgid}=''; }
441: unless ($status{$msgid}) { $status{$msgid}='new'; }
442: }
443: return ($sendtime,$shortsubj,$fromname,$fromdomain,$status{$msgid},$fromcid,$symb,$error);
444: }
445:
446:
447: sub sendemail {
448: my ($to,$subject,$body,$to_uname,$to_udom,$user_lh)=@_;
449: my $senderaddress='';
450: my $replytoaddress='';
451: my $msgsent;
452: if ($env{'form.can_reply'} eq 'N') {
453: my $lonhost = $Apache::lonnet::perlvar{'lonHostID'};
454: my $hostname = &Apache::lonnet::hostname($lonhost);
455: $replytoaddress = 'do-not-reply@'.$hostname;
456: } else {
457: my %senderemails;
458: my ($have_sender,$setreplyto);
459: if ($env{'form.reply_to_addr'}) {
460: my ($replytoname,$replytodom) = split(/:/,$env{'form.reply_to_addr'});
461: if (($replytoname eq $env{'user.name'} && $replytodom eq $env{'user.domain'})) {
462: $setreplyto = 1;
463: } else {
464: if (&Apache::lonnet::homeserver($replytoname,$replytodom) ne 'no_host') {
465: %senderemails =
466: &Apache::loncommon::getemails($replytoname,$replytodom);
467: $have_sender = 1;
468: $setreplyto = 1;
469: }
470: }
471: }
472: if (!$have_sender) {
473: %senderemails=&Apache::loncommon::getemails();
474: }
475: foreach my $type ('permanentemail','critnotification','notification') {
476: if ($senderemails{$type}) {
477: ($senderaddress) = split(/,/,$senderemails{$type});
478: if ($senderaddress) {
479: if ($setreplyto) {
480: $replytoaddress = $senderaddress;
481: }
482: last;
483: }
484: }
485: }
486: }
487: $body=
488: "*** ".&mt_user($user_lh,'This is an automatic e-mail generated by the LON-CAPA system.')."\n".
489: "*** ".($senderaddress?&mt_user($user_lh,'You can reply to this e-mail'):&mt_user($user_lh,'Please do not reply to this address.')."\n*** ".
490: &mt_user($user_lh,'A reply will not be received by the recipient!'))."\n\n".$body;
491:
492: my $msg = new Mail::Send;
493: $msg->to($to);
494: $msg->subject('[LON-CAPA] '.$subject);
495: if ($replytoaddress) {
496: $msg->add('Reply-to',$replytoaddress);
497: }
498: if ($senderaddress) {
499: $msg->add('From',$senderaddress);
500: }
501: $msg->add('Content-type','text/plain; charset=UTF-8');
502: if (my $fh = $msg->open()) {
503: print $fh $body;
504: $fh->close;
505: $msgsent = 1;
506: }
507: return $msgsent;
508: }
509:
510: # ==================================================== Send notification emails
511:
512: sub sendnotification {
513: my ($to,$touname,$toudom,$subj,$crit,$text,$msgid)=@_;
514: my $sender=$env{'environment.firstname'}.' '.$env{'environment.lastname'};
515: unless ($sender=~/\w/) {
516: $sender=$env{'user.name'}.':'.$env{'user.domain'};
517: }
518: my $critical=($crit?' critical':'');
519: my $numsent = 0;
520:
521: $text=~s/\<\;/\</gs;
522: $text=~s/\>\;/\>/gs;
523: my $homeserver = &Apache::lonnet::homeserver($touname,$toudom);
524: my $protocol = $Apache::lonnet::protocol{$homeserver};
525: $protocol = 'http' if ($protocol ne 'https');
526: my $url = $protocol.'://'.&Apache::lonnet::hostname($homeserver).
527: '/adm/email?username='.$touname.'&domain='.$toudom.
528: '&display='.&escape($msgid);
529: my ($sendtime,$shortsubj,$fromname,$fromdomain,$status,$fromcid,
530: $symb,$error) = &Apache::lonmsg::unpackmsgid($msgid);
531: my ($coursetext,$body,$bodybegin,$bodysubj,$bodyend);
532: my $user_lh = &Apache::loncommon::user_lang($touname,$toudom,$fromcid);
533: if ($fromcid ne '') {
534: $coursetext = "\n".&mt_user($user_lh,'Course').': ';
535: if ($env{'course.'.$fromcid.'.description'} ne '') {
536: $coursetext .= $env{'course.'.$fromcid.'.description'};
537: } else {
538: my %coursehash = &Apache::lonnet::coursedescription($fromcid,);
539: if ($coursehash{'description'} ne '') {
540: $coursetext .= $coursehash{'description'};
541: }
542: }
543: $coursetext .= "\n\n";
544: }
545: my @recipients = split(/,/,$to);
546: $bodybegin = $coursetext.
547: &mt_user($user_lh,
548: 'You received a'.$critical.' message from [_1] in LON-CAPA.',$sender).' ';
549: $bodysubj = &mt_user($user_lh,'The subject is
550:
551: [_1]
552:
553: ',$subj)."\n".
554: '=== '.&mt_user($user_lh,'Excerpt')." ============================================================
555: ";
556: $bodyend = "
557: ========================================================================
558:
559: ".&mt_user($user_lh,'Use
560:
561: [_1]
562:
563: to access the full message.',$url);
564: my %userenv = &Apache::lonnet::get('environment',['notifywithhtml'],$toudom,$touname);
565: my $subject = &mt_user($user_lh,"'New'$critical message from [_1]",$sender);
566: unless ($subj eq '') {
567: $subject = $subj;
568: }
569:
570: my ($blocked,$blocktext,$clientip);
571: $clientip = &Apache::lonnet::get_requestor_ip();
572: if (!$crit) {
573: my %setters;
574: my ($startblock,$endblock,$triggerblock,$by_ip,$blockdom) =
575: &Apache::loncommon::blockcheck(\%setters,'com',$clientip,$touname,$toudom);
576: if ($startblock && $endblock) {
577: $blocked = 1;
578: my $showstart = &Apache::lonlocal::locallocaltime($startblock);
579: my $showend = &Apache::lonlocal::locallocaltime($endblock);
580: $blocktext = &mt_user($user_lh,'LON-CAPA messages sent to you between [_1] and [_2] will be inaccessible until the end of this time period, because you are a student in a course with an active communications block.',$showstart,$showend);
581: } elsif ($by_ip) {
582: $blocked = 1;
583: $blocktext = &mt_user($user_lh,'LON-CAPA messages sent to you will be inaccessible from your IP address [_1], because communication is being blocked for certain IP address(es).',$clientip);
584: }
585: }
586: if ($userenv{'notifywithhtml'} ne '') {
587: my @htmlexcerpt = split(/,/,$userenv{'notifywithhtml'});
588: my $htmlfree = &make_htmlfree($text);
589: foreach my $addr (@recipients) {
590: if ($blocked) {
591: $body = $bodybegin."\n".$blocktext."\n".$bodyend;
592: } else {
593: my $sendtext;
594: if (!grep/^\Q$addr\E/,@htmlexcerpt) {
595: $sendtext = $htmlfree;
596: } else {
597: $sendtext = $text;
598: }
599: $body = $bodybegin.$bodysubj.$sendtext.$bodyend;
600: }
601: if (&sendemail($addr,$subject,$body,$touname,$toudom,$user_lh)) {
602: $numsent ++;
603: }
604: }
605: } else {
606: if ($blocked) {
607: $body = $bodybegin."\n".$blocktext."\n".$bodyend;
608: } else {
609: my $htmlfree = &make_htmlfree($text);
610: $body = $bodybegin.$bodysubj.$htmlfree.$bodyend;
611: }
612: if (&sendemail($to,$subject,$body,$touname,$toudom,$user_lh)) {
613: $numsent ++;
614: }
615: }
616: return $numsent;
617: }
618:
619: sub make_htmlfree {
620: my ($text) = @_;
621: $text =~ s/\<\/*[^\>]+\>//gs;
622: $text = &HTML::Entities::decode($text);
623: $text = &Encode::encode('utf8',$text);
624: return $text;
625: }
626:
627: sub mynewmail{
628: &newmail();
629: return $env{'user.mailcheck.lastnewmessagetime'} > $env{'user.mailcheck.lastvisit'};
630: }
631:
632:
633: sub newmail {
634: if ((time-$env{'user.mailcheck.time'})>300) {
635: my %what=&Apache::lonnet::get('email_status',['recnewemail']);
636: &Apache::lonnet::appenv({'user.mailcheck.time'=>time});
637: &Apache::lonnet::appenv({'user.mailcheck.lastnewmessagetime'=> $what{'recnewemail'}});
638: if ($what{'recnewemail'}>0) { return 1; }
639: }
640: return 0;
641: }
642:
643:
644:
645: sub author_res_msg {
646: my ($filename,$message)=@_;
647: unless ($message) { return 'empty'; }
648: $filename=&Apache::lonnet::declutter($filename);
649: my ($domain,$author,@dummy)=split(/\//,$filename);
650: my $homeserver=&Apache::lonnet::homeserver($author,$domain);
651: if ($homeserver ne 'no_host') {
652: my $id=unpack("%32C*",$message);
653: $message .= " <p>This error occurred on machine ".
654: $Apache::lonnet::perlvar{'lonHostID'}."</p>";
655: my $msgid;
656: ($msgid,$message)=&packagemsg($filename,$message);
657: return &Apache::lonnet::reply('put:'.$domain.':'.$author.
658: ':nohist_res_msgs:'.
659: &escape($filename.'_'.$id).'='.
660: &escape($message),$homeserver);
661: }
662: return 'no_host';
663: }
664:
665:
666:
667: sub retrieve_author_res_msg {
668: my $url=shift;
669: $url=&Apache::lonnet::declutter($url);
670: my ($domain,$author)=($url=~/^($match_domain)\/($match_username)\//);
671: my %errormsgs=&Apache::lonnet::dump('nohist_res_msgs',$domain,$author);
672: my $msgs='';
673: foreach my $msg (keys(%errormsgs)) {
674: if ($msg =~ /^\Q$url\E\_\d+$/) {
675: my %content=&unpackagemsg($errormsgs{$msg});
676: $msgs.='<p><img src="/adm/lonMisc/bomb.gif" /><b>'.
677: $content{'time'}.'</b>: '.$content{'message'}.
678: '<br /></p>';
679: }
680: }
681: return $msgs;
682: }
683:
684:
685:
686:
687:
688: sub del_url_author_res_msg {
689: my $url=shift;
690: $url=&Apache::lonnet::declutter($url);
691: my ($domain,$author)=($url=~/^($match_domain)\/($match_username)\//);
692: my @delmsgs=();
693: foreach my $msg (&Apache::lonnet::getkeys('nohist_res_msgs',$domain,$author)) {
694: if ($msg =~ /^\Q$url\E\_\d+$/) {
695: push (@delmsgs,$msg);
696: }
697: }
698: return &Apache::lonnet::del('nohist_res_msgs',\@delmsgs,$domain,$author);
699: }
700:
701:
702: sub clear_author_res_msg {
703: my $url=shift;
704: $url=&Apache::lonnet::declutter($url);
705: my ($domain,$author)=($url=~/^($match_domain)\/($match_username)\//);
706: my @delmsgs=();
707: foreach my $msg (&Apache::lonnet::getkeys('nohist_res_msgs',$domain,$author)) {
708: if ($msg =~ /^\Q$url\E/) {
709: push (@delmsgs,$msg);
710: }
711: }
712: return &Apache::lonnet::del('nohist_res_msgs',\@delmsgs,$domain,$author);
713: }
714:
715:
716:
717: sub all_url_author_res_msg {
718: my ($author,$domain)=@_;
719: my %returnhash=();
720: foreach my $msg (&Apache::lonnet::getkeys('nohist_res_msgs',$domain,$author)) {
721: $msg =~ /^(.+)\_\d+/;
722: $returnhash{$1}=1;
723: }
724: return %returnhash;
725: }
726:
727:
728: sub store_instructor_comment {
729: my ($msg,$uname,$udom) = @_;
730: my $cid = $env{'request.course.id'};
731: my $cnum = $env{'course.'.$cid.'.num'};
732: my $cdom = $env{'course.'.$cid.'.domain'};
733: my $subject= &mt('Record').' ['.$uname.':'.$udom.']';
734: my $result = &user_normal_msg_raw($cnum,$cdom,$subject,$msg);
735: if ($result eq 'ok' || $result eq 'con_delayed') {
736:
737: }
738: return $result;
739: }
740:
741:
742: sub user_crit_msg_raw {
743: my ($user,$domain,$subject,$message,$sendback,$toperm,$sentmessage,
744: $nosentstore,$recipid,$attachmenturl,$permresults,$senthide)=@_;
745: # Check if allowed missing
746: my ($status,$packed_message);
747: my $msgid='undefined';
748: unless (($message)&&($user)&&($domain)) { $status='empty'; };
749: my $text=$message;
750: my $homeserver=&Apache::lonnet::homeserver($user,$domain);
751: if ($homeserver ne 'no_host') {
752: ($msgid,$packed_message)=&packagemsg($subject,$message,undef,undef,
753: $attachmenturl,undef,undef,undef,undef,undef,
754: undef,undef,$recipid);
755: if ($sendback) { $packed_message.='<sendback>true</sendback>'; }
756: $status=&Apache::lonnet::cput('critical', {$msgid => $packed_message},
757: $domain,$user);
758: if (defined($sentmessage)) {
759: $$sentmessage = $packed_message;
760: }
761: if (!$nosentstore) {
762: my ($sentmsgid,$packed_message_no_citation) =
763: &packagemsg($subject,$message,undef,undef,$attachmenturl,$user,
764: $domain,$msgid,undef,undef,undef,undef,undef,$senthide,$msgid);
765: if ($status eq 'ok' || $status eq 'con_delayed') {
766: if ($senthide && $sentmsgid) {
767: &store_sent_mail($sentmsgid,$packed_message_no_citation);
768: } else {
769: &store_sent_mail($msgid,$packed_message_no_citation);
770: }
771: }
772: }
773: } else {
774: $status='no_host';
775: }
776:
777: # Notifications
778: my %userenv = &Apache::loncommon::getemails($user,$domain);
779: my $critnotify = $userenv{'critnotification'};
780: my $permemail = $userenv{'permanentemail'};
781: my $numcrit = 0;
782: my $numperm = 0;
783: my $permlogmsgstatus;
784: if ($critnotify) {
785: $numcrit = &sendnotification($critnotify,$user,$domain,$subject,1,$text,$msgid);
786: }
787: if ($toperm && $permemail) {
788: if ($critnotify && $numcrit) {
789: if (grep(/^\Q$permemail\E/,split(/,/,$critnotify))) {
790: $numperm = 1;
791: }
792: }
793: unless ($numperm) {
794: $numperm = &sendnotification($permemail,$user,$domain,$subject,1,$text,$msgid);
795: }
796: }
797: if ($toperm) {
798: $permlogmsgstatus = '. Perm. email log status '.
799: &Apache::lonnet::log($env{'user.domain'},$env{'user.name'},$env{'user.home'},
800: "Perm. e-mail count $numperm for $user at $domain");
801: if (ref($permresults) eq 'HASH') {
802: $permresults->{"$user:$domain"} = $numperm;
803: }
804: }
805: # Log this
806: &Apache::lonnet::logthis(
807: 'Sending critical '.$msgid.
808: ', log status: '.
809: &Apache::lonnet::log($env{'user.domain'},$env{'user.name'},
810: $env{'user.home'},
811: 'Sending critical '.$msgid.' to '.$user.' at '.$domain.' with status '
812: .$status).$permlogmsgstatus);
813: return $status;
814: }
815:
816:
817:
818: sub user_crit_msg {
819: my ($user,$domain,$subject,$message,$sendback,$toperm,$sentmessage,
820: $nosentstore,$recipid,$attachmenturl,$permresults,$senthide)=@_;
821: my @status;
822: my %userenv = &Apache::lonnet::get('environment',['msgforward'],
823: $domain,$user);
824: my $msgforward=$userenv{'msgforward'};
825: if ($msgforward) {
826: foreach my $addr (split(/\,/,$msgforward)) {
827: my ($forwuser,$forwdomain)=split(/\:/,$addr);
828: push(@status,
829: &user_crit_msg_raw($forwuser,$forwdomain,$subject,$message,
830: $sendback,$toperm,$sentmessage,$nosentstore,
831: $recipid,$attachmenturl,$permresults,$senthide));
832: }
833: } else {
834: push(@status,
835: &user_crit_msg_raw($user,$domain,$subject,$message,$sendback,
836: $toperm,$sentmessage,$nosentstore,$recipid,
837: $attachmenturl,$permresults,$senthide));
838: }
839: if (wantarray) {
840: return @status;
841: }
842: return join(' ',@status);
843: }
844:
845:
846: sub user_crit_received {
847: my $msgid=shift;
848: my %message=&Apache::lonnet::get('critical',[$msgid]);
849: my %contents=&unpackagemsg($message{$msgid},1);
850: my $destname = $contents{'sendername'};
851: my $destdom = $contents{'senderdomain'};
852: if ($contents{'replytoaddr'}) {
853: my ($repname,$repdom) = split(/:/,$contents{'replytoaddr'});
854: if (&Apache::lonnet::homeserver($repname,$repdom) ne 'no_host') {
855: $destname = $repname;
856: $destdom = $repdom;
857: }
858: }
859: my $status='rec: '.($contents{'sendback'}?
860: &user_normal_msg($destname,$destdom,&mt('Receipt').': '.$env{'user.name'}.
861: ' '.&mt('at').' '.$env{'user.domain'}.', '.
862: $contents{'subject'},&mt('User').' '.$env{'user.name'}.
863: ' '.&mt('at').' '.$env{'user.domain'}.
864: ' acknowledged receipt of message'."\n".' "'.
865: $contents{'subject'}.'"'."\n".&mt('dated').' '.
866: $contents{'time'}.".\n"
867: ):'no msg req');
868: $status.=' trans: '.
869: &Apache::lonnet::put(
870: 'nohist_email',{$contents{'msgid'} => $message{$msgid}});
871: $status.=' del: '.
872: &Apache::lonnet::del('critical',[$contents{'msgid'}]);
873: &Apache::lonnet::log($env{'user.domain'},$env{'user.name'},
874: $env{'user.home'},'Received critical message '.
875: $contents{'msgid'}.
876: ', '.$status);
877: return $status;
878: }
879:
880:
881:
882:
883: sub user_normal_msg_raw {
884: my ($user,$domain,$subject,$message,$citation,$baseurl,$attachmenturl,
885: $toperm,$currid,$newid,$sentmessage,$crsmsgid,$symb,$restitle,
886: $error,$nosentstore,$recipid,$permresults,$senthide)=@_;
887: # Check if allowed missing
888: my ($status,$packed_message);
889: my $msgid='undefined';
890: my $text=$message;
891: unless (($message)&&($user)&&($domain)) { $status='empty'; };
892: my $homeserver=&Apache::lonnet::homeserver($user,$domain);
893: if ($homeserver ne 'no_host') {
894: ($msgid,$packed_message)=
895: &packagemsg($subject,$message,$citation,$baseurl,
896: $attachmenturl,$user,$domain,$currid,
897: undef,$crsmsgid,$symb,$error,$recipid);
898:
899: # Store in user folder
900: $status=
901: &Apache::lonnet::cput('nohist_email',{$msgid => $packed_message},
902: $domain,$user);
903: # Save new message received time
904: &Apache::lonnet::put
905: ('email_status',{'recnewemail'=>time},$domain,$user);
906: # Into sent-mail folder if sent mail storage required
907: if (!$nosentstore) {
908: my ($sentmsgid,$packed_message_no_citation) =
909: &packagemsg($subject,$message,undef,$baseurl,$attachmenturl,
910: $user,$domain,$currid,undef,$crsmsgid,$symb,$error,
911: undef,$senthide,$msgid);
912: if ($status eq 'ok' || $status eq 'con_delayed') {
913: if ($senthide && $sentmsgid) {
914: &store_sent_mail($sentmsgid,$packed_message_no_citation);
915: } else {
916: &store_sent_mail($msgid,$packed_message_no_citation);
917: }
918: }
919: }
920: if (ref($newid) eq 'SCALAR') {
921: $$newid = $msgid;
922: }
923: if (ref($sentmessage) eq 'SCALAR') {
924: $$sentmessage = $packed_message;
925: }
926: # Notifications
927: my %userenv = &Apache::loncommon::getemails($user,$domain);
928: my $notify = $userenv{'notification'};
929: my $permemail = $userenv{'permanentemail'};
930: my $numnotify = 0;
931: my $numperm = 0;
932: my $permlogmsgstatus;
933: if ($notify) {
934: $numnotify = &sendnotification($notify,$user,$domain,$subject,0,$text,$msgid);
935: }
936: if ($toperm && $permemail) {
937: if ($notify && $numnotify) {
938: if (grep(/^\Q$permemail\E/,split(/,/,$notify))) {
939: $numperm = 1;
940: }
941: }
942: unless ($numperm) {
943: $numperm = &sendnotification($permemail,$user,$domain,$subject,0,
944: $text,$msgid);
945: }
946: }
947: if ($toperm) {
948: $permlogmsgstatus = '. Perm. email log status '.
949: &Apache::lonnet::log($env{'user.domain'},$env{'user.name'},$env{'user.home'},
950: "Perm. e-mail count $numperm for $user at $domain");
951: if (ref($permresults) eq 'HASH') {
952: $permresults->{"$user:$domain"} = $numperm;
953: }
954: }
955: &Apache::lonnet::log($env{'user.domain'},$env{'user.name'},
956: $env{'user.home'},
957: 'Sending '.$msgid.' to '.$user.' at '.$domain.' with status '.$status.
958: $permlogmsgstatus);
959: } else {
960: $status='no_host';
961: }
962: return $status;
963: }
964:
965: sub user_normal_msg {
966: my ($user,$domain,$subject,$message,$citation,$baseurl,$attachmenturl,
967: $toperm,$sentmessage,$symb,$restitle,$error,$nosentstore,$recipid,
968: $permresults,$senthide)=@_;
969: my @status;
970: my %userenv = &Apache::lonnet::get('environment',['msgforward'],
971: $domain,$user);
972: my $msgforward=$userenv{'msgforward'};
973: if ($msgforward) {
974: foreach my $fwd (split(/\,/,$msgforward)) {
975: my ($forwuser,$forwdomain)=split(/\:/,$fwd);
976: push(@status,
977: &user_normal_msg_raw($forwuser,$forwdomain,$subject,$message,
978: $citation,$baseurl,$attachmenturl,$toperm,
979: undef,undef,$sentmessage,undef,$symb,
980: $restitle,$error,$nosentstore,$recipid,
981: $permresults,$senthide));
982: }
983: } else {
984: push(@status,&user_normal_msg_raw($user,$domain,$subject,$message,
985: $citation,$baseurl,$attachmenturl,$toperm,
986: undef,undef,$sentmessage,undef,$symb,
987: $restitle,$error,$nosentstore,$recipid,
988: $permresults,$senthide));
989: }
990: if (wantarray) {
991: return @status;
992: }
993: return join(' ',@status);
994: }
995:
996: sub process_sent_mail {
997: my ($msgsubj,$subj_prefix,$numsent,$stamp,$msgname,$msgdom,$msgcount,
998: $context,$pid,$savemsg,$recusers,$recudoms,$baseurl,$attachmenturl,
999: $symb,$error,$senderuname,$senderdom,$recipid) = @_;
1000: my $sentsubj;
1001: if ($numsent > 1) {
1002: $sentsubj = $subj_prefix.' ('.$numsent.' sent) '.$msgsubj;
1003: } else {
1004: if ($subj_prefix) {
1005: $sentsubj = $subj_prefix.' ';
1006: }
1007: $sentsubj .= $msgsubj;
1008: }
1009: $sentsubj = &HTML::Entities::encode($sentsubj,'<>&"');
1010: my $sentmsgid =
1011: &buildmsgid($stamp,$sentsubj,$msgname,$msgdom,$msgcount,$context,$pid);
1012: (undef,my $sentmessage) =
1013: &packagemsg($msgsubj,$savemsg,undef,$baseurl,$attachmenturl,$recusers,
1014: $recudoms,$sentmsgid,undef,undef,$symb,$error,$recipid);
1015: my $status = &store_sent_mail($sentmsgid,$sentmessage,$senderuname,
1016: $senderdom);
1017: return $status;
1018: }
1019:
1020: sub store_sent_mail {
1021: my ($msgid,$message,$senderuname,$senderdom) = @_;
1022: if ($senderuname eq '') {
1023: $senderuname = $env{'user.name'};
1024: }
1025: if ($senderdom eq '') {
1026: $senderdom = $env{'user.domain'};
1027: }
1028: my $status =' '.&Apache::lonnet::cput('nohist_email_sent',
1029: {$msgid => $message},
1030: $senderdom,$senderuname);
1031: return $status;
1032: }
1033:
1034: sub store_recipients {
1035: my ($subject,$sendername,$senderdom,$reciphash) = @_;
1036: my $context = &get_course_context();
1037: my $now = time();
1038: my $msgcount = &get_uniq();
1039: my $recipid =
1040: &buildmsgid($now,$subject,$sendername,$senderdom,$msgcount,$context,$$);
1041: my %recipinfo = (
1042: $recipid => $reciphash,
1043: );
1044: my $status = &Apache::lonnet::put('nohist_emailrecip',\%recipinfo,
1045: $senderdom,$sendername);
1046: if ($status eq 'ok') {
1047: return ($recipid,$status);
1048: } else {
1049: return (undef,$status);
1050: }
1051: }
1052:
1053:
1054: sub foldersuffix {
1055: my $folder=shift;
1056: unless ($folder) { return ''; }
1057: my $suffix;
1058: my %folderhash = &get_user_folders($folder);
1059: if (ref($folderhash{$folder}) eq 'HASH') {
1060: $suffix = '_'.&escape($folderhash{$folder}{'id'});
1061: } else {
1062: $suffix = '_'.&escape($folder);
1063: }
1064: return $suffix;
1065: }
1066:
1067:
1068: sub get_user_folders {
1069: my ($folder) = @_;
1070: my %userfolders =
1071: &Apache::lonnet::dump('email_folders',undef,undef,$folder);
1072: my $lock = "\0".'lock_counter'; # locks db while counter incremented
1073: my $counter = "\0".'idcount'; # used in suffix for email db files
1074: if (defined($userfolders{$lock})) {
1075: delete($userfolders{$lock});
1076: }
1077: if (defined($userfolders{$counter})) {
1078: delete($userfolders{$counter});
1079: }
1080: return %userfolders;
1081: }
1082:
1083: sub secapply {
1084: my $rec=shift;
1085: my $defaultflag=shift;
1086: $rec=~s/\s+//g;
1087: unless ($rec =~ /\:/) {
1088: $rec=~s/\@/\:/g;
1089: }
1090: my ($adr,$sections_or_groups)=($rec=~/^([^\(]+)\(([^\)]+)\)/);
1091: if ($sections_or_groups) {
1092: foreach my $item (split(/\;/,$sections_or_groups)) {
1093: if (($item eq $env{'request.course.sec'}) ||
1094: ($defaultflag && ($item eq '*'))) {
1095: return $adr;
1096: } elsif ($env{'request.course.groups'}) {
1097: my @usersgroups = split(/:/,$env{'request.course.groups'});
1098: if (grep(/^\Q$item\E$/,@usersgroups)) {
1099: return $adr;
1100: }
1101: }
1102: }
1103: } else {
1104: return $rec;
1105: }
1106: return '';
1107: }
1108:
1109: sub decide_receiver {
1110: my ($feedurl,$author,$question,$course,$policy,$defaultflag) = @_;
1111: &Apache::lonenc::check_decrypt(\$feedurl);
1112: my $typestyle='';
1113: my %to=();
1114: if ($env{'form.discuss'} eq 'author' ||$author) {
1115: $typestyle.='Submitting as Author Feedback<br />';
1116: $feedurl=~ m{^/res/($LONCAPA::domain_re)/($LONCAPA::username_re)/};
1117: $to{$2.':'.$1}=1;
1118: }
1119: my $cid = $env{'request.course.id'};
1120: if ($env{'form.discuss'} eq 'question' ||$question) {
1121: $typestyle.=&mt('Submitting as Question').'<br />';
1122: foreach my $item (split(/\,/,$env{'course.'.$cid.'.question.email'})) {
1123: my $rec=&secapply($item,$defaultflag);
1124: if ($rec) { $to{$rec}=1; }
1125: }
1126: }
1127: if ($env{'form.discuss'} eq 'course' ||$course) {
1128: $typestyle.=&mt('Submitting as Comment').'<br />';
1129: foreach my $item (split(/\,/,$env{'course.'.$cid.'.comment.email'})) {
1130: my $rec=&secapply($item,$defaultflag);
1131: if ($rec) { $to{$rec}=1; }
1132: }
1133: }
1134: if ($env{'form.discuss'} eq 'policy' ||$policy) {
1135: $typestyle.=&mt('Submitting as Policy Feedback').'<br />';
1136: foreach my $item (split(/\,/,$env{'course.'.$cid.'.policy.email'})) {
1137: my $rec=&secapply($item,$defaultflag);
1138: if ($rec) { $to{$rec}=1; }
1139: }
1140: }
1141: if ((scalar(%to) eq '0') && (!$defaultflag)) {
1142: ($typestyle,%to)=
1143: &decide_receiver($feedurl,$author,$question,$course,$policy,1);
1144: }
1145: return ($typestyle,%to);
1146: }
1147:
1148: 1;
1149: __END__
1150:
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>