1: # The LearningOnline Network with CAPA
2: # Handler for requesting to have slots added to a students record
3: #
4: # $Id: slotrequest.pm,v 1.53 2006/03/21 16:03:19 albertel Exp $
5: #
6: # Copyright Michigan State University Board of Trustees
7: #
8: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
9: #
10: # LON-CAPA is free software; you can redistribute it and/or modify
11: # it under the terms of the GNU General Public License as published by
12: # the Free Software Foundation; either version 2 of the License, or
13: # (at your option) any later version.
14: #
15: # LON-CAPA is distributed in the hope that it will be useful,
16: # but WITHOUT ANY WARRANTY; without even the implied warranty of
17: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18: # GNU General Public License for more details.
19: #
20: # You should have received a copy of the GNU General Public License
21: # along with LON-CAPA; if not, write to the Free Software
22: # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
23: #
24: # /home/httpd/html/adm/gpl.txt
25: #
26: # http://www.lon-capa.org/
27: #
28: ###
29:
30: package Apache::slotrequest;
31:
32: use strict;
33: use Apache::Constants qw(:common :http :methods);
34: use Apache::loncommon();
35: use Apache::lonlocal;
36: use Apache::lonnet;
37: use Apache::lonnavmaps();
38: use Date::Manip;
39:
40: sub fail {
41: my ($r,$code)=@_;
42: if ($code eq 'not_valid') {
43: $r->print('<p>'.&mt('Unable to understand what resource you wanted to sign up for.').'</p>');
44:
45: } elsif ($code eq 'not_allowed') {
46: $r->print('<p>'.&mt('Not allowed to sign up or change reservations at this time.').'</p>');
47: } else {
48: $r->print('<p>'.&mt('Failed.').'</p>');
49: }
50:
51: &return_link($r);
52: &end_page($r);
53: }
54:
55: sub start_page {
56: my ($r,$title)=@_;
57: $r->print(&Apache::loncommon::start_page($title));
58: }
59:
60: sub end_page {
61: my ($r)=@_;
62: $r->print(&Apache::loncommon::end_page());
63: }
64:
65: =pod
66:
67: slot_reservations db
68: - keys are
69: - slotname\0id -> value is an hashref of
70: name -> user@domain of holder
71: timestamp -> timestamp of reservation
72: symb -> symb of resource that it is reserved for
73:
74: =cut
75:
76: sub get_course {
77: (undef,my $courseid)=&Apache::lonxml::whichuser();
78: my $cdom=$env{'course.'.$courseid.'.domain'};
79: my $cnum=$env{'course.'.$courseid.'.num'};
80: return ($cnum,$cdom);
81: }
82:
83: sub get_reservation_ids {
84: my ($slot_name)=@_;
85:
86: my ($cnum,$cdom)=&get_course();
87:
88: my %consumed=&Apache::lonnet::dump('slot_reservations',$cdom,$cnum,
89: "^$slot_name\0");
90: if (&network_error(%consumed)) {
91: return 'error: Unable to determine current status';
92: }
93: my ($tmp)=%consumed;
94: if ($tmp=~/^error: 2 / ) {
95: return 0;
96: }
97: return keys(%consumed);
98: }
99:
100: sub space_available {
101: my ($slot_name,$slot)=@_;
102: my $max=$slot->{'maxspace'};
103:
104: if (!defined($max)) { return 1; }
105:
106: my $consumed=scalar(&get_reservation_ids($slot_name));
107: if ($consumed < $max) {
108: return 1
109: }
110: return 0;
111: }
112:
113: sub check_for_reservation {
114: my ($symb,$mode)=@_;
115: my $student = &Apache::lonnet::EXT("resource.0.availablestudent", $symb,
116: $env{'user.domain'}, $env{'user.name'});
117:
118: my $course = &Apache::lonnet::EXT("resource.0.available", $symb,
119: $env{'user.domain'}, $env{'user.name'});
120: my @slots = (split(/:/,$student), split(/:/, $course));
121:
122: &Apache::lonxml::debug(" slot list is ".join(':',@slots));
123:
124: my ($cnum,$cdom)=&get_course();
125: my %slots=&Apache::lonnet::get('slots', [@slots], $cdom, $cnum);
126:
127: if (&network_error($student) || &network_error($course) ||
128: &network_error(%slots)) {
129: return 'error: Unable to determine current status';
130: }
131: my @got;
132: foreach my $slot_name (sort {
133: if (ref($slots{$a}) && ref($slots{$b})) {
134: return $slots{$a}{'starttime'} <=> $slots{$b}{'starttime'}
135: }
136: if (ref($slots{$a})) { return -1;}
137: if (ref($slots{$b})) { return 1;}
138: return 0;
139: } @slots) {
140: next if (!defined($slots{$slot_name}) ||
141: !ref($slots{$slot_name}));
142: &Apache::lonxml::debug(time." $slot_name ".
143: $slots{$slot_name}->{'starttime'}." -- ".
144: $slots{$slot_name}->{'startreserve'});
145: if ($slots{$slot_name}->{'endtime'} > time &&
146: $slots{$slot_name}->{'startreserve'} < time) {
147: # between start of reservation times and end of slot
148: if ($mode eq 'allslots') {
149: push(@got,$slot_name);
150: } else {
151: return($slot_name, $slots{$slot_name});
152: }
153: }
154: }
155: if ($mode eq 'allslots' && @got) {
156: return @got;
157: }
158: return (undef,undef);
159: }
160:
161: sub get_consumed_uniqueperiods {
162: my ($slots) = @_;
163: my $navmap=Apache::lonnavmaps::navmap->new;
164: my @problems = $navmap->retrieveResources(undef,
165: sub { $_[0]->is_problem() },1,0);
166: my %used_slots;
167: foreach my $problem (@problems) {
168: my $symb = $problem->symb();
169: my $student = &Apache::lonnet::EXT("resource.0.availablestudent",
170: $symb, $env{'user.domain'},
171: $env{'user.name'});
172: my $course = &Apache::lonnet::EXT("resource.0.available",
173: $symb, $env{'user.domain'},
174: $env{'user.name'});
175: if (&network_error($student) || &network_error($course)) {
176: return 'error: Unable to determine current status';
177: }
178: foreach my $slot (split(/:/,$student), split(/:/, $course)) {
179: $used_slots{$slot}=1;
180: }
181: }
182:
183: if (!ref($slots)) {
184: my ($cnum,$cdom)=&get_course();
185: my %slots=&Apache::lonnet::get('slots', [keys(%used_slots)], $cdom, $cnum);
186: if (&network_error(%slots)) {
187: return 'error: Unable to determine current status';
188: }
189: $slots = \%slots;
190: }
191:
192: my %consumed_uniqueperiods;
193: foreach my $slot_name (keys(%used_slots)) {
194: next if (!defined($slots->{$slot_name}) ||
195: !ref($slots->{$slot_name}));
196:
197: next if (!defined($slots->{$slot_name}{'uniqueperiod'}) ||
198: !ref($slots->{$slot_name}{'uniqueperiod'}));
199: $consumed_uniqueperiods{$slot_name} =
200: $slots->{$slot_name}{'uniqueperiod'};
201: }
202: return \%consumed_uniqueperiods;
203: }
204:
205: sub check_for_conflict {
206: my ($symb,$new_slot_name,$new_slot,$slots,$consumed_uniqueperiods)=@_;
207:
208: if (!defined($new_slot->{'uniqueperiod'})) { return undef; }
209:
210: if (!ref($consumed_uniqueperiods)) {
211: $consumed_uniqueperiods = &get_consumed_uniqueperiods($slots);
212: if (&network_error(%$consumed_uniqueperiods)) {
213: return 'error: Unable to determine current status';
214: }
215: }
216:
217: my ($new_uniq_start,$new_uniq_end) = @{$new_slot->{'uniqueperiod'}};
218: foreach my $slot_name (keys(%$consumed_uniqueperiods)) {
219: my ($start,$end)=@{$consumed_uniqueperiods->{$slot_name}};
220: if (!
221: ($start < $new_uniq_start && $end < $new_uniq_start) ||
222: ($start > $new_uniq_end && $end > $new_uniq_end )) {
223: return $slot_name;
224: }
225: }
226: return undef;
227:
228: }
229:
230: sub network_error {
231: my ($result) = @_;
232: if ($result =~ /^(con_lost|no_such_host|error: [^2])/) {
233: return 1;
234: }
235: return 0;
236: }
237:
238: sub make_reservation {
239: my ($slot_name,$slot,$symb)=@_;
240:
241: my ($cnum,$cdom)=&get_course();
242:
243: my $value=&Apache::lonnet::EXT("resource.0.availablestudent",$symb,
244: $env{'user.domain'},$env{'user.name'});
245: &Apache::lonxml::debug("value is $value<br />");
246: if (&network_error($value)) {
247: return 'error: Unable to determine current status';
248: }
249:
250: foreach my $other_slot (split(/:/, $value)) {
251: if ($other_slot eq $slot_name) {
252: my %consumed=&Apache::lonnet::dump('slot_reservations', $cdom,
253: $cnum, "^$slot_name\0");
254: if (&network_error($value)) {
255: return 'error: Unable to determine current status';
256: }
257: my $me=$env{'user.name'}.'@'.$env{'user.domain'};
258: foreach my $key (keys(%consumed)) {
259: if ($consumed{$key}->{'name'} eq $me) {
260: my $num=(split('\0',$key))[1];
261: return -$num;
262: }
263: }
264: }
265: }
266:
267: my $max=$slot->{'maxspace'};
268: if (!defined($max)) { $max=99999; }
269:
270: my (@ids)=&get_reservation_ids($slot_name);
271: if (&network_error(@ids)) {
272: return 'error: Unable to determine current status';
273: }
274: my $last=0;
275: foreach my $id (@ids) {
276: my $num=(split('\0',$id))[1];
277: if ($num > $last) { $last=$num; }
278: }
279:
280: my $wanted=$last+1;
281: &Apache::lonxml::debug("wanted $wanted<br />");
282: if (scalar(@ids) >= $max) {
283: # full up
284: return undef;
285: }
286:
287: my %reservation=('name' => $env{'user.name'}.'@'.$env{'user.domain'},
288: 'timestamp' => time,
289: 'symb' => $symb);
290:
291: my $success=&Apache::lonnet::newput('slot_reservations',
292: {"$slot_name\0$wanted" =>
293: \%reservation},
294: $cdom, $cnum);
295:
296: if ($success eq 'ok') {
297: my $new_value=$slot_name;
298: if ($value) {
299: $new_value=$value.':'.$new_value;
300: }
301: my $result=&Apache::lonparmset::storeparm_by_symb($symb,
302: '0_availablestudent',
303: 1, $new_value, 'string',
304: $env{'user.name'},
305: $env{'user.domain'});
306: &Apache::lonxml::debug("hrrm $result");
307: return $wanted;
308: }
309:
310: # someone else got it
311: return undef;
312: }
313:
314: sub remove_registration {
315: my ($r) = @_;
316: my $name = &Apache::loncommon::plainname($env{'form.uname'},
317: $env{'form.udom'});
318:
319: my $title = &Apache::lonnet::gettitle($env{'form.symb'});
320:
321: my $hidden_input;
322: foreach my $parm ('uname','udom','slotname','entry','symb') {
323: $hidden_input .=
324: '<input type="hidden" name="'.$parm.'" value="'
325: .&HTML::Entities::encode($env{'form.'.$parm},'"<>&\'').'" />'."\n";
326: }
327: $r->print(<<"END_CONFIRM");
328: <p> Remove $name from slot $env{'form.slotname'} for $title</p>
329: <form action="/adm/slotrequest" method="POST">
330: <input type="hidden" name="command" value="release" />
331: $hidden_input
332: <input type="submit" name="Yes" value="yes" />
333: </form>
334: <form action="/adm/slotrequest" method="POST">
335: <input type="hidden" name="command" value="showslots" />
336: <input type="submit" name="No" value="no" />
337: </form>
338: END_CONFIRM
339:
340: }
341:
342: sub release_slot {
343: my ($r,$symb,$slot_name,$inhibit_return_link,$mgr)=@_;
344:
345: if ($slot_name eq '') { $slot_name=$env{'form.slotname'}; }
346: my ($cnum,$cdom)=&get_course();
347:
348: my ($uname,$udom) = ($env{'user.name'}, $env{'user.domain'});
349: if ($mgr eq 'F'
350: && defined($env{'form.uname'}) && defined($env{'form.udom'})) {
351: ($uname,$udom) = ($env{'form.uname'}, $env{'form.udom'});
352: }
353:
354: if ($mgr eq 'F'
355: && defined($env{'form.symb'})) {
356: $symb = $env{'form.symb'};
357: }
358: my %slot=&Apache::lonnet::get_slot($slot_name);
359: my $description=&get_description($env{'form.slotname'},\%slot);
360:
361: if ($mgr ne 'F') {
362: if ($slot{'starttime'} < time) {
363: $r->print("<p>Not allowed to release Reservation: $description, as it has already ended. </p>");
364: &return_link($r);
365: return 0;
366: }
367: }
368: # get parameter string, check for existance, rebuild string with the slot
369: my @slots = split(/:/,&Apache::lonnet::EXT("resource.0.availablestudent",
370: $symb,$udom,$uname));
371:
372: my @new_slots;
373: foreach my $exist_slot (@slots) {
374: if ($exist_slot eq $slot_name) { next; }
375: push(@new_slots,$exist_slot);
376: }
377: my $new_param = join(':',@new_slots);
378:
379: # get slot reservations, check if user has one, if so remove reservation
380: my %consumed=&Apache::lonnet::dump('slot_reservations',$cdom,$cnum,
381: "^$slot_name\0");
382: foreach my $entry (keys(%consumed)) {
383: if ( $consumed{$entry}->{'name'} eq ($uname.'@'.$udom) ) {
384: &Apache::lonnet::del('slot_reservations',[$entry],
385: $cdom,$cnum);
386: }
387: }
388:
389: # store new parameter string
390: my $result=&Apache::lonparmset::storeparm_by_symb($symb,
391: '0_availablestudent',
392: 1, $new_param, 'string',
393: $uname,$udom);
394: $r->print("<p>Released Reservation: $description</p>");
395: if ($mgr eq 'F') {
396: $r->print('<p><a href="/adm/slotrequest?command=showslots">'.
397: &mt('Return to slot list').'</a></p>');
398: }
399: if (!$inhibit_return_link) { &return_link($r); }
400: return 1;
401: }
402:
403: sub delete_slot {
404: my ($r)=@_;
405:
406: my $slot_name = $env{'form.slotname'};
407: my %slot=&Apache::lonnet::get_slot($slot_name);
408:
409: my ($cnum,$cdom)=&get_course();
410: my %consumed=&Apache::lonnet::dump('slot_reservations',$cdom,$cnum,
411: "^$slot_name\0");
412: my ($tmp) = %consumed;
413: if ($tmp =~ /error: 2/) { undef(%consumed); }
414:
415: if (%slot && !%consumed) {
416: $slot{'type'} = 'deleted';
417: my $ret = &Apache::lonnet::cput('slots', {$slot_name => \%slot},
418: $cdom, $cnum);
419: if ($ret eq 'ok') {
420: $r->print("<p>Slot <tt>$slot_name</tt> marked as deleted.</p>");
421: } else {
422: $r->print("<p> An error ($ret) occurse when attempting to delete Slot <tt>$slot_name</tt>.</p>");
423: }
424: } else {
425: if (%consumed) {
426: $r->print("<p>Slot <tt>$slot_name</tt> has active reservations.</p>");
427: } else {
428: $r->print("<p>Slot <tt>$slot_name</tt> does not exist.</p>");
429: }
430: }
431: $r->print('<p><a href="/adm/slotrequest?command=showslots">'.
432: &mt('Return to slot list').'</a></p>');
433: &return_link($r);
434: }
435:
436: sub return_link {
437: my ($r) = @_;
438: $r->print('<p><a href="/adm/flip?postdata=return:">'.
439: &mt('Return to last resource').'</a></p>');
440: }
441:
442: sub get_slot {
443: my ($r,$symb)=@_;
444:
445: my %slot=&Apache::lonnet::get_slot($env{'form.slotname'});
446: my $slot_name=&check_for_conflict($symb,$env{'form.slotname'},\%slot);
447:
448: if ($slot_name =~ /^error: (.*)/) {
449: $r->print("<p>An error occured while attempting to make a reservation. ($1)</p>");
450: &return_link($r);
451: return;
452: }
453: if ($slot_name) {
454: my %slot=&Apache::lonnet::get_slot($slot_name);
455: my $description1=&get_description($slot_name,\%slot);
456: %slot=&Apache::lonnet::get_slot($env{'form.slotname'});
457: my $description2=&get_description($env{'form.slotname'},\%slot);
458: $r->print("<p>Already have a reservation: $description1</p>");
459: if ($slot_name ne $env{'form.slotname'}) {
460: $r->print(<<STUFF);
461: <form method="POST" action="/adm/slotrequest">
462: <input type="hidden" name="symb" value="$env{'form.symb'}" />
463: <input type="hidden" name="slotname" value="$env{'form.slotname'}" />
464: <input type="hidden" name="releaseslot" value="$slot_name" />
465: <input type="hidden" name="command" value="change" />
466: STUFF
467: $r->print("<p>You can either ");
468: $r->print(<<STUFF);
469: <input type="submit" name="change" value="Change" />
470: STUFF
471: $r->print(' your reservation from <b>'.$description1.'</b> to <b>'.
472: $description2.
473: '</b> <br />or </p>');
474: &return_link($r);
475: $r->print(<<STUFF);
476: </form>
477: STUFF
478: } else {
479: &return_link($r);
480: }
481: return;
482: }
483:
484: my $reserved=&make_reservation($env{'form.slotname'},
485: \%slot,$symb);
486: my $description=&get_description($env{'form.slotname'},\%slot);
487: if (defined($reserved)) {
488: if ($slot_name =~ /^error: (.*)/) {
489: $r->print("<p>An error occured while attempting to make a reservation. ($1)</p>");
490: } elsif ($reserved > -1) {
491: $r->print("<p>Success: $description</p>");
492: } elsif ($reserved < 0) {
493: $r->print("<p>Already reserved: $description</p>");
494: }
495: &return_link($r);
496: return;
497: }
498:
499: my %lt=('request'=>"Availibility list",
500: 'try' =>'Try again');
501: %lt=&Apache::lonlocal::texthash(%lt);
502:
503: $r->print(<<STUFF);
504: <p> <font color="red">Failed</font> to reserve a spot for $description. </p>
505: <p>
506: <form method="POST" action="/adm/slotrequest">
507: <input type="submit" name="Try Again" value="$lt{'try'}" />
508: <input type="hidden" name="symb" value="$env{'form.symb'}" />
509: <input type="hidden" name="slotname" value="$env{'form.slotname'}" />
510: <input type="hidden" name="command" value="get" />
511: </form>
512: ?
513: </p>
514: <p>
515: or
516: <form method="POST" action="/adm/slotrequest">
517: <input type="hidden" name="symb" value="$env{'form.symb'}" />
518: <input type="submit" name="requestattempt" value="$lt{'request'}" />
519: </form>
520: </p>
521: or
522: STUFF
523:
524: &return_link($r);
525: return;
526: }
527:
528: sub allowed_slot {
529: my ($slot_name,$slot,$symb,$slots,$consumed_uniqueperiods)=@_;
530:
531: #already started
532: if ($slot->{'starttime'} < time) {
533: # all open slot to be schedulable
534: #return 0;
535: }
536: &Apache::lonxml::debug("$slot_name starttime good");
537:
538: #already ended
539: if ($slot->{'endtime'} < time) {
540: return 0;
541: }
542: &Apache::lonxml::debug("$slot_name endtime good");
543:
544: # not allowed to pick this one
545: if (defined($slot->{'type'})
546: && $slot->{'type'} ne 'schedulable_student') {
547: return 0;
548: }
549: &Apache::lonxml::debug("$slot_name type good");
550:
551: # reserve time not yet started
552: if ($slot->{'startreserve'} > time) {
553: return 0;
554: }
555: &Apache::lonxml::debug("$slot_name reserve good");
556:
557: my $userallowed=0;
558: # its for a different set of users
559: if (defined($slot->{'allowedsections'})) {
560: if (!defined($env{'request.role.sec'})
561: && grep(/^No section assigned$/,
562: split(',',$slot->{'allowedsections'}))) {
563: $userallowed=1;
564: }
565: if (defined($env{'request.role.sec'})
566: && grep(/^\Q$env{'request.role.sec'}\E$/,
567: split(',',$slot->{'allowedsections'}))) {
568: $userallowed=1;
569: }
570: }
571: &Apache::lonxml::debug("$slot_name sections is $userallowed");
572:
573: # its for a different set of users
574: if (defined($slot->{'allowedusers'})
575: && grep(/^\Q$env{'user.name'}:$env{'user.domain'}\E$/,
576: split(',',$slot->{'allowedusers'}))) {
577: $userallowed=1;
578: }
579:
580: if (!defined($slot->{'allowedusers'})
581: && !defined($slot->{'allowedsections'})) {
582: $userallowed=1;
583: }
584:
585: &Apache::lonxml::debug("$slot_name user is $userallowed");
586: return 0 if (!$userallowed);
587:
588: # not allowed for this resource
589: if (defined($slot->{'symb'})
590: && $slot->{'symb'} ne $symb) {
591: return 0;
592: }
593:
594: my $conflict = &check_for_conflict($symb,$slot_name,$slot,$slots,
595: $consumed_uniqueperiods);
596: if ($conflict) {
597: if ($slots->{$conflict}{'starttime'} < time) {
598: return 0;
599: }
600: }
601: &Apache::lonxml::debug("$slot_name symb good");
602: return 1;
603: }
604:
605: sub get_description {
606: my ($slot_name,$slot)=@_;
607: my $description=$slot->{'description'};
608: if (!defined($description)) {
609: $description=&mt('[_1] From [_2] to [_3]',$slot_name,
610: &Apache::lonlocal::locallocaltime($slot->{'starttime'}),
611: &Apache::lonlocal::locallocaltime($slot->{'endtime'}));
612: }
613: return $description;
614: }
615:
616: sub show_choices {
617: my ($r,$symb)=@_;
618:
619: my ($cnum,$cdom)=&get_course();
620: my %slots=&Apache::lonnet::dump('slots',$cdom,$cnum);
621: my $consumed_uniqueperiods = &get_consumed_uniqueperiods(\%slots);
622: my $available;
623: $r->print('<table border="1">');
624: &Apache::lonxml::debug("Checking Slots");
625: my @got_slots=&check_for_reservation($symb,'allslots');
626: foreach my $slot (sort
627: { return $slots{$a}->{'starttime'} <=> $slots{$b}->{'starttime'} }
628: (keys(%slots))) {
629:
630: &Apache::lonxml::debug("Checking Slot $slot");
631: next if (!&allowed_slot($slot,$slots{$slot},undef,\%slots,
632: $consumed_uniqueperiods));
633:
634: $available++;
635:
636: my $description=&get_description($slot,$slots{$slot});
637:
638: my $form=&mt('Unavailable');
639: if ((grep(/^\Q$slot\E$/,@got_slots)) ||
640: &space_available($slot,$slots{$slot},$symb)) {
641: my $text=&mt('Select');
642: my $command='get';
643: if (grep(/^\Q$slot\E$/,@got_slots)) {
644: $text=&mt('Free Reservation');
645: $command='release';
646: } else {
647: my $conflict = &check_for_conflict($symb,$slot,$slots{$slot},
648: \%slots,
649: $consumed_uniqueperiods);
650: if ($conflict) {
651: $text=&mt('Change Reservation');
652: $command='get';
653: }
654: }
655: my $escsymb=&Apache::lonnet::escape($symb);
656: $form=<<STUFF;
657: <form method="POST" action="/adm/slotrequest">
658: <input type="submit" name="Select" value="$text" />
659: <input type="hidden" name="symb" value="$escsymb" />
660: <input type="hidden" name="slotname" value="$slot" />
661: <input type="hidden" name="command" value="$command" />
662: </form>
663: STUFF
664: }
665: $r->print(<<STUFF);
666: <tr>
667: <td>$form</td>
668: <td>$description</td>
669: </tr>
670: STUFF
671: }
672:
673: if (!$available) {
674: $r->print('<tr><td>No available times. <a href="/adm/flip?postdata=return:">'.
675: &mt('Return to last resource').'</a></td></tr>');
676: }
677: $r->print('</table>');
678: }
679:
680: sub to_show {
681: my ($slot,$when,$deleted) = @_;
682: my $time=time;
683: my $week=60*60*24*7;
684: if ($deleted eq 'hide' && $slot->{'type'} eq 'deleted') {
685: return 0;
686: }
687: if ($when eq 'any') {
688: return 1;
689: } elsif ($when eq 'now') {
690: if ($time > $slot->{'starttime'} &&
691: $time < $slot->{'endtime'}) {
692: return 1;
693: }
694: return 0;
695: } elsif ($when eq 'nextweek') {
696: if ( ($time < $slot->{'starttime'} &&
697: ($time+$week) > $slot->{'starttime'})
698: ||
699: ($time < $slot->{'endtime'} &&
700: ($time+$week) > $slot->{'endtime'}) ) {
701: return 1;
702: }
703: return 0;
704: } elsif ($when eq 'lastweek') {
705: if ( ($time > $slot->{'starttime'} &&
706: ($time-$week) < $slot->{'starttime'})
707: ||
708: ($time > $slot->{'endtime'} &&
709: ($time-$week) < $slot->{'endtime'}) ) {
710: return 1;
711: }
712: return 0;
713: } elsif ($when eq 'willopen') {
714: if ($time < $slot->{'starttime'}) {
715: return 1;
716: }
717: return 0;
718: } elsif ($when eq 'wereopen') {
719: if ($time > $slot->{'endtime'}) {
720: return 1;
721: }
722: return 0;
723: }
724:
725: return 1;
726: }
727:
728: sub remove_link {
729: my ($slotname,$entry,$uname,$udom,$symb) = @_;
730:
731: $slotname = &Apache::lonnet::escape($slotname);
732: $entry = &Apache::lonnet::escape($entry);
733: $uname = &Apache::lonnet::escape($uname);
734: $udom = &Apache::lonnet::escape($udom);
735: $symb = &Apache::lonnet::escape($symb);
736:
737: my $remove= &mt('Remove');
738:
739: return <<"END_LINK";
740: <a href="/adm/slotrequest?command=remove_registration&slotname=$slotname&entry=$entry&uname=$uname&udom=$udom&symb=$symb"
741: >($remove)</a>
742: END_LINK
743:
744: }
745:
746: sub show_table {
747: my ($r,$mgr)=@_;
748:
749: my ($cnum,$cdom)=&get_course();
750: my %slots=&Apache::lonnet::dump('slots',$cdom,$cnum);
751: if ( (keys(%slots))[0] =~ /^error: 2 /) {
752: undef(%slots);
753: }
754: my $available;
755: if ($mgr eq 'F') {
756: $r->print('<div>');
757: $r->print('<form method="POST" action="/adm/slotrequest">
758: <input type="hidden" name="command" value="uploadstart" />
759: <input type="submit" name="start" value="'.&mt('Upload Slot List').'" />
760: </form>');
761: $r->print('<form method="POST" action="/adm/helper/newslot.helper">
762: <input type="submit" name="newslot" value="'.&mt('Create a New Slot').'" />
763: </form>');
764: $r->print('</div>');
765: }
766:
767: my %Saveable_Parameters = ('show' => 'array',
768: 'when' => 'scalar',
769: 'order' => 'scalar',
770: 'deleted' => 'scalar',
771: );
772: &Apache::loncommon::store_course_settings('slotrequest',
773: \%Saveable_Parameters);
774: &Apache::loncommon::restore_course_settings('slotrequest',
775: \%Saveable_Parameters);
776: &Apache::grades::init_perm();
777: my ($classlist,$section,$fullname)=&Apache::grades::getclasslist('all');
778: &Apache::grades::reset_perm();
779:
780: my %show_fields=&Apache::lonlocal::texthash(
781: 'name' => 'Slot Name',
782: 'description' => 'Description',
783: 'type' => 'Type',
784: 'starttime' => 'Start time',
785: 'endtime' => 'End Time',
786: 'startreserve' => 'Time students can start reserving',
787: 'secret' => 'Secret Word',
788: 'maxspace' => 'Maximum # of students',
789: 'ip' => 'IP or DNS restrictions',
790: 'symb' => 'Resource slot is restricted to.',
791: 'allowedsections' => 'Sections slot is restricted to.',
792: 'allowedusers' => 'Users slot is restricted to.',
793: 'uniqueperiod' => 'Period of time slot is unique',
794: 'scheduled' => 'Scheduled Students',
795: 'proctor' => 'List of proctors');
796: my @show_order=('name','description','type','starttime','endtime',
797: 'startreserve','secret','maxspace','ip','symb',
798: 'allowedsections','allowedusers','uniqueperiod',
799: 'scheduled','proctor');
800: my @show =
801: (exists($env{'form.show'})) ? &Apache::loncommon::get_env_multiple('form.show')
802: : keys(%show_fields);
803: my %show = map { $_ => 1 } (@show);
804:
805: my %when_fields=&Apache::lonlocal::texthash(
806: 'now' => 'Open now',
807: 'nextweek' => 'Open within the next week',
808: 'lastweek' => 'Were open last week',
809: 'willopen' => 'Will open later',
810: 'wereopen' => 'Were open',
811: 'any' => 'Anytime',
812: );
813: my @when_order=('any','now','nextweek','lastweek','willopen','wereopen');
814: $when_fields{'select_form_order'} = \@when_order;
815: my $when = (exists($env{'form.when'})) ? $env{'form.when'}
816: : 'now';
817:
818: my %stu_display_fields=
819: &Apache::lonlocal::texthash('username' => 'User name',
820: 'fullname' => 'Full name',
821: );
822: my @stu_display_order=('fullname','username');
823: my @stu_display =
824: (exists($env{'form.studisplay'})) ? &Apache::loncommon::get_env_multiple('form.studisplay')
825: : keys(%stu_display_fields);
826: my %stu_display = map { $_ => 1 } (@stu_display);
827:
828: my $hide_radio =
829: &Apache::lonhtmlcommon::radio('deleted',$env{'form.deleted'},'hide');
830: my $show_radio =
831: &Apache::lonhtmlcommon::radio('deleted',$env{'form.deleted'},'show');
832:
833: $r->print('<form method="POST" action="/adm/slotrequest">
834: <input type="hidden" name="command" value="showslots" />');
835: $r->print('<div>');
836: $r->print('<table class="inline">
837: <tr><th>'.&mt('Show').'</th>
838: <th>'.&mt('Student Display').'</th>
839: <th>'.&mt('Open').'</th>
840: <th>'.&mt('Options').'</th>
841: </tr>
842: <tr><td>'.&Apache::loncommon::multiple_select_form('show',\@show,6,\%show_fields,\@show_order).
843: '</td>
844: <td>
845: '.&Apache::loncommon::multiple_select_form('studisplay',\@stu_display,
846: 6,\%stu_display_fields,
847: \@stu_display_order).'
848: </td>
849: <td>'.&Apache::loncommon::select_form($when,'when',%when_fields).
850: '</td>
851: <td>
852: <table>
853: <tr>
854: <td rowspan="2">Deleted slots:</td>
855: <td><label>'.$show_radio.'Show</label></td>
856: </tr>
857: <tr>
858: <td><label>'.$hide_radio.'Hide</label></td>
859: </tr>
860: </table>
861: </td>
862: </tr>
863: </table>');
864: $r->print('</div>');
865: $r->print('<p><input type="submit" name="start" value="'.&mt('Update Display').'" /></p>');
866: my $linkstart='<a href="/adm/slotrequest?command=showslots&order=';
867: $r->print('<table class="thinborder">
868: <tr>
869: <th></th>');
870: foreach my $which (@show_order) {
871: if ($which ne 'proctor' && exists($show{$which})) {
872: $r->print('<th>'.$linkstart.$which.'">'.$show_fields{$which}.'</a></th>');
873: }
874: }
875:
876: my %name_cache;
877: my $slotsort = sub {
878: if ($env{'form.order'}=~/^(type|description|endtime|startreserve|maxspace|ip|symb|allowedsections|allowedusers)$/) {
879: if (lc($slots{$a}->{$env{'form.order'}})
880: ne lc($slots{$b}->{$env{'form.order'}})) {
881: return (lc($slots{$a}->{$env{'form.order'}})
882: cmp lc($slots{$b}->{$env{'form.order'}}));
883: }
884: } elsif ($env{'form.order'} eq 'name') {
885: if (lc($a) cmp lc($b)) {
886: return lc($a) cmp lc($b);
887: }
888: } elsif ($env{'form.order'} eq 'uniqueperiod') {
889:
890: if ($slots{$a}->{'uniqueperiod'}[0]
891: ne $slots{$b}->{'uniqueperiod'}[0]) {
892: return ($slots{$a}->{'uniqueperiod'}[0]
893: cmp $slots{$b}->{'uniqueperiod'}[0]);
894: }
895: if ($slots{$a}->{'uniqueperiod'}[1]
896: ne $slots{$b}->{'uniqueperiod'}[1]) {
897: return ($slots{$a}->{'uniqueperiod'}[1]
898: cmp $slots{$b}->{'uniqueperiod'}[1]);
899: }
900: }
901: return $slots{$a}->{'starttime'} <=> $slots{$b}->{'starttime'};
902: };
903: foreach my $slot (sort $slotsort (keys(%slots))) {
904: if (!&to_show($slots{$slot},$when,$env{'form.deleted'})) { next; }
905: if (defined($slots{$slot}->{'type'})
906: && $slots{$slot}->{'type'} ne 'schedulable_student') {
907: #next;
908: }
909: my $description=&get_description($slot,$slots{$slot});
910: my $ids;
911: if (exists($show{'scheduled'})) {
912: my %consumed=&Apache::lonnet::dump('slot_reservations',$cdom,$cnum,
913: "^$slot\0");
914: my ($tmp)=%consumed;
915: if ($tmp !~ /^error: /) {
916: foreach my $entry (sort(keys(%consumed))) {
917: my (undef,$id)=split("\0",$entry);
918: my ($uname,$udom) = split('@',$consumed{$entry}{'name'});
919: $ids.= '<nobr>';
920: foreach my $item (@stu_display_order) {
921: if ($stu_display{$item}) {
922: if ($item eq 'fullname') {
923: $ids.=$fullname->{"$uname:$udom"}.' ';
924: } elsif ($item eq 'username') {
925: $ids.="<tt>$uname\@$udom</tt> ";
926: }
927: }
928: }
929: $ids.=&remove_link($slot,$entry,$uname,$udom,
930: $consumed{$entry}{'symb'}).'</nobr><br />';
931: }
932: }
933: }
934:
935: my $start=($slots{$slot}->{'starttime'}?
936: &Apache::lonlocal::locallocaltime($slots{$slot}->{'starttime'}):'');
937: my $end=($slots{$slot}->{'endtime'}?
938: &Apache::lonlocal::locallocaltime($slots{$slot}->{'endtime'}):'');
939: my $start_reserve=($slots{$slot}->{'startreserve'}?
940: &Apache::lonlocal::locallocaltime($slots{$slot}->{'startreserve'}):'');
941:
942: my $unique;
943: if (ref($slots{$slot}{'uniqueperiod'})) {
944: $unique=localtime($slots{$slot}{'uniqueperiod'}[0]).','.
945: localtime($slots{$slot}{'uniqueperiod'}[1]);
946: }
947:
948: my $title;
949: if (exists($slots{$slot}{'symb'})) {
950: my (undef,undef,$res)=
951: &Apache::lonnet::decode_symb($slots{$slot}{'symb'});
952: $res = &Apache::lonnet::clutter($res);
953: $title = &Apache::lonnet::gettitle($slots{$slot}{'symb'});
954: $title='<a href="'.$res.'?symb='.$slots{$slot}{'symb'}.'">'.$title.'</a>';
955: }
956:
957: my $allowedsections;
958: if (exists($show{'allowedsections'})) {
959: $allowedsections =
960: join(', ',sort(split(/\s*,\s*/,
961: $slots{$slot}->{'allowedsections'})));
962: }
963:
964: my @allowedusers;
965: if (exists($show{'allowedusers'})) {
966: @allowedusers= map {
967: my ($uname,$udom)=split(/:/,$_);
968: my $fullname=$name_cache{$_};
969: if (!defined($fullname)) {
970: $fullname = &Apache::loncommon::plainname($uname,$udom);
971: $fullname =~s/\s/ /g;
972: $name_cache{$_} = $fullname;
973: }
974: &Apache::loncommon::aboutmewrapper($fullname,$uname,$udom);
975: } (sort(split(/\s*,\s*/,$slots{$slot}->{'allowedusers'})));
976: }
977: my $allowedusers=join(', ',@allowedusers);
978:
979: my @proctors;
980: my $rowspan=1;
981: my $colspan=1;
982: if (exists($show{'proctor'})) {
983: $rowspan=2;
984: @proctors= map {
985: my ($uname,$udom)=split(/@/,$_);
986: my $fullname=$name_cache{$_};
987: if (!defined($fullname)) {
988: $fullname = &Apache::loncommon::plainname($uname,$udom);
989: $fullname =~s/\s/ /g;
990: $name_cache{$_} = $fullname;
991: }
992: &Apache::loncommon::aboutmewrapper($fullname,$uname,$udom);
993: } (sort(split(/\s*,\s*/,$slots{$slot}->{'proctor'})));
994: }
995: my $proctors=join(', ',@proctors);
996:
997: my $edit=(<<"EDITLINK");
998: <a href="/adm/helper/newslot.helper?name=$slot">Edit</a>
999: EDITLINK
1000:
1001: my $delete=(<<"DELETELINK");
1002: <a href="/adm/slotrequest?command=delete&slotname=$slot">Delete</a>
1003: DELETELINK
1004: if ($ids ne '') { undef($delete); }
1005:
1006: $r->print("<tr>\n<td rowspan=\"$rowspan\">$edit $delete</td>\n");
1007: if (exists($show{'name'})) {
1008: $colspan++;$r->print("<td>$slot</td>");
1009: }
1010: if (exists($show{'description'})) {
1011: $colspan++;$r->print("<td>$description</td>\n");
1012: }
1013: if (exists($show{'type'})) {
1014: $colspan++;$r->print("<td>$slots{$slot}->{'type'}</td>\n");
1015: }
1016: if (exists($show{'starttime'})) {
1017: $colspan++;$r->print("<td>$start</td>\n");
1018: }
1019: if (exists($show{'endtime'})) {
1020: $colspan++;$r->print("<td>$end</td>\n");
1021: }
1022: if (exists($show{'startreserve'})) {
1023: $colspan++;$r->print("<td>$start_reserve</td>\n");
1024: }
1025: if (exists($show{'secret'})) {
1026: $colspan++;$r->print("<td>$slots{$slot}{'secret'}</td>\n");
1027: }
1028: if (exists($show{'maxspace'})) {
1029: $colspan++;$r->print("<td>$slots{$slot}{'maxspace'}</td>\n");
1030: }
1031: if (exists($show{'ip'})) {
1032: $colspan++;$r->print("<td>$slots{$slot}{'ip'}</td>\n");
1033: }
1034: if (exists($show{'symb'})) {
1035: $colspan++;$r->print("<td>$title</td>\n");
1036: }
1037: if (exists($show{'allowedsections'})) {
1038: $colspan++;$r->print("<td>$allowedsections</td>\n");
1039: }
1040: if (exists($show{'allowedusers'})) {
1041: $colspan++;$r->print("<td>$allowedusers</td>\n");
1042: }
1043: if (exists($show{'scheduled'})) {
1044: $colspan++;$r->print("<td>$ids</td>\n</tr>\n");
1045: }
1046: if (exists($show{'proctor'})) {
1047: $r->print(<<STUFF);
1048: <tr>
1049: <td colspan="$colspan">$proctors</td>
1050: </tr>
1051: STUFF
1052: }
1053: }
1054: $r->print('</table>');
1055: }
1056:
1057: sub upload_start {
1058: my ($r)=@_;
1059: $r->print(&Apache::grades::checkforfile_js());
1060: my $result.='<table width=100% border=0><tr bgcolor="#e6ffff"><td>'."\n";
1061: $result.=' <b>'.
1062: &mt('Specify a file containing the slot definitions.').
1063: '</b></td></tr>'."\n";
1064: $result.='<tr bgcolor=#ffffe6><td>'."\n";
1065: my $upfile_select=&Apache::loncommon::upfile_select_html();
1066: my $ignore=&mt('Ignore First Line');
1067: $result.=<<ENDUPFORM;
1068: <form method="post" enctype="multipart/form-data" action="/adm/slotrequest" name="slotupload">
1069: <input type="hidden" name="command" value="csvuploadmap" />
1070: $upfile_select
1071: <br /><input type="button" onClick="javascript:checkUpload(this.form);" value="Upload Data" />
1072: <label><input type="checkbox" name="noFirstLine" />$ignore</label>
1073: </form>
1074: ENDUPFORM
1075: $result.='</td></tr></table>'."\n";
1076: $result.='</td></tr></table>'."\n";
1077: $r->print($result);
1078: }
1079:
1080: sub csvuploadmap_header {
1081: my ($r,$datatoken,$distotal)= @_;
1082: my $javascript;
1083: if ($env{'form.upfile_associate'} eq 'reverse') {
1084: $javascript=&csvupload_javascript_reverse_associate();
1085: } else {
1086: $javascript=&csvupload_javascript_forward_associate();
1087: }
1088:
1089: my $checked=(($env{'form.noFirstLine'})?' checked="checked"':'');
1090: my $ignore=&mt('Ignore First Line');
1091: $r->print(<<ENDPICK);
1092: <form method="post" enctype="multipart/form-data" action="/adm/slotrequest" name="slotupload">
1093: <h3>Identify fields</h3>
1094: Total number of records found in file: $distotal <hr />
1095: Enter as many fields as you can. The system will inform you and bring you back
1096: to this page if the data selected is insufficient to create the slots.<hr />
1097: <input type="button" value="Reverse Association" onClick="javascript:this.form.associate.value='Reverse Association';submit(this.form);" />
1098: <label><input type="checkbox" name="noFirstLine" $checked />$ignore</label>
1099: <input type="hidden" name="associate" value="" />
1100: <input type="hidden" name="datatoken" value="$datatoken" />
1101: <input type="hidden" name="fileupload" value="$env{'form.fileupload'}" />
1102: <input type="hidden" name="upfiletype" value="$env{'form.upfiletype'}" />
1103: <input type="hidden" name="upfile_associate"
1104: value="$env{'form.upfile_associate'}" />
1105: <input type="hidden" name="command" value="csvuploadassign" />
1106: <hr />
1107: <script type="text/javascript" language="Javascript">
1108: $javascript
1109: </script>
1110: ENDPICK
1111: return '';
1112:
1113: }
1114:
1115: sub csvuploadmap_footer {
1116: my ($request,$i,$keyfields) =@_;
1117: $request->print(<<ENDPICK);
1118: </table>
1119: <input type="hidden" name="nfields" value="$i" />
1120: <input type="hidden" name="keyfields" value="$keyfields" />
1121: <input type="button" onClick="javascript:verify(this.form)" value="Create Slots" /><br />
1122: </form>
1123: ENDPICK
1124: }
1125:
1126: sub csvupload_javascript_reverse_associate {
1127: my $error1=&mt('You need to specify the name, starttime, endtime and a type');
1128: return(<<ENDPICK);
1129: function verify(vf) {
1130: var foundstart=0;
1131: var foundend=0;
1132: var foundname=0;
1133: var foundtype=0;
1134: for (i=0;i<=vf.nfields.value;i++) {
1135: tw=eval('vf.f'+i+'.selectedIndex');
1136: if (i==0 && tw!=0) { foundname=1; }
1137: if (i==1 && tw!=0) { foundtype=1; }
1138: if (i==2 && tw!=0) { foundstat=1; }
1139: if (i==3 && tw!=0) { foundend=1; }
1140: }
1141: if (foundstart==0 && foundend==0 && foundtype==0 && foundname==0) {
1142: alert('$error1');
1143: return;
1144: }
1145: vf.submit();
1146: }
1147: function flip(vf,tf) {
1148: }
1149: ENDPICK
1150: }
1151:
1152: sub csvupload_javascript_forward_associate {
1153: my $error1=&mt('You need to specify the name, starttime, endtime and a type');
1154: return(<<ENDPICK);
1155: function verify(vf) {
1156: var foundstart=0;
1157: var foundend=0;
1158: var foundname=0;
1159: var foundtype=0;
1160: for (i=0;i<=vf.nfields.value;i++) {
1161: tw=eval('vf.f'+i+'.selectedIndex');
1162: if (tw==1) { foundname=1; }
1163: if (tw==2) { foundtype=1; }
1164: if (tw==3) { foundstat=1; }
1165: if (tw==4) { foundend=1; }
1166: }
1167: if (foundstart==0 && foundend==0 && foundtype==0 && foundname==0) {
1168: alert('$error1');
1169: return;
1170: }
1171: vf.submit();
1172: }
1173: function flip(vf,tf) {
1174: }
1175: ENDPICK
1176: }
1177:
1178: sub csv_upload_map {
1179: my ($r)= @_;
1180:
1181: my $datatoken;
1182: if (!$env{'form.datatoken'}) {
1183: $datatoken=&Apache::loncommon::upfile_store($r);
1184: } else {
1185: $datatoken=$env{'form.datatoken'};
1186: &Apache::loncommon::load_tmp_file($r);
1187: }
1188: my @records=&Apache::loncommon::upfile_record_sep();
1189: if ($env{'form.noFirstLine'}) { shift(@records); }
1190: &csvuploadmap_header($r,$datatoken,$#records+1);
1191: my ($i,$keyfields);
1192: if (@records) {
1193: my @fields=&csvupload_fields();
1194:
1195: if ($env{'form.upfile_associate'} eq 'reverse') {
1196: &Apache::loncommon::csv_print_samples($r,\@records);
1197: $i=&Apache::loncommon::csv_print_select_table($r,\@records,
1198: \@fields);
1199: foreach (@fields) { $keyfields.=$_->[0].','; }
1200: chop($keyfields);
1201: } else {
1202: unshift(@fields,['none','']);
1203: $i=&Apache::loncommon::csv_samples_select_table($r,\@records,
1204: \@fields);
1205: my %sone=&Apache::loncommon::record_sep($records[0]);
1206: $keyfields=join(',',sort(keys(%sone)));
1207: }
1208: }
1209: &csvuploadmap_footer($r,$i,$keyfields);
1210:
1211: return '';
1212: }
1213:
1214: sub csvupload_fields {
1215: return (['name','Slot name'],
1216: ['type','Type of slot'],
1217: ['starttime','Start Time of slot'],
1218: ['endtime','End Time of slot'],
1219: ['startreserve','Reservation Start Time'],
1220: ['ip','IP or DNS restriction'],
1221: ['proctor','List of proctor ids'],
1222: ['description','Slot Description'],
1223: ['maxspace','Maximum number of reservations'],
1224: ['symb','Resource Restriction'],
1225: ['uniqueperiod','Date range of slot exclusion'],
1226: ['secret','Secret word proctor uses to validate'],
1227: ['allowedsections','Sections slot is restricted to'],
1228: ['allowedusers','Users slot is restricted to'],
1229: );
1230: }
1231:
1232: sub csv_upload_assign {
1233: my ($r,$mgr)= @_;
1234: &Apache::loncommon::load_tmp_file($r);
1235: my @slotdata = &Apache::loncommon::upfile_record_sep();
1236: if ($env{'form.noFirstLine'}) { shift(@slotdata); }
1237: my %fields=&Apache::grades::get_fields();
1238: $r->print('<h3>Creating Slots</h3>');
1239: my $cname=$env{'course.'.$env{'request.course.id'}.'.num'};
1240: my $cdom=$env{'course.'.$env{'request.course.id'}.'.domain'};
1241: my $countdone=0;
1242: my @errors;
1243: foreach my $slot (@slotdata) {
1244: my %slot;
1245: my %entries=&Apache::loncommon::record_sep($slot);
1246: my $domain;
1247: my $name=$entries{$fields{'name'}};
1248: if ($name=~/^\s*$/) {
1249: push(@errors,"Did not create slot with no name");
1250: next;
1251: }
1252: if ($name=~/\s/) {
1253: push(@errors,"$name not created -- Name must not contain spaces");
1254: next;
1255: }
1256: if ($name=~/\W/) {
1257: push(@errors,"$name not created -- Name must contain only letters, numbers and _");
1258: next;
1259: }
1260: if ($entries{$fields{'type'}}) {
1261: $slot{'type'}=$entries{$fields{'type'}};
1262: } else {
1263: $slot{'type'}='preassigned';
1264: }
1265: if ($slot{'type'} ne 'preassigned' &&
1266: $slot{'type'} ne 'schedulable_student') {
1267: push(@errors,"$name not created -- invalid type ($slot{'type'}) must be either preassigned or schedulable_student");
1268: next;
1269: }
1270: if ($entries{$fields{'starttime'}}) {
1271: $slot{'starttime'}=&UnixDate($entries{$fields{'starttime'}},"%s");
1272: }
1273: if ($entries{$fields{'endtime'}}) {
1274: $slot{'endtime'}=&UnixDate($entries{$fields{'endtime'}},"%s");
1275: }
1276: if ($entries{$fields{'startreserve'}}) {
1277: $slot{'startreserve'}=
1278: &UnixDate($entries{$fields{'startreserve'}},"%s");
1279: }
1280: foreach my $key ('ip','proctor','description','maxspace',
1281: 'secret','symb') {
1282: if ($entries{$fields{$key}}) {
1283: $slot{$key}=$entries{$fields{$key}};
1284: }
1285: }
1286: if ($entries{$fields{'uniqueperiod'}}) {
1287: my ($start,$end)=split(',',$entries{$fields{'uniqueperiod'}});
1288: my @times=(&UnixDate($start,"%s"),
1289: &UnixDate($end,"%s"));
1290: $slot{'uniqueperiod'}=\@times;
1291: }
1292:
1293: &Apache::lonnet::cput('slots',{$name=>\%slot},$cdom,$cname);
1294: $r->print('.');
1295: $r->rflush();
1296: $countdone++;
1297: }
1298: $r->print("<p>Created $countdone slots\n</p>");
1299: foreach my $error (@errors) {
1300: $r->print("<p>$error\n</p>");
1301: }
1302: &show_table($r,$mgr);
1303: return '';
1304: }
1305:
1306: sub handler {
1307: my $r=shift;
1308:
1309: &Apache::loncommon::content_type($r,'text/html');
1310: &Apache::loncommon::no_cache($r);
1311: if ($r->header_only()) {
1312: $r->send_http_header();
1313: return OK;
1314: }
1315:
1316: &Apache::loncommon::get_unprocessed_cgi($ENV{'QUERY_STRING'});
1317:
1318: my $vgr=&Apache::lonnet::allowed('vgr',$env{'request.course.id'});
1319: my $mgr=&Apache::lonnet::allowed('mgr',$env{'request.course.id'});
1320: my $title='Requesting Another Worktime';
1321: if ($env{'form.command'} =~ /^(showslots|uploadstart|csvuploadmap|csvuploadassign)$/ && $vgr eq 'F') {
1322: $title = 'Managing Slots';
1323: }
1324: &start_page($r,$title);
1325:
1326: if ($env{'form.command'} eq 'showslots' && $vgr eq 'F') {
1327: &show_table($r,$mgr);
1328: } elsif ($env{'form.command'} eq 'remove_registration' && $mgr eq 'F') {
1329: &remove_registration($r);
1330: } elsif ($env{'form.command'} eq 'release' && $mgr eq 'F') {
1331: &release_slot($r,undef,undef,undef,$mgr);
1332: } elsif ($env{'form.command'} eq 'delete' && $mgr eq 'F') {
1333: &delete_slot($r);
1334: } elsif ($env{'form.command'} eq 'uploadstart' && $mgr eq 'F') {
1335: &upload_start($r);
1336: } elsif ($env{'form.command'} eq 'csvuploadmap' && $mgr eq 'F') {
1337: &csv_upload_map($r);
1338: } elsif ($env{'form.command'} eq 'csvuploadassign' && $mgr eq 'F') {
1339: if ($env{'form.associate'} ne 'Reverse Association') {
1340: &csv_upload_assign($r,$mgr);
1341: } else {
1342: if ( $env{'form.upfile_associate'} ne 'reverse' ) {
1343: $env{'form.upfile_associate'} = 'reverse';
1344: } else {
1345: $env{'form.upfile_associate'} = 'forward';
1346: }
1347: &csv_upload_map($r);
1348: }
1349: } else {
1350: my $symb=&Apache::lonnet::unescape($env{'form.symb'});
1351: my (undef,undef,$res)=&Apache::lonnet::decode_symb($symb);
1352: my $useslots = &Apache::lonnet::EXT("resource.0.useslots",$symb);
1353: if ($useslots ne 'resource') {
1354: &fail($r,'not_valid');
1355: return OK;
1356: }
1357: $env{'request.symb'}=$symb;
1358: my $type = ($res =~ /\.task$/) ? 'Task'
1359: : 'problem';
1360: my ($status) = &Apache::lonhomework::check_slot_access('0',$type);
1361: if ($status eq 'CAN_ANSWER' ||
1362: $status eq 'NEEDS_CHECKIN' ||
1363: $status eq 'WAITING_FOR_GRADE') {
1364: &fail($r,'not_allowed');
1365: return OK;
1366: }
1367: if ($env{'form.requestattempt'}) {
1368: &show_choices($r,$symb);
1369: } elsif ($env{'form.command'} eq 'release') {
1370: &release_slot($r,$symb);
1371: } elsif ($env{'form.command'} eq 'get') {
1372: &get_slot($r,$symb);
1373: } elsif ($env{'form.command'} eq 'change') {
1374: if (&release_slot($r,$symb,$env{'form.releaseslot'},1)) {
1375: &get_slot($r,$symb);
1376: }
1377: } else {
1378: $r->print("<p>Unknown command: ".$env{'form.command'}."</p>");
1379: }
1380: }
1381: &end_page($r);
1382: return OK;
1383: }
1384:
1385: 1;
1386: __END__
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>