1: #
2: # $Id: assesscalc.pm,v 1.43 2005/05/15 02:28:23 albertel Exp $
3: #
4: # Copyright Michigan State University Board of Trustees
5: #
6: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
7: #
8: # LON-CAPA is free software; you can redistribute it and/or modify
9: # it under the terms of the GNU General Public License as published by
10: # the Free Software Foundation; either version 2 of the License, or
11: # (at your option) any later version.
12: #
13: # LON-CAPA is distributed in the hope that it will be useful,
14: # but WITHOUT ANY WARRANTY; without even the implied warranty of
15: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
16: # GNU General Public License for more details.
17: #
18: # You should have received a copy of the GNU General Public License
19: # along with LON-CAPA; if not, write to the Free Software
20: # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
21: #
22: # /home/httpd/html/adm/gpl.txt
23: #
24: # http://www.lon-capa.org/
25: #
26: # The LearningOnline Network with CAPA
27: # Spreadsheet/Grades Display Handler
28: #
29: # POD required stuff:
30:
31: =head1 NAME
32:
33: assesscalc
34:
35: =head1 SYNOPSIS
36:
37: =head1 DESCRIPTION
38:
39: =cut
40:
41: ###################################################
42: ### AssessSheet ###
43: ###################################################
44: package Apache::assesscalc;
45:
46: use strict;
47: use warnings FATAL=>'all';
48: no warnings 'uninitialized';
49: use Apache::Constants qw(:common :http);
50: use Apache::lonnet;
51: use Apache::loncommon;
52: use Apache::Spreadsheet;
53: use Apache::loncoursedata();
54: use HTML::Entities();
55: use Spreadsheet::WriteExcel;
56: use GDBM_File;
57: use Time::HiRes;
58: use Apache::lonlocal;
59:
60: @Apache::assesscalc::ISA = ('Apache::Spreadsheet');
61:
62: ########################################################
63: ########################################################
64:
65: =pod
66:
67: =head2 Package Variables
68:
69: =over 4
70:
71: =item %Exportrows
72:
73: =item $current_name
74:
75: =item $current_domain
76:
77: =item $current_course
78:
79: =item %parmhash
80:
81: =item %nice_parameter_name
82:
83: =item %useropt
84:
85: =item %courseopt
86:
87: =back
88:
89: =cut
90:
91: ########################################################
92: ########################################################
93:
94: my %Exportrows;
95: my %newExportrows;
96:
97: my $current_name;
98: my $current_domain;
99: my $current_course;
100:
101: my %parmhash;
102: my %nice_parameter_name;
103:
104: my %useropt;
105: my %userdata;
106: my %courseopt;
107: my $navmap;
108:
109: ########################################################
110: ########################################################
111:
112: =pod
113:
114: =head2 Package Subroutines
115:
116: =item &clear_package()
117:
118: Reset all package variables and clean up caches.
119:
120: =cut
121:
122: ########################################################
123: ########################################################
124: sub clear_package {
125: if (defined($current_name) &&
126: defined($current_domain) &&
127: defined($current_course) &&
128: $current_course eq $env{'request.course.id'} &&
129: %newExportrows) {
130: &save_cached_export_rows($current_name,$current_domain);
131: }
132: undef(%Exportrows);
133: undef(%newExportrows);
134: undef($current_name);
135: undef($current_domain);
136: undef($current_course);
137: undef(%useropt);
138: undef(%userdata);
139: undef(%courseopt);
140: undef($navmap);
141: }
142:
143: sub save_cached_export_rows {
144: my ($sname,$sdomain) = @_;
145: my $result = &Apache::lonnet::put
146: ('nohist_calculatedsheets_'.$env{'request.course.id'},
147: $newExportrows{$sname.':'.$sdomain},
148: $sdomain,$sname);
149: delete($newExportrows{$sname.':'.$sdomain});
150: }
151:
152: sub initialize {
153: my ($in_navmap) = @_;
154: &clear_package();
155: $navmap = $in_navmap;
156: if (! defined($navmap)) {
157: $navmap = Apache::lonnavmaps::navmap->new();
158: }
159: if (!defined($navmap)) {
160: &Apache::lonnet::logthis('assesscalc:Can not open Coursemap');
161: }
162: &Apache::loncoursedata::clear_internal_caches();
163: }
164:
165: ########################################################
166: ########################################################
167:
168: =pod
169:
170: =item &initialize_package()
171:
172: =cut
173:
174: ########################################################
175: ########################################################
176: sub initialize_package {
177: my ($sname,$sdomain,$in_navmap) = @_;
178: $current_name = $sname;
179: $current_domain = $sdomain;
180: $navmap = $in_navmap;
181: undef(%useropt);
182: undef(%userdata);
183: if ($current_course ne $env{'request.course.id'}) {
184: $current_course = $env{'request.course.id'};
185: undef(%courseopt);
186: }
187: &load_cached_export_rows();
188: &load_parameter_caches();
189: &Apache::loncoursedata::clear_internal_caches();
190: }
191:
192:
193: ########################################################
194: ########################################################
195:
196: =pod
197:
198: =item &load_parameter_caches()
199:
200: =cut
201:
202: ########################################################
203: ########################################################
204: sub load_parameter_caches {
205: my $userprefix = $current_name.':'.$current_domain.'_';
206: $userprefix =~ s/:/_/g;
207: #
208: # Course Parameters Cache
209: if (! %courseopt) {
210: $current_course = $env{'request.course.id'};
211: undef(%courseopt);
212: if (! defined($current_name) || ! defined($current_domain)) {
213: return;
214: }
215: my $dom = $env{'course.'.$env{'request.course.id'}.'.domain'};
216: my $id = $env{'course.'.$env{'request.course.id'}.'.num'};
217: my %Tmp = &Apache::lonnet::dump('resourcedata',$dom,$id);
218: while (my ($name,$value) = each(%Tmp)) {
219: $courseopt{$name}=$value;
220: }
221: }
222: if (! %useropt) {
223: my %Tmp = &Apache::lonnet::dump('resourcedata',
224: $current_domain,$current_name);
225: while (my ($name,$value) = each(%Tmp)) {
226: if ($name =~ /^error: 2/ || $name =~ /no such file/) {
227: undef(%useropt);
228: last;
229: }
230: $useropt{$userprefix.$name}=$value;
231: }
232: $useropt{'loadtime'} = time;
233: }
234: if (! %userdata) {
235: %userdata = &Apache::loncoursedata::get_current_state($current_name,
236: $current_domain);
237: $userdata{'loadtime'} = time;
238: }
239: return;
240: }
241:
242: ########################################################
243: ########################################################
244:
245: =pod
246:
247: =head2 assesscalc object methods
248:
249: =cut
250:
251: ########################################################
252: ########################################################
253: sub ensure_current_caches {
254: my $self = shift;
255: ##
256: ## Check for a modified parameters
257: ##
258: if (! defined($current_course) ||
259: $current_course ne $env{'request.course.id'} ) {
260: $current_course = $env{'request.course.id'};
261: undef(%courseopt);
262: undef(%useropt);
263: undef(%userdata);
264: }
265: ##
266: ## Check for new user
267: ##
268: if (! defined($current_name) || $current_name ne $self->{'name'} ||
269: ! defined($current_domain) || $current_domain ne $self->{'domain'}) {
270: $current_domain = $self->{'domain'};
271: $current_name = $self->{'name'};
272: undef(%useropt);
273: undef(%userdata);
274: }
275: &load_parameter_caches();
276: }
277:
278: ##################################################
279: ##################################################
280:
281: =pod
282:
283: =item &parmval()
284:
285: Determine the value of a parameter.
286:
287: Inputs: $what, the parameter needed, $symb, $uname, $udom, $csec
288:
289: Returns: The value of a parameter, or '' if none.
290:
291: This function cascades through the possible levels searching for a value for
292: a parameter. The levels are checked in the following order:
293: user, course (at section level and course level), map, and lonnet::metadata.
294: This function uses %parmhash, which must be tied prior to calling it.
295: This function also requires %courseopt and %useropt to be initialized for
296: this user and course.
297:
298: =cut
299:
300: ##################################################
301: ##################################################
302: sub parmval {
303: my $self = shift;
304: my ($what,$symb,$uname,$udom,$csec,$recurse)=@_;
305: $uname = $self->{'name'} if (! defined($uname));
306: $udom = $self->{'domain'} if (! defined($udom));
307: $csec = $self->{'section'} if (! defined($csec));
308: $symb = $self->{'symb'} if (! defined($symb));
309: #
310: my $result='';
311: #
312: # This should be a
313: my ($mapname,$id,$fn)=&Apache::lonnet::decode_symb($symb);
314: # Cascading lookup scheme
315: my $rwhat=$what;
316: $what =~ s/^parameter\_//;
317: $what =~ s/\_([^\_]+)$/\.$1/;
318: #
319: my $symbparm = $symb.'.'.$what;
320: my $mapparm = $mapname.'___(all).'.$what;
321: my $courseprefix = $self->{'cid'};
322: my $usercourseprefix = $uname.'_'.$udom.'_'.$self->{'cid'};
323: #
324: my $seclevel = $courseprefix.'.['.$csec.'].'.$what;
325: my $seclevelr = $courseprefix.'.['.$csec.'].'.$symbparm;
326: my $seclevelm = $courseprefix.'.['.$csec.'].'.$mapparm;
327: #
328: my $courselevel = $courseprefix.'.'.$what;
329: my $courselevelr = $courseprefix.'.'.$symbparm;
330: my $courselevelm = $courseprefix.'.'.$mapparm;
331: #
332: my $ucourselevel = $usercourseprefix.'.'.$what;
333: my $ucourselevelr = $usercourseprefix.'.'.$symbparm;
334: my $ucourselevelm = $usercourseprefix.'.'.$mapparm;
335: # check user
336: if (defined($uname)) {
337: return $useropt{$ucourselevelr} if (defined($useropt{$ucourselevelr}));
338: return $useropt{$ucourselevelm} if (defined($useropt{$ucourselevelm}));
339: return $useropt{$ucourselevel} if (defined($useropt{$ucourselevel}));
340: }
341: # check section
342: if (defined($csec)) {
343: return $courseopt{$seclevelr} if (defined($courseopt{$seclevelr}));
344: return $courseopt{$seclevelm} if (defined($courseopt{$seclevelm}));
345: return $courseopt{$seclevel} if (defined($courseopt{$seclevel}));
346: }
347: #
348: # check course
349: return $courseopt{$courselevelr} if (defined($courseopt{$courselevelr}));
350: # check map parms
351: my $thisparm = $parmhash{$symbparm};
352: return $thisparm if (defined($thisparm));
353: # check default
354: $thisparm = &Apache::lonnet::metadata($fn,$rwhat.'.default');
355: return $thisparm if (defined($thisparm));
356: # check more course
357: return $courseopt{$courselevelm} if (defined($courseopt{$courselevelm}));
358: return $courseopt{$courselevel} if (defined($courseopt{$courselevel}));
359:
360: # Cascade Up
361: my $space=$what;
362: $space=~s/\.[^._]+$//;
363: if ($space ne '0') {
364: my @parts=split(/_/,$space);
365: my $id=pop(@parts);
366: my $part=join('_',@parts);
367: if ($part eq '') { $part='0'; }
368: my $newwhat=$rwhat;
369: $newwhat=~s/\Q$space\E/$part/;
370: my $partgeneral=$self->parmval($newwhat,$symb,$uname,$udom,$csec,1);
371: if (defined($partgeneral)) { return $partgeneral; }
372: }
373: if ($recurse) { return undef; }
374: my $pack_def=&Apache::lonnet::packages_tab_default($fn,'resource.'.$what);
375: if (defined($pack_def)) { return $pack_def; }
376: #nothing defined
377: return '';
378: }
379:
380: sub get_html_title {
381: my $self = shift;
382: my ($assess_title,$name,$time) = $self->get_full_title();
383: my $title = '<h1>'.$assess_title.'</h1>'.
384: '<h2>'.$name.', '.
385: &Apache::loncommon::aboutmewrapper
386: ($self->{'name'}.'@'.$self->{'domain'},
387: $self->{'name'},$self->{'domain'});
388: $title .= '<h3>'.$time.'</h3>';
389: return $title;
390: }
391:
392: sub get_title {
393: my $self = shift;
394: if (($self->{'symb'} eq '_feedback') ||
395: ($self->{'symb'} eq '_evaluation') ||
396: ($self->{'symb'} eq '_discussion') ||
397: ($self->{'symb'} eq '_tutoring')) {
398: my $assess_title = ucfirst($self->{'symb'});
399: $assess_title =~ s/^_//;
400: return $assess_title;
401: } else {
402: return &Apache::lonnet::gettitle($self->{'symb'});
403: }
404: }
405:
406: sub get_full_title {
407: my $self = shift;
408: my @title = ($self->get_title());
409: # Look up the users identifying information
410: # Get the users information
411: my $name = &Apache::loncommon::plainname($self->{'name'},
412: $self->{'domain'});
413: push (@title,$name);
414: push (@title,&Apache::lonlocal::locallocaltime(time));
415: return @title;
416: }
417:
418: sub parent_link {
419: my $self = shift;
420: my $link .= '<p><a href="/adm/studentcalc?'.
421: 'sname='.$self->{'name'}.
422: '&sdomain='.$self->{'domain'}.'">'.
423: &mt('Student level sheet').'</a></p>'."\n";
424: return $link;
425: }
426:
427: sub outsheet_html {
428: my $self = shift;
429: my ($r) = @_;
430: ####################################
431: # Report any calculation errors #
432: ####################################
433: $r->print($self->html_report_error());
434: ###################################
435: # Determine table structure
436: ###################################
437: my $importcolor = '#FFFFFF';
438: my $exportcolor = '#FFFFAA';
439: my $num_uneditable = 1;
440: my $num_left = 52-$num_uneditable;
441: my %lt=&Apache::lonlocal::texthash(
442: 'as' => 'Assessment',
443: 'ca' => 'Calculations',
444: );
445: my $tableheader =<<"END";
446: <table border="2">
447: <tr>
448: <th colspan="2" rowspan="2"><font size="+2">$lt{'as'}</font></th>
449: <td bgcolor="$importcolor" colspan="$num_uneditable"> </td>
450: <td colspan="$num_left">
451: <b><font size="+1">$lt{'ca'}</font></b></td>
452: </tr><tr>
453: END
454: my $label_num = 0;
455: foreach (split(//,'ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz')){
456: if ($label_num<$num_uneditable) {
457: $tableheader .= '<td bgcolor="'.$importcolor.'">';
458: } else {
459: $tableheader .= '<td>';
460: }
461: $tableheader .= "<b><font size=+1>$_</font></b></td>";
462: $label_num++;
463: }
464: $tableheader.="</tr>\n";
465: #
466: $r->print($tableheader);
467: #
468: # Print out template row
469: $r->print('<tr><td>Template</td><td> </td>'.
470: $self->html_template_row($num_uneditable,$importcolor).
471: "</tr>\n");
472: #
473: # Print out summary/export row
474: $r->print('<tr><td>Export</td><td>0</td>'.
475: $self->html_export_row($exportcolor)."</tr>\n");
476: #
477: # Prepare to output rows
478: $tableheader =<<"END";
479: <table border="2">
480: <tr><th>row</th><th>Item</th>
481: END
482: foreach (split(//,'ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz')){
483: if ($label_num<$num_uneditable) {
484: $tableheader.='<th bgcolor="'.$importcolor.'">';
485: } else {
486: $tableheader.='<th>';
487: }
488: $tableheader.="<b><font size=+1>$_</font></b></th>";
489: }
490: #
491: my $num_output = 0;
492: foreach my $rownum (sort {$a <=> $b} ($self->rows())) {
493: if (! $self->parameter_part_is_valid(
494: $self->{'formulas'}->{'A'.$rownum}
495: )) {
496: next;
497: }
498: if ($num_output++ % 50 == 0) {
499: $r->print("</table>\n".$tableheader);
500: }
501: $r->print('<tr><td>'.$rownum.'</td>'.
502: $self->assess_html_row($rownum,$importcolor)."</tr>\n");
503: }
504: $r->print("</table>\n");
505: return;
506: }
507:
508: sub assess_html_row {
509: my $self = shift();
510: my ($row,$importcolor) = @_;
511: my $parameter_name = $self->{'formulas'}->{'A'.$row};
512: my @rowdata = $self->get_row($row);
513: my $num_cols_output = 0;
514: my $row_html;
515: if (exists($nice_parameter_name{$parameter_name})) {
516: my $name = $nice_parameter_name{$parameter_name};
517: $name =~ s/ /\ /g;
518: $row_html .= '<td>'.$name.'<br />'.$parameter_name.'</td>';
519: } else {
520: $row_html .= '<td>'.$parameter_name.'</td>';
521: }
522: foreach my $cell (@rowdata) {
523: if ($num_cols_output < 1) {
524: $row_html .= '<td bgcolor="'.$importcolor.'">';
525: $row_html .= &Apache::Spreadsheet::html_uneditable_cell($cell,
526: '#FFDDDD');
527: } else {
528: $row_html .= '<td bgcolor="#EOFFDD">';
529: $row_html .= &Apache::Spreadsheet::html_editable_cell($cell,
530: '#E0FFDD',1);
531: }
532: $row_html .= '</td>';
533: $num_cols_output++;
534: }
535: return $row_html;
536: }
537:
538: sub csv_rows {
539: # writes the meat of the spreadsheet to an excel worksheet. Called
540: # by Spreadsheet::outsheet_excel;
541: my $self = shift;
542: my ($connection,$filehandle) = @_;
543: #
544: # Write a header row
545: $self->csv_output_row($filehandle,undef,
546: (&mt('Parameter'),&mt('Description'),&mt('Value')));
547: #
548: # Write each row
549: foreach my $rownum (sort {$a <=> $b} ($self->rows())) {
550: my $parameter_name = $self->{'formulas'}->{'A'.$rownum};
551: my $description = '';
552: if (exists($nice_parameter_name{$parameter_name})) {
553: $description = $nice_parameter_name{$parameter_name};
554: }
555: $self->csv_output_row($filehandle,$rownum,
556: $parameter_name,$description);
557: }
558: return;
559: }
560:
561: sub excel_rows {
562: # writes the meat of the spreadsheet to an excel worksheet. Called
563: # by Spreadsheet::outsheet_excel;
564: my $self = shift;
565: my ($connection,$worksheet,$cols_output,$rows_output,$format) = @_;
566: return if (! ref($worksheet));
567: #
568: # Write a header row
569: $cols_output = 0;
570: foreach my $value ('Parameter','Description','Value') {
571: $worksheet->write($rows_output,$cols_output++,$value,$format->{'h4'});
572: }
573: $rows_output++;
574: #
575: # Write each row
576: foreach my $rownum (sort {$a <=> $b} ($self->rows())) {
577: my $parameter_name = $self->{'formulas'}->{'A'.$rownum};
578: my $description = '';
579: if (exists($nice_parameter_name{$parameter_name})) {
580: $description = $nice_parameter_name{$parameter_name};
581: }
582: $self->excel_output_row($worksheet,$rownum,$rows_output++,
583: $parameter_name,$description);
584: }
585: return;
586: }
587:
588: ##
589: ## Routines to support assesscalc::compute
590: ##
591: sub get_parm_names {
592: my $self = shift;
593: my @Mandatory_parameters = @_;
594: my %parameters_and_names;
595: #
596: my ($symap,$syid,$srcf) = &Apache::lonnet::decode_symb($self->{'symb'});
597: my @Metadata = split(/\,/,&Apache::lonnet::metadata($srcf,'keys'));
598: foreach my $parm (@Mandatory_parameters,@Metadata) {
599: next if ($parm !~ /^(resource\.|stores|parameter)_/);
600: my $cleaned_name = $parm;
601: $cleaned_name =~ s/^resource\./stores_/;
602: $cleaned_name =~ s/\./_/g;
603: my $display = &Apache::lonnet::metadata($srcf,
604: $cleaned_name.'.display');
605: if (! $display) {
606: $display .= &Apache::lonnet::metadata($srcf,$cleaned_name.'.name');
607: }
608: $parameters_and_names{$cleaned_name}=$display;
609: }
610: return (%parameters_and_names);
611: }
612:
613: sub get_parameter_values {
614: my $self = shift();
615: my @Parameters;
616: my ($parameters) = @_;
617: if (!ref($parameters)) {
618: @Parameters = @_;
619: } elsif (ref($parameters) eq 'ARRAY') {
620: @Parameters = @$parameters;
621: } elsif (ref($parameters) eq 'HASH') {
622: @Parameters = keys(%$parameters);
623: }
624: #
625: my %parameters;
626: #
627: my $filename = $self->{'coursefilename'}.'_parms.db';
628: if (tie(%parmhash,'GDBM_File',
629: $self->{'coursefilename'}.'_parms.db',&GDBM_READER(),0640)) {
630: foreach my $parmname (@Parameters) {
631: my $value = $self->parmval($parmname);
632: $parameters{$parmname} =$value;
633: }
634: untie(%parmhash);
635: } else {
636: $self->logthis('unable to tie '.$filename);
637: }
638: return %parameters;
639: }
640:
641: sub deal_with_export_row {
642: my $self = shift();
643: my @exportarray = @_;
644: $Exportrows{$self->{'symb'}}->{'time'} = time;
645: $Exportrows{$self->{'symb'}}->{$self->{'filename'}} = \@exportarray;
646: #
647: # Save the export data
648: $self->save_export_data();
649: return;
650: }
651:
652: sub get_problem_state {
653: my $self = shift;
654: my %student_parameters;
655: if (exists($userdata{$self->{'symb'}}) &&
656: ref($userdata{$self->{'symb'}}) eq 'HASH') {
657: %student_parameters = %{$userdata{$self->{'symb'}}};
658: }
659: return %student_parameters;
660: }
661:
662: sub determine_parts {
663: my $self = shift;
664: my $check_hidden = shift;
665: if (exists($self->{'Parts'}) && ref($self->{'Parts'}) eq 'HASH') {
666: return;
667: }
668: my (undef,undef,$url) = &Apache::lonnet::decode_symb($self->{'symb'});
669: my $src = &Apache::lonnet::clutter($url);
670: return if (! defined($src));
671: my %Parts;
672: my $metadata = &Apache::lonnet::metadata($src,'packages');
673: foreach (split(',',$metadata)) {
674: my ($part) = (/^part_(.*)$/);
675: if (!defined($part)) { next; }
676: if (!$check_hidden) { $Parts{$part}++; next; }
677: if (!&Apache::loncommon::check_if_partid_hidden
678: ($part,$self->{'symb'},$self->{'name'},$self->{'domain'})
679: ) {
680: $Parts{$part}++;
681: }
682: }
683: # Make sure part 0 is defined.
684: $Parts{'0'}++;
685: $self->{'Parts'} = \%Parts;
686: return;
687: }
688:
689: sub parameter_part_is_valid {
690: my $self = shift;
691: my ($parameter) = @_;
692: return 1 if ($parameter eq 'timestamp');
693: if (! defined($self->{'Parts'}) ||
694: ! ref ($self->{'Parts'}) ||
695: ref($self->{'Parts'}) ne 'HASH') {
696: return 1;
697: }
698: #
699: my (undef,$part) =
700: ($parameter =~ m/^(resource|stores|parameter)_([^_]+)_.*/);
701: if (exists($self->{'Parts'}) &&
702: exists($self->{'Parts'}->{$part}) &&
703: $self->{'Parts'}->{$part} ) {
704: return 1;
705: } else {
706: return 0;
707: }
708: }
709:
710: sub compute {
711: my $self = shift;
712: my ($r) = @_;
713: $self->initialize_safe_space();
714: #########################################
715: #########################################
716: ### ###
717: ### Retrieve the problem parameters ###
718: ### ###
719: #########################################
720: #########################################
721: my @Mandatory_parameters = ("stores_0_solved",
722: "stores_0_awarddetail",
723: "stores_0_awarded",
724: "timestamp",
725: "stores_0_tries",
726: "stores_0_award");
727: #
728: # Definitions
729: undef(%nice_parameter_name);
730: my %parameters; # holds underscored parameters by name
731: #
732: # Get the metadata fields and determine their proper names
733: my %nice_parm_names = $self->get_parm_names(@Mandatory_parameters);
734: while (my($cleaned_name,$display) = each(%nice_parm_names)) {
735: $parameters{$cleaned_name}++;
736: $nice_parameter_name{$cleaned_name} = $display;
737: }
738: #
739: # Get the values of the metadata fields
740: $self->ensure_current_caches();
741: %parameters = $self->get_parameter_values(keys(%parameters));
742: #
743: # Clean out unnecessary parameters
744: foreach (keys(%parameters)) {
745: delete($parameters{$_}) if (! /(resource\.|stores_|parameter_)/);
746: }
747: #
748: # Get the students performance data
749: $self->determine_parts(($parameters{'parameter_0_hiddenparts'} ne ''));
750: my %student_parameters = $self->get_problem_state();
751: while (my ($parm,$value) = each(%student_parameters)) {
752: $parm =~ s/^resource\./stores_/;
753: $parm =~ s/\./_/g;
754: # Clean out any bad parameters
755: next if (! $self->parameter_part_is_valid($parm));
756: $parameters{$parm} = $value;
757: }
758: #
759: # Set up the formulas and parameter values
760: my %f=$self->formulas();
761: my %c;
762: #
763: # Check for blackout requirements
764: if ((!exists($env{'request.role.adv'}) || !$env{'request.role.adv'})) {
765: while (my ($parm,$value) = each(%parameters)) {
766: last if ($self->blackout());
767: next if ($parm !~ /^(parameter_.*)_problemstatus$/);
768: if ($parameters{$1.'_answerdate'} ne '' &&
769: $parameters{$1.'_answerdate'} < time) {
770: next;
771: }
772: if (lc($value) eq 'no') {
773: # We must blackout this sheet
774: $self->blackout(1);
775: }
776: }
777: }
778: #
779: # Move the parameters into the spreadsheet
780: while (my ($parm,$value) = each(%parameters)) {
781: my $cell = 'A'.$self->get_row_number_from_key($parm);
782: $f{$cell} = $parm;
783: if ($parm =~ /_submission$/ && $value =~ /(\{|\})/) {
784: $value = 'witheld';
785: }
786: $value = 'q{'.$value.'}' if ($value =~/([^\d\.]|\.\.)/);
787: $c{$parm} = $value;
788: }
789: $self->formulas(\%f);
790: $self->constants(\%c);
791: $self->calcsheet();
792: #
793: # Store export row in cache
794: my @exportarray = $self->exportrow();
795: $self->deal_with_export_row(@exportarray);
796: $self->save() if ($self->need_to_save());
797: return;
798: }
799:
800: ##
801: ## sett overrides Spreadsheet::sett
802: ##
803: sub sett {
804: my $self = shift;
805: my %t=();
806: undef(%Apache::Spreadsheet::sheet_values);
807: #
808: # Deal with the template row by copying the template formulas into each
809: # row.
810: foreach my $col ($self->template_cells()) {
811: next if ($col=~/^A/);
812: foreach my $row ($self->rows()) {
813: # Get the name of this cell
814: my $cell=$col.$row;
815: # Grab the template declaration
816: $t{$cell}=$self->formula('template_'.$col);
817: # Replace '#' with the row number
818: $t{$cell}=~s/\#/$row/g;
819: # Replace '....' with ','
820: $t{$cell}=~s/\.\.+/\,/g;
821: # Replace 'A0' with the value from 'A0'
822: $t{$cell}=~s/(^|[^\"\'])([A-Za-z]\d+)/$1\$sheet_values\{\'$2\'\}/g;
823: # Replace parameters
824: $t{$cell}=~s/(^|[^\"\'])\[([^\]]+)\]/$1.$self->expandnamed($2)/ge;
825: }
826: }
827: #
828: # Deal with the cells which have formulas
829: while (my ($cell,$formula) = each(%{$self->{'formulas'}})) {
830: next if ($cell =~ /template_/);
831: if ($cell =~ /^A/ && $cell ne 'A0') {
832: if ($formula !~ /^\!/) {
833: $Apache::Spreadsheet::sheet_values{$cell}=
834: eval($self->{'constants'}->{$formula});
835: }
836: } else {
837: $t{$cell}=$formula;
838: $t{$cell}=~s/\.\.+/\,/g;
839: $t{$cell}=~s/(^|[^\"\'])([A-Za-z]\d+)/$1\$sheet_values\{\'$2\'\}/g;
840: $t{$cell}=~s/(^|[^\"\'])\[([^\]]+)\]/$1.$self->expandnamed($2)/ge;
841: }
842: }
843: # Put %t into the safe space
844: %{$self->{'safe'}->varglob('t')}=%t;
845: }
846:
847:
848: ########################################################
849: ########################################################
850:
851: =pod
852:
853: =item &load_cached_export_rows()
854:
855: Retrieves and parsers the export rows of the assessment spreadsheets.
856: These rows are saved in the students directory in the format:
857:
858: sname:sdom:assesscalc:symb.time => time
859:
860: sname:sdom:assesscalc:symb => filename___=___Adata___;___Bdata___;___ ...
861:
862: =cut
863:
864: ########################################################
865: ########################################################
866: sub load_cached_export_rows {
867: undef(%Exportrows);
868: my @tmp = &Apache::lonnet::dump('nohist_calculatedsheets_'.
869: $env{'request.course.id'},
870: $current_domain,$current_name,undef);
871: if ($tmp[0]!~/^error/) {
872: my %tmp = @tmp;
873: my $default_filename = $env{'course.'.$env{'request.course.id'}.
874: '.spreadsheet_default_assesscalc'};
875: # We only got one key, so we will access it directly.
876: while (my ($key,$sheetdata) = each(%tmp)) {
877: my ($sname,$sdom,$sheettype,$symb) = split(':',$key);
878: if (! defined($sname) || $sname eq '' ||
879: ! defined($sdom) || $sdom eq '' ) {
880: next;
881: }
882: if ($symb =~ /\.time$/) {
883: $symb =~ s/\.time$//;
884: $Exportrows{$symb}->{'time'} = $sheetdata;
885: } else {
886: $sheetdata =~ s/^(.*)___=___//;
887: my $filename = $1;
888: $filename = $default_filename if (! defined($filename));
889: my @Data = split('___;___',$sheetdata);
890: $Exportrows{$symb}->{$filename} = \@Data;
891: }
892: }
893: }
894: }
895:
896: #############################################
897: #############################################
898:
899: =pod
900:
901: =item &export_data
902:
903: Returns the export data associated with the spreadsheet. Computes the
904: spreadsheet only if necessary.
905:
906: =cut
907:
908: #############################################
909: #############################################
910: sub export_data {
911: my $self = shift;
912: my ($r) = @_;
913: my $symb = $self->{'symb'};
914: if (! exists($env{'request.role.adv'}) || ! $env{'request.role.adv'} ||
915: ! exists($Exportrows{$symb}) || ! defined($Exportrows{$symb}) ||
916: ! $self->check_expiration_time($Exportrows{$symb}->{'time'}) ||
917: ! exists($Exportrows{$symb}->{$self->{'filename'}}) ||
918: ! defined($Exportrows{$symb}->{$self->{'filename'}}) ||
919: ! ref($Exportrows{$symb}->{$self->{'filename'}})
920: ) {
921: $self->compute($r);
922: }
923: my @Data;
924: if ($self->badcalc()) {
925: @Data = ();
926: } else {
927: @Data = @{$Exportrows{$symb}->{$self->{'filename'}}};
928: if ($Data[0] =~ /^(.*)___=___/) {
929: $self->{'sheetname'} = $1;
930: $Data[0] =~ s/^(.*)___=___//;
931: }
932: for (my $i=0;$i<$#Data;$i++) {
933: if ($Data[$i]=~/\D/ && defined($Data[$i])) {
934: $Data[$i]="'".$Data[$i]."'";
935: }
936: }
937: }
938: return @Data;
939: }
940:
941: #############################################
942: #############################################
943:
944: =pod
945:
946: =item &save_export_data()
947:
948: Writes the export data for this spreadsheet to the students cache.
949:
950: =cut
951:
952: #############################################
953: #############################################
954: sub save_export_data {
955: my $self = shift;
956: return if ($self->temporary());
957: my $student = $self->{'name'}.':'.$self->{'domain'};
958: my $symb = $self->{'symb'};
959: if ($self->badcalc()){
960: # do not save data away when calculations have not been done properly.
961: delete($Exportrows{$symb});
962: return;
963: }
964: if (! exists($Exportrows{$symb}) ||
965: ! exists($Exportrows{$symb}->{$self->{'filename'}})) {
966: return;
967: }
968: my $key = join(':',($self->{'name'},$self->{'domain'},'assesscalc',$symb));
969: my $timekey = $key.'.time';
970: my $newstore= join('___;___',
971: map {s/[^[:print:]]//g;$_;} # strip out unprintable
972: @{$Exportrows{$symb}->{$self->{'filename'}}});
973: $newstore = $self->{'filename'}.'___=___'.$newstore;
974: $newExportrows{$student}->{$key} = $newstore;
975: $newExportrows{$student}->{$timekey} = $Exportrows{$symb}->{'time'};
976: return;
977: }
978:
979: 1;
980:
981: __END__
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>
![[BACK]](/icons/back.gif){kind=icon}
Return to assesscalc.pm CVS log ![[TXT]](/icons/text.gif){kind=icon}
![[DIR]](/icons/dir.gif){kind=icon}
Up to [LON-CAPA] / loncom / interface / spreadsheet