1: # The LearningOnline Network with CAPA
2: # Navigate Maps Display Handler
3: #
4: # $Id: lonnavdisplay.pm,v 1.22.4.11 2024/07/02 02:17:56 raeburn Exp $
5: #
6: # Copyright Michigan State University Board of Trustees
7: #
8: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
9: #
10: # LON-CAPA is free software; you can redistribute it and/or modify
11: # it under the terms of the GNU General Public License as published by
12: # the Free Software Foundation; either version 2 of the License, or
13: # (at your option) any later version.
14: #
15: # LON-CAPA is distributed in the hope that it will be useful,
16: # but WITHOUT ANY WARRANTY; without even the implied warranty of
17: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18: # GNU General Public License for more details.
19: #
20: # You should have received a copy of the GNU General Public License
21: # along with LON-CAPA; if not, write to the Free Software
22: # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
23: #
24: # /home/httpd/html/adm/gpl.txt
25: #
26: # http://www.lon-capa.org/
27: #
28: ###
29:
30: package Apache::lonnavdisplay;
31:
32: use strict;
33: use Apache::Constants qw(:common :http REDIRECT);
34: use Apache::lonmenu();
35: use Apache::loncommon();
36: use Apache::lonnavmaps();
37: use Apache::lonhtmlcommon();
38: use Apache::lonnet;
39: use Apache::lonlocal;
40: use Apache::londocs();
41: use Apache::lonuserstate;
42:
43: sub handler {
44: my $r = shift;
45: real_handler($r);
46: }
47:
48: sub real_handler {
49: my $r = shift;
50: # Handle header-only request
51: if ($r->header_only) {
52: &Apache::loncommon::content_type($r,'text/html');
53: $r->send_http_header;
54: return OK;
55: }
56:
57: # Check for critical messages and redirect if present.
58: my ($redirect,$url) = &Apache::loncommon::critical_redirect(300);
59: if ($redirect) {
60: &Apache::loncommon::content_type($r,'text/html');
61: $r->header_out(Location => $url);
62: return REDIRECT;
63: }
64:
65: # ------------------------------------------------------------ Get query string
66: &Apache::loncommon::get_unprocessed_cgi($ENV{'QUERY_STRING'},['sort',
67: 'showOnlyHomework',
68: 'postsymb']);
69: # Check if course needs to be re-initialized
70: my $loncaparev = $r->dir_config('lonVersion');
71: my ($result,@reinit) = &Apache::loncommon::needs_coursereinit($loncaparev);
72: my %prog_state=();
73: my $closure;
74:
75: if ($result eq 'switch') {
76: &Apache::loncommon::content_type($r,'text/html');
77: $r->send_http_header;
78: $r->print(&Apache::loncommon::check_release_result(@reinit));
79: return OK;
80: } elsif ($result eq 'update') {
81: my $cid = $env{'request.course.id'};
82: my $cnum = $env{'course.'.$cid.'.num'};
83: my $cdom = $env{'course.'.$cid.'.domain'};
84: &Apache::loncommon::content_type($r,'text/html');
85: $r->send_http_header;
86: &startpage($r);
87: my $preamble = '<div id="LC_update_'.$cid.'" class="LC_info">'.
88: '<br />'.
89: &mt('Your course session is being updated because of recent changes by course personnel.').
90: ' '.&mt('Please be patient').'.<br /></div>'.
91: '<div style="padding:0;clear:both;margin:0;border:0"></div>';
92: $closure = <<ENDCLOSE;
93: <script type="text/javascript">
94: // <![CDATA[
95: \$("#LC_update_$cid").hide('slow');
96: // ]]>
97: </script>
98: ENDCLOSE
99: %prog_state = &Apache::lonhtmlcommon::Create_PrgWin($r,undef,$preamble);
100: &Apache::lonhtmlcommon::Update_PrgWin($r,\%prog_state,&mt('Updating course'));
101: $r->rflush();
102: my ($furl,$ferr) = &Apache::lonuserstate::readmap("$cdom/$cnum",\%prog_state,$r);
103: &Apache::lonhtmlcommon::Update_PrgWin($r,\%prog_state,&mt('Finished!'));
104: if ($ferr) {
105: &Apache::lonhtmlcommon::Close_PrgWin($r,\%prog_state);
106: $r->print($closure.&Apache::loncommon::end_page());
107: my $requrl = $r->uri;
108: $env{'user.error.msg'}="$requrl:bre:0:0:Course not initialized";
109: $env{'user.reinit'} = 1;
110: return HTTP_NOT_ACCEPTABLE;
111: }
112: }
113:
114: # Create the nav map
115: my $navmap = Apache::lonnavmaps::navmap->new();
116:
117: if (!defined($navmap)) {
118: if ($result eq 'update') {
119: &Apache::lonhtmlcommon::Close_PrgWin($r,\%prog_state);
120: $r->print($closure.&Apache::loncommon::end_page());
121: }
122: my $requrl = $r->uri;
123: $env{'user.error.msg'} = "$requrl:bre:0:0:Course not initialized";
124: $env{'user.reinit'} = 1;
125: return HTTP_NOT_ACCEPTABLE;
126: }
127:
128: if ($result eq 'update') {
129: $r->rflush();
130: &Apache::lonhtmlcommon::Close_PrgWin($r,\%prog_state);
131: $r->print($closure);
132: $r->rflush();
133: } else {
134: # Send header, don't cache this page
135: &Apache::loncommon::content_type($r,'text/html');
136: $r->send_http_header;
137: &startpage($r);
138: }
139:
140: &startContentScreen($r,'navmaps');
141: unless ($result eq 'update') {
142: $r->rflush();
143: }
144:
145: # Check that it's defined
146: if (!($navmap->courseMapDefined())) {
147: $r->print(&Apache::loncommon::help_open_menu('Navigation Screen','Navigation_Screen',undef,'RAT'));
148: $r->print('<span class="LC_error">'.&mt('Coursemap undefined.').
149: '</span>' .
150: &Apache::loncommon::end_page());
151: return OK;
152: }
153:
154: my %toplinkitems=();
155: my @resources = $navmap->retrieveResources();
156: my $sequenceCount = 0;
157: my $problemCount = 0;
158: my $notaprobCount = 0;
159: my $sequenceId;
160: my $notools;
161: foreach my $curRes (@resources) {
162: if (ref($curRes)) {
163: if ($curRes->is_sequence()) {
164: $sequenceCount++;
165: $sequenceId = $curRes->map_pc();
166: } elsif ($curRes->is_problem()) {
167: $problemCount ++;
168: } else {
169: $notaprobCount ++;
170: }
171: }
172: }
173: if (($sequenceCount == 1) && (!$problemCount) && ($notaprobCount <= 1)) {
174: $notools = 1;
175: }
176:
177: # If there's only one map in the top-level and we don't
178: # already have a filter, automatically display it
179: if ($ENV{QUERY_STRING} !~ /filter/) {
180: if ($sequenceCount == 1) {
181: # The automatic iterator creation in the render call
182: # will pick this up. We know the condition because
183: # the defined($env{'form.filter'}) also ensures this
184: # is a fresh call.
185: $env{'form.filter'} = "$sequenceId";
186: }
187: }
188:
189: # Check to see if the student is jumping to next open, do-able problem
190: if ($ENV{QUERY_STRING} =~ /^jumpToFirstHomework/) {
191: # Find the next homework problem that they can do.
192: my $iterator = $navmap->getIterator(undef, undef, undef, 1);
193: my $curRes;
194: my $foundDoableProblem = 0;
195: my $minimumduedate;
196: my $now = time();
197:
198: while ($curRes = $iterator->next()) {
199: if (ref($curRes) && $curRes->is_problem()) {
200: my $status = $curRes->status();
201: my $thisduedate=$curRes->duedate();
202: if ($thisduedate > $now
203: && $curRes->completable()) {
204:
205: $foundDoableProblem = 1;
206:
207: if (!defined($minimumduedate)
208: || $thisduedate<$minimumduedate) {
209: # Pop open all previous maps
210: my $stack = $iterator->getStack();
211: pop @$stack; # last resource in the stack is the problem
212: # itself, which we don't need in the map stack
213: my @mapPcs = map {$_->map_pc()} @$stack;
214: $env{'form.filter'} = join(',', @mapPcs);
215:
216: # Mark as both "here" and "jump"
217: $env{'form.postsymb'} = $curRes->symb();
218: $minimumduedate=$thisduedate;
219: }
220: }
221: }
222: }
223:
224: # If we found no problems, print a note to that effect.
225: if (!$foundDoableProblem) {
226: $r->print("<span class=\"LC_info\">"
227: .&mt("All homework assignments have been completed.")
228: ."</span>");
229: }
230: } else {
231: my $link = '/adm/navmaps?jumpToFirstHomework';
232: unless ($notools) {
233: &Apache::lonnavmaps::add_linkitem(\%toplinkitems,'firsthomework',
234: 'location.href="'.$link.'"',
235: "Show my first due problem");
236: }
237: }
238:
239: my $suppressEmptySequences = 0;
240: my $filterFunc = undef;
241: my $resource_no_folder_link = 0;
242:
243: # Display only due homework.
244: my $showOnlyHomework = 0;
245: if ($env{'form.showOnlyHomework'} eq "1") {
246: $showOnlyHomework = 1;
247: $suppressEmptySequences = 1;
248: $filterFunc = sub { my $res = shift;
249: return $res->completable() || $res->is_map();
250: };
251: my $link = '/adm/navmaps?sort='.$env{'form.sort'};
252: &Apache::lonnavmaps::add_linkitem(\%toplinkitems,'everything',
253: 'location.href="'.$link.'"',
254: 'Show everything');
255: $r->print("<span class=\"LC_info\">".&mt("Uncompleted Problems")."</span>");
256: $env{'form.filter'} = '';
257: $env{'form.condition'} = 1;
258: $resource_no_folder_link = 1;
259: } else {
260: my $link = '/adm/navmaps?sort='.$env{'form.sort'}.'&showOnlyHomework=1';
261: unless ($notools) {
262: &Apache::lonnavmaps::add_linkitem(\%toplinkitems,'uncompleted',
263: 'location.href="'.$link.'"',
264: 'Show only uncompleted problems');
265: }
266: }
267:
268: my %selected=($env{'form.sort'} => ' selected="selected"');
269: my $sort_html;
270: unless ($notools) {
271: $sort_html=(
272: '<form name="sortForm" action="">
273: <span class="LC_nobreak">
274: <input type="hidden" name="showOnlyHomework" value="'.$env{'form.showOnlyHomework'}.'" />
275: '.&mt('Sort by:').'
276: <select name="sort" onchange="document.sortForm.submit()">
277: <option value="default"'.$selected{'default'}.'>'.&mt('Default').'</option>
278: <option value="title"'.$selected{'title'}.'>'.&mt('Title').'</option>
279: <option value="duedate"'.$selected{'duedate'}.'>'.&mt('Due Date').'</option>
280: <option value="discussion"'.$selected{'discussion'}.'>'.&mt('Has New Discussion').'</option>
281: </select>
282: </span>
283: </form>');
284: }
285: # renderer call
286: my $renderArgs = { 'cols' => [0,1,2,3],
287: 'sort' => $env{'form.sort'},
288: 'url' => '/adm/navmaps',
289: 'navmap' => $navmap,
290: 'suppressNavmap' => 1,
291: 'suppressEmptySequences' => $suppressEmptySequences,
292: 'filterFunc' => $filterFunc,
293: 'resource_no_folder_link' => $resource_no_folder_link,
294: 'sort_html'=> $sort_html,
295: 'r' => $r,
296: 'caller' => 'navmapsdisplay',
297: 'linkitems' => \%toplinkitems,
298: 'notools' => $notools};
299:
300: my $render = &Apache::lonnavmaps::render($renderArgs);
301:
302: # If no resources were printed, print a reassuring message so the
303: # user knows there was no error.
304: if ($renderArgs->{'counter'} == 0) {
305: if ($showOnlyHomework) {
306: $r->print("<p><span class=\"LC_info\">".&mt("All homework is currently completed.")."</span></p>");
307: } else { # both jumpToFirstHomework and normal use the same: course must be empty
308: $r->print("<p><span class=\"LC_info\">".&mt("This course is empty.")."</span></p>");
309: }
310: }
311: &endContentScreen($r);
312: $r->print(&Apache::loncommon::end_page());
313: $r->rflush();
314:
315: return OK;
316: }
317:
318: sub startpage {
319: my ($r) = @_;
320: # ----------------------------------------------------- Force menu registration
321: # Header
322: my $course_type = &Apache::loncommon::course_type();
323: my $title = $course_type . ' Contents';
324: my $brcrum = [{href => '/adm/navmaps',
325: text => &mt($course_type . ' Contents'),
326: no_mt => 1},
327: ];
328: my $args = {'bread_crumbs' => $brcrum};
329: $r->print(&Apache::loncommon::start_page($title,undef,$args).
330: '<script type="text/javascript">'."\n".
331: '// <![CDATA['."\n".
332: 'window.focus();'."\n".
333: '// ]]>'."\n".
334: '</script>');
335: return;
336: }
337:
338: sub startContentScreen {
339: my ($r,$mode)=@_;
340:
341: $r->print("\n".'<ul class="LC_TabContentBigger" id="mainnav">'."\n");
342: $r->print('<li'.(($mode eq 'navmaps')?' class="active"':'').'><a href="/adm/navmaps"><b> '.&mt('Main Content').' </b></a></li>'."\n");
343: my $allowed = &Apache::lonnet::allowed('mdc',$env{'request.course.id'});
344: my ($suppcount,$errors);
345: unless ($allowed) {
346: my $cnum = $env{'course.'.$env{'request.course.id'}.'.num'};
347: my $cdom = $env{'course.'.$env{'request.course.id'}.'.domain'};
348: ($suppcount,$errors) = &Apache::lonnet::get_numsuppfiles($cnum,$cdom);
349: }
350: if ($allowed || $suppcount) {
351: $r->print('<li '.(($mode eq 'supplemental')?' class="active"':'').'><a href="/adm/supplemental"><b>'.&mt('Supplemental Content').'</b></a></li>');
352: }
353: $r->print('<li'.(($mode eq 'coursesearch')?' class="active"':'').'><a href="/adm/searchcourse"><b> '.&mt('Content Search').' </b></a></li>'."\n");
354: $r->print("\n".'</ul>'."\n");
355: $r->print('<div class="LC_Box" style="clear:both;margin:0;"><div id="maincoursedoc" style="margin:0 0;padding:0 0;"><div class="LC_ContentBox" id="mainCourseDocuments" style="display: block;">');
356: }
357:
358: sub endContentScreen {
359: my ($r)=@_;
360: $r->print('</div></div></div>');
361: }
362:
363: 1;
364: __END__
365:
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>
![[BACK]](/icons/back.gif){kind=icon}
Return to lonnavdisplay.pm CVS log ![[TXT]](/icons/text.gif){kind=icon}
![[DIR]](/icons/dir.gif){kind=icon}
Up to [LON-CAPA] / loncom / interface