1: # The LearningOnline Network with CAPA
2: # Localization routines
3: #
4: # $Id: lonlocal.pm,v 1.51 2008/11/24 16:53:16 jms Exp $
5: #
6: # Copyright Michigan State University Board of Trustees
7: #
8: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
9: #
10: # LON-CAPA is free software; you can redistribute it and/or modify
11: # it under the terms of the GNU General Public License as published by
12: # the Free Software Foundation; either version 2 of the License, or
13: # (at your option) any later version.
14: #
15: # LON-CAPA is distributed in the hope that it will be useful,
16: # but WITHOUT ANY WARRANTY; without even the implied warranty of
17: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18: # GNU General Public License for more details.
19: #
20: # You should have received a copy of the GNU General Public License
21: # along with LON-CAPA; if not, write to the Free Software
22: # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
23: #
24: # /home/httpd/html/adm/gpl.txt
25: #
26: # http://www.lon-capa.org/
27: #
28: ######################################################################
29: ######################################################################
30:
31: =pod
32:
33: =head1 NAME
34:
35: Apache::lonlocal - provides localization services
36:
37: =head1 SYNOPSIS
38:
39: lonlocal provides localization services for LON-CAPA programmers based
40: on Locale::Maketext. See
41: C<http://search.cpan.org/dist/Locale-Maketext/lib/Locale/Maketext.pod>
42: for more information on Maketext.
43:
44: =head1 OVERVIEWX<internationalization>
45:
46: As of LON-CAPA 1.1, we've started to localize LON-CAPA using the
47: Locale::Maketext module. Internationalization is the bulk of the work
48: right now (pre-1.1); localizing can be done anytime, and involves
49: little or no programming.
50:
51: The internationalization process involves putting a wrapper around
52: on-screen user messages and menus and turning them into keys,
53: which the MaketextX<Maketext> library translates into the desired
54: language output using a look-up table ("lexicon").X<lexicon>
55:
56: As keys we are currently using the plain English messages, and
57: Maketext is configured to replace the message by its own key if no
58: translation is found. This makes it easy to phase in the
59: internationalization without disturbing the screen output.
60:
61: Internationalization is somewhat tedious and effectively impossible
62: for a non-fluent speaker to perform, but is fairly easy to create
63: translations, requiring no programming skill. As a result, this is one
64: area where you can really help LON-CAPA out, even if you aren't a
65: programmer, and we'd really appreciate it.
66:
67: =head1 How To Localize Handlers For Programmers
68:
69: Into the "use" section of a module, we need to insert
70:
71: use Apache::lonlocal;
72:
73: Note that there are B<no parentheses>, we B<want> to pollute our
74: namespace.
75:
76: Inside might be something like this
77:
78: sub message {
79: my $status=shift;
80: my $message='Status unknown';
81: if ($status eq 'WON') {
82: $message='You have won.';
83: } elsif ($status eq 'LOST') {
84: $message='You are a total looser.';
85: }
86: return $message;
87: }
88: ...
89: $r->print('<h3>Gamble your Homework Points</h3>');
90: ...
91: $r->print(<<ENDMSG);
92: <font size="1">Rules:</font>
93: <font size="0">No purchase necessary. Illegal where not allowed.</font>
94: ENDMSG
95:
96: We have to now wrap the subroutine &mt()X<mt> ("maketext") around our
97: messages, but not around markup, etc. We also want minimal disturbance.
98: The first two examples are easy:
99:
100: sub message {
101: my $status=shift;
102: my $message='Status unknown';
103: if ($status eq 'WON') {
104: $message='You have won.';
105: } elsif ($status eq 'LOST') {
106: $message='You are a total looser.';
107: }
108: return &mt($message);
109: }
110: ...
111: $r->print('<h3>'.&mt('Gamble your Homework Points').'</h3>');
112:
113: The last one is a bummer, since you cannot call subroutines inside of
114: (<<MARKER). I have written a little subroutine to generate a translated
115: hash for that purpose:
116:
117: my %lt=&Apache::lonlocal::texthash('header' => 'Rules', 'disclaimer' =>
118: 'No purchase necessary. Illegal where not allowed.');
119: $r->print(<<ENDMSG);
120: <font size="1">$lt{'header'}:</font>
121: <font size="0">$lt{'disclaimer'}</font>
122: ENDMSG
123:
124: As a programmer, your job is done here. If everything worked, you
125: should see no changes on the screen.
126:
127: =head1 How To Localize LON-CAPA for Translators
128:
129: As a translator, you need to provide the lexicon for the keys, which in
130: this case is the plain text message. The lexicons sit in
131: loncom/localize/localize, with the language code as filename, for
132: example de.pm for the German translation. The file then simply looks
133: like this:
134:
135: 'You have won.'
136: => 'Sie haben gewonnen.',
137:
138: 'You are a total looser.'
139: => 'Sie sind der totale Verlierer.',
140:
141: 'Rules'
142: => 'Regeln',
143:
144: 'No purchase necessary. Illegal where not allowed.'
145: => 'Es ist erlaubt, einfach zu verlieren, und das ist Ihre Schuld.'
146:
147:
148: Comments may be added with the # symbol, which outside of a string
149: (the things with the apostrophe surrounding them, which are the
150: keys and translations) will cause the translation routines to
151: ignore the rest of the line.
152:
153: This is a relatively easy task, and any help is appreciated.
154:
155: Maketext can do a whole lot more, see
156: C<http://search.cpan.org/dist/Locale-Maketext/lib/Locale/Maketext.pod>
157: but for most purposes, we do not have to mess with that.
158:
159: =cut
160:
161: package Apache::lonlocal;
162:
163: use strict;
164: use Apache::localize;
165: use locale;
166: use POSIX qw(locale_h strftime);
167: use DateTime();
168: use DateTime::TimeZone;
169: use DateTime::Locale;
170:
171: require Exporter;
172:
173: our @ISA = qw (Exporter);
174: our @EXPORT = qw(mt mtn ns mt_user);
175:
176: # ========================================================= The language handle
177:
178: use vars qw($lh);
179:
180: # ===================================================== The "MakeText" function
181:
182: sub mt (@) {
183: # open(LOG,'>>/home/www/loncapa/loncom/localize/localize/newphrases.txt');
184: # print LOG (@_[0]."\n");
185: # close(LOG);
186: if ($lh) {
187: if ($_[0] eq '') {
188: if (wantarray) {
189: return @_;
190: } else {
191: return $_[0];
192: }
193: } else {
194: return $lh->maketext(@_);
195: }
196: } else {
197: if (wantarray) {
198: return @_;
199: } else {
200: return $_[0];
201: }
202: }
203: }
204:
205: sub mt_user {
206: my ($user_lh,@what) = @_;
207: if ($user_lh) {
208: if ($what[0] eq '') {
209: if (wantarray) {
210: return @what;
211: } else {
212: return $what[0];
213: }
214: } else {
215: return $user_lh->maketext(@what);
216: }
217: } else {
218: if (wantarray) {
219: return @what;
220: } else {
221: return $what[0];
222: }
223: }
224: }
225:
226: # ============================================================== What language?
227:
228: sub current_language {
229: if ($lh) {
230: my $lang=$lh->maketext('language_code');
231: return ($lang eq 'language_code'?'en':$lang);
232: }
233: return 'en';
234: }
235:
236: # ============================================================== What encoding?
237:
238: sub current_encoding {
239: my $default='UTF-8';
240: if ($Apache::lonnet::env{'browser.os'} eq 'win' &&
241: $Apache::lonnet::env{'browser.type'} eq 'explorer') {
242: $default='ISO-8859-1';
243: }
244: if ($lh) {
245: my $enc=$lh->maketext('char_encoding');
246: return ($enc eq 'char_encoding'?$default:$enc);
247: } else {
248: return $default;
249: }
250: }
251:
252: # =============================================================== Which locale?
253: # Refer to locale -a
254: #
255: sub current_locale {
256: if ($lh) {
257: my $enc=$lh->maketext('lang_locale');
258: return ($enc eq 'lang_locale'?'':$enc);
259: } else {
260: return undef;
261: }
262: }
263:
264: # ============================================================== Translate hash
265:
266: sub texthash {
267: my %hash=@_;
268: foreach (keys %hash) {
269: $hash{$_}=&mt($hash{$_});
270: }
271: return %hash;
272: }
273:
274: # ========= Get a handle (do not invoke in vain, leave this to access handlers)
275:
276: sub get_language_handle {
277: my $r=shift;
278: if ($r) {
279: my $headers=$r->headers_in;
280: $ENV{'HTTP_ACCEPT_LANGUAGE'}=$headers->{'Accept-language'};
281: }
282: my @languages=&Apache::loncommon::preferred_languages;
283: $ENV{'HTTP_ACCEPT_LANGUAGE'}='';
284: $lh=Apache::localize->get_handle(@languages);
285: if ($r) {
286: $r->content_languages([¤t_language()]);
287: }
288: ### setlocale(LC_ALL,¤t_locale);
289: }
290:
291: # ========================================================== Localize localtime
292: sub gettimezone {
293: my $timezone;
294: if ($Apache::lonnet::env{'course.'.$Apache::lonnet::env{'request.course.id'}.'.timezone'}) {
295: $timezone = $Apache::lonnet::env{'course.'.$Apache::lonnet::env{'request.course.id'}.'.timezone'};
296: } elsif ($Apache::lonnet::env{'request.course.id'} ne '') {
297: my $cdom = $Apache::lonnet::env{'course.'.$Apache::lonnet::env{'request.course.id'}.'.domain'};
298: if ($cdom ne '') {
299: my %domdefaults = &Apache::lonnet::get_domain_defaults($cdom);
300: if ($domdefaults{'timezone_def'} ne '') {
301: $timezone = $domdefaults{'timezone_def'};
302: }
303: }
304: } elsif ($Apache::lonnet::env{'request.role.domain'} ne '') {
305: my %uroledomdefs =
306: &Apache::lonnet::get_domain_defaults($Apache::lonnet::env{'request.role.domain'});
307: if ($uroledomdefs{'timezone_def'} ne '') {
308: $timezone = $uroledomdefs{'timezone_def'};
309: }
310: } elsif ($Apache::lonnet::env{'user.domain'} ne '') {
311: my %udomdefaults =
312: &Apache::lonnet::get_domain_defaults($Apache::lonnet::env{'user.domain'});
313: if ($udomdefaults{'timezone_def'} ne '') {
314: $timezone = $udomdefaults{'timezone_def'};
315: }
316: }
317: if ($timezone ne '') {
318: if (DateTime::TimeZone->is_valid_name($timezone)) {
319: return $timezone;
320: }
321: }
322: return 'local';
323: }
324:
325: sub locallocaltime {
326: my $thistime=shift;
327: if (!defined($thistime) || $thistime eq '') {
328: return &mt('Never');
329: }
330: if (($thistime < 0) || ($thistime eq 'NaN')) {
331: &Apache::lonnet::logthis("Unexpected time (negative or NaN) '$thistime' passed to lonlocal::locallocaltime");
332: return &mt('Never');
333: }
334: if ($thistime !~ /^\d+$/) {
335: &Apache::lonnet::logthis("Unexpected non-numeric time '$thistime' passed to lonlocal::locallocaltime");
336: return &mt('Never');
337: }
338:
339: my $dt = DateTime->from_epoch(epoch => $thistime)
340: ->set_time_zone(&gettimezone());
341: if ((¤t_language=~/^en/) || (!$lh)) {
342:
343: return $dt->strftime("%a %b %e %I:%M:%S %P %Y (%Z)");
344: } else {
345: my $format=$lh->maketext('date_locale');
346: if ($format eq 'date_locale') {
347: return $dt->strftime("%a %b %e %I:%M:%S %P %Y (%Z)");
348: }
349: my $time_zone = $dt->time_zone_short_name();
350: my $seconds = $dt->second();
351: my $minutes = $dt->minute();
352: my $twentyfour = $dt->hour();
353: my $day = $dt->day_of_month();
354: my $mon = $dt->month()-1;
355: my $year = $dt->year();
356: my $wday = $dt->wday();
357: if ($wday==7) { $wday=0; }
358: my $month =(split(/\,/,$lh->maketext('date_months')))[$mon];
359: my $weekday=(split(/\,/,$lh->maketext('date_days')))[$wday];
360: if ($seconds<10) {
361: $seconds='0'.$seconds;
362: }
363: if ($minutes<10) {
364: $minutes='0'.$minutes;
365: }
366: my $twelve=$twentyfour;
367: my $ampm;
368: if ($twelve>12) {
369: $twelve-=12;
370: $ampm=$lh->maketext('date_pm');
371: } else {
372: $ampm=$lh->maketext('date_am');
373: }
374: foreach ('seconds','minutes','twentyfour','twelve','day','year',
375: 'month','weekday','ampm') {
376: $format=~s/\$$_/eval('$'.$_)/gse;
377: }
378: return $format." ($time_zone)";
379: }
380: }
381:
382: sub getdatelocale {
383: my ($datelocale,$locale_obj);
384: if ($Apache::lonnet::env{'course.'.$Apache::lonnet::env{'request.course.id'}.'.datelocale'}) {
385: $datelocale = $Apache::lonnet::env{'course.'.$Apache::lonnet::env{'request.course.id'}.'.datelocale'};
386: } elsif ($Apache::lonnet::env{'request.course.id'} ne '') {
387: my $cdom = $Apache::lonnet::env{'course.'.$Apache::lonnet::env{'request.course.id'}.'.domain'};
388: if ($cdom ne '') {
389: my %domdefaults = &Apache::lonnet::get_domain_defaults($cdom);
390: if ($domdefaults{'datelocale_def'} ne '') {
391: $datelocale = $domdefaults{'datelocale_def'};
392: }
393: }
394: } elsif ($Apache::lonnet::env{'user.domain'} ne '') {
395: my %udomdefaults = &Apache::lonnet::get_domain_defaults($Apache::lonnet::env{'user.domain'});
396: if ($udomdefaults{'datelocale_def'} ne '') {
397: $datelocale = $udomdefaults{'datelocale_def'};
398: }
399: }
400: if ($datelocale ne '') {
401: eval {
402: $locale_obj = DateTime::Locale->load($datelocale);
403: };
404: if (!$@) {
405: if ($locale_obj->id() eq $datelocale) {
406: return $locale_obj;
407: }
408: }
409: }
410: return $locale_obj;
411: }
412:
413: =pod
414:
415: =item * normalize_string
416:
417: Normalize string (reduce fragility in the lexicon files)
418:
419: This normalizes a string to reduce fragility in the lexicon files of
420: huge messages (such as are used by the helper), and allow useful
421: formatting: reduce all consecutive whitespace to a single space,
422: and remove all HTML
423:
424: =cut
425:
426: sub normalize_string {
427: my $s = shift;
428: $s =~ s/\s+/ /g;
429: $s =~ s/<[^>]+>//g;
430: # Pop off beginning or ending spaces, which aren't good
431: $s =~ s/^\s+//;
432: $s =~ s/\s+$//;
433: return $s;
434: }
435:
436: =pod
437:
438: =item * ns
439:
440: alias for normalize_string; recommend using it only in the lexicon
441:
442: =cut
443:
444: sub ns {
445: return normalize_string(@_);
446: }
447:
448: =pod
449:
450: =item * mtn
451:
452: mtn: call the mt function and the normalization function easily.
453: Returns original non-normalized string if there was no translation
454:
455: =cut
456:
457: sub mtn (@) {
458: my @args = @_; # don't want to modify caller's string; if we
459: # didn't care about that we could set $_[0]
460: # directly
461: $args[0] = normalize_string($args[0]);
462: my $translation = &mt(@args);
463: if ($translation ne $args[0]) {
464: return $translation;
465: } else {
466: return $_[0];
467: }
468: }
469:
470: # ---------------------------------------------------- Replace MT{...} in files
471:
472: sub transstatic {
473: my $strptr=shift;
474: $$strptr=~s/MT\{([^\}]*)\}/&mt($1)/gse;
475: }
476:
477: =pod
478:
479: =item * mt_escape
480:
481: mt_escape takes a string reference and escape the [] in there so mt
482: will leave them as is and not try to expand them
483:
484: =cut
485:
486: sub mt_escape {
487: my ($str_ref) = @_;
488: $$str_ref =~s/~/~~/g;
489: $$str_ref =~s/([\[\]])/~$1/g;
490: }
491:
492: 1;
493:
494: __END__
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>