1: #
2: # $Id: assesscalc.pm,v 1.51.2.1 2006/05/15 23:44:46 albertel Exp $
3: #
4: # Copyright Michigan State University Board of Trustees
5: #
6: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
7: #
8: # LON-CAPA is free software; you can redistribute it and/or modify
9: # it under the terms of the GNU General Public License as published by
10: # the Free Software Foundation; either version 2 of the License, or
11: # (at your option) any later version.
12: #
13: # LON-CAPA is distributed in the hope that it will be useful,
14: # but WITHOUT ANY WARRANTY; without even the implied warranty of
15: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
16: # GNU General Public License for more details.
17: #
18: # You should have received a copy of the GNU General Public License
19: # along with LON-CAPA; if not, write to the Free Software
20: # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
21: #
22: # /home/httpd/html/adm/gpl.txt
23: #
24: # http://www.lon-capa.org/
25: #
26: # The LearningOnline Network with CAPA
27: # Spreadsheet/Grades Display Handler
28: #
29: # POD required stuff:
30:
31: =head1 NAME
32:
33: assesscalc
34:
35: =head1 SYNOPSIS
36:
37: =head1 DESCRIPTION
38:
39: =cut
40:
41: ###################################################
42: ### AssessSheet ###
43: ###################################################
44: package Apache::assesscalc;
45:
46: use strict;
47: use warnings FATAL=>'all';
48: no warnings 'uninitialized';
49: use Apache::Constants qw(:common :http);
50: use Apache::lonnet;
51: use Apache::loncommon;
52: use Apache::Spreadsheet;
53: use Apache::loncoursedata();
54: use HTML::Entities();
55: use Spreadsheet::WriteExcel;
56: use GDBM_File;
57: use Time::HiRes;
58: use Apache::lonlocal;
59:
60: @Apache::assesscalc::ISA = ('Apache::Spreadsheet');
61:
62: ########################################################
63: ########################################################
64:
65: =pod
66:
67: =head2 Package Variables
68:
69: =over 4
70:
71: =item %Exportrows
72:
73: =item $current_name
74:
75: =item $current_domain
76:
77: =item $current_course
78:
79: =item %parmhash
80:
81: =item %nice_parameter_name
82:
83: =item %useropt
84:
85: =item %courseopt
86:
87: =back
88:
89: =cut
90:
91: ########################################################
92: ########################################################
93:
94: my %Exportrows;
95: my %newExportrows;
96:
97: my $current_name;
98: my $current_domain;
99: my $current_course;
100:
101: my %parmhash;
102: my %nice_parameter_name;
103:
104: my %useropt;
105: my %userdata;
106: my %courseopt;
107: my $navmap;
108:
109: ########################################################
110: ########################################################
111:
112: =pod
113:
114: =head2 Package Subroutines
115:
116: =item &clear_package()
117:
118: Reset all package variables and clean up caches.
119:
120: =cut
121:
122: ########################################################
123: ########################################################
124: sub clear_package {
125: if (defined($current_name) &&
126: defined($current_domain) &&
127: defined($current_course) &&
128: $current_course eq $env{'request.course.id'} &&
129: %newExportrows) {
130: &save_cached_export_rows($current_name,$current_domain);
131: }
132: undef(%Exportrows);
133: undef(%newExportrows);
134: undef($current_name);
135: undef($current_domain);
136: undef($current_course);
137: undef(%useropt);
138: undef(%userdata);
139: undef(%courseopt);
140: undef($navmap);
141: }
142:
143: sub save_cached_export_rows {
144: my ($sname,$sdomain) = @_;
145: my $result = &Apache::lonnet::put
146: ('nohist_calculatedsheets_'.$env{'request.course.id'},
147: $newExportrows{$sname.':'.$sdomain},
148: $sdomain,$sname);
149: delete($newExportrows{$sname.':'.$sdomain});
150: }
151:
152: sub initialize {
153: my ($in_navmap) = @_;
154: &clear_package();
155: $navmap = $in_navmap;
156: if (! defined($navmap)) {
157: $navmap = Apache::lonnavmaps::navmap->new();
158: }
159: if (!defined($navmap)) {
160: &Apache::lonnet::logthis('assesscalc:Can not open Coursemap');
161: }
162: &Apache::loncoursedata::clear_internal_caches();
163: }
164:
165: ########################################################
166: ########################################################
167:
168: =pod
169:
170: =item &initialize_package()
171:
172: =cut
173:
174: ########################################################
175: ########################################################
176: sub initialize_package {
177: my ($sname,$sdomain,$in_navmap) = @_;
178: $current_name = $sname;
179: $current_domain = $sdomain;
180: $navmap = $in_navmap;
181: undef(%useropt);
182: undef(%userdata);
183: if ($current_course ne $env{'request.course.id'}) {
184: $current_course = $env{'request.course.id'};
185: undef(%courseopt);
186: }
187: &load_cached_export_rows();
188: &load_parameter_caches();
189: &Apache::loncoursedata::clear_internal_caches();
190: }
191:
192:
193: ########################################################
194: ########################################################
195:
196: =pod
197:
198: =item &load_parameter_caches()
199:
200: =cut
201:
202: ########################################################
203: ########################################################
204: sub load_parameter_caches {
205: my $userprefix = $current_name.':'.$current_domain.'_';
206: $userprefix =~ s/:/_/g;
207: #
208: # Course Parameters Cache
209: if (! %courseopt) {
210: $current_course = $env{'request.course.id'};
211: undef(%courseopt);
212: if (! defined($current_name) || ! defined($current_domain)) {
213: return;
214: }
215: my $dom = $env{'course.'.$env{'request.course.id'}.'.domain'};
216: my $id = $env{'course.'.$env{'request.course.id'}.'.num'};
217: my %Tmp = &Apache::lonnet::dump('resourcedata',$dom,$id);
218: while (my ($name,$value) = each(%Tmp)) {
219: $courseopt{$name}=$value;
220: }
221: }
222: if (! %useropt) {
223: my %Tmp = &Apache::lonnet::dump('resourcedata',
224: $current_domain,$current_name);
225: while (my ($name,$value) = each(%Tmp)) {
226: if ($name =~ /^error: 2/ || $name =~ /no such file/) {
227: undef(%useropt);
228: last;
229: }
230: $useropt{$userprefix.$name}=$value;
231: }
232: $useropt{'loadtime'} = time;
233: }
234: if (! %userdata) {
235: %userdata = &Apache::loncoursedata::get_current_state($current_name,
236: $current_domain);
237: $userdata{'loadtime'} = time;
238: }
239: return;
240: }
241:
242: ########################################################
243: ########################################################
244:
245: =pod
246:
247: =head2 assesscalc object methods
248:
249: =cut
250:
251: ########################################################
252: ########################################################
253: sub ensure_current_caches {
254: my $self = shift;
255: ##
256: ## Check for a modified parameters
257: ##
258: if (! defined($current_course) ||
259: $current_course ne $env{'request.course.id'} ) {
260: $current_course = $env{'request.course.id'};
261: undef(%courseopt);
262: undef(%useropt);
263: undef(%userdata);
264: }
265: ##
266: ## Check for new user
267: ##
268: if (! defined($current_name) || $current_name ne $self->{'name'} ||
269: ! defined($current_domain) || $current_domain ne $self->{'domain'}) {
270: $current_domain = $self->{'domain'};
271: $current_name = $self->{'name'};
272: undef(%useropt);
273: undef(%userdata);
274: }
275: &load_parameter_caches();
276: }
277:
278: ##################################################
279: ##################################################
280:
281: =pod
282:
283: =item &parmval()
284:
285: Determine the value of a parameter.
286:
287: Inputs: $what, the parameter needed, $symb, $uname, $udom, $csec
288:
289: Returns: The value of a parameter, or '' if none.
290:
291: This function cascades through the possible levels searching for a value for
292: a parameter. The levels are checked in the following order:
293: user, course (at section level and course level), map, and lonnet::metadata.
294: This function uses %parmhash, which must be tied prior to calling it.
295: This function also requires %courseopt and %useropt to be initialized for
296: this user and course.
297:
298: =cut
299:
300: ##################################################
301: ##################################################
302: sub parmval {
303: my $self = shift;
304: my ($what,$symb,$uname,$udom,$csec,$recurse,$mapname,$id,$fn)=@_;
305: $uname = $self->{'name'} if (! defined($uname));
306: $udom = $self->{'domain'} if (! defined($udom));
307: $csec = $self->{'section'} if (! defined($csec));
308: $symb = $self->{'symb'} if (! defined($symb));
309: #
310: my $result='';
311: #
312: # This should be a
313: if (!defined($mapname) || !defined($id) || !defined($fn)) {
314: ($mapname,$id,$fn)=&Apache::lonnet::decode_symb($symb);
315: $mapname = &Apache::lonnet::deversion($mapname);
316: }
317: # Cascading lookup scheme
318: my $rwhat=$what;
319: $what =~ s/^parameter\_//;
320: $what =~ s/\_([^\_]+)$/\.$1/;
321: #
322: my $symbparm = $symb.'.'.$what;
323: my $mapparm = $mapname.'___(all).'.$what;
324: my $courseprefix = $self->{'cid'};
325: my $usercourseprefix = $uname.'_'.$udom.'_'.$self->{'cid'};
326: #
327: my $seclevel = $courseprefix.'.['.$csec.'].'.$what;
328: my $seclevelr = $courseprefix.'.['.$csec.'].'.$symbparm;
329: my $seclevelm = $courseprefix.'.['.$csec.'].'.$mapparm;
330: #
331: my $courselevel = $courseprefix.'.'.$what;
332: my $courselevelr = $courseprefix.'.'.$symbparm;
333: my $courselevelm = $courseprefix.'.'.$mapparm;
334: #
335: my $ucourselevel = $usercourseprefix.'.'.$what;
336: my $ucourselevelr = $usercourseprefix.'.'.$symbparm;
337: my $ucourselevelm = $usercourseprefix.'.'.$mapparm;
338: # check user
339: if (defined($uname)) {
340: return $useropt{$ucourselevelr} if (defined($useropt{$ucourselevelr}));
341: return $useropt{$ucourselevelm} if (defined($useropt{$ucourselevelm}));
342: return $useropt{$ucourselevel} if (defined($useropt{$ucourselevel}));
343: }
344: # check section
345: if (defined($csec)) {
346: return $courseopt{$seclevelr} if (defined($courseopt{$seclevelr}));
347: return $courseopt{$seclevelm} if (defined($courseopt{$seclevelm}));
348: return $courseopt{$seclevel} if (defined($courseopt{$seclevel}));
349: }
350: #
351: # check course
352: return $courseopt{$courselevelr} if (defined($courseopt{$courselevelr}));
353: # check map parms
354: my $thisparm = $parmhash{$symbparm};
355: return $thisparm if (defined($thisparm));
356: # check default
357: $thisparm = &Apache::lonnet::metadata($fn,$rwhat.'.default');
358: return $thisparm if (defined($thisparm));
359: # check more course
360: return $courseopt{$courselevelm} if (defined($courseopt{$courselevelm}));
361: return $courseopt{$courselevel} if (defined($courseopt{$courselevel}));
362:
363: # Cascade Up
364: my $space=$what;
365: $space=~s/\.[^._]+$//;
366: if ($space ne '0') {
367: my @parts=split(/_/,$space);
368: my $id=pop(@parts);
369: my $part=join('_',@parts);
370: if ($part eq '') { $part='0'; }
371: my $newwhat=$rwhat;
372: $newwhat=~s/\Q$space\E/$part/;
373: my $partgeneral=$self->parmval($newwhat,$symb,$uname,$udom,$csec,1,
374: $mapname,$id,$fn);
375: if (defined($partgeneral)) { return $partgeneral; }
376: }
377: if ($recurse) { return undef; }
378: my $pack_def=&Apache::lonnet::packages_tab_default($fn,'resource.'.$what);
379: if (defined($pack_def)) { return $pack_def; }
380: #nothing defined
381: return '';
382: }
383:
384: sub get_html_title {
385: my $self = shift;
386: my ($assess_title,$name,$time) = $self->get_full_title();
387: my $title = '<h1>'.$assess_title.'</h1>'.
388: '<h2>'.$name.', '.
389: &Apache::loncommon::aboutmewrapper
390: ($self->{'name'}.'@'.$self->{'domain'},
391: $self->{'name'},$self->{'domain'});
392: $title .= '<h3>'.$time.'</h3>';
393: return $title;
394: }
395:
396: sub get_title {
397: my $self = shift;
398: if (($self->{'symb'} eq '_feedback') ||
399: ($self->{'symb'} eq '_evaluation') ||
400: ($self->{'symb'} eq '_discussion') ||
401: ($self->{'symb'} eq '_tutoring')) {
402: my $assess_title = ucfirst($self->{'symb'});
403: $assess_title =~ s/^_//;
404: return $assess_title;
405: } else {
406: return &Apache::lonnet::gettitle($self->{'symb'});
407: }
408: }
409:
410: sub get_full_title {
411: my $self = shift;
412: my @title = ($self->get_title());
413: # Look up the users identifying information
414: # Get the users information
415: my $name = &Apache::loncommon::plainname($self->{'name'},
416: $self->{'domain'});
417: push (@title,$name);
418: push (@title,&Apache::lonlocal::locallocaltime(time));
419: return @title;
420: }
421:
422: sub parent_link {
423: my $self = shift;
424: my $link .= '<p><a href="/adm/studentcalc?'.
425: 'sname='.$self->{'name'}.
426: '&sdomain='.$self->{'domain'}.'">'.
427: &mt('Student level sheet').'</a></p>'."\n";
428: return $link;
429: }
430:
431: sub outsheet_html {
432: my $self = shift;
433: my ($r) = @_;
434: ####################################
435: # Report any calculation errors #
436: ####################################
437: $r->print($self->html_report_error());
438: ###################################
439: # Determine table structure
440: ###################################
441: my $importcolor = '#FFFFFF';
442: my $exportcolor = '#FFFFAA';
443: my $num_uneditable = 1;
444: my $num_left = 52-$num_uneditable;
445: my %lt=&Apache::lonlocal::texthash(
446: 'as' => 'Assessment',
447: 'ca' => 'Calculations',
448: );
449: my $tableheader =<<"END";
450: <table border="2">
451: <tr>
452: <th colspan="2" rowspan="2"><font size="+2">$lt{'as'}</font></th>
453: <td bgcolor="$importcolor" colspan="$num_uneditable"> </td>
454: <td colspan="$num_left">
455: <b><font size="+1">$lt{'ca'}</font></b></td>
456: </tr><tr>
457: END
458: my $label_num = 0;
459: foreach (split(//,'ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz')){
460: if ($label_num<$num_uneditable) {
461: $tableheader .= '<td bgcolor="'.$importcolor.'">';
462: } else {
463: $tableheader .= '<td>';
464: }
465: $tableheader .= "<b><font size=+1>$_</font></b></td>";
466: $label_num++;
467: }
468: $tableheader.="</tr>\n";
469: #
470: $r->print($tableheader);
471: #
472: # Print out template row
473: $r->print('<tr><td>Template</td><td> </td>'.
474: $self->html_template_row($num_uneditable,$importcolor).
475: "</tr>\n");
476: #
477: # Print out summary/export row
478: $r->print('<tr><td>Export</td><td>0</td>'.
479: $self->html_export_row($exportcolor)."</tr>\n");
480: #
481: # Prepare to output rows
482: $tableheader =<<"END";
483: <table border="2">
484: <tr><th>row</th><th>Item</th>
485: END
486: foreach (split(//,'ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz')){
487: if ($label_num<$num_uneditable) {
488: $tableheader.='<th bgcolor="'.$importcolor.'">';
489: } else {
490: $tableheader.='<th>';
491: }
492: $tableheader.="<b><font size=+1>$_</font></b></th>";
493: }
494: #
495: my $num_output = 0;
496: foreach my $rownum (sort {$a <=> $b} ($self->rows())) {
497: if (! $self->parameter_part_is_valid(
498: $self->{'formulas'}->{'A'.$rownum}
499: )) {
500: next;
501: }
502: if ($num_output++ % 50 == 0) {
503: $r->print("</table>\n".$tableheader);
504: }
505: $r->print('<tr><td>'.$rownum.'</td>'.
506: $self->assess_html_row($rownum,$importcolor)."</tr>\n");
507: }
508: $r->print("</table>\n");
509: return;
510: }
511:
512: sub assess_html_row {
513: my $self = shift();
514: my ($row,$importcolor) = @_;
515: my $parameter_name = $self->{'formulas'}->{'A'.$row};
516: my @rowdata = $self->get_row($row);
517: my $num_cols_output = 0;
518: my $row_html;
519: my $name=$self->get_parm_name($parameter_name);
520: if ($name ne '') {
521: $name =~ s/ /\ /g;
522: $row_html .= '<td>'.$name.'<br />'.$parameter_name.'</td>';
523: } else {
524: $row_html .= '<td>'.$parameter_name.'</td>';
525: }
526: foreach my $cell (@rowdata) {
527: if ($num_cols_output < 1) {
528: $row_html .= '<td bgcolor="'.$importcolor.'">';
529: $row_html .= &Apache::Spreadsheet::html_uneditable_cell($cell,
530: '#FFDDDD');
531: } else {
532: $row_html .= '<td bgcolor="#EOFFDD">';
533: $row_html .= &Apache::Spreadsheet::html_editable_cell($cell,
534: '#E0FFDD',1);
535: }
536: $row_html .= '</td>';
537: $num_cols_output++;
538: }
539: return $row_html;
540: }
541:
542: sub csv_rows {
543: # writes the meat of the spreadsheet to an excel worksheet. Called
544: # by Spreadsheet::outsheet_excel;
545: my $self = shift;
546: my ($connection,$filehandle) = @_;
547: #
548: # Write a header row
549: $self->csv_output_row($filehandle,undef,
550: (&mt('Parameter'),&mt('Description'),&mt('Value')));
551: #
552: # Write each row
553: foreach my $rownum (sort {$a <=> $b} ($self->rows())) {
554: my $parameter_name = $self->{'formulas'}->{'A'.$rownum};
555: my $description = $self->get_parm_name($parameter_name);
556: $self->csv_output_row($filehandle,$rownum,
557: $parameter_name,$description);
558: }
559: return;
560: }
561:
562: sub excel_rows {
563: # writes the meat of the spreadsheet to an excel worksheet. Called
564: # by Spreadsheet::outsheet_excel;
565: my $self = shift;
566: my ($connection,$worksheet,$cols_output,$rows_output,$format) = @_;
567: return if (! ref($worksheet));
568: #
569: # Write a header row
570: $cols_output = 0;
571: foreach my $value ('Parameter','Description','Value') {
572: $worksheet->write($rows_output,$cols_output++,$value,$format->{'h4'});
573: }
574: $rows_output++;
575: #
576: # Write each row
577: foreach my $rownum (sort {$a <=> $b} ($self->rows())) {
578: my $parameter_name = $self->{'formulas'}->{'A'.$rownum};
579: my $description = $self->get_parm_name($parameter_name);
580: $self->excel_output_row($worksheet,$rownum,$rows_output++,
581: $parameter_name,$description);
582: }
583: return;
584: }
585:
586: ##
587: ## Routines to support assesscalc::compute
588: ##
589: sub get_parm {
590: my $self = shift;
591: my @Mandatory_parameters = @_;
592: my %parameters;
593: #
594: my ($symap,$syid,$srcf) = &Apache::lonnet::decode_symb($self->{'symb'});
595: my @Metadata = split(/\,/,&Apache::lonnet::metadata($srcf,'keys'));
596: foreach my $parm (@Mandatory_parameters,@Metadata) {
597: next if ($parm !~ /^(resource\.|stores|parameter)_/);
598: my $cleaned_name = $parm;
599: $cleaned_name =~ s/^resource\./stores_/;
600: $cleaned_name =~ s/\./_/g;
601: $parameters{$cleaned_name}=1;
602: }
603: return (keys(%parameters));
604: }
605:
606: sub get_parm_name {
607: my $self = shift;
608: my $parm = shift;
609: my ($symap,$syid,$srcf) = &Apache::lonnet::decode_symb($self->{'symb'});
610: my $display = &Apache::lonnet::metadata($srcf,$parm.'.display');
611: if (! $display) {
612: $display .= &Apache::lonnet::metadata($srcf,$parm.'.name');
613: }
614: return $display;
615: }
616:
617: sub get_parameter_values {
618: my $self = shift();
619: my @Parameters;
620: my ($parameters) = @_;
621: if (!ref($parameters)) {
622: @Parameters = @_;
623: } elsif (ref($parameters) eq 'ARRAY') {
624: @Parameters = @$parameters;
625: } elsif (ref($parameters) eq 'HASH') {
626: @Parameters = keys(%$parameters);
627: }
628: #
629: my %parameters;
630: #
631: my $filename = $self->{'coursefilename'}.'_parms.db';
632: if (tie(%parmhash,'GDBM_File',
633: $self->{'coursefilename'}.'_parms.db',&GDBM_READER(),0640)) {
634: my ($mapname,$id,$fn)=&Apache::lonnet::decode_symb($self->{'symb'});
635: $mapname = &Apache::lonnet::deversion($mapname);
636: foreach my $parmname (@Parameters) {
637: my $value = $self->parmval($parmname,$self->{'symb'},
638: $self->{'name'},$self->{'domain'},
639: $self->{'section'},undef,
640: $mapname,$id,$fn);
641: $parameters{$parmname} =$value;
642: }
643: untie(%parmhash);
644: } else {
645: $self->logthis('unable to tie '.$filename);
646: }
647: return %parameters;
648: }
649:
650: sub deal_with_export_row {
651: my $self = shift();
652: my @exportarray = @_;
653: $Exportrows{$self->{'symb'}}->{'time'} = time;
654: $Exportrows{$self->{'symb'}}->{$self->{'filename'}} = \@exportarray;
655: #
656: # Save the export data
657: $self->save_export_data();
658: return;
659: }
660:
661: sub get_problem_state {
662: my $self = shift;
663: my %student_parameters;
664: if (exists($userdata{$self->{'symb'}}) &&
665: ref($userdata{$self->{'symb'}}) eq 'HASH') {
666: %student_parameters = %{$userdata{$self->{'symb'}}};
667: }
668: return %student_parameters;
669: }
670:
671: sub determine_parts {
672: my $self = shift;
673: my $check_hidden = shift;
674: if (exists($self->{'Parts'}) && ref($self->{'Parts'}) eq 'HASH') {
675: return;
676: }
677: my (undef,undef,$url) = &Apache::lonnet::decode_symb($self->{'symb'});
678: my $src = &Apache::lonnet::clutter($url);
679: return if (! defined($src));
680: my %Parts;
681: my $metadata = &Apache::lonnet::metadata($src,'packages');
682: foreach (split(',',$metadata)) {
683: my ($part) = (/^part_(.*)$/);
684: if (!defined($part)) { next; }
685: if (!$check_hidden) { $Parts{$part}++; next; }
686: if (!&Apache::loncommon::check_if_partid_hidden
687: ($part,$self->{'symb'},$self->{'name'},$self->{'domain'})
688: ) {
689: $Parts{$part}++;
690: }
691: }
692: # Make sure part 0 is defined.
693: $Parts{'0'}++;
694: $self->{'Parts'} = \%Parts;
695: return;
696: }
697:
698: sub parameter_part_is_valid {
699: my $self = shift;
700: my ($parameter) = @_;
701: return 1 if ($parameter eq 'timestamp');
702: if (! defined($self->{'Parts'}) ||
703: ! ref ($self->{'Parts'}) ||
704: ref($self->{'Parts'}) ne 'HASH') {
705: return 1;
706: }
707: #
708: my ($start,@pieces)=split('_',$parameter);
709: if ( $start !~ m/^(resource|stores|parameter)$/) { return 0; }
710: while (@pieces) {
711: pop(@pieces);
712: my $testpart=join('_',@pieces);
713: if (exists($self->{'Parts'}->{$testpart}) &&
714: $self->{'Parts'}->{$testpart} ) {
715: return 1;
716: }
717: }
718: return 0;
719: }
720:
721: sub compute {
722: my $self = shift;
723: my ($r) = @_;
724: $self->initialize_safe_space();
725: #########################################
726: #########################################
727: ### ###
728: ### Retrieve the problem parameters ###
729: ### ###
730: #########################################
731: #########################################
732: my @Mandatory_parameters = ("stores_0_solved",
733: "stores_0_awarddetail",
734: "stores_0_awarded",
735: "timestamp",
736: "stores_0_tries",
737: "stores_0_award");
738: #
739: # Definitions
740: undef(%nice_parameter_name);
741: my %parameters; # holds underscored parameters by name
742: #
743: # Get the metadata fields and determine their proper names
744: my @parameters=$self->get_parm(@Mandatory_parameters);
745: #
746: # Get the values of the metadata fields
747: $self->ensure_current_caches();
748: %parameters = $self->get_parameter_values(@parameters);
749: #
750: # Clean out unnecessary parameters
751: foreach (keys(%parameters)) {
752: delete($parameters{$_}) if (! /(resource\.|stores_|parameter_)/);
753: }
754: #
755: # Get the students performance data
756: $self->determine_parts(($parameters{'parameter_0_hiddenparts'} ne ''));
757: my %student_parameters = $self->get_problem_state();
758: while (my ($parm,$value) = each(%student_parameters)) {
759: $parm =~ s/^resource\./stores_/;
760: $parm =~ s/\./_/g;
761: # Clean out any bad parameters
762: next if (! $self->parameter_part_is_valid($parm));
763: $parameters{$parm} = $value;
764: }
765: #
766: # Set up the formulas and parameter values
767: my %f=$self->formulas();
768: my %c;
769: #
770: # Check for blackout requirements
771: if ((!exists($env{'request.role.adv'}) || !$env{'request.role.adv'})) {
772: while (my ($parm,$value) = each(%parameters)) {
773: last if ($self->blackout());
774: next if ($parm !~ /^(parameter_.*)_problemstatus$/);
775: if ($parameters{$1.'_answerdate'} ne '' &&
776: $parameters{$1.'_answerdate'} < time) {
777: next;
778: }
779: if (lc($value) eq 'no') {
780: # We must blackout this sheet
781: $self->blackout(1);
782: }
783: }
784: }
785: #
786: # Move the parameters into the spreadsheet
787: while (my ($parm,$value) = each(%parameters)) {
788: my $cell = 'A'.$self->get_row_number_from_key($parm);
789: $f{$cell} = $parm;
790: if ($parm =~ /_submission$/ && $value =~ /(\{|\})/) {
791: $value = 'witheld';
792: }
793: $value = 'q{'.$value.'}' if ($value =~/([^\d\.]|\.\.)/);
794: $c{$parm} = $value;
795: }
796: foreach my $cell (grep(/^A/,keys(%f))) {
797: # Clean out any bad formulas
798: next if (exists($c{$f{$cell}}));
799: next if ($cell eq 'A0');
800: delete($f{$cell});
801: }
802: $self->formulas(\%f);
803: $self->constants(\%c);
804: $self->calcsheet();
805: #
806: # Store export row in cache
807: my @exportarray = $self->exportrow();
808: $self->deal_with_export_row(@exportarray);
809: $self->save() if ($self->need_to_save());
810: return;
811: }
812:
813: ##
814: ## sett overrides Spreadsheet::sett
815: ##
816: sub sett {
817: my $self = shift;
818: my %t=();
819: undef(%Apache::Spreadsheet::sheet_values);
820: #
821: # Deal with the template row by copying the template formulas into each
822: # row.
823: foreach my $col ($self->template_cells()) {
824: next if ($col=~/^A/);
825: foreach my $row ($self->rows()) {
826: # Get the name of this cell
827: my $cell=$col.$row;
828: # Grab the template declaration
829: $t{$cell}=$self->formula('template_'.$col);
830: # Replace '#' with the row number
831: $t{$cell}=~s/\#/$row/g;
832: # Replace '....' with ','
833: $t{$cell}=~s/\.\.+/\,/g;
834: # Replace 'A0' with the value from 'A0'
835: $t{$cell}=~s/(^|[^\"\'])([A-Za-z]\d+)/$1\$sheet_values\{\'$2\'\}/g;
836: # Replace parameters
837: $t{$cell}=~s/(^|[^\"\'])\[([^\]]+)\]/$1.$self->expandnamed($2)/ge;
838: }
839: }
840: #
841: # Deal with the cells which have formulas
842: while (my ($cell,$formula) = each(%{$self->{'formulas'}})) {
843: next if ($cell =~ /template_/);
844: if ($cell =~ /^A/ && $cell ne 'A0') {
845: if ($formula !~ /^\!/
846: && exists($self->{'constants'}->{$formula})
847: && $self->{'constants'}->{$formula} ne ''
848: ) {
849: $Apache::Spreadsheet::sheet_values{$cell}=
850: eval($self->{'constants'}->{$formula});
851: }
852: } else {
853: $t{$cell}=$formula;
854: $t{$cell}=~s/\.\.+/\,/g;
855: $t{$cell}=~s/(^|[^\"\'])([A-Za-z]\d+)/$1\$sheet_values\{\'$2\'\}/g;
856: $t{$cell}=~s/(^|[^\"\'])\[([^\]]+)\]/$1.$self->expandnamed($2)/ge;
857: }
858: }
859: # Put %t into the safe space
860: %{$self->{'safe'}->varglob('t')}=%t;
861: }
862:
863:
864: ########################################################
865: ########################################################
866:
867: =pod
868:
869: =item &load_cached_export_rows()
870:
871: Retrieves and parsers the export rows of the assessment spreadsheets.
872: These rows are saved in the students directory in the format:
873:
874: sname:sdom:assesscalc:symb.time => time
875:
876: sname:sdom:assesscalc:symb => filename___=___Adata___;___Bdata___;___ ...
877:
878: =cut
879:
880: ########################################################
881: ########################################################
882: sub load_cached_export_rows {
883: undef(%Exportrows);
884: my @tmp = &Apache::lonnet::dump('nohist_calculatedsheets_'.
885: $env{'request.course.id'},
886: $current_domain,$current_name,undef);
887: if ($tmp[0]!~/^error/) {
888: my %tmp = @tmp;
889: my $default_filename = $env{'course.'.$env{'request.course.id'}.
890: '.spreadsheet_default_assesscalc'};
891: # We only got one key, so we will access it directly.
892: while (my ($key,$sheetdata) = each(%tmp)) {
893: my ($sname,$sdom,$sheettype,$symb) = split(':',$key);
894: if (! defined($sname) || $sname eq '' ||
895: ! defined($sdom) || $sdom eq '' ) {
896: next;
897: }
898: if ($symb =~ /\.time$/) {
899: $symb =~ s/\.time$//;
900: $Exportrows{$symb}->{'time'} = $sheetdata;
901: } else {
902: $sheetdata =~ s/^(.*)___=___//;
903: my $filename = $1;
904: $filename = $default_filename if (! defined($filename));
905: my @Data = split('___;___',$sheetdata);
906: $Exportrows{$symb}->{$filename} = \@Data;
907: }
908: }
909: }
910: }
911:
912: #############################################
913: #############################################
914:
915: =pod
916:
917: =item &export_data
918:
919: Returns the export data associated with the spreadsheet. Computes the
920: spreadsheet only if necessary.
921:
922: =cut
923:
924: #############################################
925: #############################################
926: sub export_data {
927: my $self = shift;
928: my ($r) = @_;
929: my $symb = $self->{'symb'};
930: if (! exists($env{'request.role.adv'}) || ! $env{'request.role.adv'} ||
931: ! exists($Exportrows{$symb}) || ! defined($Exportrows{$symb}) ||
932: ! $self->check_expiration_time($Exportrows{$symb}->{'time'}) ||
933: ! exists($Exportrows{$symb}->{$self->{'filename'}}) ||
934: ! defined($Exportrows{$symb}->{$self->{'filename'}}) ||
935: ! ref($Exportrows{$symb}->{$self->{'filename'}})
936: ) {
937: $self->compute($r);
938: }
939: my @Data;
940: if ($self->badcalc()) {
941: @Data = ();
942: } else {
943: @Data = @{$Exportrows{$symb}->{$self->{'filename'}}};
944: if ($Data[0] =~ /^(.*)___=___/) {
945: $self->{'sheetname'} = $1;
946: $Data[0] =~ s/^(.*)___=___//;
947: }
948: for (my $i=0;$i<$#Data;$i++) {
949: if ($Data[$i]=~/\D/ && defined($Data[$i])) {
950: $Data[$i]="'".$Data[$i]."'";
951: }
952: }
953: }
954: return @Data;
955: }
956:
957: #############################################
958: #############################################
959:
960: =pod
961:
962: =item &save_export_data()
963:
964: Writes the export data for this spreadsheet to the students cache.
965:
966: =cut
967:
968: #############################################
969: #############################################
970: sub save_export_data {
971: my $self = shift;
972: return if ($self->temporary());
973: my $student = $self->{'name'}.':'.$self->{'domain'};
974: my $symb = $self->{'symb'};
975: if ($self->badcalc()){
976: # do not save data away when calculations have not been done properly.
977: delete($Exportrows{$symb});
978: return;
979: }
980: if (! exists($Exportrows{$symb}) ||
981: ! exists($Exportrows{$symb}->{$self->{'filename'}})) {
982: return;
983: }
984: my $key = join(':',($self->{'name'},$self->{'domain'},'assesscalc',$symb));
985: my $timekey = $key.'.time';
986: my $newstore= join('___;___',
987: map {s/[^[:print:]]//g;$_;} # strip out unprintable
988: @{$Exportrows{$symb}->{$self->{'filename'}}});
989: $newstore = $self->{'filename'}.'___=___'.$newstore;
990: $newExportrows{$student}->{$key} = $newstore;
991: $newExportrows{$student}->{$timekey} = $Exportrows{$symb}->{'time'};
992: return;
993: }
994:
995: 1;
996:
997: __END__
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>
![[BACK]](/icons/back.gif){kind=icon}
Return to assesscalc.pm CVS log ![[TXT]](/icons/text.gif){kind=icon}
![[DIR]](/icons/dir.gif){kind=icon}
Up to [LON-CAPA] / loncom / interface / spreadsheet