1: #
2: # $Id: lonspreadsheet.pm,v 1.55.6.1 2011/10/09 00:28:03 raeburn Exp $
3: #
4: # Copyright Michigan State University Board of Trustees
5: #
6: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
7: #
8: # LON-CAPA is free software; you can redistribute it and/or modify
9: # it under the terms of the GNU General Public License as published by
10: # the Free Software Foundation; either version 2 of the License, or
11: # (at your option) any later version.
12: #
13: # LON-CAPA is distributed in the hope that it will be useful,
14: # but WITHOUT ANY WARRANTY; without even the implied warranty of
15: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
16: # GNU General Public License for more details.
17: #
18: # You should have received a copy of the GNU General Public License
19: # along with LON-CAPA; if not, write to the Free Software
20: # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
21: #
22: # /home/httpd/html/adm/gpl.txt
23: #
24: # http://www.lon-capa.org/
25: #
26: # The LearningOnline Network with CAPA
27: # Spreadsheet/Grades Display Handler
28: #
29: # POD required stuff:
30:
31: =head1 NAME
32:
33: lonspreadsheet
34:
35: =head1 SYNOPSIS
36:
37: Spreadsheet interface to internal LON-CAPA data
38:
39: =head1 DESCRIPTION
40:
41: Lonspreadsheet provides course coordinators the ability to manage their
42: students grades online. The students are able to view their own grades, but
43: not the grades of their peers. The spreadsheet is highly customizable,
44: offering the ability to use Perl code to manipulate data, as well as many
45: built-in functions.
46:
47: =head2 Functions available to user of lonspreadsheet
48:
49: =over 4
50:
51: =cut
52:
53:
54: package Apache::lonspreadsheet;
55:
56: use strict;
57: use warnings FATAL=>'all';
58: no warnings 'uninitialized';
59: use Apache::classcalc();
60: use Apache::studentcalc();
61: use Apache::assesscalc();
62: use Apache::Constants qw(:common :http);
63: use Apache::lonnet;
64: use Apache::lonhtmlcommon;
65: use Apache::lonlocal;
66: use Apache::loncoursedata();
67: use HTML::Entities();
68:
69: ##
70: ## HTML utility subroutines really should go in lonhtmlcommon
71: ##
72:
73: sub textfield {
74: my ($title,$name,$value)=@_;
75: return "\n<p><b>$title:</b><br />".
76: '<input type="text" name="'.$name.'" size="80" value="'.$value.'" />';
77: }
78:
79: sub hiddenfield {
80: my ($name,$value)=@_;
81: return '<input type="hidden" name="'.$name.'" value="'.$value.'" />'."\n";
82: }
83:
84: sub selectbox {
85: my ($title,$name,$value,%options)=@_;
86: my $selout="\n<p><b>$title:</b><br />".'<select name="'.$name.'">';
87: foreach (sort keys(%options)) {
88: $selout.='<option value="'.$_.'"';
89: if ($_ eq $value) { $selout.=' selected="selected"'; }
90: $selout.='>'.&mt($options{$_}).'</option>';
91: }
92: return $selout.'</select>';
93: }
94:
95: sub file_dialogs {
96: my ($spreadsheet) = @_;
97: my $bgcolor = "#FFFFFF";
98: my $sheettype = $spreadsheet->{'type'};
99: my $result = '';
100: my $message = '';
101: ##
102: ## Deal with saving the spreadsheet
103: $spreadsheet->check_formulas_loaded();
104: if ((exists($env{'form.save'}) || exists($env{'form.makedefault'})) &&
105: exists($env{'form.savefilename'})) {
106: $spreadsheet->filename($env{'form.savefilename'});
107: my $save_status = $spreadsheet->save();
108: if ($save_status ne 'ok') {
109: $message .= '<span class="LC_error">'.
110: &mt('An error occurred while saving the spreadsheet. The error is: [_1].',
111: $save_status).'</span>';
112: } else {
113: $message .= '<span class="LC_info">'.&mt('Spreadsheet saved as: [_1] .',
114: '<span class="LC_filename">'.$spreadsheet->filename().'</span>').
115: '</span>';
116: }
117: } elsif (exists($env{'form.newformula'}) &&
118: exists($env{'form.cell'}) &&
119: $env{'form.cell'} ne '' ) {
120: ##
121: ## Make any requested modifications to the spreadsheet
122: $spreadsheet->modify_cell($env{'form.cell'},
123: $env{'form.newformula'});
124: $spreadsheet->save_tmp();
125: # output that we are dealing with a temporary file
126: $result .=&hiddenfield('workcopy',$sheettype);
127: if ($env{'form.newformula'} !~ /^\s*$/) {
128: $message .='<table><tr>'.
129: '<td valign="top"><pre>'.&mt('Cell').' '.$env{'form.cell'}.' = </pre></td>'.
130: '<td><pre>'.$env{'form.newformula'}."</pre></td></tr></table>\n";
131: } else {
132: $message .= &mt('Deleted contents of cell').' '.$env{'form.cell'}.'.';
133: }
134: }
135: ##
136: ## Editing code
137: $result .=&hiddenfield('cell','').
138: &hiddenfield('newformula','');
139: ##
140: ## Create the save and load dialogs
141: my $filename = $spreadsheet->filename();
142: my $truefilename = $filename;
143: if ($spreadsheet->is_default()) {
144: $filename = 'Default';
145: }
146: my $save_dialog = '<span class="LC_nobreak">'.
147: '<input type="submit" name="save" value="'.&mt('Save as').'" /> '.
148: '<input type="text" name="savefilename" size="30" value="'.
149: $truefilename.'" />'.
150: '</span>';
151: my $makedefault_dialog = '<input type="submit" name="makedefault" '.
152: 'value="'.&mt('Save as & Make This Sheet the Default').'"/>';
153: #
154: my $link = '<a href="javascript:openbrowser'.
155: "('sheet','loadfilename','spreadsheet')\">".&mt('Select Spreadsheet File')."</a>";
156: my $load=&mt('Load:');
157: my $load_dialog = <<END;
158: <table bgcolor="$bgcolor">
159: <tr><td><input type="submit" name="load" value="$load" /></td>
160: <td><span class="LC_nobreak">
161: <input type="text" name="loadfilename" size="20" value="$filename" />
162: $link</span>
163: </td></tr>
164: <tr><td> </td><td>
165: <select name="fileselect" onchange="document.sheet.loadfilename.value=document.sheet.fileselect.value" >
166: END
167: my $default_filename_set = 0;
168: foreach my $sheetfilename ($spreadsheet->othersheets()) {
169: $load_dialog .= ' <option value="'.$sheetfilename.'"';
170: if ($filename eq $sheetfilename) {
171: $load_dialog .= ' selected="selected"';
172: $default_filename_set = 1;
173: }
174: $load_dialog .= '>'.$sheetfilename."</option>\n";
175: }
176: $load_dialog .= "</select>\n</td><td> </td></tr>\n</table>\n";
177: #
178: my $headline = &mt('File Dialogs');
179: $result .=<<END;
180: <!--
181: <fieldset title="File Dialogs" >
182: <legend>$headline</legend>
183: -->
184: <!-- load / save dialogs -->
185: <table cellspacing="2">
186: <tr>
187: <td>$load_dialog</td>
188: <td>
189: <table bgcolor="$bgcolor">
190: <tr><td>$save_dialog</td></tr>
191: <tr><td align="center">$makedefault_dialog</td></tr>
192: </table>
193: </td>
194: </tr>
195: </table>
196: <!--
197: </fieldset>
198: -->
199: END
200: return ($result,$message);
201: }
202:
203: sub handler {
204: my $r=shift;
205: #
206: # Overload checking
207: #
208: # Check this server
209: my $loaderror=&Apache::lonnet::overloaderror($r);
210: if ($loaderror) { return $loaderror; }
211: # Check the course homeserver
212: $loaderror= &Apache::lonnet::overloaderror($r,
213: $env{'course.'.$env{'request.course.id'}.'.home'});
214: # if ($loaderror) { return $loaderror; }
215: #
216: # HTML Header
217: #
218: if ($r->header_only) {
219: &Apache::loncommon::content_type($r,'text/html');
220: $r->send_http_header;
221: return OK;
222: }
223: #
224: # Roles Checking
225: #
226: # Needs to be in a course
227: if (! $env{'request.course.fn'}) {
228: # Not in a course, or not allowed to modify parms
229: $env{'user.error.msg'}=
230: $r->uri.":opa:0:0:Cannot modify spreadsheet";
231: return HTTP_NOT_ACCEPTABLE;
232: }
233: my ($sheettype) = ($r->uri=~/\/(\w+)$/);
234: my $courseid = $env{'request.course.id'};
235:
236: ##
237: ## Check permissions
238: my $allowed_to_edit = &Apache::lonnet::allowed('mgr',
239: $env{'request.course.id'});
240: # Only those instructors/tas/whatevers with complete access
241: # (not section restricted) are able to modify spreadsheets.
242: my $allowed_to_view = &Apache::lonnet::allowed('vgr',
243: $env{'request.course.id'});
244: if (! $allowed_to_view) {
245: $allowed_to_view = &Apache::lonnet::allowed('vgr',
246: $env{'request.course.id'}.'/'.$env{'request.course.sec'});
247: # Those who are restricted by section are allowed to view.
248: # The routines in lonstatistics which decide which students'
249: # will be shown take care of the restriction by section.
250: }
251:
252: #
253: # Do not allow users without vgr or mgr priv to continue unless
254: # grading type is set to spreadsheet.
255: #
256:
257: if ((!$allowed_to_view) && (!$allowed_to_edit)) {
258: if ($env{'course.'.$courseid.'.grading'} eq 'spreadsheet') {
259: if ($sheettype ne 'studentcalc') {
260: $r->internal_redirect('/adm/studentcalc');
261: return OK;
262: }
263: } else {
264: $r->internal_redirect('/adm/quickgrades');
265: return OK;
266: }
267: }
268: #
269: # Get query string for limited number of parameters
270: #
271: &Apache::loncommon::get_unprocessed_cgi
272: ($ENV{'QUERY_STRING'},['sname','sdomain','usymb','filename','recalc',
273: 'output_format','not_first_run']);
274: #
275: # Deal with restricted student permissions
276: #
277: if ($env{'request.role'} =~ /^st\./) {
278: delete $env{'form.cell'} if (exists($env{'form.cell'}));
279: delete $env{'form.newformula'} if (exists($env{'form.newformula'}));
280: }
281: #
282: # Determine basic information about the spreadsheet
283: #
284: my $symb = undef;
285: $symb = $env{'form.usymb'} if (exists($env{'form.usymb'}));
286: my $name = $env{'user.name'};
287: my $domain = $env{'user.domain'};
288: my $warning;
289: if (exists($env{'form.sname'}) && $env{'form.sname'} ne '') {
290: if (($env{'form.sname'} ne $env{'user.name'}) ||
291: ($env{'form.sdomain'} ne $env{'user.domain'})) {
292: if (($allowed_to_view) || ($allowed_to_edit)) {
293: if (&Apache::lonnet::homeserver($env{'form.sname'},$env{'form.sdomain'}) ne 'no_host') {
294: $name = $env{'form.sname'};
295: $domain = $env{'form.sdomain'};
296: } else {
297: $warning = &mt('Requested user: "[_1]" does not exist; your own sheet is displayed instead.',$env{'form.sname'}.':'.$env{'form.sdomain'});
298: }
299: } else {
300: $warning = &mt('Your current role is not permitted to display this sheet for the requested user: "[_1]"; your own sheet is displayed instead.',$env{'form.sname'}.':'.$env{'form.sdomain'});
301: }
302: }
303: }
304: $env{'form.sname'} = $name;
305: $env{'form.sdomain'} = $domain;
306: my $section = &Apache::lonnet::getsection($domain,$name,
307: $env{'request.course.id'});
308: my @groups;
309: if (($env{'user.name'} eq $name) && ($env{'user.domain'} eq $domain)) {
310: @groups = &Apache::lonnet::sort_course_groups($env{'request.course.id'},
311: split(':',$env{'request.course.groups'}));
312: } else {
313: @groups = &Apache::lonnet::get_users_groups($domain,$name,
314: $env{'request.course.id'});
315: }
316:
317: #
318: # Only those able to view others grades will be allowed to continue
319: # if they are not requesting their own.
320: if ($sheettype eq 'classcalc') {
321: if (!$allowed_to_view) {
322: $r->internal_redirect('/adm/studentcalc');
323: return OK;
324: }
325: }
326: if ((($name ne $env{'user.name'} ) ||
327: ($domain ne $env{'user.domain'})) && $sheettype ne 'classcalc') {
328: # Check that the student is in their section?
329: if (exists($env{'request.course.sec'}) &&
330: $env{'request.course.sec'} ne '' ) {
331: my $stu_sec = &Apache::lonnet::getsection($domain,$name,
332: $env{'request.course.id'});
333: if ($stu_sec ne $env{'request.course.sec'}) {
334: $env{'user.error.msg'}=
335: $r->uri.":vgr:0:0:Requested student not in your section.";
336: return HTTP_NOT_ACCEPTABLE;
337: }
338: }
339: }
340:
341: #
342: # Open page, try to prevent browser cache.
343: #
344: &Apache::loncommon::content_type($r,'text/html');
345: &Apache::loncommon::no_cache($r);
346: $r->send_http_header;
347:
348: #
349: # Header....
350: #
351: my $nothing = &Apache::lonhtmlcommon::javascript_nothing();
352: ##
353: ## Spit out the javascript required for editing
354: ##
355: my $js;
356: if ($allowed_to_edit) {
357: my %lt=(
358: 'ce' => 'Cell',
359: 'ac' => 'Accept',
360: 'dc' => 'Discard Changes'
361: );
362: my $extra_javascript =
363: &Apache::loncommon::browser_and_searcher_javascript();
364:
365: my $cell_extra_js = &Apache::loncommon::resize_textarea_js();
366: my $cell_edit_start =
367: &Apache::loncommon::start_page('Cell Edit Window',$cell_extra_js,
368: {'only_body' => 1,
369: 'js_ready' => 1,
370: 'add_entries' => {
371: 'onresize' => "resize_textarea('LC_newformula','LC_aftertextarea')",
372: 'onload' => "resize_textarea('LC_newformula','LC_aftertextarea')",
373: }});
374: my $cell_edit_end =
375: &Apache::loncommon::end_page({'js_ready' => 1,});
376:
377: $js = <<ENDSCRIPT;
378: <script type="text/javascript">
379: //<!--
380: $extra_javascript
381:
382: var editwin;
383:
384: function celledit(cellname,cellformula) {
385: var edit_text = '';
386: // cellformula may contain less-than and greater-than symbols, so
387: // we need to escape them?
388: edit_text +='$cell_edit_start';
389: edit_text += '<form name="editwinform">';
390: edit_text += '<center><h3>$lt{'ce'} '+cellname+'</h3>';
391: edit_text += '<textarea id="LC_newformula" name="newformula" ';
392: edit_text += ' cols="60" rows="12"; wrap="off" style="width:100%">';
393: edit_text += cellformula+'</textarea>';
394: edit_text += '<div id="LC_aftertextarea"><br />';
395: edit_text += '<input type="button" name="accept" value="$lt{'ac'}"';
396: edit_text += ' onClick=\\\'javascript:';
397: edit_text += 'opener.document.sheet.cell.value=';
398: edit_text += '"'+cellname+'";';
399: edit_text += 'opener.document.sheet.newformula.value=';
400: edit_text += 'document.editwinform.newformula.value;';
401: edit_text += 'opener.document.sheet.submit();';
402: edit_text += 'self.close()\\\' />';
403: edit_text += ' ';
404: edit_text += '<input type="button" name="abort" ';
405: edit_text += 'value="$lt{'dc'}"';
406: edit_text += ' onClick="javascript:self.close()" />';
407: edit_text += '</center></div></form>$cell_edit_end';
408:
409: if (editwin != null && !(editwin.closed) ) {
410: editwin.close();
411: }
412:
413: editwin = window.open($nothing,'CellEditWin','height=280,width=480,scrollbars=no,resizable=yes,alwaysRaised=yes,dependent=yes',true);
414: editwin.document.write(edit_text);
415: editwin.document.close();
416: }
417: //-->
418: </script>
419: ENDSCRIPT
420: }
421: &Apache::lonhtmlcommon::clear_breadcrumbs();
422: &Apache::lonhtmlcommon::add_breadcrumb
423: ({href => $r->uri,
424: title => 'Spreadsheet',
425: text => 'Spreadsheet',
426: faq => 134,
427: bug => 'Spreadsheet'});
428: my $settingslink = &Apache::lonhtmlcommon::coursepreflink(&mt('Grade display settings'),
429: 'grading');
430: &Apache::lonhtmlcommon::add_breadcrumb_tool('advtools',$settingslink);
431: $r->print(&Apache::loncommon::start_page('Grades Spreadsheet',$js).
432: &Apache::lonhtmlcommon::breadcrumbs('Spreadsheet',
433: 'Spreadsheet_About'));
434: #
435: # Open the form
436: #
437: if ($warning) {
438: $r->print('<p class="LC_info">'.$warning.'</p>');
439: }
440: $r->print('<form action="'.$r->uri.'" name="sheet" method="post">');
441: $r->print(&hiddenfield('sname' ,$env{'form.sname'}).
442: &hiddenfield('sdomain',$env{'form.sdomain'}).
443: &hiddenfield('usymb' ,$env{'form.usymb'}));
444: $r->rflush();
445: ##
446: ## Determine the filename to use
447: my $filename = undef;
448: if ($allowed_to_edit) {
449: $filename = $env{'form.filename'} if (exists($env{'form.filename'}));
450: #
451: if (exists($env{'form.load'}) && exists($env{'form.loadfilename'})) {
452: $filename = $env{'form.loadfilename'};
453: $env{'form.workcopy'} = 'no';
454: }
455: }
456: ##
457: ## Take care of "backdoor" spreadsheet expiration / recalc stuff
458: if ($allowed_to_edit && exists($env{'form.recalc'})) {
459: if (exists($env{'form.recalc'})) {
460: &Apache::loncoursedata::delete_caches($env{'requres.course.id'});
461: }
462: if ($env{'form.recalc'} eq 'ilovewastingtime') {
463: &Apache::lonnet::logthis('spreadsheet expired: entire course');
464: # expire ALL spreadsheets
465: &Apache::lonnet::expirespread('','','studentcalc');
466: &Apache::lonnet::expirespread('','','assesscalc');
467: $r->print('<h3>'.
468: &mt('Expired spreadsheet caches for all students').
469: '</h3>');
470: } elsif ($env{'form.recalc'} =~ /^symb:/) {
471: # expire for all students on this symb
472: my ($symb) = ($env{'form.recalc'} =~ /^symb:(.*)$/);
473: &Apache::lonnet::logthis('spreadsheet expired: symb = '.$symb);
474: &Apache::lonnet::expirespread('','','assesscalc',$symb);
475: &Apache::lonnet::expirespread('','','studentcalc');
476: $r->print('<h3>'.
477: &mt('Expired spreadsheet caches for all students for symb [_1]',
478: $symb).
479: '</h3>');
480: } elsif ($env{'form.recalc'} =~ /^student:/) {
481: # expire all assessment spreadsheets for this user
482: my ($sname,$sdom) = ($env{'form.recalc'}=~/^student:(.*):(.*)$/);
483: &Apache::lonnet::logthis('spreadsheet expired: student = '.
484: $sname.'@'.$sdom);
485: if (defined($sname) && defined($sdom)) {
486: &Apache::lonnet::expirespread($sname,$sdom,'assesscalc');
487: &Apache::lonnet::expirespread($sname,$sdom,'studentcalc');
488: $r->print('<h3>'.
489: &mt('Expired spreadsheet caches for student [_1]',
490: $sname.'@'.$sdom).
491: '</h3>');
492: }
493: }
494: }
495: ##
496: ## Make the spreadsheet
497: &Apache::Spreadsheet::initialize_spreadsheet_package();
498: my $spreadsheet = undef;
499: if ($sheettype eq 'classcalc') {
500: $spreadsheet = Apache::classcalc->new($name,$domain,$filename,undef,
501: $section,\@groups);
502: } elsif ($sheettype eq 'studentcalc') {
503: $spreadsheet = Apache::studentcalc->new($name,$domain,$filename,undef,
504: $section,\@groups);
505: } elsif ($sheettype eq 'assesscalc' &&
506: defined($symb) &&
507: $allowed_to_edit) {
508: $spreadsheet = Apache::assesscalc->new($name,$domain,$filename,$symb,
509: $section,\@groups);
510: } else {
511: return HTTP_NOT_ACCEPTABLE;
512: }
513: if (! defined($spreadsheet)) {
514: # error error - run in circles, scream and shout
515: return;
516: }
517: $spreadsheet->initialize();
518: #
519: # Output selector
520: ##
521: ## Editing/loading/saving
522: if ($allowed_to_edit) {
523: my ($html,$action_message) = &file_dialogs($spreadsheet);
524: if ($env{'form.makedefault'}) {
525: $spreadsheet->make_default();
526: if ($action_message) {
527: $action_message .= '<br />';
528: }
529: $action_message .= &mt('Made this spreadsheet the default');
530: if ($sheettype eq 'classcalc') {
531: $action_message .= ' '.&mt('for the course');
532: } elsif ($sheettype eq 'studentcalc') {
533: $action_message .= ' '.&mt('for all students');
534: } elsif ($sheettype eq 'assesscalc') {
535: $action_message .= ' '.&mt('for all assessments');
536: }
537: $action_message .= '.';
538: }
539: $r->print('<table><tr><td valign="top">'.
540: $spreadsheet->html_header().
541: '</td>'.
542: '<td valign="center">'.$html."</td></tr></table>\n");
543: if ($action_message ne '') {
544: $r->print(<<END);
545: <table>
546: <tr><td valign="top"><b>Last Action:</b></td>
547: <td> </td>
548: <td>$action_message</td>
549: </tr>
550: </table>
551: END
552: }
553: $r->rflush();
554: } else {
555: $r->print('<table><tr><td>'.$spreadsheet->html_header().
556: "</td></tr></table>\n");
557: }
558: $r->rflush();
559: #
560: $r->print("<table><tr>");
561: $r->print('<td><input type="submit" value="'.
562: &mt('Generate Spreadsheet').'" />'.
563: '</td>');
564: if ($allowed_to_view) {
565: $r->print('<td>'.
566: &Apache::loncommon::help_open_topic("Spreadsheet_About",
567: 'Spreadsheet Help').
568: '</td>');
569: }
570: if ($allowed_to_edit) {
571: $r->print('<td>'.
572: &Apache::loncommon::help_open_topic("Spreadsheet_Editing",
573: 'Editing Help').
574: '</td>');
575: }
576: $r->print('</tr></table>');
577: #
578: # Keep track of the filename
579: $r->print(&hiddenfield('filename',$filename));
580: #
581: # Keep track of the number of times we have been called, sort of.
582: $r->print(&hiddenfield('not_first_run','whatever'));
583: #
584: if (exists($env{'form.not_first_run'}) || $sheettype ne 'classcalc') {
585: $r->print($spreadsheet->get_html_title());
586: if ($allowed_to_view || $allowed_to_edit) {
587: $r->print($spreadsheet->parent_link());
588: }
589: $r->rflush();
590: $spreadsheet->display($r);
591: }
592: $r->print('</form>'.&Apache::loncommon::end_page());
593: $spreadsheet->clear_package();
594: return OK;
595: }
596:
597: 1;
598:
599: __END__
600:
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>
![[BACK]](/icons/back.gif){kind=icon}
Return to lonspreadsheet.pm CVS log ![[TXT]](/icons/text.gif){kind=icon}
![[DIR]](/icons/dir.gif){kind=icon}
Up to [LON-CAPA] / loncom / interface / spreadsheet