1: #
2: # $Id: assesscalc.pm,v 1.56 2006/09/03 00:39:57 albertel Exp $
3: #
4: # Copyright Michigan State University Board of Trustees
5: #
6: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
7: #
8: # LON-CAPA is free software; you can redistribute it and/or modify
9: # it under the terms of the GNU General Public License as published by
10: # the Free Software Foundation; either version 2 of the License, or
11: # (at your option) any later version.
12: #
13: # LON-CAPA is distributed in the hope that it will be useful,
14: # but WITHOUT ANY WARRANTY; without even the implied warranty of
15: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
16: # GNU General Public License for more details.
17: #
18: # You should have received a copy of the GNU General Public License
19: # along with LON-CAPA; if not, write to the Free Software
20: # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
21: #
22: # /home/httpd/html/adm/gpl.txt
23: #
24: # http://www.lon-capa.org/
25: #
26: # The LearningOnline Network with CAPA
27: # Spreadsheet/Grades Display Handler
28: #
29: # POD required stuff:
30:
31: =head1 NAME
32:
33: assesscalc
34:
35: =head1 SYNOPSIS
36:
37: =head1 DESCRIPTION
38:
39: =cut
40:
41: ###################################################
42: ### AssessSheet ###
43: ###################################################
44: package Apache::assesscalc;
45:
46: use strict;
47: use warnings FATAL=>'all';
48: no warnings 'uninitialized';
49: use Apache::Constants qw(:common :http);
50: use Apache::lonnet;
51: use Apache::loncommon;
52: use Apache::Spreadsheet;
53: use Apache::loncoursedata();
54: use HTML::Entities();
55: use Spreadsheet::WriteExcel;
56: use GDBM_File;
57: use Time::HiRes;
58: use Apache::lonlocal;
59:
60: @Apache::assesscalc::ISA = ('Apache::Spreadsheet');
61:
62: ########################################################
63: ########################################################
64:
65: =pod
66:
67: =head2 Package Variables
68:
69: =over 4
70:
71: =item %Exportrows
72:
73: =item $current_name
74:
75: =item $current_domain
76:
77: =item $current_course
78:
79: =item %parmhash
80:
81: =item %nice_parameter_name
82:
83: =item %useropt
84:
85: =item %courseopt
86:
87: =back
88:
89: =cut
90:
91: ########################################################
92: ########################################################
93:
94: my %Exportrows;
95: my %newExportrows;
96:
97: my $current_name;
98: my $current_domain;
99: my $current_course;
100:
101: my %parmhash;
102: my %nice_parameter_name;
103:
104: my %useropt;
105: my %userdata;
106: my %courseopt;
107: my $navmap;
108:
109: ########################################################
110: ########################################################
111:
112: =pod
113:
114: =head2 Package Subroutines
115:
116: =item &clear_package()
117:
118: Reset all package variables and clean up caches.
119:
120: =cut
121:
122: ########################################################
123: ########################################################
124: sub clear_package {
125: if (defined($current_name) &&
126: defined($current_domain) &&
127: defined($current_course) &&
128: $current_course eq $env{'request.course.id'} &&
129: %newExportrows) {
130: &save_cached_export_rows($current_name,$current_domain);
131: }
132: undef(%Exportrows);
133: undef(%newExportrows);
134: undef($current_name);
135: undef($current_domain);
136: undef($current_course);
137: undef(%useropt);
138: undef(%userdata);
139: undef(%courseopt);
140: undef($navmap);
141: }
142:
143: sub save_cached_export_rows {
144: my ($sname,$sdomain) = @_;
145: my $result = &Apache::lonnet::put
146: ('nohist_calculatedsheets_'.$env{'request.course.id'},
147: $newExportrows{$sname.':'.$sdomain},
148: $sdomain,$sname);
149: delete($newExportrows{$sname.':'.$sdomain});
150: }
151:
152: sub initialize {
153: my ($in_navmap) = @_;
154: &clear_package();
155: $navmap = $in_navmap;
156: if (! defined($navmap)) {
157: $navmap = Apache::lonnavmaps::navmap->new();
158: }
159: if (!defined($navmap)) {
160: &Apache::lonnet::logthis('assesscalc:Can not open Coursemap');
161: }
162: &Apache::loncoursedata::clear_internal_caches();
163: }
164:
165: ########################################################
166: ########################################################
167:
168: =pod
169:
170: =item &initialize_package()
171:
172: =cut
173:
174: ########################################################
175: ########################################################
176: sub initialize_package {
177: my ($sname,$sdomain,$in_navmap) = @_;
178: $current_name = $sname;
179: $current_domain = $sdomain;
180: $navmap = $in_navmap;
181: undef(%useropt);
182: undef(%userdata);
183: if ($current_course ne $env{'request.course.id'}) {
184: $current_course = $env{'request.course.id'};
185: undef(%courseopt);
186: }
187: &load_cached_export_rows();
188: &load_parameter_caches();
189: &Apache::loncoursedata::clear_internal_caches();
190: }
191:
192:
193: ########################################################
194: ########################################################
195:
196: =pod
197:
198: =item &load_parameter_caches()
199:
200: =cut
201:
202: ########################################################
203: ########################################################
204: sub load_parameter_caches {
205: my $userprefix = $current_name.':'.$current_domain.'_';
206: $userprefix =~ s/:/_/g;
207: #
208: # Course Parameters Cache
209: if (! %courseopt) {
210: $current_course = $env{'request.course.id'};
211: undef(%courseopt);
212: if (! defined($current_name) || ! defined($current_domain)) {
213: return;
214: }
215: my $dom = $env{'course.'.$env{'request.course.id'}.'.domain'};
216: my $id = $env{'course.'.$env{'request.course.id'}.'.num'};
217: my %Tmp = &Apache::lonnet::dump('resourcedata',$dom,$id);
218: while (my ($name,$value) = each(%Tmp)) {
219: $courseopt{$name}=$value;
220: }
221: }
222: if (! %useropt) {
223: my %Tmp = &Apache::lonnet::dump('resourcedata',
224: $current_domain,$current_name);
225: while (my ($name,$value) = each(%Tmp)) {
226: if ($name =~ /^error: 2/ || $name =~ /no such file/) {
227: undef(%useropt);
228: last;
229: }
230: $useropt{$userprefix.$name}=$value;
231: }
232: $useropt{'loadtime'} = time;
233: }
234: if (! %userdata) {
235: %userdata = &Apache::loncoursedata::get_current_state($current_name,
236: $current_domain);
237: $userdata{'loadtime'} = time;
238: }
239: return;
240: }
241:
242: ########################################################
243: ########################################################
244:
245: =pod
246:
247: =head2 assesscalc object methods
248:
249: =cut
250:
251: ########################################################
252: ########################################################
253: sub ensure_current_caches {
254: my $self = shift;
255: ##
256: ## Check for a modified parameters
257: ##
258: if (! defined($current_course) ||
259: $current_course ne $env{'request.course.id'} ) {
260: $current_course = $env{'request.course.id'};
261: undef(%courseopt);
262: undef(%useropt);
263: undef(%userdata);
264: }
265: ##
266: ## Check for new user
267: ##
268: if (! defined($current_name) || $current_name ne $self->{'name'} ||
269: ! defined($current_domain) || $current_domain ne $self->{'domain'}) {
270: $current_domain = $self->{'domain'};
271: $current_name = $self->{'name'};
272: undef(%useropt);
273: undef(%userdata);
274: }
275: &load_parameter_caches();
276: }
277:
278: ##################################################
279: ##################################################
280:
281: =pod
282:
283: =item &parmval()
284:
285: Determine the value of a parameter.
286:
287: Inputs: $what, the parameter needed, $symb, $uname, $udom, $csec
288:
289: Returns: The value of a parameter, or '' if none.
290:
291: This function cascades through the possible levels searching for a value for
292: a parameter. The levels are checked in the following order:
293: user, course (at group, section level and course level), map, and
294: lonnet::metadata.
295: This function uses %parmhash, which must be tied prior to calling it.
296: This function also requires %courseopt and %useropt to be initialized for
297: this user and course.
298:
299: =cut
300:
301: ##################################################
302: ##################################################
303: sub parmval {
304: my $self = shift;
305: my ($what,$symb,$uname,$udom,$csec,$recurse,$mapname,$id,$fn,$groups)=@_;
306: $uname = $self->{'name'} if (! defined($uname));
307: $udom = $self->{'domain'} if (! defined($udom));
308: $csec = $self->{'section'} if (! defined($csec));
309: $groups = $self->{'groups'} if (! defined($groups));
310: $symb = $self->{'symb'} if (! defined($symb));
311: #
312: my $result='';
313: #
314: # This should be a
315: if (!defined($mapname) || !defined($id) || !defined($fn)) {
316: ($mapname,$id,$fn)=&Apache::lonnet::decode_symb($symb);
317: $mapname = &Apache::lonnet::deversion($mapname);
318: }
319: # Cascading lookup scheme
320: my $rwhat=$what;
321: $what =~ s/^parameter\_//;
322: $what =~ s/\_([^\_]+)$/\.$1/;
323: #
324: my $symbparm = $symb.'.'.$what;
325: my $mapparm = $mapname.'___(all).'.$what;
326: my $courseprefix = $self->{'cid'};
327: my $usercourseprefix = $uname.'_'.$udom.'_'.$self->{'cid'};
328: #
329: my $seclevel = $courseprefix.'.['.$csec.'].'.$what;
330: my $seclevelr = $courseprefix.'.['.$csec.'].'.$symbparm;
331: my $seclevelm = $courseprefix.'.['.$csec.'].'.$mapparm;
332: #
333: my $courselevel = $courseprefix.'.'.$what;
334: my $courselevelr = $courseprefix.'.'.$symbparm;
335: my $courselevelm = $courseprefix.'.'.$mapparm;
336: #
337: my $ucourselevel = $usercourseprefix.'.'.$what;
338: my $ucourselevelr = $usercourseprefix.'.'.$symbparm;
339: my $ucourselevelm = $usercourseprefix.'.'.$mapparm;
340: # check user
341: if (defined($uname)) {
342: return $useropt{$ucourselevelr} if (defined($useropt{$ucourselevelr}));
343: return $useropt{$ucourselevelm} if (defined($useropt{$ucourselevelm}));
344: return $useropt{$ucourselevel} if (defined($useropt{$ucourselevel}));
345: }
346: # check groups
347: if (defined($groups) && ref($groups) eq 'ARRAY') {
348: foreach my $group (@{$groups}) {
349: foreach my $level ($symbparm,$mapparm,$what) {
350: my $item = $courseprefix.'.['.$group.'].'.$level;
351: if (defined($courseopt{$item})) {
352: return $courseopt{$item};
353: }
354: }
355: }
356: }
357: # check section
358: if (defined($csec)) {
359: return $courseopt{$seclevelr} if (defined($courseopt{$seclevelr}));
360: return $courseopt{$seclevelm} if (defined($courseopt{$seclevelm}));
361: return $courseopt{$seclevel} if (defined($courseopt{$seclevel}));
362: }
363: #
364: # check course
365: return $courseopt{$courselevelr} if (defined($courseopt{$courselevelr}));
366: # check map parms
367: my $thisparm = $parmhash{$symbparm};
368: return $thisparm if (defined($thisparm));
369: # check default
370: $thisparm = &Apache::lonnet::metadata($fn,$rwhat.'.default');
371: return $thisparm if (defined($thisparm));
372: # check more course
373: return $courseopt{$courselevelm} if (defined($courseopt{$courselevelm}));
374: return $courseopt{$courselevel} if (defined($courseopt{$courselevel}));
375:
376: # Cascade Up
377: my $space=$what;
378: $space=~s/\.[^._]+$//;
379: if ($space ne '0') {
380: my @parts=split(/_/,$space);
381: my $id=pop(@parts);
382: my $part=join('_',@parts);
383: if ($part eq '') { $part='0'; }
384: my $newwhat=$rwhat;
385: $newwhat=~s/\Q$space\E/$part/;
386: my $partgeneral=$self->parmval($newwhat,$symb,$uname,$udom,$csec,1,
387: $mapname,$id,$fn,$groups);
388: if (defined($partgeneral)) { return $partgeneral; }
389: }
390: if ($recurse) { return undef; }
391: my $pack_def=&Apache::lonnet::packages_tab_default($fn,'resource.'.$what);
392: if (defined($pack_def)) { return $pack_def; }
393: #nothing defined
394: return '';
395: }
396:
397: sub get_html_title {
398: my $self = shift;
399: my ($assess_title,$name,$time) = $self->get_full_title();
400: my $title = '<h1>'.$assess_title.'</h1>'.
401: '<h2>'.$name.', '.
402: &Apache::loncommon::aboutmewrapper
403: ($self->{'name'}.'@'.$self->{'domain'},
404: $self->{'name'},$self->{'domain'});
405: $title .= '<h3>'.$time.'</h3>';
406: return $title;
407: }
408:
409: sub get_title {
410: my $self = shift;
411: if (($self->{'symb'} eq '_feedback') ||
412: ($self->{'symb'} eq '_evaluation') ||
413: ($self->{'symb'} eq '_discussion') ||
414: ($self->{'symb'} eq '_tutoring')) {
415: my $assess_title = ucfirst($self->{'symb'});
416: $assess_title =~ s/^_//;
417: return $assess_title;
418: } else {
419: return &Apache::lonnet::gettitle($self->{'symb'});
420: }
421: }
422:
423: sub get_full_title {
424: my $self = shift;
425: my @title = ($self->get_title());
426: # Look up the users identifying information
427: # Get the users information
428: my $name = &Apache::loncommon::plainname($self->{'name'},
429: $self->{'domain'});
430: push (@title,$name);
431: push (@title,&Apache::lonlocal::locallocaltime(time));
432: return @title;
433: }
434:
435: sub parent_link {
436: my $self = shift;
437: my $link .= '<p><a href="/adm/studentcalc?'.
438: 'sname='.$self->{'name'}.
439: '&sdomain='.$self->{'domain'}.'">'.
440: &mt('Student level sheet').'</a></p>'."\n";
441: return $link;
442: }
443:
444: sub outsheet_html {
445: my $self = shift;
446: my ($r) = @_;
447: ####################################
448: # Report any calculation errors #
449: ####################################
450: $r->print($self->html_report_error());
451: ###################################
452: # Determine table structure
453: ###################################
454: my $importcolor = '#FFFFFF';
455: my $exportcolor = '#FFFFAA';
456: my $num_uneditable = 1;
457: my $num_left = 52-$num_uneditable;
458: my %lt=&Apache::lonlocal::texthash(
459: 'as' => 'Assessment',
460: 'ca' => 'Calculations',
461: );
462: my $tableheader =<<"END";
463: <table border="2">
464: <tr>
465: <th colspan="2" rowspan="2"><font size="+2">$lt{'as'}</font></th>
466: <td bgcolor="$importcolor" colspan="$num_uneditable"> </td>
467: <td colspan="$num_left">
468: <b><font size="+1">$lt{'ca'}</font></b></td>
469: </tr><tr>
470: END
471: my $label_num = 0;
472: foreach (split(//,'ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz')){
473: if ($label_num<$num_uneditable) {
474: $tableheader .= '<td bgcolor="'.$importcolor.'">';
475: } else {
476: $tableheader .= '<td>';
477: }
478: $tableheader .= "<b><font size=+1>$_</font></b></td>";
479: $label_num++;
480: }
481: $tableheader.="</tr>\n";
482: #
483: $r->print($tableheader);
484: #
485: # Print out template row
486: $r->print('<tr><td>Template</td><td> </td>'.
487: $self->html_template_row($num_uneditable,$importcolor).
488: "</tr>\n");
489: #
490: # Print out summary/export row
491: $r->print('<tr><td>Export</td><td>0</td>'.
492: $self->html_export_row($exportcolor)."</tr>\n");
493: #
494: # Prepare to output rows
495: $tableheader =<<"END";
496: <table border="2">
497: <tr><th>row</th><th>Item</th>
498: END
499: foreach (split(//,'ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz')){
500: if ($label_num<$num_uneditable) {
501: $tableheader.='<th bgcolor="'.$importcolor.'">';
502: } else {
503: $tableheader.='<th>';
504: }
505: $tableheader.="<b><font size=+1>$_</font></b></th>";
506: }
507: #
508: my $num_output = 0;
509: foreach my $rownum (sort {$a <=> $b} ($self->rows())) {
510: if (! $self->parameter_part_is_valid(
511: $self->{'formulas'}->{'A'.$rownum}
512: )) {
513: next;
514: }
515: if ($num_output++ % 50 == 0) {
516: $r->print("</table>\n".$tableheader);
517: }
518: $r->print('<tr><td>'.$rownum.'</td>'.
519: $self->assess_html_row($rownum,$importcolor)."</tr>\n");
520: }
521: $r->print("</table>\n");
522: return;
523: }
524:
525: sub assess_html_row {
526: my $self = shift();
527: my ($row,$importcolor) = @_;
528: my $parameter_name = $self->{'formulas'}->{'A'.$row};
529: my @rowdata = $self->get_row($row);
530: my $num_cols_output = 0;
531: my $row_html;
532: my $name=$self->get_parm_name($parameter_name);
533: if ($name ne '') {
534: $name =~ s/ /\ /g;
535: $row_html .= '<td>'.$name.'<br />'.$parameter_name.'</td>';
536: } else {
537: $row_html .= '<td>'.$parameter_name.'</td>';
538: }
539: foreach my $cell (@rowdata) {
540: if ($num_cols_output < 1) {
541: $row_html .= '<td bgcolor="'.$importcolor.'">';
542: $row_html .= &Apache::Spreadsheet::html_uneditable_cell($cell,
543: '#FFDDDD');
544: } else {
545: $row_html .= '<td bgcolor="#E0FFDD">';
546: $row_html .= &Apache::Spreadsheet::html_editable_cell($cell,
547: '#E0FFDD',1);
548: }
549: $row_html .= '</td>';
550: $num_cols_output++;
551: }
552: return $row_html;
553: }
554:
555: sub csv_rows {
556: # writes the meat of the spreadsheet to an excel worksheet. Called
557: # by Spreadsheet::outsheet_excel;
558: my $self = shift;
559: my ($connection,$filehandle) = @_;
560: #
561: # Write a header row
562: $self->csv_output_row($filehandle,undef,
563: (&mt('Parameter'),&mt('Description'),&mt('Value')));
564: #
565: # Write each row
566: foreach my $rownum (sort {$a <=> $b} ($self->rows())) {
567: my $parameter_name = $self->{'formulas'}->{'A'.$rownum};
568: my $description = $self->get_parm_name($parameter_name);
569: $self->csv_output_row($filehandle,$rownum,
570: $parameter_name,$description);
571: }
572: return;
573: }
574:
575: sub excel_rows {
576: # writes the meat of the spreadsheet to an excel worksheet. Called
577: # by Spreadsheet::outsheet_excel;
578: my $self = shift;
579: my ($connection,$worksheet,$cols_output,$rows_output,$format) = @_;
580: return if (! ref($worksheet));
581: #
582: # Write a header row
583: $cols_output = 0;
584: foreach my $value ('Parameter','Description','Value') {
585: $worksheet->write($rows_output,$cols_output++,$value,$format->{'h4'});
586: }
587: $rows_output++;
588: #
589: # Write each row
590: foreach my $rownum (sort {$a <=> $b} ($self->rows())) {
591: my $parameter_name = $self->{'formulas'}->{'A'.$rownum};
592: my $description = $self->get_parm_name($parameter_name);
593: $self->excel_output_row($worksheet,$rownum,$rows_output++,
594: $parameter_name,$description);
595: }
596: return;
597: }
598:
599: ##
600: ## Routines to support assesscalc::compute
601: ##
602: sub get_parm {
603: my $self = shift;
604: my @Mandatory_parameters = @_;
605: my %parameters;
606: #
607: my ($symap,$syid,$srcf) = &Apache::lonnet::decode_symb($self->{'symb'});
608: my @Metadata = split(/\,/,&Apache::lonnet::metadata($srcf,'keys'));
609: foreach my $parm (@Mandatory_parameters,@Metadata) {
610: next if ($parm !~ /^(resource\.|stores|parameter)_/);
611: my $cleaned_name = $parm;
612: $cleaned_name =~ s/^resource\./stores_/;
613: $cleaned_name =~ s/\./_/g;
614: $parameters{$cleaned_name}=1;
615: }
616: return (keys(%parameters));
617: }
618:
619: sub get_parm_name {
620: my $self = shift;
621: my $parm = shift;
622: my ($symap,$syid,$srcf) = &Apache::lonnet::decode_symb($self->{'symb'});
623: my $display = &Apache::lonnet::metadata($srcf,$parm.'.display');
624: if (! $display) {
625: $display .= &Apache::lonnet::metadata($srcf,$parm.'.name');
626: }
627: return $display;
628: }
629:
630: sub get_parameter_values {
631: my $self = shift();
632: my @Parameters;
633: my ($parameters) = @_;
634: if (!ref($parameters)) {
635: @Parameters = @_;
636: } elsif (ref($parameters) eq 'ARRAY') {
637: @Parameters = @$parameters;
638: } elsif (ref($parameters) eq 'HASH') {
639: @Parameters = keys(%$parameters);
640: }
641: #
642: my %parameters;
643: #
644: my $filename = $self->{'coursefilename'}.'_parms.db';
645: if (tie(%parmhash,'GDBM_File',
646: $self->{'coursefilename'}.'_parms.db',&GDBM_READER(),0640)) {
647: my ($mapname,$id,$fn)=&Apache::lonnet::decode_symb($self->{'symb'});
648: $mapname = &Apache::lonnet::deversion($mapname);
649: foreach my $parmname (@Parameters) {
650: my $value = $self->parmval($parmname,$self->{'symb'},
651: $self->{'name'},$self->{'domain'},
652: $self->{'section'},undef,
653: $mapname,$id,$fn,$self->{'groups'});
654: $parameters{$parmname} =$value;
655: }
656: untie(%parmhash);
657: } else {
658: $self->logthis('unable to tie '.$filename);
659: }
660: return %parameters;
661: }
662:
663: sub deal_with_export_row {
664: my $self = shift();
665: my @exportarray = @_;
666: $Exportrows{$self->{'symb'}}->{'time'} = time;
667: $Exportrows{$self->{'symb'}}->{$self->{'filename'}} = \@exportarray;
668: #
669: # Save the export data
670: $self->save_export_data();
671: return;
672: }
673:
674: sub get_problem_state {
675: my $self = shift;
676: my %student_parameters;
677: if (exists($userdata{$self->{'symb'}}) &&
678: ref($userdata{$self->{'symb'}}) eq 'HASH') {
679: %student_parameters = %{$userdata{$self->{'symb'}}};
680: }
681: return %student_parameters;
682: }
683:
684: sub determine_parts {
685: my $self = shift;
686: my $check_hidden = shift;
687: if (exists($self->{'Parts'}) && ref($self->{'Parts'}) eq 'HASH') {
688: return;
689: }
690: my (undef,undef,$url) = &Apache::lonnet::decode_symb($self->{'symb'});
691: my $src = &Apache::lonnet::clutter($url);
692: return if (! defined($src));
693: my %Parts;
694: my $metadata = &Apache::lonnet::metadata($src,'packages');
695: foreach (split(',',$metadata)) {
696: my ($part) = (/^part_(.*)$/);
697: if (!defined($part)) { next; }
698: if (!$check_hidden) { $Parts{$part}++; next; }
699: if (!&Apache::loncommon::check_if_partid_hidden
700: ($part,$self->{'symb'},$self->{'name'},$self->{'domain'})
701: ) {
702: $Parts{$part}++;
703: }
704: }
705: # Make sure part 0 is defined.
706: $Parts{'0'}++;
707: $self->{'Parts'} = \%Parts;
708: return;
709: }
710:
711: sub parameter_part_is_valid {
712: my $self = shift;
713: my ($parameter) = @_;
714: return 1 if ($parameter eq 'timestamp');
715: if (! defined($self->{'Parts'}) ||
716: ! ref ($self->{'Parts'}) ||
717: ref($self->{'Parts'}) ne 'HASH') {
718: return 1;
719: }
720: #
721: my ($start,@pieces)=split('_',$parameter);
722: if ( $start !~ m/^(resource|stores|parameter)$/) { return 0; }
723: while (@pieces) {
724: pop(@pieces);
725: my $testpart=join('_',@pieces);
726: if (exists($self->{'Parts'}->{$testpart}) &&
727: $self->{'Parts'}->{$testpart} ) {
728: return 1;
729: }
730: }
731: return 0;
732: }
733:
734: sub compute {
735: my $self = shift;
736: my ($r) = @_;
737: $self->initialize_safe_space();
738: #########################################
739: #########################################
740: ### ###
741: ### Retrieve the problem parameters ###
742: ### ###
743: #########################################
744: #########################################
745: my @Mandatory_parameters = ("stores_0_solved",
746: "stores_0_awarddetail",
747: "stores_0_awarded",
748: "timestamp",
749: "stores_0_tries",
750: "stores_0_award");
751: #
752: # Definitions
753: undef(%nice_parameter_name);
754: my %parameters; # holds underscored parameters by name
755: #
756: # Get the metadata fields and determine their proper names
757: my @parameters=$self->get_parm(@Mandatory_parameters);
758: #
759: # Get the values of the metadata fields
760: $self->ensure_current_caches();
761: %parameters = $self->get_parameter_values(@parameters);
762: #
763: # Clean out unnecessary parameters
764: foreach (keys(%parameters)) {
765: delete($parameters{$_}) if (! /(resource\.|stores_|parameter_)/);
766: }
767: #
768: # Get the students performance data
769: $self->determine_parts(($parameters{'parameter_0_hiddenparts'} ne ''));
770: my %student_parameters = $self->get_problem_state();
771: while (my ($parm,$value) = each(%student_parameters)) {
772: $parm =~ s/^resource\./stores_/;
773: $parm =~ s/\./_/g;
774: # Clean out any bad parameters
775: next if (! $self->parameter_part_is_valid($parm));
776: $parameters{$parm} = $value;
777: }
778: #
779: # Set up the formulas and parameter values
780: my %f=$self->formulas();
781: my %c;
782: #
783: # Check for blackout requirements
784: if ((!exists($env{'request.role.adv'}) || !$env{'request.role.adv'})) {
785: while (my ($parm,$value) = each(%parameters)) {
786: last if ($self->blackout());
787: next if ($parm !~ /^(parameter_.*)_problemstatus$/);
788: if ($parameters{$1.'_answerdate'} ne '' &&
789: $parameters{$1.'_answerdate'} < time) {
790: next;
791: }
792: if (lc($value) eq 'no') {
793: # We must blackout this sheet
794: $self->blackout(1);
795: }
796: }
797: }
798: #
799: # Move the parameters into the spreadsheet
800: while (my ($parm,$value) = each(%parameters)) {
801: my $cell = 'A'.$self->get_row_number_from_key($parm);
802: $f{$cell} = $parm;
803: if ($parm =~ /_submission$/ && $value =~ /(\{|\})/) {
804: $value = 'witheld';
805: }
806: $value = 'q{'.$value.'}' if ($value =~/([^\d\.]|\.\.)/);
807: $c{$parm} = $value;
808: }
809: foreach my $cell (grep(/^A/,keys(%f))) {
810: # Clean out any bad formulas
811: next if (exists($c{$f{$cell}}));
812: next if ($cell eq 'A0');
813: delete($f{$cell});
814: }
815: $self->formulas(\%f);
816: $self->constants(\%c);
817: $self->calcsheet();
818: #
819: # Store export row in cache
820: my @exportarray = $self->exportrow();
821: $self->deal_with_export_row(@exportarray);
822: $self->save() if ($self->need_to_save());
823: return;
824: }
825:
826: ##
827: ## sett overrides Spreadsheet::sett
828: ##
829: sub sett {
830: my $self = shift;
831: my %t=();
832: undef(%Apache::Spreadsheet::sheet_values);
833: #
834: # Deal with the template row by copying the template formulas into each
835: # row.
836: foreach my $col ($self->template_cells()) {
837: next if ($col=~/^A/);
838: foreach my $row ($self->rows()) {
839: # Get the name of this cell
840: my $cell=$col.$row;
841: # Grab the template declaration
842: $t{$cell}=$self->formula('template_'.$col);
843: # Replace '#' with the row number
844: $t{$cell}=~s/\#/$row/g;
845: # Replace '....' with ','
846: $t{$cell}=~s/\.\.+/\,/g;
847: # Replace 'A0' with the value from 'A0'
848: $t{$cell}=~s/(^|[^\"\'])([A-Za-z]\d+)/$1\$sheet_values\{\'$2\'\}/g;
849: # Replace parameters
850: $t{$cell}=~s/(^|[^\"\'])\[([^\]]+)\]/$1.$self->expandnamed($2)/ge;
851: }
852: }
853: #
854: # Deal with the cells which have formulas
855: while (my ($cell,$formula) = each(%{$self->{'formulas'}})) {
856: next if ($cell =~ /template_/);
857: if ($cell =~ /^A/ && $cell ne 'A0') {
858: if ($formula !~ /^\!/
859: && exists($self->{'constants'}->{$formula})
860: && $self->{'constants'}->{$formula} ne ''
861: ) {
862: $Apache::Spreadsheet::sheet_values{$cell}=
863: eval($self->{'constants'}->{$formula});
864: }
865: } else {
866: $t{$cell}=$formula;
867: $t{$cell}=~s/\.\.+/\,/g;
868: $t{$cell}=~s/(^|[^\"\'])([A-Za-z]\d+)/$1\$sheet_values\{\'$2\'\}/g;
869: $t{$cell}=~s/(^|[^\"\'])\[([^\]]+)\]/$1.$self->expandnamed($2)/ge;
870: }
871: }
872: # Put %t into the safe space
873: %{$self->{'safe'}->varglob('t')}=%t;
874: }
875:
876:
877: ########################################################
878: ########################################################
879:
880: =pod
881:
882: =item &load_cached_export_rows()
883:
884: Retrieves and parsers the export rows of the assessment spreadsheets.
885: These rows are saved in the students directory in the format:
886:
887: sname:sdom:assesscalc:symb.time => time
888:
889: sname:sdom:assesscalc:symb => filename___=___Adata___;___Bdata___;___ ...
890:
891: =cut
892:
893: ########################################################
894: ########################################################
895: sub load_cached_export_rows {
896: undef(%Exportrows);
897: my @tmp = &Apache::lonnet::dump('nohist_calculatedsheets_'.
898: $env{'request.course.id'},
899: $current_domain,$current_name,undef);
900: if ($tmp[0]!~/^error/) {
901: my %tmp = @tmp;
902: my $default_filename = $env{'course.'.$env{'request.course.id'}.
903: '.spreadsheet_default_assesscalc'};
904: # We only got one key, so we will access it directly.
905: while (my ($key,$sheetdata) = each(%tmp)) {
906: my ($sname,$sdom,$sheettype,$symb) = split(':',$key);
907: if (! defined($sname) || $sname eq '' ||
908: ! defined($sdom) || $sdom eq '' ) {
909: next;
910: }
911: if ($symb =~ /\.time$/) {
912: $symb =~ s/\.time$//;
913: $Exportrows{$symb}->{'time'} = $sheetdata;
914: } else {
915: $sheetdata =~ s/^(.*)___=___//;
916: my $filename = $1;
917: $filename = $default_filename if (! defined($filename));
918: my @Data = split('___;___',$sheetdata);
919: $Exportrows{$symb}->{$filename} = \@Data;
920: }
921: }
922: }
923: }
924:
925: #############################################
926: #############################################
927:
928: =pod
929:
930: =item &export_data
931:
932: Returns the export data associated with the spreadsheet. Computes the
933: spreadsheet only if necessary.
934:
935: =cut
936:
937: #############################################
938: #############################################
939: sub export_data {
940: my $self = shift;
941: my ($r) = @_;
942: my $symb = $self->{'symb'};
943: if (! exists($env{'request.role.adv'}) || ! $env{'request.role.adv'} ||
944: ! exists($Exportrows{$symb}) || ! defined($Exportrows{$symb}) ||
945: ! $self->check_expiration_time($Exportrows{$symb}->{'time'}) ||
946: ! exists($Exportrows{$symb}->{$self->{'filename'}}) ||
947: ! defined($Exportrows{$symb}->{$self->{'filename'}}) ||
948: ! ref($Exportrows{$symb}->{$self->{'filename'}})
949: ) {
950: $self->compute($r);
951: }
952: my @Data;
953: if ($self->badcalc()) {
954: @Data = ();
955: } else {
956: @Data = @{$Exportrows{$symb}->{$self->{'filename'}}};
957: if ($Data[0] =~ /^(.*)___=___/) {
958: $self->{'sheetname'} = $1;
959: $Data[0] =~ s/^(.*)___=___//;
960: }
961: for (my $i=0;$i<$#Data;$i++) {
962: if ($Data[$i]=~/\D/ && defined($Data[$i])) {
963: $Data[$i]="'".$Data[$i]."'";
964: }
965: }
966: }
967: return @Data;
968: }
969:
970: #############################################
971: #############################################
972:
973: =pod
974:
975: =item &save_export_data()
976:
977: Writes the export data for this spreadsheet to the students cache.
978:
979: =cut
980:
981: #############################################
982: #############################################
983: sub save_export_data {
984: my $self = shift;
985: return if ($self->temporary());
986: my $student = $self->{'name'}.':'.$self->{'domain'};
987: my $symb = $self->{'symb'};
988: if ($self->badcalc()){
989: # do not save data away when calculations have not been done properly.
990: delete($Exportrows{$symb});
991: return;
992: }
993: if (! exists($Exportrows{$symb}) ||
994: ! exists($Exportrows{$symb}->{$self->{'filename'}})) {
995: return;
996: }
997: my $key = join(':',($self->{'name'},$self->{'domain'},'assesscalc',$symb));
998: my $timekey = $key.'.time';
999: my $newstore= join('___;___',
1000: map {s/[^[:print:]]//g;$_;} # strip out unprintable
1001: @{$Exportrows{$symb}->{$self->{'filename'}}});
1002: $newstore = $self->{'filename'}.'___=___'.$newstore;
1003: $newExportrows{$student}->{$key} = $newstore;
1004: $newExportrows{$student}->{$timekey} = $Exportrows{$symb}->{'time'};
1005: return;
1006: }
1007:
1008: 1;
1009:
1010: __END__
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>
![[BACK]](/icons/back.gif){kind=icon}
Return to assesscalc.pm CVS log ![[TXT]](/icons/text.gif){kind=icon}
![[DIR]](/icons/dir.gif){kind=icon}
Up to [LON-CAPA] / loncom / interface / spreadsheet