1: # The LearningOnline Network with CAPA
2: #
3: # $Id: lonsubmissiontimeanalysis.pm,v 1.35 2012/05/10 10:29:09 goltermann Exp $
4: #
5: # Copyright Michigan State University Board of Trustees
6: #
7: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
8: #
9: # LON-CAPA is free software; you can redistribute it and/or modify
10: # it under the terms of the GNU General Public License as published by
11: # the Free Software Foundation; either version 2 of the License, or
12: # (at your option) any later version.
13: #
14: # LON-CAPA is distributed in the hope that it will be useful,
15: # but WITHOUT ANY WARRANTY; without even the implied warranty of
16: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
17: # GNU General Public License for more details.
18: #
19: # You should have received a copy of the GNU General Public License
20: # along with LON-CAPA; if not, write to the Free Software
21: # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
22: #
23: # /home/httpd/html/adm/gpl.txt
24: #
25: # http://www.lon-capa.org/
26: #
27:
28: package Apache::lonsubmissiontimeanalysis;
29:
30: use strict;
31: use Apache::lonnet;
32: use Apache::loncommon();
33: use Apache::lonhtmlcommon();
34: use Apache::lonquickgrades();
35: use Apache::loncoursedata();
36: use Apache::lonstatistics;
37: use Apache::lonstathelpers;
38: use Apache::lonlocal;
39: use HTML::Entities();
40: use Time::Local();
41:
42: my $plotcolors = ['#33ff00',
43: '#ff33cc', '#990000', '#aaaa66', '#663399', '#ff9933',
44: '#66ccff', '#ff9999', '#cccc33', '#660000', '#33cc66',
45: ];
46:
47: my @SubmitButtons = (
48: { name => 'PrevProblemAnalysis',
49: text => 'Previous Problem' },
50: { name => 'ProblemAnalysis',
51: text => 'Analyze Problem Again' },
52: { name => 'NextProblemAnalysis',
53: text => 'Next Problem' },
54: { name => 'SelectAnother',
55: text => 'Choose a different Problem' },
56: );
57:
58: sub BuildSubmissionTimePage {
59: my ($r,$c)=@_;
60: #
61: my %Saveable_Parameters = ('Status' => 'scalar',
62: 'Section' => 'array');
63: &Apache::loncommon::store_course_settings('submissiontime_analysis',
64: \%Saveable_Parameters);
65: &Apache::loncommon::restore_course_settings('submissiontime_analysis',
66: \%Saveable_Parameters);
67: #
68: &Apache::lonstatistics::PrepareClasslist();
69: #
70: $r->print(&Apache::lonhtmlcommon::breadcrumbs('Submission Time Plots'));
71: &Apache::lonquickgrades::startGradeScreen($r,'statistics');
72: $r->print(&CreateInterface());
73: #
74: my @Students = @Apache::lonstatistics::Students;
75: #
76: if (@Students < 1) {
77: $r->print('<div class="LC_warning">'
78: .&mt('There are no students in the sections selected.'
79: .'</div>')
80: );
81: }
82: #
83: my @CacheButtonHTML =
84: &Apache::lonstathelpers::manage_caches($r,'Statistics','stats_status');
85: $r->rflush();
86: #
87: if (! exists($env{'form.problemchoice'}) ||
88: exists($env{'form.SelectAnother'})) {
89: my $submit_button = '<input type="submit" name="" value="'.
90: # &mt('Graph Problem Submission Times').'" />';
91: &mt('Generate Graph').'" />';
92: $r->print($submit_button.' 'x5);
93: $r->print('<h3>'.&mt('Please select a problem to analyze').'</h3>');
94: $r->print(&Apache::lonstathelpers::problem_selector('.',
95: $submit_button));
96: } else {
97: foreach my $button (@SubmitButtons) {
98: $r->print('<input type="submit" name="'.$button->{'name'}.'" '.
99: 'value="'.&mt($button->{'text'}).'" />');
100: $r->print(' 'x5);
101: }
102: foreach my $html (@CacheButtonHTML) {
103: $r->print($html.(' 'x5));
104: }
105: $r->rflush();
106: #
107: # Determine which problem we are to analyze
108: my $current_problem = &Apache::lonstathelpers::get_target_from_id
109: ($env{'form.problemchoice'});
110: #
111: my ($navmap,$prev,$curr,$next) =
112: &Apache::lonstathelpers::get_prev_curr_next($current_problem,
113: '.',
114: 'part');
115: if (exists($env{'form.PrevProblemAnalysis'}) && defined($prev)) {
116: $current_problem = $prev;
117: } elsif (exists($env{'form.NextProblemAnalysis'}) && defined($next)) {
118: $current_problem = $next;
119: } else {
120: $current_problem = $curr;
121: }
122: #
123: # Store the current problem choice and send it out in the form
124: $env{'form.problemchoice'} =
125: &Apache::lonstathelpers::make_target_id($current_problem);
126: $r->print('<input type="hidden" name="problemchoice" value="'.
127: $env{'form.problemchoice'}.'" />');
128: #
129: $r->print('<hr />');
130: $r->rflush();
131: #
132: my $resource = $current_problem->{'resource'};
133: if (! defined($resource)) {
134: $r->print('<div class="LC_warning">'
135: .&mt('Resource is undefined.')
136: .'</div>'
137: );
138: } else {
139: $r->print('<h1>'.$resource->compTitle.'</h1>');
140: $r->print('<h3>'.$resource->src.'</h3>');
141: $r->print('<p>'.
142: &Apache::lonstatistics::section_and_enrollment_description().
143: '</p>');
144: $r->rflush();
145: $r->print(&Apache::lonstathelpers::render_resource($resource));
146: $r->print('<br />');
147: $r->rflush();
148: if (@Students) {
149: $r->print(&analyze_times($r,$resource->symb,\@Students,
150: $current_problem->{'part'}));
151: }
152: }
153: $r->print('<hr />');
154: }
155: }
156:
157: #########################################################
158: #########################################################
159: ##
160: ## Time Analysis
161: ##
162: #########################################################
163: #########################################################
164: sub get_week_start {
165: my ($randomtime) = @_;
166: my ($sec,$min,$hour,$mday,$month,$year,$wday,$yday,$isdst) =
167: localtime($randomtime);
168: $randomtime -= $wday * 86400;
169: ($sec,$min,$hour,$mday,$month,$year,$wday,$yday,$isdst) =
170: localtime($randomtime);
171: my $week_start = &Time::Local::timelocal(0,0,0,$mday,$month,$year);
172: return $week_start;
173: }
174:
175: sub analyze_times {
176: my ($r,$symb,$students,$part) = @_;
177: my $htmltable;
178: #
179: # Convenience arrays
180: my @FullWeekDay = (qw/Sunday Monday Tuesday Wednesday Thursday Friday
181: Saturday/);
182: my @WeekDay = (qw/SUN MON TUE WED THU FRI SAT SUN/);
183: my @Month = (qw/Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec/);
184: #
185: my $html; # holds results of analysis
186: # Get the data
187: my $SubData = &Apache::loncoursedata::get_response_time_data
188: ([&Apache::lonstatistics::get_selected_sections()],
189: [&Apache::lonstatistics::get_selected_groups()],
190: $Apache::lonstatistics::enrollment_status,
191: $symb,$part);
192: if (! defined($SubData) || ! ref($SubData)) {
193: $html.= '<div class="LC_warning">'
194: .&mt('There is no submission data for this problem at all.')
195: .'</div>';
196: return $html;
197: }
198: my $NumSub = scalar(@{$SubData});
199: if (! @{$SubData}) {
200: $html.= '<div class="LC_warning">'
201: .&mt('There is no submission data for this problem.')
202: .'</div>';
203: return $html;
204: }
205: # Process the data
206: #
207: my (undef,undef,undef,$mday,$month,$year,$wday,$yday,$isdst) =
208: localtime(&get_time_from_row($SubData->[0]));
209: my $day_start = &Time::Local::timelocal(0,0,0,$mday,$month,$year);
210: #
211: # Configure the bins used to store the data.
212: my $binsize = 3600; # seconds
213: my $bins_per_day = 86400/$binsize;
214: my $bincount = 0;
215: my $endtime = $day_start;
216: #
217: # Initialize loop variables
218: my $max; # The sum of @Ydata
219: my @Ydata=(0); # number of submissions
220: my @AnsData=(0); # number of correct submissions
221: my @Xlabel=($WeekDay[$wday]); # Labels of itmes
222: my @BinEnd; # The end time of each bin
223: my $cumulative_answers = 0; # The sum of @AnsData
224: my %students; # which students have attempted the problem?
225: #
226: foreach my $row (@$SubData) {
227: my $subtime = &get_time_from_row($row);
228: while ($subtime > $endtime && $endtime < time) {
229: # Create a new bin
230: $bincount++;
231: $Ydata[$bincount] = 0;
232: $AnsData[$bincount] = 0;
233: $endtime += $binsize;
234: push(@BinEnd,$endtime);
235: if ($bincount % (86400/$binsize) == 0) {
236: $wday++;
237: $wday %= 7;
238: $Xlabel[$bincount] = $WeekDay[$wday];
239: } else {
240: $Xlabel[$bincount] = '';
241: }
242: }
243: $Ydata[$bincount]++;
244: $max = $Ydata[$bincount] if ($max < $Ydata[$bincount]);
245: $AnsData[$bincount] += &successful_submission($row);
246: $cumulative_answers += &successful_submission($row);
247: $students{$row->[&Apache::loncoursedata::RT_student_id()]}++;
248: }
249: #
250: # Pad the data to a full day
251: while ($bincount % $bins_per_day != 0) {
252: $bincount++;
253: $Ydata[$bincount]=0;
254: $AnsData[$bincount]=0;
255: $endtime += $binsize;
256: push(@BinEnd,$endtime);
257: if ($bincount % (86400/$binsize) == 0) {
258: $wday ++;
259: $wday %= 7;
260: $Xlabel[$bincount] = $WeekDay[$wday];
261: } else {
262: $Xlabel[$bincount] = '';
263: }
264: }
265: my $numstudents = scalar(keys(%students));
266: #
267: # Determine a nice maximum value to use
268: foreach my $maximum (10,15,20,25,30,40,50,60,70,80,90,100,
269: 120,150,200,250,300,350,400,450,500,
270: 600,700,800,900,1000,1100,1200,1500,2000,
271: 2500,3000,4000,5000) {
272: if ($max < $maximum) {
273: $max = $maximum;
274: last;
275: }
276: }
277: #
278: # Build the data table
279: $htmltable = '<br><h3>'.&mt('Student submission data').'</h3><p>'.
280: &Apache::loncommon::start_data_table().
281: &Apache::loncommon::start_data_table_header_row().
282: &Apache::loncommon::start_data_table_row().
283: '<th valign="bottom">'.&mt('Begin').'</th>'.
284: '<th valign="bottom">'.&mt('End').'</th>'.
285: '<th valign="bottom">'.&mt('Submissions (plotted)').'</th>'.
286: '<th valign="bottom">'.&mt('Correct Submissions (not plotted)').'</th>'.
287: '<th valign="bottom">'.&mt('Cumulative Correct of those attempting the problem (not plotted)').'</th>'.
288: '<th valign="bottom">'.&mt('Cumulative Percent Correct of those attempting the problem (not plotted)').'</th>'.
289: '<th valign="bottom">'.&mt('Cumulative Percent Correct of selected students (plotted)').'</th>'.
290: &Apache::loncommon::end_data_table_row().
291: &Apache::loncommon::end_data_table_header_row().
292: '<tbody>';
293: my @CumulativeCorrect=(0);
294: my @corr_as_percent_of_selected;
295: my @corr_as_percent_of_answering;
296: for (my $i=0;$i<=$#Ydata;$i++) {
297: $CumulativeCorrect[$i]=$CumulativeCorrect[-1]+$AnsData[$i];
298: $corr_as_percent_of_answering[$i] =
299: sprintf('%3.1f',100*$CumulativeCorrect[$i]/$numstudents);
300: $corr_as_percent_of_selected[$i] =
301: sprintf('%3.1f',100*$CumulativeCorrect[$i]/scalar(@$students));
302: if ($Ydata[$i] != 0) {
303: next if (! defined($BinEnd[$i]) || $BinEnd[$i] == 0);
304: $htmltable .=
305: &Apache::loncommon::start_data_table_row().
306: '<td align="right"><span class="LC_nobreak">'.
307: &Apache::lonlocal::locallocaltime($BinEnd[$i]-$binsize).
308: '</span></td>'.
309: '<td align="right"><span class="LC_nobreak">'.
310: &Apache::lonlocal::locallocaltime($BinEnd[$i]).'</td>'.
311: '</span></td>'.
312: '<td align="right">'.$Ydata[$i].(' 'x3).'</td>'.
313: '<td align="right">'.$AnsData[$i].(' 'x3).'</td>'.
314: '<td align="right">'.$CumulativeCorrect[$i].'</td>'.
315: '<td align="right">'.$corr_as_percent_of_answering[$i].'</td>'.
316: '<td align="right">'.$corr_as_percent_of_selected[$i].'</td>'.
317: &Apache::loncommon::end_data_table_row().$/;
318: }
319: }
320: $htmltable .= '</tbody>'.&Apache::loncommon::end_data_table().'</p>';
321: #
322: # Build the plot
323: my $title = '';#'Number of Submissions and Number Correct';
324: my $xlabel;
325: (undef,undef,undef,$mday,$month,$year,$wday) = localtime($day_start);
326: $xlabel .= $FullWeekDay[$wday].' '.
327: join(' ',($Month[$month],$mday,1900+$year)).' - ';
328: (undef,undef,undef,$mday,$month,$year,$wday) = localtime($endtime);
329: $xlabel .= $FullWeekDay[$wday].' '.
330: join(' ',($Month[$month],$mday,1900+$year));
331: my $width = 50+2*$bincount;
332: if ($width < 250) {
333: $width = 250;
334: }
335: #
336: $html .= &Apache::loncommon::DrawXYYGraph($title,
337: $xlabel,
338: 'Submissions vs Time',
339: $plotcolors,
340: \@Xlabel,
341: \@Ydata,0,$max,
342: \@corr_as_percent_of_selected,0,100,
343: (xskip => $bins_per_day,
344: x_ticks => $bins_per_day,
345: x_tick_offset => $bins_per_day,
346: width => $width,
347: y1_label=>'Number of Submissions per hour',
348: y2_label=>'Percent of Students answering Correctly',
349: 'data.1.label'=>'Submissions per hour',
350: 'data.2.label'=>'Percent correct',
351: )
352: );
353: $html .= '<br />'.$htmltable;
354: return $html;
355: }
356:
357: sub successful_submission {
358: my ($row) = @_;
359: if (ref($row) eq 'ARRAY') {
360: return $row->[&Apache::loncoursedata::RT_awarded()];
361: }
362: return undef;
363: }
364:
365: sub get_time_from_row {
366: my ($row) = @_;
367: if (ref($row) eq 'ARRAY') {
368: return $row->[&Apache::loncoursedata::RT_timestamp()];
369: }
370: return undef;
371: }
372:
373: sub get_tries_from_row {
374: my ($row) = @_;
375: if (ref($row) eq 'ARRAY') {
376: return $row->[&Apache::loncoursedata::RT_tries()];
377: }
378: return undef;
379: }
380:
381: sub Process_Row {
382: my ($row) = @_;
383: my %RowData;
384: my ($student_id,$award,$tries,$time) = @$row;
385: return %RowData;
386: }
387:
388: #########################################################
389: #########################################################
390: ##
391: ## Generic Interface Routines
392: ##
393: #########################################################
394: #########################################################
395: sub CreateInterface {
396: ##
397: ## Environment variable initialization
398: if (! exists$env{'form.AnalyzeOver'}) {
399: $env{'form.AnalyzeOver'} = 'Tries';
400: }
401: ##
402: ## Build the menu
403: my $Str = '';
404: $Str .= '<p>';
405: $Str .= &Apache::loncommon::start_data_table();
406: $Str .= &Apache::loncommon::start_data_table_header_row();
407: $Str .= '<th>'.&mt('Sections').'</th>';
408: $Str .= '<th>'.&mt('Groups').'</th>';
409: $Str .= '<th>'.&mt('Access Status').'</th>';
410: $Str .= &Apache::loncommon::end_data_table_header_row();
411: ##
412: ##
413: $Str .= &Apache::loncommon::start_data_table_row();
414: $Str .= '<td align="center">'."\n";
415: $Str .= &Apache::lonstatistics::SectionSelect('Section','multiple',4);
416: $Str .= '</td>';
417: #
418: $Str .= '<td align="center">'."\n";
419: $Str .= &Apache::lonstatistics::GroupSelect('Group','multiple',4);
420: $Str .= '</td>';
421: #
422: $Str .= '<td align="center">';
423: $Str .= &Apache::lonhtmlcommon::StatusOptions(undef,undef,4);
424: $Str .= '</td>';
425: #
426: $Str .= &Apache::loncommon::end_data_table_row();
427: $Str .= &Apache::loncommon::end_data_table();
428: #
429: $Str .= '</p>';
430: ##
431: return $Str;
432: }
433:
434: 1;
435:
436: __END__
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>