1: # The LearningOnline Network with CAPA
2: # (Publication Handler
3: #
4: # $Id: lonstatistics.pm,v 1.54 2002/11/18 20:39:46 matthew Exp $
5: #
6: # Copyright Michigan State University Board of Trustees
7: #
8: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
9: #
10: # LON-CAPA is free software; you can redistribute it and/or modify
11: # it under the terms of the GNU General Public License as published by
12: # the Free Software Foundation; either version 2 of the License, or
13: # (at your option) any later version.
14: #
15: # LON-CAPA is distributed in the hope that it will be useful,
16: # but WITHOUT ANY WARRANTY; without even the implied warranty of
17: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18: # GNU General Public License for more details.
19: #
20: # You should have received a copy of the GNU General Public License
21: # along with LON-CAPA; if not, write to the Free Software
22: # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
23: #
24: # /home/httpd/html/adm/gpl.txt
25: #
26: # http://www.lon-capa.org/
27: #
28: # (Navigate problems for statistical reports
29: # YEAR=2001
30: # 5/5,7/9,7/25/1,8/11,9/13,9/26,10/5,10/9,10/22,10/26 Behrouz Minaei
31: # 11/1,11/4,11/16,12/14,12/16,12/18,12/20,12/31 Behrouz Minaei
32: # YEAR=2002
33: # 1/22,2/1,2/6,2/25,3/2,3/6,3/17,3/21,3/22,3/26,4/7,5/6 Behrouz Minaei
34: # 5/12,5/14,5/15,5/19,5/26,7/16,25/7,29/7 Behrouz Minaei
35: #
36: ###
37:
38: package Apache::lonstatistics;
39:
40: use strict;
41: use Apache::Constants qw(:common :http);
42: use Apache::lonnet();
43: use Apache::lonhomework;
44: use Apache::loncommon;
45: use Apache::loncoursedata;
46: use Apache::lonhtmlcommon;
47: use Apache::lonproblemanalysis;
48: use Apache::lonproblemstatistics;
49: use Apache::lonstudentassessment;
50: use Apache::lonpercentage;
51: use HTML::TokeParser;
52: use GDBM_File;
53:
54:
55: sub CheckFormElement {
56: my ($cache, $ENVName, $cacheName, $default)=@_;
57:
58: if(defined($ENV{'form.'.$ENVName})) {
59: $cache->{$cacheName} = $ENV{'form.'.$ENVName};
60: } elsif(!defined($cache->{$cacheName})) {
61: $cache->{$cacheName} = $default;
62: }
63:
64: return;
65: }
66:
67: sub ProcessFormData{
68: my ($cache)=@_;
69:
70: $cache->{'reportKey'} = 'false';
71:
72: &Apache::loncommon::get_unprocessed_cgi($ENV{'QUERY_STRING'},
73: ['sort','download',
74: 'reportSelected',
75: 'StudentAssessmentStudent',
76: 'ProblemStatisticsSort']);
77: &CheckFormElement($cache, 'Status', 'Status', 'Active');
78: &CheckFormElement($cache, 'postdata', 'reportSelected', 'Class list');
79: &CheckFormElement($cache, 'reportSelected', 'reportSelected',
80: 'Class list');
81: $cache->{'reportSelected'} =
82: &Apache::lonnet::unescape($cache->{'reportSelected'});
83: &CheckFormElement($cache, 'DownloadAll', 'DownloadAll', 'false');
84: &CheckFormElement($cache, 'sort', 'sort', 'fullname');
85: &CheckFormElement($cache, 'download', 'download', 'false');
86: &CheckFormElement($cache, 'StatisticsMaps',
87: 'StatisticsMaps', 'All Maps');
88: &CheckFormElement($cache, 'StatisticsProblemSelect',
89: 'StatisticsProblemSelect', 'All Problems');
90: &CheckFormElement($cache, 'StatisticsPartSelect',
91: 'StatisticsPartSelect', 'All Parts');
92: if(defined($ENV{'form.Section'})) {
93: my @sectionsSelected = (ref($ENV{'form.Section'}) ?
94: @{$ENV{'form.Section'}} :
95: ($ENV{'form.Section'}));
96: $cache->{'sectionsSelected'} = join(':', @sectionsSelected);
97: } elsif(!defined($cache->{'sectionsSelected'})) {
98: $cache->{'sectionsSelected'} = $cache->{'sectionList'};
99: }
100:
101: # student assessment
102: if(defined($ENV{'form.CreateStudentAssessment'}) ||
103: defined($ENV{'form.NextStudent'}) ||
104: defined($ENV{'form.PreviousStudent'})) {
105: $cache->{'reportSelected'} = 'Student Assessment';
106: }
107: if(defined($ENV{'form.NextStudent'})) {
108: $cache->{'StudentAssessmentMove'} = 'next';
109: } elsif(defined($ENV{'form.PreviousStudent'})) {
110: $cache->{'StudentAssessmentMove'} = 'previous';
111: } else {
112: $cache->{'StudentAssessmentMove'} = 'selected';
113: }
114: &CheckFormElement($cache, 'StudentAssessmentStudent',
115: 'StudentAssessmentStudent', 'All Students');
116: $cache->{'StudentAssessmentStudent'} =
117: &Apache::lonnet::unescape($cache->{'StudentAssessmentStudent'});
118: &CheckFormElement($cache, 'DefaultColumns', 'DefaultColumns', 'false');
119:
120: # Problem analysis
121: &CheckFormElement($cache, 'Interval', 'Interval', '1');
122:
123: # ProblemStatistcs
124: &CheckFormElement($cache, 'DisplayCSVFormat',
125: 'DisplayFormat', 'Display Table Format');
126: &CheckFormElement($cache, 'ProblemStatisticsAscend',
127: 'ProblemStatisticsAscend', 'Ascending');
128: &CheckFormElement($cache, 'ProblemStatisticsSort',
129: 'ProblemStatisticsSort', 'Homework Sets Order');
130: &CheckFormElement($cache, 'DisplayLegend', 'DisplayLegend',
131: 'Hide Legend');
132: &CheckFormElement($cache, 'SortProblems', 'SortProblems',
133: 'Sort Within Sequence');
134:
135: # Search only form elements
136: my @headingColumns=();
137: my @sequenceColumns=();
138: my $foundColumn = 0;
139: if(defined($ENV{'form.ReselectColumns'})) {
140: my @reselected = (ref($ENV{'form.ReselectColumns'}) ?
141: @{$ENV{'form.ReselectColumns'}}
142: : ($ENV{'form.ReselectColumns'}));
143: foreach (@reselected) {
144: if(/HeadingColumn/) {
145: push(@headingColumns, $_);
146: $foundColumn = 1;
147: } elsif(/SequenceColumn/) {
148: push(@sequenceColumns, $_);
149: $foundColumn = 1;
150: }
151: }
152: }
153:
154: $cache->{'reportKey'} = 'false';
155: if($cache->{'reportSelected'} eq 'Analyze') {
156: $cache->{'reportKey'} = 'Analyze';
157: } elsif($cache->{'reportSelected'} eq 'DoDiffGraph') {
158: $cache->{'reportKey'} = 'DoDiffGraph';
159: } elsif($cache->{'reportSelected'} eq 'PercentWrongGraph') {
160: $cache->{'reportKey'} = 'PercentWrongGraph';
161: }
162:
163: if(defined($ENV{'form.DoDiffGraph'})) {
164: $cache->{'reportSelected'} = 'DoDiffGraph';
165: $cache->{'reportKey'} = 'DoDiffGraph';
166: } elsif(defined($ENV{'form.PercentWrongGraph'})) {
167: $cache->{'reportSelected'} = 'PercentWrongGraph';
168: $cache->{'reportKey'} = 'PercentWrongGraph';
169: }
170:
171: foreach (keys(%ENV)) {
172: if(/form\.Analyze/) {
173: $cache->{'reportSelected'} = 'Analyze';
174: $cache->{'reportKey'} = 'Analyze';
175: my $data;
176: (undef, $data)=split(':::', $_);
177: $cache->{'AnalyzeInfo'}=$data;
178: } elsif(/form\.HeadingColumn/) {
179: my $value = $_;
180: $value =~ s/form\.//;
181: push(@headingColumns, $value);
182: $foundColumn=1;
183: } elsif(/form\.SequenceColumn/) {
184: my $value = $_;
185: $value =~ s/form\.//;
186: push(@sequenceColumns, $value);
187: $foundColumn=1;
188: }
189: }
190:
191: if($foundColumn) {
192: $cache->{'HeadingsFound'} = join(':', @headingColumns);
193: $cache->{'SequencesFound'} = join(':', @sequenceColumns);;
194: }
195: if(!defined($cache->{'HeadingsFound'}) ||
196: $cache->{'DefaultColumns'} ne 'false') {
197: $cache->{'HeadingsFound'}='HeadingColumnFull Name';
198: }
199: if(!defined($cache->{'SequencesFound'}) ||
200: $cache->{'DefaultColumns'} ne 'false') {
201: $cache->{'SequencesFound'}='All Sequences';
202: }
203: $cache->{'DefaultColumns'} = 'false';
204:
205: return;
206: }
207:
208: =pod
209:
210: =item &SortStudents()
211:
212: Determines which students to display and in which order. Which are
213: displayed are determined by their status(active/expired). The order
214: is determined by the sort button pressed (default to username). The
215: type of sorting is username, lastname, or section.
216:
217: =over 4
218:
219: Input: $students, $CacheData
220:
221: $students: A array pointer to a list of students (username:domain)
222:
223: $CacheData: A pointer to the hash tied to the cached data
224:
225: Output: \@order
226:
227: @order: An ordered list of students (username:domain)
228:
229: =back
230:
231: =cut
232:
233: sub SortStudents {
234: my ($cache)=@_;
235:
236: my @students = split(':::',$cache->{'NamesOfStudents'});
237: my @sorted1Students=();
238: foreach (@students) {
239: if($cache->{'Status'} eq 'Any' ||
240: $cache->{$_.':Status'} eq $cache->{'Status'}) {
241: push(@sorted1Students, $_);
242: }
243: }
244:
245: my $sortBy = '';
246: if(defined($cache->{'sort'})) {
247: $sortBy = ':'.$cache->{'sort'};
248: } else {
249: $sortBy = ':fullname';
250: }
251: my @order = sort { lc($cache->{$a.$sortBy}) cmp lc($cache->{$b.$sortBy}) ||
252: lc($cache->{$a.':fullname'}) cmp lc($cache->{$b.':fullname'}) }
253: @sorted1Students;
254:
255: return \@order;
256: }
257:
258: =pod
259:
260: =item &SpaceColumns()
261:
262: Determines the width of all the columns in the chart. It is based on
263: the max of the data for that column and its header.
264:
265: =over 4
266:
267: Input: $students, $studentInformation, $headings, $ChartDB
268:
269: $students: An array pointer to a list of students (username:domain)
270:
271: $studentInformatin: The type of data for the student information. It is
272: used as part of the key in $CacheData.
273:
274: $headings: The name of the student information columns.
275:
276: $ChartDB: The name of the cache database which is opened for read/write.
277:
278: Output: None - All data stored in cache.
279:
280: =back
281:
282: =cut
283:
284: sub SpaceColumns {
285: my ($students,$studentInformation,$headings,$cache)=@_;
286:
287: # Initialize Lengths
288: for(my $index=0; $index<(scalar @$headings); $index++) {
289: my @titleLength=split(//,$headings->[$index]);
290: $cache->{$studentInformation->[$index].':columnWidth'}=
291: scalar @titleLength;
292: }
293:
294: foreach my $name (@$students) {
295: foreach (@$studentInformation) {
296: my @dataLength=split(//,$cache->{$name.':'.$_});
297: my $length=(scalar @dataLength);
298: if($length > $cache->{$_.':columnWidth'}) {
299: $cache->{$_.':columnWidth'}=$length;
300: }
301: }
302: }
303:
304: return;
305: }
306:
307: sub PrepareData {
308: my ($c, $cacheDB, $studentInformation, $headings,$r)=@_;
309:
310: # Test for access to the cache data
311: my $courseID=$ENV{'request.course.id'};
312: my $isRecalculate=0;
313: if(defined($ENV{'form.Recalculate'})) {
314: $isRecalculate=1;
315: }
316:
317: my $isCached = &Apache::loncoursedata::TestCacheData($cacheDB,
318: $isRecalculate);
319: if($isCached < 0) {
320: return "Unable to tie hash to db file.";
321: }
322:
323: # Download class list information if not using cached data
324: my %cache;
325: unless(tie(%cache,'GDBM_File',$cacheDB,&GDBM_WRCREAT(),0640)) {
326: return "Unable to tie hash to db file.";
327: }
328:
329: # if(!$isCached) {
330: my $processTopResourceMapReturn=
331: &Apache::loncoursedata::ProcessTopResourceMap(\%cache, $c);
332: if($processTopResourceMapReturn ne 'OK') {
333: untie(%cache);
334: return $processTopResourceMapReturn;
335: }
336: # }
337:
338: if($c->aborted()) {
339: untie(%cache);
340: return 'aborted';
341: }
342:
343: my $classlist=&Apache::loncoursedata::DownloadClasslist($courseID,
344: $cache{'ClasslistTimestamp'},
345: $c);
346: foreach (keys(%$classlist)) {
347: if(/^(con_lost|error|no_such_host)/i) {
348: untie(%cache);
349: return "Error getting student data.";
350: }
351: }
352:
353: if($c->aborted()) {
354: untie(%cache);
355: return 'aborted';
356: }
357:
358: # Active is a temporary solution, remember to change
359: Apache::loncoursedata::ProcessClasslist(\%cache,$classlist,$courseID,$c);
360: if($c->aborted()) {
361: untie(%cache);
362: return 'aborted';
363: }
364:
365: &ProcessFormData(\%cache);
366: my $students = &SortStudents(\%cache);
367: &SpaceColumns($students, $studentInformation, $headings, \%cache);
368: $cache{'updateTime:columnWidth'}=24;
369:
370: my $download = $cache{'download'};
371: my $downloadAll = $cache{'DownloadAll'};
372: my @allStudents=();
373: if($download ne 'false') {
374: $cache{'download'} = 'false';
375: } elsif($downloadAll ne 'false') {
376: $cache{'DownloadAll'} = 'false';
377: if($downloadAll eq 'sorted') {
378: @allStudents = @$students;
379: } else {
380: @allStudents = split(':::', $cache{'NamesOfStudents'});
381: }
382: }
383:
384: untie(%cache);
385:
386: if($download ne 'false') {
387: my @who = ($download);
388: if(&Apache::loncoursedata::DownloadStudentCourseData(\@who, 'false',
389: $cacheDB, 'true',
390: 'false', $courseID,
391: $r, $c) ne 'OK') {
392: return 'Stop at download individual';
393: }
394: } elsif($downloadAll ne 'false') {
395: if(&Apache::loncoursedata::DownloadStudentCourseData(\@allStudents,
396: 'false',
397: $cacheDB, 'true',
398: 'true', $courseID,
399: $r, $c) ne 'OK') {
400: return 'Stop at download all';
401: }
402: }
403:
404: return ('OK', $students);
405: }
406:
407: sub BuildClasslist {
408: my ($cacheDB,$students,$studentInformation,$headings,$r)=@_;
409:
410: my %cache;
411: unless(tie(%cache,'GDBM_File',$cacheDB,&GDBM_READER(),0640)) {
412: return '<html><body>Unable to tie database.</body></html>';
413: }
414:
415: my $Str='';
416: $Str .= '<table border="0"><tr><td bgcolor="#777777">'."\n";
417: $Str .= '<table border="0" cellpadding="3"><tr bgcolor="#e6ffff">'."\n";
418:
419: my $displayString = '<td align="left"><a href="/adm/statistics?';
420: $displayString .= 'sort=LINKDATA">DISPLAYDATA </a></td>'."\n";
421: $Str .= &Apache::lonhtmlcommon::CreateHeadings(\%cache,
422: $studentInformation,
423: $headings, $displayString);
424: $Str .= '</tr>'."\n";
425:
426: my $alternate=0;
427: foreach (@$students) {
428: my ($username, $domain) = split(':', $_);
429: if($alternate) {
430: $Str .= '<tr bgcolor="#ffffe6">';
431: } else {
432: $Str .= '<tr bgcolor="#ffffc6">';
433: }
434: $alternate = ($alternate + 1) % 2;
435: foreach my $data (@$studentInformation) {
436: $Str .= '<td>';
437: if($data eq 'fullname') {
438: $Str .= '<a href="/adm/statistics?reportSelected=';
439: $Str .= &Apache::lonnet::escape('Student Assessment');
440: $Str .= '&StudentAssessmentStudent=';
441: $Str .= &Apache::lonnet::escape($cache{$_.':'.$data}).'">';
442: $Str .= $cache{$_.':'.$data}.' ';
443: $Str .= '</a>';
444: } elsif($data eq 'updateTime') {
445: $Str .= '<a href="/adm/statistics?reportSelected=';
446: $Str .= &Apache::lonnet::escape('Class list');
447: $Str .= '&download='.$_.'">';
448: $Str .= $cache{$_.':'.$data}.' ';
449: $Str .= ' </a>';
450: } else {
451: $Str .= $cache{$_.':'.$data}.' ';
452: }
453:
454: $Str .= '</td>'."\n";
455: }
456: }
457:
458: $Str .= '</tr>'."\n";
459: $Str .= '</table></td></tr></table>'."\n";
460: $r->print($Str);
461: $r->rflush();
462:
463: untie(%cache);
464:
465: return;
466: }
467:
468: sub CreateMainMenu {
469: my ($status, $reports)=@_;
470:
471: my $Str = '';
472:
473: $Str .= '<table border="0"><tbody><tr>'."\n";
474: $Str .= '<td></td><td></td>'."\n";
475: $Str .= '<td align="center"><b>Analysis Reports:</b></td>'."\n";
476: $Str .= '<td align="center"><b>Student Status:</b></td></tr>'."\n";
477: $Str .= '<tr>'."\n";
478: $Str .= '<td align="center"><input type="submit" name="Refresh" ';
479: $Str .= 'value="Refresh" /></td>'."\n";
480: $Str .= '<td align="center"><input type="submit" name="DownloadAll" ';
481: $Str .= 'value="Update All Student Data" /></td>'."\n";
482: $Str .= '<td align="center">';
483: $Str .= '<select name="reportSelected" onchange="document.';
484: $Str .= 'Statistics.submit()">'."\n";
485:
486: foreach (sort(keys(%$reports))) {
487: next if($_ eq 'reportSelected');
488: $Str .= '<option name="'.$_.'"';
489: if($reports->{'reportSelected'} eq $reports->{$_}) {
490: $Str .= ' selected=""';
491: }
492: $Str .= '>'.$reports->{$_}.'</option>'."\n";
493: }
494: $Str .= '</select></td>'."\n";
495:
496: $Str .= '<td align="center">';
497: $Str .= &Apache::lonhtmlcommon::StatusOptions($status, 'Statistics');
498: $Str .= '</td>'."\n";
499:
500: $Str .= '</tr></tbody></table>'."\n";
501: $Str .= '<hr>'."\n";
502:
503: return $Str;
504: }
505:
506: sub BuildStatistics {
507: my ($r)=@_;
508:
509: my $c = $r->connection;
510: my @studentInformation=('fullname','section','id','domain','username',
511: 'updateTime');
512: my @headings=('Full Name', 'Section', 'PID', 'Domain', 'User Name',
513: 'Last Updated');
514: my $spacing = ' ';
515:
516: my %reports = ('classlist' => 'Class list',
517: 'problem_statistics' => 'Problem Statistics',
518: 'student_assessment' => 'Student Assessment',
519: 'percentage' => 'Percentage Graphs',
520: # 'activitylog' => 'Activity Log',
521: 'reportSelected' => 'Class list');
522:
523: my %cache;
524: my $courseID=$ENV{'request.course.id'};
525: my $cacheDB = "/home/httpd/perl/tmp/$ENV{'user.name'}".
526: "_$ENV{'user.domain'}_$courseID\_statistics.db";
527:
528: $r->print(&Apache::lonhtmlcommon::Title('Course Statistics and Charts'));
529:
530: my ($returnValue, $students) = &PrepareData($c, $cacheDB,
531: \@studentInformation,
532: \@headings,$r);
533: if($returnValue ne 'OK') {
534: $r->print($returnValue."\n".'</body></html>');
535: return OK;
536: }
537: if(!$c->aborted()) {
538: &Apache::loncoursedata::CheckForResidualDownload($cacheDB,
539: 'true', 'true',
540: $courseID,
541: $r, $c);
542: }
543:
544: my $GoToPage;
545: if(tie(%cache,'GDBM_File',$cacheDB,&GDBM_READER(),0640)) {
546: $GoToPage = $cache{'reportSelected'};
547: $reports{'reportSelected'} = $cache{'reportSelected'};
548: if(defined($cache{'reportKey'}) &&
549: !exists($reports{$cache{'reportKey'}}) &&
550: $cache{'reportKey'} ne 'false') {
551: $reports{$cache{'reportKey'}} = $cache{'reportSelected'};
552: }
553:
554: if(defined($cache{'OptionResponses'})) {
555: $reports{'problem_analysis'} = 'Option Response Analysis';
556: }
557:
558: $r->print('<form name="Statistics" ');
559: $r->print('method="post" action="/adm/statistics">');
560: $r->print(&CreateMainMenu($cache{'Status'}, \%reports));
561: $r->rflush();
562: untie(%cache);
563: } else {
564: $r->print('<html><body>Unable to tie database.</body></html>');
565: return OK;
566: }
567:
568: if($GoToPage eq 'Activity Log') {
569: &Apache::lonproblemstatistics::Activity();
570: } elsif($GoToPage eq 'Problem Statistics') {
571: &Apache::lonproblemstatistics::BuildProblemStatisticsPage($cacheDB,
572: $students,
573: $courseID,
574: $c,$r);
575: } elsif($GoToPage eq 'Option Response Analysis') {
576: &Apache::lonproblemanalysis::BuildProblemAnalysisPage($cacheDB, $r);
577: } elsif($GoToPage eq 'Student Assessment') {
578: &Apache::lonstudentassessment::BuildStudentAssessmentPage($cacheDB,
579: $students,
580: $courseID,
581: 'Statistics',
582: \@headings,
583: $spacing,
584: \@studentInformation,
585: $r, $c);
586: } elsif($GoToPage eq 'Analyze') {
587: &Apache::lonproblemanalysis::BuildAnalyzePage($cacheDB, $students,
588: $courseID, $r);
589: } elsif($GoToPage eq 'DoDiffGraph' || $GoToPage eq 'PercentWrongGraph') {
590: my $courseDescription = $ENV{'course.'.$courseID.'.description'};
591: $courseDescription =~ s/\ /"_"/eg;
592: &Apache::lonproblemstatistics::BuildGraphicChart($GoToPage, $cacheDB,
593: $courseDescription,
594: $students, $courseID,
595: $r, $c);
596: } elsif($GoToPage eq 'Class list') {
597: &BuildClasslist($cacheDB, $students, \@studentInformation,
598: \@headings, $r);
599: } elsif($GoToPage eq 'Percentage Graphs') {
600: &Apache::lonpercentage::BuildPercentageGraph($cacheDB, $students,
601: $courseID, $c, $r);
602: }
603:
604: $r->print('</form>'."\n");
605: $r->print("\n".'</body>'."\n".'</html>');
606: $r->rflush();
607:
608: return OK;
609: }
610:
611: # ================================================================ Main Handler
612:
613: sub handler {
614: my $r=shift;
615:
616: # $jr = $r;
617:
618: my $loaderror=&Apache::lonnet::overloaderror($r);
619: if ($loaderror) { return $loaderror; }
620: $loaderror=
621: &Apache::lonnet::overloaderror($r,
622: $ENV{'course.'.$ENV{'request.course.id'}.'.home'});
623: if ($loaderror) { return $loaderror; }
624:
625: unless(&Apache::lonnet::allowed('vgr',$ENV{'request.course.id'})) {
626: $ENV{'user.error.msg'}=
627: $r->uri.":vgr:0:0:Cannot view grades for complete course";
628: return HTTP_NOT_ACCEPTABLE;
629: }
630:
631: # Set document type for header only
632: if($r->header_only) {
633: if ($ENV{'browser.mathml'}) {
634: $r->content_type('text/xml');
635: } else {
636: $r->content_type('text/html');
637: }
638: &Apache::loncommon::no_cache($r);
639: $r->send_http_header;
640: return OK;
641: }
642:
643: unless($ENV{'request.course.fn'}) {
644: my $requrl=$r->uri;
645: $ENV{'user.error.msg'}="$requrl:bre:0:0:Course not initialized";
646: return HTTP_NOT_ACCEPTABLE;
647: }
648:
649: $r->content_type('text/html');
650: $r->send_http_header;
651:
652: &BuildStatistics($r);
653:
654: return OK;
655: }
656: 1;
657: __END__
658:
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>