1: # The LearningOnline Network with CAPA
2: # (Publication Handler
3: #
4: # $Id: lonstatistics.pm,v 1.40 2002/08/06 17:39:15 minaeibi Exp $
5: #
6: # Copyright Michigan State University Board of Trustees
7: #
8: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
9: #
10: # LON-CAPA is free software; you can redistribute it and/or modify
11: # it under the terms of the GNU General Public License as published by
12: # the Free Software Foundation; either version 2 of the License, or
13: # (at your option) any later version.
14: #
15: # LON-CAPA is distributed in the hope that it will be useful,
16: # but WITHOUT ANY WARRANTY; without even the implied warranty of
17: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18: # GNU General Public License for more details.
19: #
20: # You should have received a copy of the GNU General Public License
21: # along with LON-CAPA; if not, write to the Free Software
22: # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
23: #
24: # /home/httpd/html/adm/gpl.txt
25: #
26: # http://www.lon-capa.org/
27: #
28: # (Navigate problems for statistical reports
29: # YEAR=2001
30: # 5/5,7/9,7/25/1,8/11,9/13,9/26,10/5,10/9,10/22,10/26 Behrouz Minaei
31: # 11/1,11/4,11/16,12/14,12/16,12/18,12/20,12/31 Behrouz Minaei
32: # YEAR=2002
33: # 1/22,2/1,2/6,2/25,3/2,3/6,3/17,3/21,3/22,3/26,4/7,5/6 Behrouz Minaei
34: # 5/12,5/14,5/15,5/19,5/26,7/16,25/7,29/7 Behrouz Minaei
35: #
36: ###
37:
38: package Apache::lonstatistics;
39:
40: use strict;
41: use Apache::Constants qw(:common :http);
42: use Apache::lonnet();
43: use Apache::lonhomework;
44: use Apache::loncommon;
45: use Apache::loncoursedata;
46: use Apache::lonhtmlcommon;
47: use Apache::lonproblemanalysis;
48: use Apache::lonproblemstatistics;
49: use Apache::lonstudentassessment;
50: use Apache::lonchart;
51: use HTML::TokeParser;
52: use GDBM_File;
53:
54:
55: sub CheckFormElement {
56: my ($cache, $ENVName, $cacheName, $default)=@_;
57:
58: if(defined($ENV{'form.'.$ENVName})) {
59: $cache->{$cacheName} = $ENV{'form.'.$ENVName};
60: } elsif(!defined($cache->{$cacheName})) {
61: $cache->{$cacheName} = $default;
62: }
63:
64: return;
65: }
66:
67: sub ProcessFormData{
68: my ($cache)=@_;
69:
70: $cache->{'reportKey'} = 'false';
71:
72: &Apache::loncommon::get_unprocessed_cgi($ENV{'QUERY_STRING'},
73: ['sort','download',
74: 'reportSelected',
75: 'StudentAssessmentStudent']);
76: &CheckFormElement($cache, 'Status', 'Status', 'Active');
77: &CheckFormElement($cache, 'postdata', 'reportSelected', 'Class list');
78: &CheckFormElement($cache, 'reportSelected', 'reportSelected',
79: 'Class list');
80: $cache->{'reportSelected'} =
81: &Apache::lonnet::unescape($cache->{'reportSelected'});
82: &CheckFormElement($cache, 'DownloadAll', 'DownloadAll', 'false');
83: &CheckFormElement($cache, 'sort', 'sort', 'fullname');
84: &CheckFormElement($cache, 'download', 'download', 'false');
85:
86: # student assessment
87: if(defined($ENV{'form.CreateStudentAssessment'}) ||
88: defined($ENV{'form.NextStudent'}) ||
89: defined($ENV{'form.PreviousStudent'})) {
90: $cache->{'reportSelected'} = 'Student Assessment';
91: }
92: if(defined($ENV{'form.NextStudent'})) {
93: $cache->{'StudentAssessmentMove'} = 'next';
94: } elsif(defined($ENV{'form.PreviousStudent'})) {
95: $cache->{'StudentAssessmentMove'} = 'previous';
96: } else {
97: $cache->{'StudentAssessmentMove'} = 'selected';
98: }
99: &CheckFormElement($cache, 'StudentAssessmentStudent',
100: 'StudentAssessmentStudent', 'All Students');
101: $cache->{'StudentAssessmentStudent'} =
102: &Apache::lonnet::unescape($cache->{'StudentAssessmentStudent'});
103: &CheckFormElement($cache, 'DefaultColumns', 'DefaultColumns', 'false');
104:
105: if(defined($ENV{'form.Section'})) {
106: my @sectionsSelected = (ref($ENV{'form.Section'}) ?
107: @{$ENV{'form.Section'}} :
108: ($ENV{'form.Section'}));
109: $cache->{'sectionsSelected'} = join(':', @sectionsSelected);
110: } elsif(!defined($cache->{'sectionsSelected'})) {
111: $cache->{'sectionsSelected'} = $cache->{'sectionList'};
112: }
113:
114: # Problem analysis
115: &CheckFormElement($cache, 'Interval', 'Interval', '1');
116:
117: # ProblemStatistcs
118: &CheckFormElement($cache, 'DisplayCSVFormat',
119: 'DisplayFormat', 'Display Table Format');
120: &CheckFormElement($cache, 'ProblemStatisticsAscend',
121: 'ProblemStatisticsAscend', 'Ascending');
122: &CheckFormElement($cache, 'ProblemStatisticsMaps',
123: 'ProblemStatisticsMaps', 'All Maps');
124:
125: # Search only form elements
126: my @headingColumns=();
127: my @sequenceColumns=();
128: my $foundColumn = 0;
129: if(defined($ENV{'form.ReselectColumns'})) {
130: my @reselected = (ref($ENV{'form.ReselectColumns'}) ?
131: @{$ENV{'form.ReselectColumns'}}
132: : ($ENV{'form.ReselectColumns'}));
133: foreach (@reselected) {
134: if(/HeadingColumn/) {
135: push(@headingColumns, $_);
136: $foundColumn = 1;
137: } elsif(/SequenceColumn/) {
138: push(@sequenceColumns, $_);
139: $foundColumn = 1;
140: }
141: }
142: }
143:
144: $cache->{'reportKey'} = 'false';
145: if($cache->{'reportSelected'} eq 'Analyze') {
146: $cache->{'reportKey'} = 'Analyze';
147: } elsif($cache->{'reportSelected'} eq 'DoDiffGraph') {
148: $cache->{'reportKey'} = 'DoDiffGraph';
149: } elsif($cache->{'reportSelected'} eq 'PercentWrongGraph') {
150: $cache->{'reportKey'} = 'PercentWrongGraph';
151: }
152:
153: if(defined($ENV{'form.DoDiffGraph'})) {
154: $cache->{'reportSelected'} = 'DoDiffGraph';
155: $cache->{'reportKey'} = 'DoDiffGraph';
156: } elsif(defined($ENV{'form.PercentWrongGraph'})) {
157: $cache->{'reportSelected'} = 'PercentWrongGraph';
158: $cache->{'reportKey'} = 'PercentWrongGraph';
159: }
160:
161: foreach (keys(%ENV)) {
162: if(/form\.Analyze/) {
163: $cache->{'reportSelected'} = 'Analyze';
164: $cache->{'reportKey'} = 'Analyze';
165: my $data;
166: (undef, $data)=split(':::', $_);
167: $cache->{'AnalyzeInfo'}=$data;
168: } elsif(/form\.HeadingColumn/) {
169: my $value = $_;
170: $value =~ s/form\.//;
171: push(@headingColumns, $value);
172: $foundColumn=1;
173: } elsif(/form\.SequenceColumn/) {
174: my $value = $_;
175: $value =~ s/form\.//;
176: push(@sequenceColumns, $value);
177: $foundColumn=1;
178: }
179: }
180:
181: if($foundColumn) {
182: $cache->{'HeadingsFound'} = join(':', @headingColumns);
183: $cache->{'SequencesFound'} = join(':', @sequenceColumns);;
184: }
185: if(!defined($cache->{'HeadingsFound'}) ||
186: $cache->{'DefaultColumns'} ne 'false') {
187: $cache->{'HeadingsFound'}='HeadingColumnFull Name';
188: }
189: if(!defined($cache->{'SequencesFound'}) ||
190: $cache->{'DefaultColumns'} ne 'false') {
191: $cache->{'SequencesFound'}='All Sequences';
192: }
193: $cache->{'DefaultColumns'} = 'false';
194:
195: return;
196: }
197:
198: =pod
199:
200: =item &SortStudents()
201:
202: Determines which students to display and in which order. Which are
203: displayed are determined by their status(active/expired). The order
204: is determined by the sort button pressed (default to username). The
205: type of sorting is username, lastname, or section.
206:
207: =over 4
208:
209: Input: $students, $CacheData
210:
211: $students: A array pointer to a list of students (username:domain)
212:
213: $CacheData: A pointer to the hash tied to the cached data
214:
215: Output: \@order
216:
217: @order: An ordered list of students (username:domain)
218:
219: =back
220:
221: =cut
222:
223: sub SortStudents {
224: my ($cache)=@_;
225:
226: my @students = split(':::',$cache->{'NamesOfStudents'});
227: my @sorted1Students=();
228: foreach (@students) {
229: if($cache->{'Status'} eq 'Any' ||
230: $cache->{$_.':Status'} eq $cache->{'Status'}) {
231: push(@sorted1Students, $_);
232: }
233: }
234:
235: my $sortBy = '';
236: if(defined($cache->{'sort'})) {
237: $sortBy = ':'.$cache->{'sort'};
238: }
239: my @order = sort { $cache->{$a.$sortBy} cmp $cache->{$b.$sortBy} ||
240: $cache->{$a.':fullname'} cmp $cache->{$b.':fullname'} }
241: @sorted1Students;
242:
243: return \@order;
244: }
245:
246: =pod
247:
248: =item &SpaceColumns()
249:
250: Determines the width of all the columns in the chart. It is based on
251: the max of the data for that column and its header.
252:
253: =over 4
254:
255: Input: $students, $studentInformation, $headings, $ChartDB
256:
257: $students: An array pointer to a list of students (username:domain)
258:
259: $studentInformatin: The type of data for the student information. It is
260: used as part of the key in $CacheData.
261:
262: $headings: The name of the student information columns.
263:
264: $ChartDB: The name of the cache database which is opened for read/write.
265:
266: Output: None - All data stored in cache.
267:
268: =back
269:
270: =cut
271:
272: sub SpaceColumns {
273: my ($students,$studentInformation,$headings,$cache)=@_;
274:
275: # Initialize Lengths
276: for(my $index=0; $index<(scalar @$headings); $index++) {
277: my @titleLength=split(//,$headings->[$index]);
278: $cache->{$studentInformation->[$index].':columnWidth'}=
279: scalar @titleLength;
280: }
281:
282: foreach my $name (@$students) {
283: foreach (@$studentInformation) {
284: my @dataLength=split(//,$cache->{$name.':'.$_});
285: my $length=(scalar @dataLength);
286: if($length > $cache->{$_.':columnWidth'}) {
287: $cache->{$_.':columnWidth'}=$length;
288: }
289: }
290: }
291:
292: return;
293: }
294:
295: sub PrepareData {
296: my ($c, $cacheDB, $studentInformation, $headings,$r)=@_;
297:
298: # Test for access to the cache data
299: my $courseID=$ENV{'request.course.id'};
300: my $isRecalculate=0;
301: if(defined($ENV{'form.Recalculate'})) {
302: $isRecalculate=1;
303: }
304:
305: my $isCached = &Apache::loncoursedata::TestCacheData($cacheDB,
306: $isRecalculate);
307: if($isCached < 0) {
308: return "Unable to tie hash to db file.";
309: }
310:
311: # Download class list information if not using cached data
312: my %cache;
313: unless(tie(%cache,'GDBM_File',$cacheDB,&GDBM_WRCREAT(),0640)) {
314: return "Unable to tie hash to db file.";
315: }
316:
317: if(!$isCached) {
318: my $processTopResourceMapReturn=
319: &Apache::loncoursedata::ProcessTopResourceMap(\%cache, $c, $r);
320: if($processTopResourceMapReturn ne 'OK') {
321: untie(%cache);
322: return $processTopResourceMapReturn;
323: }
324: }
325:
326: if($c->aborted()) {
327: untie(%cache);
328: return 'aborted';
329: }
330:
331: my $classlist=&Apache::loncoursedata::DownloadClasslist($courseID,
332: $cache{'ClasslistTimestamp'},
333: $c);
334: foreach (keys(%$classlist)) {
335: if(/^(con_lost|error|no_such_host)/i) {
336: untie(%cache);
337: return "Error getting student data.";
338: }
339: }
340:
341: if($c->aborted()) {
342: untie(%cache);
343: return 'aborted';
344: }
345:
346: # Active is a temporary solution, remember to change
347: Apache::loncoursedata::ProcessClasslist(\%cache,$classlist,$courseID,$c);
348: if($c->aborted()) {
349: untie(%cache);
350: return 'aborted';
351: }
352:
353: &ProcessFormData(\%cache);
354: my $students = &SortStudents(\%cache);
355: &SpaceColumns($students, $studentInformation, $headings, \%cache);
356: $cache{'updateTime:columnWidth'}=24;
357:
358: if($cache{'download'} ne 'false') {
359: my $who = $cache{'download'};
360: my $courseData =
361: &Apache::loncoursedata::DownloadCourseInformation(
362: $who, $courseID,
363: $cache{$who.':lastDownloadTime'});
364: &Apache::loncoursedata::ProcessStudentData(\%cache, $courseData, $who);
365: $cache{'download'} = 'false';
366: } elsif($cache{'DownloadAll'} ne 'false') {
367: $cache{'DownloadAll'} = 'false';
368: my @allStudents;
369: if($cache{'DownloadAll'} eq 'sorted') {
370: @allStudents = @$students;
371: } else {
372: @allStudents = split(':::', $cache{'NamesOfStudents'});
373: }
374: &Create_PrgWin($r);
375: my $count=1;
376: foreach (@allStudents) {
377: &Update_PrgWin(scalar(@allStudents),$count,$_,$r);
378: my $courseData =
379: &Apache::loncoursedata::DownloadCourseInformation(
380: $_, $courseID,
381: $cache{$_.':lastDownloadTime'});
382: &Apache::loncoursedata::ProcessStudentData(\%cache, $courseData,
383: $_);
384: if($c->aborted()) {
385: untie(%cache);
386: return 'aborted';
387: }
388: $count++;
389: }
390: &Close_PrgWin($r);
391: }
392:
393: if($c->aborted()) {
394: untie(%cache);
395: return 'aborted';
396: }
397:
398: untie(%cache);
399:
400: return ('OK', $students);
401: }
402:
403:
404: # Create progress
405: sub Create_PrgWin {
406: my ($r)=@_;
407: $r->print(<<ENDPOP);
408: <script>
409: popwin=open('','popwin','width=400,height=100');
410: popwin.document.writeln('<html><body bgcolor="#88DDFF">'+
411: '<title>LON-CAPA Statistics</title>'+
412: '<h4>Computation Progress</h4>'+
413: '<form name=popremain>'+
414: '<input type=text size=35 name=remaining value=Starting></form>'+
415: '</body></html>');
416: popwin.document.close();
417: </script>
418: ENDPOP
419:
420: $r->rflush();
421: }
422:
423: # update progress
424: sub Update_PrgWin {
425: my ($totalStudents,$index,$name,$r)=@_;
426: $r->print('<script>popwin.document.popremain.remaining.value="'.
427: 'Computing '.$index.'/'.$totalStudents.': '.
428: $name.'";</script>');
429: $r->rflush();
430: }
431:
432: # close Progress Line
433: sub Close_PrgWin {
434: my ($r)=@_;
435: $r->print('<script>popwin.close()</script>');
436: $r->rflush();
437: }
438:
439:
440: sub BuildClasslist {
441: my ($cacheDB,$students,$studentInformation,$headings,$r)=@_;
442:
443: my %cache;
444: unless(tie(%cache,'GDBM_File',$cacheDB,&GDBM_READER(),0640)) {
445: return '<html><body>Unable to tie database.</body></html>';
446: }
447:
448: my $Str='';
449: $Str .= '<table border="0"><tr><td bgcolor="#777777">'."\n";
450: $Str .= '<table border="0" cellpadding="3"><tr bgcolor="#e6ffff">'."\n";
451:
452: my $displayString = '<td align="left"><a href="/adm/statistics?';
453: $displayString .= 'sort=LINKDATA">DISPLAYDATA </a></td>'."\n";
454: $Str .= &Apache::lonhtmlcommon::CreateHeadings(\%cache,
455: $studentInformation,
456: $headings, $displayString);
457: $Str .= '</tr>'."\n";
458:
459: my $alternate=0;
460: foreach (@$students) {
461: my ($username, $domain) = split(':', $_);
462: if($alternate) {
463: $Str .= '<tr bgcolor="#ffffe6">';
464: } else {
465: $Str .= '<tr bgcolor="#ffffc6">';
466: }
467: $alternate = ($alternate + 1) % 2;
468: foreach my $data (@$studentInformation) {
469: $Str .= '<td>';
470: if($data eq 'fullname') {
471: $Str .= '<a href="/adm/statistics?reportSelected=';
472: $Str .= &Apache::lonnet::escape('Student Assessment');
473: $Str .= '&StudentAssessmentStudent=';
474: $Str .= &Apache::lonnet::escape($cache{$_.':'.$data}).'">';
475: $Str .= $cache{$_.':'.$data}.' ';
476: $Str .= '</a>';
477: } elsif($data eq 'updateTime') {
478: $Str .= '<a href="/adm/statistics?reportSelected=';
479: $Str .= &Apache::lonnet::escape('Class list');
480: $Str .= '&download='.$_.'">';
481: $Str .= $cache{$_.':'.$data}.' ';
482: $Str .= ' </a>';
483: } else {
484: $Str .= $cache{$_.':'.$data}.' ';
485: }
486:
487: $Str .= '</td>'."\n";
488: }
489: }
490:
491: $Str .= '</tr>'."\n";
492: $Str .= '</table></td></tr></table>'."\n";
493: $r->print($Str);
494: $r->rflush();
495:
496: untie(%cache);
497:
498: return;
499: }
500:
501: sub CreateMainMenu {
502: my ($status, $reports)=@_;
503:
504: my $Str = '';
505:
506: $Str .= '<table border="0"><tbody><tr>'."\n";
507: $Str .= '<td></td><td></td>'."\n";
508: $Str .= '<td align="center"><b>Analysis Reports:</b></td>'."\n";
509: $Str .= '<td align="center"><b>Student Status:</b></td></tr>'."\n";
510: $Str .= '<tr>'."\n";
511: $Str .= '<td align="center"><input type="submit" name="Refresh" ';
512: $Str .= 'value="Refresh" /></td>'."\n";
513: $Str .= '<td align="center"><input type="submit" name="DownloadAll" ';
514: $Str .= 'value="Update All Student Data" /></td>'."\n";
515: $Str .= '<td align="center">';
516: $Str .= '<select name="reportSelected" onchange="document.';
517: $Str .= 'Statistics.submit()">'."\n";
518:
519: foreach (sort(keys(%$reports))) {
520: next if($_ eq 'reportSelected');
521: $Str .= '<option name="'.$_.'"';
522: if($reports->{'reportSelected'} eq $reports->{$_}) {
523: $Str .= ' selected=""';
524: }
525: $Str .= '>'.$reports->{$_}.'</option>'."\n";
526: }
527: $Str .= '</select></td>'."\n";
528:
529: $Str .= '<td align="center">';
530: $Str .= &Apache::lonhtmlcommon::StatusOptions($status, 'Statistics');
531: $Str .= '</td>'."\n";
532:
533: $Str .= '</tr></tbody></table>'."\n";
534: $Str .= '<hr>'."\n";
535:
536: return $Str;
537: }
538:
539: sub BuildStatistics {
540: my ($r)=@_;
541:
542: my $c = $r->connection;
543: my @studentInformation=('fullname','section','id','domain','username',
544: 'updateTime');
545: my @headings=('Full Name', 'Section', 'PID', 'Domain', 'User Name',
546: 'Last Updated');
547: my $spacing = ' ';
548: my %reports = ('classlist' => 'Class list',
549: 'problem_statistics' => 'Problem Statistics',
550: 'student_assessment' => 'Student Assessment',
551: # 'activitylog' => 'Activity Log',
552: 'reportSelected' => 'Class list');
553:
554: my %cache;
555: my $courseID=$ENV{'request.course.id'};
556: my $cacheDB = "/home/httpd/perl/tmp/$ENV{'user.name'}".
557: "_$ENV{'user.domain'}_$courseID\_statistics.db";
558:
559: my ($returnValue, $students) = &PrepareData($c, $cacheDB,
560: \@studentInformation,
561: \@headings,$r);
562: if($returnValue ne 'OK') {
563: $r->print('<html><body>'.$returnValue."\n".'</body></html>');
564: return OK;
565: }
566:
567: my $GoToPage;
568: if(tie(%cache,'GDBM_File',$cacheDB,&GDBM_READER(),0640)) {
569: $GoToPage = $cache{'reportSelected'};
570: $reports{'reportSelected'} = $cache{'reportSelected'};
571: if(defined($cache{'reportKey'}) &&
572: !exists($reports{$cache{'reportKey'}}) &&
573: $cache{'reportKey'} ne 'false') {
574: $reports{$cache{'reportKey'}} = $cache{'reportSelected'};
575: }
576:
577: if(defined($cache{'OptionResponses'})) {
578: $reports{'problem_analysis'} = 'Problem Analysis';
579: }
580:
581: $r->print(&Apache::lonhtmlcommon::Title('LON-CAPA Statistics'));
582: $r->print('<form name="Statistics" ');
583: $r->print('method="post" action="/adm/statistics">');
584: $r->print(&CreateMainMenu($cache{'Status'}, \%reports));
585: $r->rflush();
586: untie(%cache);
587: } else {
588: $r->print('<html><body>Unable to tie database.</body></html>');
589: return OK;
590: }
591:
592: if($GoToPage eq 'Activity Log') {
593: &Apache::lonproblemstatistics::Activity();
594: } elsif($GoToPage eq 'Problem Statistics') {
595: &Apache::lonproblemstatistics::BuildProblemStatisticsPage($cacheDB,
596: $students,
597: $courseID,
598: $c,$r);
599: } elsif($GoToPage eq 'Problem Analysis') {
600: &Apache::lonproblemanalysis::BuildProblemAnalysisPage($cacheDB, $r);
601: } elsif($GoToPage eq 'Student Assessment') {
602: &Apache::lonstudentassessment::BuildStudentAssessmentPage($cacheDB,
603: $students,
604: $courseID,
605: 'Statistics',
606: \@headings,
607: $spacing,
608: \@studentInformation,
609: $r, $c);
610: } elsif($GoToPage eq 'Analyze') {
611: &Apache::lonproblemanalysis::BuildAnalyzePage($cacheDB, $students,
612: $courseID, $r);
613: } elsif($GoToPage eq 'DoDiffGraph' || $GoToPage eq 'PercentWrongGraph') {
614: &Apache::lonproblemstatistics::BuildGraphicChart($GoToPage,$r,$cacheDB);
615: } elsif($GoToPage eq 'Class list') {
616: &BuildClasslist($cacheDB, $students, \@studentInformation,
617: \@headings, $r);
618: }
619:
620: $r->print('</form>'."\n");
621: $r->print("\n".'</body>'."\n".'</html>');
622: $r->rflush();
623:
624: return OK;
625: }
626:
627: # ================================================================ Main Handler
628:
629: sub handler {
630: my $r=shift;
631:
632: # $jr = $r;
633:
634: unless(&Apache::lonnet::allowed('vgr',$ENV{'request.course.id'})) {
635: $ENV{'user.error.msg'}=
636: $r->uri.":vgr:0:0:Cannot view grades for complete course";
637: return HTTP_NOT_ACCEPTABLE;
638: }
639:
640: # Set document type for header only
641: if($r->header_only) {
642: if ($ENV{'browser.mathml'}) {
643: $r->content_type('text/xml');
644: } else {
645: $r->content_type('text/html');
646: }
647: &Apache::loncommon::no_cache($r);
648: $r->send_http_header;
649: return OK;
650: }
651:
652: unless($ENV{'request.course.fn'}) {
653: my $requrl=$r->uri;
654: $ENV{'user.error.msg'}="$requrl:bre:0:0:Course not initialized";
655: return HTTP_NOT_ACCEPTABLE;
656: }
657:
658: $r->content_type('text/html');
659: $r->send_http_header;
660:
661: &BuildStatistics($r);
662:
663: return OK;
664: }
665: 1;
666: __END__
667:
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>
![[BACK]](/icons/back.gif){kind=icon}
Return to lonstatistics.pm CVS log ![[TXT]](/icons/text.gif){kind=icon}
![[DIR]](/icons/dir.gif){kind=icon}
Up to [LON-CAPA] / loncom / interface