1: # The LearningOnline Network with CAPA
2: # Quick Student Grades Display
3: #
4: # $Id: lonquickgrades.pm,v 1.49.6.1 2014/05/22 12:44:24 raeburn Exp $
5: #
6: # Copyright Michigan State University Board of Trustees
7: #
8: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
9: #
10: # LON-CAPA is free software; you can redistribute it and/or modify
11: # it under the terms of the GNU General Public License as published by
12: # the Free Software Foundation; either version 2 of the License, or
13: # (at your option) any later version.
14: #
15: # LON-CAPA is distributed in the hope that it will be useful,
16: # but WITHOUT ANY WARRANTY; without even the implied warranty of
17: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18: # GNU General Public License for more details.
19: #
20: # You should have received a copy of the GNU General Public License
21: # along with LON-CAPA; if not, write to the Free Software
22: # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
23: #
24: # /home/httpd/html/adm/gpl.txt
25: #
26: # http://www.lon-capa.org/
27: #
28:
29: package Apache::lonquickgrades;
30:
31: use strict;
32: use Apache::Constants qw(:common :http REDIRECT);
33: use POSIX;
34: use Apache::loncommon;
35: use Apache::lonlocal;
36: use Apache::lonnet;
37: use Apache::grades;
38:
39: sub handler {
40: my $r = shift;
41: return real_handler($r);
42: }
43:
44: sub real_handler {
45: my $r = shift;
46:
47: # Check for critical messages and redirect if present.
48: my ($redirect,$url) = &Apache::loncommon::critical_redirect(300);
49: if ($redirect) {
50: &Apache::loncommon::content_type($r,'text/html');
51: $r->header_out(Location => $url);
52: return REDIRECT;
53: }
54:
55: &Apache::loncommon::get_unprocessed_cgi($ENV{QUERY_STRING});
56:
57: # Handle header-only request
58: if ($env{'browser.mathml'}) {
59: &Apache::loncommon::content_type($r,'text/xml');
60: } else {
61: &Apache::loncommon::content_type($r,'text/html');
62: }
63: if ($r->header_only) {
64: $r->send_http_header;
65: return OK;
66: }
67:
68: # Send header, don't cache this page
69: &Apache::loncommon::no_cache($r);
70: $r->send_http_header;
71:
72: my $showPoints =
73: $env{'course.'.$env{'request.course.id'}.'.grading'} eq 'standard';
74: my $notshowSPRSlink =
75: (($env{'course.'.$env{'request.course.id'}.'.grading'} eq 'external')
76: || ($env{'course.'.$env{'request.course.id'}.'.grading'} eq 'externalnototals'));
77: my $notshowTotals=
78: $env{'course.'.$env{'request.course.id'}.'.grading'} eq 'externalnototals';
79:
80: # Create the nav map
81: my $navmap = Apache::lonnavmaps::navmap->new();
82:
83: if (!defined($navmap)) {
84: my $requrl = $r->uri;
85: $env{'user.error.msg'} = "$requrl:bre:0:0:Navamp initialization failed.";
86: return HTTP_NOT_ACCEPTABLE;
87: }
88:
89: # Keep this hash in sync with %statusIconMap in lonnavmaps; they
90: # should match color/icon
91: my $res = $navmap->firstResource(); # temp resource to access constants
92:
93: # Header
94: my $title = "Grading and Statistics";#$showPoints ? "Points Display" : "Completed Problems Display";
95: my $brcrum = [{href=>"/adm/quickgrades",text => "Points Display"}];
96: $r->print(&Apache::loncommon::start_page($title,undef,
97: {'bread_crumbs' => $brcrum})
98: );
99:
100: if (!$showPoints && !$notshowSPRSlink ) {
101: $r->print('<p>'
102: .&mt('This screen shows how many problems (or problem parts) you have completed'
103: .', and how many you have not yet done.'
104: .' You can also look at [_1]a detailed score sheet[_2].'
105: ,'<a href="/adm/studentcalc">','</a>')
106: .'</p>');
107: }
108:
109: $r->print('<p class="LC_info">'.&mt('This may take a few moments to display.').'</p>');
110:
111: $r->rflush();
112:
113: # End navmap using boilerplate
114:
115: my $iterator = $navmap->getIterator(undef, undef, undef, 1);
116: my $depth = 1;
117: $iterator->next(); # ignore first BEGIN_MAP
118: my $curRes = $iterator->next();
119:
120: # General overview of the following: Walk along the course resources.
121: # For every problem in the resource, tell its parent maps how many
122: # parts and how many parts correct it has. After that, each map will
123: # have a count of the total parts underneath it, correct and otherwise.
124: # After that, we will walk through the course again and read off
125: # maps in order, with their data.
126: # (If in the future people decide not to be cumulative, only add
127: # the counts to the parent map.)
128: # For convenience, "totalParts" is also "totalPoints" when we're looking
129: # at points; I can't come up with a variable name that makes sense
130: # equally for both cases.
131:
132: my $totalParts = 0; my $totalPossible = 0; my $totalRight = 0;
133: my $totalAttempted = 0;
134: my $now = time();
135: my $topLevelParts = 0; my $topLevelRight = 0; my $topLevelAttempted = 0;
136:
137: # Pre-run: Count parts correct
138: while ( $depth > 0 ) {
139: if ($curRes == $iterator->BEGIN_MAP()) {$depth++;}
140: if ($curRes == $iterator->END_MAP()) { $depth--; }
141:
142: if (ref($curRes) && $curRes->is_problem() && !$curRes->randomout)
143: {
144: # Get number of correct, incorrect parts
145: my $parts = $curRes->parts();
146: my $partsRight = 0;
147: my $partsCount = 0;
148: my $partsAttempted = 0;
149: my $stack = $iterator->getStack();
150:
151: for my $part (@{$parts}) {
152: my $completionStatus = $curRes->getCompletionStatus($part);
153: my $dateStatus = $curRes->getDateStatus($part);
154:
155: if ($completionStatus == $curRes->EXCUSED()) {
156: next;
157: }
158: if ($showPoints) {
159: my $score = 0;
160: # If we're not telling status and the answer date isn't passed yet,
161: # it's an "attempted" point
162: if ((($curRes->problemstatus($part) eq 'no') ||
163: ($curRes->problemstatus($part) eq 'no_feedback_ever')) &&
164: ($dateStatus != $curRes->ANSWER_OPEN)) {
165: my $status = $curRes->simpleStatus($part);
166: if ($status == $curRes->ATTEMPTED) {
167: $partsAttempted += $curRes->weight($part);
168: $totalAttempted += $partsAttempted;
169: }
170: } else {
171: $score = &Apache::grades::compute_points($curRes->weight($part), $curRes->awarded($part));
172: }
173: $partsRight += $score;
174: $totalRight += $score;
175: $partsCount += $curRes->weight($part);
176:
177: if ($curRes->opendate($part) < $now) {
178: $totalPossible += $curRes->weight($part);
179: }
180: $totalParts += $curRes->weight($part);
181: } else {
182: my $status = $curRes->simpleStatus($part);
183: my $thisright = 0;
184: $partsCount++;
185: if ($status == $curRes->CORRECT ||
186: $status == $curRes->PARTIALLY_CORRECT ) {
187: $partsRight++;
188: $totalRight++;
189: $thisright = 1;
190: }
191:
192: if ($status == $curRes->ATTEMPTED) {
193: $partsAttempted++;
194: $totalAttempted++;
195: }
196:
197: my $dateStatus = $curRes->getDateStatus($part);
198: $totalParts++;
199: if ($curRes->opendate($part) < $now) {
200: $totalPossible++;
201: }
202: }
203: }
204:
205: if ($depth == 1) { # in top-level only
206: $topLevelParts += $partsCount;
207: $topLevelRight += $partsRight;
208: $topLevelAttempted += $partsAttempted;
209: }
210:
211: # Crawl down stack and record parts correct and total
212: for my $res (@{$stack}) {
213: if (ref($res) && $res->is_map()) {
214: if (!defined($res->{DATA}->{CHILD_PARTS})) {
215: $res->{DATA}->{CHILD_PARTS} = 0;
216: $res->{DATA}->{CHILD_CORRECT} = 0;
217: $res->{DATA}->{CHILD_ATTEMPTED} = 0;
218: }
219:
220: $res->{DATA}->{CHILD_PARTS} += $partsCount;
221: $res->{DATA}->{CHILD_CORRECT} += $partsRight;
222: $res->{DATA}->{CHILD_ATTEMPTED} += $partsAttempted;
223: }
224: }
225: }
226: $curRes = $iterator->next();
227: }
228:
229: $iterator = $navmap->getIterator(undef, undef, undef, 1);
230: $depth = 1;
231: $iterator->next(); # ignore first BEGIN_MAP
232: $curRes = $iterator->next();
233:
234: my @start = (255, 255, 192);
235: my @end = (0, 192, 0);
236:
237: my $indentString = ' ';
238:
239: # Second pass: Print the maps.
240: $r->print(&Apache::loncommon::start_data_table()
241: .&Apache::loncommon::start_data_table_header_row()
242: .'<th>'.&mt('Folder').'</th>');
243: $title = &mt($showPoints ? "Points Scored" : "Done");
244: if ($totalAttempted) {
245: $title .= " / " . &mt("Attempted");
246: }
247: $r->print("<th>$title".($notshowTotals?'':" / ".&mt('Total')).'</th>'
248: .&Apache::loncommon::end_data_table_header_row());
249: while ($depth > 0) {
250: if ($curRes == $iterator->BEGIN_MAP()) {$depth++;}
251: if ($curRes == $iterator->END_MAP()) { $depth--; }
252:
253: if (ref($curRes) && $curRes->is_map()) {
254: my $title = $curRes->compTitle();
255:
256: my $correct = $curRes->{DATA}->{CHILD_CORRECT};
257: my $total = $curRes->{DATA}->{CHILD_PARTS};
258: my $attempted = $curRes->{DATA}->{CHILD_ATTEMPTED};
259:
260: if ($total > 0) {
261: my $ratio;
262: $ratio = $correct / $total;
263: my $color = mixColors(\@start, \@end, $ratio);
264: $r->print(&Apache::loncommon::start_data_table_row()
265: .'<td style="background-color:'.$color.';">');
266:
267: my $thisIndent = '';
268: for (my $i = 1; $i < $depth; $i++) { $thisIndent .= $indentString; }
269:
270: $r->print("$thisIndent$title</td>");
271: if ($totalAttempted) {
272: $r->print('<td valign="top">'
273: .$thisIndent
274: .'<span class="LC_nobreak">'
275: .$correct.' / '.$attempted.($notshowTotals?'':' / '.$total)
276: .'</span></td>'
277: .&Apache::loncommon::end_data_table_row()
278: );
279: } else {
280: $r->print('<td valign="top">'
281: .$thisIndent
282: .'<span class="LC_nobreak">'
283: .$correct.($notshowTotals?'':' / '.$total)
284: .'</span></td>'
285: .&Apache::loncommon::end_data_table_row());
286: }
287: }
288: }
289:
290: $curRes = $iterator->next();
291: }
292:
293: # If there were any problems at the top level, print an extra "catchall"
294: if ($topLevelParts > 0) {
295: my $ratio = $topLevelRight / $topLevelParts;
296: my $color = mixColors(\@start, \@end, $ratio);
297: $r->print(&Apache::loncommon::start_data_table_row()
298: .'<td style="background-color:'.$color.';">');
299: $r->print(&mt("Problems Not Contained In A Folder")."</td><td>");
300: $r->print("$topLevelRight / $topLevelParts</td>"
301: .&Apache::loncommon::end_data_table_row());
302: }
303:
304: if ($showPoints) {
305: my $maxHelpLink = Apache::loncommon::help_open_topic("Quick_Grades_Possibly_Correct");
306:
307: $title = $showPoints ? "Points" : "Parts Done";
308: my $totaltitle = $showPoints ? &mt("Awarded Total Points") : &mt("Total Parts Done");
309: $r->print(&Apache::loncommon::start_data_table_row()
310: .'<td colspan="2" align="right">'.$totaltitle.': <b>'.$totalRight.'</b><br />');
311: $r->print(&mt('Max Possible To Date')." $maxHelpLink: <b>$totalPossible</b><br />");
312: $title = $showPoints ? "Points" : "Parts";
313: $r->print(&mt("Total $title In Course").': <b>'.$totalParts.'</b></td>'
314: .&Apache::loncommon::end_data_table_row());
315: }
316:
317: $r->print(&Apache::loncommon::end_data_table()
318: .&Apache::loncommon::end_page());
319:
320: return OK;
321: }
322:
323: # Pass this two refs to arrays for the start and end color, and a number
324: # from 0 to 1 for how much of the latter you want to mix in. It will
325: # return a string ready to show ("#FFC309");
326: sub mixColors {
327: my $start = shift;
328: my $end = shift;
329: my $ratio = shift;
330:
331: my ($a,$b);
332: my $final = "";
333: $a = $start->[0]; $b = $end->[0];
334: my $mix1 = POSIX::floor((1-$ratio)*$a + $ratio*$b);
335: $a = $start->[1]; $b = $end->[1];
336: my $mix2 = POSIX::floor((1-$ratio)*$a + $ratio*$b);
337: $a = $start->[2]; $b = $end->[2];
338: my $mix3 = POSIX::floor((1-$ratio)*$a + $ratio*$b);
339:
340: $final = sprintf "%02x%02x%02x", $mix1, $mix2, $mix3;
341: return "#" . $final;
342: }
343:
344: 1;
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>