Return to lonspreadsheet.pm CVS log

Up to [LON-CAPA] / loncom / interface / spreadsheet

Added $spreadsheet->initialize() subroutine to take care of specific
initialization needed for each sheet.  assesscalc now has a list of
mandatory parameters (Bug 1514) but is running in to problems with
bug 1513.

#
# $Id: lonspreadsheet.pm,v 1.8 2003/05/29 13:39:38 matthew Exp $
#
# Copyright Michigan State University Board of Trustees
#
# This file is part of the LearningOnline Network with CAPA (LON-CAPA).
#
# LON-CAPA is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# LON-CAPA is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with LON-CAPA; if not, write to the Free Software
# Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
#
# /home/httpd/html/adm/gpl.txt
#
# http://www.lon-capa.org/
#
# The LearningOnline Network with CAPA
# Spreadsheet/Grades Display Handler
#
# POD required stuff:

=head1 NAME

lonspreadsheet

=head1 SYNOPSIS

Spreadsheet interface to internal LON-CAPA data

=head1 DESCRIPTION

Lonspreadsheet provides course coordinators the ability to manage their
students grades online.  The students are able to view their own grades, but
not the grades of their peers.  The spreadsheet is highly customizable,
offering the ability to use Perl code to manipulate data, as well as many
built-in functions.

=head2 Functions available to user of lonspreadsheet

=over 4

=cut


package Apache::lonspreadsheet;
            
use strict;
use Apache::classcalc();
use Apache::studentcalc();
use Apache::assesscalc();
use Apache::Constants qw(:common :http);
use Apache::lonnet;
use Apache::lonhtmlcommon;
use HTML::Entities();

##
## HTML utility subroutines really should go in lonhtmlcommon
##

sub textfield {
    my ($title,$name,$value)=@_;
    return "\n<p><b>$title:</b><br>".
        '<input type=text name="'.$name.'" size=80 value="'.$value.'">';
}

sub hiddenfield {
    my ($name,$value)=@_;
    return '<input type=hidden name="'.$name.'" value="'.$value.'" />'."\n";
}

sub selectbox {
    my ($title,$name,$value,%options)=@_;
    my $selout="\n<p><b>$title:</b><br>".'<select name="'.$name.'">';
    foreach (sort keys(%options)) {
        $selout.='<option value="'.$_.'"';
        if ($_ eq $value) { $selout.=' selected'; }
        $selout.='>'.$options{$_}.'</option>';
    }
    return $selout.'</select>';
}

sub file_dialogs {
    my ($spreadsheet) = @_;
    my $bgcolor = "#FFFFFF";
    my $sheettype = $spreadsheet->{'type'};
    my $result = '';
    ##
    ## Deal with saving the spreadsheet
    if (exists($ENV{'form.save'}) && 
        exists($ENV{'form.savefilename'})) {
        $spreadsheet->filename($ENV{'form.savefilename'});
        my $save_status = $spreadsheet->save();
        if ($save_status ne 'ok') {
            $result .= "An error occurred while saving the spreadsheet".
                "There error is:".$save_status;
            return $result;
        } else {
            $result .= "Spreadsheet saved as ".$ENV{'form.savefilename'};
        }
    } elsif (exists($ENV{'form.newformula'}) && 
             exists($ENV{'form.cell'})       && 
             $ENV{'form.cell'} ne '' ) {
        ##
        ## Make any requested modifications to the spreadsheet
        $spreadsheet->modify_cell($ENV{'form.cell'},
                                  $ENV{'form.newformula'});
        $spreadsheet->save_tmp();
        # output that we are dealing with a temporary file
        $result .=&hiddenfield('workcopy',$sheettype);
        $result .='<pre>'.$ENV{'form.cell'}.' = '.
                  $ENV{'form.newformula'}."</pre>\n";
    }
    ##
    ## Editing code
    $result .=&hiddenfield('cell','').
              &hiddenfield('newformula','');
    ##
    ## Create the save and load dialogs
    my $filename = $spreadsheet->filename();
    $filename = 'Default' if ($filename =~ /^default\.$sheettype/i);
    $filename =~ s/_$sheettype$//;
    my $save_dialog = '<nobr>'.
        '<input type="submit" name="save" value="Save as" /> '.
        '<input type="text" name="savefilename" size="30" value="'.
        $filename.'" />'.
        '</nobr>';
    my $makedefault_dialog = '<input type="submit" name="makedefault" '.
        'value="Make This Sheet the Default"/>';
    #
    my $link = '<a href="javascript:openbrowser'.
        "('sheet','loadfilename','spreadsheet')\">Browse</a>";
    my $load_dialog = <<END;
<table bgcolor="$bgcolor">
<tr><td><input type="submit" name="load" value="Load" /></td>
    <td><nobr>
        <input type="text" name="loadfilename" size="25" value="$filename" />
        $link</nobr>
    </td></tr>
<tr><td>&nbsp;</td><td>
    <select name="fileselect" onchange="document.sheet.loadfilename.value=document.sheet.fileselect.value" >
END
    my $default_filename_set = 0;
    foreach my $sheetfilename ($spreadsheet->othersheets()) {
        $sheetfilename =~ s/_$sheettype$//;
        $load_dialog .= '    <option name="'.$sheetfilename.'"';
        if ($filename eq $sheetfilename) {
            $load_dialog .= ' selected';
            $default_filename_set = 1;
        }
        $load_dialog .= '>'.$sheetfilename."</option>\n";
    }
    if ($default_filename_set) {
        $load_dialog .= '<option name="Default">Default</option>'."\n";
    } else {
        $load_dialog .= '<option name="Default" selected >Default</option>'.
            "\n";
    }
    $load_dialog .= "</td><td>&nbsp;</td></tr>\n</table>\n";
        #
    $result .=<<END;
<!-- load / save dialogs -->
<table cellspacing="2">
<tr>
    <td>$load_dialog</td>
    <td>
        <table bgcolor="$bgcolor">
        <tr><td>$save_dialog</td></tr>
        <tr><td align="center">$makedefault_dialog</td></tr>
        </table>
    </td>
</tr>
</table>
END
    return $result;
}

