1: # The LearningOnline Network with CAPA
2: # Handler for requesting to have slots added to a students record
3: #
4: # $Id: slotrequest.pm,v 1.28 2005/11/02 22:46:12 albertel Exp $
5: #
6: # Copyright Michigan State University Board of Trustees
7: #
8: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
9: #
10: # LON-CAPA is free software; you can redistribute it and/or modify
11: # it under the terms of the GNU General Public License as published by
12: # the Free Software Foundation; either version 2 of the License, or
13: # (at your option) any later version.
14: #
15: # LON-CAPA is distributed in the hope that it will be useful,
16: # but WITHOUT ANY WARRANTY; without even the implied warranty of
17: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18: # GNU General Public License for more details.
19: #
20: # You should have received a copy of the GNU General Public License
21: # along with LON-CAPA; if not, write to the Free Software
22: # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
23: #
24: # /home/httpd/html/adm/gpl.txt
25: #
26: # http://www.lon-capa.org/
27: #
28: ###
29:
30: package Apache::slotrequest;
31:
32: use strict;
33: use Apache::Constants qw(:common :http :methods);
34: use Apache::loncommon();
35: use Apache::lonlocal;
36: use Apache::lonnet;
37: use Date::Manip;
38:
39: sub fail {
40: my ($r,$code)=@_;
41: if ($code eq 'not_valid') {
42: $r->print('<p>'.&mt('Unable to understand what resource you wanted to sign up for.').'</p>');
43:
44: } elsif ($code eq 'not_allowed') {
45: $r->print('<p>'.&mt('Not allowed to sign up or change reservations at this time.').'</p>');
46: } else {
47: $r->print('<p>'.&mt('Failed.').'</p>');
48: }
49:
50: $r->print('<p><a href="/adm/flip?postdata=return:">'.
51: &mt('Return to last resource').'</a></p>');
52: &end_page($r);
53: }
54:
55: sub start_page {
56: my ($r,$title)=@_;
57: my $html=&Apache::lonxml::xmlbegin();
58: $r->print($html.'<head><title>'.&mt($title).'</title></head>');
59: $r->print(&Apache::loncommon::bodytag($title));
60: }
61:
62: sub end_page {
63: my ($r)=@_;
64: $r->print(&Apache::loncommon::endbodytag().'</html>');
65: }
66:
67: =pod
68:
69: slot_reservations db
70: - keys are
71: - slotname\0id -> value is an hashref of
72: name -> user@domain of holder
73: timestamp -> timestamp of reservation
74: symb -> symb of resource that it is reserved for
75:
76: =cut
77:
78: sub get_course {
79: (undef,my $courseid)=&Apache::lonxml::whichuser();
80: my $cdom=$env{'course.'.$courseid.'.domain'};
81: my $cnum=$env{'course.'.$courseid.'.num'};
82: return ($cnum,$cdom);
83: }
84:
85: sub get_reservation_ids {
86: my ($slot_name)=@_;
87:
88: my ($cnum,$cdom)=&get_course();
89:
90: my %consumed=&Apache::lonnet::dump('slot_reservations',$cdom,$cnum,
91: "^$slot_name\0");
92:
93: my ($tmp)=%consumed;
94: if ($tmp=~/^error: 2 / ) {
95: return 0;
96: }
97: return keys(%consumed);
98: }
99:
100: sub space_available {
101: my ($slot_name,$slot)=@_;
102: my $max=$slot->{'maxspace'};
103:
104: if (!defined($max)) { return 1; }
105:
106: my $consumed=scalar(&get_reservation_ids($slot_name));
107: if ($consumed < $max) {
108: return 1
109: }
110: return 0;
111: }
112:
113: sub check_for_reservation {
114: my ($symb)=@_;
115: my $student = &Apache::lonnet::EXT("resource.0.availablestudent", $symb,
116: $env{'user.domain'}, $env{'user.name'});
117:
118: my $course = &Apache::lonnet::EXT("resource.0.available", $symb,
119: $env{'user.domain'}, $env{'user.name'});
120: my @slots = (split(/:/,$student), split(/:/, $course));
121:
122: &Apache::lonxml::debug(" slot list is ".join(':',@slots));
123:
124: my ($cnum,$cdom)=&get_course();
125: my %slots=&Apache::lonnet::get('slots', [@slots], $cdom, $cnum);
126:
127: foreach my $slot_name (@slots) {
128: next if (!defined($slots{$slot_name}) ||
129: !ref($slots{$slot_name}));
130: &Apache::lonxml::debug(time." $slot_name ".
131: $slots{$slot_name}->{'starttime'}." -- ".
132: $slots{$slot_name}->{'startreserve'});
133: if ($slots{$slot_name}->{'endtime'} > time &&
134: $slots{$slot_name}->{'startreserve'} < time) {
135: # between start of reservation times and end of slot
136: return($slot_name, $slots{$slot_name});
137: }
138: }
139: return (undef,undef);
140: }
141:
142: sub check_for_conflict {
143: my ($symb,$new_slot_name)=@_;
144: my $student = &Apache::lonnet::EXT("resource.0.availablestudent", $symb,
145: $env{'user.domain'}, $env{'user.name'});
146: my $course = &Apache::lonnet::EXT("resource.0.available", $symb,
147: $env{'user.domain'}, $env{'user.name'});
148: my @slots = (split(/:/,$student), split(/:/, $course));
149: my ($cnum,$cdom)=&get_course();
150: my %slots=&Apache::lonnet::get('slots', [@slots], $cdom, $cnum);
151: foreach my $slot_name (@slots) {
152: next if (!defined($slots{$slot_name}) ||
153: !ref($slots{$slot_name}));
154:
155: next if (!defined($slots{$slot_name}->{'uniqueperiod'}) ||
156: !ref($slots{$slot_name}->{'uniqueperiod'}));
157: my ($start,$end)=@{$slots{$slot_name}->{'uniqueperiod'}};
158: if ($start<time && time < $end) {
159: return $slot_name;
160: }
161: }
162: return undef;
163:
164: }
165:
166: sub make_reservation {
167: my ($slot_name,$slot,$symb)=@_;
168:
169: my ($cnum,$cdom)=&get_course();
170:
171: my $value=&Apache::lonnet::EXT("resource.0.availablestudent",$symb,
172: $env{'user.domain'},$env{'user.name'});
173: &Apache::lonxml::debug("value is $value<br />");
174: foreach my $other_slot (split(/:/, $value)) {
175: if ($other_slot eq $slot_name) {
176: my %consumed=&Apache::lonnet::dump('slot_reservations', $cdom,
177: $cnum, "^$slot_name\0");
178:
179: my $me=$env{'user.name'}.'@'.$env{'user.domain'};
180: foreach my $key (keys(%consumed)) {
181: if ($consumed{$key}->{'name'} eq $me) {
182: my $num=(split('\0',$key))[1];
183: return -$num;
184: }
185: }
186: }
187: }
188:
189: my $max=$slot->{'maxspace'};
190: if (!defined($max)) { $max=99999; }
191:
192: my (@ids)=&get_reservation_ids($slot_name);
193:
194: my $last=0;
195: foreach my $id (@ids) {
196: my $num=(split('\0',$id))[1];
197: if ($num > $last) { $last=$num; }
198: }
199:
200: my $wanted=$last+1;
201: &Apache::lonxml::debug("wanted $wanted<br />");
202: if (scalar(@ids) >= $max) {
203: # full up
204: return undef;
205: }
206:
207: my %reservation=('name' => $env{'user.name'}.'@'.$env{'user.domain'},
208: 'timestamp' => time,
209: 'symb' => $symb);
210:
211: my $success=&Apache::lonnet::newput('slot_reservations',
212: {"$slot_name\0$wanted" =>
213: \%reservation},
214: $cdom, $cnum);
215:
216: if ($success eq 'ok') {
217: my $new_value=$slot_name;
218: if ($value) {
219: $new_value=$value.':'.$new_value;
220: }
221: my $result=&Apache::lonparmset::storeparm_by_symb($symb,
222: '0_availablestudent',
223: 1, $new_value, 'string',
224: $env{'user.name'},
225: $env{'user.domain'});
226: &Apache::lonxml::debug("hrrm $result");
227: return $wanted;
228: }
229:
230: # someone else got it
231: return undef;
232: }
233:
234: sub release_slot {
235: my ($r,$symb,$slot_name,$inhibit_return_link)=@_;
236:
237: if ($slot_name eq '') { $slot_name=$env{'form.slotname'}; }
238: my ($cnum,$cdom)=&get_course();
239:
240: # get parameter string, check for existance, rebuild string with the slot
241:
242: my @slots = split(/:/,&Apache::lonnet::EXT("resource.0.availablestudent",
243: $symb,$env{'user.domain'},
244: $env{'user.name'}));
245: my @new_slots;
246: foreach my $exist_slot (@slots) {
247: if ($exist_slot eq $slot_name) { next; }
248: push(@new_slots,$exist_slot);
249: }
250: my $new_param = join(':',@new_slots);
251:
252: # get slot reservations, check if user has one, if so remove reservation
253: my %consumed=&Apache::lonnet::dump('slot_reservations',$cdom,$cnum,
254: "^$slot_name\0");
255: foreach my $entry (keys(%consumed)) {
256: if ( $consumed{$entry}->{'name'} eq
257: ($env{'user.name'}.'@'.$env{'user.domain'}) ) {
258: &Apache::lonnet::del('slot_reservations',[$entry],
259: $cdom,$cnum);
260: }
261: }
262: # store new parameter string
263: my $result=&Apache::lonparmset::storeparm_by_symb($symb,
264: '0_availablestudent',
265: 1, $new_param, 'string',
266: $env{'user.name'},
267: $env{'user.domain'});
268: my %slot=&Apache::lonnet::get_slot($slot_name);
269: my $description=&get_description($env{'form.slotname'},\%slot);
270: $r->print("<p>Released Reservation: $description</p>");
271: if (!$inhibit_return_link) {
272: $r->print('<p><a href="/adm/flip?postdata=return:">'.
273: &mt('Return to last resource').'</a></p>');
274: }
275: return 1;
276: }
277:
278: sub get_slot {
279: my ($r,$symb)=@_;
280:
281: my $slot_name=&check_for_conflict($symb,$env{'form.slotname'});
282: if ($slot_name) {
283: my %slot=&Apache::lonnet::get_slot($slot_name);
284: my $description1=&get_description($slot_name,\%slot);
285: %slot=&Apache::lonnet::get_slot($env{'form.slotname'});
286: my $description2=&get_description($env{'form.slotname'},\%slot);
287: $r->print("<p>Already have a reservation: $description1</p>");
288: if ($slot_name ne $env{'form.slotname'}) {
289: $r->print(<<STUFF);
290: <form method="POST" action="/adm/slotrequest">
291: <input type="hidden" name="symb" value="$env{'form.symb'}" />
292: <input type="hidden" name="slotname" value="$env{'form.slotname'}" />
293: <input type="hidden" name="releaseslot" value="$slot_name" />
294: <input type="hidden" name="command" value="change" />
295: STUFF
296: $r->print("<p>You can either ");
297: $r->print(<<STUFF);
298: <input type="submit" name="change" value="Change" />
299: STUFF
300: $r->print(' your reservation from <b>'.$description1.'</b> to <b>'.
301: $description2.
302: '</b> <br />or <a href="/adm/flip?postdata=return:">'.
303: &mt('Return to last resource').'</a></p>');
304: $r->print(<<STUFF);
305: </form>
306: STUFF
307: } else {
308: $r->print('<p><a href="/adm/flip?postdata=return:">'.
309: &mt('Return to last resource').'</a></p>');
310: }
311: return;
312: }
313: my %slot=&Apache::lonnet::get_slot($env{'form.slotname'});
314: my $reserved=&make_reservation($env{'form.slotname'},
315: \%slot,$symb);
316: my $description=&get_description($env{'form.slotname'},\%slot);
317: if (defined($reserved)) {
318: if ($reserved > -1) {
319: $r->print("<p>Success: $description</p>");
320: $r->print('<p><a href="/adm/flip?postdata=return:">'.
321: &mt('Return to last resource').'</a></p>');
322: return;
323: } elsif ($reserved < 0) {
324: $r->print("<p>Already reserved: $description</p>");
325: $r->print('<p><a href="/adm/flip?postdata=return:">'.
326: &mt('Return to last resource').'</a></p>');
327: return;
328: }
329: }
330:
331: my %lt=('request'=>"Availibility list",
332: 'try' =>'Try again');
333: %lt=&Apache::lonlocal::texthash(%lt);
334:
335: $r->print(<<STUFF);
336: <p> <font color="red">Failed</font> to reserve a spot for $description. </p>
337: <p>
338: <form method="POST" action="/adm/slotrequest">
339: <input type="submit" name="Try Again" value="$lt{'try'}" />
340: <input type="hidden" name="symb" value="$env{'form.symb'}" />
341: <input type="hidden" name="slotname" value="$env{'form.slotname'}" />
342: <input type="hidden" name="command" value="get" />
343: </form>
344: ?
345: </p>
346: <p>
347: or
348: <form method="POST" action="/adm/slotrequest">
349: <input type="hidden" name="symb" value="$env{'form.symb'}" />
350: <input type="submit" name="requestattempt" value="$lt{'request'}" />
351: </form>
352: </p>
353: or
354: STUFF
355: $r->print('<p><a href="/adm/flip?postdata=return:">'.
356: &mt('Return to last resource').'</a></p>');
357: return;
358: }
359:
360: sub allowed_slot {
361: my ($slot_name,$slot,$symb)=@_;
362: #already started
363: if ($slot->{'starttime'} < time) {
364: # all open slot to be schedulable
365: #return 0;
366: }
367: &Apache::lonxml::debug("$slot_name starttime good");
368: #already ended
369: if ($slot->{'endtime'} < time) {
370: return 0;
371: }
372: &Apache::lonxml::debug("$slot_name endtime good");
373: # not allowed to pick this one
374: if (defined($slot->{'type'})
375: && $slot->{'type'} ne 'schedulable_student') {
376: return 0;
377: }
378: &Apache::lonxml::debug("$slot_name type good");
379: # not allowed for this resource
380: if (defined($slot->{'symb'})
381: && $slot->{'symb'} ne $symb) {
382: return 0;
383: }
384: &Apache::lonxml::debug("$slot_name symb good");
385: return 1;
386: }
387:
388: sub get_description {
389: my ($slot_name,$slot)=@_;
390: my $description=$slot->{'description'};
391: if (!defined($description)) {
392: $description=&mt('[_1] From [_2] to [_3]',$slot_name,
393: &Apache::lonlocal::locallocaltime($slot->{'starttime'}),
394: &Apache::lonlocal::locallocaltime($slot->{'endtime'}));
395: }
396: return $description;
397: }
398:
399: sub show_choices {
400: my ($r,$symb)=@_;
401:
402: my ($cnum,$cdom)=&get_course();
403: my %slots=&Apache::lonnet::dump('slots',$cdom,$cnum);
404: my $available;
405: $r->print('<table border="1">');
406: &Apache::lonxml::debug("Checking Slots");
407: my ($got_slot)=&check_for_reservation($symb);
408: foreach my $slot (sort
409: { return $slots{$a}->{'starttime'} <=> $slots{$b}->{'starttime'} }
410: (keys(%slots))) {
411:
412: &Apache::lonxml::debug("Checking Slot $slot");
413: next if (!&allowed_slot($slot,$slots{$slot}));
414:
415: $available++;
416:
417: my $description=&get_description($slot,$slots{$slot});
418:
419: my $form=&mt('Unavailable');
420: if (($slot eq $got_slot) ||
421: &space_available($slot,$slots{$slot},$symb)) {
422: my $text=&mt('Select');
423: my $command='get';
424: if ($slot eq $got_slot) {
425: $text=&mt('Free Reservation');
426: $command='release';
427: }
428: my $escsymb=&Apache::lonnet::escape($symb);
429: $form=<<STUFF;
430: <form method="POST" action="/adm/slotrequest">
431: <input type="submit" name="Select" value="$text" />
432: <input type="hidden" name="symb" value="$escsymb" />
433: <input type="hidden" name="slotname" value="$slot" />
434: <input type="hidden" name="command" value="$command" />
435: </form>
436: STUFF
437: }
438: $r->print(<<STUFF);
439: <tr>
440: <td>$form</td>
441: <td>$description</td>
442: </tr>
443: STUFF
444: }
445:
446: if (!$available) {
447: $r->print('<tr><td>No available times. <a href="/adm/flip?postdata=return:">'.
448: &mt('Return to last resource').'</a></td></tr>');
449: }
450: $r->print('</table>');
451: }
452:
453: sub show_table {
454: my ($r,$mgr)=@_;
455:
456: my ($cnum,$cdom)=&get_course();
457: my %slots=&Apache::lonnet::dump('slots',$cdom,$cnum);
458: if ( (keys(%slots))[0] =~ /^error: 2 /) {
459: undef(%slots);
460: }
461: my $available;
462: if ($mgr eq 'F') {
463: $r->print('<form method="POST" action="/adm/slotrequest">
464: <input type="hidden" name="command" value="uploadstart" />
465: <input type="submit" name="start" value="'.&mt('Upload Slot List').'" />
466: </form>');
467: $r->print('<form method="POST" action="/adm/helper/newslot.helper">
468: <input type="submit" name="newslot" value="'.&mt('Create a New Slot').'" />
469: </form>');
470: }
471: my $linkstart='<a href="/adm/slotrequest?command=showslots&order=';
472: $r->print('<table border="1">
473: <tr>
474: <th></th>
475: <th>'.$linkstart.'name" >Slot name</a></th>
476: <th>'.$linkstart.'type" >Type</a></th>
477: <th>'.$linkstart.'description" >Description</a></th>
478: <th>'.$linkstart.'starttime" >Start Time</a></th>
479: <th>'.$linkstart.'endtime" >End Time</a></th>
480: <th>'.$linkstart.'startreserve">Time Students Can Start Reserving</a></th>
481: <th>'.$linkstart.'secret" >Secret</a></th>
482: <th>'.$linkstart.'maxspace" >Max space</a></th>
483: <th> Scheduled Students</th>
484: <th>'.$linkstart.'unique" >Unique Period</a></th>
485: </tr>');
486: my %name_cache;
487: my $slotsort = sub {
488: if ($env{'form.order'}=~/^(type|description|endtime|maxspace)$/) {
489: if (lc($slots{$a}->{$env{'form.order'}})
490: ne lc($slots{$b}->{$env{'form.order'}})) {
491: return (lc($slots{$a}->{$env{'form.order'}})
492: cmp lc($slots{$b}->{$env{'form.order'}}));
493: }
494: } elsif ($env{'form.order'} eq 'name') {
495: if (lc($a) cmp lc($b)) {
496: return lc($a) cmp lc($b);
497: }
498: } elsif ($env{'form.order'} eq 'unique') {
499:
500: if ($slots{$a}->{'uniqueperiod'}[0]
501: ne $slots{$b}->{'uniqueperiod'}[0]) {
502: return ($slots{$a}->{'uniqueperiod'}[0]
503: cmp $slots{$b}->{'uniqueperiod'}[0]);
504: }
505: if ($slots{$a}->{'uniqueperiod'}[1]
506: ne $slots{$b}->{'uniqueperiod'}[1]) {
507: return ($slots{$a}->{'uniqueperiod'}[1]
508: cmp $slots{$b}->{'uniqueperiod'}[1]);
509: }
510: }
511: return $slots{$a}->{'starttime'} <=> $slots{$b}->{'starttime'};
512: };
513: foreach my $slot (sort $slotsort (keys(%slots))) {
514: if (defined($slots{$slot}->{'type'})
515: && $slots{$slot}->{'type'} ne 'schedulable_student') {
516: #next;
517: }
518: my $description=&get_description($slot,$slots{$slot});
519: my %consumed=&Apache::lonnet::dump('slot_reservations',$cdom,$cnum,
520: "^$slot\0");
521: my $ids;
522: foreach my $entry (sort(keys(%consumed))) {
523: my (undef,$id)=split("\0",$entry);
524: $ids.= $id.'-> '.$consumed{$entry}->{'name'}.'<br />';
525: }
526: my $start=($slots{$slot}->{'starttime'}?
527: &Apache::lonlocal::locallocaltime($slots{$slot}->{'starttime'}):'');
528: my $end=($slots{$slot}->{'endtime'}?
529: &Apache::lonlocal::locallocaltime($slots{$slot}->{'endtime'}):'');
530: my $start_reserve=($slots{$slot}->{'startreserve'}?
531: &Apache::lonlocal::locallocaltime($slots{$slot}->{'startreserve'}):'');
532:
533: my $unique;
534: if (ref($slots{$slot}{'uniqueperiod'})) {
535: $unique=localtime($slots{$slot}{'uniqueperiod'}[0]).','.
536: localtime($slots{$slot}{'uniqueperiod'}[1]);
537: }
538: my @proctors = map {
539: my ($uname,$udom)=split(/@/,$_);
540: my $fullname=$name_cache{$_};
541: if (!defined($fullname)) {
542: &Apache::lonnet::logthis("Gettign $uname $udom");
543: $fullname = &Apache::loncommon::plainname($uname,$udom);
544: $fullname =~s/\s/ /g;
545: $name_cache{$_} = $fullname;
546: }
547: &Apache::loncommon::aboutmewrapper($fullname,$uname,$udom);
548: } (sort(split(/\s*,\s*/,$slots{$slot}->{'proctor'})));
549:
550: my $proctors=join(', ',@proctors);
551:
552: my $edit=(<<EDITFORM);
553: <form method="POST" action="/adm/helper/newslot.helper">
554: <input type="hidden" name="name" value="$slot" />
555: <input type="submit" name="Edit" value="Edit" />
556: </form>
557: EDITFORM
558: $r->print(<<STUFF);
559: <tr>
560: <td rowspan="2">$edit</td>
561: <td>$slot</td>
562: <td>$slots{$slot}->{'type'}</td>
563: <td>$description</td>
564: <td>$start</td>
565: <td>$end</td>
566: <td>$start_reserve</td>
567: <td>$slots{$slot}->{'secret'}</td>
568: <td>$slots{$slot}->{'maxspace'}</td>
569: <td>$ids</td>
570: <td>$unique</td>
571: </tr>
572: <tr>
573: <td colspan="10">$proctors</td>
574: </tr>
575: STUFF
576: }
577: $r->print('</table>');
578: }
579:
580: sub upload_start {
581: my ($r)=@_;
582: $r->print(&Apache::grades::checkforfile_js());
583: my $result.='<table width=100% border=0><tr bgcolor="#e6ffff"><td>'."\n";
584: $result.=' <b>'.
585: &mt('Specify a file containing the slot definitions.').
586: '</b></td></tr>'."\n";
587: $result.='<tr bgcolor=#ffffe6><td>'."\n";
588: my $upfile_select=&Apache::loncommon::upfile_select_html();
589: my $ignore=&mt('Ignore First Line');
590: $result.=<<ENDUPFORM;
591: <form method="post" enctype="multipart/form-data" action="/adm/slotrequest" name="slotupload">
592: <input type="hidden" name="command" value="csvuploadmap" />
593: $upfile_select
594: <br /><input type="button" onClick="javascript:checkUpload(this.form);" value="Upload Data" />
595: <label><input type="checkbox" name="noFirstLine" />$ignore</label>
596: </form>
597: ENDUPFORM
598: $result.='</td></tr></table>'."\n";
599: $result.='</td></tr></table>'."\n";
600: $r->print($result);
601: }
602:
603: sub csvuploadmap_header {
604: my ($r,$datatoken,$distotal)= @_;
605: my $javascript;
606: if ($env{'form.upfile_associate'} eq 'reverse') {
607: $javascript=&csvupload_javascript_reverse_associate();
608: } else {
609: $javascript=&csvupload_javascript_forward_associate();
610: }
611:
612: my $checked=(($env{'form.noFirstLine'})?' checked="checked"':'');
613: my $ignore=&mt('Ignore First Line');
614: $r->print(<<ENDPICK);
615: <form method="post" enctype="multipart/form-data" action="/adm/slotrequest" name="slotupload">
616: <h3>Identify fields</h3>
617: Total number of records found in file: $distotal <hr />
618: Enter as many fields as you can. The system will inform you and bring you back
619: to this page if the data selected is insufficient to create the slots.<hr />
620: <input type="button" value="Reverse Association" onClick="javascript:this.form.associate.value='Reverse Association';submit(this.form);" />
621: <label><input type="checkbox" name="noFirstLine" $checked />$ignore</label>
622: <input type="hidden" name="associate" value="" />
623: <input type="hidden" name="datatoken" value="$datatoken" />
624: <input type="hidden" name="fileupload" value="$env{'form.fileupload'}" />
625: <input type="hidden" name="upfiletype" value="$env{'form.upfiletype'}" />
626: <input type="hidden" name="upfile_associate"
627: value="$env{'form.upfile_associate'}" />
628: <input type="hidden" name="command" value="csvuploadassign" />
629: <hr />
630: <script type="text/javascript" language="Javascript">
631: $javascript
632: </script>
633: ENDPICK
634: return '';
635:
636: }
637:
638: sub csvuploadmap_footer {
639: my ($request,$i,$keyfields) =@_;
640: $request->print(<<ENDPICK);
641: </table>
642: <input type="hidden" name="nfields" value="$i" />
643: <input type="hidden" name="keyfields" value="$keyfields" />
644: <input type="button" onClick="javascript:verify(this.form)" value="Create Slots" /><br />
645: </form>
646: ENDPICK
647: }
648:
649: sub csvupload_javascript_reverse_associate {
650: my $error1=&mt('You need to specify the name, starttime, endtime and a type');
651: return(<<ENDPICK);
652: function verify(vf) {
653: var foundstart=0;
654: var foundend=0;
655: var foundname=0;
656: var foundtype=0;
657: for (i=0;i<=vf.nfields.value;i++) {
658: tw=eval('vf.f'+i+'.selectedIndex');
659: if (i==0 && tw!=0) { foundname=1; }
660: if (i==1 && tw!=0) { foundtype=1; }
661: if (i==2 && tw!=0) { foundstat=1; }
662: if (i==3 && tw!=0) { foundend=1; }
663: }
664: if (foundstart==0 && foundend==0 && foundtype==0 && foundname==0) {
665: alert('$error1');
666: return;
667: }
668: vf.submit();
669: }
670: function flip(vf,tf) {
671: }
672: ENDPICK
673: }
674:
675: sub csvupload_javascript_forward_associate {
676: my $error1=&mt('You need to specify the name, starttime, endtime and a type');
677: return(<<ENDPICK);
678: function verify(vf) {
679: var foundstart=0;
680: var foundend=0;
681: var foundname=0;
682: var foundtype=0;
683: for (i=0;i<=vf.nfields.value;i++) {
684: tw=eval('vf.f'+i+'.selectedIndex');
685: if (tw==1) { foundname=1; }
686: if (tw==2) { foundtype=1; }
687: if (tw==3) { foundstat=1; }
688: if (tw==4) { foundend=1; }
689: }
690: if (foundstart==0 && foundend==0 && foundtype==0 && foundname==0) {
691: alert('$error1');
692: return;
693: }
694: vf.submit();
695: }
696: function flip(vf,tf) {
697: }
698: ENDPICK
699: }
700:
701: sub csv_upload_map {
702: my ($r)= @_;
703:
704: my $datatoken;
705: if (!$env{'form.datatoken'}) {
706: $datatoken=&Apache::loncommon::upfile_store($r);
707: } else {
708: $datatoken=$env{'form.datatoken'};
709: &Apache::loncommon::load_tmp_file($r);
710: }
711: my @records=&Apache::loncommon::upfile_record_sep();
712: if ($env{'form.noFirstLine'}) { shift(@records); }
713: &csvuploadmap_header($r,$datatoken,$#records+1);
714: my ($i,$keyfields);
715: if (@records) {
716: my @fields=&csvupload_fields();
717:
718: if ($env{'form.upfile_associate'} eq 'reverse') {
719: &Apache::loncommon::csv_print_samples($r,\@records);
720: $i=&Apache::loncommon::csv_print_select_table($r,\@records,
721: \@fields);
722: foreach (@fields) { $keyfields.=$_->[0].','; }
723: chop($keyfields);
724: } else {
725: unshift(@fields,['none','']);
726: $i=&Apache::loncommon::csv_samples_select_table($r,\@records,
727: \@fields);
728: my %sone=&Apache::loncommon::record_sep($records[0]);
729: $keyfields=join(',',sort(keys(%sone)));
730: }
731: }
732: &csvuploadmap_footer($r,$i,$keyfields);
733:
734: return '';
735: }
736:
737: sub csvupload_fields {
738: return (['name','Slot name'],
739: ['type','Type of slot'],
740: ['starttime','Start Time of slot'],
741: ['endtime','End Time of slot'],
742: ['startreserve','Reservation Start Time'],
743: ['ip','IP or DNS restriction'],
744: ['proctor','List of proctor ids'],
745: ['description','Slot Description'],
746: ['maxspace','Maximum number of reservations'],
747: ['symb','Resource Restriction'],
748: ['uniqueperiod','Date range of slot exclusion'],
749: ['secret','Secret word proctor uses to validate']);
750: }
751:
752: sub csv_upload_assign {
753: my ($r,$mgr)= @_;
754: &Apache::loncommon::load_tmp_file($r);
755: my @slotdata = &Apache::loncommon::upfile_record_sep();
756: if ($env{'form.noFirstLine'}) { shift(@slotdata); }
757: my %fields=&Apache::grades::get_fields();
758: $r->print('<h3>Creating Slots</h3>');
759: my $cname=$env{'course.'.$env{'request.course.id'}.'.num'};
760: my $cdom=$env{'course.'.$env{'request.course.id'}.'.domain'};
761: my $countdone=0;
762: foreach my $slot (@slotdata) {
763: my %slot;
764: my %entries=&Apache::loncommon::record_sep($slot);
765: my $domain;
766: my $name=$entries{$fields{'name'}};
767: if ($entries{$fields{'type'}}) {
768: $slot{'type'}=$entries{$fields{'type'}};
769: } else {
770: $slot{'type'}='preassigned';
771: }
772: if ($entries{$fields{'starttime'}}) {
773: $slot{'starttime'}=&UnixDate($entries{$fields{'starttime'}},"%s");
774: }
775: if ($entries{$fields{'endtime'}}) {
776: $slot{'endtime'}=&UnixDate($entries{$fields{'endtime'}},"%s");
777: }
778: if ($entries{$fields{'startreserve'}}) {
779: $slot{'startreserve'}=
780: &UnixDate($entries{$fields{'startreserve'}},"%s");
781: }
782: foreach my $key ('ip','proctor','description','maxspace',
783: 'secret','symb') {
784: if ($entries{$fields{$key}}) {
785: $slot{$key}=$entries{$fields{$key}};
786: }
787: }
788: if ($entries{$fields{'uniqueperiod'}}) {
789: my ($start,$end)=split(',',$entries{$fields{'uniqueperiod'}});
790: my @times=(&UnixDate($start,"%s"),
791: &UnixDate($end,"%s"));
792: $slot{'uniqueperiod'}=\@times;
793: }
794:
795: &Apache::lonnet::cput('slots',{$name=>\%slot},$cdom,$cname);
796: $r->print('.');
797: $r->rflush();
798: $countdone++;
799: }
800: $r->print("<br />Created $countdone slots\n");
801: $r->print("<br />\n");
802: &show_table($r,$mgr);
803: return '';
804: }
805:
806: sub handler {
807: my $r=shift;
808:
809: &Apache::loncommon::get_unprocessed_cgi($ENV{'QUERY_STRING'});
810:
811: my $vgr=&Apache::lonnet::allowed('vgr',$env{'request.course.id'});
812: my $mgr=&Apache::lonnet::allowed('mgr',$env{'request.course.id'});
813: my $title='Requesting Another Worktime';
814: if ($env{'form.command'} =~ /^(showslots|uploadstart|csvuploadmap|csvuploadassign)$/ && $vgr eq 'F') {
815: $title = 'Managing Slots';
816: }
817: &start_page($r,$title);
818:
819: if ($env{'form.command'} eq 'showslots' && $vgr eq 'F') {
820: &show_table($r,$mgr);
821: } elsif ($env{'form.command'} eq 'uploadstart' && $mgr eq 'F') {
822: &upload_start($r);
823: } elsif ($env{'form.command'} eq 'csvuploadmap' && $mgr eq 'F') {
824: &csv_upload_map($r);
825: } elsif ($env{'form.command'} eq 'csvuploadassign' && $mgr eq 'F') {
826: if ($env{'form.associate'} ne 'Reverse Association') {
827: &csv_upload_assign($r,$mgr);
828: } else {
829: if ( $env{'form.upfile_associate'} ne 'reverse' ) {
830: $env{'form.upfile_associate'} = 'reverse';
831: } else {
832: $env{'form.upfile_associate'} = 'forward';
833: }
834: &csv_upload_map($r);
835: }
836: } else {
837: my $symb=&Apache::lonnet::unescape($env{'form.symb'});
838: my (undef,undef,$res)=&Apache::lonnet::decode_symb($symb);
839: if ($res !~ /\.task$/) {
840: &fail($r,'not_valid');
841: return OK;
842: }
843: $env{'request.symb'}=$symb;
844: my ($status) = &Apache::lonhomework::check_task_access('0');
845: if ($status eq 'CAN_ANSWER' ||
846: $status eq 'NEEDS_CHECKIN' ||
847: $status eq 'WAITING_FOR_GRADE') {
848: &fail($r,'not_allowed');
849: return OK;
850: }
851: if ($env{'form.requestattempt'}) {
852: &show_choices($r,$symb);
853: } elsif ($env{'form.command'} eq 'release') {
854: &release_slot($r,$symb);
855: } elsif ($env{'form.command'} eq 'get') {
856: &get_slot($r,$symb);
857: } elsif ($env{'form.command'} eq 'change') {
858: &release_slot($r,$symb,$env{'form.releaseslot'},1);
859: &get_slot($r,$symb);
860: } else {
861: $r->print("<p>Unknown command: ".$env{'form.command'}."</p>");
862: }
863: }
864: &end_page($r);
865: return OK;
866: }
867:
868: 1;
869: __END__
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>
![[BACK]](/icons/back.gif){kind=icon}
Return to slotrequest.pm CVS log ![[TXT]](/icons/text.gif){kind=icon}
![[DIR]](/icons/dir.gif){kind=icon}
Up to [LON-CAPA] / loncom / interface