sub handler {
    my $r=shift;
    #
    # Overload checking
    #
    # Check this server
    my $loaderror=&Apache::lonnet::overloaderror($r);
    if ($loaderror) { return $loaderror; }
    # Check the course homeserver
    $loaderror= &Apache::lonnet::overloaderror($r,
                      $ENV{'course.'.$ENV{'request.course.id'}.'.home'});
#    if ($loaderror) { return $loaderror; } 
    #
    # HTML Header
    #
    if ($r->header_only) {
        $r->content_type('text/html');
        $r->send_http_header;
        return OK;
    }
    #
    # Roles Checking
    #
    # Needs to be in a course
    if (! $ENV{'request.course.fn'}) { 
        # Not in a course, or not allowed to modify parms
        $ENV{'user.error.msg'}=
            $r->uri.":opa:0:0:Cannot modify spreadsheet";
        return HTTP_NOT_ACCEPTABLE; 
    }
    #
    # Get query string for limited number of parameters
    #
    &Apache::loncommon::get_unprocessed_cgi
        ($ENV{'QUERY_STRING'},['sname','sdomain','usymb','filename']);
    #
    # Deal with restricted student permissions 
    #
    if ($ENV{'request.role'} =~ /^st\./) {
        delete $ENV{'form.cell'}       if (exists($ENV{'form.cell'}));
        delete $ENV{'form.newformula'} if (exists($ENV{'form.newformula'}));
    }
    #
    # Determine basic information about the spreadsheet
    my ($sheettype) = ($r->uri=~/\/(\w+)$/);
    #
    my $symb   = undef;
    $symb = $ENV{'form.usymb'} if (exists($ENV{'form.usymb'}));
    my $name   = $ENV{'user.name'};
    my $domain = $ENV{'user.domain'};
    if (exists($ENV{'form.sname'})) {
        $name   = $ENV{'form.sname'};
        $domain = $ENV{'form.sdomain'};
    }
    #
    # Open page, try to prevent browser cache.
    #
    $r->content_type('text/html');
    $r->header_out('Cache-control','no-cache');
    $r->header_out('Pragma','no-cache');
    $r->send_http_header;
    ##
    ## Check permissions
    my $allowed_to_edit = &Apache::lonnet::allowed('mgr',
                                                $ENV{'request.course.id'});
    my $allowed_to_view =  &Apache::lonnet::allowed('vgr',
                                                $ENV{'request.course.id'});

    #
    # Only those able to view others grades will be allowed to continue 
    # if they are not requesting their own.
    if (($sheettype eq 'classcalc') || 
        ($name   ne $ENV{'user.name'} ) ||
        ($domain ne $ENV{'user.domain'})) {
        if (! $allowed_to_view) {
            $r->print('<h1>Access Permission Denied</h1>'.
                      '</form></body></html>');
            return OK;
        }
    }
    #
    # Header....
    #
    $r->print('<html><head><title>LON-CAPA Spreadsheet</title>');
    my $nothing = &Apache::lonhtmlcommon::javascript_nothing();
    ##
    ## Spit out the javascript required for editing
    ##
    if ($allowed_to_edit) {
        my $extra_javascript = 
            &Apache::loncommon::browser_and_searcher_javascript();
        $r->print(<<ENDSCRIPT);
<script language="JavaScript">

    $extra_javascript

    var editwin;

    function celledit(cellname,cellformula) {
        var edit_text = '';
        // cellformula may contain less-than and greater-than symbols, so
        // we need to escape them?  
        edit_text +='<html><head><title>Cell Edit Window</title></head><body>';
        edit_text += '<form name="editwinform">';
        edit_text += '<center><h3>Cell '+cellname+'</h3>';
        edit_text += '<textarea name="newformula" cols="40" rows="6"';
        edit_text += ' wrap="off" >'+cellformula+'</textarea>';
        edit_text += '</br>';
        edit_text += '<input type="button" name="accept" value="Accept"';
        edit_text += ' onClick=\\\'javascript:';
        edit_text += 'opener.document.sheet.cell.value=';
        edit_text +=     '"'+cellname+'";';
        edit_text += 'opener.document.sheet.newformula.value=';
        edit_text +=     'document.editwinform.newformula.value;';
        edit_text += 'opener.document.sheet.submit();';
        edit_text += 'self.close()\\\' />';
        edit_text += '&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;';
        edit_text += '<input type="button" name="abort" ';
        edit_text +=     'value="Discard Changes"';
        edit_text += ' onClick="javascript:self.close()" />';
        edit_text += '</center></body></html>';

        if (editwin != null && !(editwin.closed) ) {
            editwin.close();
        }

        editwin = window.open($nothing,'CellEditWin','height=200,width=350,scrollbars=no,resizeable=yes,alwaysRaised=yes,dependent=yes',true);
        editwin.document.write(edit_text);
    }
</script>
ENDSCRIPT
    }
    $r->print('</head>'.&Apache::loncommon::bodytag('Grades Spreadsheet').
              '<form action="'.$r->uri.'" name="sheet" method="post">');
    $r->print(&hiddenfield('sname'  ,$ENV{'form.sname'}).
              &hiddenfield('sdomain',$ENV{'form.sdomain'}).
              &hiddenfield('usymb'  ,$ENV{'form.usymb'}));
    $r->rflush();
    ##
    ## Determine the filename to use
    my $filename = undef;
    if ($allowed_to_edit) {
        $filename = $ENV{'form.filename'} if (exists($ENV{'form.filename'}));
        #
        if (exists($ENV{'form.load'}) && exists($ENV{'form.loadfilename'})) {
            $filename = $ENV{'form.loadfilename'};
            $ENV{'form.workcopy'} = 'no';
        }
    }
    ##
    ## Make the spreadsheet
    &Apache::Spreadsheet::initialize_spreadsheet_package();
    my $spreadsheet = undef;
    if ($sheettype eq 'classcalc') {
        $spreadsheet = Apache::classcalc->new($name,$domain,$filename,undef);
    } elsif ($sheettype eq 'studentcalc') {
        $spreadsheet = Apache::studentcalc->new($name,$domain,$filename,undef);
    } elsif ($sheettype eq 'assesscalc' && 
             defined($symb) && 
             $allowed_to_edit) {
        $spreadsheet = Apache::assesscalc->new($name,$domain,$filename,$symb);
    } else {
        return HTTP_NOT_ACCEPTABLE;
    }
    if (! defined($spreadsheet)) {
        # error error - run in circles, scream and shout
        return;
    }
    $spreadsheet->initialize();
    #
    # Output selector
    $r->print('<input type="submit" value="Update Display" /><br />');
    ##
    ## Editing/loading/saving
    if ($allowed_to_edit) {
        $r->print('<table><tr><td>'.$spreadsheet->html_header().'</td>'.
                  '<td valign="bottom">'.
                  &file_dialogs($spreadsheet)."</td></tr></table>\n");
        $r->rflush();
    } else {
        $r->print('<table><tr><td>'.$spreadsheet->html_header().
                  "</td></tr></table>\n");
    }
    #
    # Keep track of the filename
    $r->print(&hiddenfield('filename',$filename));
    #
    # Keep track of the number of times we have been called, sort of.
    $r->print(&hiddenfield('not_first_run','whatever'));
    #
    if (exists($ENV{'form.not_first_run'}) || $sheettype ne 'classcalc') {
        $r->print($spreadsheet->get_html_title());
        if ($allowed_to_view || $allowed_to_edit) {
            $r->print($spreadsheet->parent_link());
        }
        $spreadsheet->display($r);
    } else {
        $r->print("<h2>Make your selections and bonk the 'update display' button</h2>");
    }
    $r->print('</form></body></html>');
    return OK;
}

1;

__END__